include/llvm/Intrinsics.td

   1 //===- Intrinsics.td - Defines all LLVM intrinsics ---------*- tablegen -*-===//
   2 //
   3 //                     The LLVM Compiler Infrastructure
   4 //
   5 // This file was developed by Chris Lattner and is distributed under the
   6 // University of Illinois Open Source License. See LICENSE.TXT for details.
   7 //
   8 //===----------------------------------------------------------------------===//
   9 //
  10 // This file defines properties of all LLVM intrinsics.
  11 //
  12 //===----------------------------------------------------------------------===//
  13
  14 include "llvm/CodeGen/ValueTypes.td"
  15
  16 //===----------------------------------------------------------------------===//
  17 //  Properties we keep track of for intrinsics.
  18 //===----------------------------------------------------------------------===//
  19
  20 class IntrinsicProperty;
  21
  22 // Intr*Mem - Memory properties.  An intrinsic is allowed to have exactly one of
  23 // these properties set.  They are listed from the most aggressive (best to use
  24 // if correct) to the least aggressive.  If no property is set, the worst case
  25 // is assumed (IntrWriteMem).
  26
  27 // IntrNoMem - The intrinsic does not access memory or have any other side
  28 // effects.  It may be CSE'd deleted if dead, etc.
  29 def IntrNoMem : IntrinsicProperty;
  30
  31 // IntrReadArgMem - This intrinsic reads only from memory that one of its
  32 // arguments points to, but may read an unspecified amount.
  33 def IntrReadArgMem : IntrinsicProperty;
  34
  35 // IntrReadMem - This intrinsic reads from unspecified memory, so it cannot be
  36 // moved across stores.  However, it can be reordered otherwise and can be
  37 // deleted if dead.
  38 def IntrReadMem : IntrinsicProperty;
  39
  40 // IntrWriteArgMem - This intrinsic reads and writes only from memory that one
  41 // of its arguments points to, but may access an unspecified amount.  It has no
  42 // other side effects.  This may only be used if the intrinsic doesn't "capture"
  43 // the argument pointer (e.g. storing it someplace).
  44 def IntrWriteArgMem : IntrinsicProperty;
  45
  46 // IntrWriteMem - This intrinsic may read or modify unspecified memory or has
  47 // other side effects.  It cannot be modified by the optimizer.  This is the
  48 // default if the intrinsic has no other Intr*Mem property.
  49 def IntrWriteMem : IntrinsicProperty;
  50
  51 //===----------------------------------------------------------------------===//
  52 // Types used by intrinsics.
  53 //===----------------------------------------------------------------------===//
  54
  55 class LLVMType<ValueType vt> {
  56   ValueType VT = vt;
  57 }
  58
  59 class LLVMPointerType<LLVMType elty>
  60   : LLVMType<iPTR>{
  61   LLVMType ElTy = elty;
  62 }
  63
  64 class LLVMMatchType<int num>
  65   : LLVMType<OtherVT>{
  66   int Number = num;
  67 }
  68
  69 def llvm_void_ty       : LLVMType<isVoid>;
  70 def llvm_anyint_ty     : LLVMType<iAny>;
  71 def llvm_anyfloat_ty   : LLVMType<fAny>;
  72 def llvm_i1_ty         : LLVMType<i1>;
  73 def llvm_i8_ty         : LLVMType<i8>;
  74 def llvm_i16_ty        : LLVMType<i16>;
  75 def llvm_i32_ty        : LLVMType<i32>;
  76 def llvm_i64_ty        : LLVMType<i64>;
  77 def llvm_float_ty      : LLVMType<f32>;
  78 def llvm_double_ty     : LLVMType<f64>;
  79 def llvm_f80_ty        : LLVMType<f80>;
  80 def llvm_f128_ty       : LLVMType<f128>;
  81 def llvm_ppcf128_ty    : LLVMType<ppcf128>;
  82 def llvm_ptr_ty        : LLVMPointerType<llvm_i8_ty>;             // i8*
  83 def llvm_ptrptr_ty     : LLVMPointerType<llvm_ptr_ty>;            // i8**
  84 def llvm_empty_ty      : LLVMType<OtherVT>;                       // { }
  85 def llvm_descriptor_ty : LLVMPointerType<llvm_empty_ty>;          // { }*
  86
  87 def llvm_v16i8_ty      : LLVMType<v16i8>;    // 16 x i8
  88 def llvm_v8i16_ty      : LLVMType<v8i16>;    //  8 x i16
  89 def llvm_v2i64_ty      : LLVMType<v2i64>;    //  2 x i64
  90 def llvm_v2i32_ty      : LLVMType<v2i32>;    //  2 x i32
  91 def llvm_v1i64_ty      : LLVMType<v1i64>;    //  1 x i64
  92 def llvm_v4i32_ty      : LLVMType<v4i32>;    //  4 x i32
  93 def llvm_v4f32_ty      : LLVMType<v4f32>;    //  4 x float
  94 def llvm_v2f64_ty      : LLVMType<v2f64>;    //  2 x double
  95
  96 // MMX Vector Types
  97 def llvm_v8i8_ty       : LLVMType<v8i8>;     //  8 x i8
  98 def llvm_v4i16_ty      : LLVMType<v4i16>;    //  4 x i16
  99
 100 def llvm_vararg_ty     : LLVMType<isVoid>;   // this means vararg here
 101
 102 //===----------------------------------------------------------------------===//
 103 // Intrinsic Definitions.
 104 //===----------------------------------------------------------------------===//
 105
 106 // Intrinsic class - This is used to define one LLVM intrinsic.  The name of the
 107 // intrinsic definition should start with "int_", then match the LLVM intrinsic
 108 // name with the "llvm." prefix removed, and all "."s turned into "_"s.  For
 109 // example, llvm.bswap.i16 -> int_bswap_i16.
 110 //
 111 //  * Types is a list containing the return type and the argument types
 112 //    expected for the intrinsic.
 113 //  * Properties can be set to describe the behavior of the intrinsic.
 114 //
 115 class Intrinsic<list<LLVMType> types,
 116                 list<IntrinsicProperty> properties = [],
 117                 string name = ""> {
 118   string LLVMName = name;
 119   string TargetPrefix = "";   // Set to a prefix for target-specific intrinsics.
 120   list<LLVMType> Types = types;
 121   list<IntrinsicProperty> Properties = properties;
 122 }
 123
 124 /// GCCBuiltin - If this intrinsic exactly corresponds to a GCC builtin, this
 125 /// specifies the name of the builtin.  This provides automatic CBE and CFE
 126 /// support.
 127 class GCCBuiltin<string name> {
 128   string GCCBuiltinName = name;
 129 }
 130
 131
 132 //===--------------- Variable Argument Handling Intrinsics ----------------===//
 133 //
 134
 135 def int_vastart : Intrinsic<[llvm_void_ty, llvm_ptr_ty], [], "llvm.va_start">;
 136 def int_vacopy  : Intrinsic<[llvm_void_ty, llvm_ptr_ty, llvm_ptr_ty], [],
 137                             "llvm.va_copy">;
 138 def int_vaend   : Intrinsic<[llvm_void_ty, llvm_ptr_ty], [], "llvm.va_end">;
 139
 140 //===------------------- Garbage Collection Intrinsics --------------------===//
 141 //
 142 def int_gcroot  : Intrinsic<[llvm_void_ty, llvm_ptrptr_ty, llvm_ptr_ty]>;
 143 def int_gcread  : Intrinsic<[llvm_ptr_ty, llvm_ptr_ty, llvm_ptrptr_ty],
 144                             [IntrReadArgMem]>;
 145 def int_gcwrite : Intrinsic<[llvm_void_ty, llvm_ptr_ty, llvm_ptr_ty,
 146                              llvm_ptrptr_ty], [IntrWriteArgMem]>;
 147
 148 //===--------------------- Code Generator Intrinsics ----------------------===//
 149 //
 150 def int_returnaddress : Intrinsic<[llvm_ptr_ty, llvm_i32_ty], [IntrNoMem]>;
 151 def int_frameaddress  : Intrinsic<[llvm_ptr_ty, llvm_i32_ty], [IntrNoMem]>;
 152 def int_stacksave     : Intrinsic<[llvm_ptr_ty], [IntrReadMem]>,
 153                         GCCBuiltin<"__builtin_stack_save">;
 154 def int_stackrestore  : Intrinsic<[llvm_void_ty, llvm_ptr_ty]>,
 155                         GCCBuiltin<"__builtin_stack_restore">;
 156 // IntrWriteArgMem is more pessimistic than strictly necessary for prefetch,
 157 // however it does conveniently prevent the prefetch from being reordered
 158 // with respect to nearby accesses to the same memory.
 159 def int_prefetch      : Intrinsic<[llvm_void_ty, llvm_ptr_ty,
 160                                    llvm_i32_ty, llvm_i32_ty],
 161                                   [IntrWriteArgMem]>;
 162 def int_pcmarker      : Intrinsic<[llvm_void_ty, llvm_i32_ty]>;
 163
 164 def int_readcyclecounter : Intrinsic<[llvm_i64_ty]>;
 165
 166 //===------------------- Standard C Library Intrinsics --------------------===//
 167 //
 168
 169 let Properties = [IntrWriteArgMem] in {
 170   def int_memcpy_i32  : Intrinsic<[llvm_void_ty, llvm_ptr_ty, llvm_ptr_ty,
 171                                    llvm_i32_ty, llvm_i32_ty]>;
 172   def int_memcpy_i64  : Intrinsic<[llvm_void_ty, llvm_ptr_ty, llvm_ptr_ty,
 173                                    llvm_i64_ty, llvm_i32_ty]>;
 174   def int_memmove_i32 : Intrinsic<[llvm_void_ty, llvm_ptr_ty, llvm_ptr_ty,
 175                                    llvm_i32_ty, llvm_i32_ty]>;
 176   def int_memmove_i64 : Intrinsic<[llvm_void_ty, llvm_ptr_ty, llvm_ptr_ty,
 177                                    llvm_i64_ty, llvm_i32_ty]>;
 178   def int_memset_i32  : Intrinsic<[llvm_void_ty, llvm_ptr_ty, llvm_i8_ty,
 179                                    llvm_i32_ty, llvm_i32_ty]>;
 180   def int_memset_i64  : Intrinsic<[llvm_void_ty, llvm_ptr_ty, llvm_i8_ty,
 181                                    llvm_i64_ty, llvm_i32_ty]>;
 182 }
 183
 184 let Properties = [IntrNoMem] in {
 185   def int_sqrt : Intrinsic<[llvm_anyfloat_ty, LLVMMatchType<0>]>;
 186   def int_powi : Intrinsic<[llvm_anyfloat_ty, LLVMMatchType<0>, llvm_i32_ty]>;
 187 }
 188
 189 // NOTE: these are internal interfaces.
 190 def int_setjmp     : Intrinsic<[llvm_i32_ty , llvm_ptr_ty]>;
 191 def int_longjmp    : Intrinsic<[llvm_void_ty, llvm_ptr_ty, llvm_i32_ty]>;
 192 def int_sigsetjmp  : Intrinsic<[llvm_i32_ty , llvm_ptr_ty, llvm_i32_ty]>;
 193 def int_siglongjmp : Intrinsic<[llvm_void_ty, llvm_ptr_ty, llvm_i32_ty]>;
 194
 195 //===-------------------- Bit Manipulation Intrinsics ---------------------===//
 196 //
 197
 198 // None of these intrinsics accesses memory at all.
 199 let Properties = [IntrNoMem] in {
 200   def int_bswap: Intrinsic<[llvm_anyint_ty, LLVMMatchType<0>]>;
 201   def int_ctpop: Intrinsic<[llvm_anyint_ty, LLVMMatchType<0>]>;
 202   def int_ctlz : Intrinsic<[llvm_anyint_ty, LLVMMatchType<0>]>;
 203   def int_cttz : Intrinsic<[llvm_anyint_ty, LLVMMatchType<0>]>;
 204   def int_part_select :
 205      Intrinsic<[llvm_anyint_ty, LLVMMatchType<0>, llvm_i32_ty, llvm_i32_ty]>;
 206   def int_part_set :
 207      Intrinsic<[llvm_anyint_ty, LLVMMatchType<0>, llvm_anyint_ty, llvm_i32_ty,
 208                 llvm_i32_ty]>;
 209 }
 210
 211 //===------------------------ Debugger Intrinsics -------------------------===//
 212 //
 213
 214 def int_dbg_stoppoint    : Intrinsic<[llvm_void_ty,
 215                                       llvm_i32_ty, llvm_i32_ty,
 216                                       llvm_descriptor_ty]>;
 217 def int_dbg_region_start : Intrinsic<[llvm_void_ty, llvm_descriptor_ty]>;
 218 def int_dbg_region_end   : Intrinsic<[llvm_void_ty, llvm_descriptor_ty]>;
 219 def int_dbg_func_start   : Intrinsic<[llvm_void_ty, llvm_descriptor_ty]>;
 220 def int_dbg_declare      : Intrinsic<[llvm_void_ty, llvm_descriptor_ty,
 221                                                     llvm_descriptor_ty]>;
 222
 223 //===------------------ Exception Handling Intrinsics----------------------===//
 224 //
 225 def int_eh_exception     : Intrinsic<[llvm_ptr_ty]>;
 226 def int_eh_selector_i32  : Intrinsic<[llvm_i32_ty, llvm_ptr_ty, llvm_ptr_ty,
 227                                                    llvm_vararg_ty]>;
 228 def int_eh_selector_i64  : Intrinsic<[llvm_i64_ty, llvm_ptr_ty, llvm_ptr_ty,
 229                                                    llvm_vararg_ty]>;
 230
 231 def int_eh_typeid_for_i32 : Intrinsic<[llvm_i32_ty, llvm_ptr_ty]>;
 232 def int_eh_typeid_for_i64 : Intrinsic<[llvm_i64_ty, llvm_ptr_ty]>;
 233
 234 def int_eh_return     : Intrinsic<[llvm_void_ty, llvm_i32_ty, llvm_ptr_ty]>,
 235                         GCCBuiltin<"__builtin_eh_return">;
 236
 237 def int_eh_unwind_init: Intrinsic<[llvm_void_ty]>,
 238                         GCCBuiltin<"__builtin_unwind_init">;
 239
 240 def int_eh_dwarf_cfa  : Intrinsic<[llvm_ptr_ty, llvm_i32_ty]>;
 241
 242 //===---------------- Generic Variable Attribute Intrinsics----------------===//
 243 //
 244 def int_var_annotation : Intrinsic<[llvm_void_ty, llvm_ptr_ty, llvm_ptr_ty,
 245                                     llvm_ptr_ty, llvm_i32_ty],
 246                                     [], "llvm.var.annotation">;
 247
 248 def int_annotation : Intrinsic<[llvm_anyint_ty, LLVMMatchType<0>, llvm_ptr_ty,
 249                                 llvm_ptr_ty, llvm_i32_ty],
 250                                 [], "llvm.annotation">;
 251
 252 //===------------------------ Trampoline Intrinsics -----------------------===//
 253 //
 254 def int_init_trampoline : Intrinsic<[llvm_ptr_ty, llvm_ptr_ty, llvm_ptr_ty,
 255                                      llvm_ptr_ty], []>,
 256                           GCCBuiltin<"__builtin_init_trampoline">;
 257
 258 //===----------------------------------------------------------------------===//
 259 // Target-specific intrinsics
 260 //===----------------------------------------------------------------------===//
 261
 262 include "llvm/IntrinsicsPowerPC.td"
 263 include "llvm/IntrinsicsX86.td"