include/llvm/Intrinsics.td

   1 //===- Intrinsics.td - Defines all LLVM intrinsics ---------*- tablegen -*-===//
   2 //
   3 //                     The LLVM Compiler Infrastructure
   4 //
   5 // This file is distributed under the University of Illinois Open Source
   6 // License. See LICENSE.TXT for details.
   7 //
   8 //===----------------------------------------------------------------------===//
   9 //
  10 // This file defines properties of all LLVM intrinsics.
  11 //
  12 //===----------------------------------------------------------------------===//
  13
  14 include "llvm/CodeGen/ValueTypes.td"
  15
  16 //===----------------------------------------------------------------------===//
  17 //  Properties we keep track of for intrinsics.
  18 //===----------------------------------------------------------------------===//
  19
  20 class IntrinsicProperty;
  21
  22 // Intr*Mem - Memory properties.  An intrinsic is allowed to have at most one of
  23 // these properties set.  They are listed from the most aggressive (best to use
  24 // if correct) to the least aggressive.  If no property is set, the worst case
  25 // is assumed (it may read and write any memory it can get access to and it may
  26 // have other side effects).
  27
  28 // IntrNoMem - The intrinsic does not access memory or have any other side
  29 // effects.  It may be CSE'd deleted if dead, etc.
  30 def IntrNoMem : IntrinsicProperty;
  31
  32 // IntrReadArgMem - This intrinsic reads only from memory that one of its
  33 // pointer-typed arguments points to, but may read an unspecified amount.
  34 def IntrReadArgMem : IntrinsicProperty;
  35
  36 // IntrReadMem - This intrinsic reads from unspecified memory, so it cannot be
  37 // moved across stores.  However, it can be reordered otherwise and can be
  38 // deleted if dead.
  39 def IntrReadMem : IntrinsicProperty;
  40
  41 // IntrReadWriteArgMem - This intrinsic reads and writes only from memory that
  42 // one of its arguments points to, but may access an unspecified amount.  The
  43 // reads and writes may be volatile, but except for this it has no other side
  44 // effects.
  45 def IntrReadWriteArgMem : IntrinsicProperty;
  46
  47 // Commutative - This intrinsic is commutative: X op Y == Y op X.
  48 def Commutative : IntrinsicProperty;
  49
  50 // Throws - This intrinsic can throw.
  51 def Throws : IntrinsicProperty;
  52
  53 // NoCapture - The specified argument pointer is not captured by the intrinsic.
  54 class NoCapture<int argNo> : IntrinsicProperty {
  55   int ArgNo = argNo;
  56 }
  57
  58 //===----------------------------------------------------------------------===//
  59 // Types used by intrinsics.
  60 //===----------------------------------------------------------------------===//
  61
  62 class LLVMType<ValueType vt> {
  63   ValueType VT = vt;
  64 }
  65
  66 class LLVMQualPointerType<LLVMType elty, int addrspace>
  67   : LLVMType<iPTR>{
  68   LLVMType ElTy = elty;
  69   int AddrSpace = addrspace;
  70 }
  71
  72 class LLVMPointerType<LLVMType elty>
  73   : LLVMQualPointerType<elty, 0>;
  74
  75 class LLVMAnyPointerType<LLVMType elty>
  76   : LLVMType<iPTRAny>{
  77   LLVMType ElTy = elty;
  78 }
  79
  80 // Match the type of another intrinsic parameter.  Number is an index into the
  81 // list of overloaded types for the intrinsic, excluding all the fixed types.
  82 // The Number value must refer to a previously listed type.  For example:
  83 //   Intrinsic<[llvm_i32_ty], [llvm_i32_ty, llvm_anyfloat_ty, LLVMMatchType<0>]>
  84 // has two overloaded types, the 2nd and 3rd arguments.  LLVMMatchType<0>
  85 // refers to the first overloaded type, which is the 2nd argument.
  86 class LLVMMatchType<int num>
  87   : LLVMType<OtherVT>{
  88   int Number = num;
  89 }
  90
  91 // Match the type of another intrinsic parameter that is expected to be
  92 // an integral vector type, but change the element size to be twice as wide
  93 // or half as wide as the other type.  This is only useful when the intrinsic
  94 // is overloaded, so the matched type should be declared as iAny.
  95 class LLVMExtendedElementVectorType<int num> : LLVMMatchType<num>;
  96 class LLVMTruncatedElementVectorType<int num> : LLVMMatchType<num>;
  97
  98 def llvm_void_ty       : LLVMType<isVoid>;
  99 def llvm_anyint_ty     : LLVMType<iAny>;
 100 def llvm_anyfloat_ty   : LLVMType<fAny>;
 101 def llvm_anyvector_ty  : LLVMType<vAny>;
 102 def llvm_i1_ty         : LLVMType<i1>;
 103 def llvm_i8_ty         : LLVMType<i8>;
 104 def llvm_i16_ty        : LLVMType<i16>;
 105 def llvm_i32_ty        : LLVMType<i32>;
 106 def llvm_i64_ty        : LLVMType<i64>;
 107 def llvm_float_ty      : LLVMType<f32>;
 108 def llvm_double_ty     : LLVMType<f64>;
 109 def llvm_f80_ty        : LLVMType<f80>;
 110 def llvm_f128_ty       : LLVMType<f128>;
 111 def llvm_ppcf128_ty    : LLVMType<ppcf128>;
 112 def llvm_ptr_ty        : LLVMPointerType<llvm_i8_ty>;             // i8*
 113 def llvm_ptrptr_ty     : LLVMPointerType<llvm_ptr_ty>;            // i8**
 114 def llvm_anyptr_ty     : LLVMAnyPointerType<llvm_i8_ty>;          // (space)i8*
 115 def llvm_empty_ty      : LLVMType<OtherVT>;                       // { }
 116 def llvm_descriptor_ty : LLVMPointerType<llvm_empty_ty>;          // { }*
 117 def llvm_metadata_ty   : LLVMType<MetadataVT>;                    // !{...}
 118
 119 def llvm_x86mmx_ty     : LLVMType<x86mmx>;
 120 def llvm_ptrx86mmx_ty  : LLVMPointerType<llvm_x86mmx_ty>;         // <1 x i64>*
 121
 122 def llvm_v2i8_ty       : LLVMType<v2i8>;     //  2 x i8
 123 def llvm_v4i8_ty       : LLVMType<v4i8>;     //  4 x i8
 124 def llvm_v8i8_ty       : LLVMType<v8i8>;     //  8 x i8
 125 def llvm_v16i8_ty      : LLVMType<v16i8>;    // 16 x i8
 126 def llvm_v32i8_ty      : LLVMType<v32i8>;    // 32 x i8
 127 def llvm_v2i16_ty      : LLVMType<v2i16>;    //  2 x i16
 128 def llvm_v4i16_ty      : LLVMType<v4i16>;    //  4 x i16
 129 def llvm_v8i16_ty      : LLVMType<v8i16>;    //  8 x i16
 130 def llvm_v16i16_ty     : LLVMType<v16i16>;   // 16 x i16
 131 def llvm_v2i32_ty      : LLVMType<v2i32>;    //  2 x i32
 132 def llvm_v4i32_ty      : LLVMType<v4i32>;    //  4 x i32
 133 def llvm_v8i32_ty      : LLVMType<v8i32>;    //  8 x i32
 134 def llvm_v1i64_ty      : LLVMType<v1i64>;    //  1 x i64
 135 def llvm_v2i64_ty      : LLVMType<v2i64>;    //  2 x i64
 136 def llvm_v4i64_ty      : LLVMType<v4i64>;    //  4 x i64
 137
 138 def llvm_v2f32_ty      : LLVMType<v2f32>;    //  2 x float
 139 def llvm_v4f32_ty      : LLVMType<v4f32>;    //  4 x float
 140 def llvm_v8f32_ty      : LLVMType<v8f32>;    //  8 x float
 141 def llvm_v2f64_ty      : LLVMType<v2f64>;    //  2 x double
 142 def llvm_v4f64_ty      : LLVMType<v4f64>;    //  4 x double
 143
 144 def llvm_vararg_ty     : LLVMType<isVoid>;   // this means vararg here
 145
 146
 147 //===----------------------------------------------------------------------===//
 148 // Intrinsic Definitions.
 149 //===----------------------------------------------------------------------===//
 150
 151 // Intrinsic class - This is used to define one LLVM intrinsic.  The name of the
 152 // intrinsic definition should start with "int_", then match the LLVM intrinsic
 153 // name with the "llvm." prefix removed, and all "."s turned into "_"s.  For
 154 // example, llvm.bswap.i16 -> int_bswap_i16.
 155 //
 156 //  * RetTypes is a list containing the return types expected for the
 157 //    intrinsic.
 158 //  * ParamTypes is a list containing the parameter types expected for the
 159 //    intrinsic.
 160 //  * Properties can be set to describe the behavior of the intrinsic.
 161 //
 162 class Intrinsic<list<LLVMType> ret_types,
 163                 list<LLVMType> param_types = [],
 164                 list<IntrinsicProperty> properties = [],
 165                 string name = ""> {
 166   string LLVMName = name;
 167   string TargetPrefix = "";   // Set to a prefix for target-specific intrinsics.
 168   list<LLVMType> RetTypes = ret_types;
 169   list<LLVMType> ParamTypes = param_types;
 170   list<IntrinsicProperty> Properties = properties;
 171
 172   bit isTarget = 0;
 173 }
 174
 175 /// GCCBuiltin - If this intrinsic exactly corresponds to a GCC builtin, this
 176 /// specifies the name of the builtin.  This provides automatic CBE and CFE
 177 /// support.
 178 class GCCBuiltin<string name> {
 179   string GCCBuiltinName = name;
 180 }
 181
 182
 183 //===--------------- Variable Argument Handling Intrinsics ----------------===//
 184 //
 185
 186 def int_vastart : Intrinsic<[], [llvm_ptr_ty], [], "llvm.va_start">;
 187 def int_vacopy  : Intrinsic<[], [llvm_ptr_ty, llvm_ptr_ty], [],
 188                             "llvm.va_copy">;
 189 def int_vaend   : Intrinsic<[], [llvm_ptr_ty], [], "llvm.va_end">;
 190
 191 //===------------------- Garbage Collection Intrinsics --------------------===//
 192 //
 193 def int_gcroot  : Intrinsic<[],
 194                             [llvm_ptrptr_ty, llvm_ptr_ty]>;
 195 def int_gcread  : Intrinsic<[llvm_ptr_ty],
 196                             [llvm_ptr_ty, llvm_ptrptr_ty],
 197                             [IntrReadArgMem]>;
 198 def int_gcwrite : Intrinsic<[],
 199                             [llvm_ptr_ty, llvm_ptr_ty, llvm_ptrptr_ty],
 200                             [IntrReadWriteArgMem, NoCapture<1>, NoCapture<2>]>;
 201
 202 //===--------------------- Code Generator Intrinsics ----------------------===//
 203 //
 204 def int_returnaddress : Intrinsic<[llvm_ptr_ty], [llvm_i32_ty], [IntrNoMem]>;
 205 def int_frameaddress  : Intrinsic<[llvm_ptr_ty], [llvm_i32_ty], [IntrNoMem]>;
 206
 207 // Note: we treat stacksave/stackrestore as writemem because we don't otherwise
 208 // model their dependencies on allocas.
 209 def int_stacksave     : Intrinsic<[llvm_ptr_ty]>,
 210                         GCCBuiltin<"__builtin_stack_save">;
 211 def int_stackrestore  : Intrinsic<[], [llvm_ptr_ty]>,
 212                         GCCBuiltin<"__builtin_stack_restore">;
 213
 214 // IntrReadWriteArgMem is more pessimistic than strictly necessary for prefetch,
 215 // however it does conveniently prevent the prefetch from being reordered
 216 // with respect to nearby accesses to the same memory.
 217 def int_prefetch      : Intrinsic<[],
 218                                   [llvm_ptr_ty, llvm_i32_ty, llvm_i32_ty,
 219                                    llvm_i32_ty],
 220                                   [IntrReadWriteArgMem, NoCapture<0>]>;
 221 def int_pcmarker      : Intrinsic<[], [llvm_i32_ty]>;
 222
 223 def int_readcyclecounter : Intrinsic<[llvm_i64_ty]>;
 224
 225 // Stack Protector Intrinsic - The stackprotector intrinsic writes the stack
 226 // guard to the correct place on the stack frame.
 227 def int_stackprotector : Intrinsic<[], [llvm_ptr_ty, llvm_ptrptr_ty], []>;
 228
 229 //===------------------- Standard C Library Intrinsics --------------------===//
 230 //
 231
 232 def int_memcpy  : Intrinsic<[],
 233                              [llvm_anyptr_ty, llvm_anyptr_ty, llvm_anyint_ty,
 234                               llvm_i32_ty, llvm_i1_ty],
 235                             [IntrReadWriteArgMem, NoCapture<0>, NoCapture<1>]>;
 236 def int_memmove : Intrinsic<[],
 237                             [llvm_anyptr_ty, llvm_anyptr_ty, llvm_anyint_ty,
 238                              llvm_i32_ty, llvm_i1_ty],
 239                             [IntrReadWriteArgMem, NoCapture<0>, NoCapture<1>]>;
 240 def int_memset  : Intrinsic<[],
 241                             [llvm_anyptr_ty, llvm_i8_ty, llvm_anyint_ty,
 242                              llvm_i32_ty, llvm_i1_ty],
 243                             [IntrReadWriteArgMem, NoCapture<0>]>;
 244
 245 // These functions do not actually read memory, but they are sensitive to the
 246 // rounding mode.  This needs to be modelled separately; in the meantime
 247 // declaring them as reading memory is conservatively correct.
 248 let Properties = [IntrReadMem] in {
 249   def int_sqrt : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 250   def int_powi : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>, llvm_i32_ty]>;
 251   def int_sin  : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 252   def int_cos  : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 253   def int_pow  : Intrinsic<[llvm_anyfloat_ty],
 254                            [LLVMMatchType<0>, LLVMMatchType<0>]>;
 255   def int_log  : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 256   def int_log10: Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 257   def int_log2 : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 258   def int_exp  : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 259   def int_exp2 : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 260 }
 261
 262 let Properties = [IntrNoMem] in {
 263   def int_fma  : Intrinsic<[llvm_anyfloat_ty],
 264                          [LLVMMatchType<0>, LLVMMatchType<0>,
 265                           LLVMMatchType<0>]>;
 266 }
 267
 268 // NOTE: these are internal interfaces.
 269 def int_setjmp     : Intrinsic<[llvm_i32_ty],  [llvm_ptr_ty]>;
 270 def int_longjmp    : Intrinsic<[], [llvm_ptr_ty, llvm_i32_ty]>;
 271 def int_sigsetjmp  : Intrinsic<[llvm_i32_ty] , [llvm_ptr_ty, llvm_i32_ty]>;
 272 def int_siglongjmp : Intrinsic<[], [llvm_ptr_ty, llvm_i32_ty]>;
 273
 274 // Internal interface for object size checking
 275 def int_objectsize : Intrinsic<[llvm_anyint_ty],
 276                                [llvm_ptr_ty, llvm_i1_ty, llvm_i32_ty],
 277                                [IntrNoMem]>,
 278                                GCCBuiltin<"__builtin_object_size">;
 279
 280 //===------------------------- Expect Intrinsics --------------------------===//
 281 //
 282 def int_expect : Intrinsic<[llvm_anyint_ty], [LLVMMatchType<0>,
 283                                               LLVMMatchType<0>], [IntrNoMem]>;
 284
 285 //===-------------------- Bit Manipulation Intrinsics ---------------------===//
 286 //
 287
 288 // None of these intrinsics accesses memory at all.
 289 let Properties = [IntrNoMem] in {
 290   def int_bswap: Intrinsic<[llvm_anyint_ty], [LLVMMatchType<0>]>;
 291   def int_ctpop: Intrinsic<[llvm_anyint_ty], [LLVMMatchType<0>]>;
 292   def int_ctlz : Intrinsic<[llvm_anyint_ty], [LLVMMatchType<0>, llvm_i1_ty]>;
 293   def int_cttz : Intrinsic<[llvm_anyint_ty], [LLVMMatchType<0>, llvm_i1_ty]>;
 294 }
 295
 296 //===------------------------ Debugger Intrinsics -------------------------===//
 297 //
 298
 299 // None of these intrinsics accesses memory at all...but that doesn't mean the
 300 // optimizers can change them aggressively.  Special handling needed in a few
 301 // places.
 302 let Properties = [IntrNoMem] in {
 303   def int_dbg_declare      : Intrinsic<[],
 304                                        [llvm_metadata_ty, llvm_metadata_ty]>;
 305   def int_dbg_value        : Intrinsic<[],
 306                                        [llvm_metadata_ty, llvm_i64_ty,
 307                                         llvm_metadata_ty]>;
 308 }
 309
 310 //===------------------ Exception Handling Intrinsics----------------------===//
 311 //
 312
 313 // The result of eh.typeid.for depends on the enclosing function, but inside a
 314 // given function it is 'const' and may be CSE'd etc.
 315 def int_eh_typeid_for : Intrinsic<[llvm_i32_ty], [llvm_ptr_ty], [IntrNoMem]>;
 316
 317 def int_eh_return_i32 : Intrinsic<[], [llvm_i32_ty, llvm_ptr_ty]>;
 318 def int_eh_return_i64 : Intrinsic<[], [llvm_i64_ty, llvm_ptr_ty]>;
 319
 320 def int_eh_unwind_init: Intrinsic<[]>,
 321                         GCCBuiltin<"__builtin_unwind_init">;
 322
 323 def int_eh_dwarf_cfa  : Intrinsic<[llvm_ptr_ty], [llvm_i32_ty]>;
 324
 325 let Properties = [IntrNoMem] in {
 326   def int_eh_sjlj_lsda             : Intrinsic<[llvm_ptr_ty]>;
 327   def int_eh_sjlj_callsite         : Intrinsic<[], [llvm_i32_ty]>;
 328 }
 329 def int_eh_sjlj_functioncontext : Intrinsic<[], [llvm_ptr_ty]>;
 330 def int_eh_sjlj_setjmp          : Intrinsic<[llvm_i32_ty], [llvm_ptr_ty]>;
 331 def int_eh_sjlj_longjmp         : Intrinsic<[], [llvm_ptr_ty]>;
 332
 333 //===---------------- Generic Variable Attribute Intrinsics----------------===//
 334 //
 335 def int_var_annotation : Intrinsic<[],
 336                                    [llvm_ptr_ty, llvm_ptr_ty,
 337                                     llvm_ptr_ty, llvm_i32_ty],
 338                                    [], "llvm.var.annotation">;
 339 def int_ptr_annotation : Intrinsic<[LLVMAnyPointerType<llvm_anyint_ty>],
 340                                    [LLVMMatchType<0>, llvm_ptr_ty, llvm_ptr_ty,
 341                                     llvm_i32_ty],
 342                                    [], "llvm.ptr.annotation">;
 343 def int_annotation : Intrinsic<[llvm_anyint_ty],
 344                                [LLVMMatchType<0>, llvm_ptr_ty,
 345                                 llvm_ptr_ty, llvm_i32_ty],
 346                                [], "llvm.annotation">;
 347
 348 //===------------------------ Trampoline Intrinsics -----------------------===//
 349 //
 350 def int_init_trampoline : Intrinsic<[],
 351                                     [llvm_ptr_ty, llvm_ptr_ty, llvm_ptr_ty],
 352                                     [IntrReadWriteArgMem, NoCapture<0>]>,
 353                                    GCCBuiltin<"__builtin_init_trampoline">;
 354
 355 def int_adjust_trampoline : Intrinsic<[llvm_ptr_ty], [llvm_ptr_ty],
 356                                       [IntrReadArgMem]>,
 357                                      GCCBuiltin<"__builtin_adjust_trampoline">;
 358
 359 //===------------------------ Overflow Intrinsics -------------------------===//
 360 //
 361
 362 // Expose the carry flag from add operations on two integrals.
 363 def int_sadd_with_overflow : Intrinsic<[llvm_anyint_ty, llvm_i1_ty],
 364                                        [LLVMMatchType<0>, LLVMMatchType<0>],
 365                                        [IntrNoMem]>;
 366 def int_uadd_with_overflow : Intrinsic<[llvm_anyint_ty, llvm_i1_ty],
 367                                        [LLVMMatchType<0>, LLVMMatchType<0>],
 368                                        [IntrNoMem]>;
 369
 370 def int_ssub_with_overflow : Intrinsic<[llvm_anyint_ty, llvm_i1_ty],
 371                                        [LLVMMatchType<0>, LLVMMatchType<0>],
 372                                        [IntrNoMem]>;
 373 def int_usub_with_overflow : Intrinsic<[llvm_anyint_ty, llvm_i1_ty],
 374                                        [LLVMMatchType<0>, LLVMMatchType<0>],
 375                                        [IntrNoMem]>;
 376
 377 def int_smul_with_overflow : Intrinsic<[llvm_anyint_ty, llvm_i1_ty],
 378                                        [LLVMMatchType<0>, LLVMMatchType<0>],
 379                                        [IntrNoMem]>;
 380 def int_umul_with_overflow : Intrinsic<[llvm_anyint_ty, llvm_i1_ty],
 381                                        [LLVMMatchType<0>, LLVMMatchType<0>],
 382                                        [IntrNoMem]>;
 383
 384 //===------------------------- Memory Use Markers -------------------------===//
 385 //
 386 def int_lifetime_start  : Intrinsic<[],
 387                                     [llvm_i64_ty, llvm_ptr_ty],
 388                                     [IntrReadWriteArgMem, NoCapture<1>]>;
 389 def int_lifetime_end    : Intrinsic<[],
 390                                     [llvm_i64_ty, llvm_ptr_ty],
 391                                     [IntrReadWriteArgMem, NoCapture<1>]>;
 392 def int_invariant_start : Intrinsic<[llvm_descriptor_ty],
 393                                     [llvm_i64_ty, llvm_ptr_ty],
 394                                     [IntrReadWriteArgMem, NoCapture<1>]>;
 395 def int_invariant_end   : Intrinsic<[],
 396                                     [llvm_descriptor_ty, llvm_i64_ty,
 397                                      llvm_ptr_ty],
 398                                     [IntrReadWriteArgMem, NoCapture<2>]>;
 399
 400 //===-------------------------- Other Intrinsics --------------------------===//
 401 //
 402 def int_flt_rounds : Intrinsic<[llvm_i32_ty]>,
 403                      GCCBuiltin<"__builtin_flt_rounds">;
 404 def int_trap : Intrinsic<[]>,
 405                GCCBuiltin<"__builtin_trap">;
 406 def int_debugtrap : Intrinsic<[]>,
 407                     GCCBuiltin<"__builtin_debugtrap">;
 408
 409 // Intrisics to support half precision floating point format
 410 let Properties = [IntrNoMem] in {
 411 def int_convert_to_fp16   : Intrinsic<[llvm_i16_ty], [llvm_float_ty]>,
 412                             GCCBuiltin<"__gnu_f2h_ieee">;
 413 def int_convert_from_fp16 : Intrinsic<[llvm_float_ty], [llvm_i16_ty]>,
 414                             GCCBuiltin<"__gnu_h2f_ieee">;
 415 }
 416
 417 // These convert intrinsics are to support various conversions between
 418 // various types with rounding and saturation. NOTE: avoid using these
 419 // intrinsics as they might be removed sometime in the future and
 420 // most targets don't support them.
 421 def int_convertff  : Intrinsic<[llvm_anyfloat_ty],
 422                                [llvm_anyfloat_ty, llvm_i32_ty, llvm_i32_ty]>;
 423 def int_convertfsi : Intrinsic<[llvm_anyfloat_ty],
 424                                [llvm_anyint_ty, llvm_i32_ty, llvm_i32_ty]>;
 425 def int_convertfui : Intrinsic<[llvm_anyfloat_ty],
 426                                [llvm_anyint_ty, llvm_i32_ty, llvm_i32_ty]>;
 427 def int_convertsif : Intrinsic<[llvm_anyint_ty],
 428                                [llvm_anyfloat_ty, llvm_i32_ty, llvm_i32_ty]>;
 429 def int_convertuif : Intrinsic<[llvm_anyint_ty],
 430                                [llvm_anyfloat_ty, llvm_i32_ty, llvm_i32_ty]>;
 431 def int_convertss  : Intrinsic<[llvm_anyint_ty],
 432                                [llvm_anyint_ty, llvm_i32_ty, llvm_i32_ty]>;
 433 def int_convertsu  : Intrinsic<[llvm_anyint_ty],
 434                                [llvm_anyint_ty, llvm_i32_ty, llvm_i32_ty]>;
 435 def int_convertus  : Intrinsic<[llvm_anyint_ty],
 436                                [llvm_anyint_ty, llvm_i32_ty, llvm_i32_ty]>;
 437 def int_convertuu  : Intrinsic<[llvm_anyint_ty],
 438                                [llvm_anyint_ty, llvm_i32_ty, llvm_i32_ty]>;
 439
 440 //===----------------------------------------------------------------------===//
 441 // Target-specific intrinsics
 442 //===----------------------------------------------------------------------===//
 443
 444 include "llvm/IntrinsicsPowerPC.td"
 445 include "llvm/IntrinsicsX86.td"
 446 include "llvm/IntrinsicsARM.td"
 447 include "llvm/IntrinsicsCellSPU.td"
 448 include "llvm/IntrinsicsXCore.td"
 449 include "llvm/IntrinsicsPTX.td"
 450 include "llvm/IntrinsicsHexagon.td"
 451 include "llvm/IntrinsicsNVVM.td"