include/llvm/Intrinsics.td

   1 //===- Intrinsics.td - Defines all LLVM intrinsics ---------*- tablegen -*-===//
   2 //
   3 //                     The LLVM Compiler Infrastructure
   4 //
   5 // This file is distributed under the University of Illinois Open Source
   6 // License. See LICENSE.TXT for details.
   7 //
   8 //===----------------------------------------------------------------------===//
   9 //
  10 // This file defines properties of all LLVM intrinsics.
  11 //
  12 //===----------------------------------------------------------------------===//
  13
  14 include "llvm/CodeGen/ValueTypes.td"
  15
  16 //===----------------------------------------------------------------------===//
  17 //  Properties we keep track of for intrinsics.
  18 //===----------------------------------------------------------------------===//
  19
  20 class IntrinsicProperty;
  21
  22 // Intr*Mem - Memory properties.  An intrinsic is allowed to have exactly one of
  23 // these properties set.  They are listed from the most aggressive (best to use
  24 // if correct) to the least aggressive.  If no property is set, the worst case
  25 // is assumed (IntrWriteMem).
  26
  27 // IntrNoMem - The intrinsic does not access memory or have any other side
  28 // effects.  It may be CSE'd deleted if dead, etc.
  29 def IntrNoMem : IntrinsicProperty;
  30
  31 // IntrReadArgMem - This intrinsic reads only from memory that one of its
  32 // arguments points to, but may read an unspecified amount.
  33 def IntrReadArgMem : IntrinsicProperty;
  34
  35 // IntrReadMem - This intrinsic reads from unspecified memory, so it cannot be
  36 // moved across stores.  However, it can be reordered otherwise and can be
  37 // deleted if dead.
  38 def IntrReadMem : IntrinsicProperty;
  39
  40 // IntrWriteArgMem - This intrinsic reads and writes only from memory that one
  41 // of its arguments points to, but may access an unspecified amount.  The reads
  42 // and writes may be volatile, but except for this it has no other side effects.
  43 def IntrWriteArgMem : IntrinsicProperty;
  44
  45 // IntrWriteMem - This intrinsic may read or modify unspecified memory or has
  46 // other side effects.  It cannot be modified by the optimizer.  This is the
  47 // default if the intrinsic has no other Intr*Mem property.
  48 def IntrWriteMem : IntrinsicProperty;
  49
  50 // Commutative - This intrinsic is commutative: X op Y == Y op X.
  51 def Commutative : IntrinsicProperty;
  52
  53 // NoCapture - The specified argument pointer is not captured by the intrinsic.
  54 class NoCapture<int argNo> : IntrinsicProperty {
  55   int ArgNo = argNo;
  56 }
  57
  58 //===----------------------------------------------------------------------===//
  59 // Types used by intrinsics.
  60 //===----------------------------------------------------------------------===//
  61
  62 class LLVMType<ValueType vt> {
  63   ValueType VT = vt;
  64 }
  65
  66 class LLVMPointerType<LLVMType elty>
  67   : LLVMType<iPTR>{
  68   LLVMType ElTy = elty;
  69 }
  70
  71 class LLVMAnyPointerType<LLVMType elty>
  72   : LLVMType<iPTRAny>{
  73   LLVMType ElTy = elty;
  74 }
  75
  76 // Match the type of another intrinsic parameter.  Number is an index into the
  77 // list of overloaded types for the intrinsic, excluding all the fixed types.
  78 // The Number value must refer to a previously listed type.  For example:
  79 //   Intrinsic<[llvm_i32_ty], [llvm_i32_ty, llvm_anyfloat_ty, LLVMMatchType<0>]>
  80 // has two overloaded types, the 2nd and 3rd arguments.  LLVMMatchType<0>
  81 // refers to the first overloaded type, which is the 2nd argument.
  82 class LLVMMatchType<int num>
  83   : LLVMType<OtherVT>{
  84   int Number = num;
  85 }
  86
  87 // Match the type of another intrinsic parameter that is expected to be
  88 // an integral vector type, but change the element size to be twice as wide
  89 // or half as wide as the other type.  This is only useful when the intrinsic
  90 // is overloaded, so the matched type should be declared as iAny.
  91 class LLVMExtendedElementVectorType<int num> : LLVMMatchType<num>;
  92 class LLVMTruncatedElementVectorType<int num> : LLVMMatchType<num>;
  93
  94 def llvm_void_ty       : LLVMType<isVoid>;
  95 def llvm_anyint_ty     : LLVMType<iAny>;
  96 def llvm_anyfloat_ty   : LLVMType<fAny>;
  97 def llvm_anyvector_ty  : LLVMType<vAny>;
  98 def llvm_i1_ty         : LLVMType<i1>;
  99 def llvm_i8_ty         : LLVMType<i8>;
 100 def llvm_i16_ty        : LLVMType<i16>;
 101 def llvm_i32_ty        : LLVMType<i32>;
 102 def llvm_i64_ty        : LLVMType<i64>;
 103 def llvm_float_ty      : LLVMType<f32>;
 104 def llvm_double_ty     : LLVMType<f64>;
 105 def llvm_f80_ty        : LLVMType<f80>;
 106 def llvm_f128_ty       : LLVMType<f128>;
 107 def llvm_ppcf128_ty    : LLVMType<ppcf128>;
 108 def llvm_ptr_ty        : LLVMPointerType<llvm_i8_ty>;             // i8*
 109 def llvm_ptrptr_ty     : LLVMPointerType<llvm_ptr_ty>;            // i8**
 110 def llvm_anyptr_ty     : LLVMAnyPointerType<llvm_i8_ty>;          // (space)i8*
 111 def llvm_empty_ty      : LLVMType<OtherVT>;                       // { }
 112 def llvm_descriptor_ty : LLVMPointerType<llvm_empty_ty>;          // { }*
 113 def llvm_metadata_ty   : LLVMType<MetadataVT>;                    // !{...}
 114
 115 def llvm_v2i8_ty       : LLVMType<v2i8>;     //  2 x i8
 116 def llvm_v4i8_ty       : LLVMType<v4i8>;     //  4 x i8
 117 def llvm_v8i8_ty       : LLVMType<v8i8>;     //  8 x i8
 118 def llvm_v16i8_ty      : LLVMType<v16i8>;    // 16 x i8
 119 def llvm_v32i8_ty      : LLVMType<v32i8>;    // 32 x i8
 120 def llvm_v2i16_ty      : LLVMType<v2i16>;    //  4 x i16
 121 def llvm_v4i16_ty      : LLVMType<v4i16>;    //  4 x i16
 122 def llvm_v8i16_ty      : LLVMType<v8i16>;    //  8 x i16
 123 def llvm_v16i16_ty     : LLVMType<v16i16>;   // 16 x i16
 124 def llvm_v2i32_ty      : LLVMType<v2i32>;    //  2 x i32
 125 def llvm_v4i32_ty      : LLVMType<v4i32>;    //  4 x i32
 126 def llvm_v8i32_ty      : LLVMType<v8i32>;    //  8 x i32
 127 def llvm_v1i64_ty      : LLVMType<v1i64>;    //  1 x i64
 128 def llvm_v2i64_ty      : LLVMType<v2i64>;    //  2 x i64
 129 def llvm_v4i64_ty      : LLVMType<v4i64>;    //  4 x i64
 130
 131 def llvm_v2f32_ty      : LLVMType<v2f32>;    //  2 x float
 132 def llvm_v4f32_ty      : LLVMType<v4f32>;    //  4 x float
 133 def llvm_v8f32_ty      : LLVMType<v8f32>;    //  8 x float
 134 def llvm_v2f64_ty      : LLVMType<v2f64>;    //  2 x double
 135 def llvm_v4f64_ty      : LLVMType<v4f64>;    //  4 x double
 136
 137 def llvm_vararg_ty     : LLVMType<isVoid>;   // this means vararg here
 138
 139
 140 //===----------------------------------------------------------------------===//
 141 // Intrinsic Definitions.
 142 //===----------------------------------------------------------------------===//
 143
 144 // Intrinsic class - This is used to define one LLVM intrinsic.  The name of the
 145 // intrinsic definition should start with "int_", then match the LLVM intrinsic
 146 // name with the "llvm." prefix removed, and all "."s turned into "_"s.  For
 147 // example, llvm.bswap.i16 -> int_bswap_i16.
 148 //
 149 //  * RetTypes is a list containing the return types expected for the
 150 //    intrinsic.
 151 //  * ParamTypes is a list containing the parameter types expected for the
 152 //    intrinsic.
 153 //  * Properties can be set to describe the behavior of the intrinsic.
 154 //
 155 class Intrinsic<list<LLVMType> ret_types,
 156                 list<LLVMType> param_types = [],
 157                 list<IntrinsicProperty> properties = [],
 158                 string name = ""> {
 159   string LLVMName = name;
 160   string TargetPrefix = "";   // Set to a prefix for target-specific intrinsics.
 161   list<LLVMType> RetTypes = ret_types;
 162   list<LLVMType> ParamTypes = param_types;
 163   list<IntrinsicProperty> Properties = properties;
 164
 165   bit isTarget = 0;
 166 }
 167
 168 /// GCCBuiltin - If this intrinsic exactly corresponds to a GCC builtin, this
 169 /// specifies the name of the builtin.  This provides automatic CBE and CFE
 170 /// support.
 171 class GCCBuiltin<string name> {
 172   string GCCBuiltinName = name;
 173 }
 174
 175
 176 //===--------------- Variable Argument Handling Intrinsics ----------------===//
 177 //
 178
 179 def int_vastart : Intrinsic<[], [llvm_ptr_ty], [], "llvm.va_start">;
 180 def int_vacopy  : Intrinsic<[], [llvm_ptr_ty, llvm_ptr_ty], [],
 181                             "llvm.va_copy">;
 182 def int_vaend   : Intrinsic<[], [llvm_ptr_ty], [], "llvm.va_end">;
 183
 184 //===------------------- Garbage Collection Intrinsics --------------------===//
 185 //
 186 def int_gcroot  : Intrinsic<[],
 187                             [llvm_ptrptr_ty, llvm_ptr_ty]>;
 188 def int_gcread  : Intrinsic<[llvm_ptr_ty],
 189                             [llvm_ptr_ty, llvm_ptrptr_ty],
 190                             [IntrReadArgMem]>;
 191 def int_gcwrite : Intrinsic<[],
 192                             [llvm_ptr_ty, llvm_ptr_ty, llvm_ptrptr_ty],
 193                             [IntrWriteArgMem, NoCapture<1>, NoCapture<2>]>;
 194
 195 //===--------------------- Code Generator Intrinsics ----------------------===//
 196 //
 197 def int_returnaddress : Intrinsic<[llvm_ptr_ty], [llvm_i32_ty], [IntrNoMem]>;
 198 def int_frameaddress  : Intrinsic<[llvm_ptr_ty], [llvm_i32_ty], [IntrNoMem]>;
 199
 200 // Note: we treat stacksave/stackrestore as writemem because we don't otherwise
 201 // model their dependencies on allocas.
 202 def int_stacksave     : Intrinsic<[llvm_ptr_ty]>,
 203                         GCCBuiltin<"__builtin_stack_save">;
 204 def int_stackrestore  : Intrinsic<[], [llvm_ptr_ty]>,
 205                         GCCBuiltin<"__builtin_stack_restore">;
 206
 207 // IntrWriteArgMem is more pessimistic than strictly necessary for prefetch,
 208 // however it does conveniently prevent the prefetch from being reordered
 209 // with respect to nearby accesses to the same memory.
 210 def int_prefetch      : Intrinsic<[],
 211                                   [llvm_ptr_ty, llvm_i32_ty, llvm_i32_ty],
 212                                   [IntrWriteArgMem, NoCapture<0>]>;
 213 def int_pcmarker      : Intrinsic<[], [llvm_i32_ty]>;
 214
 215 def int_readcyclecounter : Intrinsic<[llvm_i64_ty]>;
 216
 217 // Stack Protector Intrinsic - The stackprotector intrinsic writes the stack
 218 // guard to the correct place on the stack frame.
 219 def int_stackprotector : Intrinsic<[],
 220                                    [llvm_ptr_ty, llvm_ptrptr_ty],
 221                                    [IntrWriteMem]>;
 222
 223 //===------------------- Standard C Library Intrinsics --------------------===//
 224 //
 225
 226 def int_memcpy  : Intrinsic<[],
 227                              [llvm_anyptr_ty, llvm_anyptr_ty, llvm_anyint_ty,
 228                               llvm_i32_ty, llvm_i1_ty],
 229                             [IntrWriteArgMem, NoCapture<0>, NoCapture<1>]>;
 230 def int_memmove : Intrinsic<[],
 231                             [llvm_anyptr_ty, llvm_anyptr_ty, llvm_anyint_ty,
 232                              llvm_i32_ty, llvm_i1_ty],
 233                             [IntrWriteArgMem, NoCapture<0>, NoCapture<1>]>;
 234 def int_memset  : Intrinsic<[],
 235                             [llvm_anyptr_ty, llvm_i8_ty, llvm_anyint_ty,
 236                              llvm_i32_ty, llvm_i1_ty],
 237                             [IntrWriteArgMem, NoCapture<0>]>;
 238
 239 // These functions do not actually read memory, but they are sensitive to the
 240 // rounding mode.  This needs to be modelled separately; in the meantime
 241 // declaring them as reading memory is conservatively correct.
 242 let Properties = [IntrReadMem] in {
 243   def int_sqrt : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 244   def int_powi : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>, llvm_i32_ty]>;
 245   def int_sin  : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 246   def int_cos  : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 247   def int_pow  : Intrinsic<[llvm_anyfloat_ty],
 248                            [LLVMMatchType<0>, LLVMMatchType<0>]>;
 249   def int_log  : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 250   def int_log10: Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 251   def int_log2 : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 252   def int_exp  : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 253   def int_exp2 : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 254 }
 255
 256 // NOTE: these are internal interfaces.
 257 def int_setjmp     : Intrinsic<[llvm_i32_ty],  [llvm_ptr_ty]>;
 258 def int_longjmp    : Intrinsic<[], [llvm_ptr_ty, llvm_i32_ty]>;
 259 def int_sigsetjmp  : Intrinsic<[llvm_i32_ty] , [llvm_ptr_ty, llvm_i32_ty]>;
 260 def int_siglongjmp : Intrinsic<[], [llvm_ptr_ty, llvm_i32_ty]>;
 261
 262 // Internal interface for object size checking
 263 def int_objectsize : Intrinsic<[llvm_anyint_ty], [llvm_ptr_ty, llvm_i1_ty],
 264                                [IntrReadArgMem]>,
 265                                GCCBuiltin<"__builtin_object_size">;
 266
 267 //===-------------------- Bit Manipulation Intrinsics ---------------------===//
 268 //
 269
 270 // None of these intrinsics accesses memory at all.
 271 let Properties = [IntrNoMem] in {
 272   def int_bswap: Intrinsic<[llvm_anyint_ty], [LLVMMatchType<0>]>;
 273   def int_ctpop: Intrinsic<[llvm_anyint_ty], [LLVMMatchType<0>]>;
 274   def int_ctlz : Intrinsic<[llvm_anyint_ty], [LLVMMatchType<0>]>;
 275   def int_cttz : Intrinsic<[llvm_anyint_ty], [LLVMMatchType<0>]>;
 276 }
 277
 278 //===------------------------ Debugger Intrinsics -------------------------===//
 279 //
 280
 281 // None of these intrinsics accesses memory at all...but that doesn't mean the
 282 // optimizers can change them aggressively.  Special handling needed in a few
 283 // places.
 284 let Properties = [IntrNoMem] in {
 285   def int_dbg_declare      : Intrinsic<[],
 286                                        [llvm_metadata_ty, llvm_metadata_ty]>;
 287   def int_dbg_value        : Intrinsic<[],
 288                                        [llvm_metadata_ty, llvm_i64_ty,
 289                                         llvm_metadata_ty]>;
 290 }
 291
 292 //===------------------ Exception Handling Intrinsics----------------------===//
 293 //
 294 def int_eh_exception : Intrinsic<[llvm_ptr_ty], [], [IntrReadMem]>;
 295 def int_eh_selector  : Intrinsic<[llvm_i32_ty],
 296                                  [llvm_ptr_ty, llvm_ptr_ty, llvm_vararg_ty]>;
 297
 298 def int_eh_typeid_for : Intrinsic<[llvm_i32_ty], [llvm_ptr_ty]>;
 299
 300 def int_eh_return_i32 : Intrinsic<[], [llvm_i32_ty, llvm_ptr_ty]>;
 301 def int_eh_return_i64 : Intrinsic<[], [llvm_i64_ty, llvm_ptr_ty]>;
 302
 303 def int_eh_unwind_init: Intrinsic<[]>,
 304                         GCCBuiltin<"__builtin_unwind_init">;
 305
 306 def int_eh_dwarf_cfa  : Intrinsic<[llvm_ptr_ty], [llvm_i32_ty]>;
 307
 308 let Properties = [IntrNoMem] in {
 309   def int_eh_sjlj_lsda    : Intrinsic<[llvm_ptr_ty]>;
 310   def int_eh_sjlj_callsite: Intrinsic<[], [llvm_i32_ty]>;
 311 }
 312 def int_eh_sjlj_setjmp  : Intrinsic<[llvm_i32_ty], [llvm_ptr_ty]>;
 313 def int_eh_sjlj_longjmp : Intrinsic<[], [llvm_ptr_ty]>;
 314
 315 //===---------------- Generic Variable Attribute Intrinsics----------------===//
 316 //
 317 def int_var_annotation : Intrinsic<[],
 318                                    [llvm_ptr_ty, llvm_ptr_ty,
 319                                     llvm_ptr_ty, llvm_i32_ty],
 320                                    [], "llvm.var.annotation">;
 321 def int_ptr_annotation : Intrinsic<[LLVMAnyPointerType<llvm_anyint_ty>],
 322                                    [LLVMMatchType<0>, llvm_ptr_ty, llvm_ptr_ty,
 323                                     llvm_i32_ty],
 324                                    [], "llvm.ptr.annotation">;
 325 def int_annotation : Intrinsic<[llvm_anyint_ty],
 326                                [LLVMMatchType<0>, llvm_ptr_ty,
 327                                 llvm_ptr_ty, llvm_i32_ty],
 328                                [], "llvm.annotation">;
 329
 330 //===------------------------ Trampoline Intrinsics -----------------------===//
 331 //
 332 def int_init_trampoline : Intrinsic<[llvm_ptr_ty],
 333                                     [llvm_ptr_ty, llvm_ptr_ty, llvm_ptr_ty],
 334                                     [IntrWriteArgMem]>,
 335                           GCCBuiltin<"__builtin_init_trampoline">;
 336
 337 //===------------------------ Overflow Intrinsics -------------------------===//
 338 //
 339
 340 // Expose the carry flag from add operations on two integrals.
 341 def int_sadd_with_overflow : Intrinsic<[llvm_anyint_ty, llvm_i1_ty],
 342                                        [LLVMMatchType<0>, LLVMMatchType<0>],
 343                                        [IntrNoMem]>;
 344 def int_uadd_with_overflow : Intrinsic<[llvm_anyint_ty, llvm_i1_ty],
 345                                        [LLVMMatchType<0>, LLVMMatchType<0>],
 346                                        [IntrNoMem]>;
 347
 348 def int_ssub_with_overflow : Intrinsic<[llvm_anyint_ty, llvm_i1_ty],
 349                                        [LLVMMatchType<0>, LLVMMatchType<0>],
 350                                        [IntrNoMem]>;
 351 def int_usub_with_overflow : Intrinsic<[llvm_anyint_ty, llvm_i1_ty],
 352                                        [LLVMMatchType<0>, LLVMMatchType<0>],
 353                                        [IntrNoMem]>;
 354
 355 def int_smul_with_overflow : Intrinsic<[llvm_anyint_ty, llvm_i1_ty],
 356                                        [LLVMMatchType<0>, LLVMMatchType<0>],
 357                                        [IntrNoMem]>;
 358 def int_umul_with_overflow : Intrinsic<[llvm_anyint_ty, llvm_i1_ty],
 359                                        [LLVMMatchType<0>, LLVMMatchType<0>],
 360                                        [IntrNoMem]>;
 361
 362 //===------------------------- Atomic Intrinsics --------------------------===//
 363 //
 364 def int_memory_barrier : Intrinsic<[],
 365                                    [llvm_i1_ty, llvm_i1_ty,
 366                                     llvm_i1_ty, llvm_i1_ty, llvm_i1_ty], []>,
 367                                     GCCBuiltin<"__builtin_llvm_memory_barrier">;
 368
 369 def int_atomic_cmp_swap : Intrinsic<[llvm_anyint_ty],
 370                                     [LLVMAnyPointerType<LLVMMatchType<0>>,
 371                                      LLVMMatchType<0>, LLVMMatchType<0>],
 372                                     [IntrWriteArgMem, NoCapture<0>]>,
 373                            GCCBuiltin<"__sync_val_compare_and_swap">;
 374 def int_atomic_load_add : Intrinsic<[llvm_anyint_ty],
 375                                     [LLVMAnyPointerType<LLVMMatchType<0>>,
 376                                      LLVMMatchType<0>],
 377                                     [IntrWriteArgMem, NoCapture<0>]>,
 378                            GCCBuiltin<"__sync_fetch_and_add">;
 379 def int_atomic_swap     : Intrinsic<[llvm_anyint_ty],
 380                                     [LLVMAnyPointerType<LLVMMatchType<0>>,
 381                                      LLVMMatchType<0>],
 382                                     [IntrWriteArgMem, NoCapture<0>]>,
 383                            GCCBuiltin<"__sync_lock_test_and_set">;
 384 def int_atomic_load_sub : Intrinsic<[llvm_anyint_ty],
 385                                     [LLVMAnyPointerType<LLVMMatchType<0>>,
 386                                      LLVMMatchType<0>],
 387                                     [IntrWriteArgMem, NoCapture<0>]>,
 388                            GCCBuiltin<"__sync_fetch_and_sub">;
 389 def int_atomic_load_and : Intrinsic<[llvm_anyint_ty],
 390                                     [LLVMAnyPointerType<LLVMMatchType<0>>,
 391                                      LLVMMatchType<0>],
 392                                     [IntrWriteArgMem, NoCapture<0>]>,
 393                            GCCBuiltin<"__sync_fetch_and_and">;
 394 def int_atomic_load_or   : Intrinsic<[llvm_anyint_ty],
 395                                      [LLVMAnyPointerType<LLVMMatchType<0>>,
 396                                       LLVMMatchType<0>],
 397                                      [IntrWriteArgMem, NoCapture<0>]>,
 398                            GCCBuiltin<"__sync_fetch_and_or">;
 399 def int_atomic_load_xor : Intrinsic<[llvm_anyint_ty],
 400                                     [LLVMAnyPointerType<LLVMMatchType<0>>,
 401                                      LLVMMatchType<0>],
 402                                     [IntrWriteArgMem, NoCapture<0>]>,
 403                            GCCBuiltin<"__sync_fetch_and_xor">;
 404 def int_atomic_load_nand : Intrinsic<[llvm_anyint_ty],
 405                                      [LLVMAnyPointerType<LLVMMatchType<0>>,
 406                                       LLVMMatchType<0>],
 407                                      [IntrWriteArgMem, NoCapture<0>]>,
 408                            GCCBuiltin<"__sync_fetch_and_nand">;
 409 def int_atomic_load_min  : Intrinsic<[llvm_anyint_ty],
 410                                      [LLVMAnyPointerType<LLVMMatchType<0>>,
 411                                       LLVMMatchType<0>],
 412                                      [IntrWriteArgMem, NoCapture<0>]>,
 413                            GCCBuiltin<"__sync_fetch_and_min">;
 414 def int_atomic_load_max  : Intrinsic<[llvm_anyint_ty],
 415                                      [LLVMAnyPointerType<LLVMMatchType<0>>,
 416                                       LLVMMatchType<0>],
 417                                      [IntrWriteArgMem, NoCapture<0>]>,
 418                            GCCBuiltin<"__sync_fetch_and_max">;
 419 def int_atomic_load_umin : Intrinsic<[llvm_anyint_ty],
 420                                      [LLVMAnyPointerType<LLVMMatchType<0>>,
 421                                       LLVMMatchType<0>],
 422                                      [IntrWriteArgMem, NoCapture<0>]>,
 423                            GCCBuiltin<"__sync_fetch_and_umin">;
 424 def int_atomic_load_umax : Intrinsic<[llvm_anyint_ty],
 425                                      [LLVMAnyPointerType<LLVMMatchType<0>>,
 426                                       LLVMMatchType<0>],
 427                                      [IntrWriteArgMem, NoCapture<0>]>,
 428                            GCCBuiltin<"__sync_fetch_and_umax">;
 429
 430 //===------------------------- Memory Use Markers -------------------------===//
 431 //
 432 def int_lifetime_start  : Intrinsic<[],
 433                                     [llvm_i64_ty, llvm_ptr_ty],
 434                                     [IntrWriteArgMem, NoCapture<1>]>;
 435 def int_lifetime_end    : Intrinsic<[],
 436                                     [llvm_i64_ty, llvm_ptr_ty],
 437                                     [IntrWriteArgMem, NoCapture<1>]>;
 438 def int_invariant_start : Intrinsic<[llvm_descriptor_ty],
 439                                     [llvm_i64_ty, llvm_ptr_ty],
 440                                     [IntrReadArgMem, NoCapture<1>]>;
 441 def int_invariant_end   : Intrinsic<[],
 442                                     [llvm_descriptor_ty, llvm_i64_ty,
 443                                      llvm_ptr_ty],
 444                                     [IntrWriteArgMem, NoCapture<2>]>;
 445
 446 //===-------------------------- Other Intrinsics --------------------------===//
 447 //
 448 def int_flt_rounds : Intrinsic<[llvm_i32_ty]>,
 449                      GCCBuiltin<"__builtin_flt_rounds">;
 450 def int_trap : Intrinsic<[]>,
 451                GCCBuiltin<"__builtin_trap">;
 452
 453 // Intrisics to support half precision floating point format
 454 let Properties = [IntrNoMem] in {
 455 def int_convert_to_fp16   : Intrinsic<[llvm_i16_ty], [llvm_float_ty]>,
 456                             GCCBuiltin<"__gnu_f2h_ieee">;
 457 def int_convert_from_fp16 : Intrinsic<[llvm_float_ty], [llvm_i16_ty]>,
 458                             GCCBuiltin<"__gnu_h2f_ieee">;
 459 }
 460
 461 // These convert intrinsics are to support various conversions between
 462 // various types with rounding and saturation. NOTE: avoid using these
 463 // intrinsics as they might be removed sometime in the future and
 464 // most targets don't support them.
 465 def int_convertff  : Intrinsic<[llvm_anyfloat_ty],
 466                                [llvm_anyfloat_ty, llvm_i32_ty, llvm_i32_ty]>;
 467 def int_convertfsi : Intrinsic<[llvm_anyfloat_ty],
 468                                [llvm_anyint_ty, llvm_i32_ty, llvm_i32_ty]>;
 469 def int_convertfui : Intrinsic<[llvm_anyfloat_ty],
 470                                [llvm_anyint_ty, llvm_i32_ty, llvm_i32_ty]>;
 471 def int_convertsif : Intrinsic<[llvm_anyint_ty],
 472                                [llvm_anyfloat_ty, llvm_i32_ty, llvm_i32_ty]>;
 473 def int_convertuif : Intrinsic<[llvm_anyint_ty],
 474                                [llvm_anyfloat_ty, llvm_i32_ty, llvm_i32_ty]>;
 475 def int_convertss  : Intrinsic<[llvm_anyint_ty],
 476                                [llvm_anyint_ty, llvm_i32_ty, llvm_i32_ty]>;
 477 def int_convertsu  : Intrinsic<[llvm_anyint_ty],
 478                                [llvm_anyint_ty, llvm_i32_ty, llvm_i32_ty]>;
 479 def int_convertus  : Intrinsic<[llvm_anyint_ty],
 480                                [llvm_anyint_ty, llvm_i32_ty, llvm_i32_ty]>;
 481 def int_convertuu  : Intrinsic<[llvm_anyint_ty],
 482                                [llvm_anyint_ty, llvm_i32_ty, llvm_i32_ty]>;
 483
 484 //===----------------------------------------------------------------------===//
 485 // Target-specific intrinsics
 486 //===----------------------------------------------------------------------===//
 487
 488 include "llvm/IntrinsicsPowerPC.td"
 489 include "llvm/IntrinsicsX86.td"
 490 include "llvm/IntrinsicsARM.td"
 491 include "llvm/IntrinsicsCellSPU.td"
 492 include "llvm/IntrinsicsAlpha.td"
 493 include "llvm/IntrinsicsXCore.td"