include/llvm/Intrinsics.td

   1 //===- Intrinsics.td - Defines all LLVM intrinsics ---------*- tablegen -*-===//
   2 //
   3 //                     The LLVM Compiler Infrastructure
   4 //
   5 // This file is distributed under the University of Illinois Open Source
   6 // License. See LICENSE.TXT for details.
   7 //
   8 //===----------------------------------------------------------------------===//
   9 //
  10 // This file defines properties of all LLVM intrinsics.
  11 //
  12 //===----------------------------------------------------------------------===//
  13
  14 include "llvm/CodeGen/ValueTypes.td"
  15
  16 //===----------------------------------------------------------------------===//
  17 //  Properties we keep track of for intrinsics.
  18 //===----------------------------------------------------------------------===//
  19
  20 class IntrinsicProperty;
  21
  22 // Intr*Mem - Memory properties.  An intrinsic is allowed to have exactly one of
  23 // these properties set.  They are listed from the most aggressive (best to use
  24 // if correct) to the least aggressive.  If no property is set, the worst case
  25 // is assumed (IntrWriteMem).
  26
  27 // IntrNoMem - The intrinsic does not access memory or have any other side
  28 // effects.  It may be CSE'd deleted if dead, etc.
  29 def IntrNoMem : IntrinsicProperty;
  30
  31 // IntrReadArgMem - This intrinsic reads only from memory that one of its
  32 // arguments points to, but may read an unspecified amount.
  33 def IntrReadArgMem : IntrinsicProperty;
  34
  35 // IntrReadMem - This intrinsic reads from unspecified memory, so it cannot be
  36 // moved across stores.  However, it can be reordered otherwise and can be
  37 // deleted if dead.
  38 def IntrReadMem : IntrinsicProperty;
  39
  40 // IntrWriteArgMem - This intrinsic reads and writes only from memory that one
  41 // of its arguments points to, but may access an unspecified amount.  It has no
  42 // other side effects.  This may only be used if the intrinsic doesn't "capture"
  43 // the argument pointer (e.g. storing it someplace).
  44 def IntrWriteArgMem : IntrinsicProperty;
  45
  46 // IntrWriteMem - This intrinsic may read or modify unspecified memory or has
  47 // other side effects.  It cannot be modified by the optimizer.  This is the
  48 // default if the intrinsic has no other Intr*Mem property.
  49 def IntrWriteMem : IntrinsicProperty;
  50
  51 // Commutative - This intrinsic is commutative: X op Y == Y op X.
  52 def Commutative : IntrinsicProperty;
  53
  54 //===----------------------------------------------------------------------===//
  55 // Types used by intrinsics.
  56 //===----------------------------------------------------------------------===//
  57
  58 class LLVMType<ValueType vt> {
  59   ValueType VT = vt;
  60 }
  61
  62 class LLVMPointerType<LLVMType elty>
  63   : LLVMType<iPTR>{
  64   LLVMType ElTy = elty;
  65 }
  66
  67 class LLVMAnyPointerType<LLVMType elty>
  68   : LLVMType<iPTRAny>{
  69   LLVMType ElTy = elty;
  70 }
  71
  72 class LLVMMatchType<int num>
  73   : LLVMType<OtherVT>{
  74   int Number = num;
  75 }
  76
  77 def llvm_void_ty       : LLVMType<isVoid>;
  78 def llvm_anyint_ty     : LLVMType<iAny>;
  79 def llvm_anyfloat_ty   : LLVMType<fAny>;
  80 def llvm_i1_ty         : LLVMType<i1>;
  81 def llvm_i8_ty         : LLVMType<i8>;
  82 def llvm_i16_ty        : LLVMType<i16>;
  83 def llvm_i32_ty        : LLVMType<i32>;
  84 def llvm_i64_ty        : LLVMType<i64>;
  85 def llvm_float_ty      : LLVMType<f32>;
  86 def llvm_double_ty     : LLVMType<f64>;
  87 def llvm_f80_ty        : LLVMType<f80>;
  88 def llvm_f128_ty       : LLVMType<f128>;
  89 def llvm_ppcf128_ty    : LLVMType<ppcf128>;
  90 def llvm_ptr_ty        : LLVMPointerType<llvm_i8_ty>;             // i8*
  91 def llvm_ptrptr_ty     : LLVMPointerType<llvm_ptr_ty>;            // i8**
  92 def llvm_anyptr_ty     : LLVMAnyPointerType<llvm_i8_ty>;          // (space)i8*
  93 def llvm_empty_ty      : LLVMType<OtherVT>;                       // { }
  94 def llvm_descriptor_ty : LLVMPointerType<llvm_empty_ty>;          // { }*
  95
  96 def llvm_v16i8_ty      : LLVMType<v16i8>;    // 16 x i8
  97 def llvm_v8i16_ty      : LLVMType<v8i16>;    //  8 x i16
  98 def llvm_v2i64_ty      : LLVMType<v2i64>;    //  2 x i64
  99 def llvm_v2i32_ty      : LLVMType<v2i32>;    //  2 x i32
 100 def llvm_v1i64_ty      : LLVMType<v1i64>;    //  1 x i64
 101 def llvm_v4i32_ty      : LLVMType<v4i32>;    //  4 x i32
 102 def llvm_v4f32_ty      : LLVMType<v4f32>;    //  4 x float
 103 def llvm_v2f64_ty      : LLVMType<v2f64>;    //  2 x double
 104
 105 // MMX Vector Types
 106 def llvm_v8i8_ty       : LLVMType<v8i8>;     //  8 x i8
 107 def llvm_v4i16_ty      : LLVMType<v4i16>;    //  4 x i16
 108
 109 def llvm_vararg_ty     : LLVMType<isVoid>;   // this means vararg here
 110
 111 //===----------------------------------------------------------------------===//
 112 // Intrinsic Definitions.
 113 //===----------------------------------------------------------------------===//
 114
 115 // Intrinsic class - This is used to define one LLVM intrinsic.  The name of the
 116 // intrinsic definition should start with "int_", then match the LLVM intrinsic
 117 // name with the "llvm." prefix removed, and all "."s turned into "_"s.  For
 118 // example, llvm.bswap.i16 -> int_bswap_i16.
 119 //
 120 //  * RetTypes is a list containing the return types expected for the
 121 //    intrinsic.
 122 //  * ParamTypes is a list containing the parameter types expected for the
 123 //    intrinsic.
 124 //  * Properties can be set to describe the behavior of the intrinsic.
 125 //
 126 class Intrinsic<list<LLVMType> ret_types,
 127                 list<LLVMType> param_types = [],
 128                 list<IntrinsicProperty> properties = [],
 129                 string name = ""> {
 130   string LLVMName = name;
 131   string TargetPrefix = "";   // Set to a prefix for target-specific intrinsics.
 132   list<LLVMType> RetTypes = ret_types;
 133   list<LLVMType> ParamTypes = param_types;
 134   list<IntrinsicProperty> Properties = properties;
 135 }
 136
 137 /// GCCBuiltin - If this intrinsic exactly corresponds to a GCC builtin, this
 138 /// specifies the name of the builtin.  This provides automatic CBE and CFE
 139 /// support.
 140 class GCCBuiltin<string name> {
 141   string GCCBuiltinName = name;
 142 }
 143
 144
 145 //===--------------- Variable Argument Handling Intrinsics ----------------===//
 146 //
 147
 148 def int_vastart : Intrinsic<[llvm_void_ty], [llvm_ptr_ty], [], "llvm.va_start">;
 149 def int_vacopy  : Intrinsic<[llvm_void_ty], [llvm_ptr_ty, llvm_ptr_ty], [],
 150                             "llvm.va_copy">;
 151 def int_vaend   : Intrinsic<[llvm_void_ty], [llvm_ptr_ty], [], "llvm.va_end">;
 152
 153 //===------------------- Garbage Collection Intrinsics --------------------===//
 154 //
 155 def int_gcroot  : Intrinsic<[llvm_void_ty],
 156                             [llvm_ptrptr_ty, llvm_ptr_ty]>;
 157 def int_gcread  : Intrinsic<[llvm_ptr_ty],
 158                             [llvm_ptr_ty, llvm_ptrptr_ty],
 159                             [IntrReadArgMem]>;
 160 def int_gcwrite : Intrinsic<[llvm_void_ty],
 161                             [llvm_ptr_ty, llvm_ptr_ty, llvm_ptrptr_ty],
 162                             [IntrWriteArgMem]>;
 163
 164 //===--------------------- Code Generator Intrinsics ----------------------===//
 165 //
 166 def int_returnaddress : Intrinsic<[llvm_ptr_ty], [llvm_i32_ty], [IntrNoMem]>;
 167 def int_frameaddress  : Intrinsic<[llvm_ptr_ty], [llvm_i32_ty], [IntrNoMem]>;
 168
 169 // Note: we treat stacksave/stackrestore as writemem because we don't otherwise
 170 // model their dependencies on allocas.
 171 def int_stacksave     : Intrinsic<[llvm_ptr_ty]>,
 172                         GCCBuiltin<"__builtin_stack_save">;
 173 def int_stackrestore  : Intrinsic<[llvm_void_ty], [llvm_ptr_ty]>,
 174                         GCCBuiltin<"__builtin_stack_restore">;
 175
 176 // IntrWriteArgMem is more pessimistic than strictly necessary for prefetch,
 177 // however it does conveniently prevent the prefetch from being reordered
 178 // with respect to nearby accesses to the same memory.
 179 def int_prefetch      : Intrinsic<[llvm_void_ty],
 180                                   [llvm_ptr_ty, llvm_i32_ty, llvm_i32_ty],
 181                                   [IntrWriteArgMem]>;
 182 def int_pcmarker      : Intrinsic<[llvm_void_ty], [llvm_i32_ty]>;
 183
 184 def int_readcyclecounter : Intrinsic<[llvm_i64_ty]>;
 185
 186 // Stack Protector Intrinsic - The stackprotector intrinsic writes the stack
 187 // guard to the correct place on the stack frame.
 188 def int_stackprotector : Intrinsic<[llvm_void_ty],
 189                                    [llvm_ptr_ty, llvm_ptrptr_ty],
 190                                    [IntrWriteMem]>;
 191
 192 //===------------------- Standard C Library Intrinsics --------------------===//
 193 //
 194
 195 let Properties = [IntrWriteArgMem] in {
 196   def int_memcpy  : Intrinsic<[llvm_void_ty],
 197                                [llvm_ptr_ty, llvm_ptr_ty,
 198                                 llvm_anyint_ty, llvm_i32_ty]>;
 199   def int_memmove : Intrinsic<[llvm_void_ty],
 200                                   [llvm_ptr_ty, llvm_ptr_ty,
 201                                    llvm_anyint_ty, llvm_i32_ty]>;
 202   def int_memset  : Intrinsic<[llvm_void_ty],
 203                                [llvm_ptr_ty, llvm_i8_ty,
 204                                 llvm_anyint_ty, llvm_i32_ty]>;
 205 }
 206
 207 // These functions do not actually read memory, but they are sensitive to the
 208 // rounding mode.  This needs to be modelled separately; in the meantime
 209 // declaring them as reading memory is conservatively correct.
 210 let Properties = [IntrReadMem] in {
 211   def int_sqrt : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 212   def int_powi : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>, llvm_i32_ty]>;
 213   def int_sin  : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 214   def int_cos  : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 215   def int_pow  : Intrinsic<[llvm_anyfloat_ty],
 216                            [LLVMMatchType<0>, LLVMMatchType<0>]>;
 217   def int_log  : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 218   def int_log10: Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 219   def int_log2 : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 220   def int_exp  : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 221   def int_exp2 : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 222 }
 223
 224 // NOTE: these are internal interfaces.
 225 def int_setjmp     : Intrinsic<[llvm_i32_ty],  [llvm_ptr_ty]>;
 226 def int_longjmp    : Intrinsic<[llvm_void_ty], [llvm_ptr_ty, llvm_i32_ty]>;
 227 def int_sigsetjmp  : Intrinsic<[llvm_i32_ty] , [llvm_ptr_ty, llvm_i32_ty]>;
 228 def int_siglongjmp : Intrinsic<[llvm_void_ty], [llvm_ptr_ty, llvm_i32_ty]>;
 229
 230 //===-------------------- Bit Manipulation Intrinsics ---------------------===//
 231 //
 232
 233 // None of these intrinsics accesses memory at all.
 234 let Properties = [IntrNoMem] in {
 235   def int_bswap: Intrinsic<[llvm_anyint_ty], [LLVMMatchType<0>]>;
 236   def int_ctpop: Intrinsic<[llvm_anyint_ty], [LLVMMatchType<0>]>;
 237   def int_ctlz : Intrinsic<[llvm_anyint_ty], [LLVMMatchType<0>]>;
 238   def int_cttz : Intrinsic<[llvm_anyint_ty], [LLVMMatchType<0>]>;
 239   def int_part_select : Intrinsic<[llvm_anyint_ty],
 240                                   [LLVMMatchType<0>, llvm_i32_ty, llvm_i32_ty]>;
 241   def int_part_set : Intrinsic<[llvm_anyint_ty],
 242                                [LLVMMatchType<0>, llvm_anyint_ty,
 243                                 llvm_i32_ty, llvm_i32_ty]>;
 244 }
 245
 246 //===------------------------ Debugger Intrinsics -------------------------===//
 247 //
 248
 249 def int_dbg_stoppoint    : Intrinsic<[llvm_void_ty],
 250                                      [llvm_i32_ty, llvm_i32_ty,
 251                                       llvm_descriptor_ty]>;
 252 def int_dbg_region_start : Intrinsic<[llvm_void_ty], [llvm_descriptor_ty]>;
 253 def int_dbg_region_end   : Intrinsic<[llvm_void_ty], [llvm_descriptor_ty]>;
 254 def int_dbg_func_start   : Intrinsic<[llvm_void_ty], [llvm_descriptor_ty]>;
 255 def int_dbg_declare      : Intrinsic<[llvm_void_ty],
 256                                      [llvm_descriptor_ty, llvm_descriptor_ty]>;
 257
 258 //===------------------ Exception Handling Intrinsics----------------------===//
 259 //
 260 def int_eh_exception    : Intrinsic<[llvm_ptr_ty]>;
 261 def int_eh_selector_i32 : Intrinsic<[llvm_i32_ty],
 262                                     [llvm_ptr_ty, llvm_ptr_ty, llvm_vararg_ty]>;
 263 def int_eh_selector_i64 : Intrinsic<[llvm_i64_ty],
 264                                     [llvm_ptr_ty, llvm_ptr_ty, llvm_vararg_ty]>;
 265
 266 def int_eh_typeid_for_i32 : Intrinsic<[llvm_i32_ty], [llvm_ptr_ty]>;
 267 def int_eh_typeid_for_i64 : Intrinsic<[llvm_i64_ty], [llvm_ptr_ty]>;
 268
 269 def int_eh_return_i32 : Intrinsic<[llvm_void_ty], [llvm_i32_ty, llvm_ptr_ty]>;
 270 def int_eh_return_i64 : Intrinsic<[llvm_void_ty], [llvm_i64_ty, llvm_ptr_ty]>;
 271
 272 def int_eh_unwind_init: Intrinsic<[llvm_void_ty]>,
 273                         GCCBuiltin<"__builtin_unwind_init">;
 274
 275 def int_eh_dwarf_cfa  : Intrinsic<[llvm_ptr_ty], [llvm_i32_ty]>;
 276
 277 //===---------------- Generic Variable Attribute Intrinsics----------------===//
 278 //
 279 def int_var_annotation : Intrinsic<[llvm_void_ty],
 280                                    [llvm_ptr_ty, llvm_ptr_ty,
 281                                     llvm_ptr_ty, llvm_i32_ty],
 282                                    [], "llvm.var.annotation">;
 283 def int_ptr_annotation : Intrinsic<[LLVMAnyPointerType<llvm_anyint_ty>],
 284                                    [LLVMMatchType<0>, llvm_ptr_ty, llvm_ptr_ty,
 285                                     llvm_i32_ty],
 286                                    [], "llvm.ptr.annotation">;
 287 def int_annotation : Intrinsic<[llvm_anyint_ty],
 288                                [LLVMMatchType<0>, llvm_ptr_ty,
 289                                 llvm_ptr_ty, llvm_i32_ty],
 290                                [], "llvm.annotation">;
 291
 292 //===------------------------ Trampoline Intrinsics -----------------------===//
 293 //
 294 def int_init_trampoline : Intrinsic<[llvm_ptr_ty],
 295                                     [llvm_ptr_ty, llvm_ptr_ty, llvm_ptr_ty],
 296                                     []>,
 297                           GCCBuiltin<"__builtin_init_trampoline">;
 298
 299 //===------------------------ Overflow Intrinsics -------------------------===//
 300 //
 301
 302 // Expose the carry flag from add operations on two integrals.
 303 def int_sadd_with_overflow : Intrinsic<[llvm_anyint_ty, llvm_i1_ty],
 304                                        [LLVMMatchType<0>, LLVMMatchType<0>]>;
 305 def int_uadd_with_overflow : Intrinsic<[llvm_anyint_ty, llvm_i1_ty],
 306                                        [LLVMMatchType<0>, LLVMMatchType<0>]>;
 307
 308 //===------------------------- Atomic Intrinsics --------------------------===//
 309 //
 310 def int_memory_barrier : Intrinsic<[llvm_void_ty],
 311                                    [llvm_i1_ty, llvm_i1_ty,
 312                                     llvm_i1_ty, llvm_i1_ty, llvm_i1_ty], []>,
 313                                     GCCBuiltin<"__builtin_llvm_memory_barrier">;
 314
 315 def int_atomic_cmp_swap : Intrinsic<[llvm_anyint_ty],
 316                                     [LLVMAnyPointerType<LLVMMatchType<0>>,
 317                                      LLVMMatchType<0>, LLVMMatchType<0>],
 318                                     [IntrWriteArgMem]>,
 319                            GCCBuiltin<"__sync_val_compare_and_swap">;
 320 def int_atomic_load_add : Intrinsic<[llvm_anyint_ty],
 321                                     [LLVMAnyPointerType<LLVMMatchType<0>>,
 322                                      LLVMMatchType<0>],
 323                                     [IntrWriteArgMem]>,
 324                            GCCBuiltin<"__sync_fetch_and_add">;
 325 def int_atomic_swap     : Intrinsic<[llvm_anyint_ty],
 326                                     [LLVMAnyPointerType<LLVMMatchType<0>>,
 327                                      LLVMMatchType<0>],
 328                                     [IntrWriteArgMem]>,
 329                            GCCBuiltin<"__sync_lock_test_and_set">;
 330 def int_atomic_load_sub : Intrinsic<[llvm_anyint_ty],
 331                                     [LLVMAnyPointerType<LLVMMatchType<0>>,
 332                                      LLVMMatchType<0>],
 333                                     [IntrWriteArgMem]>,
 334                            GCCBuiltin<"__sync_fetch_and_sub">;
 335 def int_atomic_load_and : Intrinsic<[llvm_anyint_ty],
 336                                     [LLVMAnyPointerType<LLVMMatchType<0>>,
 337                                      LLVMMatchType<0>],
 338                                     [IntrWriteArgMem]>,
 339                            GCCBuiltin<"__sync_fetch_and_and">;
 340 def int_atomic_load_or   : Intrinsic<[llvm_anyint_ty],
 341                                      [LLVMAnyPointerType<LLVMMatchType<0>>,
 342                                       LLVMMatchType<0>],
 343                                      [IntrWriteArgMem]>,
 344                            GCCBuiltin<"__sync_fetch_and_or">;
 345 def int_atomic_load_xor : Intrinsic<[llvm_anyint_ty],
 346                                     [LLVMAnyPointerType<LLVMMatchType<0>>,
 347                                      LLVMMatchType<0>],
 348                                     [IntrWriteArgMem]>,
 349                            GCCBuiltin<"__sync_fetch_and_xor">;
 350 def int_atomic_load_nand : Intrinsic<[llvm_anyint_ty],
 351                                      [LLVMAnyPointerType<LLVMMatchType<0>>,
 352                                       LLVMMatchType<0>],
 353                                      [IntrWriteArgMem]>,
 354                            GCCBuiltin<"__sync_fetch_and_nand">;
 355 def int_atomic_load_min  : Intrinsic<[llvm_anyint_ty],
 356                                      [LLVMAnyPointerType<LLVMMatchType<0>>,
 357                                       LLVMMatchType<0>],
 358                                      [IntrWriteArgMem]>,
 359                            GCCBuiltin<"__sync_fetch_and_min">;
 360 def int_atomic_load_max  : Intrinsic<[llvm_anyint_ty],
 361                                      [LLVMAnyPointerType<LLVMMatchType<0>>,
 362                                       LLVMMatchType<0>],
 363                                      [IntrWriteArgMem]>,
 364                            GCCBuiltin<"__sync_fetch_and_max">;
 365 def int_atomic_load_umin : Intrinsic<[llvm_anyint_ty],
 366                                      [LLVMAnyPointerType<LLVMMatchType<0>>,
 367                                       LLVMMatchType<0>],
 368                                      [IntrWriteArgMem]>,
 369                            GCCBuiltin<"__sync_fetch_and_umin">;
 370 def int_atomic_load_umax : Intrinsic<[llvm_anyint_ty],
 371                                      [LLVMAnyPointerType<LLVMMatchType<0>>,
 372                                       LLVMMatchType<0>],
 373                                      [IntrWriteArgMem]>,
 374                            GCCBuiltin<"__sync_fetch_and_umax">;
 375
 376 //===-------------------------- Other Intrinsics --------------------------===//
 377 //
 378 def int_flt_rounds : Intrinsic<[llvm_i32_ty]>,
 379                      GCCBuiltin<"__builtin_flt_rounds">;
 380 def int_trap : Intrinsic<[llvm_void_ty]>,
 381                GCCBuiltin<"__builtin_trap">;
 382
 383 // These convert intrinsics are to support various conversions between
 384 // various types with rounding and saturation. NOTE: avoid using these
 385 // intrinsics as they might be removed sometime in the future and
 386 // most targets don't support them.
 387 def int_convertff  : Intrinsic<[llvm_anyfloat_ty],
 388                                [llvm_anyfloat_ty, llvm_i32_ty, llvm_i32_ty]>;
 389 def int_convertfsi : Intrinsic<[llvm_anyfloat_ty],
 390                                [llvm_anyint_ty, llvm_i32_ty, llvm_i32_ty]>;
 391 def int_convertfui : Intrinsic<[llvm_anyfloat_ty],
 392                                [llvm_anyint_ty, llvm_i32_ty, llvm_i32_ty]>;
 393 def int_convertsif : Intrinsic<[llvm_anyint_ty],
 394                                [llvm_anyfloat_ty, llvm_i32_ty, llvm_i32_ty]>;
 395 def int_convertuif : Intrinsic<[llvm_anyint_ty],
 396                                [llvm_anyfloat_ty, llvm_i32_ty, llvm_i32_ty]>;
 397 def int_convertss  : Intrinsic<[llvm_anyint_ty],
 398                                [llvm_anyint_ty, llvm_i32_ty, llvm_i32_ty]>;
 399 def int_convertsu  : Intrinsic<[llvm_anyint_ty],
 400                                [llvm_anyint_ty, llvm_i32_ty, llvm_i32_ty]>;
 401 def int_convertus  : Intrinsic<[llvm_anyint_ty],
 402                                [llvm_anyint_ty, llvm_i32_ty, llvm_i32_ty]>;
 403 def int_convertuu  : Intrinsic<[llvm_anyint_ty],
 404                                [llvm_anyint_ty, llvm_i32_ty, llvm_i32_ty]>;
 405
 406 //===----------------------------------------------------------------------===//
 407 // Target-specific intrinsics
 408 //===----------------------------------------------------------------------===//
 409
 410 include "llvm/IntrinsicsPowerPC.td"
 411 include "llvm/IntrinsicsX86.td"
 412 include "llvm/IntrinsicsARM.td"
 413 include "llvm/IntrinsicsCellSPU.td"
 414 include "llvm/IntrinsicsAlpha.td"
 415 include "llvm/IntrinsicsXCore.td"