1 ===========================
2 TableGen Language Reference
3 ===========================
5 .. sectionauthor:: Sean Silva <silvas@purdue.edu>
11 This document is extremely rough. If you find something lacking, please
12 fix it, file a documentation bug, or ask about it on llvmdev.
17 This document is meant to be a normative spec about the TableGen language
18 in and of itself (i.e. how to understand a given construct in terms of how
19 it affects the final set of records represented by the TableGen file). If
20 you are unsure if this document is really what you are looking for, please
21 read :doc:`/TableGenFundamentals` first.
26 The lexical and syntax notation used here is intended to imitate
27 `Python's`_. In particular, for lexical definitions, the productions
28 operate at the character level and there is no implied whitespace between
29 elements. The syntax definitions operate at the token level, so there is
30 implied whitespace between tokens.
32 .. _`Python's`: http://docs.python.org/py3k/reference/introduction.html#notation
37 TableGen supports BCPL (``// ...``) and nestable C-style (``/* ... */``)
40 The following is a listing of the basic punctuation tokens::
42 - + [ ] { } ( ) < > : ; . = ? #
44 Numeric literals take one of the following forms:
46 .. TableGen actually will lex some pretty strange sequences an interpret
47 them as numbers. What is shown here is an attempt to approximate what it
51 TokInteger: `DecimalInteger` | `HexInteger` | `BinInteger`
52 DecimalInteger: ["+" | "-"] ("0"..."9")+
53 HexInteger: "0x" ("0"..."9" | "a"..."f" | "A"..."F")+
54 BinInteger: "0b" ("0" | "1")+
56 One aspect to note is that the :token:`DecimalInteger` token *includes* the
57 ``+`` or ``-``, as opposed to having ``+`` and ``-`` be unary operators as
60 TableGen has identifier-like tokens:
63 ualpha: "a"..."z" | "A"..."Z" | "_"
64 TokIdentifier: ("0"..."9")* `ualpha` (`ualpha` | "0"..."9")*
65 TokVarName: "$" `ualpha` (`ualpha` | "0"..."9")*
67 Note that unlike most languages, TableGen allows :token:`TokIdentifier` to
68 begin with a number. In case of ambiguity, a token will be interpreted as a
69 numeric literal rather than an identifier.
71 TableGen also has two string-like literals:
74 TokString: '"' <non-'"' characters and C-like escapes> '"'
75 TokCodeFragment: "[{" <shortest text not containing "}]"> "}]"
78 The current implementation accepts the following C-like escapes::
82 TableGen also has the following keywords::
84 bit bits class code dag
85 def foreach defm field in
86 int let list multiclass string
88 TableGen also has "bang operators" which have a
89 wide variety of meanings::
91 !eq !if !head !tail !con
93 !cast !empty !subst !foreach !strconcat
98 TableGen has an ``include`` mechanism. It does not play a role in the
99 syntax per se, since it is lexically replaced with the contents of the
103 IncludeDirective: "include" `TokString`
105 TableGen's top-level production consists of "objects".
108 TableGenFile: `Object`*
109 Object: `Class` | `Def` | `Defm` | `Let` | `MultiClass` | `Foreach`
115 Class: "class" `TokIdentifier` [`TemplateArgList`] `ObjectBody`
117 A ``class`` declaration creates a record which other records can inherit
118 from. A class can be parametrized by a list of "template arguments", whose
119 values can be used in the class body.
121 A given class can only be defined once. A ``class`` declaration is
122 considered to define the class if any of the following is true:
124 .. break ObjectBody into its consituents so that they are present here?
126 #. The :token:`TemplateArgList` is present.
127 #. The :token:`Body` in the :token:`ObjectBody` is present and is not empty.
128 #. The :token:`BaseClassList` in the :token:`ObjectBody` is present.
130 You can declare an empty class by giving and empty :token:`TemplateArgList`
131 and an empty :token:`ObjectBody`. This can serve as a restricted form of
132 forward declaration: note that records deriving from the forward-declared
133 class will inherit no fields from it since the record expansion is done
134 when the record is parsed.
137 TemplateArgList: "<" `Declaration` ("," `Declaration`)* ">"
142 .. Omitting mention of arcane "field" prefix to discourage its use.
144 The declaration syntax is pretty much what you would expect as a C++
148 Declaration: `Type` `TokIdentifier` ["=" `Value`]
150 It assigns the value to the identifer.
156 Type: "string" | "code" | "bit" | "int" | "dag"
157 :| "bits" "<" `TokInteger` ">"
158 :| "list" "<" `Type` ">"
160 ClassID: `TokIdentifier`
162 Both ``string`` and ``code`` correspond to the string type; the difference
163 is purely to indicate programmer intention.
165 The :token:`ClassID` must identify a class that has been previously
172 Value: `SimpleValue` `ValueSuffix`*
173 ValueSuffix: "{" `RangeList` "}"
174 :| "[" `RangeList` "]"
175 :| "." `TokIdentifier`
176 RangeList: `RangePiece` ("," `RangePiece`)*
177 RangePiece: `TokInteger`
178 :| `TokInteger` "-" `TokInteger`
179 :| `TokInteger` `TokInteger`
181 The peculiar last form of :token:`RangePiece` is due to the fact that the
182 "``-``" is included in the :token:`TokInteger`, hence ``1-5`` gets lexed as
183 two consecutive :token:`TokInteger`'s, with values ``1`` and ``-5``,
184 instead of "1", "-", and "5".
185 The :token:`RangeList` can be thought of as specifying "list slice" in some
189 :token:`SimpleValue` has a number of forms:
193 SimpleValue: `TokIdentifier`
195 The value will be the variable referenced by the identifier. It can be one
198 .. The code for this is exceptionally abstruse. These examples are a
201 * name of a ``def``, such as the use of ``Bar`` in::
203 def Bar : SomeClass {
211 * value local to a ``def``, such as the use of ``Bar`` in::
218 * a template arg of a ``class``, such as the use of ``Bar`` in::
224 * value local to a ``multiclass``, such as the use of ``Bar`` in::
231 * a template arg to a ``multiclass``, such as the use of ``Bar`` in::
233 multiclass Foo<int Bar> {
238 SimpleValue: `TokInteger`
240 This represents the numeric value of the integer.
243 SimpleValue: `TokString`+
245 Multiple adjacent string literals are concatenated like in C/C++. The value
246 is the concatenation of the strings.
249 SimpleValue: `TokCodeFragment`
251 The value is the string value of the code fragment.
256 ``?`` represents an "unset" initializer.
259 SimpleValue: "{" `ValueList` "}"
260 ValueList: [`ValueListNE`]
261 ValueListNE: `Value` ("," `Value`)*
263 This represents a sequence of bits, as would be used to initialize a
264 ``bits<n>`` field (where ``n`` is the number of bits).
267 SimpleValue: `ClassID` "<" `ValueListNE` ">"
269 This generates a new anonymous record definition (as would be created by an
270 unnamed ``def`` inheriting from the given class with the given template
271 arguments) and the value is the value of that record definition.
274 SimpleValue: "[" `ValueList` "]" ["<" `Type` ">"]
276 A list initializer. The optional :token:`Type` can be used to indicate a
277 specific element type, otherwise the element type will be deduced from the
280 .. The initial `DagArg` of the dag must start with an identifier or
281 !cast, but this is more of an implementation detail and so for now just
285 SimpleValue: "(" `DagArg` `DagArgList` ")"
286 DagArgList: `DagArg` ("," `DagArg`)*
287 DagArg: `Value` [":" `TokVarName`]
289 The initial :token:`DagArg` is called the "operator" of the dag.
292 SimpleValue: `BangOperator` ["<" `Type` ">"] "(" `ValueListNE` ")"
298 ObjectBody: `BaseClassList` `Body`
299 BaseClassList: [`BaseClassListNE`]
300 BaseClassListNE: `SubClassRef` ("," `SubClassRef`)*
301 SubClassRef: (`ClassID` | `MultiClassID`) ["<" `ValueList` ">"]
302 DefmID: `TokIdentifier`
304 The version with the :token:`MultiClassID` is only valid in the
305 :token:`BaseClassList` of a ``defm``.
306 The :token:`MultiClassID` should be the name of a ``multiclass``.
308 .. put this somewhere else
310 It is after parsing the base class list that the "let stack" is applied.
313 Body: ";" | "{" BodyList "}"
315 BodyItem: `Declaration` ";"
316 :| "let" `TokIdentifier` [`RangeList`] "=" `Value` ";"
318 The ``let`` form allows overriding the value of an inherited field.
324 There can be pastes in the names here, like ``#NAME#``. Look into that
325 and document it (it boils down to ParseIDValue with IDParseMode ==
326 ParseNameMode). ParseObjectName calls into the general ParseValue, with
327 the only different from "arbitrary expression parsing" being IDParseMode
331 Def: "def" `TokIdentifier` `ObjectBody`
333 Defines a record whose name is given by the :token:`TokIdentifier`. The
334 fields of the record are inherited from the base classes and defined in the
337 Special handling occurs if this ``def`` appears inside a ``multiclass`` or
344 Defm: "defm" `TokIdentifier` ":" `BaseClassList` ";"
346 Note that in the :token:`BaseClassList`, all of the ``multiclass``'s must
347 precede any ``class``'s that appear.
353 Foreach: "foreach" `Declaration` "in" "{" `Object`* "}"
354 :| "foreach" `Declaration` "in" `Object`
356 The value assigned to the variable in the declaration is iterated over and
357 the object or object list is reevaluated with the variable set at each
364 Let: "let" `LetList` "in" "{" `Object`* "}"
365 :| "let" `LetList` "in" `Object`
366 LetList: `LetItem` ("," `LetItem`)*
367 LetItem: `TokIdentifier` [`RangeList`] "=" `Value`
369 This is effectively equivalent to ``let`` inside the body of a record
370 except that it applies to multiple records at a time. The bindings are
371 applied at the end of parsing the base classes of a record.
377 MultiClass: "multiclass" `TokIdentifier` [`TemplateArgList`]
378 : [":" `BaseMultiClassList`] "{" `MultiClassObject`+ "}"
379 BaseMultiClassList: `MultiClassID` ("," `MultiClassID`)*
380 MultiClassID: `TokIdentifier`
381 MultiClassObject: `Def` | `Defm` | `Let` | `Foreach`