LangRef: clarify that global declarations can have section and alignment info.
[oota-llvm.git] / docs / LangRef.rst
1 ==============================
2 LLVM Language Reference Manual
3 ==============================
4
5 .. contents::
6    :local:
7    :depth: 4
8
9 Abstract
10 ========
11
12 This document is a reference manual for the LLVM assembly language. LLVM
13 is a Static Single Assignment (SSA) based representation that provides
14 type safety, low-level operations, flexibility, and the capability of
15 representing 'all' high-level languages cleanly. It is the common code
16 representation used throughout all phases of the LLVM compilation
17 strategy.
18
19 Introduction
20 ============
21
22 The LLVM code representation is designed to be used in three different
23 forms: as an in-memory compiler IR, as an on-disk bitcode representation
24 (suitable for fast loading by a Just-In-Time compiler), and as a human
25 readable assembly language representation. This allows LLVM to provide a
26 powerful intermediate representation for efficient compiler
27 transformations and analysis, while providing a natural means to debug
28 and visualize the transformations. The three different forms of LLVM are
29 all equivalent. This document describes the human readable
30 representation and notation.
31
32 The LLVM representation aims to be light-weight and low-level while
33 being expressive, typed, and extensible at the same time. It aims to be
34 a "universal IR" of sorts, by being at a low enough level that
35 high-level ideas may be cleanly mapped to it (similar to how
36 microprocessors are "universal IR's", allowing many source languages to
37 be mapped to them). By providing type information, LLVM can be used as
38 the target of optimizations: for example, through pointer analysis, it
39 can be proven that a C automatic variable is never accessed outside of
40 the current function, allowing it to be promoted to a simple SSA value
41 instead of a memory location.
42
43 .. _wellformed:
44
45 Well-Formedness
46 ---------------
47
48 It is important to note that this document describes 'well formed' LLVM
49 assembly language. There is a difference between what the parser accepts
50 and what is considered 'well formed'. For example, the following
51 instruction is syntactically okay, but not well formed:
52
53 .. code-block:: llvm
54
55     %x = add i32 1, %x
56
57 because the definition of ``%x`` does not dominate all of its uses. The
58 LLVM infrastructure provides a verification pass that may be used to
59 verify that an LLVM module is well formed. This pass is automatically
60 run by the parser after parsing input assembly and by the optimizer
61 before it outputs bitcode. The violations pointed out by the verifier
62 pass indicate bugs in transformation passes or input to the parser.
63
64 .. _identifiers:
65
66 Identifiers
67 ===========
68
69 LLVM identifiers come in two basic types: global and local. Global
70 identifiers (functions, global variables) begin with the ``'@'``
71 character. Local identifiers (register names, types) begin with the
72 ``'%'`` character. Additionally, there are three different formats for
73 identifiers, for different purposes:
74
75 #. Named values are represented as a string of characters with their
76    prefix. For example, ``%foo``, ``@DivisionByZero``,
77    ``%a.really.long.identifier``. The actual regular expression used is
78    '``[%@][a-zA-Z$._][a-zA-Z$._0-9]*``'. Identifiers which require other
79    characters in their names can be surrounded with quotes. Special
80    characters may be escaped using ``"\xx"`` where ``xx`` is the ASCII
81    code for the character in hexadecimal. In this way, any character can
82    be used in a name value, even quotes themselves.
83 #. Unnamed values are represented as an unsigned numeric value with
84    their prefix. For example, ``%12``, ``@2``, ``%44``.
85 #. Constants, which are described in the section  Constants_ below.
86
87 LLVM requires that values start with a prefix for two reasons: Compilers
88 don't need to worry about name clashes with reserved words, and the set
89 of reserved words may be expanded in the future without penalty.
90 Additionally, unnamed identifiers allow a compiler to quickly come up
91 with a temporary variable without having to avoid symbol table
92 conflicts.
93
94 Reserved words in LLVM are very similar to reserved words in other
95 languages. There are keywords for different opcodes ('``add``',
96 '``bitcast``', '``ret``', etc...), for primitive type names ('``void``',
97 '``i32``', etc...), and others. These reserved words cannot conflict
98 with variable names, because none of them start with a prefix character
99 (``'%'`` or ``'@'``).
100
101 Here is an example of LLVM code to multiply the integer variable
102 '``%X``' by 8:
103
104 The easy way:
105
106 .. code-block:: llvm
107
108     %result = mul i32 %X, 8
109
110 After strength reduction:
111
112 .. code-block:: llvm
113
114     %result = shl i32 %X, 3
115
116 And the hard way:
117
118 .. code-block:: llvm
119
120     %0 = add i32 %X, %X           ; yields {i32}:%0
121     %1 = add i32 %0, %0           ; yields {i32}:%1
122     %result = add i32 %1, %1
123
124 This last way of multiplying ``%X`` by 8 illustrates several important
125 lexical features of LLVM:
126
127 #. Comments are delimited with a '``;``' and go until the end of line.
128 #. Unnamed temporaries are created when the result of a computation is
129    not assigned to a named value.
130 #. Unnamed temporaries are numbered sequentially (using a per-function
131    incrementing counter, starting with 0). Note that basic blocks are
132    included in this numbering. For example, if the entry basic block is not
133    given a label name, then it will get number 0.
134
135 It also shows a convention that we follow in this document. When
136 demonstrating instructions, we will follow an instruction with a comment
137 that defines the type and name of value produced.
138
139 High Level Structure
140 ====================
141
142 Module Structure
143 ----------------
144
145 LLVM programs are composed of ``Module``'s, each of which is a
146 translation unit of the input programs. Each module consists of
147 functions, global variables, and symbol table entries. Modules may be
148 combined together with the LLVM linker, which merges function (and
149 global variable) definitions, resolves forward declarations, and merges
150 symbol table entries. Here is an example of the "hello world" module:
151
152 .. code-block:: llvm
153
154     ; Declare the string constant as a global constant.
155     @.str = private unnamed_addr constant [13 x i8] c"hello world\0A\00"
156
157     ; External declaration of the puts function
158     declare i32 @puts(i8* nocapture) nounwind
159
160     ; Definition of main function
161     define i32 @main() {   ; i32()*
162       ; Convert [13 x i8]* to i8  *...
163       %cast210 = getelementptr [13 x i8]* @.str, i64 0, i64 0
164
165       ; Call puts function to write out the string to stdout.
166       call i32 @puts(i8* %cast210)
167       ret i32 0
168     }
169
170     ; Named metadata
171     !1 = metadata !{i32 42}
172     !foo = !{!1, null}
173
174 This example is made up of a :ref:`global variable <globalvars>` named
175 "``.str``", an external declaration of the "``puts``" function, a
176 :ref:`function definition <functionstructure>` for "``main``" and
177 :ref:`named metadata <namedmetadatastructure>` "``foo``".
178
179 In general, a module is made up of a list of global values (where both
180 functions and global variables are global values). Global values are
181 represented by a pointer to a memory location (in this case, a pointer
182 to an array of char, and a pointer to a function), and have one of the
183 following :ref:`linkage types <linkage>`.
184
185 .. _linkage:
186
187 Linkage Types
188 -------------
189
190 All Global Variables and Functions have one of the following types of
191 linkage:
192
193 ``private``
194     Global values with "``private``" linkage are only directly
195     accessible by objects in the current module. In particular, linking
196     code into a module with an private global value may cause the
197     private to be renamed as necessary to avoid collisions. Because the
198     symbol is private to the module, all references can be updated. This
199     doesn't show up in any symbol table in the object file.
200 ``internal``
201     Similar to private, but the value shows as a local symbol
202     (``STB_LOCAL`` in the case of ELF) in the object file. This
203     corresponds to the notion of the '``static``' keyword in C.
204 ``available_externally``
205     Globals with "``available_externally``" linkage are never emitted
206     into the object file corresponding to the LLVM module. They exist to
207     allow inlining and other optimizations to take place given knowledge
208     of the definition of the global, which is known to be somewhere
209     outside the module. Globals with ``available_externally`` linkage
210     are allowed to be discarded at will, and are otherwise the same as
211     ``linkonce_odr``. This linkage type is only allowed on definitions,
212     not declarations.
213 ``linkonce``
214     Globals with "``linkonce``" linkage are merged with other globals of
215     the same name when linkage occurs. This can be used to implement
216     some forms of inline functions, templates, or other code which must
217     be generated in each translation unit that uses it, but where the
218     body may be overridden with a more definitive definition later.
219     Unreferenced ``linkonce`` globals are allowed to be discarded. Note
220     that ``linkonce`` linkage does not actually allow the optimizer to
221     inline the body of this function into callers because it doesn't
222     know if this definition of the function is the definitive definition
223     within the program or whether it will be overridden by a stronger
224     definition. To enable inlining and other optimizations, use
225     "``linkonce_odr``" linkage.
226 ``weak``
227     "``weak``" linkage has the same merging semantics as ``linkonce``
228     linkage, except that unreferenced globals with ``weak`` linkage may
229     not be discarded. This is used for globals that are declared "weak"
230     in C source code.
231 ``common``
232     "``common``" linkage is most similar to "``weak``" linkage, but they
233     are used for tentative definitions in C, such as "``int X;``" at
234     global scope. Symbols with "``common``" linkage are merged in the
235     same way as ``weak symbols``, and they may not be deleted if
236     unreferenced. ``common`` symbols may not have an explicit section,
237     must have a zero initializer, and may not be marked
238     ':ref:`constant <globalvars>`'. Functions and aliases may not have
239     common linkage.
240
241 .. _linkage_appending:
242
243 ``appending``
244     "``appending``" linkage may only be applied to global variables of
245     pointer to array type. When two global variables with appending
246     linkage are linked together, the two global arrays are appended
247     together. This is the LLVM, typesafe, equivalent of having the
248     system linker append together "sections" with identical names when
249     .o files are linked.
250 ``extern_weak``
251     The semantics of this linkage follow the ELF object file model: the
252     symbol is weak until linked, if not linked, the symbol becomes null
253     instead of being an undefined reference.
254 ``linkonce_odr``, ``weak_odr``
255     Some languages allow differing globals to be merged, such as two
256     functions with different semantics. Other languages, such as
257     ``C++``, ensure that only equivalent globals are ever merged (the
258     "one definition rule" --- "ODR").  Such languages can use the
259     ``linkonce_odr`` and ``weak_odr`` linkage types to indicate that the
260     global will only be merged with equivalent globals. These linkage
261     types are otherwise the same as their non-``odr`` versions.
262 ``external``
263     If none of the above identifiers are used, the global is externally
264     visible, meaning that it participates in linkage and can be used to
265     resolve external symbol references.
266
267 It is illegal for a function *declaration* to have any linkage type
268 other than ``external`` or ``extern_weak``.
269
270 .. _callingconv:
271
272 Calling Conventions
273 -------------------
274
275 LLVM :ref:`functions <functionstructure>`, :ref:`calls <i_call>` and
276 :ref:`invokes <i_invoke>` can all have an optional calling convention
277 specified for the call. The calling convention of any pair of dynamic
278 caller/callee must match, or the behavior of the program is undefined.
279 The following calling conventions are supported by LLVM, and more may be
280 added in the future:
281
282 "``ccc``" - The C calling convention
283     This calling convention (the default if no other calling convention
284     is specified) matches the target C calling conventions. This calling
285     convention supports varargs function calls and tolerates some
286     mismatch in the declared prototype and implemented declaration of
287     the function (as does normal C).
288 "``fastcc``" - The fast calling convention
289     This calling convention attempts to make calls as fast as possible
290     (e.g. by passing things in registers). This calling convention
291     allows the target to use whatever tricks it wants to produce fast
292     code for the target, without having to conform to an externally
293     specified ABI (Application Binary Interface). `Tail calls can only
294     be optimized when this, the GHC or the HiPE convention is
295     used. <CodeGenerator.html#id80>`_ This calling convention does not
296     support varargs and requires the prototype of all callees to exactly
297     match the prototype of the function definition.
298 "``coldcc``" - The cold calling convention
299     This calling convention attempts to make code in the caller as
300     efficient as possible under the assumption that the call is not
301     commonly executed. As such, these calls often preserve all registers
302     so that the call does not break any live ranges in the caller side.
303     This calling convention does not support varargs and requires the
304     prototype of all callees to exactly match the prototype of the
305     function definition. Furthermore the inliner doesn't consider such function
306     calls for inlining.
307 "``cc 10``" - GHC convention
308     This calling convention has been implemented specifically for use by
309     the `Glasgow Haskell Compiler (GHC) <http://www.haskell.org/ghc>`_.
310     It passes everything in registers, going to extremes to achieve this
311     by disabling callee save registers. This calling convention should
312     not be used lightly but only for specific situations such as an
313     alternative to the *register pinning* performance technique often
314     used when implementing functional programming languages. At the
315     moment only X86 supports this convention and it has the following
316     limitations:
317
318     -  On *X86-32* only supports up to 4 bit type parameters. No
319        floating point types are supported.
320     -  On *X86-64* only supports up to 10 bit type parameters and 6
321        floating point parameters.
322
323     This calling convention supports `tail call
324     optimization <CodeGenerator.html#id80>`_ but requires both the
325     caller and callee are using it.
326 "``cc 11``" - The HiPE calling convention
327     This calling convention has been implemented specifically for use by
328     the `High-Performance Erlang
329     (HiPE) <http://www.it.uu.se/research/group/hipe/>`_ compiler, *the*
330     native code compiler of the `Ericsson's Open Source Erlang/OTP
331     system <http://www.erlang.org/download.shtml>`_. It uses more
332     registers for argument passing than the ordinary C calling
333     convention and defines no callee-saved registers. The calling
334     convention properly supports `tail call
335     optimization <CodeGenerator.html#id80>`_ but requires that both the
336     caller and the callee use it. It uses a *register pinning*
337     mechanism, similar to GHC's convention, for keeping frequently
338     accessed runtime components pinned to specific hardware registers.
339     At the moment only X86 supports this convention (both 32 and 64
340     bit).
341 "``webkit_jscc``" - WebKit's JavaScript calling convention
342     This calling convention has been implemented for `WebKit FTL JIT
343     <https://trac.webkit.org/wiki/FTLJIT>`_. It passes arguments on the
344     stack right to left (as cdecl does), and returns a value in the
345     platform's customary return register.
346 "``anyregcc``" - Dynamic calling convention for code patching
347     This is a special convention that supports patching an arbitrary code
348     sequence in place of a call site. This convention forces the call
349     arguments into registers but allows them to be dynamcially
350     allocated. This can currently only be used with calls to
351     llvm.experimental.patchpoint because only this intrinsic records
352     the location of its arguments in a side table. See :doc:`StackMaps`.
353 "``preserve_mostcc``" - The `PreserveMost` calling convention
354     This calling convention attempts to make the code in the caller as little
355     intrusive as possible. This calling convention behaves identical to the `C`
356     calling convention on how arguments and return values are passed, but it
357     uses a different set of caller/callee-saved registers. This alleviates the
358     burden of saving and recovering a large register set before and after the
359     call in the caller. If the arguments are passed in callee-saved registers,
360     then they will be preserved by the callee across the call. This doesn't
361     apply for values returned in callee-saved registers.
362
363     - On X86-64 the callee preserves all general purpose registers, except for
364       R11. R11 can be used as a scratch register. Floating-point registers
365       (XMMs/YMMs) are not preserved and need to be saved by the caller.
366
367     The idea behind this convention is to support calls to runtime functions
368     that have a hot path and a cold path. The hot path is usually a small piece
369     of code that doesn't many registers. The cold path might need to call out to
370     another function and therefore only needs to preserve the caller-saved
371     registers, which haven't already been saved by the caller. The
372     `PreserveMost` calling convention is very similar to the `cold` calling
373     convention in terms of caller/callee-saved registers, but they are used for
374     different types of function calls. `coldcc` is for function calls that are
375     rarely executed, whereas `preserve_mostcc` function calls are intended to be
376     on the hot path and definitely executed a lot. Furthermore `preserve_mostcc`
377     doesn't prevent the inliner from inlining the function call.
378
379     This calling convention will be used by a future version of the ObjectiveC
380     runtime and should therefore still be considered experimental at this time.
381     Although this convention was created to optimize certain runtime calls to
382     the ObjectiveC runtime, it is not limited to this runtime and might be used
383     by other runtimes in the future too. The current implementation only
384     supports X86-64, but the intention is to support more architectures in the
385     future.
386 "``preserve_allcc``" - The `PreserveAll` calling convention
387     This calling convention attempts to make the code in the caller even less
388     intrusive than the `PreserveMost` calling convention. This calling
389     convention also behaves identical to the `C` calling convention on how
390     arguments and return values are passed, but it uses a different set of
391     caller/callee-saved registers. This removes the burden of saving and
392     recovering a large register set before and after the call in the caller. If
393     the arguments are passed in callee-saved registers, then they will be
394     preserved by the callee across the call. This doesn't apply for values
395     returned in callee-saved registers.
396
397     - On X86-64 the callee preserves all general purpose registers, except for
398       R11. R11 can be used as a scratch register. Furthermore it also preserves
399       all floating-point registers (XMMs/YMMs).
400
401     The idea behind this convention is to support calls to runtime functions
402     that don't need to call out to any other functions.
403
404     This calling convention, like the `PreserveMost` calling convention, will be
405     used by a future version of the ObjectiveC runtime and should be considered
406     experimental at this time.
407 "``cc <n>``" - Numbered convention
408     Any calling convention may be specified by number, allowing
409     target-specific calling conventions to be used. Target specific
410     calling conventions start at 64.
411
412 More calling conventions can be added/defined on an as-needed basis, to
413 support Pascal conventions or any other well-known target-independent
414 convention.
415
416 .. _visibilitystyles:
417
418 Visibility Styles
419 -----------------
420
421 All Global Variables and Functions have one of the following visibility
422 styles:
423
424 "``default``" - Default style
425     On targets that use the ELF object file format, default visibility
426     means that the declaration is visible to other modules and, in
427     shared libraries, means that the declared entity may be overridden.
428     On Darwin, default visibility means that the declaration is visible
429     to other modules. Default visibility corresponds to "external
430     linkage" in the language.
431 "``hidden``" - Hidden style
432     Two declarations of an object with hidden visibility refer to the
433     same object if they are in the same shared object. Usually, hidden
434     visibility indicates that the symbol will not be placed into the
435     dynamic symbol table, so no other module (executable or shared
436     library) can reference it directly.
437 "``protected``" - Protected style
438     On ELF, protected visibility indicates that the symbol will be
439     placed in the dynamic symbol table, but that references within the
440     defining module will bind to the local symbol. That is, the symbol
441     cannot be overridden by another module.
442
443 A symbol with ``internal`` or ``private`` linkage must have ``default``
444 visibility.
445
446 .. _dllstorageclass:
447
448 DLL Storage Classes
449 -------------------
450
451 All Global Variables, Functions and Aliases can have one of the following
452 DLL storage class:
453
454 ``dllimport``
455     "``dllimport``" causes the compiler to reference a function or variable via
456     a global pointer to a pointer that is set up by the DLL exporting the
457     symbol. On Microsoft Windows targets, the pointer name is formed by
458     combining ``__imp_`` and the function or variable name.
459 ``dllexport``
460     "``dllexport``" causes the compiler to provide a global pointer to a pointer
461     in a DLL, so that it can be referenced with the ``dllimport`` attribute. On
462     Microsoft Windows targets, the pointer name is formed by combining
463     ``__imp_`` and the function or variable name. Since this storage class
464     exists for defining a dll interface, the compiler, assembler and linker know
465     it is externally referenced and must refrain from deleting the symbol.
466
467 .. _tls_model:
468
469 Thread Local Storage Models
470 ---------------------------
471
472 A variable may be defined as ``thread_local``, which means that it will
473 not be shared by threads (each thread will have a separated copy of the
474 variable). Not all targets support thread-local variables. Optionally, a
475 TLS model may be specified:
476
477 ``localdynamic``
478     For variables that are only used within the current shared library.
479 ``initialexec``
480     For variables in modules that will not be loaded dynamically.
481 ``localexec``
482     For variables defined in the executable and only used within it.
483
484 If no explicit model is given, the "general dynamic" model is used.
485
486 The models correspond to the ELF TLS models; see `ELF Handling For
487 Thread-Local Storage <http://people.redhat.com/drepper/tls.pdf>`_ for
488 more information on under which circumstances the different models may
489 be used. The target may choose a different TLS model if the specified
490 model is not supported, or if a better choice of model can be made.
491
492 A model can also be specified in a alias, but then it only governs how
493 the alias is accessed. It will not have any effect in the aliasee.
494
495 .. _namedtypes:
496
497 Structure Types
498 ---------------
499
500 LLVM IR allows you to specify both "identified" and "literal" :ref:`structure
501 types <t_struct>`.  Literal types are uniqued structurally, but identified types
502 are never uniqued.  An :ref:`opaque structural type <t_opaque>` can also be used
503 to forward declare a type which is not yet available.
504
505 An example of a identified structure specification is:
506
507 .. code-block:: llvm
508
509     %mytype = type { %mytype*, i32 }
510
511 Prior to the LLVM 3.0 release, identified types were structurally uniqued.  Only
512 literal types are uniqued in recent versions of LLVM.
513
514 .. _globalvars:
515
516 Global Variables
517 ----------------
518
519 Global variables define regions of memory allocated at compilation time
520 instead of run-time.
521
522 Global variables definitions must be initialized.
523
524 Global variables in other translation units can also be declared, in which
525 case they don't have an initializer.
526
527 Either global variable definitions or declarations may have an explicit section
528 to be placed in and may have an optional explicit alignment specified.
529
530 A variable may be defined as a global ``constant``, which indicates that
531 the contents of the variable will **never** be modified (enabling better
532 optimization, allowing the global data to be placed in the read-only
533 section of an executable, etc). Note that variables that need runtime
534 initialization cannot be marked ``constant`` as there is a store to the
535 variable.
536
537 LLVM explicitly allows *declarations* of global variables to be marked
538 constant, even if the final definition of the global is not. This
539 capability can be used to enable slightly better optimization of the
540 program, but requires the language definition to guarantee that
541 optimizations based on the 'constantness' are valid for the translation
542 units that do not include the definition.
543
544 As SSA values, global variables define pointer values that are in scope
545 (i.e. they dominate) all basic blocks in the program. Global variables
546 always define a pointer to their "content" type because they describe a
547 region of memory, and all memory objects in LLVM are accessed through
548 pointers.
549
550 Global variables can be marked with ``unnamed_addr`` which indicates
551 that the address is not significant, only the content. Constants marked
552 like this can be merged with other constants if they have the same
553 initializer. Note that a constant with significant address *can* be
554 merged with a ``unnamed_addr`` constant, the result being a constant
555 whose address is significant.
556
557 A global variable may be declared to reside in a target-specific
558 numbered address space. For targets that support them, address spaces
559 may affect how optimizations are performed and/or what target
560 instructions are used to access the variable. The default address space
561 is zero. The address space qualifier must precede any other attributes.
562
563 LLVM allows an explicit section to be specified for globals. If the
564 target supports it, it will emit globals to the section specified.
565
566 By default, global initializers are optimized by assuming that global
567 variables defined within the module are not modified from their
568 initial values before the start of the global initializer.  This is
569 true even for variables potentially accessible from outside the
570 module, including those with external linkage or appearing in
571 ``@llvm.used`` or dllexported variables. This assumption may be suppressed
572 by marking the variable with ``externally_initialized``.
573
574 An explicit alignment may be specified for a global, which must be a
575 power of 2. If not present, or if the alignment is set to zero, the
576 alignment of the global is set by the target to whatever it feels
577 convenient. If an explicit alignment is specified, the global is forced
578 to have exactly that alignment. Targets and optimizers are not allowed
579 to over-align the global if the global has an assigned section. In this
580 case, the extra alignment could be observable: for example, code could
581 assume that the globals are densely packed in their section and try to
582 iterate over them as an array, alignment padding would break this
583 iteration.
584
585 Globals can also have a :ref:`DLL storage class <dllstorageclass>`.
586
587 Variables and aliasaes can have a
588 :ref:`Thread Local Storage Model <tls_model>`.
589
590 Syntax::
591
592     [@<GlobalVarName> =] [Linkage] [Visibility] [DLLStorageClass] [ThreadLocal]
593                          [unnamed_addr] [AddrSpace] [ExternallyInitialized]
594                          <global | constant> <Type> [<InitializerConstant>]
595                          [, section "name"] [, align <Alignment>]
596
597 For example, the following defines a global in a numbered address space
598 with an initializer, section, and alignment:
599
600 .. code-block:: llvm
601
602     @G = addrspace(5) constant float 1.0, section "foo", align 4
603
604 The following example just declares a global variable
605
606 .. code-block:: llvm
607
608    @G = external global i32
609
610 The following example defines a thread-local global with the
611 ``initialexec`` TLS model:
612
613 .. code-block:: llvm
614
615     @G = thread_local(initialexec) global i32 0, align 4
616
617 .. _functionstructure:
618
619 Functions
620 ---------
621
622 LLVM function definitions consist of the "``define``" keyword, an
623 optional :ref:`linkage type <linkage>`, an optional :ref:`visibility
624 style <visibility>`, an optional :ref:`DLL storage class <dllstorageclass>`,
625 an optional :ref:`calling convention <callingconv>`,
626 an optional ``unnamed_addr`` attribute, a return type, an optional
627 :ref:`parameter attribute <paramattrs>` for the return type, a function
628 name, a (possibly empty) argument list (each with optional :ref:`parameter
629 attributes <paramattrs>`), optional :ref:`function attributes <fnattrs>`,
630 an optional section, an optional alignment, an optional :ref:`garbage
631 collector name <gc>`, an optional :ref:`prefix <prefixdata>`, an opening
632 curly brace, a list of basic blocks, and a closing curly brace.
633
634 LLVM function declarations consist of the "``declare``" keyword, an
635 optional :ref:`linkage type <linkage>`, an optional :ref:`visibility
636 style <visibility>`, an optional :ref:`DLL storage class <dllstorageclass>`,
637 an optional :ref:`calling convention <callingconv>`,
638 an optional ``unnamed_addr`` attribute, a return type, an optional
639 :ref:`parameter attribute <paramattrs>` for the return type, a function
640 name, a possibly empty list of arguments, an optional alignment, an optional
641 :ref:`garbage collector name <gc>` and an optional :ref:`prefix <prefixdata>`.
642
643 A function definition contains a list of basic blocks, forming the CFG (Control
644 Flow Graph) for the function. Each basic block may optionally start with a label
645 (giving the basic block a symbol table entry), contains a list of instructions,
646 and ends with a :ref:`terminator <terminators>` instruction (such as a branch or
647 function return). If an explicit label is not provided, a block is assigned an
648 implicit numbered label, using the next value from the same counter as used for
649 unnamed temporaries (:ref:`see above<identifiers>`). For example, if a function
650 entry block does not have an explicit label, it will be assigned label "%0",
651 then the first unnamed temporary in that block will be "%1", etc.
652
653 The first basic block in a function is special in two ways: it is
654 immediately executed on entrance to the function, and it is not allowed
655 to have predecessor basic blocks (i.e. there can not be any branches to
656 the entry block of a function). Because the block can have no
657 predecessors, it also cannot have any :ref:`PHI nodes <i_phi>`.
658
659 LLVM allows an explicit section to be specified for functions. If the
660 target supports it, it will emit functions to the section specified.
661
662 An explicit alignment may be specified for a function. If not present,
663 or if the alignment is set to zero, the alignment of the function is set
664 by the target to whatever it feels convenient. If an explicit alignment
665 is specified, the function is forced to have at least that much
666 alignment. All alignments must be a power of 2.
667
668 If the ``unnamed_addr`` attribute is given, the address is know to not
669 be significant and two identical functions can be merged.
670
671 Syntax::
672
673     define [linkage] [visibility] [DLLStorageClass]
674            [cconv] [ret attrs]
675            <ResultType> @<FunctionName> ([argument list])
676            [unnamed_addr] [fn Attrs] [section "name"] [align N]
677            [gc] [prefix Constant] { ... }
678
679 .. _langref_aliases:
680
681 Aliases
682 -------
683
684 Aliases, unlike function or variables, don't create any new data. They
685 are just a new symbol and metadata for an existing position.
686
687 Aliases have a name and an aliasee that is either a global value or a
688 constant expression.
689
690 Aliases may have an optional :ref:`linkage type <linkage>`, an optional
691 :ref:`visibility style <visibility>`, an optional :ref:`DLL storage class
692 <dllstorageclass>` and an optional :ref:`tls model <tls_model>`.
693
694 Syntax::
695
696     @<Name> = [Visibility] [DLLStorageClass] [ThreadLocal] [unnamed_addr] alias [Linkage] <AliaseeTy> @<Aliasee>
697
698 The linkage must be one of ``private``, ``internal``, ``linkonce``, ``weak``,
699 ``linkonce_odr``, ``weak_odr``, ``external``. Note that some system linkers
700 might not correctly handle dropping a weak symbol that is aliased.
701
702 Alias that are not ``unnamed_addr`` are guaranteed to have the same address as
703 the aliasee expression. ``unnamed_addr`` ones are only guaranteed to point
704 to the same content.
705
706 Since aliases are only a second name, some restrictions apply, of which
707 some can only be checked when producing an object file:
708
709 * The expression defining the aliasee must be computable at assembly
710   time. Since it is just a name, no relocations can be used.
711
712 * No alias in the expression can be weak as the possibility of the
713   intermediate alias being overridden cannot be represented in an
714   object file.
715
716 * No global value in the expression can be a declaration, since that
717   would require a relocation, which is not possible.
718
719 .. _namedmetadatastructure:
720
721 Named Metadata
722 --------------
723
724 Named metadata is a collection of metadata. :ref:`Metadata
725 nodes <metadata>` (but not metadata strings) are the only valid
726 operands for a named metadata.
727
728 Syntax::
729
730     ; Some unnamed metadata nodes, which are referenced by the named metadata.
731     !0 = metadata !{metadata !"zero"}
732     !1 = metadata !{metadata !"one"}
733     !2 = metadata !{metadata !"two"}
734     ; A named metadata.
735     !name = !{!0, !1, !2}
736
737 .. _paramattrs:
738
739 Parameter Attributes
740 --------------------
741
742 The return type and each parameter of a function type may have a set of
743 *parameter attributes* associated with them. Parameter attributes are
744 used to communicate additional information about the result or
745 parameters of a function. Parameter attributes are considered to be part
746 of the function, not of the function type, so functions with different
747 parameter attributes can have the same function type.
748
749 Parameter attributes are simple keywords that follow the type specified.
750 If multiple parameter attributes are needed, they are space separated.
751 For example:
752
753 .. code-block:: llvm
754
755     declare i32 @printf(i8* noalias nocapture, ...)
756     declare i32 @atoi(i8 zeroext)
757     declare signext i8 @returns_signed_char()
758
759 Note that any attributes for the function result (``nounwind``,
760 ``readonly``) come immediately after the argument list.
761
762 Currently, only the following parameter attributes are defined:
763
764 ``zeroext``
765     This indicates to the code generator that the parameter or return
766     value should be zero-extended to the extent required by the target's
767     ABI (which is usually 32-bits, but is 8-bits for a i1 on x86-64) by
768     the caller (for a parameter) or the callee (for a return value).
769 ``signext``
770     This indicates to the code generator that the parameter or return
771     value should be sign-extended to the extent required by the target's
772     ABI (which is usually 32-bits) by the caller (for a parameter) or
773     the callee (for a return value).
774 ``inreg``
775     This indicates that this parameter or return value should be treated
776     in a special target-dependent fashion during while emitting code for
777     a function call or return (usually, by putting it in a register as
778     opposed to memory, though some targets use it to distinguish between
779     two different kinds of registers). Use of this attribute is
780     target-specific.
781 ``byval``
782     This indicates that the pointer parameter should really be passed by
783     value to the function. The attribute implies that a hidden copy of
784     the pointee is made between the caller and the callee, so the callee
785     is unable to modify the value in the caller. This attribute is only
786     valid on LLVM pointer arguments. It is generally used to pass
787     structs and arrays by value, but is also valid on pointers to
788     scalars. The copy is considered to belong to the caller not the
789     callee (for example, ``readonly`` functions should not write to
790     ``byval`` parameters). This is not a valid attribute for return
791     values.
792
793     The byval attribute also supports specifying an alignment with the
794     align attribute. It indicates the alignment of the stack slot to
795     form and the known alignment of the pointer specified to the call
796     site. If the alignment is not specified, then the code generator
797     makes a target-specific assumption.
798
799 .. _attr_inalloca:
800
801 ``inalloca``
802
803     The ``inalloca`` argument attribute allows the caller to take the
804     address of outgoing stack arguments.  An ``inalloca`` argument must
805     be a pointer to stack memory produced by an ``alloca`` instruction.
806     The alloca, or argument allocation, must also be tagged with the
807     inalloca keyword.  Only the past argument may have the ``inalloca``
808     attribute, and that argument is guaranteed to be passed in memory.
809
810     An argument allocation may be used by a call at most once because
811     the call may deallocate it.  The ``inalloca`` attribute cannot be
812     used in conjunction with other attributes that affect argument
813     storage, like ``inreg``, ``nest``, ``sret``, or ``byval``.  The
814     ``inalloca`` attribute also disables LLVM's implicit lowering of
815     large aggregate return values, which means that frontend authors
816     must lower them with ``sret`` pointers.
817
818     When the call site is reached, the argument allocation must have
819     been the most recent stack allocation that is still live, or the
820     results are undefined.  It is possible to allocate additional stack
821     space after an argument allocation and before its call site, but it
822     must be cleared off with :ref:`llvm.stackrestore
823     <int_stackrestore>`.
824
825     See :doc:`InAlloca` for more information on how to use this
826     attribute.
827
828 ``sret``
829     This indicates that the pointer parameter specifies the address of a
830     structure that is the return value of the function in the source
831     program. This pointer must be guaranteed by the caller to be valid:
832     loads and stores to the structure may be assumed by the callee
833     not to trap and to be properly aligned. This may only be applied to
834     the first parameter. This is not a valid attribute for return
835     values.
836
837 .. _noalias:
838
839 ``noalias``
840     This indicates that pointer values :ref:`based <pointeraliasing>` on
841     the argument or return value do not alias pointer values which are
842     not *based* on it, ignoring certain "irrelevant" dependencies. For a
843     call to the parent function, dependencies between memory references
844     from before or after the call and from those during the call are
845     "irrelevant" to the ``noalias`` keyword for the arguments and return
846     value used in that call. The caller shares the responsibility with
847     the callee for ensuring that these requirements are met. For further
848     details, please see the discussion of the NoAlias response in :ref:`alias
849     analysis <Must, May, or No>`.
850
851     Note that this definition of ``noalias`` is intentionally similar
852     to the definition of ``restrict`` in C99 for function arguments,
853     though it is slightly weaker.
854
855     For function return values, C99's ``restrict`` is not meaningful,
856     while LLVM's ``noalias`` is.
857 ``nocapture``
858     This indicates that the callee does not make any copies of the
859     pointer that outlive the callee itself. This is not a valid
860     attribute for return values.
861
862 .. _nest:
863
864 ``nest``
865     This indicates that the pointer parameter can be excised using the
866     :ref:`trampoline intrinsics <int_trampoline>`. This is not a valid
867     attribute for return values and can only be applied to one parameter.
868
869 ``returned``
870     This indicates that the function always returns the argument as its return
871     value. This is an optimization hint to the code generator when generating
872     the caller, allowing tail call optimization and omission of register saves
873     and restores in some cases; it is not checked or enforced when generating
874     the callee. The parameter and the function return type must be valid
875     operands for the :ref:`bitcast instruction <i_bitcast>`. This is not a
876     valid attribute for return values and can only be applied to one parameter.
877
878 ``nonnull``
879     This indicates that the parameter or return pointer is not null. This
880     attribute may only be applied to pointer typed parameters. This is not
881     checked or enforced by LLVM, the caller must ensure that the pointer
882     passed in is non-null, or the callee must ensure that the returned pointer 
883     is non-null.
884
885 .. _gc:
886
887 Garbage Collector Names
888 -----------------------
889
890 Each function may specify a garbage collector name, which is simply a
891 string:
892
893 .. code-block:: llvm
894
895     define void @f() gc "name" { ... }
896
897 The compiler declares the supported values of *name*. Specifying a
898 collector which will cause the compiler to alter its output in order to
899 support the named garbage collection algorithm.
900
901 .. _prefixdata:
902
903 Prefix Data
904 -----------
905
906 Prefix data is data associated with a function which the code generator
907 will emit immediately before the function body.  The purpose of this feature
908 is to allow frontends to associate language-specific runtime metadata with
909 specific functions and make it available through the function pointer while
910 still allowing the function pointer to be called.  To access the data for a
911 given function, a program may bitcast the function pointer to a pointer to
912 the constant's type.  This implies that the IR symbol points to the start
913 of the prefix data.
914
915 To maintain the semantics of ordinary function calls, the prefix data must
916 have a particular format.  Specifically, it must begin with a sequence of
917 bytes which decode to a sequence of machine instructions, valid for the
918 module's target, which transfer control to the point immediately succeeding
919 the prefix data, without performing any other visible action.  This allows
920 the inliner and other passes to reason about the semantics of the function
921 definition without needing to reason about the prefix data.  Obviously this
922 makes the format of the prefix data highly target dependent.
923
924 Prefix data is laid out as if it were an initializer for a global variable
925 of the prefix data's type.  No padding is automatically placed between the
926 prefix data and the function body.  If padding is required, it must be part
927 of the prefix data.
928
929 A trivial example of valid prefix data for the x86 architecture is ``i8 144``,
930 which encodes the ``nop`` instruction:
931
932 .. code-block:: llvm
933
934     define void @f() prefix i8 144 { ... }
935
936 Generally prefix data can be formed by encoding a relative branch instruction
937 which skips the metadata, as in this example of valid prefix data for the
938 x86_64 architecture, where the first two bytes encode ``jmp .+10``:
939
940 .. code-block:: llvm
941
942     %0 = type <{ i8, i8, i8* }>
943
944     define void @f() prefix %0 <{ i8 235, i8 8, i8* @md}> { ... }
945
946 A function may have prefix data but no body.  This has similar semantics
947 to the ``available_externally`` linkage in that the data may be used by the
948 optimizers but will not be emitted in the object file.
949
950 .. _attrgrp:
951
952 Attribute Groups
953 ----------------
954
955 Attribute groups are groups of attributes that are referenced by objects within
956 the IR. They are important for keeping ``.ll`` files readable, because a lot of
957 functions will use the same set of attributes. In the degenerative case of a
958 ``.ll`` file that corresponds to a single ``.c`` file, the single attribute
959 group will capture the important command line flags used to build that file.
960
961 An attribute group is a module-level object. To use an attribute group, an
962 object references the attribute group's ID (e.g. ``#37``). An object may refer
963 to more than one attribute group. In that situation, the attributes from the
964 different groups are merged.
965
966 Here is an example of attribute groups for a function that should always be
967 inlined, has a stack alignment of 4, and which shouldn't use SSE instructions:
968
969 .. code-block:: llvm
970
971    ; Target-independent attributes:
972    attributes #0 = { alwaysinline alignstack=4 }
973
974    ; Target-dependent attributes:
975    attributes #1 = { "no-sse" }
976
977    ; Function @f has attributes: alwaysinline, alignstack=4, and "no-sse".
978    define void @f() #0 #1 { ... }
979
980 .. _fnattrs:
981
982 Function Attributes
983 -------------------
984
985 Function attributes are set to communicate additional information about
986 a function. Function attributes are considered to be part of the
987 function, not of the function type, so functions with different function
988 attributes can have the same function type.
989
990 Function attributes are simple keywords that follow the type specified.
991 If multiple attributes are needed, they are space separated. For
992 example:
993
994 .. code-block:: llvm
995
996     define void @f() noinline { ... }
997     define void @f() alwaysinline { ... }
998     define void @f() alwaysinline optsize { ... }
999     define void @f() optsize { ... }
1000
1001 ``alignstack(<n>)``
1002     This attribute indicates that, when emitting the prologue and
1003     epilogue, the backend should forcibly align the stack pointer.
1004     Specify the desired alignment, which must be a power of two, in
1005     parentheses.
1006 ``alwaysinline``
1007     This attribute indicates that the inliner should attempt to inline
1008     this function into callers whenever possible, ignoring any active
1009     inlining size threshold for this caller.
1010 ``builtin``
1011     This indicates that the callee function at a call site should be
1012     recognized as a built-in function, even though the function's declaration
1013     uses the ``nobuiltin`` attribute. This is only valid at call sites for
1014     direct calls to functions which are declared with the ``nobuiltin``
1015     attribute.
1016 ``cold``
1017     This attribute indicates that this function is rarely called. When
1018     computing edge weights, basic blocks post-dominated by a cold
1019     function call are also considered to be cold; and, thus, given low
1020     weight.
1021 ``inlinehint``
1022     This attribute indicates that the source code contained a hint that
1023     inlining this function is desirable (such as the "inline" keyword in
1024     C/C++). It is just a hint; it imposes no requirements on the
1025     inliner.
1026 ``jumptable``
1027     This attribute indicates that the function should be added to a
1028     jump-instruction table at code-generation time, and that all address-taken
1029     references to this function should be replaced with a reference to the
1030     appropriate jump-instruction-table function pointer. Note that this creates
1031     a new pointer for the original function, which means that code that depends
1032     on function-pointer identity can break. So, any function annotated with
1033     ``jumptable`` must also be ``unnamed_addr``.
1034 ``minsize``
1035     This attribute suggests that optimization passes and code generator
1036     passes make choices that keep the code size of this function as small
1037     as possible and perform optimizations that may sacrifice runtime
1038     performance in order to minimize the size of the generated code.
1039 ``naked``
1040     This attribute disables prologue / epilogue emission for the
1041     function. This can have very system-specific consequences.
1042 ``nobuiltin``
1043     This indicates that the callee function at a call site is not recognized as
1044     a built-in function. LLVM will retain the original call and not replace it
1045     with equivalent code based on the semantics of the built-in function, unless
1046     the call site uses the ``builtin`` attribute. This is valid at call sites
1047     and on function declarations and definitions.
1048 ``noduplicate``
1049     This attribute indicates that calls to the function cannot be
1050     duplicated. A call to a ``noduplicate`` function may be moved
1051     within its parent function, but may not be duplicated within
1052     its parent function.
1053
1054     A function containing a ``noduplicate`` call may still
1055     be an inlining candidate, provided that the call is not
1056     duplicated by inlining. That implies that the function has
1057     internal linkage and only has one call site, so the original
1058     call is dead after inlining.
1059 ``noimplicitfloat``
1060     This attributes disables implicit floating point instructions.
1061 ``noinline``
1062     This attribute indicates that the inliner should never inline this
1063     function in any situation. This attribute may not be used together
1064     with the ``alwaysinline`` attribute.
1065 ``nonlazybind``
1066     This attribute suppresses lazy symbol binding for the function. This
1067     may make calls to the function faster, at the cost of extra program
1068     startup time if the function is not called during program startup.
1069 ``noredzone``
1070     This attribute indicates that the code generator should not use a
1071     red zone, even if the target-specific ABI normally permits it.
1072 ``noreturn``
1073     This function attribute indicates that the function never returns
1074     normally. This produces undefined behavior at runtime if the
1075     function ever does dynamically return.
1076 ``nounwind``
1077     This function attribute indicates that the function never returns
1078     with an unwind or exceptional control flow. If the function does
1079     unwind, its runtime behavior is undefined.
1080 ``optnone``
1081     This function attribute indicates that the function is not optimized
1082     by any optimization or code generator passes with the
1083     exception of interprocedural optimization passes.
1084     This attribute cannot be used together with the ``alwaysinline``
1085     attribute; this attribute is also incompatible
1086     with the ``minsize`` attribute and the ``optsize`` attribute.
1087
1088     This attribute requires the ``noinline`` attribute to be specified on
1089     the function as well, so the function is never inlined into any caller.
1090     Only functions with the ``alwaysinline`` attribute are valid
1091     candidates for inlining into the body of this function.
1092 ``optsize``
1093     This attribute suggests that optimization passes and code generator
1094     passes make choices that keep the code size of this function low,
1095     and otherwise do optimizations specifically to reduce code size as
1096     long as they do not significantly impact runtime performance.
1097 ``readnone``
1098     On a function, this attribute indicates that the function computes its
1099     result (or decides to unwind an exception) based strictly on its arguments,
1100     without dereferencing any pointer arguments or otherwise accessing
1101     any mutable state (e.g. memory, control registers, etc) visible to
1102     caller functions. It does not write through any pointer arguments
1103     (including ``byval`` arguments) and never changes any state visible
1104     to callers. This means that it cannot unwind exceptions by calling
1105     the ``C++`` exception throwing methods.
1106
1107     On an argument, this attribute indicates that the function does not
1108     dereference that pointer argument, even though it may read or write the
1109     memory that the pointer points to if accessed through other pointers.
1110 ``readonly``
1111     On a function, this attribute indicates that the function does not write
1112     through any pointer arguments (including ``byval`` arguments) or otherwise
1113     modify any state (e.g. memory, control registers, etc) visible to
1114     caller functions. It may dereference pointer arguments and read
1115     state that may be set in the caller. A readonly function always
1116     returns the same value (or unwinds an exception identically) when
1117     called with the same set of arguments and global state. It cannot
1118     unwind an exception by calling the ``C++`` exception throwing
1119     methods.
1120
1121     On an argument, this attribute indicates that the function does not write
1122     through this pointer argument, even though it may write to the memory that
1123     the pointer points to.
1124 ``returns_twice``
1125     This attribute indicates that this function can return twice. The C
1126     ``setjmp`` is an example of such a function. The compiler disables
1127     some optimizations (like tail calls) in the caller of these
1128     functions.
1129 ``sanitize_address``
1130     This attribute indicates that AddressSanitizer checks
1131     (dynamic address safety analysis) are enabled for this function.
1132 ``sanitize_memory``
1133     This attribute indicates that MemorySanitizer checks (dynamic detection
1134     of accesses to uninitialized memory) are enabled for this function.
1135 ``sanitize_thread``
1136     This attribute indicates that ThreadSanitizer checks
1137     (dynamic thread safety analysis) are enabled for this function.
1138 ``ssp``
1139     This attribute indicates that the function should emit a stack
1140     smashing protector. It is in the form of a "canary" --- a random value
1141     placed on the stack before the local variables that's checked upon
1142     return from the function to see if it has been overwritten. A
1143     heuristic is used to determine if a function needs stack protectors
1144     or not. The heuristic used will enable protectors for functions with:
1145
1146     - Character arrays larger than ``ssp-buffer-size`` (default 8).
1147     - Aggregates containing character arrays larger than ``ssp-buffer-size``.
1148     - Calls to alloca() with variable sizes or constant sizes greater than
1149       ``ssp-buffer-size``.
1150
1151     Variables that are identified as requiring a protector will be arranged
1152     on the stack such that they are adjacent to the stack protector guard.
1153
1154     If a function that has an ``ssp`` attribute is inlined into a
1155     function that doesn't have an ``ssp`` attribute, then the resulting
1156     function will have an ``ssp`` attribute.
1157 ``sspreq``
1158     This attribute indicates that the function should *always* emit a
1159     stack smashing protector. This overrides the ``ssp`` function
1160     attribute.
1161
1162     Variables that are identified as requiring a protector will be arranged
1163     on the stack such that they are adjacent to the stack protector guard.
1164     The specific layout rules are:
1165
1166     #. Large arrays and structures containing large arrays
1167        (``>= ssp-buffer-size``) are closest to the stack protector.
1168     #. Small arrays and structures containing small arrays
1169        (``< ssp-buffer-size``) are 2nd closest to the protector.
1170     #. Variables that have had their address taken are 3rd closest to the
1171        protector.
1172
1173     If a function that has an ``sspreq`` attribute is inlined into a
1174     function that doesn't have an ``sspreq`` attribute or which has an
1175     ``ssp`` or ``sspstrong`` attribute, then the resulting function will have
1176     an ``sspreq`` attribute.
1177 ``sspstrong``
1178     This attribute indicates that the function should emit a stack smashing
1179     protector. This attribute causes a strong heuristic to be used when
1180     determining if a function needs stack protectors.  The strong heuristic
1181     will enable protectors for functions with:
1182
1183     - Arrays of any size and type
1184     - Aggregates containing an array of any size and type.
1185     - Calls to alloca().
1186     - Local variables that have had their address taken.
1187
1188     Variables that are identified as requiring a protector will be arranged
1189     on the stack such that they are adjacent to the stack protector guard.
1190     The specific layout rules are:
1191
1192     #. Large arrays and structures containing large arrays
1193        (``>= ssp-buffer-size``) are closest to the stack protector.
1194     #. Small arrays and structures containing small arrays
1195        (``< ssp-buffer-size``) are 2nd closest to the protector.
1196     #. Variables that have had their address taken are 3rd closest to the
1197        protector.
1198
1199     This overrides the ``ssp`` function attribute.
1200
1201     If a function that has an ``sspstrong`` attribute is inlined into a
1202     function that doesn't have an ``sspstrong`` attribute, then the
1203     resulting function will have an ``sspstrong`` attribute.
1204 ``uwtable``
1205     This attribute indicates that the ABI being targeted requires that
1206     an unwind table entry be produce for this function even if we can
1207     show that no exceptions passes by it. This is normally the case for
1208     the ELF x86-64 abi, but it can be disabled for some compilation
1209     units.
1210
1211 .. _moduleasm:
1212
1213 Module-Level Inline Assembly
1214 ----------------------------
1215
1216 Modules may contain "module-level inline asm" blocks, which corresponds
1217 to the GCC "file scope inline asm" blocks. These blocks are internally
1218 concatenated by LLVM and treated as a single unit, but may be separated
1219 in the ``.ll`` file if desired. The syntax is very simple:
1220
1221 .. code-block:: llvm
1222
1223     module asm "inline asm code goes here"
1224     module asm "more can go here"
1225
1226 The strings can contain any character by escaping non-printable
1227 characters. The escape sequence used is simply "\\xx" where "xx" is the
1228 two digit hex code for the number.
1229
1230 The inline asm code is simply printed to the machine code .s file when
1231 assembly code is generated.
1232
1233 .. _langref_datalayout:
1234
1235 Data Layout
1236 -----------
1237
1238 A module may specify a target specific data layout string that specifies
1239 how data is to be laid out in memory. The syntax for the data layout is
1240 simply:
1241
1242 .. code-block:: llvm
1243
1244     target datalayout = "layout specification"
1245
1246 The *layout specification* consists of a list of specifications
1247 separated by the minus sign character ('-'). Each specification starts
1248 with a letter and may include other information after the letter to
1249 define some aspect of the data layout. The specifications accepted are
1250 as follows:
1251
1252 ``E``
1253     Specifies that the target lays out data in big-endian form. That is,
1254     the bits with the most significance have the lowest address
1255     location.
1256 ``e``
1257     Specifies that the target lays out data in little-endian form. That
1258     is, the bits with the least significance have the lowest address
1259     location.
1260 ``S<size>``
1261     Specifies the natural alignment of the stack in bits. Alignment
1262     promotion of stack variables is limited to the natural stack
1263     alignment to avoid dynamic stack realignment. The stack alignment
1264     must be a multiple of 8-bits. If omitted, the natural stack
1265     alignment defaults to "unspecified", which does not prevent any
1266     alignment promotions.
1267 ``p[n]:<size>:<abi>:<pref>``
1268     This specifies the *size* of a pointer and its ``<abi>`` and
1269     ``<pref>``\erred alignments for address space ``n``. All sizes are in
1270     bits. The address space, ``n`` is optional, and if not specified,
1271     denotes the default address space 0.  The value of ``n`` must be
1272     in the range [1,2^23).
1273 ``i<size>:<abi>:<pref>``
1274     This specifies the alignment for an integer type of a given bit
1275     ``<size>``. The value of ``<size>`` must be in the range [1,2^23).
1276 ``v<size>:<abi>:<pref>``
1277     This specifies the alignment for a vector type of a given bit
1278     ``<size>``.
1279 ``f<size>:<abi>:<pref>``
1280     This specifies the alignment for a floating point type of a given bit
1281     ``<size>``. Only values of ``<size>`` that are supported by the target
1282     will work. 32 (float) and 64 (double) are supported on all targets; 80
1283     or 128 (different flavors of long double) are also supported on some
1284     targets.
1285 ``a:<abi>:<pref>``
1286     This specifies the alignment for an object of aggregate type.
1287 ``m:<mangling>``
1288     If present, specifies that llvm names are mangled in the output. The
1289     options are
1290
1291     * ``e``: ELF mangling: Private symbols get a ``.L`` prefix.
1292     * ``m``: Mips mangling: Private symbols get a ``$`` prefix.
1293     * ``o``: Mach-O mangling: Private symbols get ``L`` prefix. Other
1294       symbols get a ``_`` prefix.
1295     * ``w``: Windows COFF prefix:  Similar to Mach-O, but stdcall and fastcall
1296       functions also get a suffix based on the frame size.
1297 ``n<size1>:<size2>:<size3>...``
1298     This specifies a set of native integer widths for the target CPU in
1299     bits. For example, it might contain ``n32`` for 32-bit PowerPC,
1300     ``n32:64`` for PowerPC 64, or ``n8:16:32:64`` for X86-64. Elements of
1301     this set are considered to support most general arithmetic operations
1302     efficiently.
1303
1304 On every specification that takes a ``<abi>:<pref>``, specifying the
1305 ``<pref>`` alignment is optional. If omitted, the preceding ``:``
1306 should be omitted too and ``<pref>`` will be equal to ``<abi>``.
1307
1308 When constructing the data layout for a given target, LLVM starts with a
1309 default set of specifications which are then (possibly) overridden by
1310 the specifications in the ``datalayout`` keyword. The default
1311 specifications are given in this list:
1312
1313 -  ``E`` - big endian
1314 -  ``p:64:64:64`` - 64-bit pointers with 64-bit alignment.
1315 -  ``p[n]:64:64:64`` - Other address spaces are assumed to be the
1316    same as the default address space.
1317 -  ``S0`` - natural stack alignment is unspecified
1318 -  ``i1:8:8`` - i1 is 8-bit (byte) aligned
1319 -  ``i8:8:8`` - i8 is 8-bit (byte) aligned
1320 -  ``i16:16:16`` - i16 is 16-bit aligned
1321 -  ``i32:32:32`` - i32 is 32-bit aligned
1322 -  ``i64:32:64`` - i64 has ABI alignment of 32-bits but preferred
1323    alignment of 64-bits
1324 -  ``f16:16:16`` - half is 16-bit aligned
1325 -  ``f32:32:32`` - float is 32-bit aligned
1326 -  ``f64:64:64`` - double is 64-bit aligned
1327 -  ``f128:128:128`` - quad is 128-bit aligned
1328 -  ``v64:64:64`` - 64-bit vector is 64-bit aligned
1329 -  ``v128:128:128`` - 128-bit vector is 128-bit aligned
1330 -  ``a:0:64`` - aggregates are 64-bit aligned
1331
1332 When LLVM is determining the alignment for a given type, it uses the
1333 following rules:
1334
1335 #. If the type sought is an exact match for one of the specifications,
1336    that specification is used.
1337 #. If no match is found, and the type sought is an integer type, then
1338    the smallest integer type that is larger than the bitwidth of the
1339    sought type is used. If none of the specifications are larger than
1340    the bitwidth then the largest integer type is used. For example,
1341    given the default specifications above, the i7 type will use the
1342    alignment of i8 (next largest) while both i65 and i256 will use the
1343    alignment of i64 (largest specified).
1344 #. If no match is found, and the type sought is a vector type, then the
1345    largest vector type that is smaller than the sought vector type will
1346    be used as a fall back. This happens because <128 x double> can be
1347    implemented in terms of 64 <2 x double>, for example.
1348
1349 The function of the data layout string may not be what you expect.
1350 Notably, this is not a specification from the frontend of what alignment
1351 the code generator should use.
1352
1353 Instead, if specified, the target data layout is required to match what
1354 the ultimate *code generator* expects. This string is used by the
1355 mid-level optimizers to improve code, and this only works if it matches
1356 what the ultimate code generator uses. If you would like to generate IR
1357 that does not embed this target-specific detail into the IR, then you
1358 don't have to specify the string. This will disable some optimizations
1359 that require precise layout information, but this also prevents those
1360 optimizations from introducing target specificity into the IR.
1361
1362 .. _langref_triple:
1363
1364 Target Triple
1365 -------------
1366
1367 A module may specify a target triple string that describes the target
1368 host. The syntax for the target triple is simply:
1369
1370 .. code-block:: llvm
1371
1372     target triple = "x86_64-apple-macosx10.7.0"
1373
1374 The *target triple* string consists of a series of identifiers delimited
1375 by the minus sign character ('-'). The canonical forms are:
1376
1377 ::
1378
1379     ARCHITECTURE-VENDOR-OPERATING_SYSTEM
1380     ARCHITECTURE-VENDOR-OPERATING_SYSTEM-ENVIRONMENT
1381
1382 This information is passed along to the backend so that it generates
1383 code for the proper architecture. It's possible to override this on the
1384 command line with the ``-mtriple`` command line option.
1385
1386 .. _pointeraliasing:
1387
1388 Pointer Aliasing Rules
1389 ----------------------
1390
1391 Any memory access must be done through a pointer value associated with
1392 an address range of the memory access, otherwise the behavior is
1393 undefined. Pointer values are associated with address ranges according
1394 to the following rules:
1395
1396 -  A pointer value is associated with the addresses associated with any
1397    value it is *based* on.
1398 -  An address of a global variable is associated with the address range
1399    of the variable's storage.
1400 -  The result value of an allocation instruction is associated with the
1401    address range of the allocated storage.
1402 -  A null pointer in the default address-space is associated with no
1403    address.
1404 -  An integer constant other than zero or a pointer value returned from
1405    a function not defined within LLVM may be associated with address
1406    ranges allocated through mechanisms other than those provided by
1407    LLVM. Such ranges shall not overlap with any ranges of addresses
1408    allocated by mechanisms provided by LLVM.
1409
1410 A pointer value is *based* on another pointer value according to the
1411 following rules:
1412
1413 -  A pointer value formed from a ``getelementptr`` operation is *based*
1414    on the first operand of the ``getelementptr``.
1415 -  The result value of a ``bitcast`` is *based* on the operand of the
1416    ``bitcast``.
1417 -  A pointer value formed by an ``inttoptr`` is *based* on all pointer
1418    values that contribute (directly or indirectly) to the computation of
1419    the pointer's value.
1420 -  The "*based* on" relationship is transitive.
1421
1422 Note that this definition of *"based"* is intentionally similar to the
1423 definition of *"based"* in C99, though it is slightly weaker.
1424
1425 LLVM IR does not associate types with memory. The result type of a
1426 ``load`` merely indicates the size and alignment of the memory from
1427 which to load, as well as the interpretation of the value. The first
1428 operand type of a ``store`` similarly only indicates the size and
1429 alignment of the store.
1430
1431 Consequently, type-based alias analysis, aka TBAA, aka
1432 ``-fstrict-aliasing``, is not applicable to general unadorned LLVM IR.
1433 :ref:`Metadata <metadata>` may be used to encode additional information
1434 which specialized optimization passes may use to implement type-based
1435 alias analysis.
1436
1437 .. _volatile:
1438
1439 Volatile Memory Accesses
1440 ------------------------
1441
1442 Certain memory accesses, such as :ref:`load <i_load>`'s,
1443 :ref:`store <i_store>`'s, and :ref:`llvm.memcpy <int_memcpy>`'s may be
1444 marked ``volatile``. The optimizers must not change the number of
1445 volatile operations or change their order of execution relative to other
1446 volatile operations. The optimizers *may* change the order of volatile
1447 operations relative to non-volatile operations. This is not Java's
1448 "volatile" and has no cross-thread synchronization behavior.
1449
1450 IR-level volatile loads and stores cannot safely be optimized into
1451 llvm.memcpy or llvm.memmove intrinsics even when those intrinsics are
1452 flagged volatile. Likewise, the backend should never split or merge
1453 target-legal volatile load/store instructions.
1454
1455 .. admonition:: Rationale
1456
1457  Platforms may rely on volatile loads and stores of natively supported
1458  data width to be executed as single instruction. For example, in C
1459  this holds for an l-value of volatile primitive type with native
1460  hardware support, but not necessarily for aggregate types. The
1461  frontend upholds these expectations, which are intentionally
1462  unspecified in the IR. The rules above ensure that IR transformation
1463  do not violate the frontend's contract with the language.
1464
1465 .. _memmodel:
1466
1467 Memory Model for Concurrent Operations
1468 --------------------------------------
1469
1470 The LLVM IR does not define any way to start parallel threads of
1471 execution or to register signal handlers. Nonetheless, there are
1472 platform-specific ways to create them, and we define LLVM IR's behavior
1473 in their presence. This model is inspired by the C++0x memory model.
1474
1475 For a more informal introduction to this model, see the :doc:`Atomics`.
1476
1477 We define a *happens-before* partial order as the least partial order
1478 that
1479
1480 -  Is a superset of single-thread program order, and
1481 -  When a *synchronizes-with* ``b``, includes an edge from ``a`` to
1482    ``b``. *Synchronizes-with* pairs are introduced by platform-specific
1483    techniques, like pthread locks, thread creation, thread joining,
1484    etc., and by atomic instructions. (See also :ref:`Atomic Memory Ordering
1485    Constraints <ordering>`).
1486
1487 Note that program order does not introduce *happens-before* edges
1488 between a thread and signals executing inside that thread.
1489
1490 Every (defined) read operation (load instructions, memcpy, atomic
1491 loads/read-modify-writes, etc.) R reads a series of bytes written by
1492 (defined) write operations (store instructions, atomic
1493 stores/read-modify-writes, memcpy, etc.). For the purposes of this
1494 section, initialized globals are considered to have a write of the
1495 initializer which is atomic and happens before any other read or write
1496 of the memory in question. For each byte of a read R, R\ :sub:`byte`
1497 may see any write to the same byte, except:
1498
1499 -  If write\ :sub:`1`  happens before write\ :sub:`2`, and
1500    write\ :sub:`2` happens before R\ :sub:`byte`, then
1501    R\ :sub:`byte` does not see write\ :sub:`1`.
1502 -  If R\ :sub:`byte` happens before write\ :sub:`3`, then
1503    R\ :sub:`byte` does not see write\ :sub:`3`.
1504
1505 Given that definition, R\ :sub:`byte` is defined as follows:
1506
1507 -  If R is volatile, the result is target-dependent. (Volatile is
1508    supposed to give guarantees which can support ``sig_atomic_t`` in
1509    C/C++, and may be used for accesses to addresses which do not behave
1510    like normal memory. It does not generally provide cross-thread
1511    synchronization.)
1512 -  Otherwise, if there is no write to the same byte that happens before
1513    R\ :sub:`byte`, R\ :sub:`byte` returns ``undef`` for that byte.
1514 -  Otherwise, if R\ :sub:`byte` may see exactly one write,
1515    R\ :sub:`byte` returns the value written by that write.
1516 -  Otherwise, if R is atomic, and all the writes R\ :sub:`byte` may
1517    see are atomic, it chooses one of the values written. See the :ref:`Atomic
1518    Memory Ordering Constraints <ordering>` section for additional
1519    constraints on how the choice is made.
1520 -  Otherwise R\ :sub:`byte` returns ``undef``.
1521
1522 R returns the value composed of the series of bytes it read. This
1523 implies that some bytes within the value may be ``undef`` **without**
1524 the entire value being ``undef``. Note that this only defines the
1525 semantics of the operation; it doesn't mean that targets will emit more
1526 than one instruction to read the series of bytes.
1527
1528 Note that in cases where none of the atomic intrinsics are used, this
1529 model places only one restriction on IR transformations on top of what
1530 is required for single-threaded execution: introducing a store to a byte
1531 which might not otherwise be stored is not allowed in general.
1532 (Specifically, in the case where another thread might write to and read
1533 from an address, introducing a store can change a load that may see
1534 exactly one write into a load that may see multiple writes.)
1535
1536 .. _ordering:
1537
1538 Atomic Memory Ordering Constraints
1539 ----------------------------------
1540
1541 Atomic instructions (:ref:`cmpxchg <i_cmpxchg>`,
1542 :ref:`atomicrmw <i_atomicrmw>`, :ref:`fence <i_fence>`,
1543 :ref:`atomic load <i_load>`, and :ref:`atomic store <i_store>`) take
1544 ordering parameters that determine which other atomic instructions on
1545 the same address they *synchronize with*. These semantics are borrowed
1546 from Java and C++0x, but are somewhat more colloquial. If these
1547 descriptions aren't precise enough, check those specs (see spec
1548 references in the :doc:`atomics guide <Atomics>`).
1549 :ref:`fence <i_fence>` instructions treat these orderings somewhat
1550 differently since they don't take an address. See that instruction's
1551 documentation for details.
1552
1553 For a simpler introduction to the ordering constraints, see the
1554 :doc:`Atomics`.
1555
1556 ``unordered``
1557     The set of values that can be read is governed by the happens-before
1558     partial order. A value cannot be read unless some operation wrote
1559     it. This is intended to provide a guarantee strong enough to model
1560     Java's non-volatile shared variables. This ordering cannot be
1561     specified for read-modify-write operations; it is not strong enough
1562     to make them atomic in any interesting way.
1563 ``monotonic``
1564     In addition to the guarantees of ``unordered``, there is a single
1565     total order for modifications by ``monotonic`` operations on each
1566     address. All modification orders must be compatible with the
1567     happens-before order. There is no guarantee that the modification
1568     orders can be combined to a global total order for the whole program
1569     (and this often will not be possible). The read in an atomic
1570     read-modify-write operation (:ref:`cmpxchg <i_cmpxchg>` and
1571     :ref:`atomicrmw <i_atomicrmw>`) reads the value in the modification
1572     order immediately before the value it writes. If one atomic read
1573     happens before another atomic read of the same address, the later
1574     read must see the same value or a later value in the address's
1575     modification order. This disallows reordering of ``monotonic`` (or
1576     stronger) operations on the same address. If an address is written
1577     ``monotonic``-ally by one thread, and other threads ``monotonic``-ally
1578     read that address repeatedly, the other threads must eventually see
1579     the write. This corresponds to the C++0x/C1x
1580     ``memory_order_relaxed``.
1581 ``acquire``
1582     In addition to the guarantees of ``monotonic``, a
1583     *synchronizes-with* edge may be formed with a ``release`` operation.
1584     This is intended to model C++'s ``memory_order_acquire``.
1585 ``release``
1586     In addition to the guarantees of ``monotonic``, if this operation
1587     writes a value which is subsequently read by an ``acquire``
1588     operation, it *synchronizes-with* that operation. (This isn't a
1589     complete description; see the C++0x definition of a release
1590     sequence.) This corresponds to the C++0x/C1x
1591     ``memory_order_release``.
1592 ``acq_rel`` (acquire+release)
1593     Acts as both an ``acquire`` and ``release`` operation on its
1594     address. This corresponds to the C++0x/C1x ``memory_order_acq_rel``.
1595 ``seq_cst`` (sequentially consistent)
1596     In addition to the guarantees of ``acq_rel`` (``acquire`` for an
1597     operation which only reads, ``release`` for an operation which only
1598     writes), there is a global total order on all
1599     sequentially-consistent operations on all addresses, which is
1600     consistent with the *happens-before* partial order and with the
1601     modification orders of all the affected addresses. Each
1602     sequentially-consistent read sees the last preceding write to the
1603     same address in this global order. This corresponds to the C++0x/C1x
1604     ``memory_order_seq_cst`` and Java volatile.
1605
1606 .. _singlethread:
1607
1608 If an atomic operation is marked ``singlethread``, it only *synchronizes
1609 with* or participates in modification and seq\_cst total orderings with
1610 other operations running in the same thread (for example, in signal
1611 handlers).
1612
1613 .. _fastmath:
1614
1615 Fast-Math Flags
1616 ---------------
1617
1618 LLVM IR floating-point binary ops (:ref:`fadd <i_fadd>`,
1619 :ref:`fsub <i_fsub>`, :ref:`fmul <i_fmul>`, :ref:`fdiv <i_fdiv>`,
1620 :ref:`frem <i_frem>`) have the following flags that can set to enable
1621 otherwise unsafe floating point operations
1622
1623 ``nnan``
1624    No NaNs - Allow optimizations to assume the arguments and result are not
1625    NaN. Such optimizations are required to retain defined behavior over
1626    NaNs, but the value of the result is undefined.
1627
1628 ``ninf``
1629    No Infs - Allow optimizations to assume the arguments and result are not
1630    +/-Inf. Such optimizations are required to retain defined behavior over
1631    +/-Inf, but the value of the result is undefined.
1632
1633 ``nsz``
1634    No Signed Zeros - Allow optimizations to treat the sign of a zero
1635    argument or result as insignificant.
1636
1637 ``arcp``
1638    Allow Reciprocal - Allow optimizations to use the reciprocal of an
1639    argument rather than perform division.
1640
1641 ``fast``
1642    Fast - Allow algebraically equivalent transformations that may
1643    dramatically change results in floating point (e.g. reassociate). This
1644    flag implies all the others.
1645
1646 .. _typesystem:
1647
1648 Type System
1649 ===========
1650
1651 The LLVM type system is one of the most important features of the
1652 intermediate representation. Being typed enables a number of
1653 optimizations to be performed on the intermediate representation
1654 directly, without having to do extra analyses on the side before the
1655 transformation. A strong type system makes it easier to read the
1656 generated code and enables novel analyses and transformations that are
1657 not feasible to perform on normal three address code representations.
1658
1659 .. _t_void:
1660
1661 Void Type
1662 ---------
1663
1664 :Overview:
1665
1666
1667 The void type does not represent any value and has no size.
1668
1669 :Syntax:
1670
1671
1672 ::
1673
1674       void
1675
1676
1677 .. _t_function:
1678
1679 Function Type
1680 -------------
1681
1682 :Overview:
1683
1684
1685 The function type can be thought of as a function signature. It consists of a
1686 return type and a list of formal parameter types. The return type of a function
1687 type is a void type or first class type --- except for :ref:`label <t_label>`
1688 and :ref:`metadata <t_metadata>` types.
1689
1690 :Syntax:
1691
1692 ::
1693
1694       <returntype> (<parameter list>)
1695
1696 ...where '``<parameter list>``' is a comma-separated list of type
1697 specifiers. Optionally, the parameter list may include a type ``...``, which
1698 indicates that the function takes a variable number of arguments.  Variable
1699 argument functions can access their arguments with the :ref:`variable argument
1700 handling intrinsic <int_varargs>` functions.  '``<returntype>``' is any type
1701 except :ref:`label <t_label>` and :ref:`metadata <t_metadata>`.
1702
1703 :Examples:
1704
1705 +---------------------------------+---------------------------------------------------------------------------------------------------------------------------------------------------------------------+
1706 | ``i32 (i32)``                   | function taking an ``i32``, returning an ``i32``                                                                                                                    |
1707 +---------------------------------+---------------------------------------------------------------------------------------------------------------------------------------------------------------------+
1708 | ``float (i16, i32 *) *``        | :ref:`Pointer <t_pointer>` to a function that takes an ``i16`` and a :ref:`pointer <t_pointer>` to ``i32``, returning ``float``.                                    |
1709 +---------------------------------+---------------------------------------------------------------------------------------------------------------------------------------------------------------------+
1710 | ``i32 (i8*, ...)``              | A vararg function that takes at least one :ref:`pointer <t_pointer>` to ``i8`` (char in C), which returns an integer. This is the signature for ``printf`` in LLVM. |
1711 +---------------------------------+---------------------------------------------------------------------------------------------------------------------------------------------------------------------+
1712 | ``{i32, i32} (i32)``            | A function taking an ``i32``, returning a :ref:`structure <t_struct>` containing two ``i32`` values                                                                 |
1713 +---------------------------------+---------------------------------------------------------------------------------------------------------------------------------------------------------------------+
1714
1715 .. _t_firstclass:
1716
1717 First Class Types
1718 -----------------
1719
1720 The :ref:`first class <t_firstclass>` types are perhaps the most important.
1721 Values of these types are the only ones which can be produced by
1722 instructions.
1723
1724 .. _t_single_value:
1725
1726 Single Value Types
1727 ^^^^^^^^^^^^^^^^^^
1728
1729 These are the types that are valid in registers from CodeGen's perspective.
1730
1731 .. _t_integer:
1732
1733 Integer Type
1734 """"""""""""
1735
1736 :Overview:
1737
1738 The integer type is a very simple type that simply specifies an
1739 arbitrary bit width for the integer type desired. Any bit width from 1
1740 bit to 2\ :sup:`23`\ -1 (about 8 million) can be specified.
1741
1742 :Syntax:
1743
1744 ::
1745
1746       iN
1747
1748 The number of bits the integer will occupy is specified by the ``N``
1749 value.
1750
1751 Examples:
1752 *********
1753
1754 +----------------+------------------------------------------------+
1755 | ``i1``         | a single-bit integer.                          |
1756 +----------------+------------------------------------------------+
1757 | ``i32``        | a 32-bit integer.                              |
1758 +----------------+------------------------------------------------+
1759 | ``i1942652``   | a really big integer of over 1 million bits.   |
1760 +----------------+------------------------------------------------+
1761
1762 .. _t_floating:
1763
1764 Floating Point Types
1765 """"""""""""""""""""
1766
1767 .. list-table::
1768    :header-rows: 1
1769
1770    * - Type
1771      - Description
1772
1773    * - ``half``
1774      - 16-bit floating point value
1775
1776    * - ``float``
1777      - 32-bit floating point value
1778
1779    * - ``double``
1780      - 64-bit floating point value
1781
1782    * - ``fp128``
1783      - 128-bit floating point value (112-bit mantissa)
1784
1785    * - ``x86_fp80``
1786      -  80-bit floating point value (X87)
1787
1788    * - ``ppc_fp128``
1789      - 128-bit floating point value (two 64-bits)
1790
1791 X86_mmx Type
1792 """"""""""""
1793
1794 :Overview:
1795
1796 The x86_mmx type represents a value held in an MMX register on an x86
1797 machine. The operations allowed on it are quite limited: parameters and
1798 return values, load and store, and bitcast. User-specified MMX
1799 instructions are represented as intrinsic or asm calls with arguments
1800 and/or results of this type. There are no arrays, vectors or constants
1801 of this type.
1802
1803 :Syntax:
1804
1805 ::
1806
1807       x86_mmx
1808
1809
1810 .. _t_pointer:
1811
1812 Pointer Type
1813 """"""""""""
1814
1815 :Overview:
1816
1817 The pointer type is used to specify memory locations. Pointers are
1818 commonly used to reference objects in memory.
1819
1820 Pointer types may have an optional address space attribute defining the
1821 numbered address space where the pointed-to object resides. The default
1822 address space is number zero. The semantics of non-zero address spaces
1823 are target-specific.
1824
1825 Note that LLVM does not permit pointers to void (``void*``) nor does it
1826 permit pointers to labels (``label*``). Use ``i8*`` instead.
1827
1828 :Syntax:
1829
1830 ::
1831
1832       <type> *
1833
1834 :Examples:
1835
1836 +-------------------------+--------------------------------------------------------------------------------------------------------------+
1837 | ``[4 x i32]*``          | A :ref:`pointer <t_pointer>` to :ref:`array <t_array>` of four ``i32`` values.                               |
1838 +-------------------------+--------------------------------------------------------------------------------------------------------------+
1839 | ``i32 (i32*) *``        | A :ref:`pointer <t_pointer>` to a :ref:`function <t_function>` that takes an ``i32*``, returning an ``i32``. |
1840 +-------------------------+--------------------------------------------------------------------------------------------------------------+
1841 | ``i32 addrspace(5)*``   | A :ref:`pointer <t_pointer>` to an ``i32`` value that resides in address space #5.                           |
1842 +-------------------------+--------------------------------------------------------------------------------------------------------------+
1843
1844 .. _t_vector:
1845
1846 Vector Type
1847 """""""""""
1848
1849 :Overview:
1850
1851 A vector type is a simple derived type that represents a vector of
1852 elements. Vector types are used when multiple primitive data are
1853 operated in parallel using a single instruction (SIMD). A vector type
1854 requires a size (number of elements) and an underlying primitive data
1855 type. Vector types are considered :ref:`first class <t_firstclass>`.
1856
1857 :Syntax:
1858
1859 ::
1860
1861       < <# elements> x <elementtype> >
1862
1863 The number of elements is a constant integer value larger than 0;
1864 elementtype may be any integer or floating point type, or a pointer to
1865 these types. Vectors of size zero are not allowed.
1866
1867 :Examples:
1868
1869 +-------------------+--------------------------------------------------+
1870 | ``<4 x i32>``     | Vector of 4 32-bit integer values.               |
1871 +-------------------+--------------------------------------------------+
1872 | ``<8 x float>``   | Vector of 8 32-bit floating-point values.        |
1873 +-------------------+--------------------------------------------------+
1874 | ``<2 x i64>``     | Vector of 2 64-bit integer values.               |
1875 +-------------------+--------------------------------------------------+
1876 | ``<4 x i64*>``    | Vector of 4 pointers to 64-bit integer values.   |
1877 +-------------------+--------------------------------------------------+
1878
1879 .. _t_label:
1880
1881 Label Type
1882 ^^^^^^^^^^
1883
1884 :Overview:
1885
1886 The label type represents code labels.
1887
1888 :Syntax:
1889
1890 ::
1891
1892       label
1893
1894 .. _t_metadata:
1895
1896 Metadata Type
1897 ^^^^^^^^^^^^^
1898
1899 :Overview:
1900
1901 The metadata type represents embedded metadata. No derived types may be
1902 created from metadata except for :ref:`function <t_function>` arguments.
1903
1904 :Syntax:
1905
1906 ::
1907
1908       metadata
1909
1910 .. _t_aggregate:
1911
1912 Aggregate Types
1913 ^^^^^^^^^^^^^^^
1914
1915 Aggregate Types are a subset of derived types that can contain multiple
1916 member types. :ref:`Arrays <t_array>` and :ref:`structs <t_struct>` are
1917 aggregate types. :ref:`Vectors <t_vector>` are not considered to be
1918 aggregate types.
1919
1920 .. _t_array:
1921
1922 Array Type
1923 """"""""""
1924
1925 :Overview:
1926
1927 The array type is a very simple derived type that arranges elements
1928 sequentially in memory. The array type requires a size (number of
1929 elements) and an underlying data type.
1930
1931 :Syntax:
1932
1933 ::
1934
1935       [<# elements> x <elementtype>]
1936
1937 The number of elements is a constant integer value; ``elementtype`` may
1938 be any type with a size.
1939
1940 :Examples:
1941
1942 +------------------+--------------------------------------+
1943 | ``[40 x i32]``   | Array of 40 32-bit integer values.   |
1944 +------------------+--------------------------------------+
1945 | ``[41 x i32]``   | Array of 41 32-bit integer values.   |
1946 +------------------+--------------------------------------+
1947 | ``[4 x i8]``     | Array of 4 8-bit integer values.     |
1948 +------------------+--------------------------------------+
1949
1950 Here are some examples of multidimensional arrays:
1951
1952 +-----------------------------+----------------------------------------------------------+
1953 | ``[3 x [4 x i32]]``         | 3x4 array of 32-bit integer values.                      |
1954 +-----------------------------+----------------------------------------------------------+
1955 | ``[12 x [10 x float]]``     | 12x10 array of single precision floating point values.   |
1956 +-----------------------------+----------------------------------------------------------+
1957 | ``[2 x [3 x [4 x i16]]]``   | 2x3x4 array of 16-bit integer values.                    |
1958 +-----------------------------+----------------------------------------------------------+
1959
1960 There is no restriction on indexing beyond the end of the array implied
1961 by a static type (though there are restrictions on indexing beyond the
1962 bounds of an allocated object in some cases). This means that
1963 single-dimension 'variable sized array' addressing can be implemented in
1964 LLVM with a zero length array type. An implementation of 'pascal style
1965 arrays' in LLVM could use the type "``{ i32, [0 x float]}``", for
1966 example.
1967
1968 .. _t_struct:
1969
1970 Structure Type
1971 """"""""""""""
1972
1973 :Overview:
1974
1975 The structure type is used to represent a collection of data members
1976 together in memory. The elements of a structure may be any type that has
1977 a size.
1978
1979 Structures in memory are accessed using '``load``' and '``store``' by
1980 getting a pointer to a field with the '``getelementptr``' instruction.
1981 Structures in registers are accessed using the '``extractvalue``' and
1982 '``insertvalue``' instructions.
1983
1984 Structures may optionally be "packed" structures, which indicate that
1985 the alignment of the struct is one byte, and that there is no padding
1986 between the elements. In non-packed structs, padding between field types
1987 is inserted as defined by the DataLayout string in the module, which is
1988 required to match what the underlying code generator expects.
1989
1990 Structures can either be "literal" or "identified". A literal structure
1991 is defined inline with other types (e.g. ``{i32, i32}*``) whereas
1992 identified types are always defined at the top level with a name.
1993 Literal types are uniqued by their contents and can never be recursive
1994 or opaque since there is no way to write one. Identified types can be
1995 recursive, can be opaqued, and are never uniqued.
1996
1997 :Syntax:
1998
1999 ::
2000
2001       %T1 = type { <type list> }     ; Identified normal struct type
2002       %T2 = type <{ <type list> }>   ; Identified packed struct type
2003
2004 :Examples:
2005
2006 +------------------------------+---------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------+
2007 | ``{ i32, i32, i32 }``        | A triple of three ``i32`` values                                                                                                                                                      |
2008 +------------------------------+---------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------+
2009 | ``{ float, i32 (i32) * }``   | A pair, where the first element is a ``float`` and the second element is a :ref:`pointer <t_pointer>` to a :ref:`function <t_function>` that takes an ``i32``, returning an ``i32``.  |
2010 +------------------------------+---------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------+
2011 | ``<{ i8, i32 }>``            | A packed struct known to be 5 bytes in size.                                                                                                                                          |
2012 +------------------------------+---------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------+
2013
2014 .. _t_opaque:
2015
2016 Opaque Structure Types
2017 """"""""""""""""""""""
2018
2019 :Overview:
2020
2021 Opaque structure types are used to represent named structure types that
2022 do not have a body specified. This corresponds (for example) to the C
2023 notion of a forward declared structure.
2024
2025 :Syntax:
2026
2027 ::
2028
2029       %X = type opaque
2030       %52 = type opaque
2031
2032 :Examples:
2033
2034 +--------------+-------------------+
2035 | ``opaque``   | An opaque type.   |
2036 +--------------+-------------------+
2037
2038 .. _constants:
2039
2040 Constants
2041 =========
2042
2043 LLVM has several different basic types of constants. This section
2044 describes them all and their syntax.
2045
2046 Simple Constants
2047 ----------------
2048
2049 **Boolean constants**
2050     The two strings '``true``' and '``false``' are both valid constants
2051     of the ``i1`` type.
2052 **Integer constants**
2053     Standard integers (such as '4') are constants of the
2054     :ref:`integer <t_integer>` type. Negative numbers may be used with
2055     integer types.
2056 **Floating point constants**
2057     Floating point constants use standard decimal notation (e.g.
2058     123.421), exponential notation (e.g. 1.23421e+2), or a more precise
2059     hexadecimal notation (see below). The assembler requires the exact
2060     decimal value of a floating-point constant. For example, the
2061     assembler accepts 1.25 but rejects 1.3 because 1.3 is a repeating
2062     decimal in binary. Floating point constants must have a :ref:`floating
2063     point <t_floating>` type.
2064 **Null pointer constants**
2065     The identifier '``null``' is recognized as a null pointer constant
2066     and must be of :ref:`pointer type <t_pointer>`.
2067
2068 The one non-intuitive notation for constants is the hexadecimal form of
2069 floating point constants. For example, the form
2070 '``double    0x432ff973cafa8000``' is equivalent to (but harder to read
2071 than) '``double 4.5e+15``'. The only time hexadecimal floating point
2072 constants are required (and the only time that they are generated by the
2073 disassembler) is when a floating point constant must be emitted but it
2074 cannot be represented as a decimal floating point number in a reasonable
2075 number of digits. For example, NaN's, infinities, and other special
2076 values are represented in their IEEE hexadecimal format so that assembly
2077 and disassembly do not cause any bits to change in the constants.
2078
2079 When using the hexadecimal form, constants of types half, float, and
2080 double are represented using the 16-digit form shown above (which
2081 matches the IEEE754 representation for double); half and float values
2082 must, however, be exactly representable as IEEE 754 half and single
2083 precision, respectively. Hexadecimal format is always used for long
2084 double, and there are three forms of long double. The 80-bit format used
2085 by x86 is represented as ``0xK`` followed by 20 hexadecimal digits. The
2086 128-bit format used by PowerPC (two adjacent doubles) is represented by
2087 ``0xM`` followed by 32 hexadecimal digits. The IEEE 128-bit format is
2088 represented by ``0xL`` followed by 32 hexadecimal digits. Long doubles
2089 will only work if they match the long double format on your target.
2090 The IEEE 16-bit format (half precision) is represented by ``0xH``
2091 followed by 4 hexadecimal digits. All hexadecimal formats are big-endian
2092 (sign bit at the left).
2093
2094 There are no constants of type x86_mmx.
2095
2096 .. _complexconstants:
2097
2098 Complex Constants
2099 -----------------
2100
2101 Complex constants are a (potentially recursive) combination of simple
2102 constants and smaller complex constants.
2103
2104 **Structure constants**
2105     Structure constants are represented with notation similar to
2106     structure type definitions (a comma separated list of elements,
2107     surrounded by braces (``{}``)). For example:
2108     "``{ i32 4, float 17.0, i32* @G }``", where "``@G``" is declared as
2109     "``@G = external global i32``". Structure constants must have
2110     :ref:`structure type <t_struct>`, and the number and types of elements
2111     must match those specified by the type.
2112 **Array constants**
2113     Array constants are represented with notation similar to array type
2114     definitions (a comma separated list of elements, surrounded by
2115     square brackets (``[]``)). For example:
2116     "``[ i32 42, i32 11, i32 74 ]``". Array constants must have
2117     :ref:`array type <t_array>`, and the number and types of elements must
2118     match those specified by the type.
2119 **Vector constants**
2120     Vector constants are represented with notation similar to vector
2121     type definitions (a comma separated list of elements, surrounded by
2122     less-than/greater-than's (``<>``)). For example:
2123     "``< i32 42, i32 11, i32 74, i32 100 >``". Vector constants
2124     must have :ref:`vector type <t_vector>`, and the number and types of
2125     elements must match those specified by the type.
2126 **Zero initialization**
2127     The string '``zeroinitializer``' can be used to zero initialize a
2128     value to zero of *any* type, including scalar and
2129     :ref:`aggregate <t_aggregate>` types. This is often used to avoid
2130     having to print large zero initializers (e.g. for large arrays) and
2131     is always exactly equivalent to using explicit zero initializers.
2132 **Metadata node**
2133     A metadata node is a structure-like constant with :ref:`metadata
2134     type <t_metadata>`. For example:
2135     "``metadata !{ i32 0, metadata !"test" }``". Unlike other
2136     constants that are meant to be interpreted as part of the
2137     instruction stream, metadata is a place to attach additional
2138     information such as debug info.
2139
2140 Global Variable and Function Addresses
2141 --------------------------------------
2142
2143 The addresses of :ref:`global variables <globalvars>` and
2144 :ref:`functions <functionstructure>` are always implicitly valid
2145 (link-time) constants. These constants are explicitly referenced when
2146 the :ref:`identifier for the global <identifiers>` is used and always have
2147 :ref:`pointer <t_pointer>` type. For example, the following is a legal LLVM
2148 file:
2149
2150 .. code-block:: llvm
2151
2152     @X = global i32 17
2153     @Y = global i32 42
2154     @Z = global [2 x i32*] [ i32* @X, i32* @Y ]
2155
2156 .. _undefvalues:
2157
2158 Undefined Values
2159 ----------------
2160
2161 The string '``undef``' can be used anywhere a constant is expected, and
2162 indicates that the user of the value may receive an unspecified
2163 bit-pattern. Undefined values may be of any type (other than '``label``'
2164 or '``void``') and be used anywhere a constant is permitted.
2165
2166 Undefined values are useful because they indicate to the compiler that
2167 the program is well defined no matter what value is used. This gives the
2168 compiler more freedom to optimize. Here are some examples of
2169 (potentially surprising) transformations that are valid (in pseudo IR):
2170
2171 .. code-block:: llvm
2172
2173       %A = add %X, undef
2174       %B = sub %X, undef
2175       %C = xor %X, undef
2176     Safe:
2177       %A = undef
2178       %B = undef
2179       %C = undef
2180
2181 This is safe because all of the output bits are affected by the undef
2182 bits. Any output bit can have a zero or one depending on the input bits.
2183
2184 .. code-block:: llvm
2185
2186       %A = or %X, undef
2187       %B = and %X, undef
2188     Safe:
2189       %A = -1
2190       %B = 0
2191     Unsafe:
2192       %A = undef
2193       %B = undef
2194
2195 These logical operations have bits that are not always affected by the
2196 input. For example, if ``%X`` has a zero bit, then the output of the
2197 '``and``' operation will always be a zero for that bit, no matter what
2198 the corresponding bit from the '``undef``' is. As such, it is unsafe to
2199 optimize or assume that the result of the '``and``' is '``undef``'.
2200 However, it is safe to assume that all bits of the '``undef``' could be
2201 0, and optimize the '``and``' to 0. Likewise, it is safe to assume that
2202 all the bits of the '``undef``' operand to the '``or``' could be set,
2203 allowing the '``or``' to be folded to -1.
2204
2205 .. code-block:: llvm
2206
2207       %A = select undef, %X, %Y
2208       %B = select undef, 42, %Y
2209       %C = select %X, %Y, undef
2210     Safe:
2211       %A = %X     (or %Y)
2212       %B = 42     (or %Y)
2213       %C = %Y
2214     Unsafe:
2215       %A = undef
2216       %B = undef
2217       %C = undef
2218
2219 This set of examples shows that undefined '``select``' (and conditional
2220 branch) conditions can go *either way*, but they have to come from one
2221 of the two operands. In the ``%A`` example, if ``%X`` and ``%Y`` were
2222 both known to have a clear low bit, then ``%A`` would have to have a
2223 cleared low bit. However, in the ``%C`` example, the optimizer is
2224 allowed to assume that the '``undef``' operand could be the same as
2225 ``%Y``, allowing the whole '``select``' to be eliminated.
2226
2227 .. code-block:: llvm
2228
2229       %A = xor undef, undef
2230
2231       %B = undef
2232       %C = xor %B, %B
2233
2234       %D = undef
2235       %E = icmp lt %D, 4
2236       %F = icmp gte %D, 4
2237
2238     Safe:
2239       %A = undef
2240       %B = undef
2241       %C = undef
2242       %D = undef
2243       %E = undef
2244       %F = undef
2245
2246 This example points out that two '``undef``' operands are not
2247 necessarily the same. This can be surprising to people (and also matches
2248 C semantics) where they assume that "``X^X``" is always zero, even if
2249 ``X`` is undefined. This isn't true for a number of reasons, but the
2250 short answer is that an '``undef``' "variable" can arbitrarily change
2251 its value over its "live range". This is true because the variable
2252 doesn't actually *have a live range*. Instead, the value is logically
2253 read from arbitrary registers that happen to be around when needed, so
2254 the value is not necessarily consistent over time. In fact, ``%A`` and
2255 ``%C`` need to have the same semantics or the core LLVM "replace all
2256 uses with" concept would not hold.
2257
2258 .. code-block:: llvm
2259
2260       %A = fdiv undef, %X
2261       %B = fdiv %X, undef
2262     Safe:
2263       %A = undef
2264     b: unreachable
2265
2266 These examples show the crucial difference between an *undefined value*
2267 and *undefined behavior*. An undefined value (like '``undef``') is
2268 allowed to have an arbitrary bit-pattern. This means that the ``%A``
2269 operation can be constant folded to '``undef``', because the '``undef``'
2270 could be an SNaN, and ``fdiv`` is not (currently) defined on SNaN's.
2271 However, in the second example, we can make a more aggressive
2272 assumption: because the ``undef`` is allowed to be an arbitrary value,
2273 we are allowed to assume that it could be zero. Since a divide by zero
2274 has *undefined behavior*, we are allowed to assume that the operation
2275 does not execute at all. This allows us to delete the divide and all
2276 code after it. Because the undefined operation "can't happen", the
2277 optimizer can assume that it occurs in dead code.
2278
2279 .. code-block:: llvm
2280
2281     a:  store undef -> %X
2282     b:  store %X -> undef
2283     Safe:
2284     a: <deleted>
2285     b: unreachable
2286
2287 These examples reiterate the ``fdiv`` example: a store *of* an undefined
2288 value can be assumed to not have any effect; we can assume that the
2289 value is overwritten with bits that happen to match what was already
2290 there. However, a store *to* an undefined location could clobber
2291 arbitrary memory, therefore, it has undefined behavior.
2292
2293 .. _poisonvalues:
2294
2295 Poison Values
2296 -------------
2297
2298 Poison values are similar to :ref:`undef values <undefvalues>`, however
2299 they also represent the fact that an instruction or constant expression
2300 which cannot evoke side effects has nevertheless detected a condition
2301 which results in undefined behavior.
2302
2303 There is currently no way of representing a poison value in the IR; they
2304 only exist when produced by operations such as :ref:`add <i_add>` with
2305 the ``nsw`` flag.
2306
2307 Poison value behavior is defined in terms of value *dependence*:
2308
2309 -  Values other than :ref:`phi <i_phi>` nodes depend on their operands.
2310 -  :ref:`Phi <i_phi>` nodes depend on the operand corresponding to
2311    their dynamic predecessor basic block.
2312 -  Function arguments depend on the corresponding actual argument values
2313    in the dynamic callers of their functions.
2314 -  :ref:`Call <i_call>` instructions depend on the :ref:`ret <i_ret>`
2315    instructions that dynamically transfer control back to them.
2316 -  :ref:`Invoke <i_invoke>` instructions depend on the
2317    :ref:`ret <i_ret>`, :ref:`resume <i_resume>`, or exception-throwing
2318    call instructions that dynamically transfer control back to them.
2319 -  Non-volatile loads and stores depend on the most recent stores to all
2320    of the referenced memory addresses, following the order in the IR
2321    (including loads and stores implied by intrinsics such as
2322    :ref:`@llvm.memcpy <int_memcpy>`.)
2323 -  An instruction with externally visible side effects depends on the
2324    most recent preceding instruction with externally visible side
2325    effects, following the order in the IR. (This includes :ref:`volatile
2326    operations <volatile>`.)
2327 -  An instruction *control-depends* on a :ref:`terminator
2328    instruction <terminators>` if the terminator instruction has
2329    multiple successors and the instruction is always executed when
2330    control transfers to one of the successors, and may not be executed
2331    when control is transferred to another.
2332 -  Additionally, an instruction also *control-depends* on a terminator
2333    instruction if the set of instructions it otherwise depends on would
2334    be different if the terminator had transferred control to a different
2335    successor.
2336 -  Dependence is transitive.
2337
2338 Poison Values have the same behavior as :ref:`undef values <undefvalues>`,
2339 with the additional affect that any instruction which has a *dependence*
2340 on a poison value has undefined behavior.
2341
2342 Here are some examples:
2343
2344 .. code-block:: llvm
2345
2346     entry:
2347       %poison = sub nuw i32 0, 1           ; Results in a poison value.
2348       %still_poison = and i32 %poison, 0   ; 0, but also poison.
2349       %poison_yet_again = getelementptr i32* @h, i32 %still_poison
2350       store i32 0, i32* %poison_yet_again  ; memory at @h[0] is poisoned
2351
2352       store i32 %poison, i32* @g           ; Poison value stored to memory.
2353       %poison2 = load i32* @g              ; Poison value loaded back from memory.
2354
2355       store volatile i32 %poison, i32* @g  ; External observation; undefined behavior.
2356
2357       %narrowaddr = bitcast i32* @g to i16*
2358       %wideaddr = bitcast i32* @g to i64*
2359       %poison3 = load i16* %narrowaddr     ; Returns a poison value.
2360       %poison4 = load i64* %wideaddr       ; Returns a poison value.
2361
2362       %cmp = icmp slt i32 %poison, 0       ; Returns a poison value.
2363       br i1 %cmp, label %true, label %end  ; Branch to either destination.
2364
2365     true:
2366       store volatile i32 0, i32* @g        ; This is control-dependent on %cmp, so
2367                                            ; it has undefined behavior.
2368       br label %end
2369
2370     end:
2371       %p = phi i32 [ 0, %entry ], [ 1, %true ]
2372                                            ; Both edges into this PHI are
2373                                            ; control-dependent on %cmp, so this
2374                                            ; always results in a poison value.
2375
2376       store volatile i32 0, i32* @g        ; This would depend on the store in %true
2377                                            ; if %cmp is true, or the store in %entry
2378                                            ; otherwise, so this is undefined behavior.
2379
2380       br i1 %cmp, label %second_true, label %second_end
2381                                            ; The same branch again, but this time the
2382                                            ; true block doesn't have side effects.
2383
2384     second_true:
2385       ; No side effects!
2386       ret void
2387
2388     second_end:
2389       store volatile i32 0, i32* @g        ; This time, the instruction always depends
2390                                            ; on the store in %end. Also, it is
2391                                            ; control-equivalent to %end, so this is
2392                                            ; well-defined (ignoring earlier undefined
2393                                            ; behavior in this example).
2394
2395 .. _blockaddress:
2396
2397 Addresses of Basic Blocks
2398 -------------------------
2399
2400 ``blockaddress(@function, %block)``
2401
2402 The '``blockaddress``' constant computes the address of the specified
2403 basic block in the specified function, and always has an ``i8*`` type.
2404 Taking the address of the entry block is illegal.
2405
2406 This value only has defined behavior when used as an operand to the
2407 ':ref:`indirectbr <i_indirectbr>`' instruction, or for comparisons
2408 against null. Pointer equality tests between labels addresses results in
2409 undefined behavior --- though, again, comparison against null is ok, and
2410 no label is equal to the null pointer. This may be passed around as an
2411 opaque pointer sized value as long as the bits are not inspected. This
2412 allows ``ptrtoint`` and arithmetic to be performed on these values so
2413 long as the original value is reconstituted before the ``indirectbr``
2414 instruction.
2415
2416 Finally, some targets may provide defined semantics when using the value
2417 as the operand to an inline assembly, but that is target specific.
2418
2419 .. _constantexprs:
2420
2421 Constant Expressions
2422 --------------------
2423
2424 Constant expressions are used to allow expressions involving other
2425 constants to be used as constants. Constant expressions may be of any
2426 :ref:`first class <t_firstclass>` type and may involve any LLVM operation
2427 that does not have side effects (e.g. load and call are not supported).
2428 The following is the syntax for constant expressions:
2429
2430 ``trunc (CST to TYPE)``
2431     Truncate a constant to another type. The bit size of CST must be
2432     larger than the bit size of TYPE. Both types must be integers.
2433 ``zext (CST to TYPE)``
2434     Zero extend a constant to another type. The bit size of CST must be
2435     smaller than the bit size of TYPE. Both types must be integers.
2436 ``sext (CST to TYPE)``
2437     Sign extend a constant to another type. The bit size of CST must be
2438     smaller than the bit size of TYPE. Both types must be integers.
2439 ``fptrunc (CST to TYPE)``
2440     Truncate a floating point constant to another floating point type.
2441     The size of CST must be larger than the size of TYPE. Both types
2442     must be floating point.
2443 ``fpext (CST to TYPE)``
2444     Floating point extend a constant to another type. The size of CST
2445     must be smaller or equal to the size of TYPE. Both types must be
2446     floating point.
2447 ``fptoui (CST to TYPE)``
2448     Convert a floating point constant to the corresponding unsigned
2449     integer constant. TYPE must be a scalar or vector integer type. CST
2450     must be of scalar or vector floating point type. Both CST and TYPE
2451     must be scalars, or vectors of the same number of elements. If the
2452     value won't fit in the integer type, the results are undefined.
2453 ``fptosi (CST to TYPE)``
2454     Convert a floating point constant to the corresponding signed
2455     integer constant. TYPE must be a scalar or vector integer type. CST
2456     must be of scalar or vector floating point type. Both CST and TYPE
2457     must be scalars, or vectors of the same number of elements. If the
2458     value won't fit in the integer type, the results are undefined.
2459 ``uitofp (CST to TYPE)``
2460     Convert an unsigned integer constant to the corresponding floating
2461     point constant. TYPE must be a scalar or vector floating point type.
2462     CST must be of scalar or vector integer type. Both CST and TYPE must
2463     be scalars, or vectors of the same number of elements. If the value
2464     won't fit in the floating point type, the results are undefined.
2465 ``sitofp (CST to TYPE)``
2466     Convert a signed integer constant to the corresponding floating
2467     point constant. TYPE must be a scalar or vector floating point type.
2468     CST must be of scalar or vector integer type. Both CST and TYPE must
2469     be scalars, or vectors of the same number of elements. If the value
2470     won't fit in the floating point type, the results are undefined.
2471 ``ptrtoint (CST to TYPE)``
2472     Convert a pointer typed constant to the corresponding integer
2473     constant. ``TYPE`` must be an integer type. ``CST`` must be of
2474     pointer type. The ``CST`` value is zero extended, truncated, or
2475     unchanged to make it fit in ``TYPE``.
2476 ``inttoptr (CST to TYPE)``
2477     Convert an integer constant to a pointer constant. TYPE must be a
2478     pointer type. CST must be of integer type. The CST value is zero
2479     extended, truncated, or unchanged to make it fit in a pointer size.
2480     This one is *really* dangerous!
2481 ``bitcast (CST to TYPE)``
2482     Convert a constant, CST, to another TYPE. The constraints of the
2483     operands are the same as those for the :ref:`bitcast
2484     instruction <i_bitcast>`.
2485 ``addrspacecast (CST to TYPE)``
2486     Convert a constant pointer or constant vector of pointer, CST, to another
2487     TYPE in a different address space. The constraints of the operands are the
2488     same as those for the :ref:`addrspacecast instruction <i_addrspacecast>`.
2489 ``getelementptr (CSTPTR, IDX0, IDX1, ...)``, ``getelementptr inbounds (CSTPTR, IDX0, IDX1, ...)``
2490     Perform the :ref:`getelementptr operation <i_getelementptr>` on
2491     constants. As with the :ref:`getelementptr <i_getelementptr>`
2492     instruction, the index list may have zero or more indexes, which are
2493     required to make sense for the type of "CSTPTR".
2494 ``select (COND, VAL1, VAL2)``
2495     Perform the :ref:`select operation <i_select>` on constants.
2496 ``icmp COND (VAL1, VAL2)``
2497     Performs the :ref:`icmp operation <i_icmp>` on constants.
2498 ``fcmp COND (VAL1, VAL2)``
2499     Performs the :ref:`fcmp operation <i_fcmp>` on constants.
2500 ``extractelement (VAL, IDX)``
2501     Perform the :ref:`extractelement operation <i_extractelement>` on
2502     constants.
2503 ``insertelement (VAL, ELT, IDX)``
2504     Perform the :ref:`insertelement operation <i_insertelement>` on
2505     constants.
2506 ``shufflevector (VEC1, VEC2, IDXMASK)``
2507     Perform the :ref:`shufflevector operation <i_shufflevector>` on
2508     constants.
2509 ``extractvalue (VAL, IDX0, IDX1, ...)``
2510     Perform the :ref:`extractvalue operation <i_extractvalue>` on
2511     constants. The index list is interpreted in a similar manner as
2512     indices in a ':ref:`getelementptr <i_getelementptr>`' operation. At
2513     least one index value must be specified.
2514 ``insertvalue (VAL, ELT, IDX0, IDX1, ...)``
2515     Perform the :ref:`insertvalue operation <i_insertvalue>` on constants.
2516     The index list is interpreted in a similar manner as indices in a
2517     ':ref:`getelementptr <i_getelementptr>`' operation. At least one index
2518     value must be specified.
2519 ``OPCODE (LHS, RHS)``
2520     Perform the specified operation of the LHS and RHS constants. OPCODE
2521     may be any of the :ref:`binary <binaryops>` or :ref:`bitwise
2522     binary <bitwiseops>` operations. The constraints on operands are
2523     the same as those for the corresponding instruction (e.g. no bitwise
2524     operations on floating point values are allowed).
2525
2526 Other Values
2527 ============
2528
2529 .. _inlineasmexprs:
2530
2531 Inline Assembler Expressions
2532 ----------------------------
2533
2534 LLVM supports inline assembler expressions (as opposed to :ref:`Module-Level
2535 Inline Assembly <moduleasm>`) through the use of a special value. This
2536 value represents the inline assembler as a string (containing the
2537 instructions to emit), a list of operand constraints (stored as a
2538 string), a flag that indicates whether or not the inline asm expression
2539 has side effects, and a flag indicating whether the function containing
2540 the asm needs to align its stack conservatively. An example inline
2541 assembler expression is:
2542
2543 .. code-block:: llvm
2544
2545     i32 (i32) asm "bswap $0", "=r,r"
2546
2547 Inline assembler expressions may **only** be used as the callee operand
2548 of a :ref:`call <i_call>` or an :ref:`invoke <i_invoke>` instruction.
2549 Thus, typically we have:
2550
2551 .. code-block:: llvm
2552
2553     %X = call i32 asm "bswap $0", "=r,r"(i32 %Y)
2554
2555 Inline asms with side effects not visible in the constraint list must be
2556 marked as having side effects. This is done through the use of the
2557 '``sideeffect``' keyword, like so:
2558
2559 .. code-block:: llvm
2560
2561     call void asm sideeffect "eieio", ""()
2562
2563 In some cases inline asms will contain code that will not work unless
2564 the stack is aligned in some way, such as calls or SSE instructions on
2565 x86, yet will not contain code that does that alignment within the asm.
2566 The compiler should make conservative assumptions about what the asm
2567 might contain and should generate its usual stack alignment code in the
2568 prologue if the '``alignstack``' keyword is present:
2569
2570 .. code-block:: llvm
2571
2572     call void asm alignstack "eieio", ""()
2573
2574 Inline asms also support using non-standard assembly dialects. The
2575 assumed dialect is ATT. When the '``inteldialect``' keyword is present,
2576 the inline asm is using the Intel dialect. Currently, ATT and Intel are
2577 the only supported dialects. An example is:
2578
2579 .. code-block:: llvm
2580
2581     call void asm inteldialect "eieio", ""()
2582
2583 If multiple keywords appear the '``sideeffect``' keyword must come
2584 first, the '``alignstack``' keyword second and the '``inteldialect``'
2585 keyword last.
2586
2587 Inline Asm Metadata
2588 ^^^^^^^^^^^^^^^^^^^
2589
2590 The call instructions that wrap inline asm nodes may have a
2591 "``!srcloc``" MDNode attached to it that contains a list of constant
2592 integers. If present, the code generator will use the integer as the
2593 location cookie value when report errors through the ``LLVMContext``
2594 error reporting mechanisms. This allows a front-end to correlate backend
2595 errors that occur with inline asm back to the source code that produced
2596 it. For example:
2597
2598 .. code-block:: llvm
2599
2600     call void asm sideeffect "something bad", ""(), !srcloc !42
2601     ...
2602     !42 = !{ i32 1234567 }
2603
2604 It is up to the front-end to make sense of the magic numbers it places
2605 in the IR. If the MDNode contains multiple constants, the code generator
2606 will use the one that corresponds to the line of the asm that the error
2607 occurs on.
2608
2609 .. _metadata:
2610
2611 Metadata Nodes and Metadata Strings
2612 -----------------------------------
2613
2614 LLVM IR allows metadata to be attached to instructions in the program
2615 that can convey extra information about the code to the optimizers and
2616 code generator. One example application of metadata is source-level
2617 debug information. There are two metadata primitives: strings and nodes.
2618 All metadata has the ``metadata`` type and is identified in syntax by a
2619 preceding exclamation point ('``!``').
2620
2621 A metadata string is a string surrounded by double quotes. It can
2622 contain any character by escaping non-printable characters with
2623 "``\xx``" where "``xx``" is the two digit hex code. For example:
2624 "``!"test\00"``".
2625
2626 Metadata nodes are represented with notation similar to structure
2627 constants (a comma separated list of elements, surrounded by braces and
2628 preceded by an exclamation point). Metadata nodes can have any values as
2629 their operand. For example:
2630
2631 .. code-block:: llvm
2632
2633     !{ metadata !"test\00", i32 10}
2634
2635 A :ref:`named metadata <namedmetadatastructure>` is a collection of
2636 metadata nodes, which can be looked up in the module symbol table. For
2637 example:
2638
2639 .. code-block:: llvm
2640
2641     !foo =  metadata !{!4, !3}
2642
2643 Metadata can be used as function arguments. Here ``llvm.dbg.value``
2644 function is using two metadata arguments:
2645
2646 .. code-block:: llvm
2647
2648     call void @llvm.dbg.value(metadata !24, i64 0, metadata !25)
2649
2650 Metadata can be attached with an instruction. Here metadata ``!21`` is
2651 attached to the ``add`` instruction using the ``!dbg`` identifier:
2652
2653 .. code-block:: llvm
2654
2655     %indvar.next = add i64 %indvar, 1, !dbg !21
2656
2657 More information about specific metadata nodes recognized by the
2658 optimizers and code generator is found below.
2659
2660 '``tbaa``' Metadata
2661 ^^^^^^^^^^^^^^^^^^^
2662
2663 In LLVM IR, memory does not have types, so LLVM's own type system is not
2664 suitable for doing TBAA. Instead, metadata is added to the IR to
2665 describe a type system of a higher level language. This can be used to
2666 implement typical C/C++ TBAA, but it can also be used to implement
2667 custom alias analysis behavior for other languages.
2668
2669 The current metadata format is very simple. TBAA metadata nodes have up
2670 to three fields, e.g.:
2671
2672 .. code-block:: llvm
2673
2674     !0 = metadata !{ metadata !"an example type tree" }
2675     !1 = metadata !{ metadata !"int", metadata !0 }
2676     !2 = metadata !{ metadata !"float", metadata !0 }
2677     !3 = metadata !{ metadata !"const float", metadata !2, i64 1 }
2678
2679 The first field is an identity field. It can be any value, usually a
2680 metadata string, which uniquely identifies the type. The most important
2681 name in the tree is the name of the root node. Two trees with different
2682 root node names are entirely disjoint, even if they have leaves with
2683 common names.
2684
2685 The second field identifies the type's parent node in the tree, or is
2686 null or omitted for a root node. A type is considered to alias all of
2687 its descendants and all of its ancestors in the tree. Also, a type is
2688 considered to alias all types in other trees, so that bitcode produced
2689 from multiple front-ends is handled conservatively.
2690
2691 If the third field is present, it's an integer which if equal to 1
2692 indicates that the type is "constant" (meaning
2693 ``pointsToConstantMemory`` should return true; see `other useful
2694 AliasAnalysis methods <AliasAnalysis.html#OtherItfs>`_).
2695
2696 '``tbaa.struct``' Metadata
2697 ^^^^^^^^^^^^^^^^^^^^^^^^^^
2698
2699 The :ref:`llvm.memcpy <int_memcpy>` is often used to implement
2700 aggregate assignment operations in C and similar languages, however it
2701 is defined to copy a contiguous region of memory, which is more than
2702 strictly necessary for aggregate types which contain holes due to
2703 padding. Also, it doesn't contain any TBAA information about the fields
2704 of the aggregate.
2705
2706 ``!tbaa.struct`` metadata can describe which memory subregions in a
2707 memcpy are padding and what the TBAA tags of the struct are.
2708
2709 The current metadata format is very simple. ``!tbaa.struct`` metadata
2710 nodes are a list of operands which are in conceptual groups of three.
2711 For each group of three, the first operand gives the byte offset of a
2712 field in bytes, the second gives its size in bytes, and the third gives
2713 its tbaa tag. e.g.:
2714
2715 .. code-block:: llvm
2716
2717     !4 = metadata !{ i64 0, i64 4, metadata !1, i64 8, i64 4, metadata !2 }
2718
2719 This describes a struct with two fields. The first is at offset 0 bytes
2720 with size 4 bytes, and has tbaa tag !1. The second is at offset 8 bytes
2721 and has size 4 bytes and has tbaa tag !2.
2722
2723 Note that the fields need not be contiguous. In this example, there is a
2724 4 byte gap between the two fields. This gap represents padding which
2725 does not carry useful data and need not be preserved.
2726
2727 '``fpmath``' Metadata
2728 ^^^^^^^^^^^^^^^^^^^^^
2729
2730 ``fpmath`` metadata may be attached to any instruction of floating point
2731 type. It can be used to express the maximum acceptable error in the
2732 result of that instruction, in ULPs, thus potentially allowing the
2733 compiler to use a more efficient but less accurate method of computing
2734 it. ULP is defined as follows:
2735
2736     If ``x`` is a real number that lies between two finite consecutive
2737     floating-point numbers ``a`` and ``b``, without being equal to one
2738     of them, then ``ulp(x) = |b - a|``, otherwise ``ulp(x)`` is the
2739     distance between the two non-equal finite floating-point numbers
2740     nearest ``x``. Moreover, ``ulp(NaN)`` is ``NaN``.
2741
2742 The metadata node shall consist of a single positive floating point
2743 number representing the maximum relative error, for example:
2744
2745 .. code-block:: llvm
2746
2747     !0 = metadata !{ float 2.5 } ; maximum acceptable inaccuracy is 2.5 ULPs
2748
2749 '``range``' Metadata
2750 ^^^^^^^^^^^^^^^^^^^^
2751
2752 ``range`` metadata may be attached only to loads of integer types. It
2753 expresses the possible ranges the loaded value is in. The ranges are
2754 represented with a flattened list of integers. The loaded value is known
2755 to be in the union of the ranges defined by each consecutive pair. Each
2756 pair has the following properties:
2757
2758 -  The type must match the type loaded by the instruction.
2759 -  The pair ``a,b`` represents the range ``[a,b)``.
2760 -  Both ``a`` and ``b`` are constants.
2761 -  The range is allowed to wrap.
2762 -  The range should not represent the full or empty set. That is,
2763    ``a!=b``.
2764
2765 In addition, the pairs must be in signed order of the lower bound and
2766 they must be non-contiguous.
2767
2768 Examples:
2769
2770 .. code-block:: llvm
2771
2772       %a = load i8* %x, align 1, !range !0 ; Can only be 0 or 1
2773       %b = load i8* %y, align 1, !range !1 ; Can only be 255 (-1), 0 or 1
2774       %c = load i8* %z, align 1, !range !2 ; Can only be 0, 1, 3, 4 or 5
2775       %d = load i8* %z, align 1, !range !3 ; Can only be -2, -1, 3, 4 or 5
2776     ...
2777     !0 = metadata !{ i8 0, i8 2 }
2778     !1 = metadata !{ i8 255, i8 2 }
2779     !2 = metadata !{ i8 0, i8 2, i8 3, i8 6 }
2780     !3 = metadata !{ i8 -2, i8 0, i8 3, i8 6 }
2781
2782 '``llvm.loop``'
2783 ^^^^^^^^^^^^^^^
2784
2785 It is sometimes useful to attach information to loop constructs. Currently,
2786 loop metadata is implemented as metadata attached to the branch instruction
2787 in the loop latch block. This type of metadata refer to a metadata node that is
2788 guaranteed to be separate for each loop. The loop identifier metadata is
2789 specified with the name ``llvm.loop``.
2790
2791 The loop identifier metadata is implemented using a metadata that refers to
2792 itself to avoid merging it with any other identifier metadata, e.g.,
2793 during module linkage or function inlining. That is, each loop should refer
2794 to their own identification metadata even if they reside in separate functions.
2795 The following example contains loop identifier metadata for two separate loop
2796 constructs:
2797
2798 .. code-block:: llvm
2799
2800     !0 = metadata !{ metadata !0 }
2801     !1 = metadata !{ metadata !1 }
2802
2803 The loop identifier metadata can be used to specify additional per-loop
2804 metadata. Any operands after the first operand can be treated as user-defined
2805 metadata. For example the ``llvm.vectorizer.unroll`` metadata is understood
2806 by the loop vectorizer to indicate how many times to unroll the loop:
2807
2808 .. code-block:: llvm
2809
2810       br i1 %exitcond, label %._crit_edge, label %.lr.ph, !llvm.loop !0
2811     ...
2812     !0 = metadata !{ metadata !0, metadata !1 }
2813     !1 = metadata !{ metadata !"llvm.vectorizer.unroll", i32 2 }
2814
2815 '``llvm.mem``'
2816 ^^^^^^^^^^^^^^^
2817
2818 Metadata types used to annotate memory accesses with information helpful
2819 for optimizations are prefixed with ``llvm.mem``.
2820
2821 '``llvm.mem.parallel_loop_access``' Metadata
2822 ^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^
2823
2824 The ``llvm.mem.parallel_loop_access`` metadata refers to a loop identifier, 
2825 or metadata containing a list of loop identifiers for nested loops. 
2826 The metadata is attached to memory accessing instructions and denotes that 
2827 no loop carried memory dependence exist between it and other instructions denoted 
2828 with the same loop identifier.
2829
2830 Precisely, given two instructions ``m1`` and ``m2`` that both have the 
2831 ``llvm.mem.parallel_loop_access`` metadata, with ``L1`` and ``L2`` being the 
2832 set of loops associated with that metadata, respectively, then there is no loop 
2833 carried dependence between ``m1`` and ``m2`` for loops in both ``L1`` and 
2834 ``L2``.
2835
2836 As a special case, if all memory accessing instructions in a loop have 
2837 ``llvm.mem.parallel_loop_access`` metadata that refers to that loop, then the 
2838 loop has no loop carried memory dependences and is considered to be a parallel 
2839 loop.  
2840
2841 Note that if not all memory access instructions have such metadata referring to 
2842 the loop, then the loop is considered not being trivially parallel. Additional 
2843 memory dependence analysis is required to make that determination.  As a fail 
2844 safe mechanism, this causes loops that were originally parallel to be considered 
2845 sequential (if optimization passes that are unaware of the parallel semantics 
2846 insert new memory instructions into the loop body).
2847
2848 Example of a loop that is considered parallel due to its correct use of
2849 both ``llvm.loop`` and ``llvm.mem.parallel_loop_access``
2850 metadata types that refer to the same loop identifier metadata.
2851
2852 .. code-block:: llvm
2853
2854    for.body:
2855      ...
2856      %val0 = load i32* %arrayidx, !llvm.mem.parallel_loop_access !0
2857      ...
2858      store i32 %val0, i32* %arrayidx1, !llvm.mem.parallel_loop_access !0
2859      ...
2860      br i1 %exitcond, label %for.end, label %for.body, !llvm.loop !0
2861
2862    for.end:
2863    ...
2864    !0 = metadata !{ metadata !0 }
2865
2866 It is also possible to have nested parallel loops. In that case the
2867 memory accesses refer to a list of loop identifier metadata nodes instead of
2868 the loop identifier metadata node directly:
2869
2870 .. code-block:: llvm
2871
2872    outer.for.body:
2873      ...
2874      %val1 = load i32* %arrayidx3, !llvm.mem.parallel_loop_access !2
2875      ...
2876      br label %inner.for.body
2877
2878    inner.for.body:
2879      ...
2880      %val0 = load i32* %arrayidx1, !llvm.mem.parallel_loop_access !0
2881      ...
2882      store i32 %val0, i32* %arrayidx2, !llvm.mem.parallel_loop_access !0
2883      ...
2884      br i1 %exitcond, label %inner.for.end, label %inner.for.body, !llvm.loop !1
2885
2886    inner.for.end:
2887      ...
2888      store i32 %val1, i32* %arrayidx4, !llvm.mem.parallel_loop_access !2
2889      ...
2890      br i1 %exitcond, label %outer.for.end, label %outer.for.body, !llvm.loop !2
2891
2892    outer.for.end:                                          ; preds = %for.body
2893    ...
2894    !0 = metadata !{ metadata !1, metadata !2 } ; a list of loop identifiers
2895    !1 = metadata !{ metadata !1 } ; an identifier for the inner loop
2896    !2 = metadata !{ metadata !2 } ; an identifier for the outer loop
2897
2898 '``llvm.vectorizer``'
2899 ^^^^^^^^^^^^^^^^^^^^^
2900
2901 Metadata prefixed with ``llvm.vectorizer`` is used to control per-loop
2902 vectorization parameters such as vectorization factor and unroll factor.
2903
2904 ``llvm.vectorizer`` metadata should be used in conjunction with ``llvm.loop``
2905 loop identification metadata.
2906
2907 '``llvm.vectorizer.unroll``' Metadata
2908 ^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^
2909
2910 This metadata instructs the loop vectorizer to unroll the specified
2911 loop exactly ``N`` times.
2912
2913 The first operand is the string ``llvm.vectorizer.unroll`` and the second
2914 operand is an integer specifying the unroll factor. For example:
2915
2916 .. code-block:: llvm
2917
2918    !0 = metadata !{ metadata !"llvm.vectorizer.unroll", i32 4 }
2919
2920 Note that setting ``llvm.vectorizer.unroll`` to 1 disables unrolling of the
2921 loop.
2922
2923 If ``llvm.vectorizer.unroll`` is set to 0 then the amount of unrolling will be
2924 determined automatically.
2925
2926 '``llvm.vectorizer.width``' Metadata
2927 ^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^
2928
2929 This metadata sets the target width of the vectorizer to ``N``. Without
2930 this metadata, the vectorizer will choose a width automatically.
2931 Regardless of this metadata, the vectorizer will only vectorize loops if
2932 it believes it is valid to do so.
2933
2934 The first operand is the string ``llvm.vectorizer.width`` and the second
2935 operand is an integer specifying the width. For example:
2936
2937 .. code-block:: llvm
2938
2939    !0 = metadata !{ metadata !"llvm.vectorizer.width", i32 4 }
2940
2941 Note that setting ``llvm.vectorizer.width`` to 1 disables vectorization of the
2942 loop.
2943
2944 If ``llvm.vectorizer.width`` is set to 0 then the width will be determined
2945 automatically.
2946
2947 Module Flags Metadata
2948 =====================
2949
2950 Information about the module as a whole is difficult to convey to LLVM's
2951 subsystems. The LLVM IR isn't sufficient to transmit this information.
2952 The ``llvm.module.flags`` named metadata exists in order to facilitate
2953 this. These flags are in the form of key / value pairs --- much like a
2954 dictionary --- making it easy for any subsystem who cares about a flag to
2955 look it up.
2956
2957 The ``llvm.module.flags`` metadata contains a list of metadata triplets.
2958 Each triplet has the following form:
2959
2960 -  The first element is a *behavior* flag, which specifies the behavior
2961    when two (or more) modules are merged together, and it encounters two
2962    (or more) metadata with the same ID. The supported behaviors are
2963    described below.
2964 -  The second element is a metadata string that is a unique ID for the
2965    metadata. Each module may only have one flag entry for each unique ID (not
2966    including entries with the **Require** behavior).
2967 -  The third element is the value of the flag.
2968
2969 When two (or more) modules are merged together, the resulting
2970 ``llvm.module.flags`` metadata is the union of the modules' flags. That is, for
2971 each unique metadata ID string, there will be exactly one entry in the merged
2972 modules ``llvm.module.flags`` metadata table, and the value for that entry will
2973 be determined by the merge behavior flag, as described below. The only exception
2974 is that entries with the *Require* behavior are always preserved.
2975
2976 The following behaviors are supported:
2977
2978 .. list-table::
2979    :header-rows: 1
2980    :widths: 10 90
2981
2982    * - Value
2983      - Behavior
2984
2985    * - 1
2986      - **Error**
2987            Emits an error if two values disagree, otherwise the resulting value
2988            is that of the operands.
2989
2990    * - 2
2991      - **Warning**
2992            Emits a warning if two values disagree. The result value will be the
2993            operand for the flag from the first module being linked.
2994
2995    * - 3
2996      - **Require**
2997            Adds a requirement that another module flag be present and have a
2998            specified value after linking is performed. The value must be a
2999            metadata pair, where the first element of the pair is the ID of the
3000            module flag to be restricted, and the second element of the pair is
3001            the value the module flag should be restricted to. This behavior can
3002            be used to restrict the allowable results (via triggering of an
3003            error) of linking IDs with the **Override** behavior.
3004
3005    * - 4
3006      - **Override**
3007            Uses the specified value, regardless of the behavior or value of the
3008            other module. If both modules specify **Override**, but the values
3009            differ, an error will be emitted.
3010
3011    * - 5
3012      - **Append**
3013            Appends the two values, which are required to be metadata nodes.
3014
3015    * - 6
3016      - **AppendUnique**
3017            Appends the two values, which are required to be metadata
3018            nodes. However, duplicate entries in the second list are dropped
3019            during the append operation.
3020
3021 It is an error for a particular unique flag ID to have multiple behaviors,
3022 except in the case of **Require** (which adds restrictions on another metadata
3023 value) or **Override**.
3024
3025 An example of module flags:
3026
3027 .. code-block:: llvm
3028
3029     !0 = metadata !{ i32 1, metadata !"foo", i32 1 }
3030     !1 = metadata !{ i32 4, metadata !"bar", i32 37 }
3031     !2 = metadata !{ i32 2, metadata !"qux", i32 42 }
3032     !3 = metadata !{ i32 3, metadata !"qux",
3033       metadata !{
3034         metadata !"foo", i32 1
3035       }
3036     }
3037     !llvm.module.flags = !{ !0, !1, !2, !3 }
3038
3039 -  Metadata ``!0`` has the ID ``!"foo"`` and the value '1'. The behavior
3040    if two or more ``!"foo"`` flags are seen is to emit an error if their
3041    values are not equal.
3042
3043 -  Metadata ``!1`` has the ID ``!"bar"`` and the value '37'. The
3044    behavior if two or more ``!"bar"`` flags are seen is to use the value
3045    '37'.
3046
3047 -  Metadata ``!2`` has the ID ``!"qux"`` and the value '42'. The
3048    behavior if two or more ``!"qux"`` flags are seen is to emit a
3049    warning if their values are not equal.
3050
3051 -  Metadata ``!3`` has the ID ``!"qux"`` and the value:
3052
3053    ::
3054
3055        metadata !{ metadata !"foo", i32 1 }
3056
3057    The behavior is to emit an error if the ``llvm.module.flags`` does not
3058    contain a flag with the ID ``!"foo"`` that has the value '1' after linking is
3059    performed.
3060
3061 Objective-C Garbage Collection Module Flags Metadata
3062 ----------------------------------------------------
3063
3064 On the Mach-O platform, Objective-C stores metadata about garbage
3065 collection in a special section called "image info". The metadata
3066 consists of a version number and a bitmask specifying what types of
3067 garbage collection are supported (if any) by the file. If two or more
3068 modules are linked together their garbage collection metadata needs to
3069 be merged rather than appended together.
3070
3071 The Objective-C garbage collection module flags metadata consists of the
3072 following key-value pairs:
3073
3074 .. list-table::
3075    :header-rows: 1
3076    :widths: 30 70
3077
3078    * - Key
3079      - Value
3080
3081    * - ``Objective-C Version``
3082      - **[Required]** --- The Objective-C ABI version. Valid values are 1 and 2.
3083
3084    * - ``Objective-C Image Info Version``
3085      - **[Required]** --- The version of the image info section. Currently
3086        always 0.
3087
3088    * - ``Objective-C Image Info Section``
3089      - **[Required]** --- The section to place the metadata. Valid values are
3090        ``"__OBJC, __image_info, regular"`` for Objective-C ABI version 1, and
3091        ``"__DATA,__objc_imageinfo, regular, no_dead_strip"`` for
3092        Objective-C ABI version 2.
3093
3094    * - ``Objective-C Garbage Collection``
3095      - **[Required]** --- Specifies whether garbage collection is supported or
3096        not. Valid values are 0, for no garbage collection, and 2, for garbage
3097        collection supported.
3098
3099    * - ``Objective-C GC Only``
3100      - **[Optional]** --- Specifies that only garbage collection is supported.
3101        If present, its value must be 6. This flag requires that the
3102        ``Objective-C Garbage Collection`` flag have the value 2.
3103
3104 Some important flag interactions:
3105
3106 -  If a module with ``Objective-C Garbage Collection`` set to 0 is
3107    merged with a module with ``Objective-C Garbage Collection`` set to
3108    2, then the resulting module has the
3109    ``Objective-C Garbage Collection`` flag set to 0.
3110 -  A module with ``Objective-C Garbage Collection`` set to 0 cannot be
3111    merged with a module with ``Objective-C GC Only`` set to 6.
3112
3113 Automatic Linker Flags Module Flags Metadata
3114 --------------------------------------------
3115
3116 Some targets support embedding flags to the linker inside individual object
3117 files. Typically this is used in conjunction with language extensions which
3118 allow source files to explicitly declare the libraries they depend on, and have
3119 these automatically be transmitted to the linker via object files.
3120
3121 These flags are encoded in the IR using metadata in the module flags section,
3122 using the ``Linker Options`` key. The merge behavior for this flag is required
3123 to be ``AppendUnique``, and the value for the key is expected to be a metadata
3124 node which should be a list of other metadata nodes, each of which should be a
3125 list of metadata strings defining linker options.
3126
3127 For example, the following metadata section specifies two separate sets of
3128 linker options, presumably to link against ``libz`` and the ``Cocoa``
3129 framework::
3130
3131     !0 = metadata !{ i32 6, metadata !"Linker Options",
3132        metadata !{
3133           metadata !{ metadata !"-lz" },
3134           metadata !{ metadata !"-framework", metadata !"Cocoa" } } }
3135     !llvm.module.flags = !{ !0 }
3136
3137 The metadata encoding as lists of lists of options, as opposed to a collapsed
3138 list of options, is chosen so that the IR encoding can use multiple option
3139 strings to specify e.g., a single library, while still having that specifier be
3140 preserved as an atomic element that can be recognized by a target specific
3141 assembly writer or object file emitter.
3142
3143 Each individual option is required to be either a valid option for the target's
3144 linker, or an option that is reserved by the target specific assembly writer or
3145 object file emitter. No other aspect of these options is defined by the IR.
3146
3147 .. _intrinsicglobalvariables:
3148
3149 Intrinsic Global Variables
3150 ==========================
3151
3152 LLVM has a number of "magic" global variables that contain data that
3153 affect code generation or other IR semantics. These are documented here.
3154 All globals of this sort should have a section specified as
3155 "``llvm.metadata``". This section and all globals that start with
3156 "``llvm.``" are reserved for use by LLVM.
3157
3158 .. _gv_llvmused:
3159
3160 The '``llvm.used``' Global Variable
3161 -----------------------------------
3162
3163 The ``@llvm.used`` global is an array which has
3164 :ref:`appending linkage <linkage_appending>`. This array contains a list of
3165 pointers to named global variables, functions and aliases which may optionally
3166 have a pointer cast formed of bitcast or getelementptr. For example, a legal
3167 use of it is:
3168
3169 .. code-block:: llvm
3170
3171     @X = global i8 4
3172     @Y = global i32 123
3173
3174     @llvm.used = appending global [2 x i8*] [
3175        i8* @X,
3176        i8* bitcast (i32* @Y to i8*)
3177     ], section "llvm.metadata"
3178
3179 If a symbol appears in the ``@llvm.used`` list, then the compiler, assembler,
3180 and linker are required to treat the symbol as if there is a reference to the
3181 symbol that it cannot see (which is why they have to be named). For example, if
3182 a variable has internal linkage and no references other than that from the
3183 ``@llvm.used`` list, it cannot be deleted. This is commonly used to represent
3184 references from inline asms and other things the compiler cannot "see", and
3185 corresponds to "``attribute((used))``" in GNU C.
3186
3187 On some targets, the code generator must emit a directive to the
3188 assembler or object file to prevent the assembler and linker from
3189 molesting the symbol.
3190
3191 .. _gv_llvmcompilerused:
3192
3193 The '``llvm.compiler.used``' Global Variable
3194 --------------------------------------------
3195
3196 The ``@llvm.compiler.used`` directive is the same as the ``@llvm.used``
3197 directive, except that it only prevents the compiler from touching the
3198 symbol. On targets that support it, this allows an intelligent linker to
3199 optimize references to the symbol without being impeded as it would be
3200 by ``@llvm.used``.
3201
3202 This is a rare construct that should only be used in rare circumstances,
3203 and should not be exposed to source languages.
3204
3205 .. _gv_llvmglobalctors:
3206
3207 The '``llvm.global_ctors``' Global Variable
3208 -------------------------------------------
3209
3210 .. code-block:: llvm
3211
3212     %0 = type { i32, void ()*, i8* }
3213     @llvm.global_ctors = appending global [1 x %0] [%0 { i32 65535, void ()* @ctor, i8* @data }]
3214
3215 The ``@llvm.global_ctors`` array contains a list of constructor
3216 functions, priorities, and an optional associated global or function.
3217 The functions referenced by this array will be called in ascending order
3218 of priority (i.e. lowest first) when the module is loaded. The order of
3219 functions with the same priority is not defined.
3220
3221 If the third field is present, non-null, and points to a global variable
3222 or function, the initializer function will only run if the associated
3223 data from the current module is not discarded.
3224
3225 .. _llvmglobaldtors:
3226
3227 The '``llvm.global_dtors``' Global Variable
3228 -------------------------------------------
3229
3230 .. code-block:: llvm
3231
3232     %0 = type { i32, void ()*, i8* }
3233     @llvm.global_dtors = appending global [1 x %0] [%0 { i32 65535, void ()* @dtor, i8* @data }]
3234
3235 The ``@llvm.global_dtors`` array contains a list of destructor
3236 functions, priorities, and an optional associated global or function.
3237 The functions referenced by this array will be called in descending
3238 order of priority (i.e. highest first) when the module is unloaded. The
3239 order of functions with the same priority is not defined.
3240
3241 If the third field is present, non-null, and points to a global variable
3242 or function, the destructor function will only run if the associated
3243 data from the current module is not discarded.
3244
3245 Instruction Reference
3246 =====================
3247
3248 The LLVM instruction set consists of several different classifications
3249 of instructions: :ref:`terminator instructions <terminators>`, :ref:`binary
3250 instructions <binaryops>`, :ref:`bitwise binary
3251 instructions <bitwiseops>`, :ref:`memory instructions <memoryops>`, and
3252 :ref:`other instructions <otherops>`.
3253
3254 .. _terminators:
3255
3256 Terminator Instructions
3257 -----------------------
3258
3259 As mentioned :ref:`previously <functionstructure>`, every basic block in a
3260 program ends with a "Terminator" instruction, which indicates which
3261 block should be executed after the current block is finished. These
3262 terminator instructions typically yield a '``void``' value: they produce
3263 control flow, not values (the one exception being the
3264 ':ref:`invoke <i_invoke>`' instruction).
3265
3266 The terminator instructions are: ':ref:`ret <i_ret>`',
3267 ':ref:`br <i_br>`', ':ref:`switch <i_switch>`',
3268 ':ref:`indirectbr <i_indirectbr>`', ':ref:`invoke <i_invoke>`',
3269 ':ref:`resume <i_resume>`', and ':ref:`unreachable <i_unreachable>`'.
3270
3271 .. _i_ret:
3272
3273 '``ret``' Instruction
3274 ^^^^^^^^^^^^^^^^^^^^^
3275
3276 Syntax:
3277 """""""
3278
3279 ::
3280
3281       ret <type> <value>       ; Return a value from a non-void function
3282       ret void                 ; Return from void function
3283
3284 Overview:
3285 """""""""
3286
3287 The '``ret``' instruction is used to return control flow (and optionally
3288 a value) from a function back to the caller.
3289
3290 There are two forms of the '``ret``' instruction: one that returns a
3291 value and then causes control flow, and one that just causes control
3292 flow to occur.
3293
3294 Arguments:
3295 """"""""""
3296
3297 The '``ret``' instruction optionally accepts a single argument, the
3298 return value. The type of the return value must be a ':ref:`first
3299 class <t_firstclass>`' type.
3300
3301 A function is not :ref:`well formed <wellformed>` if it it has a non-void
3302 return type and contains a '``ret``' instruction with no return value or
3303 a return value with a type that does not match its type, or if it has a
3304 void return type and contains a '``ret``' instruction with a return
3305 value.
3306
3307 Semantics:
3308 """"""""""
3309
3310 When the '``ret``' instruction is executed, control flow returns back to
3311 the calling function's context. If the caller is a
3312 ":ref:`call <i_call>`" instruction, execution continues at the
3313 instruction after the call. If the caller was an
3314 ":ref:`invoke <i_invoke>`" instruction, execution continues at the
3315 beginning of the "normal" destination block. If the instruction returns
3316 a value, that value shall set the call or invoke instruction's return
3317 value.
3318
3319 Example:
3320 """"""""
3321
3322 .. code-block:: llvm
3323
3324       ret i32 5                       ; Return an integer value of 5
3325       ret void                        ; Return from a void function
3326       ret { i32, i8 } { i32 4, i8 2 } ; Return a struct of values 4 and 2
3327
3328 .. _i_br:
3329
3330 '``br``' Instruction
3331 ^^^^^^^^^^^^^^^^^^^^
3332
3333 Syntax:
3334 """""""
3335
3336 ::
3337
3338       br i1 <cond>, label <iftrue>, label <iffalse>
3339       br label <dest>          ; Unconditional branch
3340
3341 Overview:
3342 """""""""
3343
3344 The '``br``' instruction is used to cause control flow to transfer to a
3345 different basic block in the current function. There are two forms of
3346 this instruction, corresponding to a conditional branch and an
3347 unconditional branch.
3348
3349 Arguments:
3350 """"""""""
3351
3352 The conditional branch form of the '``br``' instruction takes a single
3353 '``i1``' value and two '``label``' values. The unconditional form of the
3354 '``br``' instruction takes a single '``label``' value as a target.
3355
3356 Semantics:
3357 """"""""""
3358
3359 Upon execution of a conditional '``br``' instruction, the '``i1``'
3360 argument is evaluated. If the value is ``true``, control flows to the
3361 '``iftrue``' ``label`` argument. If "cond" is ``false``, control flows
3362 to the '``iffalse``' ``label`` argument.
3363
3364 Example:
3365 """"""""
3366
3367 .. code-block:: llvm
3368
3369     Test:
3370       %cond = icmp eq i32 %a, %b
3371       br i1 %cond, label %IfEqual, label %IfUnequal
3372     IfEqual:
3373       ret i32 1
3374     IfUnequal:
3375       ret i32 0
3376
3377 .. _i_switch:
3378
3379 '``switch``' Instruction
3380 ^^^^^^^^^^^^^^^^^^^^^^^^
3381
3382 Syntax:
3383 """""""
3384
3385 ::
3386
3387       switch <intty> <value>, label <defaultdest> [ <intty> <val>, label <dest> ... ]
3388
3389 Overview:
3390 """""""""
3391
3392 The '``switch``' instruction is used to transfer control flow to one of
3393 several different places. It is a generalization of the '``br``'
3394 instruction, allowing a branch to occur to one of many possible
3395 destinations.
3396
3397 Arguments:
3398 """"""""""
3399
3400 The '``switch``' instruction uses three parameters: an integer
3401 comparison value '``value``', a default '``label``' destination, and an
3402 array of pairs of comparison value constants and '``label``'s. The table
3403 is not allowed to contain duplicate constant entries.
3404
3405 Semantics:
3406 """"""""""
3407
3408 The ``switch`` instruction specifies a table of values and destinations.
3409 When the '``switch``' instruction is executed, this table is searched
3410 for the given value. If the value is found, control flow is transferred
3411 to the corresponding destination; otherwise, control flow is transferred
3412 to the default destination.
3413
3414 Implementation:
3415 """""""""""""""
3416
3417 Depending on properties of the target machine and the particular
3418 ``switch`` instruction, this instruction may be code generated in
3419 different ways. For example, it could be generated as a series of
3420 chained conditional branches or with a lookup table.
3421
3422 Example:
3423 """"""""
3424
3425 .. code-block:: llvm
3426
3427      ; Emulate a conditional br instruction
3428      %Val = zext i1 %value to i32
3429      switch i32 %Val, label %truedest [ i32 0, label %falsedest ]
3430
3431      ; Emulate an unconditional br instruction
3432      switch i32 0, label %dest [ ]
3433
3434      ; Implement a jump table:
3435      switch i32 %val, label %otherwise [ i32 0, label %onzero
3436                                          i32 1, label %onone
3437                                          i32 2, label %ontwo ]
3438
3439 .. _i_indirectbr:
3440
3441 '``indirectbr``' Instruction
3442 ^^^^^^^^^^^^^^^^^^^^^^^^^^^^
3443
3444 Syntax:
3445 """""""
3446
3447 ::
3448
3449       indirectbr <somety>* <address>, [ label <dest1>, label <dest2>, ... ]
3450
3451 Overview:
3452 """""""""
3453
3454 The '``indirectbr``' instruction implements an indirect branch to a
3455 label within the current function, whose address is specified by
3456 "``address``". Address must be derived from a
3457 :ref:`blockaddress <blockaddress>` constant.
3458
3459 Arguments:
3460 """"""""""
3461
3462 The '``address``' argument is the address of the label to jump to. The
3463 rest of the arguments indicate the full set of possible destinations
3464 that the address may point to. Blocks are allowed to occur multiple
3465 times in the destination list, though this isn't particularly useful.
3466
3467 This destination list is required so that dataflow analysis has an
3468 accurate understanding of the CFG.
3469
3470 Semantics:
3471 """"""""""
3472
3473 Control transfers to the block specified in the address argument. All
3474 possible destination blocks must be listed in the label list, otherwise
3475 this instruction has undefined behavior. This implies that jumps to
3476 labels defined in other functions have undefined behavior as well.
3477
3478 Implementation:
3479 """""""""""""""
3480
3481 This is typically implemented with a jump through a register.
3482
3483 Example:
3484 """"""""
3485
3486 .. code-block:: llvm
3487
3488      indirectbr i8* %Addr, [ label %bb1, label %bb2, label %bb3 ]
3489
3490 .. _i_invoke:
3491
3492 '``invoke``' Instruction
3493 ^^^^^^^^^^^^^^^^^^^^^^^^
3494
3495 Syntax:
3496 """""""
3497
3498 ::
3499
3500       <result> = invoke [cconv] [ret attrs] <ptr to function ty> <function ptr val>(<function args>) [fn attrs]
3501                     to label <normal label> unwind label <exception label>
3502
3503 Overview:
3504 """""""""
3505
3506 The '``invoke``' instruction causes control to transfer to a specified
3507 function, with the possibility of control flow transfer to either the
3508 '``normal``' label or the '``exception``' label. If the callee function
3509 returns with the "``ret``" instruction, control flow will return to the
3510 "normal" label. If the callee (or any indirect callees) returns via the
3511 ":ref:`resume <i_resume>`" instruction or other exception handling
3512 mechanism, control is interrupted and continued at the dynamically
3513 nearest "exception" label.
3514
3515 The '``exception``' label is a `landing
3516 pad <ExceptionHandling.html#overview>`_ for the exception. As such,
3517 '``exception``' label is required to have the
3518 ":ref:`landingpad <i_landingpad>`" instruction, which contains the
3519 information about the behavior of the program after unwinding happens,
3520 as its first non-PHI instruction. The restrictions on the
3521 "``landingpad``" instruction's tightly couples it to the "``invoke``"
3522 instruction, so that the important information contained within the
3523 "``landingpad``" instruction can't be lost through normal code motion.
3524
3525 Arguments:
3526 """"""""""
3527
3528 This instruction requires several arguments:
3529
3530 #. The optional "cconv" marker indicates which :ref:`calling
3531    convention <callingconv>` the call should use. If none is
3532    specified, the call defaults to using C calling conventions.
3533 #. The optional :ref:`Parameter Attributes <paramattrs>` list for return
3534    values. Only '``zeroext``', '``signext``', and '``inreg``' attributes
3535    are valid here.
3536 #. '``ptr to function ty``': shall be the signature of the pointer to
3537    function value being invoked. In most cases, this is a direct
3538    function invocation, but indirect ``invoke``'s are just as possible,
3539    branching off an arbitrary pointer to function value.
3540 #. '``function ptr val``': An LLVM value containing a pointer to a
3541    function to be invoked.
3542 #. '``function args``': argument list whose types match the function
3543    signature argument types and parameter attributes. All arguments must
3544    be of :ref:`first class <t_firstclass>` type. If the function signature
3545    indicates the function accepts a variable number of arguments, the
3546    extra arguments can be specified.
3547 #. '``normal label``': the label reached when the called function
3548    executes a '``ret``' instruction.
3549 #. '``exception label``': the label reached when a callee returns via
3550    the :ref:`resume <i_resume>` instruction or other exception handling
3551    mechanism.
3552 #. The optional :ref:`function attributes <fnattrs>` list. Only
3553    '``noreturn``', '``nounwind``', '``readonly``' and '``readnone``'
3554    attributes are valid here.
3555
3556 Semantics:
3557 """"""""""
3558
3559 This instruction is designed to operate as a standard '``call``'
3560 instruction in most regards. The primary difference is that it
3561 establishes an association with a label, which is used by the runtime
3562 library to unwind the stack.
3563
3564 This instruction is used in languages with destructors to ensure that
3565 proper cleanup is performed in the case of either a ``longjmp`` or a
3566 thrown exception. Additionally, this is important for implementation of
3567 '``catch``' clauses in high-level languages that support them.
3568
3569 For the purposes of the SSA form, the definition of the value returned
3570 by the '``invoke``' instruction is deemed to occur on the edge from the
3571 current block to the "normal" label. If the callee unwinds then no
3572 return value is available.
3573
3574 Example:
3575 """"""""
3576
3577 .. code-block:: llvm
3578
3579       %retval = invoke i32 @Test(i32 15) to label %Continue
3580                   unwind label %TestCleanup              ; {i32}:retval set
3581       %retval = invoke coldcc i32 %Testfnptr(i32 15) to label %Continue
3582                   unwind label %TestCleanup              ; {i32}:retval set
3583
3584 .. _i_resume:
3585
3586 '``resume``' Instruction
3587 ^^^^^^^^^^^^^^^^^^^^^^^^
3588
3589 Syntax:
3590 """""""
3591
3592 ::
3593
3594       resume <type> <value>
3595
3596 Overview:
3597 """""""""
3598
3599 The '``resume``' instruction is a terminator instruction that has no
3600 successors.
3601
3602 Arguments:
3603 """"""""""
3604
3605 The '``resume``' instruction requires one argument, which must have the
3606 same type as the result of any '``landingpad``' instruction in the same
3607 function.
3608
3609 Semantics:
3610 """"""""""
3611
3612 The '``resume``' instruction resumes propagation of an existing
3613 (in-flight) exception whose unwinding was interrupted with a
3614 :ref:`landingpad <i_landingpad>` instruction.
3615
3616 Example:
3617 """"""""
3618
3619 .. code-block:: llvm
3620
3621       resume { i8*, i32 } %exn
3622
3623 .. _i_unreachable:
3624
3625 '``unreachable``' Instruction
3626 ^^^^^^^^^^^^^^^^^^^^^^^^^^^^^
3627
3628 Syntax:
3629 """""""
3630
3631 ::
3632
3633       unreachable
3634
3635 Overview:
3636 """""""""
3637
3638 The '``unreachable``' instruction has no defined semantics. This
3639 instruction is used to inform the optimizer that a particular portion of
3640 the code is not reachable. This can be used to indicate that the code
3641 after a no-return function cannot be reached, and other facts.
3642
3643 Semantics:
3644 """"""""""
3645
3646 The '``unreachable``' instruction has no defined semantics.
3647
3648 .. _binaryops:
3649
3650 Binary Operations
3651 -----------------
3652
3653 Binary operators are used to do most of the computation in a program.
3654 They require two operands of the same type, execute an operation on
3655 them, and produce a single value. The operands might represent multiple
3656 data, as is the case with the :ref:`vector <t_vector>` data type. The
3657 result value has the same type as its operands.
3658
3659 There are several different binary operators:
3660
3661 .. _i_add:
3662
3663 '``add``' Instruction
3664 ^^^^^^^^^^^^^^^^^^^^^
3665
3666 Syntax:
3667 """""""
3668
3669 ::
3670
3671       <result> = add <ty> <op1>, <op2>          ; yields {ty}:result
3672       <result> = add nuw <ty> <op1>, <op2>      ; yields {ty}:result
3673       <result> = add nsw <ty> <op1>, <op2>      ; yields {ty}:result
3674       <result> = add nuw nsw <ty> <op1>, <op2>  ; yields {ty}:result
3675
3676 Overview:
3677 """""""""
3678
3679 The '``add``' instruction returns the sum of its two operands.
3680
3681 Arguments:
3682 """"""""""
3683
3684 The two arguments to the '``add``' instruction must be
3685 :ref:`integer <t_integer>` or :ref:`vector <t_vector>` of integer values. Both
3686 arguments must have identical types.
3687
3688 Semantics:
3689 """"""""""
3690
3691 The value produced is the integer sum of the two operands.
3692
3693 If the sum has unsigned overflow, the result returned is the
3694 mathematical result modulo 2\ :sup:`n`\ , where n is the bit width of
3695 the result.
3696
3697 Because LLVM integers use a two's complement representation, this
3698 instruction is appropriate for both signed and unsigned integers.
3699
3700 ``nuw`` and ``nsw`` stand for "No Unsigned Wrap" and "No Signed Wrap",
3701 respectively. If the ``nuw`` and/or ``nsw`` keywords are present, the
3702 result value of the ``add`` is a :ref:`poison value <poisonvalues>` if
3703 unsigned and/or signed overflow, respectively, occurs.
3704
3705 Example:
3706 """"""""
3707
3708 .. code-block:: llvm
3709
3710       <result> = add i32 4, %var          ; yields {i32}:result = 4 + %var
3711
3712 .. _i_fadd:
3713
3714 '``fadd``' Instruction
3715 ^^^^^^^^^^^^^^^^^^^^^^
3716
3717 Syntax:
3718 """""""
3719
3720 ::
3721
3722       <result> = fadd [fast-math flags]* <ty> <op1>, <op2>   ; yields {ty}:result
3723
3724 Overview:
3725 """""""""
3726
3727 The '``fadd``' instruction returns the sum of its two operands.
3728
3729 Arguments:
3730 """"""""""
3731
3732 The two arguments to the '``fadd``' instruction must be :ref:`floating
3733 point <t_floating>` or :ref:`vector <t_vector>` of floating point values.
3734 Both arguments must have identical types.
3735
3736 Semantics:
3737 """"""""""
3738
3739 The value produced is the floating point sum of the two operands. This
3740 instruction can also take any number of :ref:`fast-math flags <fastmath>`,
3741 which are optimization hints to enable otherwise unsafe floating point
3742 optimizations:
3743
3744 Example:
3745 """"""""
3746
3747 .. code-block:: llvm
3748
3749       <result> = fadd float 4.0, %var          ; yields {float}:result = 4.0 + %var
3750
3751 '``sub``' Instruction
3752 ^^^^^^^^^^^^^^^^^^^^^
3753
3754 Syntax:
3755 """""""
3756
3757 ::
3758
3759       <result> = sub <ty> <op1>, <op2>          ; yields {ty}:result
3760       <result> = sub nuw <ty> <op1>, <op2>      ; yields {ty}:result
3761       <result> = sub nsw <ty> <op1>, <op2>      ; yields {ty}:result
3762       <result> = sub nuw nsw <ty> <op1>, <op2>  ; yields {ty}:result
3763
3764 Overview:
3765 """""""""
3766
3767 The '``sub``' instruction returns the difference of its two operands.
3768
3769 Note that the '``sub``' instruction is used to represent the '``neg``'
3770 instruction present in most other intermediate representations.
3771
3772 Arguments:
3773 """"""""""
3774
3775 The two arguments to the '``sub``' instruction must be
3776 :ref:`integer <t_integer>` or :ref:`vector <t_vector>` of integer values. Both
3777 arguments must have identical types.
3778
3779 Semantics:
3780 """"""""""
3781
3782 The value produced is the integer difference of the two operands.
3783
3784 If the difference has unsigned overflow, the result returned is the
3785 mathematical result modulo 2\ :sup:`n`\ , where n is the bit width of
3786 the result.
3787
3788 Because LLVM integers use a two's complement representation, this
3789 instruction is appropriate for both signed and unsigned integers.
3790
3791 ``nuw`` and ``nsw`` stand for "No Unsigned Wrap" and "No Signed Wrap",
3792 respectively. If the ``nuw`` and/or ``nsw`` keywords are present, the
3793 result value of the ``sub`` is a :ref:`poison value <poisonvalues>` if
3794 unsigned and/or signed overflow, respectively, occurs.
3795
3796 Example:
3797 """"""""
3798
3799 .. code-block:: llvm
3800
3801       <result> = sub i32 4, %var          ; yields {i32}:result = 4 - %var
3802       <result> = sub i32 0, %val          ; yields {i32}:result = -%var
3803
3804 .. _i_fsub:
3805
3806 '``fsub``' Instruction
3807 ^^^^^^^^^^^^^^^^^^^^^^
3808
3809 Syntax:
3810 """""""
3811
3812 ::
3813
3814       <result> = fsub [fast-math flags]* <ty> <op1>, <op2>   ; yields {ty}:result
3815
3816 Overview:
3817 """""""""
3818
3819 The '``fsub``' instruction returns the difference of its two operands.
3820
3821 Note that the '``fsub``' instruction is used to represent the '``fneg``'
3822 instruction present in most other intermediate representations.
3823
3824 Arguments:
3825 """"""""""
3826
3827 The two arguments to the '``fsub``' instruction must be :ref:`floating
3828 point <t_floating>` or :ref:`vector <t_vector>` of floating point values.
3829 Both arguments must have identical types.
3830
3831 Semantics:
3832 """"""""""
3833
3834 The value produced is the floating point difference of the two operands.
3835 This instruction can also take any number of :ref:`fast-math
3836 flags <fastmath>`, which are optimization hints to enable otherwise
3837 unsafe floating point optimizations:
3838
3839 Example:
3840 """"""""
3841
3842 .. code-block:: llvm
3843
3844       <result> = fsub float 4.0, %var           ; yields {float}:result = 4.0 - %var
3845       <result> = fsub float -0.0, %val          ; yields {float}:result = -%var
3846
3847 '``mul``' Instruction
3848 ^^^^^^^^^^^^^^^^^^^^^
3849
3850 Syntax:
3851 """""""
3852
3853 ::
3854
3855       <result> = mul <ty> <op1>, <op2>          ; yields {ty}:result
3856       <result> = mul nuw <ty> <op1>, <op2>      ; yields {ty}:result
3857       <result> = mul nsw <ty> <op1>, <op2>      ; yields {ty}:result
3858       <result> = mul nuw nsw <ty> <op1>, <op2>  ; yields {ty}:result
3859
3860 Overview:
3861 """""""""
3862
3863 The '``mul``' instruction returns the product of its two operands.
3864
3865 Arguments:
3866 """"""""""
3867
3868 The two arguments to the '``mul``' instruction must be
3869 :ref:`integer <t_integer>` or :ref:`vector <t_vector>` of integer values. Both
3870 arguments must have identical types.
3871
3872 Semantics:
3873 """"""""""
3874
3875 The value produced is the integer product of the two operands.
3876
3877 If the result of the multiplication has unsigned overflow, the result
3878 returned is the mathematical result modulo 2\ :sup:`n`\ , where n is the
3879 bit width of the result.
3880
3881 Because LLVM integers use a two's complement representation, and the
3882 result is the same width as the operands, this instruction returns the
3883 correct result for both signed and unsigned integers. If a full product
3884 (e.g. ``i32`` * ``i32`` -> ``i64``) is needed, the operands should be
3885 sign-extended or zero-extended as appropriate to the width of the full
3886 product.
3887
3888 ``nuw`` and ``nsw`` stand for "No Unsigned Wrap" and "No Signed Wrap",
3889 respectively. If the ``nuw`` and/or ``nsw`` keywords are present, the
3890 result value of the ``mul`` is a :ref:`poison value <poisonvalues>` if
3891 unsigned and/or signed overflow, respectively, occurs.
3892
3893 Example:
3894 """"""""
3895
3896 .. code-block:: llvm
3897
3898       <result> = mul i32 4, %var          ; yields {i32}:result = 4 * %var
3899
3900 .. _i_fmul:
3901
3902 '``fmul``' Instruction
3903 ^^^^^^^^^^^^^^^^^^^^^^
3904
3905 Syntax:
3906 """""""
3907
3908 ::
3909
3910       <result> = fmul [fast-math flags]* <ty> <op1>, <op2>   ; yields {ty}:result
3911
3912 Overview:
3913 """""""""
3914
3915 The '``fmul``' instruction returns the product of its two operands.
3916
3917 Arguments:
3918 """"""""""
3919
3920 The two arguments to the '``fmul``' instruction must be :ref:`floating
3921 point <t_floating>` or :ref:`vector <t_vector>` of floating point values.
3922 Both arguments must have identical types.
3923
3924 Semantics:
3925 """"""""""
3926
3927 The value produced is the floating point product of the two operands.
3928 This instruction can also take any number of :ref:`fast-math
3929 flags <fastmath>`, which are optimization hints to enable otherwise
3930 unsafe floating point optimizations:
3931
3932 Example:
3933 """"""""
3934
3935 .. code-block:: llvm
3936
3937       <result> = fmul float 4.0, %var          ; yields {float}:result = 4.0 * %var
3938
3939 '``udiv``' Instruction
3940 ^^^^^^^^^^^^^^^^^^^^^^
3941
3942 Syntax:
3943 """""""
3944
3945 ::
3946
3947       <result> = udiv <ty> <op1>, <op2>         ; yields {ty}:result
3948       <result> = udiv exact <ty> <op1>, <op2>   ; yields {ty}:result
3949
3950 Overview:
3951 """""""""
3952
3953 The '``udiv``' instruction returns the quotient of its two operands.
3954
3955 Arguments:
3956 """"""""""
3957
3958 The two arguments to the '``udiv``' instruction must be
3959 :ref:`integer <t_integer>` or :ref:`vector <t_vector>` of integer values. Both
3960 arguments must have identical types.
3961
3962 Semantics:
3963 """"""""""
3964
3965 The value produced is the unsigned integer quotient of the two operands.
3966
3967 Note that unsigned integer division and signed integer division are
3968 distinct operations; for signed integer division, use '``sdiv``'.
3969
3970 Division by zero leads to undefined behavior.
3971
3972 If the ``exact`` keyword is present, the result value of the ``udiv`` is
3973 a :ref:`poison value <poisonvalues>` if %op1 is not a multiple of %op2 (as
3974 such, "((a udiv exact b) mul b) == a").
3975
3976 Example:
3977 """"""""
3978
3979 .. code-block:: llvm
3980
3981       <result> = udiv i32 4, %var          ; yields {i32}:result = 4 / %var
3982
3983 '``sdiv``' Instruction
3984 ^^^^^^^^^^^^^^^^^^^^^^
3985
3986 Syntax:
3987 """""""
3988
3989 ::
3990
3991       <result> = sdiv <ty> <op1>, <op2>         ; yields {ty}:result
3992       <result> = sdiv exact <ty> <op1>, <op2>   ; yields {ty}:result
3993
3994 Overview:
3995 """""""""
3996
3997 The '``sdiv``' instruction returns the quotient of its two operands.
3998
3999 Arguments:
4000 """"""""""
4001
4002 The two arguments to the '``sdiv``' instruction must be
4003 :ref:`integer <t_integer>` or :ref:`vector <t_vector>` of integer values. Both
4004 arguments must have identical types.
4005
4006 Semantics:
4007 """"""""""
4008
4009 The value produced is the signed integer quotient of the two operands
4010 rounded towards zero.
4011
4012 Note that signed integer division and unsigned integer division are
4013 distinct operations; for unsigned integer division, use '``udiv``'.
4014
4015 Division by zero leads to undefined behavior. Overflow also leads to
4016 undefined behavior; this is a rare case, but can occur, for example, by
4017 doing a 32-bit division of -2147483648 by -1.
4018
4019 If the ``exact`` keyword is present, the result value of the ``sdiv`` is
4020 a :ref:`poison value <poisonvalues>` if the result would be rounded.
4021
4022 Example:
4023 """"""""
4024
4025 .. code-block:: llvm
4026
4027       <result> = sdiv i32 4, %var          ; yields {i32}:result = 4 / %var
4028
4029 .. _i_fdiv:
4030
4031 '``fdiv``' Instruction
4032 ^^^^^^^^^^^^^^^^^^^^^^
4033
4034 Syntax:
4035 """""""
4036
4037 ::
4038
4039       <result> = fdiv [fast-math flags]* <ty> <op1>, <op2>   ; yields {ty}:result
4040
4041 Overview:
4042 """""""""
4043
4044 The '``fdiv``' instruction returns the quotient of its two operands.
4045
4046 Arguments:
4047 """"""""""
4048
4049 The two arguments to the '``fdiv``' instruction must be :ref:`floating
4050 point <t_floating>` or :ref:`vector <t_vector>` of floating point values.
4051 Both arguments must have identical types.
4052
4053 Semantics:
4054 """"""""""
4055
4056 The value produced is the floating point quotient of the two operands.
4057 This instruction can also take any number of :ref:`fast-math
4058 flags <fastmath>`, which are optimization hints to enable otherwise
4059 unsafe floating point optimizations:
4060
4061 Example:
4062 """"""""
4063
4064 .. code-block:: llvm
4065
4066       <result> = fdiv float 4.0, %var          ; yields {float}:result = 4.0 / %var
4067
4068 '``urem``' Instruction
4069 ^^^^^^^^^^^^^^^^^^^^^^
4070
4071 Syntax:
4072 """""""
4073
4074 ::
4075
4076       <result> = urem <ty> <op1>, <op2>   ; yields {ty}:result
4077
4078 Overview:
4079 """""""""
4080
4081 The '``urem``' instruction returns the remainder from the unsigned
4082 division of its two arguments.
4083
4084 Arguments:
4085 """"""""""
4086
4087 The two arguments to the '``urem``' instruction must be
4088 :ref:`integer <t_integer>` or :ref:`vector <t_vector>` of integer values. Both
4089 arguments must have identical types.
4090
4091 Semantics:
4092 """"""""""
4093
4094 This instruction returns the unsigned integer *remainder* of a division.
4095 This instruction always performs an unsigned division to get the
4096 remainder.
4097
4098 Note that unsigned integer remainder and signed integer remainder are
4099 distinct operations; for signed integer remainder, use '``srem``'.
4100
4101 Taking the remainder of a division by zero leads to undefined behavior.
4102
4103 Example:
4104 """"""""
4105
4106 .. code-block:: llvm
4107
4108       <result> = urem i32 4, %var          ; yields {i32}:result = 4 % %var
4109
4110 '``srem``' Instruction
4111 ^^^^^^^^^^^^^^^^^^^^^^
4112
4113 Syntax:
4114 """""""
4115
4116 ::
4117
4118       <result> = srem <ty> <op1>, <op2>   ; yields {ty}:result
4119
4120 Overview:
4121 """""""""
4122
4123 The '``srem``' instruction returns the remainder from the signed
4124 division of its two operands. This instruction can also take
4125 :ref:`vector <t_vector>` versions of the values in which case the elements
4126 must be integers.
4127
4128 Arguments:
4129 """"""""""
4130
4131 The two arguments to the '``srem``' instruction must be
4132 :ref:`integer <t_integer>` or :ref:`vector <t_vector>` of integer values. Both
4133 arguments must have identical types.
4134
4135 Semantics:
4136 """"""""""
4137
4138 This instruction returns the *remainder* of a division (where the result
4139 is either zero or has the same sign as the dividend, ``op1``), not the
4140 *modulo* operator (where the result is either zero or has the same sign
4141 as the divisor, ``op2``) of a value. For more information about the
4142 difference, see `The Math
4143 Forum <http://mathforum.org/dr.math/problems/anne.4.28.99.html>`_. For a
4144 table of how this is implemented in various languages, please see
4145 `Wikipedia: modulo
4146 operation <http://en.wikipedia.org/wiki/Modulo_operation>`_.
4147
4148 Note that signed integer remainder and unsigned integer remainder are
4149 distinct operations; for unsigned integer remainder, use '``urem``'.
4150
4151 Taking the remainder of a division by zero leads to undefined behavior.
4152 Overflow also leads to undefined behavior; this is a rare case, but can
4153 occur, for example, by taking the remainder of a 32-bit division of
4154 -2147483648 by -1. (The remainder doesn't actually overflow, but this
4155 rule lets srem be implemented using instructions that return both the
4156 result of the division and the remainder.)
4157
4158 Example:
4159 """"""""
4160
4161 .. code-block:: llvm
4162
4163       <result> = srem i32 4, %var          ; yields {i32}:result = 4 % %var
4164
4165 .. _i_frem:
4166
4167 '``frem``' Instruction
4168 ^^^^^^^^^^^^^^^^^^^^^^
4169
4170 Syntax:
4171 """""""
4172
4173 ::
4174
4175       <result> = frem [fast-math flags]* <ty> <op1>, <op2>   ; yields {ty}:result
4176
4177 Overview:
4178 """""""""
4179
4180 The '``frem``' instruction returns the remainder from the division of
4181 its two operands.
4182
4183 Arguments:
4184 """"""""""
4185
4186 The two arguments to the '``frem``' instruction must be :ref:`floating
4187 point <t_floating>` or :ref:`vector <t_vector>` of floating point values.
4188 Both arguments must have identical types.
4189
4190 Semantics:
4191 """"""""""
4192
4193 This instruction returns the *remainder* of a division. The remainder
4194 has the same sign as the dividend. This instruction can also take any
4195 number of :ref:`fast-math flags <fastmath>`, which are optimization hints
4196 to enable otherwise unsafe floating point optimizations:
4197
4198 Example:
4199 """"""""
4200
4201 .. code-block:: llvm
4202
4203       <result> = frem float 4.0, %var          ; yields {float}:result = 4.0 % %var
4204
4205 .. _bitwiseops:
4206
4207 Bitwise Binary Operations
4208 -------------------------
4209
4210 Bitwise binary operators are used to do various forms of bit-twiddling
4211 in a program. They are generally very efficient instructions and can
4212 commonly be strength reduced from other instructions. They require two
4213 operands of the same type, execute an operation on them, and produce a
4214 single value. The resulting value is the same type as its operands.
4215
4216 '``shl``' Instruction
4217 ^^^^^^^^^^^^^^^^^^^^^
4218
4219 Syntax:
4220 """""""
4221
4222 ::
4223
4224       <result> = shl <ty> <op1>, <op2>           ; yields {ty}:result
4225       <result> = shl nuw <ty> <op1>, <op2>       ; yields {ty}:result
4226       <result> = shl nsw <ty> <op1>, <op2>       ; yields {ty}:result
4227       <result> = shl nuw nsw <ty> <op1>, <op2>   ; yields {ty}:result
4228
4229 Overview:
4230 """""""""
4231
4232 The '``shl``' instruction returns the first operand shifted to the left
4233 a specified number of bits.
4234
4235 Arguments:
4236 """"""""""
4237
4238 Both arguments to the '``shl``' instruction must be the same
4239 :ref:`integer <t_integer>` or :ref:`vector <t_vector>` of integer type.
4240 '``op2``' is treated as an unsigned value.
4241
4242 Semantics:
4243 """"""""""
4244
4245 The value produced is ``op1`` \* 2\ :sup:`op2` mod 2\ :sup:`n`,
4246 where ``n`` is the width of the result. If ``op2`` is (statically or
4247 dynamically) negative or equal to or larger than the number of bits in
4248 ``op1``, the result is undefined. If the arguments are vectors, each
4249 vector element of ``op1`` is shifted by the corresponding shift amount
4250 in ``op2``.
4251
4252 If the ``nuw`` keyword is present, then the shift produces a :ref:`poison
4253 value <poisonvalues>` if it shifts out any non-zero bits. If the
4254 ``nsw`` keyword is present, then the shift produces a :ref:`poison
4255 value <poisonvalues>` if it shifts out any bits that disagree with the
4256 resultant sign bit. As such, NUW/NSW have the same semantics as they
4257 would if the shift were expressed as a mul instruction with the same
4258 nsw/nuw bits in (mul %op1, (shl 1, %op2)).
4259
4260 Example:
4261 """"""""
4262
4263 .. code-block:: llvm
4264
4265       <result> = shl i32 4, %var   ; yields {i32}: 4 << %var
4266       <result> = shl i32 4, 2      ; yields {i32}: 16
4267       <result> = shl i32 1, 10     ; yields {i32}: 1024
4268       <result> = shl i32 1, 32     ; undefined
4269       <result> = shl <2 x i32> < i32 1, i32 1>, < i32 1, i32 2>   ; yields: result=<2 x i32> < i32 2, i32 4>
4270
4271 '``lshr``' Instruction
4272 ^^^^^^^^^^^^^^^^^^^^^^
4273
4274 Syntax:
4275 """""""
4276
4277 ::
4278
4279       <result> = lshr <ty> <op1>, <op2>         ; yields {ty}:result
4280       <result> = lshr exact <ty> <op1>, <op2>   ; yields {ty}:result
4281
4282 Overview:
4283 """""""""
4284
4285 The '``lshr``' instruction (logical shift right) returns the first
4286 operand shifted to the right a specified number of bits with zero fill.
4287
4288 Arguments:
4289 """"""""""
4290
4291 Both arguments to the '``lshr``' instruction must be the same
4292 :ref:`integer <t_integer>` or :ref:`vector <t_vector>` of integer type.
4293 '``op2``' is treated as an unsigned value.
4294
4295 Semantics:
4296 """"""""""
4297
4298 This instruction always performs a logical shift right operation. The
4299 most significant bits of the result will be filled with zero bits after
4300 the shift. If ``op2`` is (statically or dynamically) equal to or larger
4301 than the number of bits in ``op1``, the result is undefined. If the
4302 arguments are vectors, each vector element of ``op1`` is shifted by the
4303 corresponding shift amount in ``op2``.
4304
4305 If the ``exact`` keyword is present, the result value of the ``lshr`` is
4306 a :ref:`poison value <poisonvalues>` if any of the bits shifted out are
4307 non-zero.
4308
4309 Example:
4310 """"""""
4311
4312 .. code-block:: llvm
4313
4314       <result> = lshr i32 4, 1   ; yields {i32}:result = 2
4315       <result> = lshr i32 4, 2   ; yields {i32}:result = 1
4316       <result> = lshr i8  4, 3   ; yields {i8}:result = 0
4317       <result> = lshr i8 -2, 1   ; yields {i8}:result = 0x7F
4318       <result> = lshr i32 1, 32  ; undefined
4319       <result> = lshr <2 x i32> < i32 -2, i32 4>, < i32 1, i32 2>   ; yields: result=<2 x i32> < i32 0x7FFFFFFF, i32 1>
4320
4321 '``ashr``' Instruction
4322 ^^^^^^^^^^^^^^^^^^^^^^
4323
4324 Syntax:
4325 """""""
4326
4327 ::
4328
4329       <result> = ashr <ty> <op1>, <op2>         ; yields {ty}:result
4330       <result> = ashr exact <ty> <op1>, <op2>   ; yields {ty}:result
4331
4332 Overview:
4333 """""""""
4334
4335 The '``ashr``' instruction (arithmetic shift right) returns the first
4336 operand shifted to the right a specified number of bits with sign
4337 extension.
4338
4339 Arguments:
4340 """"""""""
4341
4342 Both arguments to the '``ashr``' instruction must be the same
4343 :ref:`integer <t_integer>` or :ref:`vector <t_vector>` of integer type.
4344 '``op2``' is treated as an unsigned value.
4345
4346 Semantics:
4347 """"""""""
4348
4349 This instruction always performs an arithmetic shift right operation,
4350 The most significant bits of the result will be filled with the sign bit
4351 of ``op1``. If ``op2`` is (statically or dynamically) equal to or larger
4352 than the number of bits in ``op1``, the result is undefined. If the
4353 arguments are vectors, each vector element of ``op1`` is shifted by the
4354 corresponding shift amount in ``op2``.
4355
4356 If the ``exact`` keyword is present, the result value of the ``ashr`` is
4357 a :ref:`poison value <poisonvalues>` if any of the bits shifted out are
4358 non-zero.
4359
4360 Example:
4361 """"""""
4362
4363 .. code-block:: llvm
4364
4365       <result> = ashr i32 4, 1   ; yields {i32}:result = 2
4366       <result> = ashr i32 4, 2   ; yields {i32}:result = 1
4367       <result> = ashr i8  4, 3   ; yields {i8}:result = 0
4368       <result> = ashr i8 -2, 1   ; yields {i8}:result = -1
4369       <result> = ashr i32 1, 32  ; undefined
4370       <result> = ashr <2 x i32> < i32 -2, i32 4>, < i32 1, i32 3>   ; yields: result=<2 x i32> < i32 -1, i32 0>
4371
4372 '``and``' Instruction
4373 ^^^^^^^^^^^^^^^^^^^^^
4374
4375 Syntax:
4376 """""""
4377
4378 ::
4379
4380       <result> = and <ty> <op1>, <op2>   ; yields {ty}:result
4381
4382 Overview:
4383 """""""""
4384
4385 The '``and``' instruction returns the bitwise logical and of its two
4386 operands.
4387
4388 Arguments:
4389 """"""""""
4390
4391 The two arguments to the '``and``' instruction must be
4392 :ref:`integer <t_integer>` or :ref:`vector <t_vector>` of integer values. Both
4393 arguments must have identical types.
4394
4395 Semantics:
4396 """"""""""
4397
4398 The truth table used for the '``and``' instruction is:
4399
4400 +-----+-----+-----+
4401 | In0 | In1 | Out |
4402 +-----+-----+-----+
4403 |   0 |   0 |   0 |
4404 +-----+-----+-----+
4405 |   0 |   1 |   0 |
4406 +-----+-----+-----+
4407 |   1 |   0 |   0 |
4408 +-----+-----+-----+
4409 |   1 |   1 |   1 |
4410 +-----+-----+-----+
4411
4412 Example:
4413 """"""""
4414
4415 .. code-block:: llvm
4416
4417       <result> = and i32 4, %var         ; yields {i32}:result = 4 & %var
4418       <result> = and i32 15, 40          ; yields {i32}:result = 8
4419       <result> = and i32 4, 8            ; yields {i32}:result = 0
4420
4421 '``or``' Instruction
4422 ^^^^^^^^^^^^^^^^^^^^
4423
4424 Syntax:
4425 """""""
4426
4427 ::
4428
4429       <result> = or <ty> <op1>, <op2>   ; yields {ty}:result
4430
4431 Overview:
4432 """""""""
4433
4434 The '``or``' instruction returns the bitwise logical inclusive or of its
4435 two operands.
4436
4437 Arguments:
4438 """"""""""
4439
4440 The two arguments to the '``or``' instruction must be
4441 :ref:`integer <t_integer>` or :ref:`vector <t_vector>` of integer values. Both
4442 arguments must have identical types.
4443
4444 Semantics:
4445 """"""""""
4446
4447 The truth table used for the '``or``' instruction is:
4448
4449 +-----+-----+-----+
4450 | In0 | In1 | Out |
4451 +-----+-----+-----+
4452 |   0 |   0 |   0 |
4453 +-----+-----+-----+
4454 |   0 |   1 |   1 |
4455 +-----+-----+-----+
4456 |   1 |   0 |   1 |
4457 +-----+-----+-----+
4458 |   1 |   1 |   1 |
4459 +-----+-----+-----+
4460
4461 Example:
4462 """"""""
4463
4464 ::
4465
4466       <result> = or i32 4, %var         ; yields {i32}:result = 4 | %var
4467       <result> = or i32 15, 40          ; yields {i32}:result = 47
4468       <result> = or i32 4, 8            ; yields {i32}:result = 12
4469
4470 '``xor``' Instruction
4471 ^^^^^^^^^^^^^^^^^^^^^
4472
4473 Syntax:
4474 """""""
4475
4476 ::
4477
4478       <result> = xor <ty> <op1>, <op2>   ; yields {ty}:result
4479
4480 Overview:
4481 """""""""
4482
4483 The '``xor``' instruction returns the bitwise logical exclusive or of
4484 its two operands. The ``xor`` is used to implement the "one's
4485 complement" operation, which is the "~" operator in C.
4486
4487 Arguments:
4488 """"""""""
4489
4490 The two arguments to the '``xor``' instruction must be
4491 :ref:`integer <t_integer>` or :ref:`vector <t_vector>` of integer values. Both
4492 arguments must have identical types.
4493
4494 Semantics:
4495 """"""""""
4496
4497 The truth table used for the '``xor``' instruction is:
4498
4499 +-----+-----+-----+
4500 | In0 | In1 | Out |
4501 +-----+-----+-----+
4502 |   0 |   0 |   0 |
4503 +-----+-----+-----+
4504 |   0 |   1 |   1 |
4505 +-----+-----+-----+
4506 |   1 |   0 |   1 |
4507 +-----+-----+-----+
4508 |   1 |   1 |   0 |
4509 +-----+-----+-----+
4510
4511 Example:
4512 """"""""
4513
4514 .. code-block:: llvm
4515
4516       <result> = xor i32 4, %var         ; yields {i32}:result = 4 ^ %var
4517       <result> = xor i32 15, 40          ; yields {i32}:result = 39
4518       <result> = xor i32 4, 8            ; yields {i32}:result = 12
4519       <result> = xor i32 %V, -1          ; yields {i32}:result = ~%V
4520
4521 Vector Operations
4522 -----------------
4523
4524 LLVM supports several instructions to represent vector operations in a
4525 target-independent manner. These instructions cover the element-access
4526 and vector-specific operations needed to process vectors effectively.
4527 While LLVM does directly support these vector operations, many
4528 sophisticated algorithms will want to use target-specific intrinsics to
4529 take full advantage of a specific target.
4530
4531 .. _i_extractelement:
4532
4533 '``extractelement``' Instruction
4534 ^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^
4535
4536 Syntax:
4537 """""""
4538
4539 ::
4540
4541       <result> = extractelement <n x <ty>> <val>, <ty2> <idx>  ; yields <ty>
4542
4543 Overview:
4544 """""""""
4545
4546 The '``extractelement``' instruction extracts a single scalar element
4547 from a vector at a specified index.
4548
4549 Arguments:
4550 """"""""""
4551
4552 The first operand of an '``extractelement``' instruction is a value of
4553 :ref:`vector <t_vector>` type. The second operand is an index indicating
4554 the position from which to extract the element. The index may be a
4555 variable of any integer type.
4556
4557 Semantics:
4558 """"""""""
4559
4560 The result is a scalar of the same type as the element type of ``val``.
4561 Its value is the value at position ``idx`` of ``val``. If ``idx``
4562 exceeds the length of ``val``, the results are undefined.
4563
4564 Example:
4565 """"""""
4566
4567 .. code-block:: llvm
4568
4569       <result> = extractelement <4 x i32> %vec, i32 0    ; yields i32
4570
4571 .. _i_insertelement:
4572
4573 '``insertelement``' Instruction
4574 ^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^
4575
4576 Syntax:
4577 """""""
4578
4579 ::
4580
4581       <result> = insertelement <n x <ty>> <val>, <ty> <elt>, <ty2> <idx>    ; yields <n x <ty>>
4582
4583 Overview:
4584 """""""""
4585
4586 The '``insertelement``' instruction inserts a scalar element into a
4587 vector at a specified index.
4588
4589 Arguments:
4590 """"""""""
4591
4592 The first operand of an '``insertelement``' instruction is a value of
4593 :ref:`vector <t_vector>` type. The second operand is a scalar value whose
4594 type must equal the element type of the first operand. The third operand
4595 is an index indicating the position at which to insert the value. The
4596 index may be a variable of any integer type.
4597
4598 Semantics:
4599 """"""""""
4600
4601 The result is a vector of the same type as ``val``. Its element values
4602 are those of ``val`` except at position ``idx``, where it gets the value
4603 ``elt``. If ``idx`` exceeds the length of ``val``, the results are
4604 undefined.
4605
4606 Example:
4607 """"""""
4608
4609 .. code-block:: llvm
4610
4611       <result> = insertelement <4 x i32> %vec, i32 1, i32 0    ; yields <4 x i32>
4612
4613 .. _i_shufflevector:
4614
4615 '``shufflevector``' Instruction
4616 ^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^
4617
4618 Syntax:
4619 """""""
4620
4621 ::
4622
4623       <result> = shufflevector <n x <ty>> <v1>, <n x <ty>> <v2>, <m x i32> <mask>    ; yields <m x <ty>>
4624
4625 Overview:
4626 """""""""
4627
4628 The '``shufflevector``' instruction constructs a permutation of elements
4629 from two input vectors, returning a vector with the same element type as
4630 the input and length that is the same as the shuffle mask.
4631
4632 Arguments:
4633 """"""""""
4634
4635 The first two operands of a '``shufflevector``' instruction are vectors
4636 with the same type. The third argument is a shuffle mask whose element
4637 type is always 'i32'. The result of the instruction is a vector whose
4638 length is the same as the shuffle mask and whose element type is the
4639 same as the element type of the first two operands.
4640
4641 The shuffle mask operand is required to be a constant vector with either
4642 constant integer or undef values.
4643
4644 Semantics:
4645 """"""""""
4646
4647 The elements of the two input vectors are numbered from left to right
4648 across both of the vectors. The shuffle mask operand specifies, for each
4649 element of the result vector, which element of the two input vectors the
4650 result element gets. The element selector may be undef (meaning "don't
4651 care") and the second operand may be undef if performing a shuffle from
4652 only one vector.
4653
4654 Example:
4655 """"""""
4656
4657 .. code-block:: llvm
4658
4659       <result> = shufflevector <4 x i32> %v1, <4 x i32> %v2,
4660                               <4 x i32> <i32 0, i32 4, i32 1, i32 5>  ; yields <4 x i32>
4661       <result> = shufflevector <4 x i32> %v1, <4 x i32> undef,
4662                               <4 x i32> <i32 0, i32 1, i32 2, i32 3>  ; yields <4 x i32> - Identity shuffle.
4663       <result> = shufflevector <8 x i32> %v1, <8 x i32> undef,
4664                               <4 x i32> <i32 0, i32 1, i32 2, i32 3>  ; yields <4 x i32>
4665       <result> = shufflevector <4 x i32> %v1, <4 x i32> %v2,
4666                               <8 x i32> <i32 0, i32 1, i32 2, i32 3, i32 4, i32 5, i32 6, i32 7 >  ; yields <8 x i32>
4667
4668 Aggregate Operations
4669 --------------------
4670
4671 LLVM supports several instructions for working with
4672 :ref:`aggregate <t_aggregate>` values.
4673
4674 .. _i_extractvalue:
4675
4676 '``extractvalue``' Instruction
4677 ^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^
4678
4679 Syntax:
4680 """""""
4681
4682 ::
4683
4684       <result> = extractvalue <aggregate type> <val>, <idx>{, <idx>}*
4685
4686 Overview:
4687 """""""""
4688
4689 The '``extractvalue``' instruction extracts the value of a member field
4690 from an :ref:`aggregate <t_aggregate>` value.
4691
4692 Arguments:
4693 """"""""""
4694
4695 The first operand of an '``extractvalue``' instruction is a value of
4696 :ref:`struct <t_struct>` or :ref:`array <t_array>` type. The operands are
4697 constant indices to specify which value to extract in a similar manner
4698 as indices in a '``getelementptr``' instruction.
4699
4700 The major differences to ``getelementptr`` indexing are:
4701
4702 -  Since the value being indexed is not a pointer, the first index is
4703    omitted and assumed to be zero.
4704 -  At least one index must be specified.
4705 -  Not only struct indices but also array indices must be in bounds.
4706
4707 Semantics:
4708 """"""""""
4709
4710 The result is the value at the position in the aggregate specified by
4711 the index operands.
4712
4713 Example:
4714 """"""""
4715
4716 .. code-block:: llvm
4717
4718       <result> = extractvalue {i32, float} %agg, 0    ; yields i32
4719
4720 .. _i_insertvalue:
4721
4722 '``insertvalue``' Instruction
4723 ^^^^^^^^^^^^^^^^^^^^^^^^^^^^^
4724
4725 Syntax:
4726 """""""
4727
4728 ::
4729
4730       <result> = insertvalue <aggregate type> <val>, <ty> <elt>, <idx>{, <idx>}*    ; yields <aggregate type>
4731
4732 Overview:
4733 """""""""
4734
4735 The '``insertvalue``' instruction inserts a value into a member field in
4736 an :ref:`aggregate <t_aggregate>` value.
4737
4738 Arguments:
4739 """"""""""
4740
4741 The first operand of an '``insertvalue``' instruction is a value of
4742 :ref:`struct <t_struct>` or :ref:`array <t_array>` type. The second operand is
4743 a first-class value to insert. The following operands are constant
4744 indices indicating the position at which to insert the value in a
4745 similar manner as indices in a '``extractvalue``' instruction. The value
4746 to insert must have the same type as the value identified by the
4747 indices.
4748
4749 Semantics:
4750 """"""""""
4751
4752 The result is an aggregate of the same type as ``val``. Its value is
4753 that of ``val`` except that the value at the position specified by the
4754 indices is that of ``elt``.
4755
4756 Example:
4757 """"""""
4758
4759 .. code-block:: llvm
4760
4761       %agg1 = insertvalue {i32, float} undef, i32 1, 0              ; yields {i32 1, float undef}
4762       %agg2 = insertvalue {i32, float} %agg1, float %val, 1         ; yields {i32 1, float %val}
4763       %agg3 = insertvalue {i32, {float}} %agg1, float %val, 1, 0    ; yields {i32 1, float %val}
4764
4765 .. _memoryops:
4766
4767 Memory Access and Addressing Operations
4768 ---------------------------------------
4769
4770 A key design point of an SSA-based representation is how it represents
4771 memory. In LLVM, no memory locations are in SSA form, which makes things
4772 very simple. This section describes how to read, write, and allocate
4773 memory in LLVM.
4774
4775 .. _i_alloca:
4776
4777 '``alloca``' Instruction
4778 ^^^^^^^^^^^^^^^^^^^^^^^^
4779
4780 Syntax:
4781 """""""
4782
4783 ::
4784
4785       <result> = alloca [inalloca] <type> [, <ty> <NumElements>] [, align <alignment>]     ; yields {type*}:result
4786
4787 Overview:
4788 """""""""
4789
4790 The '``alloca``' instruction allocates memory on the stack frame of the
4791 currently executing function, to be automatically released when this
4792 function returns to its caller. The object is always allocated in the
4793 generic address space (address space zero).
4794
4795 Arguments:
4796 """"""""""
4797
4798 The '``alloca``' instruction allocates ``sizeof(<type>)*NumElements``
4799 bytes of memory on the runtime stack, returning a pointer of the
4800 appropriate type to the program. If "NumElements" is specified, it is
4801 the number of elements allocated, otherwise "NumElements" is defaulted
4802 to be one. If a constant alignment is specified, the value result of the
4803 allocation is guaranteed to be aligned to at least that boundary. If not
4804 specified, or if zero, the target can choose to align the allocation on
4805 any convenient boundary compatible with the type.
4806
4807 '``type``' may be any sized type.
4808
4809 Semantics:
4810 """"""""""
4811
4812 Memory is allocated; a pointer is returned. The operation is undefined
4813 if there is insufficient stack space for the allocation. '``alloca``'d
4814 memory is automatically released when the function returns. The
4815 '``alloca``' instruction is commonly used to represent automatic
4816 variables that must have an address available. When the function returns
4817 (either with the ``ret`` or ``resume`` instructions), the memory is
4818 reclaimed. Allocating zero bytes is legal, but the result is undefined.
4819 The order in which memory is allocated (ie., which way the stack grows)
4820 is not specified.
4821
4822 Example:
4823 """"""""
4824
4825 .. code-block:: llvm
4826
4827       %ptr = alloca i32                             ; yields {i32*}:ptr
4828       %ptr = alloca i32, i32 4                      ; yields {i32*}:ptr
4829       %ptr = alloca i32, i32 4, align 1024          ; yields {i32*}:ptr
4830       %ptr = alloca i32, align 1024                 ; yields {i32*}:ptr
4831
4832 .. _i_load:
4833
4834 '``load``' Instruction
4835 ^^^^^^^^^^^^^^^^^^^^^^
4836
4837 Syntax:
4838 """""""
4839
4840 ::
4841
4842       <result> = load [volatile] <ty>* <pointer>[, align <alignment>][, !nontemporal !<index>][, !invariant.load !<index>]
4843       <result> = load atomic [volatile] <ty>* <pointer> [singlethread] <ordering>, align <alignment>
4844       !<index> = !{ i32 1 }
4845
4846 Overview:
4847 """""""""
4848
4849 The '``load``' instruction is used to read from memory.
4850
4851 Arguments:
4852 """"""""""
4853
4854 The argument to the ``load`` instruction specifies the memory address
4855 from which to load. The pointer must point to a :ref:`first
4856 class <t_firstclass>` type. If the ``load`` is marked as ``volatile``,
4857 then the optimizer is not allowed to modify the number or order of
4858 execution of this ``load`` with other :ref:`volatile
4859 operations <volatile>`.
4860
4861 If the ``load`` is marked as ``atomic``, it takes an extra
4862 :ref:`ordering <ordering>` and optional ``singlethread`` argument. The
4863 ``release`` and ``acq_rel`` orderings are not valid on ``load``
4864 instructions. Atomic loads produce :ref:`defined <memmodel>` results
4865 when they may see multiple atomic stores. The type of the pointee must
4866 be an integer type whose bit width is a power of two greater than or
4867 equal to eight and less than or equal to a target-specific size limit.
4868 ``align`` must be explicitly specified on atomic loads, and the load has
4869 undefined behavior if the alignment is not set to a value which is at
4870 least the size in bytes of the pointee. ``!nontemporal`` does not have
4871 any defined semantics for atomic loads.
4872
4873 The optional constant ``align`` argument specifies the alignment of the
4874 operation (that is, the alignment of the memory address). A value of 0
4875 or an omitted ``align`` argument means that the operation has the ABI
4876 alignment for the target. It is the responsibility of the code emitter
4877 to ensure that the alignment information is correct. Overestimating the
4878 alignment results in undefined behavior. Underestimating the alignment
4879 may produce less efficient code. An alignment of 1 is always safe.
4880
4881 The optional ``!nontemporal`` metadata must reference a single
4882 metadata name ``<index>`` corresponding to a metadata node with one
4883 ``i32`` entry of value 1. The existence of the ``!nontemporal``
4884 metadata on the instruction tells the optimizer and code generator
4885 that this load is not expected to be reused in the cache. The code
4886 generator may select special instructions to save cache bandwidth, such
4887 as the ``MOVNT`` instruction on x86.
4888
4889 The optional ``!invariant.load`` metadata must reference a single
4890 metadata name ``<index>`` corresponding to a metadata node with no
4891 entries. The existence of the ``!invariant.load`` metadata on the
4892 instruction tells the optimizer and code generator that this load
4893 address points to memory which does not change value during program
4894 execution. The optimizer may then move this load around, for example, by
4895 hoisting it out of loops using loop invariant code motion.
4896
4897 Semantics:
4898 """"""""""
4899
4900 The location of memory pointed to is loaded. If the value being loaded
4901 is of scalar type then the number of bytes read does not exceed the
4902 minimum number of bytes needed to hold all bits of the type. For
4903 example, loading an ``i24`` reads at most three bytes. When loading a
4904 value of a type like ``i20`` with a size that is not an integral number
4905 of bytes, the result is undefined if the value was not originally
4906 written using a store of the same type.
4907
4908 Examples:
4909 """""""""
4910
4911 .. code-block:: llvm
4912
4913       %ptr = alloca i32                               ; yields {i32*}:ptr
4914       store i32 3, i32* %ptr                          ; yields {void}
4915       %val = load i32* %ptr                           ; yields {i32}:val = i32 3
4916
4917 .. _i_store:
4918
4919 '``store``' Instruction
4920 ^^^^^^^^^^^^^^^^^^^^^^^
4921
4922 Syntax:
4923 """""""
4924
4925 ::
4926
4927       store [volatile] <ty> <value>, <ty>* <pointer>[, align <alignment>][, !nontemporal !<index>]        ; yields {void}
4928       store atomic [volatile] <ty> <value>, <ty>* <pointer> [singlethread] <ordering>, align <alignment>  ; yields {void}
4929
4930 Overview:
4931 """""""""
4932
4933 The '``store``' instruction is used to write to memory.
4934
4935 Arguments:
4936 """"""""""
4937
4938 There are two arguments to the ``store`` instruction: a value to store
4939 and an address at which to store it. The type of the ``<pointer>``
4940 operand must be a pointer to the :ref:`first class <t_firstclass>` type of
4941 the ``<value>`` operand. If the ``store`` is marked as ``volatile``,
4942 then the optimizer is not allowed to modify the number or order of
4943 execution of this ``store`` with other :ref:`volatile
4944 operations <volatile>`.
4945
4946 If the ``store`` is marked as ``atomic``, it takes an extra
4947 :ref:`ordering <ordering>` and optional ``singlethread`` argument. The
4948 ``acquire`` and ``acq_rel`` orderings aren't valid on ``store``
4949 instructions. Atomic loads produce :ref:`defined <memmodel>` results
4950 when they may see multiple atomic stores. The type of the pointee must
4951 be an integer type whose bit width is a power of two greater than or
4952 equal to eight and less than or equal to a target-specific size limit.
4953 ``align`` must be explicitly specified on atomic stores, and the store
4954 has undefined behavior if the alignment is not set to a value which is
4955 at least the size in bytes of the pointee. ``!nontemporal`` does not
4956 have any defined semantics for atomic stores.
4957
4958 The optional constant ``align`` argument specifies the alignment of the
4959 operation (that is, the alignment of the memory address). A value of 0
4960 or an omitted ``align`` argument means that the operation has the ABI
4961 alignment for the target. It is the responsibility of the code emitter
4962 to ensure that the alignment information is correct. Overestimating the
4963 alignment results in undefined behavior. Underestimating the
4964 alignment may produce less efficient code. An alignment of 1 is always
4965 safe.
4966
4967 The optional ``!nontemporal`` metadata must reference a single metadata
4968 name ``<index>`` corresponding to a metadata node with one ``i32`` entry of
4969 value 1. The existence of the ``!nontemporal`` metadata on the instruction
4970 tells the optimizer and code generator that this load is not expected to
4971 be reused in the cache. The code generator may select special
4972 instructions to save cache bandwidth, such as the MOVNT instruction on
4973 x86.
4974
4975 Semantics:
4976 """"""""""
4977
4978 The contents of memory are updated to contain ``<value>`` at the
4979 location specified by the ``<pointer>`` operand. If ``<value>`` is
4980 of scalar type then the number of bytes written does not exceed the
4981 minimum number of bytes needed to hold all bits of the type. For
4982 example, storing an ``i24`` writes at most three bytes. When writing a
4983 value of a type like ``i20`` with a size that is not an integral number
4984 of bytes, it is unspecified what happens to the extra bits that do not
4985 belong to the type, but they will typically be overwritten.
4986
4987 Example:
4988 """"""""
4989
4990 .. code-block:: llvm
4991
4992       %ptr = alloca i32                               ; yields {i32*}:ptr
4993       store i32 3, i32* %ptr                          ; yields {void}
4994       %val = load i32* %ptr                           ; yields {i32}:val = i32 3
4995
4996 .. _i_fence:
4997
4998 '``fence``' Instruction
4999 ^^^^^^^^^^^^^^^^^^^^^^^
5000
5001 Syntax:
5002 """""""
5003
5004 ::
5005
5006       fence [singlethread] <ordering>                   ; yields {void}
5007
5008 Overview:
5009 """""""""
5010
5011 The '``fence``' instruction is used to introduce happens-before edges
5012 between operations.
5013
5014 Arguments:
5015 """"""""""
5016
5017 '``fence``' instructions take an :ref:`ordering <ordering>` argument which
5018 defines what *synchronizes-with* edges they add. They can only be given
5019 ``acquire``, ``release``, ``acq_rel``, and ``seq_cst`` orderings.
5020
5021 Semantics:
5022 """"""""""
5023
5024 A fence A which has (at least) ``release`` ordering semantics
5025 *synchronizes with* a fence B with (at least) ``acquire`` ordering
5026 semantics if and only if there exist atomic operations X and Y, both
5027 operating on some atomic object M, such that A is sequenced before X, X
5028 modifies M (either directly or through some side effect of a sequence
5029 headed by X), Y is sequenced before B, and Y observes M. This provides a
5030 *happens-before* dependency between A and B. Rather than an explicit
5031 ``fence``, one (but not both) of the atomic operations X or Y might
5032 provide a ``release`` or ``acquire`` (resp.) ordering constraint and
5033 still *synchronize-with* the explicit ``fence`` and establish the
5034 *happens-before* edge.
5035
5036 A ``fence`` which has ``seq_cst`` ordering, in addition to having both
5037 ``acquire`` and ``release`` semantics specified above, participates in
5038 the global program order of other ``seq_cst`` operations and/or fences.
5039
5040 The optional ":ref:`singlethread <singlethread>`" argument specifies
5041 that the fence only synchronizes with other fences in the same thread.
5042 (This is useful for interacting with signal handlers.)
5043
5044 Example:
5045 """"""""
5046
5047 .. code-block:: llvm
5048
5049       fence acquire                          ; yields {void}
5050       fence singlethread seq_cst             ; yields {void}
5051
5052 .. _i_cmpxchg:
5053
5054 '``cmpxchg``' Instruction
5055 ^^^^^^^^^^^^^^^^^^^^^^^^^
5056
5057 Syntax:
5058 """""""
5059
5060 ::
5061
5062       cmpxchg [volatile] <ty>* <pointer>, <ty> <cmp>, <ty> <new> [singlethread] <success ordering> <failure ordering> ; yields {ty}
5063
5064 Overview:
5065 """""""""
5066
5067 The '``cmpxchg``' instruction is used to atomically modify memory. It
5068 loads a value in memory and compares it to a given value. If they are
5069 equal, it stores a new value into the memory.
5070
5071 Arguments:
5072 """"""""""
5073
5074 There are three arguments to the '``cmpxchg``' instruction: an address
5075 to operate on, a value to compare to the value currently be at that
5076 address, and a new value to place at that address if the compared values
5077 are equal. The type of '<cmp>' must be an integer type whose bit width
5078 is a power of two greater than or equal to eight and less than or equal
5079 to a target-specific size limit. '<cmp>' and '<new>' must have the same
5080 type, and the type of '<pointer>' must be a pointer to that type. If the
5081 ``cmpxchg`` is marked as ``volatile``, then the optimizer is not allowed
5082 to modify the number or order of execution of this ``cmpxchg`` with
5083 other :ref:`volatile operations <volatile>`.
5084
5085 The success and failure :ref:`ordering <ordering>` arguments specify how this
5086 ``cmpxchg`` synchronizes with other atomic operations. The both ordering
5087 parameters must be at least ``monotonic``, the ordering constraint on failure
5088 must be no stronger than that on success, and the failure ordering cannot be
5089 either ``release`` or ``acq_rel``.
5090
5091 The optional "``singlethread``" argument declares that the ``cmpxchg``
5092 is only atomic with respect to code (usually signal handlers) running in
5093 the same thread as the ``cmpxchg``. Otherwise the cmpxchg is atomic with
5094 respect to all other code in the system.
5095
5096 The pointer passed into cmpxchg must have alignment greater than or
5097 equal to the size in memory of the operand.
5098
5099 Semantics:
5100 """"""""""
5101
5102 The contents of memory at the location specified by the '``<pointer>``'
5103 operand is read and compared to '``<cmp>``'; if the read value is the
5104 equal, '``<new>``' is written. The original value at the location is
5105 returned.
5106
5107 A successful ``cmpxchg`` is a read-modify-write instruction for the purpose of
5108 identifying release sequences. A failed ``cmpxchg`` is equivalent to an atomic
5109 load with an ordering parameter determined the second ordering parameter.
5110
5111 Example:
5112 """"""""
5113
5114 .. code-block:: llvm
5115
5116     entry:
5117       %orig = atomic load i32* %ptr unordered                   ; yields {i32}
5118       br label %loop
5119
5120     loop:
5121       %cmp = phi i32 [ %orig, %entry ], [%old, %loop]
5122       %squared = mul i32 %cmp, %cmp
5123       %old = cmpxchg i32* %ptr, i32 %cmp, i32 %squared acq_rel monotonic ; yields {i32}
5124       %success = icmp eq i32 %cmp, %old
5125       br i1 %success, label %done, label %loop
5126
5127     done:
5128       ...
5129
5130 .. _i_atomicrmw:
5131
5132 '``atomicrmw``' Instruction
5133 ^^^^^^^^^^^^^^^^^^^^^^^^^^^
5134
5135 Syntax:
5136 """""""
5137
5138 ::
5139
5140       atomicrmw [volatile] <operation> <ty>* <pointer>, <ty> <value> [singlethread] <ordering>                   ; yields {ty}
5141
5142 Overview:
5143 """""""""
5144
5145 The '``atomicrmw``' instruction is used to atomically modify memory.
5146
5147 Arguments:
5148 """"""""""
5149
5150 There are three arguments to the '``atomicrmw``' instruction: an
5151 operation to apply, an address whose value to modify, an argument to the
5152 operation. The operation must be one of the following keywords:
5153
5154 -  xchg
5155 -  add
5156 -  sub
5157 -  and
5158 -  nand
5159 -  or
5160 -  xor
5161 -  max
5162 -  min
5163 -  umax
5164 -  umin
5165
5166 The type of '<value>' must be an integer type whose bit width is a power
5167 of two greater than or equal to eight and less than or equal to a
5168 target-specific size limit. The type of the '``<pointer>``' operand must
5169 be a pointer to that type. If the ``atomicrmw`` is marked as
5170 ``volatile``, then the optimizer is not allowed to modify the number or
5171 order of execution of this ``atomicrmw`` with other :ref:`volatile
5172 operations <volatile>`.
5173
5174 Semantics:
5175 """"""""""
5176
5177 The contents of memory at the location specified by the '``<pointer>``'
5178 operand are atomically read, modified, and written back. The original
5179 value at the location is returned. The modification is specified by the
5180 operation argument:
5181
5182 -  xchg: ``*ptr = val``
5183 -  add: ``*ptr = *ptr + val``
5184 -  sub: ``*ptr = *ptr - val``
5185 -  and: ``*ptr = *ptr & val``
5186 -  nand: ``*ptr = ~(*ptr & val)``
5187 -  or: ``*ptr = *ptr | val``
5188 -  xor: ``*ptr = *ptr ^ val``
5189 -  max: ``*ptr = *ptr > val ? *ptr : val`` (using a signed comparison)
5190 -  min: ``*ptr = *ptr < val ? *ptr : val`` (using a signed comparison)
5191 -  umax: ``*ptr = *ptr > val ? *ptr : val`` (using an unsigned
5192    comparison)
5193 -  umin: ``*ptr = *ptr < val ? *ptr : val`` (using an unsigned
5194    comparison)
5195
5196 Example:
5197 """"""""
5198
5199 .. code-block:: llvm
5200
5201       %old = atomicrmw add i32* %ptr, i32 1 acquire                        ; yields {i32}
5202
5203 .. _i_getelementptr:
5204
5205 '``getelementptr``' Instruction
5206 ^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^
5207
5208 Syntax:
5209 """""""
5210
5211 ::
5212
5213       <result> = getelementptr <pty>* <ptrval>{, <ty> <idx>}*
5214       <result> = getelementptr inbounds <pty>* <ptrval>{, <ty> <idx>}*
5215       <result> = getelementptr <ptr vector> ptrval, <vector index type> idx
5216
5217 Overview:
5218 """""""""
5219
5220 The '``getelementptr``' instruction is used to get the address of a
5221 subelement of an :ref:`aggregate <t_aggregate>` data structure. It performs
5222 address calculation only and does not access memory.
5223
5224 Arguments:
5225 """"""""""
5226
5227 The first argument is always a pointer or a vector of pointers, and
5228 forms the basis of the calculation. The remaining arguments are indices
5229 that indicate which of the elements of the aggregate object are indexed.
5230 The interpretation of each index is dependent on the type being indexed
5231 into. The first index always indexes the pointer value given as the
5232 first argument, the second index indexes a value of the type pointed to
5233 (not necessarily the value directly pointed to, since the first index
5234 can be non-zero), etc. The first type indexed into must be a pointer
5235 value, subsequent types can be arrays, vectors, and structs. Note that
5236 subsequent types being indexed into can never be pointers, since that
5237 would require loading the pointer before continuing calculation.
5238
5239 The type of each index argument depends on the type it is indexing into.
5240 When indexing into a (optionally packed) structure, only ``i32`` integer
5241 **constants** are allowed (when using a vector of indices they must all
5242 be the **same** ``i32`` integer constant). When indexing into an array,
5243 pointer or vector, integers of any width are allowed, and they are not
5244 required to be constant. These integers are treated as signed values
5245 where relevant.
5246
5247 For example, let's consider a C code fragment and how it gets compiled
5248 to LLVM:
5249
5250 .. code-block:: c
5251
5252     struct RT {
5253       char A;
5254       int B[10][20];
5255       char C;
5256     };
5257     struct ST {
5258       int X;
5259       double Y;
5260       struct RT Z;
5261     };
5262
5263     int *foo(struct ST *s) {
5264       return &s[1].Z.B[5][13];
5265     }
5266
5267 The LLVM code generated by Clang is:
5268
5269 .. code-block:: llvm
5270
5271     %struct.RT = type { i8, [10 x [20 x i32]], i8 }
5272     %struct.ST = type { i32, double, %struct.RT }
5273
5274     define i32* @foo(%struct.ST* %s) nounwind uwtable readnone optsize ssp {
5275     entry:
5276       %arrayidx = getelementptr inbounds %struct.ST* %s, i64 1, i32 2, i32 1, i64 5, i64 13
5277       ret i32* %arrayidx
5278     }
5279
5280 Semantics:
5281 """"""""""
5282
5283 In the example above, the first index is indexing into the
5284 '``%struct.ST*``' type, which is a pointer, yielding a '``%struct.ST``'
5285 = '``{ i32, double, %struct.RT }``' type, a structure. The second index
5286 indexes into the third element of the structure, yielding a
5287 '``%struct.RT``' = '``{ i8 , [10 x [20 x i32]], i8 }``' type, another
5288 structure. The third index indexes into the second element of the
5289 structure, yielding a '``[10 x [20 x i32]]``' type, an array. The two
5290 dimensions of the array are subscripted into, yielding an '``i32``'
5291 type. The '``getelementptr``' instruction returns a pointer to this
5292 element, thus computing a value of '``i32*``' type.
5293
5294 Note that it is perfectly legal to index partially through a structure,
5295 returning a pointer to an inner element. Because of this, the LLVM code
5296 for the given testcase is equivalent to:
5297
5298 .. code-block:: llvm
5299
5300     define i32* @foo(%struct.ST* %s) {
5301       %t1 = getelementptr %struct.ST* %s, i32 1                 ; yields %struct.ST*:%t1
5302       %t2 = getelementptr %struct.ST* %t1, i32 0, i32 2         ; yields %struct.RT*:%t2
5303       %t3 = getelementptr %struct.RT* %t2, i32 0, i32 1         ; yields [10 x [20 x i32]]*:%t3
5304       %t4 = getelementptr [10 x [20 x i32]]* %t3, i32 0, i32 5  ; yields [20 x i32]*:%t4
5305       %t5 = getelementptr [20 x i32]* %t4, i32 0, i32 13        ; yields i32*:%t5
5306       ret i32* %t5
5307     }
5308
5309 If the ``inbounds`` keyword is present, the result value of the
5310 ``getelementptr`` is a :ref:`poison value <poisonvalues>` if the base
5311 pointer is not an *in bounds* address of an allocated object, or if any
5312 of the addresses that would be formed by successive addition of the
5313 offsets implied by the indices to the base address with infinitely
5314 precise signed arithmetic are not an *in bounds* address of that
5315 allocated object. The *in bounds* addresses for an allocated object are
5316 all the addresses that point into the object, plus the address one byte
5317 past the end. In cases where the base is a vector of pointers the
5318 ``inbounds`` keyword applies to each of the computations element-wise.
5319
5320 If the ``inbounds`` keyword is not present, the offsets are added to the
5321 base address with silently-wrapping two's complement arithmetic. If the
5322 offsets have a different width from the pointer, they are sign-extended
5323 or truncated to the width of the pointer. The result value of the
5324 ``getelementptr`` may be outside the object pointed to by the base
5325 pointer. The result value may not necessarily be used to access memory
5326 though, even if it happens to point into allocated storage. See the
5327 :ref:`Pointer Aliasing Rules <pointeraliasing>` section for more
5328 information.
5329
5330 The getelementptr instruction is often confusing. For some more insight
5331 into how it works, see :doc:`the getelementptr FAQ <GetElementPtr>`.
5332
5333 Example:
5334 """"""""
5335
5336 .. code-block:: llvm
5337
5338         ; yields [12 x i8]*:aptr
5339         %aptr = getelementptr {i32, [12 x i8]}* %saptr, i64 0, i32 1
5340         ; yields i8*:vptr
5341         %vptr = getelementptr {i32, <2 x i8>}* %svptr, i64 0, i32 1, i32 1
5342         ; yields i8*:eptr
5343         %eptr = getelementptr [12 x i8]* %aptr, i64 0, i32 1
5344         ; yields i32*:iptr
5345         %iptr = getelementptr [10 x i32]* @arr, i16 0, i16 0
5346
5347 In cases where the pointer argument is a vector of pointers, each index
5348 must be a vector with the same number of elements. For example:
5349
5350 .. code-block:: llvm
5351
5352      %A = getelementptr <4 x i8*> %ptrs, <4 x i64> %offsets,
5353
5354 Conversion Operations
5355 ---------------------
5356
5357 The instructions in this category are the conversion instructions
5358 (casting) which all take a single operand and a type. They perform
5359 various bit conversions on the operand.
5360
5361 '``trunc .. to``' Instruction
5362 ^^^^^^^^^^^^^^^^^^^^^^^^^^^^^
5363
5364 Syntax:
5365 """""""
5366
5367 ::
5368
5369       <result> = trunc <ty> <value> to <ty2>             ; yields ty2
5370
5371 Overview:
5372 """""""""
5373
5374 The '``trunc``' instruction truncates its operand to the type ``ty2``.
5375
5376 Arguments:
5377 """"""""""
5378
5379 The '``trunc``' instruction takes a value to trunc, and a type to trunc
5380 it to. Both types must be of :ref:`integer <t_integer>` types, or vectors
5381 of the same number of integers. The bit size of the ``value`` must be
5382 larger than the bit size of the destination type, ``ty2``. Equal sized
5383 types are not allowed.
5384
5385 Semantics:
5386 """"""""""
5387
5388 The '``trunc``' instruction truncates the high order bits in ``value``
5389 and converts the remaining bits to ``ty2``. Since the source size must
5390 be larger than the destination size, ``trunc`` cannot be a *no-op cast*.
5391 It will always truncate bits.
5392
5393 Example:
5394 """"""""
5395
5396 .. code-block:: llvm
5397
5398       %X = trunc i32 257 to i8                        ; yields i8:1
5399       %Y = trunc i32 123 to i1                        ; yields i1:true
5400       %Z = trunc i32 122 to i1                        ; yields i1:false
5401       %W = trunc <2 x i16> <i16 8, i16 7> to <2 x i8> ; yields <i8 8, i8 7>
5402
5403 '``zext .. to``' Instruction
5404 ^^^^^^^^^^^^^^^^^^^^^^^^^^^^
5405
5406 Syntax:
5407 """""""
5408
5409 ::
5410
5411       <result> = zext <ty> <value> to <ty2>             ; yields ty2
5412
5413 Overview:
5414 """""""""
5415
5416 The '``zext``' instruction zero extends its operand to type ``ty2``.
5417
5418 Arguments:
5419 """"""""""
5420
5421 The '``zext``' instruction takes a value to cast, and a type to cast it
5422 to. Both types must be of :ref:`integer <t_integer>` types, or vectors of
5423 the same number of integers. The bit size of the ``value`` must be
5424 smaller than the bit size of the destination type, ``ty2``.
5425
5426 Semantics:
5427 """"""""""
5428
5429 The ``zext`` fills the high order bits of the ``value`` with zero bits
5430 until it reaches the size of the destination type, ``ty2``.
5431
5432 When zero extending from i1, the result will always be either 0 or 1.
5433
5434 Example:
5435 """"""""
5436
5437 .. code-block:: llvm
5438
5439       %X = zext i32 257 to i64              ; yields i64:257
5440       %Y = zext i1 true to i32              ; yields i32:1
5441       %Z = zext <2 x i16> <i16 8, i16 7> to <2 x i32> ; yields <i32 8, i32 7>
5442
5443 '``sext .. to``' Instruction
5444 ^^^^^^^^^^^^^^^^^^^^^^^^^^^^
5445
5446 Syntax:
5447 """""""
5448
5449 ::
5450
5451       <result> = sext <ty> <value> to <ty2>             ; yields ty2
5452
5453 Overview:
5454 """""""""
5455
5456 The '``sext``' sign extends ``value`` to the type ``ty2``.
5457
5458 Arguments:
5459 """"""""""
5460
5461 The '``sext``' instruction takes a value to cast, and a type to cast it
5462 to. Both types must be of :ref:`integer <t_integer>` types, or vectors of
5463 the same number of integers. The bit size of the ``value`` must be
5464 smaller than the bit size of the destination type, ``ty2``.
5465
5466 Semantics:
5467 """"""""""
5468
5469 The '``sext``' instruction performs a sign extension by copying the sign
5470 bit (highest order bit) of the ``value`` until it reaches the bit size
5471 of the type ``ty2``.
5472
5473 When sign extending from i1, the extension always results in -1 or 0.
5474
5475 Example:
5476 """"""""
5477
5478 .. code-block:: llvm
5479
5480       %X = sext i8  -1 to i16              ; yields i16   :65535
5481       %Y = sext i1 true to i32             ; yields i32:-1
5482       %Z = sext <2 x i16> <i16 8, i16 7> to <2 x i32> ; yields <i32 8, i32 7>
5483
5484 '``fptrunc .. to``' Instruction
5485 ^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^
5486
5487 Syntax:
5488 """""""
5489
5490 ::
5491
5492       <result> = fptrunc <ty> <value> to <ty2>             ; yields ty2
5493
5494 Overview:
5495 """""""""
5496
5497 The '``fptrunc``' instruction truncates ``value`` to type ``ty2``.
5498
5499 Arguments:
5500 """"""""""
5501
5502 The '``fptrunc``' instruction takes a :ref:`floating point <t_floating>`
5503 value to cast and a :ref:`floating point <t_floating>` type to cast it to.
5504 The size of ``value`` must be larger than the size of ``ty2``. This
5505 implies that ``fptrunc`` cannot be used to make a *no-op cast*.
5506
5507 Semantics:
5508 """"""""""
5509
5510 The '``fptrunc``' instruction truncates a ``value`` from a larger
5511 :ref:`floating point <t_floating>` type to a smaller :ref:`floating
5512 point <t_floating>` type. If the value cannot fit within the
5513 destination type, ``ty2``, then the results are undefined.
5514
5515 Example:
5516 """"""""
5517
5518 .. code-block:: llvm
5519
5520       %X = fptrunc double 123.0 to float         ; yields float:123.0
5521       %Y = fptrunc double 1.0E+300 to float      ; yields undefined
5522
5523 '``fpext .. to``' Instruction
5524 ^^^^^^^^^^^^^^^^^^^^^^^^^^^^^
5525
5526 Syntax:
5527 """""""
5528
5529 ::
5530
5531       <result> = fpext <ty> <value> to <ty2>             ; yields ty2
5532
5533 Overview:
5534 """""""""
5535
5536 The '``fpext``' extends a floating point ``value`` to a larger floating
5537 point value.
5538
5539 Arguments:
5540 """"""""""
5541
5542 The '``fpext``' instruction takes a :ref:`floating point <t_floating>`
5543 ``value`` to cast, and a :ref:`floating point <t_floating>` type to cast it
5544 to. The source type must be smaller than the destination type.
5545
5546 Semantics:
5547 """"""""""
5548
5549 The '``fpext``' instruction extends the ``value`` from a smaller
5550 :ref:`floating point <t_floating>` type to a larger :ref:`floating
5551 point <t_floating>` type. The ``fpext`` cannot be used to make a
5552 *no-op cast* because it always changes bits. Use ``bitcast`` to make a
5553 *no-op cast* for a floating point cast.
5554
5555 Example:
5556 """"""""
5557
5558 .. code-block:: llvm
5559
5560       %X = fpext float 3.125 to double         ; yields double:3.125000e+00
5561       %Y = fpext double %X to fp128            ; yields fp128:0xL00000000000000004000900000000000
5562
5563 '``fptoui .. to``' Instruction
5564 ^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^
5565
5566 Syntax:
5567 """""""
5568
5569 ::
5570
5571       <result> = fptoui <ty> <value> to <ty2>             ; yields ty2
5572
5573 Overview:
5574 """""""""
5575
5576 The '``fptoui``' converts a floating point ``value`` to its unsigned
5577 integer equivalent of type ``ty2``.
5578
5579 Arguments:
5580 """"""""""
5581
5582 The '``fptoui``' instruction takes a value to cast, which must be a
5583 scalar or vector :ref:`floating point <t_floating>` value, and a type to
5584 cast it to ``ty2``, which must be an :ref:`integer <t_integer>` type. If
5585 ``ty`` is a vector floating point type, ``ty2`` must be a vector integer
5586 type with the same number of elements as ``ty``
5587
5588 Semantics:
5589 """"""""""
5590
5591 The '``fptoui``' instruction converts its :ref:`floating
5592 point <t_floating>` operand into the nearest (rounding towards zero)
5593 unsigned integer value. If the value cannot fit in ``ty2``, the results
5594 are undefined.
5595
5596 Example:
5597 """"""""
5598
5599 .. code-block:: llvm
5600
5601       %X = fptoui double 123.0 to i32      ; yields i32:123
5602       %Y = fptoui float 1.0E+300 to i1     ; yields undefined:1
5603       %Z = fptoui float 1.04E+17 to i8     ; yields undefined:1
5604
5605 '``fptosi .. to``' Instruction
5606 ^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^
5607
5608 Syntax:
5609 """""""
5610
5611 ::
5612
5613       <result> = fptosi <ty> <value> to <ty2>             ; yields ty2
5614
5615 Overview:
5616 """""""""
5617
5618 The '``fptosi``' instruction converts :ref:`floating point <t_floating>`
5619 ``value`` to type ``ty2``.
5620
5621 Arguments:
5622 """"""""""
5623
5624 The '``fptosi``' instruction takes a value to cast, which must be a
5625 scalar or vector :ref:`floating point <t_floating>` value, and a type to
5626 cast it to ``ty2``, which must be an :ref:`integer <t_integer>` type. If
5627 ``ty`` is a vector floating point type, ``ty2`` must be a vector integer
5628 type with the same number of elements as ``ty``
5629
5630 Semantics:
5631 """"""""""
5632
5633 The '``fptosi``' instruction converts its :ref:`floating
5634 point <t_floating>` operand into the nearest (rounding towards zero)
5635 signed integer value. If the value cannot fit in ``ty2``, the results
5636 are undefined.
5637
5638 Example:
5639 """"""""
5640
5641 .. code-block:: llvm
5642
5643       %X = fptosi double -123.0 to i32      ; yields i32:-123
5644       %Y = fptosi float 1.0E-247 to i1      ; yields undefined:1
5645       %Z = fptosi float 1.04E+17 to i8      ; yields undefined:1
5646
5647 '``uitofp .. to``' Instruction
5648 ^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^
5649
5650 Syntax:
5651 """""""
5652
5653 ::
5654
5655       <result> = uitofp <ty> <value> to <ty2>             ; yields ty2
5656
5657 Overview:
5658 """""""""
5659
5660 The '``uitofp``' instruction regards ``value`` as an unsigned integer
5661 and converts that value to the ``ty2`` type.
5662
5663 Arguments:
5664 """"""""""
5665
5666 The '``uitofp``' instruction takes a value to cast, which must be a
5667 scalar or vector :ref:`integer <t_integer>` value, and a type to cast it to
5668 ``ty2``, which must be an :ref:`floating point <t_floating>` type. If
5669 ``ty`` is a vector integer type, ``ty2`` must be a vector floating point
5670 type with the same number of elements as ``ty``
5671
5672 Semantics:
5673 """"""""""
5674
5675 The '``uitofp``' instruction interprets its operand as an unsigned
5676 integer quantity and converts it to the corresponding floating point
5677 value. If the value cannot fit in the floating point value, the results
5678 are undefined.
5679
5680 Example:
5681 """"""""
5682
5683 .. code-block:: llvm
5684
5685       %X = uitofp i32 257 to float         ; yields float:257.0
5686       %Y = uitofp i8 -1 to double          ; yields double:255.0
5687
5688 '``sitofp .. to``' Instruction
5689 ^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^
5690
5691 Syntax:
5692 """""""
5693
5694 ::
5695
5696       <result> = sitofp <ty> <value> to <ty2>             ; yields ty2
5697
5698 Overview:
5699 """""""""
5700
5701 The '``sitofp``' instruction regards ``value`` as a signed integer and
5702 converts that value to the ``ty2`` type.
5703
5704 Arguments:
5705 """"""""""
5706
5707 The '``sitofp``' instruction takes a value to cast, which must be a
5708 scalar or vector :ref:`integer <t_integer>` value, and a type to cast it to
5709 ``ty2``, which must be an :ref:`floating point <t_floating>` type. If
5710 ``ty`` is a vector integer type, ``ty2`` must be a vector floating point
5711 type with the same number of elements as ``ty``
5712
5713 Semantics:
5714 """"""""""
5715
5716 The '``sitofp``' instruction interprets its operand as a signed integer
5717 quantity and converts it to the corresponding floating point value. If
5718 the value cannot fit in the floating point value, the results are
5719 undefined.
5720
5721 Example:
5722 """"""""
5723
5724 .. code-block:: llvm
5725
5726       %X = sitofp i32 257 to float         ; yields float:257.0
5727       %Y = sitofp i8 -1 to double          ; yields double:-1.0
5728
5729 .. _i_ptrtoint:
5730
5731 '``ptrtoint .. to``' Instruction
5732 ^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^
5733
5734 Syntax:
5735 """""""
5736
5737 ::
5738
5739       <result> = ptrtoint <ty> <value> to <ty2>             ; yields ty2
5740
5741 Overview:
5742 """""""""
5743
5744 The '``ptrtoint``' instruction converts the pointer or a vector of
5745 pointers ``value`` to the integer (or vector of integers) type ``ty2``.
5746
5747 Arguments:
5748 """"""""""
5749
5750 The '``ptrtoint``' instruction takes a ``value`` to cast, which must be
5751 a a value of type :ref:`pointer <t_pointer>` or a vector of pointers, and a
5752 type to cast it to ``ty2``, which must be an :ref:`integer <t_integer>` or
5753 a vector of integers type.
5754
5755 Semantics:
5756 """"""""""
5757
5758 The '``ptrtoint``' instruction converts ``value`` to integer type
5759 ``ty2`` by interpreting the pointer value as an integer and either
5760 truncating or zero extending that value to the size of the integer type.
5761 If ``value`` is smaller than ``ty2`` then a zero extension is done. If
5762 ``value`` is larger than ``ty2`` then a truncation is done. If they are
5763 the same size, then nothing is done (*no-op cast*) other than a type
5764 change.
5765
5766 Example:
5767 """"""""
5768
5769 .. code-block:: llvm
5770
5771       %X = ptrtoint i32* %P to i8                         ; yields truncation on 32-bit architecture
5772       %Y = ptrtoint i32* %P to i64                        ; yields zero extension on 32-bit architecture
5773       %Z = ptrtoint <4 x i32*> %P to <4 x i64>; yields vector zero extension for a vector of addresses on 32-bit architecture
5774
5775 .. _i_inttoptr:
5776
5777 '``inttoptr .. to``' Instruction
5778 ^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^
5779
5780 Syntax:
5781 """""""
5782
5783 ::
5784
5785       <result> = inttoptr <ty> <value> to <ty2>             ; yields ty2
5786
5787 Overview:
5788 """""""""
5789
5790 The '``inttoptr``' instruction converts an integer ``value`` to a
5791 pointer type, ``ty2``.
5792
5793 Arguments:
5794 """"""""""
5795
5796 The '``inttoptr``' instruction takes an :ref:`integer <t_integer>` value to
5797 cast, and a type to cast it to, which must be a :ref:`pointer <t_pointer>`
5798 type.
5799
5800 Semantics:
5801 """"""""""
5802
5803 The '``inttoptr``' instruction converts ``value`` to type ``ty2`` by
5804 applying either a zero extension or a truncation depending on the size
5805 of the integer ``value``. If ``value`` is larger than the size of a
5806 pointer then a truncation is done. If ``value`` is smaller than the size
5807 of a pointer then a zero extension is done. If they are the same size,
5808 nothing is done (*no-op cast*).
5809
5810 Example:
5811 """"""""
5812
5813 .. code-block:: llvm
5814
5815       %X = inttoptr i32 255 to i32*          ; yields zero extension on 64-bit architecture
5816       %Y = inttoptr i32 255 to i32*          ; yields no-op on 32-bit architecture
5817       %Z = inttoptr i64 0 to i32*            ; yields truncation on 32-bit architecture
5818       %Z = inttoptr <4 x i32> %G to <4 x i8*>; yields truncation of vector G to four pointers
5819
5820 .. _i_bitcast:
5821
5822 '``bitcast .. to``' Instruction
5823 ^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^
5824
5825 Syntax:
5826 """""""
5827
5828 ::
5829
5830       <result> = bitcast <ty> <value> to <ty2>             ; yields ty2
5831
5832 Overview:
5833 """""""""
5834
5835 The '``bitcast``' instruction converts ``value`` to type ``ty2`` without
5836 changing any bits.
5837
5838 Arguments:
5839 """"""""""
5840
5841 The '``bitcast``' instruction takes a value to cast, which must be a
5842 non-aggregate first class value, and a type to cast it to, which must
5843 also be a non-aggregate :ref:`first class <t_firstclass>` type. The
5844 bit sizes of ``value`` and the destination type, ``ty2``, must be
5845 identical.  If the source type is a pointer, the destination type must
5846 also be a pointer of the same size. This instruction supports bitwise
5847 conversion of vectors to integers and to vectors of other types (as
5848 long as they have the same size).
5849
5850 Semantics:
5851 """"""""""
5852
5853 The '``bitcast``' instruction converts ``value`` to type ``ty2``. It
5854 is always a *no-op cast* because no bits change with this
5855 conversion. The conversion is done as if the ``value`` had been stored
5856 to memory and read back as type ``ty2``. Pointer (or vector of
5857 pointers) types may only be converted to other pointer (or vector of
5858 pointers) types with the same address space through this instruction.
5859 To convert pointers to other types, use the :ref:`inttoptr <i_inttoptr>`
5860 or :ref:`ptrtoint <i_ptrtoint>` instructions first.
5861
5862 Example:
5863 """"""""
5864
5865 .. code-block:: llvm
5866
5867       %X = bitcast i8 255 to i8              ; yields i8 :-1
5868       %Y = bitcast i32* %x to sint*          ; yields sint*:%x
5869       %Z = bitcast <2 x int> %V to i64;        ; yields i64: %V
5870       %Z = bitcast <2 x i32*> %V to <2 x i64*> ; yields <2 x i64*>
5871
5872 .. _i_addrspacecast:
5873
5874 '``addrspacecast .. to``' Instruction
5875 ^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^
5876
5877 Syntax:
5878 """""""
5879
5880 ::
5881
5882       <result> = addrspacecast <pty> <ptrval> to <pty2>       ; yields pty2
5883
5884 Overview:
5885 """""""""
5886
5887 The '``addrspacecast``' instruction converts ``ptrval`` from ``pty`` in
5888 address space ``n`` to type ``pty2`` in address space ``m``.
5889
5890 Arguments:
5891 """"""""""
5892
5893 The '``addrspacecast``' instruction takes a pointer or vector of pointer value
5894 to cast and a pointer type to cast it to, which must have a different
5895 address space.
5896
5897 Semantics:
5898 """"""""""
5899
5900 The '``addrspacecast``' instruction converts the pointer value
5901 ``ptrval`` to type ``pty2``. It can be a *no-op cast* or a complex
5902 value modification, depending on the target and the address space
5903 pair. Pointer conversions within the same address space must be
5904 performed with the ``bitcast`` instruction. Note that if the address space
5905 conversion is legal then both result and operand refer to the same memory
5906 location.
5907
5908 Example:
5909 """"""""
5910
5911 .. code-block:: llvm
5912
5913       %X = addrspacecast i32* %x to i32 addrspace(1)*    ; yields i32 addrspace(1)*:%x
5914       %Y = addrspacecast i32 addrspace(1)* %y to i64 addrspace(2)*    ; yields i64 addrspace(2)*:%y
5915       %Z = addrspacecast <4 x i32*> %z to <4 x float addrspace(3)*>   ; yields <4 x float addrspace(3)*>:%z
5916
5917 .. _otherops:
5918
5919 Other Operations
5920 ----------------
5921
5922 The instructions in this category are the "miscellaneous" instructions,
5923 which defy better classification.
5924
5925 .. _i_icmp:
5926
5927 '``icmp``' Instruction
5928 ^^^^^^^^^^^^^^^^^^^^^^
5929
5930 Syntax:
5931 """""""
5932
5933 ::
5934
5935       <result> = icmp <cond> <ty> <op1>, <op2>   ; yields {i1} or {<N x i1>}:result
5936
5937 Overview:
5938 """""""""
5939
5940 The '``icmp``' instruction returns a boolean value or a vector of
5941 boolean values based on comparison of its two integer, integer vector,
5942 pointer, or pointer vector operands.
5943
5944 Arguments:
5945 """"""""""
5946
5947 The '``icmp``' instruction takes three operands. The first operand is
5948 the condition code indicating the kind of comparison to perform. It is
5949 not a value, just a keyword. The possible condition code are:
5950
5951 #. ``eq``: equal
5952 #. ``ne``: not equal
5953 #. ``ugt``: unsigned greater than
5954 #. ``uge``: unsigned greater or equal
5955 #. ``ult``: unsigned less than
5956 #. ``ule``: unsigned less or equal
5957 #. ``sgt``: signed greater than
5958 #. ``sge``: signed greater or equal
5959 #. ``slt``: signed less than
5960 #. ``sle``: signed less or equal
5961
5962 The remaining two arguments must be :ref:`integer <t_integer>` or
5963 :ref:`pointer <t_pointer>` or integer :ref:`vector <t_vector>` typed. They
5964 must also be identical types.
5965
5966 Semantics:
5967 """"""""""
5968
5969 The '``icmp``' compares ``op1`` and ``op2`` according to the condition
5970 code given as ``cond``. The comparison performed always yields either an
5971 :ref:`i1 <t_integer>` or vector of ``i1`` result, as follows:
5972
5973 #. ``eq``: yields ``true`` if the operands are equal, ``false``
5974    otherwise. No sign interpretation is necessary or performed.
5975 #. ``ne``: yields ``true`` if the operands are unequal, ``false``
5976    otherwise. No sign interpretation is necessary or performed.
5977 #. ``ugt``: interprets the operands as unsigned values and yields
5978    ``true`` if ``op1`` is greater than ``op2``.
5979 #. ``uge``: interprets the operands as unsigned values and yields
5980    ``true`` if ``op1`` is greater than or equal to ``op2``.
5981 #. ``ult``: interprets the operands as unsigned values and yields
5982    ``true`` if ``op1`` is less than ``op2``.
5983 #. ``ule``: interprets the operands as unsigned values and yields
5984    ``true`` if ``op1`` is less than or equal to ``op2``.
5985 #. ``sgt``: interprets the operands as signed values and yields ``true``
5986    if ``op1`` is greater than ``op2``.
5987 #. ``sge``: interprets the operands as signed values and yields ``true``
5988    if ``op1`` is greater than or equal to ``op2``.
5989 #. ``slt``: interprets the operands as signed values and yields ``true``
5990    if ``op1`` is less than ``op2``.
5991 #. ``sle``: interprets the operands as signed values and yields ``true``
5992    if ``op1`` is less than or equal to ``op2``.
5993
5994 If the operands are :ref:`pointer <t_pointer>` typed, the pointer values
5995 are compared as if they were integers.
5996
5997 If the operands are integer vectors, then they are compared element by
5998 element. The result is an ``i1`` vector with the same number of elements
5999 as the values being compared. Otherwise, the result is an ``i1``.
6000
6001 Example:
6002 """"""""
6003
6004 .. code-block:: llvm
6005
6006       <result> = icmp eq i32 4, 5          ; yields: result=false
6007       <result> = icmp ne float* %X, %X     ; yields: result=false
6008       <result> = icmp ult i16  4, 5        ; yields: result=true
6009       <result> = icmp sgt i16  4, 5        ; yields: result=false
6010       <result> = icmp ule i16 -4, 5        ; yields: result=false
6011       <result> = icmp sge i16  4, 5        ; yields: result=false
6012
6013 Note that the code generator does not yet support vector types with the
6014 ``icmp`` instruction.
6015
6016 .. _i_fcmp:
6017
6018 '``fcmp``' Instruction
6019 ^^^^^^^^^^^^^^^^^^^^^^
6020
6021 Syntax:
6022 """""""
6023
6024 ::
6025
6026       <result> = fcmp <cond> <ty> <op1>, <op2>     ; yields {i1} or {<N x i1>}:result
6027
6028 Overview:
6029 """""""""
6030
6031 The '``fcmp``' instruction returns a boolean value or vector of boolean
6032 values based on comparison of its operands.
6033
6034 If the operands are floating point scalars, then the result type is a
6035 boolean (:ref:`i1 <t_integer>`).
6036
6037 If the operands are floating point vectors, then the result type is a
6038 vector of boolean with the same number of elements as the operands being
6039 compared.
6040
6041 Arguments:
6042 """"""""""
6043
6044 The '``fcmp``' instruction takes three operands. The first operand is
6045 the condition code indicating the kind of comparison to perform. It is
6046 not a value, just a keyword. The possible condition code are:
6047
6048 #. ``false``: no comparison, always returns false
6049 #. ``oeq``: ordered and equal
6050 #. ``ogt``: ordered and greater than
6051 #. ``oge``: ordered and greater than or equal
6052 #. ``olt``: ordered and less than
6053 #. ``ole``: ordered and less than or equal
6054 #. ``one``: ordered and not equal
6055 #. ``ord``: ordered (no nans)
6056 #. ``ueq``: unordered or equal
6057 #. ``ugt``: unordered or greater than
6058 #. ``uge``: unordered or greater than or equal
6059 #. ``ult``: unordered or less than
6060 #. ``ule``: unordered or less than or equal
6061 #. ``une``: unordered or not equal
6062 #. ``uno``: unordered (either nans)
6063 #. ``true``: no comparison, always returns true
6064
6065 *Ordered* means that neither operand is a QNAN while *unordered* means
6066 that either operand may be a QNAN.
6067
6068 Each of ``val1`` and ``val2`` arguments must be either a :ref:`floating
6069 point <t_floating>` type or a :ref:`vector <t_vector>` of floating point
6070 type. They must have identical types.
6071
6072 Semantics:
6073 """"""""""
6074
6075 The '``fcmp``' instruction compares ``op1`` and ``op2`` according to the
6076 condition code given as ``cond``. If the operands are vectors, then the
6077 vectors are compared element by element. Each comparison performed
6078 always yields an :ref:`i1 <t_integer>` result, as follows:
6079
6080 #. ``false``: always yields ``false``, regardless of operands.
6081 #. ``oeq``: yields ``true`` if both operands are not a QNAN and ``op1``
6082    is equal to ``op2``.
6083 #. ``ogt``: yields ``true`` if both operands are not a QNAN and ``op1``
6084    is greater than ``op2``.
6085 #. ``oge``: yields ``true`` if both operands are not a QNAN and ``op1``
6086    is greater than or equal to ``op2``.
6087 #. ``olt``: yields ``true`` if both operands are not a QNAN and ``op1``
6088    is less than ``op2``.
6089 #. ``ole``: yields ``true`` if both operands are not a QNAN and ``op1``
6090    is less than or equal to ``op2``.
6091 #. ``one``: yields ``true`` if both operands are not a QNAN and ``op1``
6092    is not equal to ``op2``.
6093 #. ``ord``: yields ``true`` if both operands are not a QNAN.
6094 #. ``ueq``: yields ``true`` if either operand is a QNAN or ``op1`` is
6095    equal to ``op2``.
6096 #. ``ugt``: yields ``true`` if either operand is a QNAN or ``op1`` is
6097    greater than ``op2``.
6098 #. ``uge``: yields ``true`` if either operand is a QNAN or ``op1`` is
6099    greater than or equal to ``op2``.
6100 #. ``ult``: yields ``true`` if either operand is a QNAN or ``op1`` is
6101    less than ``op2``.
6102 #. ``ule``: yields ``true`` if either operand is a QNAN or ``op1`` is
6103    less than or equal to ``op2``.
6104 #. ``une``: yields ``true`` if either operand is a QNAN or ``op1`` is
6105    not equal to ``op2``.
6106 #. ``uno``: yields ``true`` if either operand is a QNAN.
6107 #. ``true``: always yields ``true``, regardless of operands.
6108
6109 Example:
6110 """"""""
6111
6112 .. code-block:: llvm
6113
6114       <result> = fcmp oeq float 4.0, 5.0    ; yields: result=false
6115       <result> = fcmp one float 4.0, 5.0    ; yields: result=true
6116       <result> = fcmp olt float 4.0, 5.0    ; yields: result=true
6117       <result> = fcmp ueq double 1.0, 2.0   ; yields: result=false
6118
6119 Note that the code generator does not yet support vector types with the
6120 ``fcmp`` instruction.
6121
6122 .. _i_phi:
6123
6124 '``phi``' Instruction
6125 ^^^^^^^^^^^^^^^^^^^^^
6126
6127 Syntax:
6128 """""""
6129
6130 ::
6131
6132       <result> = phi <ty> [ <val0>, <label0>], ...
6133
6134 Overview:
6135 """""""""
6136
6137 The '``phi``' instruction is used to implement the Ï† node in the SSA
6138 graph representing the function.
6139
6140 Arguments:
6141 """"""""""
6142
6143 The type of the incoming values is specified with the first type field.
6144 After this, the '``phi``' instruction takes a list of pairs as
6145 arguments, with one pair for each predecessor basic block of the current
6146 block. Only values of :ref:`first class <t_firstclass>` type may be used as
6147 the value arguments to the PHI node. Only labels may be used as the
6148 label arguments.
6149
6150 There must be no non-phi instructions between the start of a basic block
6151 and the PHI instructions: i.e. PHI instructions must be first in a basic
6152 block.
6153
6154 For the purposes of the SSA form, the use of each incoming value is
6155 deemed to occur on the edge from the corresponding predecessor block to
6156 the current block (but after any definition of an '``invoke``'
6157 instruction's return value on the same edge).
6158
6159 Semantics:
6160 """"""""""
6161
6162 At runtime, the '``phi``' instruction logically takes on the value
6163 specified by the pair corresponding to the predecessor basic block that
6164 executed just prior to the current block.
6165
6166 Example:
6167 """"""""
6168
6169 .. code-block:: llvm
6170
6171     Loop:       ; Infinite loop that counts from 0 on up...
6172       %indvar = phi i32 [ 0, %LoopHeader ], [ %nextindvar, %Loop ]
6173       %nextindvar = add i32 %indvar, 1
6174       br label %Loop
6175
6176 .. _i_select:
6177
6178 '``select``' Instruction
6179 ^^^^^^^^^^^^^^^^^^^^^^^^
6180
6181 Syntax:
6182 """""""
6183
6184 ::
6185
6186       <result> = select selty <cond>, <ty> <val1>, <ty> <val2>             ; yields ty
6187
6188       selty is either i1 or {<N x i1>}
6189
6190 Overview:
6191 """""""""
6192
6193 The '``select``' instruction is used to choose one value based on a
6194 condition, without IR-level branching.
6195
6196 Arguments:
6197 """"""""""
6198
6199 The '``select``' instruction requires an 'i1' value or a vector of 'i1'
6200 values indicating the condition, and two values of the same :ref:`first
6201 class <t_firstclass>` type. If the val1/val2 are vectors and the
6202 condition is a scalar, then entire vectors are selected, not individual
6203 elements.
6204
6205 Semantics:
6206 """"""""""
6207
6208 If the condition is an i1 and it evaluates to 1, the instruction returns
6209 the first value argument; otherwise, it returns the second value
6210 argument.
6211
6212 If the condition is a vector of i1, then the value arguments must be
6213 vectors of the same size, and the selection is done element by element.
6214
6215 Example:
6216 """"""""
6217
6218 .. code-block:: llvm
6219
6220       %X = select i1 true, i8 17, i8 42          ; yields i8:17
6221
6222 .. _i_call:
6223
6224 '``call``' Instruction
6225 ^^^^^^^^^^^^^^^^^^^^^^
6226
6227 Syntax:
6228 """""""
6229
6230 ::
6231
6232       <result> = [tail | musttail] call [cconv] [ret attrs] <ty> [<fnty>*] <fnptrval>(<function args>) [fn attrs]
6233
6234 Overview:
6235 """""""""
6236
6237 The '``call``' instruction represents a simple function call.
6238
6239 Arguments:
6240 """"""""""
6241
6242 This instruction requires several arguments:
6243
6244 #. The optional ``tail`` and ``musttail`` markers indicate that the optimizers
6245    should perform tail call optimization.  The ``tail`` marker is a hint that
6246    `can be ignored <CodeGenerator.html#sibcallopt>`_.  The ``musttail`` marker
6247    means that the call must be tail call optimized in order for the program to
6248    be correct.  The ``musttail`` marker provides these guarantees:
6249
6250    #. The call will not cause unbounded stack growth if it is part of a
6251       recursive cycle in the call graph.
6252    #. Arguments with the :ref:`inalloca <attr_inalloca>` attribute are
6253       forwarded in place.
6254
6255    Both markers imply that the callee does not access allocas or varargs from
6256    the caller.  Calls marked ``musttail`` must obey the following additional
6257    rules:
6258
6259    - The call must immediately precede a :ref:`ret <i_ret>` instruction,
6260      or a pointer bitcast followed by a ret instruction.
6261    - The ret instruction must return the (possibly bitcasted) value
6262      produced by the call or void.
6263    - The caller and callee prototypes must match.  Pointer types of
6264      parameters or return types may differ in pointee type, but not
6265      in address space.
6266    - The calling conventions of the caller and callee must match.
6267    - All ABI-impacting function attributes, such as sret, byval, inreg,
6268      returned, and inalloca, must match.
6269
6270    Tail call optimization for calls marked ``tail`` is guaranteed to occur if
6271    the following conditions are met:
6272
6273    -  Caller and callee both have the calling convention ``fastcc``.
6274    -  The call is in tail position (ret immediately follows call and ret
6275       uses value of call or is void).
6276    -  Option ``-tailcallopt`` is enabled, or
6277       ``llvm::GuaranteedTailCallOpt`` is ``true``.
6278    -  `Platform specific constraints are
6279       met. <CodeGenerator.html#tailcallopt>`_
6280
6281 #. The optional "cconv" marker indicates which :ref:`calling
6282    convention <callingconv>` the call should use. If none is
6283    specified, the call defaults to using C calling conventions. The
6284    calling convention of the call must match the calling convention of
6285    the target function, or else the behavior is undefined.
6286 #. The optional :ref:`Parameter Attributes <paramattrs>` list for return
6287    values. Only '``zeroext``', '``signext``', and '``inreg``' attributes
6288    are valid here.
6289 #. '``ty``': the type of the call instruction itself which is also the
6290    type of the return value. Functions that return no value are marked
6291    ``void``.
6292 #. '``fnty``': shall be the signature of the pointer to function value
6293    being invoked. The argument types must match the types implied by
6294    this signature. This type can be omitted if the function is not
6295    varargs and if the function type does not return a pointer to a
6296    function.
6297 #. '``fnptrval``': An LLVM value containing a pointer to a function to
6298    be invoked. In most cases, this is a direct function invocation, but
6299    indirect ``call``'s are just as possible, calling an arbitrary pointer
6300    to function value.
6301 #. '``function args``': argument list whose types match the function
6302    signature argument types and parameter attributes. All arguments must
6303    be of :ref:`first class <t_firstclass>` type. If the function signature
6304    indicates the function accepts a variable number of arguments, the
6305    extra arguments can be specified.
6306 #. The optional :ref:`function attributes <fnattrs>` list. Only
6307    '``noreturn``', '``nounwind``', '``readonly``' and '``readnone``'
6308    attributes are valid here.
6309
6310 Semantics:
6311 """"""""""
6312
6313 The '``call``' instruction is used to cause control flow to transfer to
6314 a specified function, with its incoming arguments bound to the specified
6315 values. Upon a '``ret``' instruction in the called function, control
6316 flow continues with the instruction after the function call, and the
6317 return value of the function is bound to the result argument.
6318
6319 Example:
6320 """"""""
6321
6322 .. code-block:: llvm
6323
6324       %retval = call i32 @test(i32 %argc)
6325       call i32 (i8*, ...)* @printf(i8* %msg, i32 12, i8 42)        ; yields i32
6326       %X = tail call i32 @foo()                                    ; yields i32
6327       %Y = tail call fastcc i32 @foo()  ; yields i32
6328       call void %foo(i8 97 signext)
6329
6330       %struct.A = type { i32, i8 }
6331       %r = call %struct.A @foo()                        ; yields { 32, i8 }
6332       %gr = extractvalue %struct.A %r, 0                ; yields i32
6333       %gr1 = extractvalue %struct.A %r, 1               ; yields i8
6334       %Z = call void @foo() noreturn                    ; indicates that %foo never returns normally
6335       %ZZ = call zeroext i32 @bar()                     ; Return value is %zero extended
6336
6337 llvm treats calls to some functions with names and arguments that match
6338 the standard C99 library as being the C99 library functions, and may
6339 perform optimizations or generate code for them under that assumption.
6340 This is something we'd like to change in the future to provide better
6341 support for freestanding environments and non-C-based languages.
6342
6343 .. _i_va_arg:
6344
6345 '``va_arg``' Instruction
6346 ^^^^^^^^^^^^^^^^^^^^^^^^
6347
6348 Syntax:
6349 """""""
6350
6351 ::
6352
6353       <resultval> = va_arg <va_list*> <arglist>, <argty>
6354
6355 Overview:
6356 """""""""
6357
6358 The '``va_arg``' instruction is used to access arguments passed through
6359 the "variable argument" area of a function call. It is used to implement
6360 the ``va_arg`` macro in C.
6361
6362 Arguments:
6363 """"""""""
6364
6365 This instruction takes a ``va_list*`` value and the type of the
6366 argument. It returns a value of the specified argument type and
6367 increments the ``va_list`` to point to the next argument. The actual
6368 type of ``va_list`` is target specific.
6369
6370 Semantics:
6371 """"""""""
6372
6373 The '``va_arg``' instruction loads an argument of the specified type
6374 from the specified ``va_list`` and causes the ``va_list`` to point to
6375 the next argument. For more information, see the variable argument
6376 handling :ref:`Intrinsic Functions <int_varargs>`.
6377
6378 It is legal for this instruction to be called in a function which does
6379 not take a variable number of arguments, for example, the ``vfprintf``
6380 function.
6381
6382 ``va_arg`` is an LLVM instruction instead of an :ref:`intrinsic
6383 function <intrinsics>` because it takes a type as an argument.
6384
6385 Example:
6386 """"""""
6387
6388 See the :ref:`variable argument processing <int_varargs>` section.
6389
6390 Note that the code generator does not yet fully support va\_arg on many
6391 targets. Also, it does not currently support va\_arg with aggregate
6392 types on any target.
6393
6394 .. _i_landingpad:
6395
6396 '``landingpad``' Instruction
6397 ^^^^^^^^^^^^^^^^^^^^^^^^^^^^
6398
6399 Syntax:
6400 """""""
6401
6402 ::
6403
6404       <resultval> = landingpad <resultty> personality <type> <pers_fn> <clause>+
6405       <resultval> = landingpad <resultty> personality <type> <pers_fn> cleanup <clause>*
6406
6407       <clause> := catch <type> <value>
6408       <clause> := filter <array constant type> <array constant>
6409
6410 Overview:
6411 """""""""
6412
6413 The '``landingpad``' instruction is used by `LLVM's exception handling
6414 system <ExceptionHandling.html#overview>`_ to specify that a basic block
6415 is a landing pad --- one where the exception lands, and corresponds to the
6416 code found in the ``catch`` portion of a ``try``/``catch`` sequence. It
6417 defines values supplied by the personality function (``pers_fn``) upon
6418 re-entry to the function. The ``resultval`` has the type ``resultty``.
6419
6420 Arguments:
6421 """"""""""
6422
6423 This instruction takes a ``pers_fn`` value. This is the personality
6424 function associated with the unwinding mechanism. The optional
6425 ``cleanup`` flag indicates that the landing pad block is a cleanup.
6426
6427 A ``clause`` begins with the clause type --- ``catch`` or ``filter`` --- and
6428 contains the global variable representing the "type" that may be caught
6429 or filtered respectively. Unlike the ``catch`` clause, the ``filter``
6430 clause takes an array constant as its argument. Use
6431 "``[0 x i8**] undef``" for a filter which cannot throw. The
6432 '``landingpad``' instruction must contain *at least* one ``clause`` or
6433 the ``cleanup`` flag.
6434
6435 Semantics:
6436 """"""""""
6437
6438 The '``landingpad``' instruction defines the values which are set by the
6439 personality function (``pers_fn``) upon re-entry to the function, and
6440 therefore the "result type" of the ``landingpad`` instruction. As with
6441 calling conventions, how the personality function results are
6442 represented in LLVM IR is target specific.
6443
6444 The clauses are applied in order from top to bottom. If two
6445 ``landingpad`` instructions are merged together through inlining, the
6446 clauses from the calling function are appended to the list of clauses.
6447 When the call stack is being unwound due to an exception being thrown,
6448 the exception is compared against each ``clause`` in turn. If it doesn't
6449 match any of the clauses, and the ``cleanup`` flag is not set, then
6450 unwinding continues further up the call stack.
6451
6452 The ``landingpad`` instruction has several restrictions:
6453
6454 -  A landing pad block is a basic block which is the unwind destination
6455    of an '``invoke``' instruction.
6456 -  A landing pad block must have a '``landingpad``' instruction as its
6457    first non-PHI instruction.
6458 -  There can be only one '``landingpad``' instruction within the landing
6459    pad block.
6460 -  A basic block that is not a landing pad block may not include a
6461    '``landingpad``' instruction.
6462 -  All '``landingpad``' instructions in a function must have the same
6463    personality function.
6464
6465 Example:
6466 """"""""
6467
6468 .. code-block:: llvm
6469
6470       ;; A landing pad which can catch an integer.
6471       %res = landingpad { i8*, i32 } personality i32 (...)* @__gxx_personality_v0
6472                catch i8** @_ZTIi
6473       ;; A landing pad that is a cleanup.
6474       %res = landingpad { i8*, i32 } personality i32 (...)* @__gxx_personality_v0
6475                cleanup
6476       ;; A landing pad which can catch an integer and can only throw a double.
6477       %res = landingpad { i8*, i32 } personality i32 (...)* @__gxx_personality_v0
6478                catch i8** @_ZTIi
6479                filter [1 x i8**] [@_ZTId]
6480
6481 .. _intrinsics:
6482
6483 Intrinsic Functions
6484 ===================
6485
6486 LLVM supports the notion of an "intrinsic function". These functions
6487 have well known names and semantics and are required to follow certain
6488 restrictions. Overall, these intrinsics represent an extension mechanism
6489 for the LLVM language that does not require changing all of the
6490 transformations in LLVM when adding to the language (or the bitcode
6491 reader/writer, the parser, etc...).
6492
6493 Intrinsic function names must all start with an "``llvm.``" prefix. This
6494 prefix is reserved in LLVM for intrinsic names; thus, function names may
6495 not begin with this prefix. Intrinsic functions must always be external
6496 functions: you cannot define the body of intrinsic functions. Intrinsic
6497 functions may only be used in call or invoke instructions: it is illegal
6498 to take the address of an intrinsic function. Additionally, because
6499 intrinsic functions are part of the LLVM language, it is required if any
6500 are added that they be documented here.
6501
6502 Some intrinsic functions can be overloaded, i.e., the intrinsic
6503 represents a family of functions that perform the same operation but on
6504 different data types. Because LLVM can represent over 8 million
6505 different integer types, overloading is used commonly to allow an
6506 intrinsic function to operate on any integer type. One or more of the
6507 argument types or the result type can be overloaded to accept any
6508 integer type. Argument types may also be defined as exactly matching a
6509 previous argument's type or the result type. This allows an intrinsic
6510 function which accepts multiple arguments, but needs all of them to be
6511 of the same type, to only be overloaded with respect to a single
6512 argument or the result.
6513
6514 Overloaded intrinsics will have the names of its overloaded argument
6515 types encoded into its function name, each preceded by a period. Only
6516 those types which are overloaded result in a name suffix. Arguments
6517 whose type is matched against another type do not. For example, the
6518 ``llvm.ctpop`` function can take an integer of any width and returns an
6519 integer of exactly the same integer width. This leads to a family of
6520 functions such as ``i8 @llvm.ctpop.i8(i8 %val)`` and
6521 ``i29 @llvm.ctpop.i29(i29 %val)``. Only one type, the return type, is
6522 overloaded, and only one type suffix is required. Because the argument's
6523 type is matched against the return type, it does not require its own
6524 name suffix.
6525
6526 To learn how to add an intrinsic function, please see the `Extending
6527 LLVM Guide <ExtendingLLVM.html>`_.
6528
6529 .. _int_varargs:
6530
6531 Variable Argument Handling Intrinsics
6532 -------------------------------------
6533
6534 Variable argument support is defined in LLVM with the
6535 :ref:`va_arg <i_va_arg>` instruction and these three intrinsic
6536 functions. These functions are related to the similarly named macros
6537 defined in the ``<stdarg.h>`` header file.
6538
6539 All of these functions operate on arguments that use a target-specific
6540 value type "``va_list``". The LLVM assembly language reference manual
6541 does not define what this type is, so all transformations should be
6542 prepared to handle these functions regardless of the type used.
6543
6544 This example shows how the :ref:`va_arg <i_va_arg>` instruction and the
6545 variable argument handling intrinsic functions are used.
6546
6547 .. code-block:: llvm
6548
6549     define i32 @test(i32 %X, ...) {
6550       ; Initialize variable argument processing
6551       %ap = alloca i8*
6552       %ap2 = bitcast i8** %ap to i8*
6553       call void @llvm.va_start(i8* %ap2)
6554
6555       ; Read a single integer argument
6556       %tmp = va_arg i8** %ap, i32
6557
6558       ; Demonstrate usage of llvm.va_copy and llvm.va_end
6559       %aq = alloca i8*
6560       %aq2 = bitcast i8** %aq to i8*
6561       call void @llvm.va_copy(i8* %aq2, i8* %ap2)
6562       call void @llvm.va_end(i8* %aq2)
6563
6564       ; Stop processing of arguments.
6565       call void @llvm.va_end(i8* %ap2)
6566       ret i32 %tmp
6567     }
6568
6569     declare void @llvm.va_start(i8*)
6570     declare void @llvm.va_copy(i8*, i8*)
6571     declare void @llvm.va_end(i8*)
6572
6573 .. _int_va_start:
6574
6575 '``llvm.va_start``' Intrinsic
6576 ^^^^^^^^^^^^^^^^^^^^^^^^^^^^^
6577
6578 Syntax:
6579 """""""
6580
6581 ::
6582
6583       declare void @llvm.va_start(i8* <arglist>)
6584
6585 Overview:
6586 """""""""
6587
6588 The '``llvm.va_start``' intrinsic initializes ``*<arglist>`` for
6589 subsequent use by ``va_arg``.
6590
6591 Arguments:
6592 """"""""""
6593
6594 The argument is a pointer to a ``va_list`` element to initialize.
6595
6596 Semantics:
6597 """"""""""
6598
6599 The '``llvm.va_start``' intrinsic works just like the ``va_start`` macro
6600 available in C. In a target-dependent way, it initializes the
6601 ``va_list`` element to which the argument points, so that the next call
6602 to ``va_arg`` will produce the first variable argument passed to the
6603 function. Unlike the C ``va_start`` macro, this intrinsic does not need
6604 to know the last argument of the function as the compiler can figure
6605 that out.
6606
6607 '``llvm.va_end``' Intrinsic
6608 ^^^^^^^^^^^^^^^^^^^^^^^^^^^
6609
6610 Syntax:
6611 """""""
6612
6613 ::
6614
6615       declare void @llvm.va_end(i8* <arglist>)
6616
6617 Overview:
6618 """""""""
6619
6620 The '``llvm.va_end``' intrinsic destroys ``*<arglist>``, which has been
6621 initialized previously with ``llvm.va_start`` or ``llvm.va_copy``.
6622
6623 Arguments:
6624 """"""""""
6625
6626 The argument is a pointer to a ``va_list`` to destroy.
6627
6628 Semantics:
6629 """"""""""
6630
6631 The '``llvm.va_end``' intrinsic works just like the ``va_end`` macro
6632 available in C. In a target-dependent way, it destroys the ``va_list``
6633 element to which the argument points. Calls to
6634 :ref:`llvm.va_start <int_va_start>` and
6635 :ref:`llvm.va_copy <int_va_copy>` must be matched exactly with calls to
6636 ``llvm.va_end``.
6637
6638 .. _int_va_copy:
6639
6640 '``llvm.va_copy``' Intrinsic
6641 ^^^^^^^^^^^^^^^^^^^^^^^^^^^^
6642
6643 Syntax:
6644 """""""
6645
6646 ::
6647
6648       declare void @llvm.va_copy(i8* <destarglist>, i8* <srcarglist>)
6649
6650 Overview:
6651 """""""""
6652
6653 The '``llvm.va_copy``' intrinsic copies the current argument position
6654 from the source argument list to the destination argument list.
6655
6656 Arguments:
6657 """"""""""
6658
6659 The first argument is a pointer to a ``va_list`` element to initialize.
6660 The second argument is a pointer to a ``va_list`` element to copy from.
6661
6662 Semantics:
6663 """"""""""
6664
6665 The '``llvm.va_copy``' intrinsic works just like the ``va_copy`` macro
6666 available in C. In a target-dependent way, it copies the source
6667 ``va_list`` element into the destination ``va_list`` element. This
6668 intrinsic is necessary because the `` llvm.va_start`` intrinsic may be
6669 arbitrarily complex and require, for example, memory allocation.
6670
6671 Accurate Garbage Collection Intrinsics
6672 --------------------------------------
6673
6674 LLVM support for `Accurate Garbage Collection <GarbageCollection.html>`_
6675 (GC) requires the implementation and generation of these intrinsics.
6676 These intrinsics allow identification of :ref:`GC roots on the
6677 stack <int_gcroot>`, as well as garbage collector implementations that
6678 require :ref:`read <int_gcread>` and :ref:`write <int_gcwrite>` barriers.
6679 Front-ends for type-safe garbage collected languages should generate
6680 these intrinsics to make use of the LLVM garbage collectors. For more
6681 details, see `Accurate Garbage Collection with
6682 LLVM <GarbageCollection.html>`_.
6683
6684 The garbage collection intrinsics only operate on objects in the generic
6685 address space (address space zero).
6686
6687 .. _int_gcroot:
6688
6689 '``llvm.gcroot``' Intrinsic
6690 ^^^^^^^^^^^^^^^^^^^^^^^^^^^
6691
6692 Syntax:
6693 """""""
6694
6695 ::
6696
6697       declare void @llvm.gcroot(i8** %ptrloc, i8* %metadata)
6698
6699 Overview:
6700 """""""""
6701
6702 The '``llvm.gcroot``' intrinsic declares the existence of a GC root to
6703 the code generator, and allows some metadata to be associated with it.
6704
6705 Arguments:
6706 """"""""""
6707
6708 The first argument specifies the address of a stack object that contains
6709 the root pointer. The second pointer (which must be either a constant or
6710 a global value address) contains the meta-data to be associated with the
6711 root.
6712
6713 Semantics:
6714 """"""""""
6715
6716 At runtime, a call to this intrinsic stores a null pointer into the
6717 "ptrloc" location. At compile-time, the code generator generates
6718 information to allow the runtime to find the pointer at GC safe points.
6719 The '``llvm.gcroot``' intrinsic may only be used in a function which
6720 :ref:`specifies a GC algorithm <gc>`.
6721
6722 .. _int_gcread:
6723
6724 '``llvm.gcread``' Intrinsic
6725 ^^^^^^^^^^^^^^^^^^^^^^^^^^^
6726
6727 Syntax:
6728 """""""
6729
6730 ::
6731
6732       declare i8* @llvm.gcread(i8* %ObjPtr, i8** %Ptr)
6733
6734 Overview:
6735 """""""""
6736
6737 The '``llvm.gcread``' intrinsic identifies reads of references from heap
6738 locations, allowing garbage collector implementations that require read
6739 barriers.
6740
6741 Arguments:
6742 """"""""""
6743
6744 The second argument is the address to read from, which should be an
6745 address allocated from the garbage collector. The first object is a
6746 pointer to the start of the referenced object, if needed by the language
6747 runtime (otherwise null).
6748
6749 Semantics:
6750 """"""""""
6751
6752 The '``llvm.gcread``' intrinsic has the same semantics as a load
6753 instruction, but may be replaced with substantially more complex code by
6754 the garbage collector runtime, as needed. The '``llvm.gcread``'
6755 intrinsic may only be used in a function which :ref:`specifies a GC
6756 algorithm <gc>`.
6757
6758 .. _int_gcwrite:
6759
6760 '``llvm.gcwrite``' Intrinsic
6761 ^^^^^^^^^^^^^^^^^^^^^^^^^^^^
6762
6763 Syntax:
6764 """""""
6765
6766 ::
6767
6768       declare void @llvm.gcwrite(i8* %P1, i8* %Obj, i8** %P2)
6769
6770 Overview:
6771 """""""""
6772
6773 The '``llvm.gcwrite``' intrinsic identifies writes of references to heap
6774 locations, allowing garbage collector implementations that require write
6775 barriers (such as generational or reference counting collectors).
6776
6777 Arguments:
6778 """"""""""
6779
6780 The first argument is the reference to store, the second is the start of
6781 the object to store it to, and the third is the address of the field of
6782 Obj to store to. If the runtime does not require a pointer to the
6783 object, Obj may be null.
6784
6785 Semantics:
6786 """"""""""
6787
6788 The '``llvm.gcwrite``' intrinsic has the same semantics as a store
6789 instruction, but may be replaced with substantially more complex code by
6790 the garbage collector runtime, as needed. The '``llvm.gcwrite``'
6791 intrinsic may only be used in a function which :ref:`specifies a GC
6792 algorithm <gc>`.
6793
6794 Code Generator Intrinsics
6795 -------------------------
6796
6797 These intrinsics are provided by LLVM to expose special features that
6798 may only be implemented with code generator support.
6799
6800 '``llvm.returnaddress``' Intrinsic
6801 ^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^
6802
6803 Syntax:
6804 """""""
6805
6806 ::
6807
6808       declare i8  *@llvm.returnaddress(i32 <level>)
6809
6810 Overview:
6811 """""""""
6812
6813 The '``llvm.returnaddress``' intrinsic attempts to compute a
6814 target-specific value indicating the return address of the current
6815 function or one of its callers.
6816
6817 Arguments:
6818 """"""""""
6819
6820 The argument to this intrinsic indicates which function to return the
6821 address for. Zero indicates the calling function, one indicates its
6822 caller, etc. The argument is **required** to be a constant integer
6823 value.
6824
6825 Semantics:
6826 """"""""""
6827
6828 The '``llvm.returnaddress``' intrinsic either returns a pointer
6829 indicating the return address of the specified call frame, or zero if it
6830 cannot be identified. The value returned by this intrinsic is likely to
6831 be incorrect or 0 for arguments other than zero, so it should only be
6832 used for debugging purposes.
6833
6834 Note that calling this intrinsic does not prevent function inlining or
6835 other aggressive transformations, so the value returned may not be that
6836 of the obvious source-language caller.
6837
6838 '``llvm.frameaddress``' Intrinsic
6839 ^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^
6840
6841 Syntax:
6842 """""""
6843
6844 ::
6845
6846       declare i8* @llvm.frameaddress(i32 <level>)
6847
6848 Overview:
6849 """""""""
6850
6851 The '``llvm.frameaddress``' intrinsic attempts to return the
6852 target-specific frame pointer value for the specified stack frame.
6853
6854 Arguments:
6855 """"""""""
6856
6857 The argument to this intrinsic indicates which function to return the
6858 frame pointer for. Zero indicates the calling function, one indicates
6859 its caller, etc. The argument is **required** to be a constant integer
6860 value.
6861
6862 Semantics:
6863 """"""""""
6864
6865 The '``llvm.frameaddress``' intrinsic either returns a pointer
6866 indicating the frame address of the specified call frame, or zero if it
6867 cannot be identified. The value returned by this intrinsic is likely to
6868 be incorrect or 0 for arguments other than zero, so it should only be
6869 used for debugging purposes.
6870
6871 Note that calling this intrinsic does not prevent function inlining or
6872 other aggressive transformations, so the value returned may not be that
6873 of the obvious source-language caller.
6874
6875 .. _int_read_register:
6876 .. _int_write_register:
6877
6878 '``llvm.read_register``' and '``llvm.write_register``' Intrinsics
6879 ^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^
6880
6881 Syntax:
6882 """""""
6883
6884 ::
6885
6886       declare i32 @llvm.read_register.i32(metadata)
6887       declare i64 @llvm.read_register.i64(metadata)
6888       declare void @llvm.write_register.i32(metadata, i32 @value)
6889       declare void @llvm.write_register.i64(metadata, i64 @value)
6890       !0 = metadata !{metadata !"sp\00"}
6891
6892 Overview:
6893 """""""""
6894
6895 The '``llvm.read_register``' and '``llvm.write_register``' intrinsics
6896 provides access to the named register. The register must be valid on
6897 the architecture being compiled to. The type needs to be compatible
6898 with the register being read.
6899
6900 Semantics:
6901 """"""""""
6902
6903 The '``llvm.read_register``' intrinsic returns the current value of the
6904 register, where possible. The '``llvm.write_register``' intrinsic sets
6905 the current value of the register, where possible.
6906
6907 This is useful to implement named register global variables that need
6908 to always be mapped to a specific register, as is common practice on
6909 bare-metal programs including OS kernels.
6910
6911 The compiler doesn't check for register availability or use of the used
6912 register in surrounding code, including inline assembly. Because of that,
6913 allocatable registers are not supported.
6914
6915 Warning: So far it only works with the stack pointer on selected
6916 architectures (ARM, AArch64, PowerPC and x86_64). Significant amount of
6917 work is needed to support other registers and even more so, allocatable
6918 registers.
6919
6920 .. _int_stacksave:
6921
6922 '``llvm.stacksave``' Intrinsic
6923 ^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^
6924
6925 Syntax:
6926 """""""
6927
6928 ::
6929
6930       declare i8* @llvm.stacksave()
6931
6932 Overview:
6933 """""""""
6934
6935 The '``llvm.stacksave``' intrinsic is used to remember the current state
6936 of the function stack, for use with
6937 :ref:`llvm.stackrestore <int_stackrestore>`. This is useful for
6938 implementing language features like scoped automatic variable sized
6939 arrays in C99.
6940
6941 Semantics:
6942 """"""""""
6943
6944 This intrinsic returns a opaque pointer value that can be passed to
6945 :ref:`llvm.stackrestore <int_stackrestore>`. When an
6946 ``llvm.stackrestore`` intrinsic is executed with a value saved from
6947 ``llvm.stacksave``, it effectively restores the state of the stack to
6948 the state it was in when the ``llvm.stacksave`` intrinsic executed. In
6949 practice, this pops any :ref:`alloca <i_alloca>` blocks from the stack that
6950 were allocated after the ``llvm.stacksave`` was executed.
6951
6952 .. _int_stackrestore:
6953
6954 '``llvm.stackrestore``' Intrinsic
6955 ^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^
6956
6957 Syntax:
6958 """""""
6959
6960 ::
6961
6962       declare void @llvm.stackrestore(i8* %ptr)
6963
6964 Overview:
6965 """""""""
6966
6967 The '``llvm.stackrestore``' intrinsic is used to restore the state of
6968 the function stack to the state it was in when the corresponding
6969 :ref:`llvm.stacksave <int_stacksave>` intrinsic executed. This is
6970 useful for implementing language features like scoped automatic variable
6971 sized arrays in C99.
6972
6973 Semantics:
6974 """"""""""
6975
6976 See the description for :ref:`llvm.stacksave <int_stacksave>`.
6977
6978 '``llvm.prefetch``' Intrinsic
6979 ^^^^^^^^^^^^^^^^^^^^^^^^^^^^^
6980
6981 Syntax:
6982 """""""
6983
6984 ::
6985
6986       declare void @llvm.prefetch(i8* <address>, i32 <rw>, i32 <locality>, i32 <cache type>)
6987
6988 Overview:
6989 """""""""
6990
6991 The '``llvm.prefetch``' intrinsic is a hint to the code generator to
6992 insert a prefetch instruction if supported; otherwise, it is a noop.
6993 Prefetches have no effect on the behavior of the program but can change
6994 its performance characteristics.
6995
6996 Arguments:
6997 """"""""""
6998
6999 ``address`` is the address to be prefetched, ``rw`` is the specifier
7000 determining if the fetch should be for a read (0) or write (1), and
7001 ``locality`` is a temporal locality specifier ranging from (0) - no
7002 locality, to (3) - extremely local keep in cache. The ``cache type``
7003 specifies whether the prefetch is performed on the data (1) or
7004 instruction (0) cache. The ``rw``, ``locality`` and ``cache type``
7005 arguments must be constant integers.
7006
7007 Semantics:
7008 """"""""""
7009
7010 This intrinsic does not modify the behavior of the program. In
7011 particular, prefetches cannot trap and do not produce a value. On
7012 targets that support this intrinsic, the prefetch can provide hints to
7013 the processor cache for better performance.
7014
7015 '``llvm.pcmarker``' Intrinsic
7016 ^^^^^^^^^^^^^^^^^^^^^^^^^^^^^
7017
7018 Syntax:
7019 """""""
7020
7021 ::
7022
7023       declare void @llvm.pcmarker(i32 <id>)
7024
7025 Overview:
7026 """""""""
7027
7028 The '``llvm.pcmarker``' intrinsic is a method to export a Program
7029 Counter (PC) in a region of code to simulators and other tools. The
7030 method is target specific, but it is expected that the marker will use
7031 exported symbols to transmit the PC of the marker. The marker makes no
7032 guarantees that it will remain with any specific instruction after
7033 optimizations. It is possible that the presence of a marker will inhibit
7034 optimizations. The intended use is to be inserted after optimizations to
7035 allow correlations of simulation runs.
7036
7037 Arguments:
7038 """"""""""
7039
7040 ``id`` is a numerical id identifying the marker.
7041
7042 Semantics:
7043 """"""""""
7044
7045 This intrinsic does not modify the behavior of the program. Backends
7046 that do not support this intrinsic may ignore it.
7047
7048 '``llvm.readcyclecounter``' Intrinsic
7049 ^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^
7050
7051 Syntax:
7052 """""""
7053
7054 ::
7055
7056       declare i64 @llvm.readcyclecounter()
7057
7058 Overview:
7059 """""""""
7060
7061 The '``llvm.readcyclecounter``' intrinsic provides access to the cycle
7062 counter register (or similar low latency, high accuracy clocks) on those
7063 targets that support it. On X86, it should map to RDTSC. On Alpha, it
7064 should map to RPCC. As the backing counters overflow quickly (on the
7065 order of 9 seconds on alpha), this should only be used for small
7066 timings.
7067
7068 Semantics:
7069 """"""""""
7070
7071 When directly supported, reading the cycle counter should not modify any
7072 memory. Implementations are allowed to either return a application
7073 specific value or a system wide value. On backends without support, this
7074 is lowered to a constant 0.
7075
7076 Note that runtime support may be conditional on the privilege-level code is
7077 running at and the host platform.
7078
7079 '``llvm.clear_cache``' Intrinsic
7080 ^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^
7081
7082 Syntax:
7083 """""""
7084
7085 ::
7086
7087       declare void @llvm.clear_cache(i8*, i8*)
7088
7089 Overview:
7090 """""""""
7091
7092 The '``llvm.clear_cache``' intrinsic ensures visibility of modifications
7093 in the specified range to the execution unit of the processor. On
7094 targets with non-unified instruction and data cache, the implementation
7095 flushes the instruction cache.
7096
7097 Semantics:
7098 """"""""""
7099
7100 On platforms with coherent instruction and data caches (e.g. x86), this
7101 intrinsic is a nop. On platforms with non-coherent instruction and data
7102 cache (e.g. ARM, MIPS), the intrinsic is lowered either to appropriate
7103 instructions or a system call, if cache flushing requires special
7104 privileges.
7105
7106 The default behavior is to emit a call to ``__clear_cache`` from the run
7107 time library.
7108
7109 This instrinsic does *not* empty the instruction pipeline. Modifications
7110 of the current function are outside the scope of the intrinsic.
7111
7112 Standard C Library Intrinsics
7113 -----------------------------
7114
7115 LLVM provides intrinsics for a few important standard C library
7116 functions. These intrinsics allow source-language front-ends to pass
7117 information about the alignment of the pointer arguments to the code
7118 generator, providing opportunity for more efficient code generation.
7119
7120 .. _int_memcpy:
7121
7122 '``llvm.memcpy``' Intrinsic
7123 ^^^^^^^^^^^^^^^^^^^^^^^^^^^
7124
7125 Syntax:
7126 """""""
7127
7128 This is an overloaded intrinsic. You can use ``llvm.memcpy`` on any
7129 integer bit width and for different address spaces. Not all targets
7130 support all bit widths however.
7131
7132 ::
7133
7134       declare void @llvm.memcpy.p0i8.p0i8.i32(i8* <dest>, i8* <src>,
7135                                               i32 <len>, i32 <align>, i1 <isvolatile>)
7136       declare void @llvm.memcpy.p0i8.p0i8.i64(i8* <dest>, i8* <src>,
7137                                               i64 <len>, i32 <align>, i1 <isvolatile>)
7138
7139 Overview:
7140 """""""""
7141
7142 The '``llvm.memcpy.*``' intrinsics copy a block of memory from the
7143 source location to the destination location.
7144
7145 Note that, unlike the standard libc function, the ``llvm.memcpy.*``
7146 intrinsics do not return a value, takes extra alignment/isvolatile
7147 arguments and the pointers can be in specified address spaces.
7148
7149 Arguments:
7150 """"""""""
7151
7152 The first argument is a pointer to the destination, the second is a
7153 pointer to the source. The third argument is an integer argument
7154 specifying the number of bytes to copy, the fourth argument is the
7155 alignment of the source and destination locations, and the fifth is a
7156 boolean indicating a volatile access.
7157
7158 If the call to this intrinsic has an alignment value that is not 0 or 1,
7159 then the caller guarantees that both the source and destination pointers
7160 are aligned to that boundary.
7161
7162 If the ``isvolatile`` parameter is ``true``, the ``llvm.memcpy`` call is
7163 a :ref:`volatile operation <volatile>`. The detailed access behavior is not
7164 very cleanly specified and it is unwise to depend on it.
7165
7166 Semantics:
7167 """"""""""
7168
7169 The '``llvm.memcpy.*``' intrinsics copy a block of memory from the
7170 source location to the destination location, which are not allowed to
7171 overlap. It copies "len" bytes of memory over. If the argument is known
7172 to be aligned to some boundary, this can be specified as the fourth
7173 argument, otherwise it should be set to 0 or 1 (both meaning no alignment).
7174
7175 '``llvm.memmove``' Intrinsic
7176 ^^^^^^^^^^^^^^^^^^^^^^^^^^^^
7177
7178 Syntax:
7179 """""""
7180
7181 This is an overloaded intrinsic. You can use llvm.memmove on any integer
7182 bit width and for different address space. Not all targets support all
7183 bit widths however.
7184
7185 ::
7186
7187       declare void @llvm.memmove.p0i8.p0i8.i32(i8* <dest>, i8* <src>,
7188                                                i32 <len>, i32 <align>, i1 <isvolatile>)
7189       declare void @llvm.memmove.p0i8.p0i8.i64(i8* <dest>, i8* <src>,
7190                                                i64 <len>, i32 <align>, i1 <isvolatile>)
7191
7192 Overview:
7193 """""""""
7194
7195 The '``llvm.memmove.*``' intrinsics move a block of memory from the
7196 source location to the destination location. It is similar to the
7197 '``llvm.memcpy``' intrinsic but allows the two memory locations to
7198 overlap.
7199
7200 Note that, unlike the standard libc function, the ``llvm.memmove.*``
7201 intrinsics do not return a value, takes extra alignment/isvolatile
7202 arguments and the pointers can be in specified address spaces.
7203
7204 Arguments:
7205 """"""""""
7206
7207 The first argument is a pointer to the destination, the second is a
7208 pointer to the source. The third argument is an integer argument
7209 specifying the number of bytes to copy, the fourth argument is the
7210 alignment of the source and destination locations, and the fifth is a
7211 boolean indicating a volatile access.
7212
7213 If the call to this intrinsic has an alignment value that is not 0 or 1,
7214 then the caller guarantees that the source and destination pointers are
7215 aligned to that boundary.
7216
7217 If the ``isvolatile`` parameter is ``true``, the ``llvm.memmove`` call
7218 is a :ref:`volatile operation <volatile>`. The detailed access behavior is
7219 not very cleanly specified and it is unwise to depend on it.
7220
7221 Semantics:
7222 """"""""""
7223
7224 The '``llvm.memmove.*``' intrinsics copy a block of memory from the
7225 source location to the destination location, which may overlap. It
7226 copies "len" bytes of memory over. If the argument is known to be
7227 aligned to some boundary, this can be specified as the fourth argument,
7228 otherwise it should be set to 0 or 1 (both meaning no alignment).
7229
7230 '``llvm.memset.*``' Intrinsics
7231 ^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^
7232
7233 Syntax:
7234 """""""
7235
7236 This is an overloaded intrinsic. You can use llvm.memset on any integer
7237 bit width and for different address spaces. However, not all targets
7238 support all bit widths.
7239
7240 ::
7241
7242       declare void @llvm.memset.p0i8.i32(i8* <dest>, i8 <val>,
7243                                          i32 <len>, i32 <align>, i1 <isvolatile>)
7244       declare void @llvm.memset.p0i8.i64(i8* <dest>, i8 <val>,
7245                                          i64 <len>, i32 <align>, i1 <isvolatile>)
7246
7247 Overview:
7248 """""""""
7249
7250 The '``llvm.memset.*``' intrinsics fill a block of memory with a
7251 particular byte value.
7252
7253 Note that, unlike the standard libc function, the ``llvm.memset``
7254 intrinsic does not return a value and takes extra alignment/volatile
7255 arguments. Also, the destination can be in an arbitrary address space.
7256
7257 Arguments:
7258 """"""""""
7259
7260 The first argument is a pointer to the destination to fill, the second
7261 is the byte value with which to fill it, the third argument is an
7262 integer argument specifying the number of bytes to fill, and the fourth
7263 argument is the known alignment of the destination location.
7264
7265 If the call to this intrinsic has an alignment value that is not 0 or 1,
7266 then the caller guarantees that the destination pointer is aligned to
7267 that boundary.
7268
7269 If the ``isvolatile`` parameter is ``true``, the ``llvm.memset`` call is
7270 a :ref:`volatile operation <volatile>`. The detailed access behavior is not
7271 very cleanly specified and it is unwise to depend on it.
7272
7273 Semantics:
7274 """"""""""
7275
7276 The '``llvm.memset.*``' intrinsics fill "len" bytes of memory starting
7277 at the destination location. If the argument is known to be aligned to
7278 some boundary, this can be specified as the fourth argument, otherwise
7279 it should be set to 0 or 1 (both meaning no alignment).
7280
7281 '``llvm.sqrt.*``' Intrinsic
7282 ^^^^^^^^^^^^^^^^^^^^^^^^^^^
7283
7284 Syntax:
7285 """""""
7286
7287 This is an overloaded intrinsic. You can use ``llvm.sqrt`` on any
7288 floating point or vector of floating point type. Not all targets support
7289 all types however.
7290
7291 ::
7292
7293       declare float     @llvm.sqrt.f32(float %Val)
7294       declare double    @llvm.sqrt.f64(double %Val)
7295       declare x86_fp80  @llvm.sqrt.f80(x86_fp80 %Val)
7296       declare fp128     @llvm.sqrt.f128(fp128 %Val)
7297       declare ppc_fp128 @llvm.sqrt.ppcf128(ppc_fp128 %Val)
7298
7299 Overview:
7300 """""""""
7301
7302 The '``llvm.sqrt``' intrinsics return the sqrt of the specified operand,
7303 returning the same value as the libm '``sqrt``' functions would. Unlike
7304 ``sqrt`` in libm, however, ``llvm.sqrt`` has undefined behavior for
7305 negative numbers other than -0.0 (which allows for better optimization,
7306 because there is no need to worry about errno being set).
7307 ``llvm.sqrt(-0.0)`` is defined to return -0.0 like IEEE sqrt.
7308
7309 Arguments:
7310 """"""""""
7311
7312 The argument and return value are floating point numbers of the same
7313 type.
7314
7315 Semantics:
7316 """"""""""
7317
7318 This function returns the sqrt of the specified operand if it is a
7319 nonnegative floating point number.
7320
7321 '``llvm.powi.*``' Intrinsic
7322 ^^^^^^^^^^^^^^^^^^^^^^^^^^^
7323
7324 Syntax:
7325 """""""
7326
7327 This is an overloaded intrinsic. You can use ``llvm.powi`` on any
7328 floating point or vector of floating point type. Not all targets support
7329 all types however.
7330
7331 ::
7332
7333       declare float     @llvm.powi.f32(float  %Val, i32 %power)
7334       declare double    @llvm.powi.f64(double %Val, i32 %power)
7335       declare x86_fp80  @llvm.powi.f80(x86_fp80  %Val, i32 %power)
7336       declare fp128     @llvm.powi.f128(fp128 %Val, i32 %power)
7337       declare ppc_fp128 @llvm.powi.ppcf128(ppc_fp128  %Val, i32 %power)
7338
7339 Overview:
7340 """""""""
7341
7342 The '``llvm.powi.*``' intrinsics return the first operand raised to the
7343 specified (positive or negative) power. The order of evaluation of
7344 multiplications is not defined. When a vector of floating point type is
7345 used, the second argument remains a scalar integer value.
7346
7347 Arguments:
7348 """"""""""
7349
7350 The second argument is an integer power, and the first is a value to
7351 raise to that power.
7352
7353 Semantics:
7354 """"""""""
7355
7356 This function returns the first value raised to the second power with an
7357 unspecified sequence of rounding operations.
7358
7359 '``llvm.sin.*``' Intrinsic
7360 ^^^^^^^^^^^^^^^^^^^^^^^^^^
7361
7362 Syntax:
7363 """""""
7364
7365 This is an overloaded intrinsic. You can use ``llvm.sin`` on any
7366 floating point or vector of floating point type. Not all targets support
7367 all types however.
7368
7369 ::
7370
7371       declare float     @llvm.sin.f32(float  %Val)
7372       declare double    @llvm.sin.f64(double %Val)
7373       declare x86_fp80  @llvm.sin.f80(x86_fp80  %Val)
7374       declare fp128     @llvm.sin.f128(fp128 %Val)
7375       declare ppc_fp128 @llvm.sin.ppcf128(ppc_fp128  %Val)
7376
7377 Overview:
7378 """""""""
7379
7380 The '``llvm.sin.*``' intrinsics return the sine of the operand.
7381
7382 Arguments:
7383 """"""""""
7384
7385 The argument and return value are floating point numbers of the same
7386 type.
7387
7388 Semantics:
7389 """"""""""
7390
7391 This function returns the sine of the specified operand, returning the
7392 same values as the libm ``sin`` functions would, and handles error
7393 conditions in the same way.
7394
7395 '``llvm.cos.*``' Intrinsic
7396 ^^^^^^^^^^^^^^^^^^^^^^^^^^
7397
7398 Syntax:
7399 """""""
7400
7401 This is an overloaded intrinsic. You can use ``llvm.cos`` on any
7402 floating point or vector of floating point type. Not all targets support
7403 all types however.
7404
7405 ::
7406
7407       declare float     @llvm.cos.f32(float  %Val)
7408       declare double    @llvm.cos.f64(double %Val)
7409       declare x86_fp80  @llvm.cos.f80(x86_fp80  %Val)
7410       declare fp128     @llvm.cos.f128(fp128 %Val)
7411       declare ppc_fp128 @llvm.cos.ppcf128(ppc_fp128  %Val)
7412
7413 Overview:
7414 """""""""
7415
7416 The '``llvm.cos.*``' intrinsics return the cosine of the operand.
7417
7418 Arguments:
7419 """"""""""
7420
7421 The argument and return value are floating point numbers of the same
7422 type.
7423
7424 Semantics:
7425 """"""""""
7426
7427 This function returns the cosine of the specified operand, returning the
7428 same values as the libm ``cos`` functions would, and handles error
7429 conditions in the same way.
7430
7431 '``llvm.pow.*``' Intrinsic
7432 ^^^^^^^^^^^^^^^^^^^^^^^^^^
7433
7434 Syntax:
7435 """""""
7436
7437 This is an overloaded intrinsic. You can use ``llvm.pow`` on any
7438 floating point or vector of floating point type. Not all targets support
7439 all types however.
7440
7441 ::
7442
7443       declare float     @llvm.pow.f32(float  %Val, float %Power)
7444       declare double    @llvm.pow.f64(double %Val, double %Power)
7445       declare x86_fp80  @llvm.pow.f80(x86_fp80  %Val, x86_fp80 %Power)
7446       declare fp128     @llvm.pow.f128(fp128 %Val, fp128 %Power)
7447       declare ppc_fp128 @llvm.pow.ppcf128(ppc_fp128  %Val, ppc_fp128 Power)
7448
7449 Overview:
7450 """""""""
7451
7452 The '``llvm.pow.*``' intrinsics return the first operand raised to the
7453 specified (positive or negative) power.
7454
7455 Arguments:
7456 """"""""""
7457
7458 The second argument is a floating point power, and the first is a value
7459 to raise to that power.
7460
7461 Semantics:
7462 """"""""""
7463
7464 This function returns the first value raised to the second power,
7465 returning the same values as the libm ``pow`` functions would, and
7466 handles error conditions in the same way.
7467
7468 '``llvm.exp.*``' Intrinsic
7469 ^^^^^^^^^^^^^^^^^^^^^^^^^^
7470
7471 Syntax:
7472 """""""
7473
7474 This is an overloaded intrinsic. You can use ``llvm.exp`` on any
7475 floating point or vector of floating point type. Not all targets support
7476 all types however.
7477
7478 ::
7479
7480       declare float     @llvm.exp.f32(float  %Val)
7481       declare double    @llvm.exp.f64(double %Val)
7482       declare x86_fp80  @llvm.exp.f80(x86_fp80  %Val)
7483       declare fp128     @llvm.exp.f128(fp128 %Val)
7484       declare ppc_fp128 @llvm.exp.ppcf128(ppc_fp128  %Val)
7485
7486 Overview:
7487 """""""""
7488
7489 The '``llvm.exp.*``' intrinsics perform the exp function.
7490
7491 Arguments:
7492 """"""""""
7493
7494 The argument and return value are floating point numbers of the same
7495 type.
7496
7497 Semantics:
7498 """"""""""
7499
7500 This function returns the same values as the libm ``exp`` functions
7501 would, and handles error conditions in the same way.
7502
7503 '``llvm.exp2.*``' Intrinsic
7504 ^^^^^^^^^^^^^^^^^^^^^^^^^^^
7505
7506 Syntax:
7507 """""""
7508
7509 This is an overloaded intrinsic. You can use ``llvm.exp2`` on any
7510 floating point or vector of floating point type. Not all targets support
7511 all types however.
7512
7513 ::
7514
7515       declare float     @llvm.exp2.f32(float  %Val)
7516       declare double    @llvm.exp2.f64(double %Val)
7517       declare x86_fp80  @llvm.exp2.f80(x86_fp80  %Val)
7518       declare fp128     @llvm.exp2.f128(fp128 %Val)
7519       declare ppc_fp128 @llvm.exp2.ppcf128(ppc_fp128  %Val)
7520
7521 Overview:
7522 """""""""
7523
7524 The '``llvm.exp2.*``' intrinsics perform the exp2 function.
7525
7526 Arguments:
7527 """"""""""
7528
7529 The argument and return value are floating point numbers of the same
7530 type.
7531
7532 Semantics:
7533 """"""""""
7534
7535 This function returns the same values as the libm ``exp2`` functions
7536 would, and handles error conditions in the same way.
7537
7538 '``llvm.log.*``' Intrinsic
7539 ^^^^^^^^^^^^^^^^^^^^^^^^^^
7540
7541 Syntax:
7542 """""""
7543
7544 This is an overloaded intrinsic. You can use ``llvm.log`` on any
7545 floating point or vector of floating point type. Not all targets support
7546 all types however.
7547
7548 ::
7549
7550       declare float     @llvm.log.f32(float  %Val)
7551       declare double    @llvm.log.f64(double %Val)
7552       declare x86_fp80  @llvm.log.f80(x86_fp80  %Val)
7553       declare fp128     @llvm.log.f128(fp128 %Val)
7554       declare ppc_fp128 @llvm.log.ppcf128(ppc_fp128  %Val)
7555
7556 Overview:
7557 """""""""
7558
7559 The '``llvm.log.*``' intrinsics perform the log function.
7560
7561 Arguments:
7562 """"""""""
7563
7564 The argument and return value are floating point numbers of the same
7565 type.
7566
7567 Semantics:
7568 """"""""""
7569
7570 This function returns the same values as the libm ``log`` functions
7571 would, and handles error conditions in the same way.
7572
7573 '``llvm.log10.*``' Intrinsic
7574 ^^^^^^^^^^^^^^^^^^^^^^^^^^^^
7575
7576 Syntax:
7577 """""""
7578
7579 This is an overloaded intrinsic. You can use ``llvm.log10`` on any
7580 floating point or vector of floating point type. Not all targets support
7581 all types however.
7582
7583 ::
7584
7585       declare float     @llvm.log10.f32(float  %Val)
7586       declare double    @llvm.log10.f64(double %Val)
7587       declare x86_fp80  @llvm.log10.f80(x86_fp80  %Val)
7588       declare fp128     @llvm.log10.f128(fp128 %Val)
7589       declare ppc_fp128 @llvm.log10.ppcf128(ppc_fp128  %Val)
7590
7591 Overview:
7592 """""""""
7593
7594 The '``llvm.log10.*``' intrinsics perform the log10 function.
7595
7596 Arguments:
7597 """"""""""
7598
7599 The argument and return value are floating point numbers of the same
7600 type.
7601
7602 Semantics:
7603 """"""""""
7604
7605 This function returns the same values as the libm ``log10`` functions
7606 would, and handles error conditions in the same way.
7607
7608 '``llvm.log2.*``' Intrinsic
7609 ^^^^^^^^^^^^^^^^^^^^^^^^^^^
7610
7611 Syntax:
7612 """""""
7613
7614 This is an overloaded intrinsic. You can use ``llvm.log2`` on any
7615 floating point or vector of floating point type. Not all targets support
7616 all types however.
7617
7618 ::
7619
7620       declare float     @llvm.log2.f32(float  %Val)
7621       declare double    @llvm.log2.f64(double %Val)
7622       declare x86_fp80  @llvm.log2.f80(x86_fp80  %Val)
7623       declare fp128     @llvm.log2.f128(fp128 %Val)
7624       declare ppc_fp128 @llvm.log2.ppcf128(ppc_fp128  %Val)
7625
7626 Overview:
7627 """""""""
7628
7629 The '``llvm.log2.*``' intrinsics perform the log2 function.
7630
7631 Arguments:
7632 """"""""""
7633
7634 The argument and return value are floating point numbers of the same
7635 type.
7636
7637 Semantics:
7638 """"""""""
7639
7640 This function returns the same values as the libm ``log2`` functions
7641 would, and handles error conditions in the same way.
7642
7643 '``llvm.fma.*``' Intrinsic
7644 ^^^^^^^^^^^^^^^^^^^^^^^^^^
7645
7646 Syntax:
7647 """""""
7648
7649 This is an overloaded intrinsic. You can use ``llvm.fma`` on any
7650 floating point or vector of floating point type. Not all targets support
7651 all types however.
7652
7653 ::
7654
7655       declare float     @llvm.fma.f32(float  %a, float  %b, float  %c)
7656       declare double    @llvm.fma.f64(double %a, double %b, double %c)
7657       declare x86_fp80  @llvm.fma.f80(x86_fp80 %a, x86_fp80 %b, x86_fp80 %c)
7658       declare fp128     @llvm.fma.f128(fp128 %a, fp128 %b, fp128 %c)
7659       declare ppc_fp128 @llvm.fma.ppcf128(ppc_fp128 %a, ppc_fp128 %b, ppc_fp128 %c)
7660
7661 Overview:
7662 """""""""
7663
7664 The '``llvm.fma.*``' intrinsics perform the fused multiply-add
7665 operation.
7666
7667 Arguments:
7668 """"""""""
7669
7670 The argument and return value are floating point numbers of the same
7671 type.
7672
7673 Semantics:
7674 """"""""""
7675
7676 This function returns the same values as the libm ``fma`` functions
7677 would, and does not set errno.
7678
7679 '``llvm.fabs.*``' Intrinsic
7680 ^^^^^^^^^^^^^^^^^^^^^^^^^^^
7681
7682 Syntax:
7683 """""""
7684
7685 This is an overloaded intrinsic. You can use ``llvm.fabs`` on any
7686 floating point or vector of floating point type. Not all targets support
7687 all types however.
7688
7689 ::
7690
7691       declare float     @llvm.fabs.f32(float  %Val)
7692       declare double    @llvm.fabs.f64(double %Val)
7693       declare x86_fp80  @llvm.fabs.f80(x86_fp80  %Val)
7694       declare fp128     @llvm.fabs.f128(fp128 %Val)
7695       declare ppc_fp128 @llvm.fabs.ppcf128(ppc_fp128  %Val)
7696
7697 Overview:
7698 """""""""
7699
7700 The '``llvm.fabs.*``' intrinsics return the absolute value of the
7701 operand.
7702
7703 Arguments:
7704 """"""""""
7705
7706 The argument and return value are floating point numbers of the same
7707 type.
7708
7709 Semantics:
7710 """"""""""
7711
7712 This function returns the same values as the libm ``fabs`` functions
7713 would, and handles error conditions in the same way.
7714
7715 '``llvm.copysign.*``' Intrinsic
7716 ^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^
7717
7718 Syntax:
7719 """""""
7720
7721 This is an overloaded intrinsic. You can use ``llvm.copysign`` on any
7722 floating point or vector of floating point type. Not all targets support
7723 all types however.
7724
7725 ::
7726
7727       declare float     @llvm.copysign.f32(float  %Mag, float  %Sgn)
7728       declare double    @llvm.copysign.f64(double %Mag, double %Sgn)
7729       declare x86_fp80  @llvm.copysign.f80(x86_fp80  %Mag, x86_fp80  %Sgn)
7730       declare fp128     @llvm.copysign.f128(fp128 %Mag, fp128 %Sgn)
7731       declare ppc_fp128 @llvm.copysign.ppcf128(ppc_fp128  %Mag, ppc_fp128  %Sgn)
7732
7733 Overview:
7734 """""""""
7735
7736 The '``llvm.copysign.*``' intrinsics return a value with the magnitude of the
7737 first operand and the sign of the second operand.
7738
7739 Arguments:
7740 """"""""""
7741
7742 The arguments and return value are floating point numbers of the same
7743 type.
7744
7745 Semantics:
7746 """"""""""
7747
7748 This function returns the same values as the libm ``copysign``
7749 functions would, and handles error conditions in the same way.
7750
7751 '``llvm.floor.*``' Intrinsic
7752 ^^^^^^^^^^^^^^^^^^^^^^^^^^^^
7753
7754 Syntax:
7755 """""""
7756
7757 This is an overloaded intrinsic. You can use ``llvm.floor`` on any
7758 floating point or vector of floating point type. Not all targets support
7759 all types however.
7760
7761 ::
7762
7763       declare float     @llvm.floor.f32(float  %Val)
7764       declare double    @llvm.floor.f64(double %Val)
7765       declare x86_fp80  @llvm.floor.f80(x86_fp80  %Val)
7766       declare fp128     @llvm.floor.f128(fp128 %Val)
7767       declare ppc_fp128 @llvm.floor.ppcf128(ppc_fp128  %Val)
7768
7769 Overview:
7770 """""""""
7771
7772 The '``llvm.floor.*``' intrinsics return the floor of the operand.
7773
7774 Arguments:
7775 """"""""""
7776
7777 The argument and return value are floating point numbers of the same
7778 type.
7779
7780 Semantics:
7781 """"""""""
7782
7783 This function returns the same values as the libm ``floor`` functions
7784 would, and handles error conditions in the same way.
7785
7786 '``llvm.ceil.*``' Intrinsic
7787 ^^^^^^^^^^^^^^^^^^^^^^^^^^^
7788
7789 Syntax:
7790 """""""
7791
7792 This is an overloaded intrinsic. You can use ``llvm.ceil`` on any
7793 floating point or vector of floating point type. Not all targets support
7794 all types however.
7795
7796 ::
7797
7798       declare float     @llvm.ceil.f32(float  %Val)
7799       declare double    @llvm.ceil.f64(double %Val)
7800       declare x86_fp80  @llvm.ceil.f80(x86_fp80  %Val)
7801       declare fp128     @llvm.ceil.f128(fp128 %Val)
7802       declare ppc_fp128 @llvm.ceil.ppcf128(ppc_fp128  %Val)
7803
7804 Overview:
7805 """""""""
7806
7807 The '``llvm.ceil.*``' intrinsics return the ceiling of the operand.
7808
7809 Arguments:
7810 """"""""""
7811
7812 The argument and return value are floating point numbers of the same
7813 type.
7814
7815 Semantics:
7816 """"""""""
7817
7818 This function returns the same values as the libm ``ceil`` functions
7819 would, and handles error conditions in the same way.
7820
7821 '``llvm.trunc.*``' Intrinsic
7822 ^^^^^^^^^^^^^^^^^^^^^^^^^^^^
7823
7824 Syntax:
7825 """""""
7826
7827 This is an overloaded intrinsic. You can use ``llvm.trunc`` on any
7828 floating point or vector of floating point type. Not all targets support
7829 all types however.
7830
7831 ::
7832
7833       declare float     @llvm.trunc.f32(float  %Val)
7834       declare double    @llvm.trunc.f64(double %Val)
7835       declare x86_fp80  @llvm.trunc.f80(x86_fp80  %Val)
7836       declare fp128     @llvm.trunc.f128(fp128 %Val)
7837       declare ppc_fp128 @llvm.trunc.ppcf128(ppc_fp128  %Val)
7838
7839 Overview:
7840 """""""""
7841
7842 The '``llvm.trunc.*``' intrinsics returns the operand rounded to the
7843 nearest integer not larger in magnitude than the operand.
7844
7845 Arguments:
7846 """"""""""
7847
7848 The argument and return value are floating point numbers of the same
7849 type.
7850
7851 Semantics:
7852 """"""""""
7853
7854 This function returns the same values as the libm ``trunc`` functions
7855 would, and handles error conditions in the same way.
7856
7857 '``llvm.rint.*``' Intrinsic
7858 ^^^^^^^^^^^^^^^^^^^^^^^^^^^
7859
7860 Syntax:
7861 """""""
7862
7863 This is an overloaded intrinsic. You can use ``llvm.rint`` on any
7864 floating point or vector of floating point type. Not all targets support
7865 all types however.
7866
7867 ::
7868
7869       declare float     @llvm.rint.f32(float  %Val)
7870       declare double    @llvm.rint.f64(double %Val)
7871       declare x86_fp80  @llvm.rint.f80(x86_fp80  %Val)
7872       declare fp128     @llvm.rint.f128(fp128 %Val)
7873       declare ppc_fp128 @llvm.rint.ppcf128(ppc_fp128  %Val)
7874
7875 Overview:
7876 """""""""
7877
7878 The '``llvm.rint.*``' intrinsics returns the operand rounded to the
7879 nearest integer. It may raise an inexact floating-point exception if the
7880 operand isn't an integer.
7881
7882 Arguments:
7883 """"""""""
7884
7885 The argument and return value are floating point numbers of the same
7886 type.
7887
7888 Semantics:
7889 """"""""""
7890
7891 This function returns the same values as the libm ``rint`` functions
7892 would, and handles error conditions in the same way.
7893
7894 '``llvm.nearbyint.*``' Intrinsic
7895 ^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^
7896
7897 Syntax:
7898 """""""
7899
7900 This is an overloaded intrinsic. You can use ``llvm.nearbyint`` on any
7901 floating point or vector of floating point type. Not all targets support
7902 all types however.
7903
7904 ::
7905
7906       declare float     @llvm.nearbyint.f32(float  %Val)
7907       declare double    @llvm.nearbyint.f64(double %Val)
7908       declare x86_fp80  @llvm.nearbyint.f80(x86_fp80  %Val)
7909       declare fp128     @llvm.nearbyint.f128(fp128 %Val)
7910       declare ppc_fp128 @llvm.nearbyint.ppcf128(ppc_fp128  %Val)
7911
7912 Overview:
7913 """""""""
7914
7915 The '``llvm.nearbyint.*``' intrinsics returns the operand rounded to the
7916 nearest integer.
7917
7918 Arguments:
7919 """"""""""
7920
7921 The argument and return value are floating point numbers of the same
7922 type.
7923
7924 Semantics:
7925 """"""""""
7926
7927 This function returns the same values as the libm ``nearbyint``
7928 functions would, and handles error conditions in the same way.
7929
7930 '``llvm.round.*``' Intrinsic
7931 ^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^
7932
7933 Syntax:
7934 """""""
7935
7936 This is an overloaded intrinsic. You can use ``llvm.round`` on any
7937 floating point or vector of floating point type. Not all targets support
7938 all types however.
7939
7940 ::
7941
7942       declare float     @llvm.round.f32(float  %Val)
7943       declare double    @llvm.round.f64(double %Val)
7944       declare x86_fp80  @llvm.round.f80(x86_fp80  %Val)
7945       declare fp128     @llvm.round.f128(fp128 %Val)
7946       declare ppc_fp128 @llvm.round.ppcf128(ppc_fp128  %Val)
7947
7948 Overview:
7949 """""""""
7950
7951 The '``llvm.round.*``' intrinsics returns the operand rounded to the
7952 nearest integer.
7953
7954 Arguments:
7955 """"""""""
7956
7957 The argument and return value are floating point numbers of the same
7958 type.
7959
7960 Semantics:
7961 """"""""""
7962
7963 This function returns the same values as the libm ``round``
7964 functions would, and handles error conditions in the same way.
7965
7966 Bit Manipulation Intrinsics
7967 ---------------------------
7968
7969 LLVM provides intrinsics for a few important bit manipulation
7970 operations. These allow efficient code generation for some algorithms.
7971
7972 '``llvm.bswap.*``' Intrinsics
7973 ^^^^^^^^^^^^^^^^^^^^^^^^^^^^^
7974
7975 Syntax:
7976 """""""
7977
7978 This is an overloaded intrinsic function. You can use bswap on any
7979 integer type that is an even number of bytes (i.e. BitWidth % 16 == 0).
7980
7981 ::
7982
7983       declare i16 @llvm.bswap.i16(i16 <id>)
7984       declare i32 @llvm.bswap.i32(i32 <id>)
7985       declare i64 @llvm.bswap.i64(i64 <id>)
7986
7987 Overview:
7988 """""""""
7989
7990 The '``llvm.bswap``' family of intrinsics is used to byte swap integer
7991 values with an even number of bytes (positive multiple of 16 bits).
7992 These are useful for performing operations on data that is not in the
7993 target's native byte order.
7994
7995 Semantics:
7996 """"""""""
7997
7998 The ``llvm.bswap.i16`` intrinsic returns an i16 value that has the high
7999 and low byte of the input i16 swapped. Similarly, the ``llvm.bswap.i32``
8000 intrinsic returns an i32 value that has the four bytes of the input i32
8001 swapped, so that if the input bytes are numbered 0, 1, 2, 3 then the
8002 returned i32 will have its bytes in 3, 2, 1, 0 order. The
8003 ``llvm.bswap.i48``, ``llvm.bswap.i64`` and other intrinsics extend this
8004 concept to additional even-byte lengths (6 bytes, 8 bytes and more,
8005 respectively).
8006
8007 '``llvm.ctpop.*``' Intrinsic
8008 ^^^^^^^^^^^^^^^^^^^^^^^^^^^^
8009
8010 Syntax:
8011 """""""
8012
8013 This is an overloaded intrinsic. You can use llvm.ctpop on any integer
8014 bit width, or on any vector with integer elements. Not all targets
8015 support all bit widths or vector types, however.
8016
8017 ::
8018
8019       declare i8 @llvm.ctpop.i8(i8  <src>)
8020       declare i16 @llvm.ctpop.i16(i16 <src>)
8021       declare i32 @llvm.ctpop.i32(i32 <src>)
8022       declare i64 @llvm.ctpop.i64(i64 <src>)
8023       declare i256 @llvm.ctpop.i256(i256 <src>)
8024       declare <2 x i32> @llvm.ctpop.v2i32(<2 x i32> <src>)
8025
8026 Overview:
8027 """""""""
8028
8029 The '``llvm.ctpop``' family of intrinsics counts the number of bits set
8030 in a value.
8031
8032 Arguments:
8033 """"""""""
8034
8035 The only argument is the value to be counted. The argument may be of any
8036 integer type, or a vector with integer elements. The return type must
8037 match the argument type.
8038
8039 Semantics:
8040 """"""""""
8041
8042 The '``llvm.ctpop``' intrinsic counts the 1's in a variable, or within
8043 each element of a vector.
8044
8045 '``llvm.ctlz.*``' Intrinsic
8046 ^^^^^^^^^^^^^^^^^^^^^^^^^^^
8047
8048 Syntax:
8049 """""""
8050
8051 This is an overloaded intrinsic. You can use ``llvm.ctlz`` on any
8052 integer bit width, or any vector whose elements are integers. Not all
8053 targets support all bit widths or vector types, however.
8054
8055 ::
8056
8057       declare i8   @llvm.ctlz.i8  (i8   <src>, i1 <is_zero_undef>)
8058       declare i16  @llvm.ctlz.i16 (i16  <src>, i1 <is_zero_undef>)
8059       declare i32  @llvm.ctlz.i32 (i32  <src>, i1 <is_zero_undef>)
8060       declare i64  @llvm.ctlz.i64 (i64  <src>, i1 <is_zero_undef>)
8061       declare i256 @llvm.ctlz.i256(i256 <src>, i1 <is_zero_undef>)
8062       declase <2 x i32> @llvm.ctlz.v2i32(<2 x i32> <src>, i1 <is_zero_undef>)
8063
8064 Overview:
8065 """""""""
8066
8067 The '``llvm.ctlz``' family of intrinsic functions counts the number of
8068 leading zeros in a variable.
8069
8070 Arguments:
8071 """"""""""
8072
8073 The first argument is the value to be counted. This argument may be of
8074 any integer type, or a vectory with integer element type. The return
8075 type must match the first argument type.
8076
8077 The second argument must be a constant and is a flag to indicate whether
8078 the intrinsic should ensure that a zero as the first argument produces a
8079 defined result. Historically some architectures did not provide a
8080 defined result for zero values as efficiently, and many algorithms are
8081 now predicated on avoiding zero-value inputs.
8082
8083 Semantics:
8084 """"""""""
8085
8086 The '``llvm.ctlz``' intrinsic counts the leading (most significant)
8087 zeros in a variable, or within each element of the vector. If
8088 ``src == 0`` then the result is the size in bits of the type of ``src``
8089 if ``is_zero_undef == 0`` and ``undef`` otherwise. For example,
8090 ``llvm.ctlz(i32 2) = 30``.
8091
8092 '``llvm.cttz.*``' Intrinsic
8093 ^^^^^^^^^^^^^^^^^^^^^^^^^^^
8094
8095 Syntax:
8096 """""""
8097
8098 This is an overloaded intrinsic. You can use ``llvm.cttz`` on any
8099 integer bit width, or any vector of integer elements. Not all targets
8100 support all bit widths or vector types, however.
8101
8102 ::
8103
8104       declare i8   @llvm.cttz.i8  (i8   <src>, i1 <is_zero_undef>)
8105       declare i16  @llvm.cttz.i16 (i16  <src>, i1 <is_zero_undef>)
8106       declare i32  @llvm.cttz.i32 (i32  <src>, i1 <is_zero_undef>)
8107       declare i64  @llvm.cttz.i64 (i64  <src>, i1 <is_zero_undef>)
8108       declare i256 @llvm.cttz.i256(i256 <src>, i1 <is_zero_undef>)
8109       declase <2 x i32> @llvm.cttz.v2i32(<2 x i32> <src>, i1 <is_zero_undef>)
8110
8111 Overview:
8112 """""""""
8113
8114 The '``llvm.cttz``' family of intrinsic functions counts the number of
8115 trailing zeros.
8116
8117 Arguments:
8118 """"""""""
8119
8120 The first argument is the value to be counted. This argument may be of
8121 any integer type, or a vectory with integer element type. The return
8122 type must match the first argument type.
8123
8124 The second argument must be a constant and is a flag to indicate whether
8125 the intrinsic should ensure that a zero as the first argument produces a
8126 defined result. Historically some architectures did not provide a
8127 defined result for zero values as efficiently, and many algorithms are
8128 now predicated on avoiding zero-value inputs.
8129
8130 Semantics:
8131 """"""""""
8132
8133 The '``llvm.cttz``' intrinsic counts the trailing (least significant)
8134 zeros in a variable, or within each element of a vector. If ``src == 0``
8135 then the result is the size in bits of the type of ``src`` if
8136 ``is_zero_undef == 0`` and ``undef`` otherwise. For example,
8137 ``llvm.cttz(2) = 1``.
8138
8139 Arithmetic with Overflow Intrinsics
8140 -----------------------------------
8141
8142 LLVM provides intrinsics for some arithmetic with overflow operations.
8143
8144 '``llvm.sadd.with.overflow.*``' Intrinsics
8145 ^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^
8146
8147 Syntax:
8148 """""""
8149
8150 This is an overloaded intrinsic. You can use ``llvm.sadd.with.overflow``
8151 on any integer bit width.
8152
8153 ::
8154
8155       declare {i16, i1} @llvm.sadd.with.overflow.i16(i16 %a, i16 %b)
8156       declare {i32, i1} @llvm.sadd.with.overflow.i32(i32 %a, i32 %b)
8157       declare {i64, i1} @llvm.sadd.with.overflow.i64(i64 %a, i64 %b)
8158
8159 Overview:
8160 """""""""
8161
8162 The '``llvm.sadd.with.overflow``' family of intrinsic functions perform
8163 a signed addition of the two arguments, and indicate whether an overflow
8164 occurred during the signed summation.
8165
8166 Arguments:
8167 """"""""""
8168
8169 The arguments (%a and %b) and the first element of the result structure
8170 may be of integer types of any bit width, but they must have the same
8171 bit width. The second element of the result structure must be of type
8172 ``i1``. ``%a`` and ``%b`` are the two values that will undergo signed
8173 addition.
8174
8175 Semantics:
8176 """"""""""
8177
8178 The '``llvm.sadd.with.overflow``' family of intrinsic functions perform
8179 a signed addition of the two variables. They return a structure --- the
8180 first element of which is the signed summation, and the second element
8181 of which is a bit specifying if the signed summation resulted in an
8182 overflow.
8183
8184 Examples:
8185 """""""""
8186
8187 .. code-block:: llvm
8188
8189       %res = call {i32, i1} @llvm.sadd.with.overflow.i32(i32 %a, i32 %b)
8190       %sum = extractvalue {i32, i1} %res, 0
8191       %obit = extractvalue {i32, i1} %res, 1
8192       br i1 %obit, label %overflow, label %normal
8193
8194 '``llvm.uadd.with.overflow.*``' Intrinsics
8195 ^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^
8196
8197 Syntax:
8198 """""""
8199
8200 This is an overloaded intrinsic. You can use ``llvm.uadd.with.overflow``
8201 on any integer bit width.
8202
8203 ::
8204
8205       declare {i16, i1} @llvm.uadd.with.overflow.i16(i16 %a, i16 %b)
8206       declare {i32, i1} @llvm.uadd.with.overflow.i32(i32 %a, i32 %b)
8207       declare {i64, i1} @llvm.uadd.with.overflow.i64(i64 %a, i64 %b)
8208
8209 Overview:
8210 """""""""
8211
8212 The '``llvm.uadd.with.overflow``' family of intrinsic functions perform
8213 an unsigned addition of the two arguments, and indicate whether a carry
8214 occurred during the unsigned summation.
8215
8216 Arguments:
8217 """"""""""
8218
8219 The arguments (%a and %b) and the first element of the result structure
8220 may be of integer types of any bit width, but they must have the same
8221 bit width. The second element of the result structure must be of type
8222 ``i1``. ``%a`` and ``%b`` are the two values that will undergo unsigned
8223 addition.
8224
8225 Semantics:
8226 """"""""""
8227
8228 The '``llvm.uadd.with.overflow``' family of intrinsic functions perform
8229 an unsigned addition of the two arguments. They return a structure --- the
8230 first element of which is the sum, and the second element of which is a
8231 bit specifying if the unsigned summation resulted in a carry.
8232
8233 Examples:
8234 """""""""
8235
8236 .. code-block:: llvm
8237
8238       %res = call {i32, i1} @llvm.uadd.with.overflow.i32(i32 %a, i32 %b)
8239       %sum = extractvalue {i32, i1} %res, 0
8240       %obit = extractvalue {i32, i1} %res, 1
8241       br i1 %obit, label %carry, label %normal
8242
8243 '``llvm.ssub.with.overflow.*``' Intrinsics
8244 ^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^
8245
8246 Syntax:
8247 """""""
8248
8249 This is an overloaded intrinsic. You can use ``llvm.ssub.with.overflow``
8250 on any integer bit width.
8251
8252 ::
8253
8254       declare {i16, i1} @llvm.ssub.with.overflow.i16(i16 %a, i16 %b)
8255       declare {i32, i1} @llvm.ssub.with.overflow.i32(i32 %a, i32 %b)
8256       declare {i64, i1} @llvm.ssub.with.overflow.i64(i64 %a, i64 %b)
8257
8258 Overview:
8259 """""""""
8260
8261 The '``llvm.ssub.with.overflow``' family of intrinsic functions perform
8262 a signed subtraction of the two arguments, and indicate whether an
8263 overflow occurred during the signed subtraction.
8264
8265 Arguments:
8266 """"""""""
8267
8268 The arguments (%a and %b) and the first element of the result structure
8269 may be of integer types of any bit width, but they must have the same
8270 bit width. The second element of the result structure must be of type
8271 ``i1``. ``%a`` and ``%b`` are the two values that will undergo signed
8272 subtraction.
8273
8274 Semantics:
8275 """"""""""
8276
8277 The '``llvm.ssub.with.overflow``' family of intrinsic functions perform
8278 a signed subtraction of the two arguments. They return a structure --- the
8279 first element of which is the subtraction, and the second element of
8280 which is a bit specifying if the signed subtraction resulted in an
8281 overflow.
8282
8283 Examples:
8284 """""""""
8285
8286 .. code-block:: llvm
8287
8288       %res = call {i32, i1} @llvm.ssub.with.overflow.i32(i32 %a, i32 %b)
8289       %sum = extractvalue {i32, i1} %res, 0
8290       %obit = extractvalue {i32, i1} %res, 1
8291       br i1 %obit, label %overflow, label %normal
8292
8293 '``llvm.usub.with.overflow.*``' Intrinsics
8294 ^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^
8295
8296 Syntax:
8297 """""""
8298
8299 This is an overloaded intrinsic. You can use ``llvm.usub.with.overflow``
8300 on any integer bit width.
8301
8302 ::
8303
8304       declare {i16, i1} @llvm.usub.with.overflow.i16(i16 %a, i16 %b)
8305       declare {i32, i1} @llvm.usub.with.overflow.i32(i32 %a, i32 %b)
8306       declare {i64, i1} @llvm.usub.with.overflow.i64(i64 %a, i64 %b)
8307
8308 Overview:
8309 """""""""
8310
8311 The '``llvm.usub.with.overflow``' family of intrinsic functions perform
8312 an unsigned subtraction of the two arguments, and indicate whether an
8313 overflow occurred during the unsigned subtraction.
8314
8315 Arguments:
8316 """"""""""
8317
8318 The arguments (%a and %b) and the first element of the result structure
8319 may be of integer types of any bit width, but they must have the same
8320 bit width. The second element of the result structure must be of type
8321 ``i1``. ``%a`` and ``%b`` are the two values that will undergo unsigned
8322 subtraction.
8323
8324 Semantics:
8325 """"""""""
8326
8327 The '``llvm.usub.with.overflow``' family of intrinsic functions perform
8328 an unsigned subtraction of the two arguments. They return a structure ---
8329 the first element of which is the subtraction, and the second element of
8330 which is a bit specifying if the unsigned subtraction resulted in an
8331 overflow.
8332
8333 Examples:
8334 """""""""
8335
8336 .. code-block:: llvm
8337
8338       %res = call {i32, i1} @llvm.usub.with.overflow.i32(i32 %a, i32 %b)
8339       %sum = extractvalue {i32, i1} %res, 0
8340       %obit = extractvalue {i32, i1} %res, 1
8341       br i1 %obit, label %overflow, label %normal
8342
8343 '``llvm.smul.with.overflow.*``' Intrinsics
8344 ^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^
8345
8346 Syntax:
8347 """""""
8348
8349 This is an overloaded intrinsic. You can use ``llvm.smul.with.overflow``
8350 on any integer bit width.
8351
8352 ::
8353
8354       declare {i16, i1} @llvm.smul.with.overflow.i16(i16 %a, i16 %b)
8355       declare {i32, i1} @llvm.smul.with.overflow.i32(i32 %a, i32 %b)
8356       declare {i64, i1} @llvm.smul.with.overflow.i64(i64 %a, i64 %b)
8357
8358 Overview:
8359 """""""""
8360
8361 The '``llvm.smul.with.overflow``' family of intrinsic functions perform
8362 a signed multiplication of the two arguments, and indicate whether an
8363 overflow occurred during the signed multiplication.
8364
8365 Arguments:
8366 """"""""""
8367
8368 The arguments (%a and %b) and the first element of the result structure
8369 may be of integer types of any bit width, but they must have the same
8370 bit width. The second element of the result structure must be of type
8371 ``i1``. ``%a`` and ``%b`` are the two values that will undergo signed
8372 multiplication.
8373
8374 Semantics:
8375 """"""""""
8376
8377 The '``llvm.smul.with.overflow``' family of intrinsic functions perform
8378 a signed multiplication of the two arguments. They return a structure ---
8379 the first element of which is the multiplication, and the second element
8380 of which is a bit specifying if the signed multiplication resulted in an
8381 overflow.
8382
8383 Examples:
8384 """""""""
8385
8386 .. code-block:: llvm
8387
8388       %res = call {i32, i1} @llvm.smul.with.overflow.i32(i32 %a, i32 %b)
8389       %sum = extractvalue {i32, i1} %res, 0
8390       %obit = extractvalue {i32, i1} %res, 1
8391       br i1 %obit, label %overflow, label %normal
8392
8393 '``llvm.umul.with.overflow.*``' Intrinsics
8394 ^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^
8395
8396 Syntax:
8397 """""""
8398
8399 This is an overloaded intrinsic. You can use ``llvm.umul.with.overflow``
8400 on any integer bit width.
8401
8402 ::
8403
8404       declare {i16, i1} @llvm.umul.with.overflow.i16(i16 %a, i16 %b)
8405       declare {i32, i1} @llvm.umul.with.overflow.i32(i32 %a, i32 %b)
8406       declare {i64, i1} @llvm.umul.with.overflow.i64(i64 %a, i64 %b)
8407
8408 Overview:
8409 """""""""
8410
8411 The '``llvm.umul.with.overflow``' family of intrinsic functions perform
8412 a unsigned multiplication of the two arguments, and indicate whether an
8413 overflow occurred during the unsigned multiplication.
8414
8415 Arguments:
8416 """"""""""
8417
8418 The arguments (%a and %b) and the first element of the result structure
8419 may be of integer types of any bit width, but they must have the same
8420 bit width. The second element of the result structure must be of type
8421 ``i1``. ``%a`` and ``%b`` are the two values that will undergo unsigned
8422 multiplication.
8423
8424 Semantics:
8425 """"""""""
8426
8427 The '``llvm.umul.with.overflow``' family of intrinsic functions perform
8428 an unsigned multiplication of the two arguments. They return a structure ---
8429 the first element of which is the multiplication, and the second
8430 element of which is a bit specifying if the unsigned multiplication
8431 resulted in an overflow.
8432
8433 Examples:
8434 """""""""
8435
8436 .. code-block:: llvm
8437
8438       %res = call {i32, i1} @llvm.umul.with.overflow.i32(i32 %a, i32 %b)
8439       %sum = extractvalue {i32, i1} %res, 0
8440       %obit = extractvalue {i32, i1} %res, 1
8441       br i1 %obit, label %overflow, label %normal
8442
8443 Specialised Arithmetic Intrinsics
8444 ---------------------------------
8445
8446 '``llvm.fmuladd.*``' Intrinsic
8447 ^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^
8448
8449 Syntax:
8450 """""""
8451
8452 ::
8453
8454       declare float @llvm.fmuladd.f32(float %a, float %b, float %c)
8455       declare double @llvm.fmuladd.f64(double %a, double %b, double %c)
8456
8457 Overview:
8458 """""""""
8459
8460 The '``llvm.fmuladd.*``' intrinsic functions represent multiply-add
8461 expressions that can be fused if the code generator determines that (a) the
8462 target instruction set has support for a fused operation, and (b) that the
8463 fused operation is more efficient than the equivalent, separate pair of mul
8464 and add instructions.
8465
8466 Arguments:
8467 """"""""""
8468
8469 The '``llvm.fmuladd.*``' intrinsics each take three arguments: two
8470 multiplicands, a and b, and an addend c.
8471
8472 Semantics:
8473 """"""""""
8474
8475 The expression:
8476
8477 ::
8478
8479       %0 = call float @llvm.fmuladd.f32(%a, %b, %c)
8480
8481 is equivalent to the expression a \* b + c, except that rounding will
8482 not be performed between the multiplication and addition steps if the
8483 code generator fuses the operations. Fusion is not guaranteed, even if
8484 the target platform supports it. If a fused multiply-add is required the
8485 corresponding llvm.fma.\* intrinsic function should be used
8486 instead. This never sets errno, just as '``llvm.fma.*``'.
8487
8488 Examples:
8489 """""""""
8490
8491 .. code-block:: llvm
8492
8493       %r2 = call float @llvm.fmuladd.f32(float %a, float %b, float %c) ; yields {float}:r2 = (a * b) + c
8494
8495 Half Precision Floating Point Intrinsics
8496 ----------------------------------------
8497
8498 For most target platforms, half precision floating point is a
8499 storage-only format. This means that it is a dense encoding (in memory)
8500 but does not support computation in the format.
8501
8502 This means that code must first load the half-precision floating point
8503 value as an i16, then convert it to float with
8504 :ref:`llvm.convert.from.fp16 <int_convert_from_fp16>`. Computation can
8505 then be performed on the float value (including extending to double
8506 etc). To store the value back to memory, it is first converted to float
8507 if needed, then converted to i16 with
8508 :ref:`llvm.convert.to.fp16 <int_convert_to_fp16>`, then storing as an
8509 i16 value.
8510
8511 .. _int_convert_to_fp16:
8512
8513 '``llvm.convert.to.fp16``' Intrinsic
8514 ^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^
8515
8516 Syntax:
8517 """""""
8518
8519 ::
8520
8521       declare i16 @llvm.convert.to.fp16(f32 %a)
8522
8523 Overview:
8524 """""""""
8525
8526 The '``llvm.convert.to.fp16``' intrinsic function performs a conversion
8527 from single precision floating point format to half precision floating
8528 point format.
8529
8530 Arguments:
8531 """"""""""
8532
8533 The intrinsic function contains single argument - the value to be
8534 converted.
8535
8536 Semantics:
8537 """"""""""
8538
8539 The '``llvm.convert.to.fp16``' intrinsic function performs a conversion
8540 from single precision floating point format to half precision floating
8541 point format. The return value is an ``i16`` which contains the
8542 converted number.
8543
8544 Examples:
8545 """""""""
8546
8547 .. code-block:: llvm
8548
8549       %res = call i16 @llvm.convert.to.fp16(f32 %a)
8550       store i16 %res, i16* @x, align 2
8551
8552 .. _int_convert_from_fp16:
8553
8554 '``llvm.convert.from.fp16``' Intrinsic
8555 ^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^
8556
8557 Syntax:
8558 """""""
8559
8560 ::
8561
8562       declare f32 @llvm.convert.from.fp16(i16 %a)
8563
8564 Overview:
8565 """""""""
8566
8567 The '``llvm.convert.from.fp16``' intrinsic function performs a
8568 conversion from half precision floating point format to single precision
8569 floating point format.
8570
8571 Arguments:
8572 """"""""""
8573
8574 The intrinsic function contains single argument - the value to be
8575 converted.
8576
8577 Semantics:
8578 """"""""""
8579
8580 The '``llvm.convert.from.fp16``' intrinsic function performs a
8581 conversion from half single precision floating point format to single
8582 precision floating point format. The input half-float value is
8583 represented by an ``i16`` value.
8584
8585 Examples:
8586 """""""""
8587
8588 .. code-block:: llvm
8589
8590       %a = load i16* @x, align 2
8591       %res = call f32 @llvm.convert.from.fp16(i16 %a)
8592
8593 Debugger Intrinsics
8594 -------------------
8595
8596 The LLVM debugger intrinsics (which all start with ``llvm.dbg.``
8597 prefix), are described in the `LLVM Source Level
8598 Debugging <SourceLevelDebugging.html#format_common_intrinsics>`_
8599 document.
8600
8601 Exception Handling Intrinsics
8602 -----------------------------
8603
8604 The LLVM exception handling intrinsics (which all start with
8605 ``llvm.eh.`` prefix), are described in the `LLVM Exception
8606 Handling <ExceptionHandling.html#format_common_intrinsics>`_ document.
8607
8608 .. _int_trampoline:
8609
8610 Trampoline Intrinsics
8611 ---------------------
8612
8613 These intrinsics make it possible to excise one parameter, marked with
8614 the :ref:`nest <nest>` attribute, from a function. The result is a
8615 callable function pointer lacking the nest parameter - the caller does
8616 not need to provide a value for it. Instead, the value to use is stored
8617 in advance in a "trampoline", a block of memory usually allocated on the
8618 stack, which also contains code to splice the nest value into the
8619 argument list. This is used to implement the GCC nested function address
8620 extension.
8621
8622 For example, if the function is ``i32 f(i8* nest %c, i32 %x, i32 %y)``
8623 then the resulting function pointer has signature ``i32 (i32, i32)*``.
8624 It can be created as follows:
8625
8626 .. code-block:: llvm
8627
8628       %tramp = alloca [10 x i8], align 4 ; size and alignment only correct for X86
8629       %tramp1 = getelementptr [10 x i8]* %tramp, i32 0, i32 0
8630       call i8* @llvm.init.trampoline(i8* %tramp1, i8* bitcast (i32 (i8*, i32, i32)* @f to i8*), i8* %nval)
8631       %p = call i8* @llvm.adjust.trampoline(i8* %tramp1)
8632       %fp = bitcast i8* %p to i32 (i32, i32)*
8633
8634 The call ``%val = call i32 %fp(i32 %x, i32 %y)`` is then equivalent to
8635 ``%val = call i32 %f(i8* %nval, i32 %x, i32 %y)``.
8636
8637 .. _int_it:
8638
8639 '``llvm.init.trampoline``' Intrinsic
8640 ^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^
8641
8642 Syntax:
8643 """""""
8644
8645 ::
8646
8647       declare void @llvm.init.trampoline(i8* <tramp>, i8* <func>, i8* <nval>)
8648
8649 Overview:
8650 """""""""
8651
8652 This fills the memory pointed to by ``tramp`` with executable code,
8653 turning it into a trampoline.
8654
8655 Arguments:
8656 """"""""""
8657
8658 The ``llvm.init.trampoline`` intrinsic takes three arguments, all
8659 pointers. The ``tramp`` argument must point to a sufficiently large and
8660 sufficiently aligned block of memory; this memory is written to by the
8661 intrinsic. Note that the size and the alignment are target-specific -
8662 LLVM currently provides no portable way of determining them, so a
8663 front-end that generates this intrinsic needs to have some
8664 target-specific knowledge. The ``func`` argument must hold a function
8665 bitcast to an ``i8*``.
8666
8667 Semantics:
8668 """"""""""
8669
8670 The block of memory pointed to by ``tramp`` is filled with target
8671 dependent code, turning it into a function. Then ``tramp`` needs to be
8672 passed to :ref:`llvm.adjust.trampoline <int_at>` to get a pointer which can
8673 be :ref:`bitcast (to a new function) and called <int_trampoline>`. The new
8674 function's signature is the same as that of ``func`` with any arguments
8675 marked with the ``nest`` attribute removed. At most one such ``nest``
8676 argument is allowed, and it must be of pointer type. Calling the new
8677 function is equivalent to calling ``func`` with the same argument list,
8678 but with ``nval`` used for the missing ``nest`` argument. If, after
8679 calling ``llvm.init.trampoline``, the memory pointed to by ``tramp`` is
8680 modified, then the effect of any later call to the returned function
8681 pointer is undefined.
8682
8683 .. _int_at:
8684
8685 '``llvm.adjust.trampoline``' Intrinsic
8686 ^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^
8687
8688 Syntax:
8689 """""""
8690
8691 ::
8692
8693       declare i8* @llvm.adjust.trampoline(i8* <tramp>)
8694
8695 Overview:
8696 """""""""
8697
8698 This performs any required machine-specific adjustment to the address of
8699 a trampoline (passed as ``tramp``).
8700
8701 Arguments:
8702 """"""""""
8703
8704 ``tramp`` must point to a block of memory which already has trampoline
8705 code filled in by a previous call to
8706 :ref:`llvm.init.trampoline <int_it>`.
8707
8708 Semantics:
8709 """"""""""
8710
8711 On some architectures the address of the code to be executed needs to be
8712 different to the address where the trampoline is actually stored. This
8713 intrinsic returns the executable address corresponding to ``tramp``
8714 after performing the required machine specific adjustments. The pointer
8715 returned can then be :ref:`bitcast and executed <int_trampoline>`.
8716
8717 Memory Use Markers
8718 ------------------
8719
8720 This class of intrinsics exists to information about the lifetime of
8721 memory objects and ranges where variables are immutable.
8722
8723 .. _int_lifestart:
8724
8725 '``llvm.lifetime.start``' Intrinsic
8726 ^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^
8727
8728 Syntax:
8729 """""""
8730
8731 ::
8732
8733       declare void @llvm.lifetime.start(i64 <size>, i8* nocapture <ptr>)
8734
8735 Overview:
8736 """""""""
8737
8738 The '``llvm.lifetime.start``' intrinsic specifies the start of a memory
8739 object's lifetime.
8740
8741 Arguments:
8742 """"""""""
8743
8744 The first argument is a constant integer representing the size of the
8745 object, or -1 if it is variable sized. The second argument is a pointer
8746 to the object.
8747
8748 Semantics:
8749 """"""""""
8750
8751 This intrinsic indicates that before this point in the code, the value
8752 of the memory pointed to by ``ptr`` is dead. This means that it is known
8753 to never be used and has an undefined value. A load from the pointer
8754 that precedes this intrinsic can be replaced with ``'undef'``.
8755
8756 .. _int_lifeend:
8757
8758 '``llvm.lifetime.end``' Intrinsic
8759 ^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^
8760
8761 Syntax:
8762 """""""
8763
8764 ::
8765
8766       declare void @llvm.lifetime.end(i64 <size>, i8* nocapture <ptr>)
8767
8768 Overview:
8769 """""""""
8770
8771 The '``llvm.lifetime.end``' intrinsic specifies the end of a memory
8772 object's lifetime.
8773
8774 Arguments:
8775 """"""""""
8776
8777 The first argument is a constant integer representing the size of the
8778 object, or -1 if it is variable sized. The second argument is a pointer
8779 to the object.
8780
8781 Semantics:
8782 """"""""""
8783
8784 This intrinsic indicates that after this point in the code, the value of
8785 the memory pointed to by ``ptr`` is dead. This means that it is known to
8786 never be used and has an undefined value. Any stores into the memory
8787 object following this intrinsic may be removed as dead.
8788
8789 '``llvm.invariant.start``' Intrinsic
8790 ^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^
8791
8792 Syntax:
8793 """""""
8794
8795 ::
8796
8797       declare {}* @llvm.invariant.start(i64 <size>, i8* nocapture <ptr>)
8798
8799 Overview:
8800 """""""""
8801
8802 The '``llvm.invariant.start``' intrinsic specifies that the contents of
8803 a memory object will not change.
8804
8805 Arguments:
8806 """"""""""
8807
8808 The first argument is a constant integer representing the size of the
8809 object, or -1 if it is variable sized. The second argument is a pointer
8810 to the object.
8811
8812 Semantics:
8813 """"""""""
8814
8815 This intrinsic indicates that until an ``llvm.invariant.end`` that uses
8816 the return value, the referenced memory location is constant and
8817 unchanging.
8818
8819 '``llvm.invariant.end``' Intrinsic
8820 ^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^
8821
8822 Syntax:
8823 """""""
8824
8825 ::
8826
8827       declare void @llvm.invariant.end({}* <start>, i64 <size>, i8* nocapture <ptr>)
8828
8829 Overview:
8830 """""""""
8831
8832 The '``llvm.invariant.end``' intrinsic specifies that the contents of a
8833 memory object are mutable.
8834
8835 Arguments:
8836 """"""""""
8837
8838 The first argument is the matching ``llvm.invariant.start`` intrinsic.
8839 The second argument is a constant integer representing the size of the
8840 object, or -1 if it is variable sized and the third argument is a
8841 pointer to the object.
8842
8843 Semantics:
8844 """"""""""
8845
8846 This intrinsic indicates that the memory is mutable again.
8847
8848 General Intrinsics
8849 ------------------
8850
8851 This class of intrinsics is designed to be generic and has no specific
8852 purpose.
8853
8854 '``llvm.var.annotation``' Intrinsic
8855 ^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^
8856
8857 Syntax:
8858 """""""
8859
8860 ::
8861
8862       declare void @llvm.var.annotation(i8* <val>, i8* <str>, i8* <str>, i32  <int>)
8863
8864 Overview:
8865 """""""""
8866
8867 The '``llvm.var.annotation``' intrinsic.
8868
8869 Arguments:
8870 """"""""""
8871
8872 The first argument is a pointer to a value, the second is a pointer to a
8873 global string, the third is a pointer to a global string which is the
8874 source file name, and the last argument is the line number.
8875
8876 Semantics:
8877 """"""""""
8878
8879 This intrinsic allows annotation of local variables with arbitrary
8880 strings. This can be useful for special purpose optimizations that want
8881 to look for these annotations. These have no other defined use; they are
8882 ignored by code generation and optimization.
8883
8884 '``llvm.ptr.annotation.*``' Intrinsic
8885 ^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^
8886
8887 Syntax:
8888 """""""
8889
8890 This is an overloaded intrinsic. You can use '``llvm.ptr.annotation``' on a
8891 pointer to an integer of any width. *NOTE* you must specify an address space for
8892 the pointer. The identifier for the default address space is the integer
8893 '``0``'.
8894
8895 ::
8896
8897       declare i8*   @llvm.ptr.annotation.p<address space>i8(i8* <val>, i8* <str>, i8* <str>, i32  <int>)
8898       declare i16*  @llvm.ptr.annotation.p<address space>i16(i16* <val>, i8* <str>, i8* <str>, i32  <int>)
8899       declare i32*  @llvm.ptr.annotation.p<address space>i32(i32* <val>, i8* <str>, i8* <str>, i32  <int>)
8900       declare i64*  @llvm.ptr.annotation.p<address space>i64(i64* <val>, i8* <str>, i8* <str>, i32  <int>)
8901       declare i256* @llvm.ptr.annotation.p<address space>i256(i256* <val>, i8* <str>, i8* <str>, i32  <int>)
8902
8903 Overview:
8904 """""""""
8905
8906 The '``llvm.ptr.annotation``' intrinsic.
8907
8908 Arguments:
8909 """"""""""
8910
8911 The first argument is a pointer to an integer value of arbitrary bitwidth
8912 (result of some expression), the second is a pointer to a global string, the
8913 third is a pointer to a global string which is the source file name, and the
8914 last argument is the line number. It returns the value of the first argument.
8915
8916 Semantics:
8917 """"""""""
8918
8919 This intrinsic allows annotation of a pointer to an integer with arbitrary
8920 strings. This can be useful for special purpose optimizations that want to look
8921 for these annotations. These have no other defined use; they are ignored by code
8922 generation and optimization.
8923
8924 '``llvm.annotation.*``' Intrinsic
8925 ^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^
8926
8927 Syntax:
8928 """""""
8929
8930 This is an overloaded intrinsic. You can use '``llvm.annotation``' on
8931 any integer bit width.
8932
8933 ::
8934
8935       declare i8 @llvm.annotation.i8(i8 <val>, i8* <str>, i8* <str>, i32  <int>)
8936       declare i16 @llvm.annotation.i16(i16 <val>, i8* <str>, i8* <str>, i32  <int>)
8937       declare i32 @llvm.annotation.i32(i32 <val>, i8* <str>, i8* <str>, i32  <int>)
8938       declare i64 @llvm.annotation.i64(i64 <val>, i8* <str>, i8* <str>, i32  <int>)
8939       declare i256 @llvm.annotation.i256(i256 <val>, i8* <str>, i8* <str>, i32  <int>)
8940
8941 Overview:
8942 """""""""
8943
8944 The '``llvm.annotation``' intrinsic.
8945
8946 Arguments:
8947 """"""""""
8948
8949 The first argument is an integer value (result of some expression), the
8950 second is a pointer to a global string, the third is a pointer to a
8951 global string which is the source file name, and the last argument is
8952 the line number. It returns the value of the first argument.
8953
8954 Semantics:
8955 """"""""""
8956
8957 This intrinsic allows annotations to be put on arbitrary expressions
8958 with arbitrary strings. This can be useful for special purpose
8959 optimizations that want to look for these annotations. These have no
8960 other defined use; they are ignored by code generation and optimization.
8961
8962 '``llvm.trap``' Intrinsic
8963 ^^^^^^^^^^^^^^^^^^^^^^^^^
8964
8965 Syntax:
8966 """""""
8967
8968 ::
8969
8970       declare void @llvm.trap() noreturn nounwind
8971
8972 Overview:
8973 """""""""
8974
8975 The '``llvm.trap``' intrinsic.
8976
8977 Arguments:
8978 """"""""""
8979
8980 None.
8981
8982 Semantics:
8983 """"""""""
8984
8985 This intrinsic is lowered to the target dependent trap instruction. If
8986 the target does not have a trap instruction, this intrinsic will be
8987 lowered to a call of the ``abort()`` function.
8988
8989 '``llvm.debugtrap``' Intrinsic
8990 ^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^
8991
8992 Syntax:
8993 """""""
8994
8995 ::
8996
8997       declare void @llvm.debugtrap() nounwind
8998
8999 Overview:
9000 """""""""
9001
9002 The '``llvm.debugtrap``' intrinsic.
9003
9004 Arguments:
9005 """"""""""
9006
9007 None.
9008
9009 Semantics:
9010 """"""""""
9011
9012 This intrinsic is lowered to code which is intended to cause an
9013 execution trap with the intention of requesting the attention of a
9014 debugger.
9015
9016 '``llvm.stackprotector``' Intrinsic
9017 ^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^
9018
9019 Syntax:
9020 """""""
9021
9022 ::
9023
9024       declare void @llvm.stackprotector(i8* <guard>, i8** <slot>)
9025
9026 Overview:
9027 """""""""
9028
9029 The ``llvm.stackprotector`` intrinsic takes the ``guard`` and stores it
9030 onto the stack at ``slot``. The stack slot is adjusted to ensure that it
9031 is placed on the stack before local variables.
9032
9033 Arguments:
9034 """"""""""
9035
9036 The ``llvm.stackprotector`` intrinsic requires two pointer arguments.
9037 The first argument is the value loaded from the stack guard
9038 ``@__stack_chk_guard``. The second variable is an ``alloca`` that has
9039 enough space to hold the value of the guard.
9040
9041 Semantics:
9042 """"""""""
9043
9044 This intrinsic causes the prologue/epilogue inserter to force the position of
9045 the ``AllocaInst`` stack slot to be before local variables on the stack. This is
9046 to ensure that if a local variable on the stack is overwritten, it will destroy
9047 the value of the guard. When the function exits, the guard on the stack is
9048 checked against the original guard by ``llvm.stackprotectorcheck``. If they are
9049 different, then ``llvm.stackprotectorcheck`` causes the program to abort by
9050 calling the ``__stack_chk_fail()`` function.
9051
9052 '``llvm.stackprotectorcheck``' Intrinsic
9053 ^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^
9054
9055 Syntax:
9056 """""""
9057
9058 ::
9059
9060       declare void @llvm.stackprotectorcheck(i8** <guard>)
9061
9062 Overview:
9063 """""""""
9064
9065 The ``llvm.stackprotectorcheck`` intrinsic compares ``guard`` against an already
9066 created stack protector and if they are not equal calls the
9067 ``__stack_chk_fail()`` function.
9068
9069 Arguments:
9070 """"""""""
9071
9072 The ``llvm.stackprotectorcheck`` intrinsic requires one pointer argument, the
9073 the variable ``@__stack_chk_guard``.
9074
9075 Semantics:
9076 """"""""""
9077
9078 This intrinsic is provided to perform the stack protector check by comparing
9079 ``guard`` with the stack slot created by ``llvm.stackprotector`` and if the
9080 values do not match call the ``__stack_chk_fail()`` function.
9081
9082 The reason to provide this as an IR level intrinsic instead of implementing it
9083 via other IR operations is that in order to perform this operation at the IR
9084 level without an intrinsic, one would need to create additional basic blocks to
9085 handle the success/failure cases. This makes it difficult to stop the stack
9086 protector check from disrupting sibling tail calls in Codegen. With this
9087 intrinsic, we are able to generate the stack protector basic blocks late in
9088 codegen after the tail call decision has occurred.
9089
9090 '``llvm.objectsize``' Intrinsic
9091 ^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^
9092
9093 Syntax:
9094 """""""
9095
9096 ::
9097
9098       declare i32 @llvm.objectsize.i32(i8* <object>, i1 <min>)
9099       declare i64 @llvm.objectsize.i64(i8* <object>, i1 <min>)
9100
9101 Overview:
9102 """""""""
9103
9104 The ``llvm.objectsize`` intrinsic is designed to provide information to
9105 the optimizers to determine at compile time whether a) an operation
9106 (like memcpy) will overflow a buffer that corresponds to an object, or
9107 b) that a runtime check for overflow isn't necessary. An object in this
9108 context means an allocation of a specific class, structure, array, or
9109 other object.
9110
9111 Arguments:
9112 """"""""""
9113
9114 The ``llvm.objectsize`` intrinsic takes two arguments. The first
9115 argument is a pointer to or into the ``object``. The second argument is
9116 a boolean and determines whether ``llvm.objectsize`` returns 0 (if true)
9117 or -1 (if false) when the object size is unknown. The second argument
9118 only accepts constants.
9119
9120 Semantics:
9121 """"""""""
9122
9123 The ``llvm.objectsize`` intrinsic is lowered to a constant representing
9124 the size of the object concerned. If the size cannot be determined at
9125 compile time, ``llvm.objectsize`` returns ``i32/i64 -1 or 0`` (depending
9126 on the ``min`` argument).
9127
9128 '``llvm.expect``' Intrinsic
9129 ^^^^^^^^^^^^^^^^^^^^^^^^^^^
9130
9131 Syntax:
9132 """""""
9133
9134 This is an overloaded intrinsic. You can use ``llvm.expect`` on any
9135 integer bit width.
9136
9137 ::
9138
9139       declare i1 @llvm.expect.i1(i1 <val>, i1 <expected_val>)
9140       declare i32 @llvm.expect.i32(i32 <val>, i32 <expected_val>)
9141       declare i64 @llvm.expect.i64(i64 <val>, i64 <expected_val>)
9142
9143 Overview:
9144 """""""""
9145
9146 The ``llvm.expect`` intrinsic provides information about expected (the
9147 most probable) value of ``val``, which can be used by optimizers.
9148
9149 Arguments:
9150 """"""""""
9151
9152 The ``llvm.expect`` intrinsic takes two arguments. The first argument is
9153 a value. The second argument is an expected value, this needs to be a
9154 constant value, variables are not allowed.
9155
9156 Semantics:
9157 """"""""""
9158
9159 This intrinsic is lowered to the ``val``.
9160
9161 '``llvm.donothing``' Intrinsic
9162 ^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^
9163
9164 Syntax:
9165 """""""
9166
9167 ::
9168
9169       declare void @llvm.donothing() nounwind readnone
9170
9171 Overview:
9172 """""""""
9173
9174 The ``llvm.donothing`` intrinsic doesn't perform any operation. It's the
9175 only intrinsic that can be called with an invoke instruction.
9176
9177 Arguments:
9178 """"""""""
9179
9180 None.
9181
9182 Semantics:
9183 """"""""""
9184
9185 This intrinsic does nothing, and it's removed by optimizers and ignored
9186 by codegen.
9187
9188 Stack Map Intrinsics
9189 --------------------
9190
9191 LLVM provides experimental intrinsics to support runtime patching
9192 mechanisms commonly desired in dynamic language JITs. These intrinsics
9193 are described in :doc:`StackMaps`.