cmake/modules/TableGen.cmake

   1 # LLVM_TARGET_DEFINITIONS must contain the name of the .td file to process.
   2 # Extra parameters for `tblgen' may come after `ofn' parameter.
   3 # Adds the name of the generated file to TABLEGEN_OUTPUT.
   4
   5 function(tablegen project ofn)
   6   # Validate calling context.
   7   foreach(v
   8       ${project}_TABLEGEN_EXE
   9       LLVM_MAIN_SRC_DIR
  10       LLVM_MAIN_INCLUDE_DIR
  11       )
  12     if(NOT ${v})
  13       message(FATAL_ERROR "${v} not set")
  14     endif()
  15   endforeach()
  16
  17   file(GLOB local_tds "*.td")
  18   file(GLOB_RECURSE global_tds "${LLVM_MAIN_INCLUDE_DIR}/llvm/*.td")
  19
  20   if (IS_ABSOLUTE ${LLVM_TARGET_DEFINITIONS})
  21     set(LLVM_TARGET_DEFINITIONS_ABSOLUTE ${LLVM_TARGET_DEFINITIONS})
  22   else()
  23     set(LLVM_TARGET_DEFINITIONS_ABSOLUTE
  24       ${CMAKE_CURRENT_SOURCE_DIR}/${LLVM_TARGET_DEFINITIONS})
  25   endif()
  26   add_custom_command(OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/${ofn}.tmp
  27     # Generate tablegen output in a temporary file.
  28     COMMAND ${${project}_TABLEGEN_EXE} ${ARGN} -I ${CMAKE_CURRENT_SOURCE_DIR}
  29     -I ${LLVM_MAIN_SRC_DIR}/lib/Target -I ${LLVM_MAIN_INCLUDE_DIR}
  30     ${LLVM_TARGET_DEFINITIONS_ABSOLUTE}
  31     -o ${CMAKE_CURRENT_BINARY_DIR}/${ofn}.tmp
  32     # The file in LLVM_TARGET_DEFINITIONS may be not in the current
  33     # directory and local_tds may not contain it, so we must
  34     # explicitly list it here:
  35     DEPENDS ${${project}_TABLEGEN_EXE} ${local_tds} ${global_tds}
  36     ${LLVM_TARGET_DEFINITIONS_ABSOLUTE}
  37     COMMENT "Building ${ofn}..."
  38     )
  39   add_custom_command(OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/${ofn}
  40     # Only update the real output file if there are any differences.
  41     # This prevents recompilation of all the files depending on it if there
  42     # aren't any.
  43     COMMAND ${CMAKE_COMMAND} -E copy_if_different
  44         ${CMAKE_CURRENT_BINARY_DIR}/${ofn}.tmp
  45         ${CMAKE_CURRENT_BINARY_DIR}/${ofn}
  46     DEPENDS ${CMAKE_CURRENT_BINARY_DIR}/${ofn}.tmp
  47     COMMENT "Updating ${ofn}..."
  48     )
  49
  50   # `make clean' must remove all those generated files:
  51   set_property(DIRECTORY APPEND
  52     PROPERTY ADDITIONAL_MAKE_CLEAN_FILES ${ofn}.tmp ${ofn})
  53
  54   set(TABLEGEN_OUTPUT ${TABLEGEN_OUTPUT} ${CMAKE_CURRENT_BINARY_DIR}/${ofn} PARENT_SCOPE)
  55   set_source_files_properties(${CMAKE_CURRENT_BINARY_DIR}/${ofn} PROPERTIES
  56     GENERATED 1)
  57 endfunction()
  58
  59 # Creates a target for publicly exporting tablegen dependencies.
  60 function(add_public_tablegen_target target)
  61   if(NOT TABLEGEN_OUTPUT)
  62     message(FATAL_ERROR "Requires tablegen() definitions as TABLEGEN_OUTPUT.")
  63   endif()
  64   add_custom_target(${target}
  65     DEPENDS ${TABLEGEN_OUTPUT})
  66   if(LLVM_COMMON_DEPENDS)
  67     add_dependencies(${target} ${LLVM_COMMON_DEPENDS})
  68   endif()
  69   set_target_properties(${target} PROPERTIES FOLDER "Tablegenning")
  70   set(LLVM_COMMON_DEPENDS ${LLVM_COMMON_DEPENDS} ${target} PARENT_SCOPE)
  71 endfunction()
  72
  73 if(CMAKE_CROSSCOMPILING)
  74   set(CX_NATIVE_TG_DIR "${CMAKE_BINARY_DIR}/native")
  75
  76   add_custom_command(OUTPUT ${CX_NATIVE_TG_DIR}
  77     COMMAND ${CMAKE_COMMAND} -E make_directory ${CX_NATIVE_TG_DIR}
  78     COMMENT "Creating ${CX_NATIVE_TG_DIR}...")
  79
  80   # Forward a subset of configure options to discover additional tablegen modules.
  81   get_cmake_property(_variableNames CACHE_VARIABLES)
  82   foreach (_variableName ${_variableNames})
  83     if (_variableName MATCHES "^(LLVM_EXTERNAL_.*_SOURCE_DIR)$")
  84       list(APPEND CX_CMAKE_ARGUMENTS "-D${_variableName}=\"${${_variableName}}\"")
  85     endif ()
  86   endforeach()
  87
  88   add_custom_command(OUTPUT ${CX_NATIVE_TG_DIR}/CMakeCache.txt
  89     # TODO: Clear the old CMakeCache.txt somehow without breaking restat.
  90     COMMAND ${CMAKE_COMMAND} -UMAKE_TOOLCHAIN_FILE -DCMAKE_BUILD_TYPE=Release
  91                              -DLLVM_BUILD_POLLY=OFF ${CX_CMAKE_ARGUMENTS}
  92                              -G "${CMAKE_GENERATOR}" ${CMAKE_SOURCE_DIR}
  93     WORKING_DIRECTORY ${CX_NATIVE_TG_DIR}
  94     DEPENDS ${CX_NATIVE_TG_DIR}
  95     COMMENT "Configuring native TableGen...")
  96
  97   add_custom_target(ConfigureNativeTableGen DEPENDS ${CX_NATIVE_TG_DIR}/CMakeCache.txt)
  98
  99   set_directory_properties(PROPERTIES ADDITIONAL_MAKE_CLEAN_FILES ${CX_NATIVE_TG_DIR})
 100 endif()
 101
 102 macro(add_tablegen target project)
 103   set(${target}_OLD_LLVM_LINK_COMPONENTS ${LLVM_LINK_COMPONENTS})
 104   set(LLVM_LINK_COMPONENTS ${LLVM_LINK_COMPONENTS} TableGen)
 105   add_llvm_utility(${target} ${ARGN})
 106   set(LLVM_LINK_COMPONENTS ${${target}_OLD_LLVM_LINK_COMPONENTS})
 107
 108   set(${project}_TABLEGEN "${target}" CACHE
 109       STRING "Native TableGen executable. Saves building one when cross-compiling.")
 110
 111   # Upgrade existing LLVM_TABLEGEN setting.
 112   if(${project} STREQUAL LLVM)
 113     if(${LLVM_TABLEGEN} STREQUAL tblgen)
 114       set(LLVM_TABLEGEN "${target}" CACHE
 115           STRING "Native TableGen executable. Saves building one when cross-compiling."
 116           FORCE)
 117     endif()
 118   endif()
 119
 120   # Effective tblgen executable to be used:
 121   set(${project}_TABLEGEN_EXE ${${project}_TABLEGEN} PARENT_SCOPE)
 122
 123   if(CMAKE_CROSSCOMPILING)
 124     if( ${${project}_TABLEGEN} STREQUAL "${target}" )
 125       set(${project}_TABLEGEN_EXE "${CX_NATIVE_TG_DIR}/bin/${target}")
 126       set(${project}_TABLEGEN_EXE ${${project}_TABLEGEN_EXE} PARENT_SCOPE)
 127
 128       add_custom_command(OUTPUT ${${project}_TABLEGEN_EXE}
 129         COMMAND ${CMAKE_BUILD_TOOL} ${target}
 130         DEPENDS ${CX_NATIVE_TG_DIR}/CMakeCache.txt
 131         WORKING_DIRECTORY ${CX_NATIVE_TG_DIR}
 132         COMMENT "Building native TableGen...")
 133       add_custom_target(${project}NativeTableGen DEPENDS ${${project}_TABLEGEN_EXE})
 134       add_dependencies(${project}NativeTableGen ConfigureNativeTableGen)
 135
 136       add_dependencies(${target} ${project}NativeTableGen)
 137     endif()
 138   endif()
 139
 140   if( MINGW )
 141     if(CMAKE_SIZEOF_VOID_P MATCHES "8")
 142       set_target_properties(${target} PROPERTIES LINK_FLAGS -Wl,--stack,16777216)
 143     endif(CMAKE_SIZEOF_VOID_P MATCHES "8")
 144   endif( MINGW )
 145   if (${project} STREQUAL LLVM AND NOT LLVM_INSTALL_TOOLCHAIN_ONLY)
 146     install(TARGETS ${target}
 147             EXPORT LLVMExports
 148             RUNTIME DESTINATION bin)
 149   endif()
 150   set_property(GLOBAL APPEND PROPERTY LLVM_EXPORTS ${target})
 151 endmacro()