cmake/modules/LLVMConfig.cmake

   1 function(get_system_libs return_var)
   2   # Returns in `return_var' a list of system libraries used by LLVM.
   3   if( NOT MSVC )
   4     if( MINGW )
   5       set(system_libs ${system_libs} imagehlp psapi)
   6     elseif( CMAKE_HOST_UNIX )
   7       if( HAVE_LIBDL )
   8         set(system_libs ${system_libs} ${CMAKE_DL_LIBS})
   9       endif()
  10       if( LLVM_ENABLE_THREADS AND HAVE_LIBPTHREAD )
  11         set(system_libs ${system_libs} pthread)
  12       endif()
  13     endif( MINGW )
  14   endif( NOT MSVC )
  15   set(${return_var} ${system_libs} PARENT_SCOPE)
  16 endfunction(get_system_libs)
  17
  18
  19 function(is_llvm_target_library library return_var)
  20   # Sets variable `return_var' to ON if `library' corresponds to a
  21   # LLVM supported target. To OFF if it doesn't.
  22   set(${return_var} OFF PARENT_SCOPE)
  23   string(TOUPPER "${library}" capitalized_lib)
  24   string(TOUPPER "${LLVM_ALL_TARGETS}" targets)
  25   foreach(t ${targets})
  26     if( capitalized_lib STREQUAL "LLVM${t}" OR
  27         capitalized_lib STREQUAL "LLVM${t}CODEGEN" OR
  28         capitalized_lib STREQUAL "LLVM${t}ASMPARSER" OR
  29         capitalized_lib STREQUAL "LLVM${t}ASMPRINTER" OR
  30         capitalized_lib STREQUAL "LLVM${t}DISASSEMBLER" OR
  31         capitalized_lib STREQUAL "LLVM${t}INFO" )
  32       set(${return_var} ON PARENT_SCOPE)
  33       break()
  34     endif()
  35   endforeach()
  36 endfunction(is_llvm_target_library)
  37
  38
  39 macro(llvm_config executable)
  40   explicit_llvm_config(${executable} ${ARGN})
  41 endmacro(llvm_config)
  42
  43
  44 function(explicit_llvm_config executable)
  45   set( link_components ${ARGN} )
  46
  47   explicit_map_components_to_libraries(LIBRARIES ${link_components})
  48   target_link_libraries(${executable} ${LIBRARIES})
  49 endfunction(explicit_llvm_config)
  50
  51
  52 # This is a variant intended for the final user:
  53 function(llvm_map_components_to_libraries OUT_VAR)
  54   explicit_map_components_to_libraries(result ${ARGN})
  55   get_system_libs(sys_result)
  56   set( ${OUT_VAR} ${result} ${sys_result} PARENT_SCOPE )
  57 endfunction(llvm_map_components_to_libraries)
  58
  59
  60 function(explicit_map_components_to_libraries out_libs)
  61   set( link_components ${ARGN} )
  62   foreach(c ${link_components})
  63     # add codegen, asmprinter, asmparser, disassembler
  64     list(FIND LLVM_TARGETS_TO_BUILD ${c} idx)
  65     if( NOT idx LESS 0 )
  66       list(FIND llvm_libs "LLVM${c}CodeGen" idx)
  67       if( NOT idx LESS 0 )
  68         list(APPEND expanded_components "LLVM${c}CodeGen")
  69       else()
  70         list(FIND llvm_libs "LLVM${c}" idx)
  71         if( NOT idx LESS 0 )
  72           list(APPEND expanded_components "LLVM${c}")
  73         else()
  74           message(FATAL_ERROR "Target ${c} is not in the set of libraries.")
  75         endif()
  76       endif()
  77       list(FIND llvm_libs "LLVM${c}AsmPrinter" asmidx)
  78       if( NOT asmidx LESS 0 )
  79         list(APPEND expanded_components "LLVM${c}AsmPrinter")
  80       endif()
  81       list(FIND llvm_libs "LLVM${c}AsmParser" asmidx)
  82       if( NOT asmidx LESS 0 )
  83         list(APPEND expanded_components "LLVM${c}AsmParser")
  84       endif()
  85       list(FIND llvm_libs "LLVM${c}Info" asmidx)
  86       if( NOT asmidx LESS 0 )
  87         list(APPEND expanded_components "LLVM${c}Info")
  88       endif()
  89       list(FIND llvm_libs "LLVM${c}Disassembler" asmidx)
  90       if( NOT asmidx LESS 0 )
  91         list(APPEND expanded_components "LLVM${c}Disassembler")
  92       endif()
  93     elseif( c STREQUAL "native" )
  94       list(APPEND expanded_components "LLVM${LLVM_NATIVE_ARCH}CodeGen")
  95     elseif( c STREQUAL "nativecodegen" )
  96       list(APPEND expanded_components "LLVM${LLVM_NATIVE_ARCH}CodeGen")
  97     elseif( c STREQUAL "backend" )
  98       # same case as in `native'.
  99     elseif( c STREQUAL "engine" )
 100       # TODO: as we assume we are on X86, this is `jit'.
 101       list(APPEND expanded_components "LLVMJIT")
 102     elseif( c STREQUAL "all" )
 103       list(APPEND expanded_components ${llvm_libs})
 104     else( NOT idx LESS 0 )
 105       list(APPEND expanded_components LLVM${c})
 106     endif( NOT idx LESS 0 )
 107   endforeach(c)
 108   # We must match capitalization.
 109   string(TOUPPER "${llvm_libs}" capitalized_libs)
 110   list(REMOVE_DUPLICATES expanded_components)
 111   list(LENGTH expanded_components lst_size)
 112   set(result "")
 113   while( 0 LESS ${lst_size} )
 114     list(GET expanded_components 0 c)
 115     string(TOUPPER "${c}" capitalized)
 116     list(FIND capitalized_libs ${capitalized} idx)
 117     set(add_it ON)
 118     if( idx LESS 0 )
 119       # The library is unkown. Maybe is an ommitted target?
 120       is_llvm_target_library(${c} iltl_result)
 121       if( NOT iltl_result )
 122         message(FATAL_ERROR "Library ${c} not found in list of llvm libraries.")
 123       endif()
 124       set(add_it OFF)
 125     endif( idx LESS 0 )
 126     list(GET llvm_libs ${idx} canonical_lib)
 127     list(REMOVE_ITEM result ${canonical_lib})
 128     foreach(c ${MSVC_LIB_DEPS_${canonical_lib}})
 129       list(REMOVE_ITEM expanded_components ${c})
 130     endforeach()
 131     if( add_it )
 132       list(APPEND result ${canonical_lib})
 133       list(APPEND expanded_components ${MSVC_LIB_DEPS_${canonical_lib}})
 134     endif()
 135     list(REMOVE_AT expanded_components 0)
 136     list(LENGTH expanded_components lst_size)
 137   endwhile( 0 LESS ${lst_size} )
 138   set(${out_libs} ${result} PARENT_SCOPE)
 139 endfunction(explicit_map_components_to_libraries)
 140
 141
 142 # The library dependency data is contained in the file
 143 # LLVMLibDeps.cmake on this directory. It is automatically generated
 144 # by tools/llvm-config/CMakeLists.txt when the build comprises all the
 145 # targets and we are on a environment Posix enough to build the
 146 # llvm-config script. This, in practice, just excludes MSVC.
 147
 148 # When you remove or rename a library from the build, be sure to
 149 # remove its file from lib/ as well, or the GenLibDeps.pl script will
 150 # include it on its analysis!
 151
 152 # The format generated by GenLibDeps.pl
 153
 154 # LLVMARMAsmPrinter.o: LLVMARMCodeGen.o libLLVMAsmPrinter.a libLLVMCodeGen.a libLLVMCore.a libLLVMSupport.a libLLVMTarget.a
 155
 156 # is translated to:
 157
 158 # set(MSVC_LIB_DEPS_LLVMARMAsmPrinter LLVMARMCodeGen LLVMAsmPrinter LLVMCodeGen LLVMCore LLVMSupport LLVMTarget)
 159
 160 # It is necessary to remove the `lib' prefix and the `.a'.
 161
 162 # This 'sed' script should do the trick:
 163 # sed -e s'#\.a##g' -e 's#libLLVM#LLVM#g' -e 's#: # #' -e 's#\(.*\)#set(MSVC_LIB_DEPS_\1)#' ~/llvm/tools/llvm-config/LibDeps.txt
 164
 165 include(LLVMLibDeps)