cmake/modules/HandleLLVMOptions.cmake

   1 # This CMake module is responsible for interpreting the user defined LLVM_
   2 # options and executing the appropriate CMake commands to realize the users'
   3 # selections.
   4
   5 include(AddLLVMDefinitions)
   6 include(CheckCCompilerFlag)
   7 include(CheckCXXCompilerFlag)
   8
   9 if( CMAKE_COMPILER_IS_GNUCXX )
  10   set(LLVM_COMPILER_IS_GCC_COMPATIBLE ON)
  11 elseif( "${CMAKE_CXX_COMPILER_ID}" MATCHES "Clang" )
  12   set(LLVM_COMPILER_IS_GCC_COMPATIBLE ON)
  13 endif()
  14
  15 if( LLVM_ENABLE_ASSERTIONS )
  16   # MSVC doesn't like _DEBUG on release builds. See PR 4379.
  17   if( NOT MSVC )
  18     add_definitions( -D_DEBUG )
  19   endif()
  20   # On Release builds cmake automatically defines NDEBUG, so we
  21   # explicitly undefine it:
  22   if( uppercase_CMAKE_BUILD_TYPE STREQUAL "RELEASE" )
  23     add_definitions( -UNDEBUG )
  24   endif()
  25 else()
  26   if( NOT uppercase_CMAKE_BUILD_TYPE STREQUAL "RELEASE" )
  27     if( NOT MSVC_IDE AND NOT XCODE )
  28       add_definitions( -DNDEBUG )
  29     endif()
  30   endif()
  31 endif()
  32
  33 if(WIN32)
  34   if(CYGWIN)
  35     set(LLVM_ON_WIN32 0)
  36     set(LLVM_ON_UNIX 1)
  37   else(CYGWIN)
  38     set(LLVM_ON_WIN32 1)
  39     set(LLVM_ON_UNIX 0)
  40   endif(CYGWIN)
  41   set(LTDL_SHLIB_EXT ".dll")
  42   set(EXEEXT ".exe")
  43   # Maximum path length is 160 for non-unicode paths
  44   set(MAXPATHLEN 160)
  45 else(WIN32)
  46   if(UNIX)
  47     set(LLVM_ON_WIN32 0)
  48     set(LLVM_ON_UNIX 1)
  49     if(APPLE)
  50       set(LTDL_SHLIB_EXT ".dylib")
  51     else(APPLE)
  52       set(LTDL_SHLIB_EXT ".so")
  53     endif(APPLE)
  54     set(EXEEXT "")
  55     # FIXME: Maximum path length is currently set to 'safe' fixed value
  56     set(MAXPATHLEN 2024)
  57   else(UNIX)
  58     MESSAGE(SEND_ERROR "Unable to determine platform")
  59   endif(UNIX)
  60 endif(WIN32)
  61
  62 function(add_flag_or_print_warning flag)
  63   check_c_compiler_flag(${flag} C_SUPPORTS_${flag})
  64   check_cxx_compiler_flag(${flag} CXX_SUPPORTS_${flag})
  65   if (C_SUPPORTS_${flag} AND CXX_SUPPORTS_${flag})
  66     message(STATUS "Building with ${flag}")
  67     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} ${flag}" PARENT_SCOPE)
  68     set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} ${flag}" PARENT_SCOPE)
  69   else()
  70     message(WARNING "${flag} is not supported.")
  71   endif()
  72 endfunction()
  73
  74 function(append_if variable value condition)
  75   if (${condition})
  76     set(${variable} "${${variable}} ${value}" PARENT_SCOPE)
  77   endif()
  78 endfunction()
  79
  80 if( LLVM_ENABLE_PIC )
  81   if( XCODE )
  82     # Xcode has -mdynamic-no-pic on by default, which overrides -fPIC. I don't
  83     # know how to disable this, so just force ENABLE_PIC off for now.
  84     message(WARNING "-fPIC not supported with Xcode.")
  85   elseif( WIN32 OR CYGWIN)
  86     # On Windows all code is PIC. MinGW warns if -fPIC is used.
  87   else()
  88     add_flag_or_print_warning("-fPIC")
  89
  90     if( WIN32 OR CYGWIN)
  91       # MinGW warns if -fvisibility-inlines-hidden is used.
  92     else()
  93       check_cxx_compiler_flag("-fvisibility-inlines-hidden" SUPPORTS_FVISIBILITY_INLINES_HIDDEN_FLAG)
  94       append_if(CMAKE_CXX_FLAGS "-fvisibility-inlines-hidden" SUPPORTS_FVISIBILITY_INLINES_HIDDEN_FLAG)
  95     endif()
  96   endif()
  97 endif()
  98
  99 if( CMAKE_SIZEOF_VOID_P EQUAL 8 AND NOT WIN32 )
 100   # TODO: support other platforms and toolchains.
 101   if( LLVM_BUILD_32_BITS )
 102     message(STATUS "Building 32 bits executables and libraries.")
 103     add_llvm_definitions( -m32 )
 104     set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -m32")
 105     set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} -m32")
 106     set(CMAKE_MODULE_LINKER_FLAGS "${CMAKE_MODULE_LINKER_FLAGS} -m32")
 107   endif( LLVM_BUILD_32_BITS )
 108 endif( CMAKE_SIZEOF_VOID_P EQUAL 8 AND NOT WIN32 )
 109
 110 # On Win32 using MS tools, provide an option to set the number of parallel jobs
 111 # to use.
 112 if( MSVC_IDE )
 113   set(LLVM_COMPILER_JOBS "0" CACHE STRING
 114     "Number of parallel compiler jobs. 0 means use all processors. Default is 0.")
 115   if( NOT LLVM_COMPILER_JOBS STREQUAL "1" )
 116     if( LLVM_COMPILER_JOBS STREQUAL "0" )
 117       add_llvm_definitions( /MP )
 118     else()
 119       if (MSVC10)
 120         message(FATAL_ERROR
 121           "Due to a bug in CMake only 0 and 1 is supported for "
 122           "LLVM_COMPILER_JOBS when generating for Visual Studio 2010")
 123       else()
 124         message(STATUS "Number of parallel compiler jobs set to " ${LLVM_COMPILER_JOBS})
 125         add_llvm_definitions( /MP${LLVM_COMPILER_JOBS} )
 126       endif()
 127     endif()
 128   else()
 129     message(STATUS "Parallel compilation disabled")
 130   endif()
 131 endif()
 132
 133 if( MSVC )
 134   include(ChooseMSVCCRT)
 135
 136   if( MSVC11 )
 137     add_llvm_definitions(-D_VARIADIC_MAX=10)
 138   endif()
 139
 140   # Add definitions that make MSVC much less annoying.
 141   add_llvm_definitions(
 142     # For some reason MS wants to deprecate a bunch of standard functions...
 143     -D_CRT_SECURE_NO_DEPRECATE
 144     -D_CRT_SECURE_NO_WARNINGS
 145     -D_CRT_NONSTDC_NO_DEPRECATE
 146     -D_CRT_NONSTDC_NO_WARNINGS
 147     -D_SCL_SECURE_NO_DEPRECATE
 148     -D_SCL_SECURE_NO_WARNINGS
 149
 150     # Disabled warnings.
 151     -wd4065 # Suppress 'switch statement contains 'default' but no 'case' labels'
 152     -wd4146 # Suppress 'unary minus operator applied to unsigned type, result still unsigned'
 153     -wd4180 # Suppress 'qualifier applied to function type has no meaning; ignored'
 154     -wd4181 # Suppress 'qualifier applied to reference type; ignored'
 155     -wd4224 # Suppress 'nonstandard extension used : formal parameter 'identifier' was previously defined as a type'
 156     -wd4244 # Suppress ''argument' : conversion from 'type1' to 'type2', possible loss of data'
 157     -wd4267 # Suppress ''var' : conversion from 'size_t' to 'type', possible loss of data'
 158     -wd4275 # Suppress 'An exported class was derived from a class that was not exported.'
 159     -wd4291 # Suppress ''declaration' : no matching operator delete found; memory will not be freed if initialization throws an exception'
 160     -wd4345 # Suppress 'behavior change: an object of POD type constructed with an initializer of the form () will be default-initialized'
 161     -wd4351 # Suppress 'new behavior: elements of array 'array' will be default initialized'
 162     -wd4355 # Suppress ''this' : used in base member initializer list'
 163     -wd4503 # Suppress ''identifier' : decorated name length exceeded, name was truncated'
 164     -wd4551 # Suppress 'function call missing argument list'
 165     -wd4624 # Suppress ''derived class' : destructor could not be generated because a base class destructor is inaccessible'
 166     -wd4715 # Suppress ''function' : not all control paths return a value'
 167     -wd4722 # Suppress ''function' : destructor never returns, potential memory leak'
 168     -wd4800 # Suppress ''type' : forcing value to bool 'true' or 'false' (performance warning)'
 169
 170     # Promoted warnings.
 171     -w14062 # Promote 'enumerator in switch of enum is not handled' to level 1 warning.
 172
 173     # Promoted warnings to errors.
 174     -we4238 # Promote 'nonstandard extension used : class rvalue used as lvalue' to error.
 175     )
 176
 177   # Enable warnings
 178   if (LLVM_ENABLE_WARNINGS)
 179     add_llvm_definitions( /W4 )
 180     if (LLVM_ENABLE_PEDANTIC)
 181       # No MSVC equivalent available
 182     endif (LLVM_ENABLE_PEDANTIC)
 183   endif (LLVM_ENABLE_WARNINGS)
 184   if (LLVM_ENABLE_WERROR)
 185     add_llvm_definitions( /WX )
 186   endif (LLVM_ENABLE_WERROR)
 187 elseif( LLVM_COMPILER_IS_GCC_COMPATIBLE )
 188   if (LLVM_ENABLE_WARNINGS)
 189     add_llvm_definitions( -Wall -W -Wno-unused-parameter -Wwrite-strings )
 190
 191     # Turn off missing field initializer warnings for gcc to avoid noise from
 192     # false positives with empty {}. Turn them on otherwise (they're off by
 193     # default for clang).
 194     check_cxx_compiler_flag("-Wmissing-field-initializers" CXX_SUPPORTS_MISSING_FIELD_INITIALIZERS_FLAG)
 195     if (CXX_SUPPORTS_MISSING_FIELD_INITIALIZERS_FLAG)
 196       if (CMAKE_COMPILER_IS_GNUCXX)
 197         add_llvm_definitions( -Wno-missing-field-initializers )
 198       else()
 199         add_llvm_definitions( -Wmissing-field-initializers )
 200       endif()
 201     endif()
 202
 203     if (LLVM_ENABLE_PEDANTIC)
 204       add_llvm_definitions( -pedantic -Wno-long-long )
 205     endif (LLVM_ENABLE_PEDANTIC)
 206     check_cxx_compiler_flag("-Werror -Wcovered-switch-default" CXX_SUPPORTS_COVERED_SWITCH_DEFAULT_FLAG)
 207     append_if(CMAKE_CXX_FLAGS "-Wcovered-switch-default" CXX_SUPPORTS_COVERED_SWITCH_DEFAULT_FLAG)
 208     check_c_compiler_flag("-Werror -Wcovered-switch-default" C_SUPPORTS_COVERED_SWITCH_DEFAULT_FLAG)
 209     append_if(CMAKE_C_FLAGS "-Wcovered-switch-default" C_SUPPORTS_COVERED_SWITCH_DEFAULT_FLAG)
 210     append_if(CMAKE_CXX_FLAGS "-Wno-uninitialized" USE_NO_UNINITIALIZED)
 211     append_if(CMAKE_CXX_FLAGS "-Wno-maybe-uninitialized" USE_NO_MAYBE_UNINITIALIZED)
 212   endif (LLVM_ENABLE_WARNINGS)
 213   if (LLVM_ENABLE_WERROR)
 214     add_llvm_definitions( -Werror )
 215   endif (LLVM_ENABLE_WERROR)
 216 endif( MSVC )
 217
 218 add_llvm_definitions( -D__STDC_CONSTANT_MACROS )
 219 add_llvm_definitions( -D__STDC_FORMAT_MACROS )
 220 add_llvm_definitions( -D__STDC_LIMIT_MACROS )