cmake/modules/HandleLLVMOptions.cmake

   1 include(AddLLVMDefinitions)
   2
   3 # Run-time build mode; It is used for unittests.
   4 if(MSVC_IDE)
   5   # Expect "$(Configuration)", "$(OutDir)", etc.
   6   # It is expanded by msbuild or similar.
   7   set(RUNTIME_BUILD_MODE "${CMAKE_CFG_INTDIR}")
   8 elseif(NOT CMAKE_BUILD_TYPE STREQUAL "")
   9   # Expect "Release" "Debug", etc.
  10   # Or unittests could not run.
  11   set(RUNTIME_BUILD_MODE ${CMAKE_BUILD_TYPE})
  12 else()
  13   # It might be "."
  14   set(RUNTIME_BUILD_MODE "${CMAKE_CFG_INTDIR}")
  15 endif()
  16
  17 set(LIT_ARGS_DEFAULT "-sv")
  18 if (MSVC OR XCODE)
  19   set(LIT_ARGS_DEFAULT "${LIT_ARGS_DEFAULT} --no-progress-bar")
  20 endif()
  21 set(LLVM_LIT_ARGS "${LIT_ARGS_DEFAULT}"
  22     CACHE STRING "Default options for lit")
  23
  24 set(LLVM_LIT_TOOLS_DIR "" CACHE PATH "Path to GnuWin32 tools")
  25
  26 if( LLVM_ENABLE_ASSERTIONS )
  27   # MSVC doesn't like _DEBUG on release builds. See PR 4379.
  28   if( NOT MSVC )
  29     add_definitions( -D_DEBUG )
  30   endif()
  31   # On Release builds cmake automatically defines NDEBUG, so we
  32   # explicitly undefine it:
  33   if( uppercase_CMAKE_BUILD_TYPE STREQUAL "RELEASE" )
  34     add_definitions( -UNDEBUG )
  35   endif()
  36 else()
  37   if( NOT uppercase_CMAKE_BUILD_TYPE STREQUAL "RELEASE" )
  38     if( NOT MSVC_IDE AND NOT XCODE )
  39       add_definitions( -DNDEBUG )
  40     endif()
  41   endif()
  42 endif()
  43
  44 if(WIN32)
  45   if(CYGWIN)
  46     set(LLVM_ON_WIN32 0)
  47     set(LLVM_ON_UNIX 1)
  48   else(CYGWIN)
  49     set(LLVM_ON_WIN32 1)
  50     set(LLVM_ON_UNIX 0)
  51   endif(CYGWIN)
  52   set(LTDL_SHLIB_EXT ".dll")
  53   set(EXEEXT ".exe")
  54   # Maximum path length is 160 for non-unicode paths
  55   set(MAXPATHLEN 160)
  56 else(WIN32)
  57   if(UNIX)
  58     set(LLVM_ON_WIN32 0)
  59     set(LLVM_ON_UNIX 1)
  60     if(APPLE)
  61       set(LTDL_SHLIB_EXT ".dylib")
  62     else(APPLE)
  63       set(LTDL_SHLIB_EXT ".so")
  64     endif(APPLE)
  65     set(EXEEXT "")
  66     # FIXME: Maximum path length is currently set to 'safe' fixed value
  67     set(MAXPATHLEN 2024)
  68   else(UNIX)
  69     MESSAGE(SEND_ERROR "Unable to determine platform")
  70   endif(UNIX)
  71 endif(WIN32)
  72
  73 if( LLVM_ENABLE_PIC )
  74   if( XCODE )
  75     # Xcode has -mdynamic-no-pic on by default, which overrides -fPIC. I don't
  76     # know how to disable this, so just force ENABLE_PIC off for now.
  77     message(WARNING "-fPIC not supported with Xcode.")
  78   elseif( WIN32 )
  79     # On Windows all code is PIC. MinGW warns if -fPIC is used.
  80   else()
  81     include(CheckCXXCompilerFlag)
  82     check_cxx_compiler_flag("-fPIC" SUPPORTS_FPIC_FLAG)
  83     if( SUPPORTS_FPIC_FLAG )
  84       message(STATUS "Building with -fPIC")
  85       set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -fPIC")
  86       set(CMAKE_C_FLAGS "${CMAKE_CXX_FLAGS} -fPIC")
  87     else( SUPPORTS_FPIC_FLAG )
  88       message(WARNING "-fPIC not supported.")
  89     endif()
  90   endif()
  91 endif()
  92
  93 if( CMAKE_SIZEOF_VOID_P EQUAL 8 AND NOT WIN32 )
  94   # TODO: support other platforms and toolchains.
  95   option(LLVM_BUILD_32_BITS "Build 32 bits executables and libraries." OFF)
  96   if( LLVM_BUILD_32_BITS )
  97     message(STATUS "Building 32 bits executables and libraries.")
  98     add_llvm_definitions( -m32 )
  99     list(APPEND CMAKE_EXE_LINKER_FLAGS -m32)
 100     list(APPEND CMAKE_SHARED_LINKER_FLAGS -m32)
 101   endif( LLVM_BUILD_32_BITS )
 102 endif( CMAKE_SIZEOF_VOID_P EQUAL 8 AND NOT WIN32 )
 103
 104 if( MSVC )
 105   include(ChooseMSVCCRT)
 106
 107   # Add definitions that make MSVC much less annoying.
 108   add_llvm_definitions(
 109     # For some reason MS wants to deprecate a bunch of standard functions...
 110     -D_CRT_SECURE_NO_DEPRECATE
 111     -D_CRT_SECURE_NO_WARNINGS
 112     -D_CRT_NONSTDC_NO_DEPRECATE
 113     -D_CRT_NONSTDC_NO_WARNINGS
 114     -D_SCL_SECURE_NO_DEPRECATE
 115     -D_SCL_SECURE_NO_WARNINGS
 116
 117     -wd4146 # Suppress 'unary minus operator applied to unsigned type, result still unsigned'
 118     -wd4180 # Suppress 'qualifier applied to function type has no meaning; ignored'
 119     -wd4224 # Suppress 'nonstandard extension used : formal parameter 'identifier' was previously defined as a type'
 120     -wd4244 # Suppress ''argument' : conversion from 'type1' to 'type2', possible loss of data'
 121     -wd4267 # Suppress ''var' : conversion from 'size_t' to 'type', possible loss of data'
 122     -wd4275 # Suppress 'An exported class was derived from a class that was not exported.'
 123     -wd4291 # Suppress ''declaration' : no matching operator delete found; memory will not be freed if initialization throws an exception'
 124     -wd4345 # Suppress 'behavior change: an object of POD type constructed with an initializer of the form () will be default-initialized'
 125     -wd4351 # Suppress 'new behavior: elements of array 'array' will be default initialized'
 126     -wd4355 # Suppress ''this' : used in base member initializer list'
 127     -wd4503 # Suppress ''identifier' : decorated name length exceeded, name was truncated'
 128     -wd4624 # Suppress ''derived class' : destructor could not be generated because a base class destructor is inaccessible'
 129     -wd4715 # Suppress ''function' : not all control paths return a value'
 130     -wd4800 # Suppress ''type' : forcing value to bool 'true' or 'false' (performance warning)'
 131     -wd4065 # Suppress 'switch statement contains 'default' but no 'case' labels'
 132
 133     -w14062 # Promote "enumerator in switch of enum is not handled" to level 1 warning.
 134     )
 135
 136   # Enable warnings
 137   if (LLVM_ENABLE_WARNINGS)
 138     add_llvm_definitions( /W4 /Wall )
 139     if (LLVM_ENABLE_PEDANTIC)
 140       # No MSVC equivalent available
 141     endif (LLVM_ENABLE_PEDANTIC)
 142   endif (LLVM_ENABLE_WARNINGS)
 143   if (LLVM_ENABLE_WERROR)
 144     add_llvm_definitions( /WX )
 145   endif (LLVM_ENABLE_WERROR)
 146 elseif( CMAKE_COMPILER_IS_GNUCXX )
 147   if (LLVM_ENABLE_WARNINGS)
 148     add_llvm_definitions( -Wall -W -Wno-unused-parameter -Wwrite-strings )
 149     if (LLVM_ENABLE_PEDANTIC)
 150       add_llvm_definitions( -pedantic -Wno-long-long )
 151     endif (LLVM_ENABLE_PEDANTIC)
 152   endif (LLVM_ENABLE_WARNINGS)
 153   if (LLVM_ENABLE_WERROR)
 154     add_llvm_definitions( -Werror )
 155   endif (LLVM_ENABLE_WERROR)
 156 endif( MSVC )
 157
 158 add_llvm_definitions( -D__STDC_LIMIT_MACROS )
 159 add_llvm_definitions( -D__STDC_CONSTANT_MACROS )
 160