cmake/modules/HandleLLVMOptions.cmake

   1 # This CMake module is responsible for interpreting the user defined LLVM_
   2 # options and executing the appropriate CMake commands to realize the users'
   3 # selections.
   4
   5 include(HandleLLVMStdlib)
   6 include(AddLLVMDefinitions)
   7 include(CheckCCompilerFlag)
   8 include(CheckCXXCompilerFlag)
   9
  10 if(NOT LLVM_FORCE_USE_OLD_TOOLCHAIN)
  11   if(CMAKE_CXX_COMPILER_ID STREQUAL "GNU")
  12     if(CMAKE_CXX_COMPILER_VERSION VERSION_LESS 4.7)
  13       message(FATAL_ERROR "Host GCC version must be at least 4.7!")
  14     endif()
  15   elseif(CMAKE_CXX_COMPILER_ID STREQUAL "Clang")
  16     if(CMAKE_CXX_COMPILER_VERSION VERSION_LESS 3.1)
  17       message(FATAL_ERROR "Host Clang version must be at least 3.1!")
  18     endif()
  19
  20     # Also test that we aren't using too old of a version of libstdc++ with the
  21     # Clang compiler. This is tricky as there is no real way to check the
  22     # version of libstdc++ directly. Instead we test for a known bug in
  23     # libstdc++4.6 that is fixed in libstdc++4.7.
  24     if(NOT LLVM_ENABLE_LIBCXX)
  25       set(OLD_CMAKE_REQUIRED_FLAGS ${CMAKE_REQUIRED_FLAGS})
  26       set(OLD_CMAKE_REQUIRED_LIBRARIES ${CMAKE_REQUIRED_LIBRARIES})
  27       set(CMAKE_REQUIRED_FLAGS "-std=c++0x")
  28       check_cxx_source_compiles("
  29 #include <atomic>
  30 std::atomic<float> x(0.0f);
  31 int main() { return (float)x; }"
  32         LLVM_NO_OLD_LIBSTDCXX)
  33       if(NOT LLVM_NO_OLD_LIBSTDCXX)
  34         message(FATAL_ERROR "Host Clang must be able to find libstdc++4.7 or newer!")
  35       endif()
  36       set(CMAKE_REQUIRED_FLAGS ${OLD_CMAKE_REQUIRED_FLAGS})
  37       set(CMAKE_REQUIRED_LIBRARIES ${OLD_CMAKE_REQUIRED_LIBRARIES})
  38     endif()
  39   elseif(CMAKE_CXX_COMPILER_ID MATCHES "MSVC")
  40     if(CMAKE_CXX_COMPILER_VERSION VERSION_LESS 17.0)
  41       message(FATAL_ERROR "Host Visual Studio must be at least 2012 (MSVC 17.0)")
  42     endif()
  43   endif()
  44 endif()
  45
  46 if( LLVM_ENABLE_ASSERTIONS )
  47   # MSVC doesn't like _DEBUG on release builds. See PR 4379.
  48   if( NOT MSVC )
  49     add_definitions( -D_DEBUG )
  50   endif()
  51   # On non-Debug builds cmake automatically defines NDEBUG, so we
  52   # explicitly undefine it:
  53   if( NOT uppercase_CMAKE_BUILD_TYPE STREQUAL "DEBUG" )
  54     add_definitions( -UNDEBUG )
  55     # Also remove /D NDEBUG to avoid MSVC warnings about conflicting defines.
  56     foreach (flags_var_to_scrub
  57         CMAKE_CXX_FLAGS_RELEASE
  58         CMAKE_CXX_FLAGS_RELWITHDEBINFO
  59         CMAKE_CXX_FLAGS_MINSIZEREL
  60         CMAKE_C_FLAGS_RELEASE
  61         CMAKE_C_FLAGS_RELWITHDEBINFO
  62         CMAKE_C_FLAGS_MINSIZEREL)
  63       string (REGEX REPLACE "(^| )[/-]D *NDEBUG($| )" " "
  64         "${flags_var_to_scrub}" "${${flags_var_to_scrub}}")
  65     endforeach()
  66   endif()
  67 endif()
  68
  69 if(WIN32)
  70   set(LLVM_HAVE_LINK_VERSION_SCRIPT 0)
  71   if(CYGWIN)
  72     set(LLVM_ON_WIN32 0)
  73     set(LLVM_ON_UNIX 1)
  74   else(CYGWIN)
  75     set(LLVM_ON_WIN32 1)
  76     set(LLVM_ON_UNIX 0)
  77   endif(CYGWIN)
  78   # Maximum path length is 160 for non-unicode paths
  79   set(MAXPATHLEN 160)
  80 else(WIN32)
  81   if(UNIX)
  82     set(LLVM_ON_WIN32 0)
  83     set(LLVM_ON_UNIX 1)
  84     if(APPLE)
  85       set(LLVM_HAVE_LINK_VERSION_SCRIPT 0)
  86     else(APPLE)
  87       set(LLVM_HAVE_LINK_VERSION_SCRIPT 1)
  88     endif(APPLE)
  89     # FIXME: Maximum path length is currently set to 'safe' fixed value
  90     set(MAXPATHLEN 2024)
  91   else(UNIX)
  92     MESSAGE(SEND_ERROR "Unable to determine platform")
  93   endif(UNIX)
  94 endif(WIN32)
  95
  96 set(EXEEXT ${CMAKE_EXECUTABLE_SUFFIX})
  97 set(LTDL_SHLIB_EXT ${CMAKE_SHARED_LIBRARY_SUFFIX})
  98
  99 # We use *.dylib rather than *.so on darwin.
 100 set(LLVM_PLUGIN_EXT ${CMAKE_SHARED_LIBRARY_SUFFIX})
 101
 102 if(APPLE)
 103   # Darwin-specific linker flags for loadable modules.
 104   set(CMAKE_MODULE_LINKER_FLAGS "${CMAKE_MODULE_LINKER_FLAGS} -Wl,-flat_namespace -Wl,-undefined -Wl,suppress")
 105 endif()
 106
 107 function(append value)
 108   foreach(variable ${ARGN})
 109     set(${variable} "${${variable}} ${value}" PARENT_SCOPE)
 110   endforeach(variable)
 111 endfunction()
 112
 113 function(append_if condition value)
 114   if (${condition})
 115     foreach(variable ${ARGN})
 116       set(${variable} "${${variable}} ${value}" PARENT_SCOPE)
 117     endforeach(variable)
 118   endif()
 119 endfunction()
 120
 121 macro(add_flag_if_supported flag name)
 122   check_c_compiler_flag("-Werror ${flag}" "C_SUPPORTS_${name}")
 123   append_if("C_SUPPORTS_${name}" "${flag}" CMAKE_C_FLAGS)
 124   check_cxx_compiler_flag("-Werror ${flag}" "CXX_SUPPORTS_${name}")
 125   append_if("CXX_SUPPORTS_${name}" "${flag}" CMAKE_CXX_FLAGS)
 126 endmacro()
 127
 128 function(add_flag_or_print_warning flag name)
 129   check_c_compiler_flag("-Werror ${flag}" "C_SUPPORTS_${name}")
 130   check_cxx_compiler_flag("-Werror ${flag}" "CXX_SUPPORTS_${name}")
 131   if (C_SUPPORTS_${name} AND CXX_SUPPORTS_${name})
 132     message(STATUS "Building with ${flag}")
 133     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} ${flag}" PARENT_SCOPE)
 134     set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} ${flag}" PARENT_SCOPE)
 135   else()
 136     message(WARNING "${flag} is not supported.")
 137   endif()
 138 endfunction()
 139
 140 if( LLVM_ENABLE_PIC )
 141   if( XCODE )
 142     # Xcode has -mdynamic-no-pic on by default, which overrides -fPIC. I don't
 143     # know how to disable this, so just force ENABLE_PIC off for now.
 144     message(WARNING "-fPIC not supported with Xcode.")
 145   elseif( WIN32 OR CYGWIN)
 146     # On Windows all code is PIC. MinGW warns if -fPIC is used.
 147   else()
 148     add_flag_or_print_warning("-fPIC" FPIC)
 149
 150     if( WIN32 OR CYGWIN)
 151       # MinGW warns if -fvisibility-inlines-hidden is used.
 152     else()
 153       check_cxx_compiler_flag("-fvisibility-inlines-hidden" SUPPORTS_FVISIBILITY_INLINES_HIDDEN_FLAG)
 154       append_if(SUPPORTS_FVISIBILITY_INLINES_HIDDEN_FLAG "-fvisibility-inlines-hidden" CMAKE_CXX_FLAGS)
 155     endif()
 156   endif()
 157 endif()
 158
 159 if( CMAKE_SIZEOF_VOID_P EQUAL 8 AND NOT WIN32 )
 160   # TODO: support other platforms and toolchains.
 161   if( LLVM_BUILD_32_BITS )
 162     message(STATUS "Building 32 bits executables and libraries.")
 163     add_llvm_definitions( -m32 )
 164     set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -m32")
 165     set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} -m32")
 166     set(CMAKE_MODULE_LINKER_FLAGS "${CMAKE_MODULE_LINKER_FLAGS} -m32")
 167   endif( LLVM_BUILD_32_BITS )
 168 endif( CMAKE_SIZEOF_VOID_P EQUAL 8 AND NOT WIN32 )
 169
 170 if (LLVM_BUILD_STATIC)
 171   set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -static")
 172 endif()
 173
 174 if( XCODE )
 175   # For Xcode enable several build settings that correspond to
 176   # many warnings that are on by default in Clang but are
 177   # not enabled for historical reasons.  For versions of Xcode
 178   # that do not support these options they will simply
 179   # be ignored.
 180   set(CMAKE_XCODE_ATTRIBUTE_GCC_WARN_ABOUT_RETURN_TYPE "YES")
 181   set(CMAKE_XCODE_ATTRIBUTE_GCC_WARN_ABOUT_MISSING_NEWLINE "YES")
 182   set(CMAKE_XCODE_ATTRIBUTE_GCC_WARN_UNUSED_VALUE "YES")
 183   set(CMAKE_XCODE_ATTRIBUTE_GCC_WARN_UNUSED_VARIABLE "YES")
 184   set(CMAKE_XCODE_ATTRIBUTE_GCC_WARN_SIGN_COMPARE "YES")
 185   set(CMAKE_XCODE_ATTRIBUTE_GCC_WARN_UNUSED_FUNCTION "YES")
 186   set(CMAKE_XCODE_ATTRIBUTE_GCC_WARN_INITIALIZER_NOT_FULLY_BRACKETED "YES")
 187   set(CMAKE_XCODE_ATTRIBUTE_GCC_WARN_HIDDEN_VIRTUAL_FUNCTIONS "YES")
 188   set(CMAKE_XCODE_ATTRIBUTE_GCC_WARN_UNINITIALIZED_AUTOS "YES")
 189   set(CMAKE_XCODE_ATTRIBUTE_CLANG_WARN_BOOL_CONVERSION "YES")
 190   set(CMAKE_XCODE_ATTRIBUTE_CLANG_WARN_EMPTY_BODY "YES")
 191   set(CMAKE_XCODE_ATTRIBUTE_CLANG_WARN_ENUM_CONVERSION "YES")
 192   set(CMAKE_XCODE_ATTRIBUTE_CLANG_WARN_INT_CONVERSION "YES")
 193   set(CMAKE_XCODE_ATTRIBUTE_CLANG_WARN_CONSTANT_CONVERSION "YES")
 194   set(CMAKE_XCODE_ATTRIBUTE_GCC_WARN_NON_VIRTUAL_DESTRUCTOR "YES")
 195 endif()
 196
 197 # On Win32 using MS tools, provide an option to set the number of parallel jobs
 198 # to use.
 199 if( MSVC_IDE )
 200   set(LLVM_COMPILER_JOBS "0" CACHE STRING
 201     "Number of parallel compiler jobs. 0 means use all processors. Default is 0.")
 202   if( NOT LLVM_COMPILER_JOBS STREQUAL "1" )
 203     if( LLVM_COMPILER_JOBS STREQUAL "0" )
 204       add_llvm_definitions( /MP )
 205     else()
 206       message(STATUS "Number of parallel compiler jobs set to " ${LLVM_COMPILER_JOBS})
 207       add_llvm_definitions( /MP${LLVM_COMPILER_JOBS} )
 208     endif()
 209   else()
 210     message(STATUS "Parallel compilation disabled")
 211   endif()
 212 endif()
 213
 214 if( MSVC )
 215   include(ChooseMSVCCRT)
 216
 217   if( NOT (${CMAKE_VERSION} VERSION_LESS 2.8.11) )
 218     # set stack reserved size to ~10MB
 219     # CMake previously automatically set this value for MSVC builds, but the
 220     # behavior was changed in CMake 2.8.11 (Issue 12437) to use the MSVC default
 221     # value (1 MB) which is not enough for us in tasks such as parsing recursive
 222     # C++ templates in Clang.
 223     set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} /STACK:10000000")
 224   endif()
 225
 226   if( MSVC11 )
 227     add_llvm_definitions(-D_VARIADIC_MAX=10)
 228   endif()
 229
 230   # Add definitions that make MSVC much less annoying.
 231   add_llvm_definitions(
 232     # For some reason MS wants to deprecate a bunch of standard functions...
 233     -D_CRT_SECURE_NO_DEPRECATE
 234     -D_CRT_SECURE_NO_WARNINGS
 235     -D_CRT_NONSTDC_NO_DEPRECATE
 236     -D_CRT_NONSTDC_NO_WARNINGS
 237     -D_SCL_SECURE_NO_DEPRECATE
 238     -D_SCL_SECURE_NO_WARNINGS
 239
 240     # Disabled warnings.
 241     -wd4146 # Suppress 'unary minus operator applied to unsigned type, result still unsigned'
 242     -wd4180 # Suppress 'qualifier applied to function type has no meaning; ignored'
 243     -wd4244 # Suppress ''argument' : conversion from 'type1' to 'type2', possible loss of data'
 244     -wd4258 # Suppress ''var' : definition from the for loop is ignored; the definition from the enclosing scope is used'
 245     -wd4267 # Suppress ''var' : conversion from 'size_t' to 'type', possible loss of data'
 246     -wd4291 # Suppress ''declaration' : no matching operator delete found; memory will not be freed if initialization throws an exception'
 247     -wd4345 # Suppress 'behavior change: an object of POD type constructed with an initializer of the form () will be default-initialized'
 248     -wd4351 # Suppress 'new behavior: elements of array 'array' will be default initialized'
 249     -wd4355 # Suppress ''this' : used in base member initializer list'
 250     -wd4456 # Suppress 'declaration of 'var' hides local variable'
 251     -wd4457 # Suppress 'declaration of 'var' hides function parameter'
 252     -wd4458 # Suppress 'declaration of 'var' hides class member'
 253     -wd4459 # Suppress 'declaration of 'var' hides global declaration'
 254     -wd4503 # Suppress ''identifier' : decorated name length exceeded, name was truncated'
 255     -wd4624 # Suppress ''derived class' : destructor could not be generated because a base class destructor is inaccessible'
 256     -wd4722 # Suppress 'function' : destructor never returns, potential memory leak
 257     -wd4800 # Suppress ''type' : forcing value to bool 'true' or 'false' (performance warning)'
 258
 259     # Promoted warnings.
 260     -w14062 # Promote 'enumerator in switch of enum is not handled' to level 1 warning.
 261
 262     # Promoted warnings to errors.
 263     -we4238 # Promote 'nonstandard extension used : class rvalue used as lvalue' to error.
 264     )
 265
 266   # Enable warnings
 267   if (LLVM_ENABLE_WARNINGS)
 268     add_llvm_definitions( /W4 )
 269     if (LLVM_ENABLE_PEDANTIC)
 270       # No MSVC equivalent available
 271     endif (LLVM_ENABLE_PEDANTIC)
 272   endif (LLVM_ENABLE_WARNINGS)
 273   if (LLVM_ENABLE_WERROR)
 274     add_llvm_definitions( /WX )
 275   endif (LLVM_ENABLE_WERROR)
 276 elseif( LLVM_COMPILER_IS_GCC_COMPATIBLE )
 277   if (LLVM_ENABLE_WARNINGS)
 278     append("-Wall -W -Wno-unused-parameter -Wwrite-strings" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 279
 280     # Turn off missing field initializer warnings for gcc to avoid noise from
 281     # false positives with empty {}. Turn them on otherwise (they're off by
 282     # default for clang).
 283     check_cxx_compiler_flag("-Wmissing-field-initializers" CXX_SUPPORTS_MISSING_FIELD_INITIALIZERS_FLAG)
 284     if (CXX_SUPPORTS_MISSING_FIELD_INITIALIZERS_FLAG)
 285       if (CMAKE_COMPILER_IS_GNUCXX)
 286         append("-Wno-missing-field-initializers" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 287       else()
 288         append("-Wmissing-field-initializers" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 289       endif()
 290     endif()
 291
 292     append_if(LLVM_ENABLE_PEDANTIC "-pedantic -Wno-long-long" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 293     add_flag_if_supported("-Wcovered-switch-default" COVERED_SWITCH_DEFAULT_FLAG)
 294     append_if(USE_NO_UNINITIALIZED "-Wno-uninitialized" CMAKE_CXX_FLAGS)
 295     append_if(USE_NO_MAYBE_UNINITIALIZED "-Wno-maybe-uninitialized" CMAKE_CXX_FLAGS)
 296
 297     # Check if -Wnon-virtual-dtor warns even though the class is marked final.
 298     # If it does, don't add it. So it won't be added on clang 3.4 and older.
 299     # This also catches cases when -Wnon-virtual-dtor isn't supported by
 300     # the compiler at all.
 301     set(OLD_CMAKE_REQUIRED_FLAGS ${CMAKE_REQUIRED_FLAGS})
 302     set(CMAKE_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS} -std=c++11 -Werror=non-virtual-dtor")
 303     CHECK_CXX_SOURCE_COMPILES("class base {public: virtual void anchor();protected: ~base();};
 304                                class derived final : public base { public: ~derived();};
 305                                int main() { return 0; }"
 306                               CXX_WONT_WARN_ON_FINAL_NONVIRTUALDTOR)
 307     set(CMAKE_REQUIRED_FLAGS ${OLD_CMAKE_REQUIRED_FLAGS})
 308     append_if(CXX_WONT_WARN_ON_FINAL_NONVIRTUALDTOR
 309               "-Wnon-virtual-dtor" CMAKE_CXX_FLAGS)
 310
 311     # Check if -Wcomment is OK with an // comment ending with '\' if the next
 312     # line is also a // comment.
 313     set(OLD_CMAKE_REQUIRED_FLAGS ${CMAKE_REQUIRED_FLAGS})
 314     set(CMAKE_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS} -Werror -Wcomment")
 315     CHECK_C_SOURCE_COMPILES("// \\\\\\n//\\nint main() {return 0;}"
 316                             C_WCOMMENT_ALLOWS_LINE_WRAP)
 317     set(CMAKE_REQUIRED_FLAGS ${OLD_CMAKE_REQUIRED_FLAGS})
 318     if (NOT C_WCOMMENT_ALLOWS_LINE_WRAP)
 319       append("-Wno-comment" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 320     endif()
 321   endif (LLVM_ENABLE_WARNINGS)
 322   append_if(LLVM_ENABLE_WERROR "-Werror" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 323   if (NOT LLVM_ENABLE_TIMESTAMPS)
 324     add_flag_if_supported("-Werror=date-time" WERROR_DATE_TIME)
 325   endif ()
 326   if (LLVM_ENABLE_CXX1Y)
 327     check_cxx_compiler_flag("-std=c++1y" CXX_SUPPORTS_CXX1Y)
 328     append_if(CXX_SUPPORTS_CXX1Y "-std=c++1y" CMAKE_CXX_FLAGS)
 329   else()
 330     check_cxx_compiler_flag("-std=c++11" CXX_SUPPORTS_CXX11)
 331     if (CXX_SUPPORTS_CXX11)
 332       if (CYGWIN OR MINGW)
 333         # MinGW and Cygwin are a bit stricter and lack things like
 334         # 'strdup', 'stricmp', etc in c++11 mode.
 335         append("-std=gnu++11" CMAKE_CXX_FLAGS)
 336       else()
 337         append("-std=c++11" CMAKE_CXX_FLAGS)
 338       endif()
 339     else()
 340       message(FATAL_ERROR "LLVM requires C++11 support but the '-std=c++11' flag isn't supported.")
 341     endif()
 342   endif()
 343   if (LLVM_ENABLE_MODULES)
 344     set(OLD_CMAKE_REQUIRED_FLAGS ${CMAKE_REQUIRED_FLAGS})
 345     set(CMAKE_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS} -fmodules -fcxx-modules")
 346     # Check that we can build code with modules enabled, and that repeatedly
 347     # including <cassert> still manages to respect NDEBUG properly.
 348     CHECK_CXX_SOURCE_COMPILES("#undef NDEBUG
 349                                #include <cassert>
 350                                #define NDEBUG
 351                                #include <cassert>
 352                                int main() { assert(this code is not compiled); }"
 353                                CXX_SUPPORTS_MODULES)
 354     set(CMAKE_REQUIRED_FLAGS ${OLD_CMAKE_REQUIRED_FLAGS})
 355     if (CXX_SUPPORTS_MODULES)
 356       append_if(CXX_SUPPORTS_MODULES "-fmodules" CMAKE_C_FLAGS)
 357       append_if(CXX_SUPPORTS_MODULES "-fmodules -fcxx-modules" CMAKE_CXX_FLAGS)
 358     else()
 359       message(FATAL_ERROR "LLVM_ENABLE_MODULES is not supported by this compiler")
 360     endif()
 361   endif(LLVM_ENABLE_MODULES)
 362 endif( MSVC )
 363
 364 macro(append_common_sanitizer_flags)
 365   # Append -fno-omit-frame-pointer and turn on debug info to get better
 366   # stack traces.
 367   add_flag_if_supported("-fno-omit-frame-pointer" FNO_OMIT_FRAME_POINTER)
 368   if (NOT uppercase_CMAKE_BUILD_TYPE STREQUAL "DEBUG" AND
 369       NOT uppercase_CMAKE_BUILD_TYPE STREQUAL "RELWITHDEBINFO")
 370     add_flag_if_supported("-gline-tables-only" GLINE_TABLES_ONLY)
 371   endif()
 372   # Use -O1 even in debug mode, otherwise sanitizers slowdown is too large.
 373   if (uppercase_CMAKE_BUILD_TYPE STREQUAL "DEBUG")
 374     add_flag_if_supported("-O1" O1)
 375   endif()
 376 endmacro()
 377
 378 # Turn on sanitizers if necessary.
 379 if(LLVM_USE_SANITIZER)
 380   if (LLVM_ON_UNIX)
 381     if (LLVM_USE_SANITIZER STREQUAL "Address")
 382       append_common_sanitizer_flags()
 383       append("-fsanitize=address" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 384     elseif (LLVM_USE_SANITIZER MATCHES "Memory(WithOrigins)?")
 385       append_common_sanitizer_flags()
 386       append("-fsanitize=memory" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 387       if(LLVM_USE_SANITIZER STREQUAL "MemoryWithOrigins")
 388         append("-fsanitize-memory-track-origins" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 389       endif()
 390     elseif (LLVM_USE_SANITIZER STREQUAL "Undefined")
 391       append_common_sanitizer_flags()
 392       append("-fsanitize=undefined -fno-sanitize=vptr,function -fno-sanitize-recover"
 393               CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 394     else()
 395       message(WARNING "Unsupported value of LLVM_USE_SANITIZER: ${LLVM_USE_SANITIZER}")
 396     endif()
 397   else()
 398     message(WARNING "LLVM_USE_SANITIZER is not supported on this platform.")
 399   endif()
 400 endif()
 401
 402 # Turn on -gsplit-dwarf if requested
 403 if(LLVM_USE_SPLIT_DWARF)
 404   add_definitions("-gsplit-dwarf")
 405 endif()
 406
 407 add_llvm_definitions( -D__STDC_CONSTANT_MACROS )
 408 add_llvm_definitions( -D__STDC_FORMAT_MACROS )
 409 add_llvm_definitions( -D__STDC_LIMIT_MACROS )
 410
 411 # clang doesn't print colored diagnostics when invoked from Ninja
 412 if (UNIX AND
 413     CMAKE_CXX_COMPILER_ID STREQUAL "Clang" AND
 414     CMAKE_GENERATOR STREQUAL "Ninja")
 415   append("-fcolor-diagnostics" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 416 endif()
 417
 418 # Add flags for add_dead_strip().
 419 # FIXME: With MSVS, consider compiling with /Gy and linking with /OPT:REF?
 420 # But MinSizeRel seems to add that automatically, so maybe disable these
 421 # flags instead if LLVM_NO_DEAD_STRIP is set.
 422 if(NOT CYGWIN AND NOT WIN32)
 423   if(NOT ${CMAKE_SYSTEM_NAME} MATCHES "Darwin")
 424     check_c_compiler_flag("-Werror -fno-function-sections" C_SUPPORTS_FNO_FUNCTION_SECTIONS)
 425     if (C_SUPPORTS_FNO_FUNCTION_SECTIONS)
 426       # Don't add -ffunction-section if it can be disabled with -fno-function-sections.
 427       # Doing so will break sanitizers.
 428       add_flag_if_supported("-ffunction-sections" FFUNCTION_SECTIONS)
 429     endif()
 430     add_flag_if_supported("-fdata-sections" FDATA_SECTIONS)
 431   endif()
 432 endif()
 433
 434 if(CYGWIN OR MINGW)
 435   # Prune --out-implib from executables. It doesn't make sense even
 436   # with --export-all-symbols.
 437   string(REGEX REPLACE "-Wl,--out-implib,[^ ]+ " " "
 438     CMAKE_C_LINK_EXECUTABLE "${CMAKE_C_LINK_EXECUTABLE}")
 439   string(REGEX REPLACE "-Wl,--out-implib,[^ ]+ " " "
 440     CMAKE_CXX_LINK_EXECUTABLE "${CMAKE_CXX_LINK_EXECUTABLE}")
 441 endif()
 442
 443 if(MSVC)
 444   # Remove flags here, for exceptions and RTTI.
 445   # Each target property or source property should be responsible to control
 446   # them.
 447   # CL.EXE complains to override flags like "/GR /GR-".
 448   string(REGEX REPLACE "(^| ) */EH[-cs]+ *( |$)" "\\1 \\2" CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS}")
 449   string(REGEX REPLACE "(^| ) */GR-? *( |$)" "\\1 \\2" CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS}")
 450 endif()
 451
 452 # Provide public options to globally control RTTI and EH
 453 option(LLVM_ENABLE_EH "Enable Exception handling" OFF)
 454 option(LLVM_ENABLE_RTTI "Enable run time type information" OFF)
 455 if(LLVM_ENABLE_EH AND NOT LLVM_ENABLE_RTTI)
 456   message(FATAL_ERROR "Exception handling requires RTTI. You must set LLVM_ENABLE_RTTI to ON")
 457 endif()
 458
 459 # Plugin support
 460 # FIXME: Make this configurable.
 461 if(WIN32 OR CYGWIN)
 462   if(BUILD_SHARED_LIBS)
 463     set(LLVM_ENABLE_PLUGINS ON)
 464   else()
 465     set(LLVM_ENABLE_PLUGINS OFF)
 466   endif()
 467 else()
 468   set(LLVM_ENABLE_PLUGINS ON)
 469 endif()