cmake/modules/CMakeLists.txt

   1 set(LLVM_INSTALL_PACKAGE_DIR share/llvm/cmake)
   2 set(llvm_cmake_builddir "${LLVM_BINARY_DIR}/${LLVM_INSTALL_PACKAGE_DIR}")
   3
   4 get_property(llvm_libs GLOBAL PROPERTY LLVM_LIBS)
   5
   6 foreach(lib ${llvm_libs})
   7   get_property(llvm_lib_deps GLOBAL PROPERTY LLVMBUILD_LIB_DEPS_${lib})
   8   set(all_llvm_lib_deps
   9     "${all_llvm_lib_deps}\nset_property(GLOBAL PROPERTY LLVMBUILD_LIB_DEPS_${lib} ${llvm_lib_deps})")
  10 endforeach(lib)
  11
  12 # Generate LLVMConfig.cmake for the build tree.
  13 set(LLVM_CONFIG_CODE "
  14 # LLVM_BUILD_* values available only from LLVM build tree.
  15 set(LLVM_BUILD_BINARY_DIR \"${LLVM_BINARY_DIR}\")
  16 set(LLVM_BUILD_ENABLE_ASSERTIONS \"${LLVM_ENABLE_ASSERTIONS}\")
  17 set(LLVM_BUILD_LIBRARY_DIR \"${LLVM_LIBRARY_DIR}\")
  18 set(LLVM_BUILD_MAIN_INCLUDE_DIR \"${LLVM_MAIN_INCLUDE_DIR}\")
  19 set(LLVM_BUILD_MAIN_SRC_DIR \"${LLVM_MAIN_SRC_DIR}\")
  20 set(LLVM_BUILD_TOOLS_BINARY_DIR \"${LLVM_TOOLS_BINARY_DIR}\")
  21 ")
  22 set(LLVM_CONFIG_INCLUDE_DIRS
  23   "${LLVM_MAIN_INCLUDE_DIR}"
  24   "${LLVM_INCLUDE_DIR}"
  25   )
  26 set(LLVM_CONFIG_LIBRARY_DIRS
  27   "${LLVM_LIBRARY_DIR}"
  28   )
  29 set(LLVM_CONFIG_CMAKE_DIR "${CMAKE_CURRENT_SOURCE_DIR}")
  30 configure_file(
  31   LLVMConfig.cmake.in
  32   ${llvm_cmake_builddir}/LLVMConfig.cmake
  33   @ONLY)
  34
  35 # For compatibility with projects that include(LLVMConfig)
  36 # via CMAKE_MODULE_PATH, place API modules next to it.
  37 # This should be removed in the future.
  38 file(COPY .
  39   DESTINATION ${llvm_cmake_builddir}
  40   FILES_MATCHING PATTERN *.cmake
  41   PATTERN .svn EXCLUDE
  42   PATTERN CMakeFiles EXCLUDE
  43   )
  44
  45 # Generate LLVMConfig.cmake for the install tree.
  46 set(LLVM_CONFIG_CODE "
  47 # Compute the installation prefix from this LLVMConfig.cmake file location.
  48 get_filename_component(LLVM_INSTALL_PREFIX \"\${CMAKE_CURRENT_LIST_FILE}\" PATH)")
  49 # Construct the proper number of get_filename_component(... PATH)
  50 # calls to compute the installation prefix.
  51 string(REGEX REPLACE "/" ";" _count "${LLVM_INSTALL_PACKAGE_DIR}")
  52 foreach(p ${_count})
  53   set(LLVM_CONFIG_CODE "${LLVM_CONFIG_CODE}
  54 get_filename_component(LLVM_INSTALL_PREFIX \"\${LLVM_INSTALL_PREFIX}\" PATH)")
  55 endforeach(p)
  56 set(LLVM_CONFIG_INCLUDE_DIRS "\${LLVM_INSTALL_PREFIX}/include")
  57 set(LLVM_CONFIG_LIBRARY_DIRS "\${LLVM_INSTALL_PREFIX}/lib")
  58 set(LLVM_CONFIG_CMAKE_DIR "\${LLVM_INSTALL_PREFIX}/${LLVM_INSTALL_PACKAGE_DIR}")
  59 configure_file(
  60   LLVMConfig.cmake.in
  61   ${CMAKE_CURRENT_BINARY_DIR}/CMakeFiles/LLVMConfig.cmake
  62   @ONLY)
  63
  64 # Generate LLVMConfigVersion.cmake for build and install tree.
  65 configure_file(
  66   LLVMConfigVersion.cmake.in
  67   ${llvm_cmake_builddir}/LLVMConfigVersion.cmake
  68   @ONLY)
  69
  70 install(EXPORT LLVMExports DESTINATION ${LLVM_INSTALL_PACKAGE_DIR})
  71
  72 if (NOT LLVM_INSTALL_TOOLCHAIN_ONLY)
  73   install(FILES
  74     ${CMAKE_CURRENT_BINARY_DIR}/CMakeFiles/LLVMConfig.cmake
  75     ${llvm_cmake_builddir}/LLVMConfigVersion.cmake
  76     LLVM-Config.cmake
  77     DESTINATION ${LLVM_INSTALL_PACKAGE_DIR})
  78
  79   install(DIRECTORY .
  80     DESTINATION ${LLVM_INSTALL_PACKAGE_DIR}
  81     FILES_MATCHING PATTERN *.cmake
  82     PATTERN .svn EXCLUDE
  83     PATTERN LLVMConfig.cmake EXCLUDE
  84     PATTERN LLVMConfigVersion.cmake EXCLUDE
  85     PATTERN LLVM-Config.cmake EXCLUDE
  86     PATTERN GetHostTriple.cmake EXCLUDE
  87     PATTERN VersionFromVCS.cmake EXCLUDE
  88     PATTERN CheckAtomic.cmake EXCLUDE)
  89 endif()