cmake/modules/AddLLVM.cmake

   1 include(LLVMParseArguments)
   2 include(LLVMProcessSources)
   3 include(LLVM-Config)
   4
   5 function(llvm_update_compile_flags name)
   6   get_property(sources TARGET ${name} PROPERTY SOURCES)
   7   if("${sources}" MATCHES "\\.c(;|$)")
   8     set(update_src_props ON)
   9   endif()
  10
  11   # LLVM_REQUIRES_EH is an internal flag that individual
  12   # targets can use to force EH
  13   if(LLVM_REQUIRES_EH OR LLVM_ENABLE_EH)
  14     if(NOT (LLVM_REQUIRES_RTTI OR LLVM_ENABLE_RTTI))
  15       message(AUTHOR_WARNING "Exception handling requires RTTI. Enabling RTTI for ${name}")
  16       set(LLVM_REQUIRES_RTTI ON)
  17     endif()
  18   else()
  19     if(LLVM_COMPILER_IS_GCC_COMPATIBLE)
  20       list(APPEND LLVM_COMPILE_FLAGS "-fno-exceptions")
  21     elseif(MSVC)
  22       list(APPEND LLVM_COMPILE_DEFINITIONS _HAS_EXCEPTIONS=0)
  23       list(APPEND LLVM_COMPILE_FLAGS "/EHs-c-")
  24     endif()
  25   endif()
  26
  27   # LLVM_REQUIRES_RTTI is an internal flag that individual
  28   # targets can use to force RTTI
  29   if(NOT (LLVM_REQUIRES_RTTI OR LLVM_ENABLE_RTTI))
  30     list(APPEND LLVM_COMPILE_DEFINITIONS GTEST_HAS_RTTI=0)
  31     if (LLVM_COMPILER_IS_GCC_COMPATIBLE)
  32       list(APPEND LLVM_COMPILE_FLAGS "-fno-rtti")
  33     elseif (MSVC)
  34       list(APPEND LLVM_COMPILE_FLAGS "/GR-")
  35     endif ()
  36   endif()
  37
  38   # Assume that;
  39   #   - LLVM_COMPILE_FLAGS is list.
  40   #   - PROPERTY COMPILE_FLAGS is string.
  41   string(REPLACE ";" " " target_compile_flags "${LLVM_COMPILE_FLAGS}")
  42
  43   if(update_src_props)
  44     foreach(fn ${sources})
  45       get_filename_component(suf ${fn} EXT)
  46       if("${suf}" STREQUAL ".cpp")
  47         set_property(SOURCE ${fn} APPEND_STRING PROPERTY
  48           COMPILE_FLAGS "${target_compile_flags}")
  49       endif()
  50     endforeach()
  51   else()
  52     # Update target props, since all sources are C++.
  53     set_property(TARGET ${name} APPEND_STRING PROPERTY
  54       COMPILE_FLAGS "${target_compile_flags}")
  55   endif()
  56
  57   set_property(TARGET ${name} APPEND PROPERTY COMPILE_DEFINITIONS ${LLVM_COMPILE_DEFINITIONS})
  58 endfunction()
  59
  60 function(add_llvm_symbol_exports target_name export_file)
  61   if(${CMAKE_SYSTEM_NAME} MATCHES "Darwin")
  62     set(native_export_file "${target_name}.exports")
  63     add_custom_command(OUTPUT ${native_export_file}
  64       COMMAND sed -e "s/^/_/" < ${export_file} > ${native_export_file}
  65       DEPENDS ${export_file}
  66       VERBATIM
  67       COMMENT "Creating export file for ${target_name}")
  68     set_property(TARGET ${target_name} APPEND_STRING PROPERTY
  69                  LINK_FLAGS " -Wl,-exported_symbols_list,${CMAKE_CURRENT_BINARY_DIR}/${native_export_file}")
  70   elseif(LLVM_HAVE_LINK_VERSION_SCRIPT)
  71     # Gold and BFD ld require a version script rather than a plain list.
  72     set(native_export_file "${target_name}.exports")
  73     # FIXME: Don't write the "local:" line on OpenBSD.
  74     add_custom_command(OUTPUT ${native_export_file}
  75       COMMAND echo "{" > ${native_export_file}
  76       COMMAND grep -q "[[:alnum:]]" ${export_file} && echo "  global:" >> ${native_export_file} || :
  77       COMMAND sed -e "s/$/;/" -e "s/^/    /" < ${export_file} >> ${native_export_file}
  78       COMMAND echo "  local: *;" >> ${native_export_file}
  79       COMMAND echo "};" >> ${native_export_file}
  80       DEPENDS ${export_file}
  81       VERBATIM
  82       COMMENT "Creating export file for ${target_name}")
  83     set_property(TARGET ${target_name} APPEND_STRING PROPERTY
  84                  LINK_FLAGS "  -Wl,--version-script,${CMAKE_CURRENT_BINARY_DIR}/${native_export_file}")
  85   else()
  86     set(native_export_file "${target_name}.def")
  87
  88     set(CAT "cat")
  89     set(export_file_nativeslashes ${export_file})
  90     if(WIN32 AND NOT CYGWIN)
  91       set(CAT "type")
  92       # Convert ${export_file} to native format (backslashes) for "type"
  93       # Does not use file(TO_NATIVE_PATH) as it doesn't create a native
  94       # path but a build-system specific format (see CMake bug
  95       # http://public.kitware.com/Bug/print_bug_page.php?bug_id=5939 )
  96       string(REPLACE / \\ export_file_nativeslashes ${export_file})
  97     endif()
  98
  99     add_custom_command(OUTPUT ${native_export_file}
 100       COMMAND ${CMAKE_COMMAND} -E echo "EXPORTS" > ${native_export_file}
 101       COMMAND ${CAT} ${export_file_nativeslashes} >> ${native_export_file}
 102       DEPENDS ${export_file}
 103       VERBATIM
 104       COMMENT "Creating export file for ${target_name}")
 105     set(export_file_linker_flag "${CMAKE_CURRENT_BINARY_DIR}/${native_export_file}")
 106     if(MSVC)
 107       set(export_file_linker_flag "/DEF:${export_file_linker_flag}")
 108     endif()
 109     set_property(TARGET ${target_name} APPEND_STRING PROPERTY
 110                  LINK_FLAGS " ${export_file_linker_flag}")
 111   endif()
 112
 113   add_custom_target(${target_name}_exports DEPENDS ${native_export_file})
 114   set_target_properties(${target_name}_exports PROPERTIES FOLDER "Misc")
 115
 116   get_property(srcs TARGET ${target_name} PROPERTY SOURCES)
 117   foreach(src ${srcs})
 118     get_filename_component(extension ${src} EXT)
 119     if(extension STREQUAL ".cpp")
 120       set(first_source_file ${src})
 121       break()
 122     endif()
 123   endforeach()
 124
 125   # Force re-linking when the exports file changes. Actually, it
 126   # forces recompilation of the source file. The LINK_DEPENDS target
 127   # property only works for makefile-based generators.
 128   # FIXME: This is not safe because this will create the same target
 129   # ${native_export_file} in several different file:
 130   # - One where we emitted ${target_name}_exports
 131   # - One where we emitted the build command for the following object.
 132   # set_property(SOURCE ${first_source_file} APPEND PROPERTY
 133   #   OBJECT_DEPENDS ${CMAKE_CURRENT_BINARY_DIR}/${native_export_file})
 134
 135   set_property(DIRECTORY APPEND
 136     PROPERTY ADDITIONAL_MAKE_CLEAN_FILES ${native_export_file})
 137
 138   add_dependencies(${target_name} ${target_name}_exports)
 139
 140   # Add dependency to *_exports later -- CMake issue 14747
 141   list(APPEND LLVM_COMMON_DEPENDS ${target_name}_exports)
 142   set(LLVM_COMMON_DEPENDS ${LLVM_COMMON_DEPENDS} PARENT_SCOPE)
 143 endfunction(add_llvm_symbol_exports)
 144
 145 if(NOT WIN32 AND NOT APPLE)
 146   execute_process(
 147     COMMAND ${CMAKE_C_COMPILER} -Wl,--version
 148     OUTPUT_VARIABLE stdout
 149     )
 150   if("${stdout}" MATCHES "GNU gold")
 151     set(LLVM_LINKER_IS_GOLD ON)
 152   endif()
 153 endif()
 154
 155 function(add_link_opts target_name)
 156   # Pass -O3 to the linker. This enabled different optimizations on different
 157   # linkers.
 158   if(NOT (${CMAKE_SYSTEM_NAME} MATCHES "Darwin" OR WIN32))
 159     set_property(TARGET ${target_name} APPEND_STRING PROPERTY
 160                  LINK_FLAGS " -Wl,-O3")
 161   endif()
 162
 163   if(LLVM_LINKER_IS_GOLD)
 164     # With gold gc-sections is always safe.
 165     set_property(TARGET ${target_name} APPEND_STRING PROPERTY
 166                  LINK_FLAGS " -Wl,--gc-sections")
 167     # Note that there is a bug with -Wl,--icf=safe so it is not safe
 168     # to enable. See https://sourceware.org/bugzilla/show_bug.cgi?id=17704.
 169   endif()
 170
 171   if(NOT LLVM_NO_DEAD_STRIP)
 172     if(${CMAKE_SYSTEM_NAME} MATCHES "Darwin")
 173       # ld64's implementation of -dead_strip breaks tools that use plugins.
 174       set_property(TARGET ${target_name} APPEND_STRING PROPERTY
 175                    LINK_FLAGS " -Wl,-dead_strip")
 176     elseif(NOT WIN32 AND NOT LLVM_LINKER_IS_GOLD)
 177       # Object files are compiled with -ffunction-data-sections.
 178       # Versions of bfd ld < 2.23.1 have a bug in --gc-sections that breaks
 179       # tools that use plugins. Always pass --gc-sections once we require
 180       # a newer linker.
 181       set_property(TARGET ${target_name} APPEND_STRING PROPERTY
 182                    LINK_FLAGS " -Wl,--gc-sections")
 183     endif()
 184   endif()
 185 endfunction(add_link_opts)
 186
 187 # Set each output directory according to ${CMAKE_CONFIGURATION_TYPES}.
 188 # Note: Don't set variables CMAKE_*_OUTPUT_DIRECTORY any more,
 189 # or a certain builder, for eaxample, msbuild.exe, would be confused.
 190 function(set_output_directory target bindir libdir)
 191   # Do nothing if *_OUTPUT_INTDIR is empty.
 192   if("${bindir}" STREQUAL "")
 193     return()
 194   endif()
 195
 196   # moddir -- corresponding to LIBRARY_OUTPUT_DIRECTORY.
 197   # It affects output of add_library(MODULE).
 198   if(WIN32 OR CYGWIN)
 199     # DLL platform
 200     set(moddir ${bindir})
 201   else()
 202     set(moddir ${libdir})
 203   endif()
 204   if(NOT "${CMAKE_CFG_INTDIR}" STREQUAL ".")
 205     foreach(build_mode ${CMAKE_CONFIGURATION_TYPES})
 206       string(TOUPPER "${build_mode}" CONFIG_SUFFIX)
 207       string(REPLACE ${CMAKE_CFG_INTDIR} ${build_mode} bi ${bindir})
 208       string(REPLACE ${CMAKE_CFG_INTDIR} ${build_mode} li ${libdir})
 209       string(REPLACE ${CMAKE_CFG_INTDIR} ${build_mode} mi ${moddir})
 210       set_target_properties(${target} PROPERTIES "RUNTIME_OUTPUT_DIRECTORY_${CONFIG_SUFFIX}" ${bi})
 211       set_target_properties(${target} PROPERTIES "ARCHIVE_OUTPUT_DIRECTORY_${CONFIG_SUFFIX}" ${li})
 212       set_target_properties(${target} PROPERTIES "LIBRARY_OUTPUT_DIRECTORY_${CONFIG_SUFFIX}" ${mi})
 213     endforeach()
 214   else()
 215     set_target_properties(${target} PROPERTIES RUNTIME_OUTPUT_DIRECTORY ${bindir})
 216     set_target_properties(${target} PROPERTIES ARCHIVE_OUTPUT_DIRECTORY ${libdir})
 217     set_target_properties(${target} PROPERTIES LIBRARY_OUTPUT_DIRECTORY ${moddir})
 218   endif()
 219 endfunction()
 220
 221 # llvm_add_library(name sources...
 222 #   SHARED;STATIC
 223 #     STATIC by default w/o BUILD_SHARED_LIBS.
 224 #     SHARED by default w/  BUILD_SHARED_LIBS.
 225 #   MODULE
 226 #     Target ${name} might not be created on unsupported platforms.
 227 #     Check with "if(TARGET ${name})".
 228 #   OUTPUT_NAME name
 229 #     Corresponds to OUTPUT_NAME in target properties.
 230 #   DEPENDS targets...
 231 #     Same semantics as add_dependencies().
 232 #   LINK_COMPONENTS components...
 233 #     Same as the variable LLVM_LINK_COMPONENTS.
 234 #   LINK_LIBS lib_targets...
 235 #     Same semantics as target_link_libraries().
 236 #   ADDITIONAL_HEADERS
 237 #     May specify header files for IDE generators.
 238 #   )
 239 function(llvm_add_library name)
 240   cmake_parse_arguments(ARG
 241     "MODULE;SHARED;STATIC"
 242     "OUTPUT_NAME"
 243     "ADDITIONAL_HEADERS;DEPENDS;LINK_COMPONENTS;LINK_LIBS;OBJLIBS"
 244     ${ARGN})
 245   list(APPEND LLVM_COMMON_DEPENDS ${ARG_DEPENDS})
 246   if(ARG_ADDITIONAL_HEADERS)
 247     # Pass through ADDITIONAL_HEADERS.
 248     set(ARG_ADDITIONAL_HEADERS ADDITIONAL_HEADERS ${ARG_ADDITIONAL_HEADERS})
 249   endif()
 250   if(ARG_OBJLIBS)
 251     set(ALL_FILES ${ARG_OBJLIBS})
 252   else()
 253     llvm_process_sources(ALL_FILES ${ARG_UNPARSED_ARGUMENTS} ${ARG_ADDITIONAL_HEADERS})
 254   endif()
 255
 256   if(ARG_MODULE)
 257     if(ARG_SHARED OR ARG_STATIC)
 258       message(WARNING "MODULE with SHARED|STATIC doesn't make sense.")
 259     endif()
 260     if(NOT LLVM_ENABLE_PLUGINS)
 261       message(STATUS "${name} ignored -- Loadable modules not supported on this platform.")
 262       return()
 263     endif()
 264   else()
 265     if(BUILD_SHARED_LIBS AND NOT ARG_STATIC)
 266       set(ARG_SHARED TRUE)
 267     endif()
 268     if(NOT ARG_SHARED)
 269       set(ARG_STATIC TRUE)
 270     endif()
 271   endif()
 272
 273   # Generate objlib
 274   if(ARG_SHARED AND ARG_STATIC)
 275     # Generate an obj library for both targets.
 276     set(obj_name "obj.${name}")
 277     add_library(${obj_name} OBJECT EXCLUDE_FROM_ALL
 278       ${ALL_FILES}
 279       )
 280     llvm_update_compile_flags(${obj_name})
 281     set(ALL_FILES "$<TARGET_OBJECTS:${obj_name}>")
 282
 283     # Do add_dependencies(obj) later due to CMake issue 14747.
 284     list(APPEND objlibs ${obj_name})
 285
 286     set_target_properties(${obj_name} PROPERTIES FOLDER "Object Libraries")
 287   endif()
 288
 289   if(ARG_SHARED AND ARG_STATIC)
 290     # static
 291     set(name_static "${name}_static")
 292     if(ARG_OUTPUT_NAME)
 293       set(output_name OUTPUT_NAME "${ARG_OUTPUT_NAME}")
 294     endif()
 295     # DEPENDS has been appended to LLVM_COMMON_LIBS.
 296     llvm_add_library(${name_static} STATIC
 297       ${output_name}
 298       OBJLIBS ${ALL_FILES} # objlib
 299       LINK_LIBS ${ARG_LINK_LIBS}
 300       LINK_COMPONENTS ${ARG_LINK_COMPONENTS}
 301       )
 302     # FIXME: Add name_static to anywhere in TARGET ${name}'s PROPERTY.
 303     set(ARG_STATIC)
 304   endif()
 305
 306   if(ARG_MODULE)
 307     add_library(${name} MODULE ${ALL_FILES})
 308   elseif(ARG_SHARED)
 309     add_library(${name} SHARED ${ALL_FILES})
 310   else()
 311     add_library(${name} STATIC ${ALL_FILES})
 312   endif()
 313   set_output_directory(${name} ${LLVM_RUNTIME_OUTPUT_INTDIR} ${LLVM_LIBRARY_OUTPUT_INTDIR})
 314   llvm_update_compile_flags(${name})
 315   add_link_opts( ${name} )
 316   if(ARG_OUTPUT_NAME)
 317     set_target_properties(${name}
 318       PROPERTIES
 319       OUTPUT_NAME ${ARG_OUTPUT_NAME}
 320       )
 321   endif()
 322
 323   if(ARG_MODULE)
 324     set_target_properties(${name} PROPERTIES
 325       PREFIX ""
 326       SUFFIX ${LLVM_PLUGIN_EXT}
 327       )
 328   endif()
 329
 330   if(ARG_SHARED)
 331     if(WIN32)
 332       set_target_properties(${name} PROPERTIES
 333         PREFIX ""
 334         )
 335     endif()
 336     if (MSVC)
 337       set_target_properties(${name}
 338         PROPERTIES
 339         IMPORT_SUFFIX ".imp")
 340     endif ()
 341   endif()
 342
 343   if(ARG_MODULE OR ARG_SHARED)
 344     # Do not add -Dname_EXPORTS to the command-line when building files in this
 345     # target. Doing so is actively harmful for the modules build because it
 346     # creates extra module variants, and not useful because we don't use these
 347     # macros.
 348     set_target_properties( ${name} PROPERTIES DEFINE_SYMBOL "" )
 349
 350     if (LLVM_EXPORTED_SYMBOL_FILE)
 351       add_llvm_symbol_exports( ${name} ${LLVM_EXPORTED_SYMBOL_FILE} )
 352     endif()
 353   endif()
 354
 355   # Add the explicit dependency information for this library.
 356   #
 357   # It would be nice to verify that we have the dependencies for this library
 358   # name, but using get_property(... SET) doesn't suffice to determine if a
 359   # property has been set to an empty value.
 360   get_property(lib_deps GLOBAL PROPERTY LLVMBUILD_LIB_DEPS_${name})
 361
 362   llvm_map_components_to_libnames(llvm_libs
 363     ${ARG_LINK_COMPONENTS}
 364     ${LLVM_LINK_COMPONENTS}
 365     )
 366
 367   if(CMAKE_VERSION VERSION_LESS 2.8.12)
 368     # Link libs w/o keywords, assuming PUBLIC.
 369     target_link_libraries(${name}
 370       ${ARG_LINK_LIBS}
 371       ${lib_deps}
 372       ${llvm_libs}
 373       )
 374   elseif(ARG_STATIC)
 375     target_link_libraries(${name} INTERFACE
 376       ${ARG_LINK_LIBS}
 377       ${lib_deps}
 378       ${llvm_libs}
 379       )
 380   else()
 381     # We can use PRIVATE since SO knows its dependent libs.
 382     target_link_libraries(${name} PRIVATE
 383       ${ARG_LINK_LIBS}
 384       ${lib_deps}
 385       ${llvm_libs}
 386       )
 387   endif()
 388
 389   if(LLVM_COMMON_DEPENDS)
 390     add_dependencies(${name} ${LLVM_COMMON_DEPENDS})
 391     # Add dependencies also to objlibs.
 392     # CMake issue 14747 --  add_dependencies() might be ignored to objlib's user.
 393     foreach(objlib ${objlibs})
 394       add_dependencies(${objlib} ${LLVM_COMMON_DEPENDS})
 395     endforeach()
 396   endif()
 397 endfunction()
 398
 399 macro(add_llvm_library name)
 400   if( BUILD_SHARED_LIBS )
 401     llvm_add_library(${name} SHARED ${ARGN})
 402   else()
 403     llvm_add_library(${name} ${ARGN})
 404   endif()
 405   set_property( GLOBAL APPEND PROPERTY LLVM_LIBS ${name} )
 406
 407   if( EXCLUDE_FROM_ALL )
 408     set_target_properties( ${name} PROPERTIES EXCLUDE_FROM_ALL ON)
 409   else()
 410     if (NOT LLVM_INSTALL_TOOLCHAIN_ONLY OR ${name} STREQUAL "LTO")
 411       install(TARGETS ${name}
 412         EXPORT LLVMExports
 413         RUNTIME DESTINATION bin
 414         LIBRARY DESTINATION lib${LLVM_LIBDIR_SUFFIX}
 415         ARCHIVE DESTINATION lib${LLVM_LIBDIR_SUFFIX})
 416     endif()
 417     set_property(GLOBAL APPEND PROPERTY LLVM_EXPORTS ${name})
 418   endif()
 419   set_target_properties(${name} PROPERTIES FOLDER "Libraries")
 420 endmacro(add_llvm_library name)
 421
 422 macro(add_llvm_loadable_module name)
 423   llvm_add_library(${name} MODULE ${ARGN})
 424   if(NOT TARGET ${name})
 425     # Add empty "phony" target
 426     add_custom_target(${name})
 427   else()
 428     if( EXCLUDE_FROM_ALL )
 429       set_target_properties( ${name} PROPERTIES EXCLUDE_FROM_ALL ON)
 430     else()
 431       if (NOT LLVM_INSTALL_TOOLCHAIN_ONLY)
 432         if(WIN32 OR CYGWIN)
 433           # DLL platform
 434           set(dlldir "bin")
 435         else()
 436           set(dlldir "lib${LLVM_LIBDIR_SUFFIX}")
 437         endif()
 438         install(TARGETS ${name}
 439           EXPORT LLVMExports
 440           LIBRARY DESTINATION ${dlldir}
 441           ARCHIVE DESTINATION lib${LLVM_LIBDIR_SUFFIX})
 442       endif()
 443       set_property(GLOBAL APPEND PROPERTY LLVM_EXPORTS ${name})
 444     endif()
 445   endif()
 446
 447   set_target_properties(${name} PROPERTIES FOLDER "Loadable modules")
 448 endmacro(add_llvm_loadable_module name)
 449
 450
 451 macro(add_llvm_executable name)
 452   llvm_process_sources( ALL_FILES ${ARGN} )
 453   if( EXCLUDE_FROM_ALL )
 454     add_executable(${name} EXCLUDE_FROM_ALL ${ALL_FILES})
 455   else()
 456     add_executable(${name} ${ALL_FILES})
 457   endif()
 458   llvm_update_compile_flags(${name})
 459   add_link_opts( ${name} )
 460
 461   # Do not add -Dname_EXPORTS to the command-line when building files in this
 462   # target. Doing so is actively harmful for the modules build because it
 463   # creates extra module variants, and not useful because we don't use these
 464   # macros.
 465   set_target_properties( ${name} PROPERTIES DEFINE_SYMBOL "" )
 466
 467   if (LLVM_EXPORTED_SYMBOL_FILE)
 468     add_llvm_symbol_exports( ${name} ${LLVM_EXPORTED_SYMBOL_FILE} )
 469   endif(LLVM_EXPORTED_SYMBOL_FILE)
 470
 471   set(EXCLUDE_FROM_ALL OFF)
 472   set_output_directory(${name} ${LLVM_RUNTIME_OUTPUT_INTDIR} ${LLVM_LIBRARY_OUTPUT_INTDIR})
 473   llvm_config( ${name} ${LLVM_LINK_COMPONENTS} )
 474   if( LLVM_COMMON_DEPENDS )
 475     add_dependencies( ${name} ${LLVM_COMMON_DEPENDS} )
 476   endif( LLVM_COMMON_DEPENDS )
 477 endmacro(add_llvm_executable name)
 478
 479
 480 set (LLVM_TOOLCHAIN_TOOLS
 481   llvm-ar
 482   llvm-objdump
 483   )
 484
 485 macro(add_llvm_tool name)
 486   if( NOT LLVM_BUILD_TOOLS )
 487     set(EXCLUDE_FROM_ALL ON)
 488   endif()
 489   add_llvm_executable(${name} ${ARGN})
 490
 491   list(FIND LLVM_TOOLCHAIN_TOOLS ${name} LLVM_IS_${name}_TOOLCHAIN_TOOL)
 492   if (LLVM_IS_${name}_TOOLCHAIN_TOOL GREATER -1 OR NOT LLVM_INSTALL_TOOLCHAIN_ONLY)
 493     if( LLVM_BUILD_TOOLS )
 494       install(TARGETS ${name}
 495               EXPORT LLVMExports
 496               RUNTIME DESTINATION bin)
 497     endif()
 498   endif()
 499   if( LLVM_BUILD_TOOLS )
 500     set_property(GLOBAL APPEND PROPERTY LLVM_EXPORTS ${name})
 501   endif()
 502   set_target_properties(${name} PROPERTIES FOLDER "Tools")
 503 endmacro(add_llvm_tool name)
 504
 505
 506 macro(add_llvm_example name)
 507   if( NOT LLVM_BUILD_EXAMPLES )
 508     set(EXCLUDE_FROM_ALL ON)
 509   endif()
 510   add_llvm_executable(${name} ${ARGN})
 511   if( LLVM_BUILD_EXAMPLES )
 512     install(TARGETS ${name} RUNTIME DESTINATION examples)
 513   endif()
 514   set_target_properties(${name} PROPERTIES FOLDER "Examples")
 515 endmacro(add_llvm_example name)
 516
 517
 518 macro(add_llvm_utility name)
 519   add_llvm_executable(${name} ${ARGN})
 520   set_target_properties(${name} PROPERTIES FOLDER "Utils")
 521 endmacro(add_llvm_utility name)
 522
 523
 524 macro(add_llvm_target target_name)
 525   include_directories(BEFORE
 526     ${CMAKE_CURRENT_BINARY_DIR}
 527     ${CMAKE_CURRENT_SOURCE_DIR})
 528   add_llvm_library(LLVM${target_name} ${ARGN})
 529   set( CURRENT_LLVM_TARGET LLVM${target_name} )
 530 endmacro(add_llvm_target)
 531
 532 # Add external project that may want to be built as part of llvm such as Clang,
 533 # lld, and Polly. This adds two options. One for the source directory of the
 534 # project, which defaults to ${CMAKE_CURRENT_SOURCE_DIR}/${name}. Another to
 535 # enable or disable building it with everything else.
 536 # Additional parameter can be specified as the name of directory.
 537 macro(add_llvm_external_project name)
 538   set(add_llvm_external_dir "${ARGN}")
 539   if("${add_llvm_external_dir}" STREQUAL "")
 540     set(add_llvm_external_dir ${name})
 541   endif()
 542   list(APPEND LLVM_IMPLICIT_PROJECT_IGNORE "${CMAKE_CURRENT_SOURCE_DIR}/${add_llvm_external_dir}")
 543   string(REPLACE "-" "_" nameUNDERSCORE ${name})
 544   string(TOUPPER ${nameUNDERSCORE} nameUPPER)
 545   set(LLVM_EXTERNAL_${nameUPPER}_SOURCE_DIR "${CMAKE_CURRENT_SOURCE_DIR}/${add_llvm_external_dir}"
 546       CACHE PATH "Path to ${name} source directory")
 547   if (NOT ${LLVM_EXTERNAL_${nameUPPER}_SOURCE_DIR} STREQUAL ""
 548       AND EXISTS ${LLVM_EXTERNAL_${nameUPPER}_SOURCE_DIR}/CMakeLists.txt)
 549     option(LLVM_EXTERNAL_${nameUPPER}_BUILD
 550            "Whether to build ${name} as part of LLVM" ON)
 551     if (LLVM_EXTERNAL_${nameUPPER}_BUILD)
 552       add_subdirectory(${LLVM_EXTERNAL_${nameUPPER}_SOURCE_DIR} ${add_llvm_external_dir})
 553     endif()
 554   endif()
 555 endmacro(add_llvm_external_project)
 556
 557 macro(add_llvm_tool_subdirectory name)
 558   list(APPEND LLVM_IMPLICIT_PROJECT_IGNORE "${CMAKE_CURRENT_SOURCE_DIR}/${name}")
 559   add_subdirectory(${name})
 560 endmacro(add_llvm_tool_subdirectory)
 561
 562 macro(ignore_llvm_tool_subdirectory name)
 563   list(APPEND LLVM_IMPLICIT_PROJECT_IGNORE "${CMAKE_CURRENT_SOURCE_DIR}/${name}")
 564 endmacro(ignore_llvm_tool_subdirectory)
 565
 566 function(add_llvm_implicit_external_projects)
 567   set(list_of_implicit_subdirs "")
 568   file(GLOB sub-dirs "${CMAKE_CURRENT_SOURCE_DIR}/*")
 569   foreach(dir ${sub-dirs})
 570     if(IS_DIRECTORY "${dir}")
 571       list(FIND LLVM_IMPLICIT_PROJECT_IGNORE "${dir}" tool_subdir_ignore)
 572       if( tool_subdir_ignore EQUAL -1
 573           AND EXISTS "${dir}/CMakeLists.txt")
 574         get_filename_component(fn "${dir}" NAME)
 575         list(APPEND list_of_implicit_subdirs "${fn}")
 576       endif()
 577     endif()
 578   endforeach()
 579
 580   foreach(external_proj ${list_of_implicit_subdirs})
 581     add_llvm_external_project("${external_proj}")
 582   endforeach()
 583 endfunction(add_llvm_implicit_external_projects)
 584
 585 # Generic support for adding a unittest.
 586 function(add_unittest test_suite test_name)
 587   if( NOT LLVM_BUILD_TESTS )
 588     set(EXCLUDE_FROM_ALL ON)
 589   endif()
 590
 591   # Visual Studio 2012 only supports up to 8 template parameters in
 592   # std::tr1::tuple by default, but gtest requires 10
 593   if (MSVC AND MSVC_VERSION EQUAL 1700)
 594     list(APPEND LLVM_COMPILE_DEFINITIONS _VARIADIC_MAX=10)
 595   endif ()
 596
 597   include_directories(${LLVM_MAIN_SRC_DIR}/utils/unittest/googletest/include)
 598   if (NOT LLVM_ENABLE_THREADS)
 599     list(APPEND LLVM_COMPILE_DEFINITIONS GTEST_HAS_PTHREAD=0)
 600   endif ()
 601
 602   if (SUPPORTS_NO_VARIADIC_MACROS_FLAG)
 603     list(APPEND LLVM_COMPILE_FLAGS "-Wno-variadic-macros")
 604   endif ()
 605
 606   set(LLVM_REQUIRES_RTTI OFF)
 607
 608   add_llvm_executable(${test_name} ${ARGN})
 609   set(outdir ${CMAKE_CURRENT_BINARY_DIR}/${CMAKE_CFG_INTDIR})
 610   set_output_directory(${test_name} ${outdir} ${outdir})
 611   target_link_libraries(${test_name}
 612     gtest
 613     gtest_main
 614     LLVMSupport # gtest needs it for raw_ostream.
 615     )
 616
 617   add_dependencies(${test_suite} ${test_name})
 618   get_target_property(test_suite_folder ${test_suite} FOLDER)
 619   if (NOT ${test_suite_folder} STREQUAL "NOTFOUND")
 620     set_property(TARGET ${test_name} PROPERTY FOLDER "${test_suite_folder}")
 621   endif ()
 622 endfunction()
 623
 624 function(llvm_add_go_executable binary pkgpath)
 625   cmake_parse_arguments(ARG "ALL" "" "DEPENDS;GOFLAGS" ${ARGN})
 626
 627   if(LLVM_BINDINGS MATCHES "go")
 628     # FIXME: This should depend only on the libraries Go needs.
 629     get_property(llvmlibs GLOBAL PROPERTY LLVM_LIBS)
 630     set(binpath ${CMAKE_BINARY_DIR}/bin/${binary}${CMAKE_EXECUTABLE_SUFFIX})
 631     set(cc "${CMAKE_C_COMPILER} ${CMAKE_C_COMPILER_ARG1}")
 632     set(cxx "${CMAKE_CXX_COMPILER} ${CMAKE_CXX_COMPILER_ARG1}")
 633     set(cppflags "")
 634     get_property(include_dirs DIRECTORY PROPERTY INCLUDE_DIRECTORIES)
 635     foreach(d ${include_dirs})
 636       set(cppflags "${cppflags} -I${d}")
 637     endforeach(d)
 638     set(ldflags "${CMAKE_EXE_LINKER_FLAGS}")
 639     add_custom_command(OUTPUT ${binpath}
 640       COMMAND ${CMAKE_BINARY_DIR}/bin/llvm-go "cc=${cc}" "cxx=${cxx}" "cppflags=${cppflags}" "ldflags=${ldflags}"
 641               ${ARG_GOFLAGS} build -o ${binpath} ${pkgpath}
 642       DEPENDS llvm-config ${CMAKE_BINARY_DIR}/bin/llvm-go${CMAKE_EXECUTABLE_SUFFIX}
 643               ${llvmlibs} ${ARG_DEPENDS}
 644       COMMENT "Building Go executable ${binary}"
 645       VERBATIM)
 646     if (ARG_ALL)
 647       add_custom_target(${binary} ALL DEPENDS ${binpath})
 648     else()
 649       add_custom_target(${binary} DEPENDS ${binpath})
 650     endif()
 651   endif()
 652 endfunction()
 653
 654 # This function provides an automatic way to 'configure'-like generate a file
 655 # based on a set of common and custom variables, specifically targeting the
 656 # variables needed for the 'lit.site.cfg' files. This function bundles the
 657 # common variables that any Lit instance is likely to need, and custom
 658 # variables can be passed in.
 659 function(configure_lit_site_cfg input output)
 660   foreach(c ${LLVM_TARGETS_TO_BUILD})
 661     set(TARGETS_BUILT "${TARGETS_BUILT} ${c}")
 662   endforeach(c)
 663   set(TARGETS_TO_BUILD ${TARGETS_BUILT})
 664
 665   set(SHLIBEXT "${LTDL_SHLIB_EXT}")
 666
 667   # Configuration-time: See Unit/lit.site.cfg.in
 668   if (CMAKE_CFG_INTDIR STREQUAL ".")
 669     set(LLVM_BUILD_MODE ".")
 670   else ()
 671     set(LLVM_BUILD_MODE "%(build_mode)s")
 672   endif ()
 673
 674   # They below might not be the build tree but provided binary tree.
 675   set(LLVM_SOURCE_DIR ${LLVM_MAIN_SRC_DIR})
 676   set(LLVM_BINARY_DIR ${LLVM_BINARY_DIR})
 677   string(REPLACE ${CMAKE_CFG_INTDIR} ${LLVM_BUILD_MODE} LLVM_TOOLS_DIR ${LLVM_TOOLS_BINARY_DIR})
 678   string(REPLACE ${CMAKE_CFG_INTDIR} ${LLVM_BUILD_MODE} LLVM_LIBS_DIR  ${LLVM_LIBRARY_DIR})
 679
 680   # SHLIBDIR points the build tree.
 681   string(REPLACE ${CMAKE_CFG_INTDIR} ${LLVM_BUILD_MODE} SHLIBDIR "${LLVM_SHLIB_OUTPUT_INTDIR}")
 682
 683   set(PYTHON_EXECUTABLE ${PYTHON_EXECUTABLE})
 684   # FIXME: "ENABLE_SHARED" doesn't make sense, since it is used just for
 685   # plugins. We may rename it.
 686   if(LLVM_ENABLE_PLUGINS)
 687     set(ENABLE_SHARED "1")
 688   else()
 689     set(ENABLE_SHARED "0")
 690   endif()
 691
 692   if(LLVM_ENABLE_ASSERTIONS AND NOT MSVC_IDE)
 693     set(ENABLE_ASSERTIONS "1")
 694   else()
 695     set(ENABLE_ASSERTIONS "0")
 696   endif()
 697
 698   set(HOST_OS ${CMAKE_SYSTEM_NAME})
 699   set(HOST_ARCH ${CMAKE_SYSTEM_PROCESSOR})
 700
 701   set(HOST_CC "${CMAKE_C_COMPILER} ${CMAKE_C_COMPILER_ARG1}")
 702   set(HOST_CXX "${CMAKE_CXX_COMPILER} ${CMAKE_CXX_COMPILER_ARG1}")
 703   set(HOST_LDFLAGS "${CMAKE_EXE_LINKER_FLAGS}")
 704
 705   configure_file(${input} ${output} @ONLY)
 706 endfunction()
 707
 708 # A raw function to create a lit target. This is used to implement the testuite
 709 # management functions.
 710 function(add_lit_target target comment)
 711   parse_arguments(ARG "PARAMS;DEPENDS;ARGS" "" ${ARGN})
 712   set(LIT_ARGS "${ARG_ARGS} ${LLVM_LIT_ARGS}")
 713   separate_arguments(LIT_ARGS)
 714   if (NOT CMAKE_CFG_INTDIR STREQUAL ".")
 715     list(APPEND LIT_ARGS --param build_mode=${CMAKE_CFG_INTDIR})
 716   endif ()
 717   if (LLVM_MAIN_SRC_DIR)
 718     set (LIT_COMMAND ${PYTHON_EXECUTABLE} ${LLVM_MAIN_SRC_DIR}/utils/lit/lit.py)
 719   else()
 720     find_program(LIT_COMMAND llvm-lit)
 721   endif ()
 722   list(APPEND LIT_COMMAND ${LIT_ARGS})
 723   foreach(param ${ARG_PARAMS})
 724     list(APPEND LIT_COMMAND --param ${param})
 725   endforeach()
 726   if( ARG_DEPENDS )
 727     add_custom_target(${target}
 728       COMMAND ${LIT_COMMAND} ${ARG_DEFAULT_ARGS}
 729       COMMENT "${comment}"
 730       ${cmake_3_2_USES_TERMINAL}
 731       )
 732     add_dependencies(${target} ${ARG_DEPENDS})
 733   else()
 734     add_custom_target(${target}
 735       COMMAND ${CMAKE_COMMAND} -E echo "${target} does nothing, no tools built.")
 736     message(STATUS "${target} does nothing.")
 737   endif()
 738
 739   # Tests should be excluded from "Build Solution".
 740   set_target_properties(${target} PROPERTIES EXCLUDE_FROM_DEFAULT_BUILD ON)
 741 endfunction()
 742
 743 # A function to add a set of lit test suites to be driven through 'check-*' targets.
 744 function(add_lit_testsuite target comment)
 745   parse_arguments(ARG "PARAMS;DEPENDS;ARGS" "" ${ARGN})
 746
 747   # EXCLUDE_FROM_ALL excludes the test ${target} out of check-all.
 748   if(NOT EXCLUDE_FROM_ALL)
 749     # Register the testsuites, params and depends for the global check rule.
 750     set_property(GLOBAL APPEND PROPERTY LLVM_LIT_TESTSUITES ${ARG_DEFAULT_ARGS})
 751     set_property(GLOBAL APPEND PROPERTY LLVM_LIT_PARAMS ${ARG_PARAMS})
 752     set_property(GLOBAL APPEND PROPERTY LLVM_LIT_DEPENDS ${ARG_DEPENDS})
 753     set_property(GLOBAL APPEND PROPERTY LLVM_LIT_EXTRA_ARGS ${ARG_ARGS})
 754   endif()
 755
 756   # Produce a specific suffixed check rule.
 757   add_lit_target(${target} ${comment}
 758     ${ARG_DEFAULT_ARGS}
 759     PARAMS ${ARG_PARAMS}
 760     DEPENDS ${ARG_DEPENDS}
 761     ARGS ${ARG_ARGS}
 762     )
 763 endfunction()