cmake/config-ix.cmake

   1 include(CheckIncludeFile)
   2 include(CheckLibraryExists)
   3 include(CheckSymbolExists)
   4 include(CheckFunctionExists)
   5 include(CheckCXXSourceCompiles)
   6 include(TestBigEndian)
   7
   8 if( UNIX AND NOT BEOS )
   9   # Used by check_symbol_exists:
  10   set(CMAKE_REQUIRED_LIBRARIES m)
  11 endif()
  12
  13 # Helper macros and functions
  14 macro(add_cxx_include result files)
  15   set(${result} "")
  16   foreach (file_name ${files})
  17      set(${result} "${${result}}#include<${file_name}>\n")
  18   endforeach()
  19 endmacro(add_cxx_include files result)
  20
  21 function(check_type_exists type files variable)
  22   add_cxx_include(includes "${files}")
  23   CHECK_CXX_SOURCE_COMPILES("
  24     ${includes} ${type} typeVar;
  25     int main() {
  26         return 0;
  27     }
  28     " ${variable})
  29 endfunction()
  30
  31 # include checks
  32 check_include_file(argz.h HAVE_ARGZ_H)
  33 check_include_file(assert.h HAVE_ASSERT_H)
  34 check_include_file(dirent.h HAVE_DIRENT_H)
  35 check_include_file(dl.h HAVE_DL_H)
  36 check_include_file(dld.h HAVE_DLD_H)
  37 check_include_file(dlfcn.h HAVE_DLFCN_H)
  38 check_include_file(errno.h HAVE_ERRNO_H)
  39 check_include_file(execinfo.h HAVE_EXECINFO_H)
  40 check_include_file(fcntl.h HAVE_FCNTL_H)
  41 check_include_file(inttypes.h HAVE_INTTYPES_H)
  42 check_include_file(limits.h HAVE_LIMITS_H)
  43 check_include_file(link.h HAVE_LINK_H)
  44 check_include_file(malloc.h HAVE_MALLOC_H)
  45 check_include_file(malloc/malloc.h HAVE_MALLOC_MALLOC_H)
  46 check_include_file(memory.h HAVE_MEMORY_H)
  47 check_include_file(ndir.h HAVE_NDIR_H)
  48 if( NOT LLVM_ON_WIN32 )
  49   check_include_file(pthread.h HAVE_PTHREAD_H)
  50 endif()
  51 check_include_file(setjmp.h HAVE_SETJMP_H)
  52 check_include_file(signal.h HAVE_SIGNAL_H)
  53 check_include_file(stdint.h HAVE_STDINT_H)
  54 check_include_file(stdio.h HAVE_STDIO_H)
  55 check_include_file(stdlib.h HAVE_STDLIB_H)
  56 check_include_file(string.h HAVE_STRING_H)
  57 check_include_file(sys/dir.h HAVE_SYS_DIR_H)
  58 check_include_file(sys/dl.h HAVE_SYS_DL_H)
  59 check_include_file(sys/ioctl.h HAVE_SYS_IOCTL_H)
  60 check_include_file(sys/mman.h HAVE_SYS_MMAN_H)
  61 check_include_file(sys/ndir.h HAVE_SYS_NDIR_H)
  62 check_include_file(sys/param.h HAVE_SYS_PARAM_H)
  63 check_include_file(sys/resource.h HAVE_SYS_RESOURCE_H)
  64 check_include_file(sys/stat.h HAVE_SYS_STAT_H)
  65 check_include_file(sys/time.h HAVE_SYS_TIME_H)
  66 check_include_file(sys/types.h HAVE_SYS_TYPES_H)
  67 check_include_file(sys/wait.h HAVE_SYS_WAIT_H)
  68 check_include_file(termios.h HAVE_TERMIOS_H)
  69 check_include_file(unistd.h HAVE_UNISTD_H)
  70 check_include_file(utime.h HAVE_UTIME_H)
  71 check_include_file(valgrind/valgrind.h HAVE_VALGRIND_VALGRIND_H)
  72 check_include_file(windows.h HAVE_WINDOWS_H)
  73 check_include_file(fenv.h HAVE_FENV_H)
  74
  75 # library checks
  76 if( NOT LLVM_ON_WIN32 )
  77   check_library_exists(pthread pthread_create "" HAVE_LIBPTHREAD)
  78   check_library_exists(pthread pthread_getspecific "" HAVE_PTHREAD_GETSPECIFIC)
  79   check_library_exists(pthread pthread_rwlock_init "" HAVE_PTHREAD_RWLOCK_INIT)
  80   check_library_exists(dl dlopen "" HAVE_LIBDL)
  81 endif()
  82
  83 # function checks
  84 check_symbol_exists(getpagesize unistd.h HAVE_GETPAGESIZE)
  85 check_symbol_exists(getrusage sys/resource.h HAVE_GETRUSAGE)
  86 check_symbol_exists(setrlimit sys/resource.h HAVE_SETRLIMIT)
  87 check_function_exists(isatty HAVE_ISATTY)
  88 check_symbol_exists(isinf cmath HAVE_ISINF_IN_CMATH)
  89 check_symbol_exists(isinf math.h HAVE_ISINF_IN_MATH_H)
  90 check_symbol_exists(finite ieeefp.h HAVE_FINITE_IN_IEEEFP_H)
  91 check_symbol_exists(isnan cmath HAVE_ISNAN_IN_CMATH)
  92 check_symbol_exists(isnan math.h HAVE_ISNAN_IN_MATH_H)
  93 check_symbol_exists(ceilf math.h HAVE_CEILF)
  94 check_symbol_exists(floorf math.h HAVE_FLOORF)
  95 check_symbol_exists(nearbyintf math.h HAVE_NEARBYINTF)
  96 check_symbol_exists(mallinfo malloc.h HAVE_MALLINFO)
  97 check_symbol_exists(malloc_zone_statistics malloc/malloc.h
  98                     HAVE_MALLOC_ZONE_STATISTICS)
  99 check_symbol_exists(mkdtemp "stdlib.h;unistd.h" HAVE_MKDTEMP)
 100 check_symbol_exists(mkstemp "stdlib.h;unistd.h" HAVE_MKSTEMP)
 101 check_symbol_exists(mktemp "stdlib.h;unistd.h" HAVE_MKTEMP)
 102 if( NOT LLVM_ON_WIN32 )
 103   check_symbol_exists(pthread_mutex_lock pthread.h HAVE_PTHREAD_MUTEX_LOCK)
 104 endif()
 105 check_symbol_exists(sbrk unistd.h HAVE_SBRK)
 106 check_symbol_exists(strtoll stdlib.h HAVE_STRTOLL)
 107 check_symbol_exists(strerror string.h HAVE_STRERROR)
 108 check_symbol_exists(strerror_r string.h HAVE_STRERROR_R)
 109 check_symbol_exists(strerror_s string.h HAVE_STRERROR_S)
 110 check_symbol_exists(setenv stdlib.h HAVE_SETENV)
 111 if ( LLVM_ON_WIN32 )
 112   check_symbol_exists(_chsize_s io.h HAVE__CHSIZE_S)
 113 endif()
 114
 115 check_symbol_exists(__GLIBC__ stdio.h LLVM_USING_GLIBC)
 116 if( LLVM_USING_GLIBC )
 117   add_llvm_definitions( -D_GNU_SOURCE )
 118 endif()
 119
 120 # Type checks
 121 check_type_exists(std::bidirectional_iterator<int,int> "iterator;iostream" HAVE_BI_ITERATOR)
 122 check_type_exists(std::iterator<int,int,int> iterator HAVE_STD_ITERATOR)
 123 check_type_exists(std::forward_iterator<int,int> iterator HAVE_FWD_ITERATOR)
 124
 125 set(headers "")
 126 if (HAVE_SYS_TYPES_H)
 127   set(headers ${headers} "sys/types.h")
 128 endif()
 129
 130 if (HAVE_INTTYPES_H)
 131   set(headers ${headers} "inttypes.h")
 132 endif()
 133
 134 if (HAVE_STDINT_H)
 135   set(headers ${headers} "stdint.h")
 136 endif()
 137
 138 check_type_exists(uint64_t "${headers}" HAVE_UINT64_T)
 139 check_type_exists(u_int64_t "${headers}" HAVE_U_INT64_T)
 140
 141 # available programs checks
 142 function(llvm_find_program name)
 143   string(TOUPPER ${name} NAME)
 144   find_program(LLVM_PATH_${NAME} ${name})
 145   mark_as_advanced(LLVM_PATH_${NAME})
 146   if(LLVM_PATH_${NAME})
 147     set(HAVE_${NAME} 1 CACHE INTERNAL "Is ${name} available ?")
 148     mark_as_advanced(HAVE_${NAME})
 149   else(LLVM_PATH_${NAME})
 150     set(HAVE_${NAME} "" CACHE INTERNAL "Is ${name} available ?")
 151   endif(LLVM_PATH_${NAME})
 152 endfunction()
 153
 154 llvm_find_program(gv)
 155 llvm_find_program(circo)
 156 llvm_find_program(twopi)
 157 llvm_find_program(neato)
 158 llvm_find_program(fdp)
 159 llvm_find_program(dot)
 160 llvm_find_program(dotty)
 161
 162 # Define LLVM_MULTITHREADED if gcc atomic builtins exists.
 163 include(CheckAtomic)
 164
 165 include(CheckCXXCompilerFlag)
 166 # On windows all code is position-independent and mingw warns if -fPIC
 167 # is in the command-line.
 168 if( NOT WIN32 )
 169   check_cxx_compiler_flag("-fPIC" SUPPORTS_FPIC_FLAG)
 170 endif()
 171
 172 check_cxx_compiler_flag("-Wno-variadic-macros" SUPPORTS_NO_VARIADIC_MACROS_FLAG)
 173
 174 include(GetTargetTriple)
 175 get_target_triple(LLVM_HOSTTRIPLE)
 176
 177 # FIXME: We don't distinguish the target and the host. :(
 178 set(TARGET_TRIPLE "${LLVM_HOSTTRIPLE}")
 179
 180 # Determine the native architecture.
 181 string(TOLOWER "${LLVM_TARGET_ARCH}" LLVM_NATIVE_ARCH)
 182 if( LLVM_NATIVE_ARCH STREQUAL "host" )
 183   string(REGEX MATCH "^[^-]*" LLVM_NATIVE_ARCH ${LLVM_HOSTTRIPLE})
 184 endif ()
 185
 186 if (LLVM_NATIVE_ARCH MATCHES "i[2-6]86")
 187   set(LLVM_NATIVE_ARCH X86)
 188 elseif (LLVM_NATIVE_ARCH STREQUAL "x86")
 189   set(LLVM_NATIVE_ARCH X86)
 190 elseif (LLVM_NATIVE_ARCH STREQUAL "amd64")
 191   set(LLVM_NATIVE_ARCH X86)
 192 elseif (LLVM_NATIVE_ARCH STREQUAL "x86_64")
 193   set(LLVM_NATIVE_ARCH X86)
 194 elseif (LLVM_NATIVE_ARCH MATCHES "sparc")
 195   set(LLVM_NATIVE_ARCH Sparc)
 196 elseif (LLVM_NATIVE_ARCH MATCHES "powerpc")
 197   set(LLVM_NATIVE_ARCH PowerPC)
 198 elseif (LLVM_NATIVE_ARCH MATCHES "alpha")
 199   set(LLVM_NATIVE_ARCH Alpha)
 200 elseif (LLVM_NATIVE_ARCH MATCHES "arm")
 201   set(LLVM_NATIVE_ARCH ARM)
 202 elseif (LLVM_NATIVE_ARCH MATCHES "mips")
 203   set(LLVM_NATIVE_ARCH Mips)
 204 elseif (LLVM_NATIVE_ARCH MATCHES "xcore")
 205   set(LLVM_NATIVE_ARCH XCore)
 206 elseif (LLVM_NATIVE_ARCH MATCHES "msp430")
 207   set(LLVM_NATIVE_ARCH MSP430)
 208 else ()
 209   message(STATUS
 210     "Unknown architecture ${LLVM_NATIVE_ARCH}; lli will not JIT code")
 211   set(LLVM_NATIVE_ARCH)
 212 endif ()
 213
 214 if (LLVM_NATIVE_ARCH)
 215   list(FIND LLVM_TARGETS_TO_BUILD ${LLVM_NATIVE_ARCH} NATIVE_ARCH_IDX)
 216   if (NATIVE_ARCH_IDX EQUAL -1)
 217     message(STATUS
 218       "Native target ${LLVM_NATIVE_ARCH} is not selected; lli will not JIT code")
 219     set(LLVM_NATIVE_ARCH)
 220   else ()
 221     message(STATUS "Native target architecture is ${LLVM_NATIVE_ARCH}")
 222     set(LLVM_NATIVE_TARGET LLVMInitialize${LLVM_NATIVE_ARCH}Target)
 223     set(LLVM_NATIVE_TARGETINFO LLVMInitialize${LLVM_NATIVE_ARCH}TargetInfo)
 224     set(LLVM_NATIVE_ASMPRINTER LLVMInitialize${LLVM_NATIVE_ARCH}AsmPrinter)
 225   endif ()
 226 endif()
 227
 228 if( MINGW )
 229   set(HAVE_LIBIMAGEHLP 1)
 230   set(HAVE_LIBPSAPI 1)
 231   # TODO: Check existence of libraries.
 232   #   include(CheckLibraryExists)
 233   #   CHECK_LIBRARY_EXISTS(imagehlp ??? . HAVE_LIBIMAGEHLP)
 234 endif( MINGW )
 235
 236 if( MSVC )
 237   set(error_t int)
 238   set(mode_t "unsigned short")
 239   set(LTDL_SHLIBPATH_VAR "PATH")
 240   set(LTDL_SYSSEARCHPATH "")
 241   set(LTDL_DLOPEN_DEPLIBS 1)
 242   set(SHLIBEXT ".lib")
 243   set(LTDL_OBJDIR "_libs")
 244   set(HAVE_STRTOLL 1)
 245   set(strtoll "_strtoi64")
 246   set(strtoull "_strtoui64")
 247   set(stricmp "_stricmp")
 248   set(strdup "_strdup")
 249 else( MSVC )
 250   set(LTDL_SHLIBPATH_VAR "LD_LIBRARY_PATH")
 251   set(LTDL_SYSSEARCHPATH "") # TODO
 252   set(LTDL_DLOPEN_DEPLIBS 0)  # TODO
 253 endif( MSVC )
 254
 255 # FIXME: Signal handler return type, currently hardcoded to 'void'
 256 set(RETSIGTYPE void)
 257
 258 if( LLVM_ENABLE_THREADS )
 259   if( HAVE_PTHREAD_H OR WIN32 )
 260     set(ENABLE_THREADS 1)
 261   endif()
 262 endif()
 263
 264 if( ENABLE_THREADS )
 265   message(STATUS "Threads enabled.")
 266 else( ENABLE_THREADS )
 267   message(STATUS "Threads disabled.")
 268 endif()
 269
 270 set(LLVM_PREFIX ${CMAKE_INSTALL_PREFIX})
 271
 272 configure_file(
 273   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/config.h.cmake
 274   ${LLVM_BINARY_DIR}/include/llvm/Config/config.h
 275   )
 276
 277 configure_file(
 278   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/llvm-config.h.cmake
 279   ${LLVM_BINARY_DIR}/include/llvm/Config/llvm-config.h
 280   )
 281
 282 configure_file(
 283   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Support/DataTypes.h.cmake
 284   ${LLVM_BINARY_DIR}/include/llvm/Support/DataTypes.h
 285   )
 286