cmake/config-ix.cmake

   1 if( WIN32 AND NOT CYGWIN )
   2   # We consider Cygwin as another Unix
   3   set(PURE_WINDOWS 1)
   4 endif()
   5
   6 include(CheckIncludeFile)
   7 include(CheckIncludeFileCXX)
   8 include(CheckLibraryExists)
   9 include(CheckSymbolExists)
  10 include(CheckFunctionExists)
  11 include(CheckCXXSourceCompiles)
  12 include(TestBigEndian)
  13
  14 if( UNIX AND NOT BEOS )
  15   # Used by check_symbol_exists:
  16   set(CMAKE_REQUIRED_LIBRARIES m)
  17 endif()
  18
  19 # Helper macros and functions
  20 macro(add_cxx_include result files)
  21   set(${result} "")
  22   foreach (file_name ${files})
  23      set(${result} "${${result}}#include<${file_name}>\n")
  24   endforeach()
  25 endmacro(add_cxx_include files result)
  26
  27 function(check_type_exists type files variable)
  28   add_cxx_include(includes "${files}")
  29   CHECK_CXX_SOURCE_COMPILES("
  30     ${includes} ${type} typeVar;
  31     int main() {
  32         return 0;
  33     }
  34     " ${variable})
  35 endfunction()
  36
  37 # include checks
  38 check_include_file_cxx(cxxabi.h HAVE_CXXABI_H)
  39 check_include_file(dirent.h HAVE_DIRENT_H)
  40 check_include_file(dlfcn.h HAVE_DLFCN_H)
  41 check_include_file(errno.h HAVE_ERRNO_H)
  42 check_include_file(execinfo.h HAVE_EXECINFO_H)
  43 check_include_file(fcntl.h HAVE_FCNTL_H)
  44 check_include_file(inttypes.h HAVE_INTTYPES_H)
  45 check_include_file(limits.h HAVE_LIMITS_H)
  46 check_include_file(malloc.h HAVE_MALLOC_H)
  47 check_include_file(malloc/malloc.h HAVE_MALLOC_MALLOC_H)
  48 check_include_file(ndir.h HAVE_NDIR_H)
  49 if( NOT PURE_WINDOWS )
  50   check_include_file(pthread.h HAVE_PTHREAD_H)
  51 endif()
  52 check_include_file(sanitizer/msan_interface.h HAVE_SANITIZER_MSAN_INTERFACE_H)
  53 check_include_file(signal.h HAVE_SIGNAL_H)
  54 check_include_file(stdint.h HAVE_STDINT_H)
  55 check_include_file(sys/dir.h HAVE_SYS_DIR_H)
  56 check_include_file(sys/ioctl.h HAVE_SYS_IOCTL_H)
  57 check_include_file(sys/mman.h HAVE_SYS_MMAN_H)
  58 check_include_file(sys/ndir.h HAVE_SYS_NDIR_H)
  59 check_include_file(sys/param.h HAVE_SYS_PARAM_H)
  60 check_include_file(sys/resource.h HAVE_SYS_RESOURCE_H)
  61 check_include_file(sys/stat.h HAVE_SYS_STAT_H)
  62 check_include_file(sys/time.h HAVE_SYS_TIME_H)
  63 check_include_file(sys/uio.h HAVE_SYS_UIO_H)
  64 check_include_file(sys/wait.h HAVE_SYS_WAIT_H)
  65 check_include_file(termios.h HAVE_TERMIOS_H)
  66 check_include_file(unistd.h HAVE_UNISTD_H)
  67 check_include_file(utime.h HAVE_UTIME_H)
  68 check_include_file(valgrind/valgrind.h HAVE_VALGRIND_VALGRIND_H)
  69 check_include_file(zlib.h HAVE_ZLIB_H)
  70 check_include_file(fenv.h HAVE_FENV_H)
  71 check_symbol_exists(FE_ALL_EXCEPT "fenv.h" HAVE_DECL_FE_ALL_EXCEPT)
  72 check_symbol_exists(FE_INEXACT "fenv.h" HAVE_DECL_FE_INEXACT)
  73
  74 check_include_file(mach/mach.h HAVE_MACH_MACH_H)
  75 check_include_file(mach-o/dyld.h HAVE_MACH_O_DYLD_H)
  76
  77 # library checks
  78 if( NOT PURE_WINDOWS )
  79   check_library_exists(pthread pthread_create "" HAVE_LIBPTHREAD)
  80   if (HAVE_LIBPTHREAD)
  81     check_library_exists(pthread pthread_getspecific "" HAVE_PTHREAD_GETSPECIFIC)
  82     check_library_exists(pthread pthread_rwlock_init "" HAVE_PTHREAD_RWLOCK_INIT)
  83     check_library_exists(pthread pthread_mutex_lock "" HAVE_PTHREAD_MUTEX_LOCK)
  84   else()
  85     # this could be Android
  86     check_library_exists(c pthread_create "" PTHREAD_IN_LIBC)
  87     if (PTHREAD_IN_LIBC)
  88       check_library_exists(c pthread_getspecific "" HAVE_PTHREAD_GETSPECIFIC)
  89       check_library_exists(c pthread_rwlock_init "" HAVE_PTHREAD_RWLOCK_INIT)
  90       check_library_exists(c pthread_mutex_lock "" HAVE_PTHREAD_MUTEX_LOCK)
  91     endif()
  92   endif()
  93   check_library_exists(dl dlopen "" HAVE_LIBDL)
  94   check_library_exists(rt clock_gettime "" HAVE_LIBRT)
  95   if (LLVM_ENABLE_ZLIB)
  96     check_library_exists(z compress2 "" HAVE_LIBZ)
  97   else()
  98     set(HAVE_LIBZ 0)
  99   endif()
 100 endif()
 101
 102 # function checks
 103 check_symbol_exists(arc4random "stdlib.h" HAVE_ARC4RANDOM)
 104 check_symbol_exists(backtrace "execinfo.h" HAVE_BACKTRACE)
 105 check_symbol_exists(getpagesize unistd.h HAVE_GETPAGESIZE)
 106 check_symbol_exists(getrusage sys/resource.h HAVE_GETRUSAGE)
 107 check_symbol_exists(setrlimit sys/resource.h HAVE_SETRLIMIT)
 108 check_symbol_exists(isatty unistd.h HAVE_ISATTY)
 109 check_symbol_exists(isinf cmath HAVE_ISINF_IN_CMATH)
 110 check_symbol_exists(isinf math.h HAVE_ISINF_IN_MATH_H)
 111 check_symbol_exists(finite ieeefp.h HAVE_FINITE_IN_IEEEFP_H)
 112 check_symbol_exists(isnan cmath HAVE_ISNAN_IN_CMATH)
 113 check_symbol_exists(isnan math.h HAVE_ISNAN_IN_MATH_H)
 114 check_symbol_exists(ceilf math.h HAVE_CEILF)
 115 check_symbol_exists(floorf math.h HAVE_FLOORF)
 116 check_symbol_exists(fmodf math.h HAVE_FMODF)
 117 check_symbol_exists(log math.h HAVE_LOG)
 118 check_symbol_exists(log2 math.h HAVE_LOG2)
 119 check_symbol_exists(log10 math.h HAVE_LOG10)
 120 check_symbol_exists(exp math.h HAVE_EXP)
 121 check_symbol_exists(exp2 math.h HAVE_EXP2)
 122 check_symbol_exists(exp10 math.h HAVE_EXP10)
 123 check_symbol_exists(futimens sys/stat.h HAVE_FUTIMENS)
 124 check_symbol_exists(futimes sys/time.h HAVE_FUTIMES)
 125 if( HAVE_SETJMP_H )
 126   check_symbol_exists(longjmp setjmp.h HAVE_LONGJMP)
 127   check_symbol_exists(setjmp setjmp.h HAVE_SETJMP)
 128   check_symbol_exists(siglongjmp setjmp.h HAVE_SIGLONGJMP)
 129   check_symbol_exists(sigsetjmp setjmp.h HAVE_SIGSETJMP)
 130 endif()
 131 if( HAVE_SYS_UIO_H )
 132   check_symbol_exists(writev sys/uio.h HAVE_WRITEV)
 133 endif()
 134 check_symbol_exists(nearbyintf math.h HAVE_NEARBYINTF)
 135 check_symbol_exists(mallinfo malloc.h HAVE_MALLINFO)
 136 check_symbol_exists(malloc_zone_statistics malloc/malloc.h
 137                     HAVE_MALLOC_ZONE_STATISTICS)
 138 check_symbol_exists(mkdtemp "stdlib.h;unistd.h" HAVE_MKDTEMP)
 139 check_symbol_exists(mkstemp "stdlib.h;unistd.h" HAVE_MKSTEMP)
 140 check_symbol_exists(mktemp "stdlib.h;unistd.h" HAVE_MKTEMP)
 141 check_symbol_exists(closedir "sys/types.h;dirent.h" HAVE_CLOSEDIR)
 142 check_symbol_exists(opendir "sys/types.h;dirent.h" HAVE_OPENDIR)
 143 check_symbol_exists(readdir "sys/types.h;dirent.h" HAVE_READDIR)
 144 check_symbol_exists(getcwd unistd.h HAVE_GETCWD)
 145 check_symbol_exists(gettimeofday sys/time.h HAVE_GETTIMEOFDAY)
 146 check_symbol_exists(getrlimit "sys/types.h;sys/time.h;sys/resource.h" HAVE_GETRLIMIT)
 147 check_symbol_exists(posix_spawn spawn.h HAVE_POSIX_SPAWN)
 148 check_symbol_exists(pread unistd.h HAVE_PREAD)
 149 check_symbol_exists(sbrk unistd.h HAVE_SBRK)
 150 check_symbol_exists(srand48 stdlib.h HAVE_RAND48_SRAND48)
 151 if( HAVE_RAND48_SRAND48 )
 152   check_symbol_exists(lrand48 stdlib.h HAVE_RAND48_LRAND48)
 153   if( HAVE_RAND48_LRAND48 )
 154     check_symbol_exists(drand48 stdlib.h HAVE_RAND48_DRAND48)
 155     if( HAVE_RAND48_DRAND48 )
 156       set(HAVE_RAND48 1 CACHE INTERNAL "are srand48/lrand48/drand48 available?")
 157     endif()
 158   endif()
 159 endif()
 160 check_symbol_exists(strtoll stdlib.h HAVE_STRTOLL)
 161 check_symbol_exists(strtoq stdlib.h HAVE_STRTOQ)
 162 check_symbol_exists(strerror string.h HAVE_STRERROR)
 163 check_symbol_exists(strerror_r string.h HAVE_STRERROR_R)
 164 check_symbol_exists(strerror_s string.h HAVE_DECL_STRERROR_S)
 165 check_symbol_exists(setenv stdlib.h HAVE_SETENV)
 166 if( PURE_WINDOWS )
 167   check_symbol_exists(_chsize_s io.h HAVE__CHSIZE_S)
 168
 169   check_function_exists(_alloca HAVE__ALLOCA)
 170   check_function_exists(__alloca HAVE___ALLOCA)
 171   check_function_exists(__chkstk HAVE___CHKSTK)
 172   check_function_exists(___chkstk HAVE____CHKSTK)
 173
 174   check_function_exists(__ashldi3 HAVE___ASHLDI3)
 175   check_function_exists(__ashrdi3 HAVE___ASHRDI3)
 176   check_function_exists(__divdi3 HAVE___DIVDI3)
 177   check_function_exists(__fixdfdi HAVE___FIXDFDI)
 178   check_function_exists(__fixsfdi HAVE___FIXSFDI)
 179   check_function_exists(__floatdidf HAVE___FLOATDIDF)
 180   check_function_exists(__lshrdi3 HAVE___LSHRDI3)
 181   check_function_exists(__moddi3 HAVE___MODDI3)
 182   check_function_exists(__udivdi3 HAVE___UDIVDI3)
 183   check_function_exists(__umoddi3 HAVE___UMODDI3)
 184
 185   check_function_exists(__main HAVE___MAIN)
 186   check_function_exists(__cmpdi2 HAVE___CMPDI2)
 187 endif()
 188 if( HAVE_DLFCN_H )
 189   if( HAVE_LIBDL )
 190     list(APPEND CMAKE_REQUIRED_LIBRARIES dl)
 191   endif()
 192   check_symbol_exists(dlerror dlfcn.h HAVE_DLERROR)
 193   check_symbol_exists(dlopen dlfcn.h HAVE_DLOPEN)
 194   if( HAVE_LIBDL )
 195     list(REMOVE_ITEM CMAKE_REQUIRED_LIBRARIES dl)
 196   endif()
 197 endif()
 198
 199 check_symbol_exists(__GLIBC__ stdio.h LLVM_USING_GLIBC)
 200 if( LLVM_USING_GLIBC )
 201   add_llvm_definitions( -D_GNU_SOURCE )
 202 endif()
 203
 204 set(headers "sys/types.h")
 205
 206 if (HAVE_INTTYPES_H)
 207   set(headers ${headers} "inttypes.h")
 208 endif()
 209
 210 if (HAVE_STDINT_H)
 211   set(headers ${headers} "stdint.h")
 212 endif()
 213
 214 check_type_exists(int64_t "${headers}" HAVE_INT64_T)
 215 check_type_exists(uint64_t "${headers}" HAVE_UINT64_T)
 216 check_type_exists(u_int64_t "${headers}" HAVE_U_INT64_T)
 217 check_type_exists(error_t errno.h HAVE_ERROR_T)
 218
 219 # available programs checks
 220 function(llvm_find_program name)
 221   string(TOUPPER ${name} NAME)
 222   string(REGEX REPLACE "\\." "_" NAME ${NAME})
 223
 224   find_program(LLVM_PATH_${NAME} NAMES ${ARGV})
 225   mark_as_advanced(LLVM_PATH_${NAME})
 226   if(LLVM_PATH_${NAME})
 227     set(HAVE_${NAME} 1 CACHE INTERNAL "Is ${name} available ?")
 228     mark_as_advanced(HAVE_${NAME})
 229   else(LLVM_PATH_${NAME})
 230     set(HAVE_${NAME} "" CACHE INTERNAL "Is ${name} available ?")
 231   endif(LLVM_PATH_${NAME})
 232 endfunction()
 233
 234 llvm_find_program(gv)
 235 llvm_find_program(circo)
 236 llvm_find_program(twopi)
 237 llvm_find_program(neato)
 238 llvm_find_program(fdp)
 239 llvm_find_program(dot)
 240 llvm_find_program(dotty)
 241 llvm_find_program(xdot xdot.py)
 242 llvm_find_program(Graphviz)
 243
 244 if( LLVM_ENABLE_FFI )
 245   find_path(FFI_INCLUDE_PATH ffi.h PATHS ${FFI_INCLUDE_DIR})
 246   if( FFI_INCLUDE_PATH )
 247     set(FFI_HEADER ffi.h CACHE INTERNAL "")
 248     set(HAVE_FFI_H 1 CACHE INTERNAL "")
 249   else()
 250     find_path(FFI_INCLUDE_PATH ffi/ffi.h PATHS ${FFI_INCLUDE_DIR})
 251     if( FFI_INCLUDE_PATH )
 252       set(FFI_HEADER ffi/ffi.h CACHE INTERNAL "")
 253       set(HAVE_FFI_FFI_H 1 CACHE INTERNAL "")
 254     endif()
 255   endif()
 256
 257   if( NOT FFI_HEADER )
 258     message(FATAL_ERROR "libffi includes are not found.")
 259   endif()
 260
 261   find_library(FFI_LIBRARY_PATH ffi PATHS ${FFI_LIBRARY_DIR})
 262   if( NOT FFI_LIBRARY_PATH )
 263     message(FATAL_ERROR "libffi is not found.")
 264   endif()
 265
 266   list(APPEND CMAKE_REQUIRED_LIBRARIES ${FFI_LIBRARY_PATH})
 267   list(APPEND CMAKE_REQUIRED_INCLUDES ${FFI_INCLUDE_PATH})
 268   check_symbol_exists(ffi_call ${FFI_HEADER} HAVE_FFI_CALL)
 269   list(REMOVE_ITEM CMAKE_REQUIRED_INCLUDES ${FFI_INCLUDE_PATH})
 270   list(REMOVE_ITEM CMAKE_REQUIRED_LIBRARIES ${FFI_LIBRARY_PATH})
 271 else()
 272   unset(HAVE_FFI_FFI_H CACHE)
 273   unset(HAVE_FFI_H CACHE)
 274   unset(HAVE_FFI_CALL CACHE)
 275 endif( LLVM_ENABLE_FFI )
 276
 277 # Define LLVM_HAS_ATOMICS if gcc or MSVC atomic builtins are supported.
 278 include(CheckAtomic)
 279
 280 if( LLVM_ENABLE_PIC )
 281   set(ENABLE_PIC 1)
 282 else()
 283   set(ENABLE_PIC 0)
 284 endif()
 285
 286 find_package(LibXml2)
 287 if (LIBXML2_FOUND)
 288   set(CLANG_HAVE_LIBXML 1)
 289 endif ()
 290
 291 include(CheckCXXCompilerFlag)
 292
 293 check_cxx_compiler_flag("-Wno-variadic-macros" SUPPORTS_NO_VARIADIC_MACROS_FLAG)
 294
 295 set(USE_NO_MAYBE_UNINITIALIZED 0)
 296 set(USE_NO_UNINITIALIZED 0)
 297
 298 # Disable gcc's potentially uninitialized use analysis as it presents lots of
 299 # false positives.
 300 if (CMAKE_COMPILER_IS_GNUCXX)
 301   check_cxx_compiler_flag("-Wmaybe-uninitialized" HAS_MAYBE_UNINITIALIZED)
 302   if (HAS_MAYBE_UNINITIALIZED)
 303     set(USE_NO_MAYBE_UNINITIALIZED 1)
 304   else()
 305     # Only recent versions of gcc make the distinction between -Wuninitialized
 306     # and -Wmaybe-uninitialized. If -Wmaybe-uninitialized isn't supported, just
 307     # turn off all uninitialized use warnings.
 308     check_cxx_compiler_flag("-Wuninitialized" HAS_UNINITIALIZED)
 309     set(USE_NO_UNINITIALIZED ${HAS_UNINITIALIZED})
 310   endif()
 311 endif()
 312
 313 # By default, we target the host, but this can be overridden at CMake
 314 # invocation time.
 315 include(GetHostTriple)
 316 get_host_triple(LLVM_INFERRED_HOST_TRIPLE)
 317
 318 set(LLVM_HOST_TRIPLE "${LLVM_INFERRED_HOST_TRIPLE}" CACHE STRING
 319     "Host on which LLVM binaries will run")
 320
 321 # Determine the native architecture.
 322 string(TOLOWER "${LLVM_TARGET_ARCH}" LLVM_NATIVE_ARCH)
 323 if( LLVM_NATIVE_ARCH STREQUAL "host" )
 324   string(REGEX MATCH "^[^-]*" LLVM_NATIVE_ARCH ${LLVM_HOST_TRIPLE})
 325 endif ()
 326
 327 if (LLVM_NATIVE_ARCH MATCHES "i[2-6]86")
 328   set(LLVM_NATIVE_ARCH X86)
 329 elseif (LLVM_NATIVE_ARCH STREQUAL "x86")
 330   set(LLVM_NATIVE_ARCH X86)
 331 elseif (LLVM_NATIVE_ARCH STREQUAL "amd64")
 332   set(LLVM_NATIVE_ARCH X86)
 333 elseif (LLVM_NATIVE_ARCH STREQUAL "x86_64")
 334   set(LLVM_NATIVE_ARCH X86)
 335 elseif (LLVM_NATIVE_ARCH MATCHES "sparc")
 336   set(LLVM_NATIVE_ARCH Sparc)
 337 elseif (LLVM_NATIVE_ARCH MATCHES "powerpc")
 338   set(LLVM_NATIVE_ARCH PowerPC)
 339 elseif (LLVM_NATIVE_ARCH MATCHES "aarch64")
 340   set(LLVM_NATIVE_ARCH AArch64)
 341 elseif (LLVM_NATIVE_ARCH MATCHES "arm")
 342   set(LLVM_NATIVE_ARCH ARM)
 343 elseif (LLVM_NATIVE_ARCH MATCHES "mips")
 344   set(LLVM_NATIVE_ARCH Mips)
 345 elseif (LLVM_NATIVE_ARCH MATCHES "xcore")
 346   set(LLVM_NATIVE_ARCH XCore)
 347 elseif (LLVM_NATIVE_ARCH MATCHES "msp430")
 348   set(LLVM_NATIVE_ARCH MSP430)
 349 elseif (LLVM_NATIVE_ARCH MATCHES "hexagon")
 350   set(LLVM_NATIVE_ARCH Hexagon)
 351 elseif (LLVM_NATIVE_ARCH MATCHES "s390x")
 352   set(LLVM_NATIVE_ARCH SystemZ)
 353 else ()
 354   message(FATAL_ERROR "Unknown architecture ${LLVM_NATIVE_ARCH}")
 355 endif ()
 356
 357 # If build targets includes "host", then replace with native architecture.
 358 list(FIND LLVM_TARGETS_TO_BUILD "host" idx)
 359 if( NOT idx LESS 0 )
 360   list(REMOVE_AT LLVM_TARGETS_TO_BUILD ${idx})
 361   list(APPEND LLVM_TARGETS_TO_BUILD ${LLVM_NATIVE_ARCH})
 362   list(REMOVE_DUPLICATES LLVM_TARGETS_TO_BUILD)
 363 endif()
 364
 365 list(FIND LLVM_TARGETS_TO_BUILD ${LLVM_NATIVE_ARCH} NATIVE_ARCH_IDX)
 366 if (NATIVE_ARCH_IDX EQUAL -1)
 367   message(STATUS
 368     "Native target ${LLVM_NATIVE_ARCH} is not selected; lli will not JIT code")
 369 else ()
 370   message(STATUS "Native target architecture is ${LLVM_NATIVE_ARCH}")
 371   set(LLVM_NATIVE_TARGET LLVMInitialize${LLVM_NATIVE_ARCH}Target)
 372   set(LLVM_NATIVE_TARGETINFO LLVMInitialize${LLVM_NATIVE_ARCH}TargetInfo)
 373   set(LLVM_NATIVE_TARGETMC LLVMInitialize${LLVM_NATIVE_ARCH}TargetMC)
 374   set(LLVM_NATIVE_ASMPRINTER LLVMInitialize${LLVM_NATIVE_ARCH}AsmPrinter)
 375
 376   # We don't have an ASM parser for all architectures yet.
 377   if (EXISTS ${CMAKE_SOURCE_DIR}/lib/Target/${LLVM_NATIVE_ARCH}/AsmParser/CMakeLists.txt)
 378     set(LLVM_NATIVE_ASMPARSER LLVMInitialize${LLVM_NATIVE_ARCH}AsmParser)
 379   endif ()
 380
 381   # We don't have an disassembler for all architectures yet.
 382   if (EXISTS ${CMAKE_SOURCE_DIR}/lib/Target/${LLVM_NATIVE_ARCH}/Disassembler/CMakeLists.txt)
 383     set(LLVM_NATIVE_DISASSEMBLER LLVMInitialize${LLVM_NATIVE_ARCH}Disassembler)
 384   endif ()
 385 endif ()
 386
 387 if( MINGW )
 388   set(HAVE_LIBIMAGEHLP 1)
 389   set(HAVE_LIBPSAPI 1)
 390   # TODO: Check existence of libraries.
 391   #   include(CheckLibraryExists)
 392   #   CHECK_LIBRARY_EXISTS(imagehlp ??? . HAVE_LIBIMAGEHLP)
 393 endif( MINGW )
 394
 395 if( MSVC )
 396   set(error_t int)
 397   set(LTDL_SYSSEARCHPATH "")
 398   set(LTDL_DLOPEN_DEPLIBS 1)
 399   set(SHLIBEXT ".lib")
 400   set(LTDL_OBJDIR "_libs")
 401   set(HAVE_STRTOLL 1)
 402   set(strtoll "_strtoi64")
 403   set(strtoull "_strtoui64")
 404   set(stricmp "_stricmp")
 405   set(strdup "_strdup")
 406 else( MSVC )
 407   set(LTDL_SYSSEARCHPATH "") # TODO
 408   set(LTDL_DLOPEN_DEPLIBS 0)  # TODO
 409 endif( MSVC )
 410
 411 if( PURE_WINDOWS )
 412   CHECK_CXX_SOURCE_COMPILES("
 413     #include <windows.h>
 414     #include <imagehlp.h>
 415     extern \"C\" void foo(PENUMLOADED_MODULES_CALLBACK);
 416     extern \"C\" void foo(BOOL(CALLBACK*)(PCSTR,ULONG_PTR,ULONG,PVOID));
 417     int main(){return 0;}"
 418     HAVE_ELMCB_PCSTR)
 419   if( HAVE_ELMCB_PCSTR )
 420     set(WIN32_ELMCB_PCSTR "PCSTR")
 421   else()
 422     set(WIN32_ELMCB_PCSTR "PSTR")
 423   endif()
 424 endif( PURE_WINDOWS )
 425
 426 # FIXME: Signal handler return type, currently hardcoded to 'void'
 427 set(RETSIGTYPE void)
 428
 429 if( LLVM_ENABLE_THREADS )
 430   # Check if threading primitives aren't supported on this platform
 431   if( NOT HAVE_PTHREAD_H AND NOT WIN32 )
 432     set(LLVM_ENABLE_THREADS 0)
 433   endif()
 434 endif()
 435
 436 if( LLVM_ENABLE_THREADS )
 437   message(STATUS "Threads enabled.")
 438 else( LLVM_ENABLE_THREADS )
 439   message(STATUS "Threads disabled.")
 440 endif()
 441
 442 if (LLVM_ENABLE_ZLIB )
 443   # Check if zlib is available in the system.
 444   if ( NOT HAVE_ZLIB_H OR NOT HAVE_LIBZ )
 445     set(LLVM_ENABLE_ZLIB 0)
 446   endif()
 447 endif()
 448
 449 set(LLVM_PREFIX ${CMAKE_INSTALL_PREFIX})