cmake/config-ix.cmake

   1 include(CheckIncludeFile)
   2 include(CheckLibraryExists)
   3 include(CheckSymbolExists)
   4 include(CheckFunctionExists)
   5 include(CheckCXXSourceCompiles)
   6 include(TestBigEndian)
   7
   8 if( UNIX AND NOT BEOS )
   9   # Used by check_symbol_exists:
  10   set(CMAKE_REQUIRED_LIBRARIES m)
  11 endif()
  12
  13 # Helper macros and functions
  14 macro(add_cxx_include result files)
  15   set(${result} "")
  16   foreach (file_name ${files})
  17      set(${result} "${${result}}#include<${file_name}>\n")
  18   endforeach()
  19 endmacro(add_cxx_include files result)
  20
  21 function(check_type_exists type files variable)
  22   add_cxx_include(includes "${files}")
  23   CHECK_CXX_SOURCE_COMPILES("
  24     ${includes} ${type} typeVar;
  25     int main() {
  26         return 0;
  27     }
  28     " ${variable})
  29 endfunction()
  30
  31 # include checks
  32 check_include_file(argz.h HAVE_ARGZ_H)
  33 check_include_file(assert.h HAVE_ASSERT_H)
  34 check_include_file(ctype.h HAVE_CTYPE_H)
  35 check_include_file(dirent.h HAVE_DIRENT_H)
  36 check_include_file(dl.h HAVE_DL_H)
  37 check_include_file(dld.h HAVE_DLD_H)
  38 check_include_file(dlfcn.h HAVE_DLFCN_H)
  39 check_include_file(errno.h HAVE_ERRNO_H)
  40 check_include_file(execinfo.h HAVE_EXECINFO_H)
  41 check_include_file(fcntl.h HAVE_FCNTL_H)
  42 check_include_file(inttypes.h HAVE_INTTYPES_H)
  43 check_include_file(limits.h HAVE_LIMITS_H)
  44 check_include_file(link.h HAVE_LINK_H)
  45 check_include_file(malloc.h HAVE_MALLOC_H)
  46 check_include_file(malloc/malloc.h HAVE_MALLOC_MALLOC_H)
  47 check_include_file(memory.h HAVE_MEMORY_H)
  48 check_include_file(ndir.h HAVE_NDIR_H)
  49 if( NOT LLVM_ON_WIN32 )
  50   check_include_file(pthread.h HAVE_PTHREAD_H)
  51 endif()
  52 check_include_file(setjmp.h HAVE_SETJMP_H)
  53 check_include_file(signal.h HAVE_SIGNAL_H)
  54 check_include_file(stdint.h HAVE_STDINT_H)
  55 check_include_file(stdio.h HAVE_STDIO_H)
  56 check_include_file(stdlib.h HAVE_STDLIB_H)
  57 check_include_file(string.h HAVE_STRING_H)
  58 check_include_file(sys/dir.h HAVE_SYS_DIR_H)
  59 check_include_file(sys/dl.h HAVE_SYS_DL_H)
  60 check_include_file(sys/ioctl.h HAVE_SYS_IOCTL_H)
  61 check_include_file(sys/mman.h HAVE_SYS_MMAN_H)
  62 check_include_file(sys/ndir.h HAVE_SYS_NDIR_H)
  63 check_include_file(sys/param.h HAVE_SYS_PARAM_H)
  64 check_include_file(sys/resource.h HAVE_SYS_RESOURCE_H)
  65 check_include_file(sys/stat.h HAVE_SYS_STAT_H)
  66 check_include_file(sys/time.h HAVE_SYS_TIME_H)
  67 check_include_file(sys/types.h HAVE_SYS_TYPES_H)
  68 check_include_file(sys/wait.h HAVE_SYS_WAIT_H)
  69 check_include_file(termios.h HAVE_TERMIOS_H)
  70 check_include_file(unistd.h HAVE_UNISTD_H)
  71 check_include_file(utime.h HAVE_UTIME_H)
  72 check_include_file(valgrind/valgrind.h HAVE_VALGRIND_VALGRIND_H)
  73 check_include_file(windows.h HAVE_WINDOWS_H)
  74 check_include_file(fenv.h HAVE_FENV_H)
  75
  76 # library checks
  77 if( NOT LLVM_ON_WIN32 )
  78   check_library_exists(pthread pthread_create "" HAVE_LIBPTHREAD)
  79   check_library_exists(pthread pthread_getspecific "" HAVE_PTHREAD_GETSPECIFIC)
  80   check_library_exists(pthread pthread_rwlock_init "" HAVE_PTHREAD_RWLOCK_INIT)
  81   check_library_exists(dl dlopen "" HAVE_LIBDL)
  82 endif()
  83
  84 # function checks
  85 check_symbol_exists(getpagesize unistd.h HAVE_GETPAGESIZE)
  86 check_symbol_exists(getrusage sys/resource.h HAVE_GETRUSAGE)
  87 check_symbol_exists(setrlimit sys/resource.h HAVE_SETRLIMIT)
  88 check_function_exists(isatty HAVE_ISATTY)
  89 check_symbol_exists(isinf cmath HAVE_ISINF_IN_CMATH)
  90 check_symbol_exists(isinf math.h HAVE_ISINF_IN_MATH_H)
  91 check_symbol_exists(finite ieeefp.h HAVE_FINITE_IN_IEEEFP_H)
  92 check_symbol_exists(isnan cmath HAVE_ISNAN_IN_CMATH)
  93 check_symbol_exists(isnan math.h HAVE_ISNAN_IN_MATH_H)
  94 check_symbol_exists(ceilf math.h HAVE_CEILF)
  95 check_symbol_exists(floorf math.h HAVE_FLOORF)
  96 check_symbol_exists(fmodf math.h HAVE_FMODF)
  97 check_symbol_exists(nearbyintf math.h HAVE_NEARBYINTF)
  98 check_symbol_exists(mallinfo malloc.h HAVE_MALLINFO)
  99 check_symbol_exists(malloc_zone_statistics malloc/malloc.h
 100                     HAVE_MALLOC_ZONE_STATISTICS)
 101 check_symbol_exists(mkdtemp "stdlib.h;unistd.h" HAVE_MKDTEMP)
 102 check_symbol_exists(mkstemp "stdlib.h;unistd.h" HAVE_MKSTEMP)
 103 check_symbol_exists(mktemp "stdlib.h;unistd.h" HAVE_MKTEMP)
 104 if( NOT LLVM_ON_WIN32 )
 105   check_symbol_exists(pthread_mutex_lock pthread.h HAVE_PTHREAD_MUTEX_LOCK)
 106 endif()
 107 check_symbol_exists(sbrk unistd.h HAVE_SBRK)
 108 check_symbol_exists(strtoll stdlib.h HAVE_STRTOLL)
 109 check_symbol_exists(strerror string.h HAVE_STRERROR)
 110 check_symbol_exists(strerror_r string.h HAVE_STRERROR_R)
 111 check_symbol_exists(strerror_s string.h HAVE_STRERROR_S)
 112 check_symbol_exists(setenv stdlib.h HAVE_SETENV)
 113 if ( LLVM_ON_WIN32 )
 114   check_symbol_exists(_chsize_s io.h HAVE__CHSIZE_S)
 115 endif()
 116 if( HAVE_ARGZ_H )
 117   check_symbol_exists(argz_append argz.h HAVE_ARGZ_APPEND)
 118   check_symbol_exists(argz_create_sep argz.h HAVE_ARGZ_CREATE_SEP)
 119   check_symbol_exists(argz_insert argz.h HAVE_ARGZ_INSERT)
 120   check_symbol_exists(argz_next argz.h HAVE_ARGZ_NEXT)
 121   check_symbol_exists(argz_stringify argz.h HAVE_ARGZ_STRINGIFY)
 122 endif()
 123
 124 check_symbol_exists(__GLIBC__ stdio.h LLVM_USING_GLIBC)
 125 if( LLVM_USING_GLIBC )
 126   add_llvm_definitions( -D_GNU_SOURCE )
 127 endif()
 128
 129 # Type checks
 130 check_type_exists(std::bidirectional_iterator<int,int> "iterator;iostream" HAVE_BI_ITERATOR)
 131 check_type_exists(std::iterator<int,int,int> iterator HAVE_STD_ITERATOR)
 132 check_type_exists(std::forward_iterator<int,int> iterator HAVE_FWD_ITERATOR)
 133
 134 set(headers "")
 135 if (HAVE_SYS_TYPES_H)
 136   set(headers ${headers} "sys/types.h")
 137 endif()
 138
 139 if (HAVE_INTTYPES_H)
 140   set(headers ${headers} "inttypes.h")
 141 endif()
 142
 143 if (HAVE_STDINT_H)
 144   set(headers ${headers} "stdint.h")
 145 endif()
 146
 147 check_type_exists(int64_t "${headers}" HAVE_INT64_T)
 148 check_type_exists(uint64_t "${headers}" HAVE_UINT64_T)
 149 check_type_exists(u_int64_t "${headers}" HAVE_U_INT64_T)
 150
 151 # available programs checks
 152 function(llvm_find_program name)
 153   string(TOUPPER ${name} NAME)
 154   find_program(LLVM_PATH_${NAME} ${name})
 155   mark_as_advanced(LLVM_PATH_${NAME})
 156   if(LLVM_PATH_${NAME})
 157     set(HAVE_${NAME} 1 CACHE INTERNAL "Is ${name} available ?")
 158     mark_as_advanced(HAVE_${NAME})
 159   else(LLVM_PATH_${NAME})
 160     set(HAVE_${NAME} "" CACHE INTERNAL "Is ${name} available ?")
 161   endif(LLVM_PATH_${NAME})
 162 endfunction()
 163
 164 llvm_find_program(gv)
 165 llvm_find_program(circo)
 166 llvm_find_program(twopi)
 167 llvm_find_program(neato)
 168 llvm_find_program(fdp)
 169 llvm_find_program(dot)
 170 llvm_find_program(dotty)
 171
 172 # Define LLVM_MULTITHREADED if gcc atomic builtins exists.
 173 include(CheckAtomic)
 174
 175 set(ENABLE_PIC ${LLVM_ENABLE_PIC})
 176
 177 include(CheckCXXCompilerFlag)
 178
 179 check_cxx_compiler_flag("-Wno-variadic-macros" SUPPORTS_NO_VARIADIC_MACROS_FLAG)
 180
 181 include(GetTargetTriple)
 182 get_target_triple(LLVM_HOSTTRIPLE)
 183
 184 # FIXME: We don't distinguish the target and the host. :(
 185 set(TARGET_TRIPLE "${LLVM_HOSTTRIPLE}")
 186
 187 # Determine the native architecture.
 188 string(TOLOWER "${LLVM_TARGET_ARCH}" LLVM_NATIVE_ARCH)
 189 if( LLVM_NATIVE_ARCH STREQUAL "host" )
 190   string(REGEX MATCH "^[^-]*" LLVM_NATIVE_ARCH ${LLVM_HOSTTRIPLE})
 191 endif ()
 192
 193 if (LLVM_NATIVE_ARCH MATCHES "i[2-6]86")
 194   set(LLVM_NATIVE_ARCH X86)
 195 elseif (LLVM_NATIVE_ARCH STREQUAL "x86")
 196   set(LLVM_NATIVE_ARCH X86)
 197 elseif (LLVM_NATIVE_ARCH STREQUAL "amd64")
 198   set(LLVM_NATIVE_ARCH X86)
 199 elseif (LLVM_NATIVE_ARCH STREQUAL "x86_64")
 200   set(LLVM_NATIVE_ARCH X86)
 201 elseif (LLVM_NATIVE_ARCH MATCHES "sparc")
 202   set(LLVM_NATIVE_ARCH Sparc)
 203 elseif (LLVM_NATIVE_ARCH MATCHES "powerpc")
 204   set(LLVM_NATIVE_ARCH PowerPC)
 205 elseif (LLVM_NATIVE_ARCH MATCHES "alpha")
 206   set(LLVM_NATIVE_ARCH Alpha)
 207 elseif (LLVM_NATIVE_ARCH MATCHES "arm")
 208   set(LLVM_NATIVE_ARCH ARM)
 209 elseif (LLVM_NATIVE_ARCH MATCHES "mips")
 210   set(LLVM_NATIVE_ARCH Mips)
 211 elseif (LLVM_NATIVE_ARCH MATCHES "xcore")
 212   set(LLVM_NATIVE_ARCH XCore)
 213 elseif (LLVM_NATIVE_ARCH MATCHES "msp430")
 214   set(LLVM_NATIVE_ARCH MSP430)
 215 else ()
 216   message(STATUS
 217     "Unknown architecture ${LLVM_NATIVE_ARCH}; lli will not JIT code")
 218   set(LLVM_NATIVE_ARCH)
 219 endif ()
 220
 221 if (LLVM_NATIVE_ARCH)
 222   list(FIND LLVM_TARGETS_TO_BUILD ${LLVM_NATIVE_ARCH} NATIVE_ARCH_IDX)
 223   if (NATIVE_ARCH_IDX EQUAL -1)
 224     message(STATUS
 225       "Native target ${LLVM_NATIVE_ARCH} is not selected; lli will not JIT code")
 226     set(LLVM_NATIVE_ARCH)
 227   else ()
 228     message(STATUS "Native target architecture is ${LLVM_NATIVE_ARCH}")
 229     set(LLVM_NATIVE_TARGET LLVMInitialize${LLVM_NATIVE_ARCH}Target)
 230     set(LLVM_NATIVE_TARGETINFO LLVMInitialize${LLVM_NATIVE_ARCH}TargetInfo)
 231     set(LLVM_NATIVE_ASMPRINTER LLVMInitialize${LLVM_NATIVE_ARCH}AsmPrinter)
 232   endif ()
 233 endif()
 234
 235 if( MINGW )
 236   set(HAVE_LIBIMAGEHLP 1)
 237   set(HAVE_LIBPSAPI 1)
 238   # TODO: Check existence of libraries.
 239   #   include(CheckLibraryExists)
 240   #   CHECK_LIBRARY_EXISTS(imagehlp ??? . HAVE_LIBIMAGEHLP)
 241 endif( MINGW )
 242
 243 if( MSVC )
 244   set(error_t int)
 245   set(mode_t "unsigned short")
 246   set(LTDL_SHLIBPATH_VAR "PATH")
 247   set(LTDL_SYSSEARCHPATH "")
 248   set(LTDL_DLOPEN_DEPLIBS 1)
 249   set(SHLIBEXT ".lib")
 250   set(LTDL_OBJDIR "_libs")
 251   set(HAVE_STRTOLL 1)
 252   set(strtoll "_strtoi64")
 253   set(strtoull "_strtoui64")
 254   set(stricmp "_stricmp")
 255   set(strdup "_strdup")
 256 else( MSVC )
 257   set(LTDL_SHLIBPATH_VAR "LD_LIBRARY_PATH")
 258   set(LTDL_SYSSEARCHPATH "") # TODO
 259   set(LTDL_DLOPEN_DEPLIBS 0)  # TODO
 260 endif( MSVC )
 261
 262 # FIXME: Signal handler return type, currently hardcoded to 'void'
 263 set(RETSIGTYPE void)
 264
 265 if( LLVM_ENABLE_THREADS )
 266   if( HAVE_PTHREAD_H OR WIN32 )
 267     set(ENABLE_THREADS 1)
 268   endif()
 269 endif()
 270
 271 if( ENABLE_THREADS )
 272   message(STATUS "Threads enabled.")
 273 else( ENABLE_THREADS )
 274   message(STATUS "Threads disabled.")
 275 endif()
 276
 277 set(LLVM_PREFIX ${CMAKE_INSTALL_PREFIX})
 278
 279 configure_file(
 280   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/config.h.cmake
 281   ${LLVM_BINARY_DIR}/include/llvm/Config/config.h
 282   )
 283
 284 configure_file(
 285   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/llvm-config.h.cmake
 286   ${LLVM_BINARY_DIR}/include/llvm/Config/llvm-config.h
 287   )
 288
 289 configure_file(
 290   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Support/DataTypes.h.cmake
 291   ${LLVM_BINARY_DIR}/include/llvm/Support/DataTypes.h
 292   )
 293