cmake/config-ix.cmake

   1 include(CheckIncludeFile)
   2 include(CheckLibraryExists)
   3 include(CheckSymbolExists)
   4 include(CheckFunctionExists)
   5 include(CheckCXXSourceCompiles)
   6
   7 # Helper macros and functions
   8 macro(add_cxx_include result files)
   9   set(${result} "")
  10   foreach (file_name ${files})
  11      set(${result} "${${result}}#include<${file_name}>\n")
  12   endforeach()
  13 endmacro(add_cxx_include files result)
  14
  15 function(check_type_exists type files variable)
  16   add_cxx_include(includes "${files}")
  17   CHECK_CXX_SOURCE_COMPILES("
  18     ${includes} ${type} typeVar;
  19     int main() {
  20         return 0;
  21     }
  22     " ${variable})
  23 endfunction()
  24
  25 # include checks
  26 check_include_file(argz.h HAVE_ARGZ_H)
  27 check_include_file(assert.h HAVE_ASSERT_H)
  28 check_include_file(dirent.h HAVE_DIRENT_H)
  29 check_include_file(dl.h HAVE_DL_H)
  30 check_include_file(dld.h HAVE_DLD_H)
  31 check_include_file(dlfcn.h HAVE_DLFCN_H)
  32 check_include_file(errno.h HAVE_ERRNO_H)
  33 check_include_file(execinfo.h HAVE_EXECINFO_H)
  34 check_include_file(fcntl.h HAVE_FCNTL_H)
  35 check_include_file(inttypes.h HAVE_INTTYPES_H)
  36 check_include_file(limits.h HAVE_LIMITS_H)
  37 check_include_file(link.h HAVE_LINK_H)
  38 check_include_file(malloc.h HAVE_MALLOC_H)
  39 check_include_file(malloc/malloc.h HAVE_MALLOC_MALLOC_H)
  40 check_include_file(memory.h HAVE_MEMORY_H)
  41 check_include_file(ndir.h HAVE_NDIR_H)
  42 if( NOT LLVM_ON_WIN32 )
  43   check_include_file(pthread.h HAVE_PTHREAD_H)
  44 endif()
  45 check_include_file(setjmp.h HAVE_SETJMP_H)
  46 check_include_file(signal.h HAVE_SIGNAL_H)
  47 check_include_file(stdint.h HAVE_STDINT_H)
  48 check_include_file(stdio.h HAVE_STDIO_H)
  49 check_include_file(stdlib.h HAVE_STDLIB_H)
  50 check_include_file(string.h HAVE_STRING_H)
  51 check_include_file(sys/dir.h HAVE_SYS_DIR_H)
  52 check_include_file(sys/dl.h HAVE_SYS_DL_H)
  53 check_include_file(sys/ioctl.h HAVE_SYS_IOCTL_H)
  54 check_include_file(sys/mman.h HAVE_SYS_MMAN_H)
  55 check_include_file(sys/ndir.h HAVE_SYS_NDIR_H)
  56 check_include_file(sys/param.h HAVE_SYS_PARAM_H)
  57 check_include_file(sys/resource.h HAVE_SYS_RESOURCE_H)
  58 check_include_file(sys/stat.h HAVE_SYS_STAT_H)
  59 check_include_file(sys/time.h HAVE_SYS_TIME_H)
  60 check_include_file(sys/types.h HAVE_SYS_TYPES_H)
  61 check_include_file(sys/wait.h HAVE_SYS_WAIT_H)
  62 check_include_file(termios.h HAVE_TERMIOS_H)
  63 check_include_file(unistd.h HAVE_UNISTD_H)
  64 check_include_file(utime.h HAVE_UTIME_H)
  65 check_include_file(windows.h HAVE_WINDOWS_H)
  66
  67 # library checks
  68 if( NOT LLVM_ON_WIN32 )
  69   check_library_exists(pthread pthread_create "" HAVE_LIBPTHREAD)
  70   check_library_exists(pthread pthread_getspecific "" HAVE_PTHREAD_GETSPECIFIC)
  71   check_library_exists(pthread pthread_rwlock_init "" HAVE_PTHREAD_RWLOCK_INIT)
  72   check_library_exists(dl dlopen "" HAVE_LIBDL)
  73 endif()
  74
  75 # function checks
  76 check_symbol_exists(getpagesize unistd.h HAVE_GETPAGESIZE)
  77 check_symbol_exists(getrusage sys/resource.h HAVE_GETRUSAGE)
  78 check_symbol_exists(setrlimit sys/resource.h HAVE_SETRLIMIT)
  79 check_function_exists(isatty HAVE_ISATTY)
  80 check_symbol_exists(isinf cmath HAVE_ISINF_IN_CMATH)
  81 check_symbol_exists(isinf math.h HAVE_ISINF_IN_MATH_H)
  82 check_symbol_exists(finite ieeefp.h HAVE_FINITE_IN_IEEEFP_H)
  83 check_symbol_exists(isnan cmath HAVE_ISNAN_IN_CMATH)
  84 check_symbol_exists(isnan math.h HAVE_ISNAN_IN_MATH_H)
  85 check_symbol_exists(ceilf math.h HAVE_CEILF)
  86 check_symbol_exists(floorf math.h HAVE_FLOORF)
  87 check_symbol_exists(mallinfo malloc.h HAVE_MALLINFO)
  88 check_symbol_exists(malloc_zone_statistics malloc/malloc.h
  89                     HAVE_MALLOC_ZONE_STATISTICS)
  90 check_symbol_exists(mkdtemp "stdlib.h;unistd.h" HAVE_MKDTEMP)
  91 check_symbol_exists(mkstemp "stdlib.h;unistd.h" HAVE_MKSTEMP)
  92 check_symbol_exists(mktemp "stdlib.h;unistd.h" HAVE_MKTEMP)
  93 if( NOT LLVM_ON_WIN32 )
  94   check_symbol_exists(pthread_mutex_lock pthread.h HAVE_PTHREAD_MUTEX_LOCK)
  95 endif()
  96 check_symbol_exists(sbrk unistd.h HAVE_SBRK)
  97 check_symbol_exists(strtoll stdlib.h HAVE_STRTOLL)
  98 check_symbol_exists(strerror string.h HAVE_STRERROR)
  99 check_symbol_exists(strerror_r string.h HAVE_STRERROR_R)
 100 check_symbol_exists(strerror_s string.h HAVE_STRERROR_S)
 101 check_symbol_exists(setenv stdlib.h HAVE_SETENV)
 102
 103 check_symbol_exists(__GLIBC__ stdio.h LLVM_USING_GLIBC)
 104 if( LLVM_USING_GLIBC )
 105   add_llvm_definitions( -D_GNU_SOURCE )
 106 endif()
 107
 108 # Type checks
 109 check_type_exists(std::bidirectional_iterator<int,int> "iterator;iostream" HAVE_BI_ITERATOR)
 110 check_type_exists(std::iterator<int,int,int> iterator HAVE_STD_ITERATOR)
 111 check_type_exists(std::forward_iterator<int,int> iterator HAVE_FWD_ITERATOR)
 112
 113 set(headers "")
 114 if (HAVE_SYS_TYPES_H)
 115   set(headers ${headers} "sys/types.h")
 116 endif()
 117
 118 if (HAVE_INTTYPES_H)
 119   set(headers ${headers} "inttypes.h")
 120 endif()
 121
 122 if (HAVE_STDINT_H)
 123   set(headers ${headers} "stdint.h")
 124 endif()
 125
 126 check_type_exists(uint64_t "${headers}" HAVE_UINT64_T)
 127 check_type_exists(u_int64_t "${headers}" HAVE_U_INT64_T)
 128
 129 # available programs checks
 130 find_program(DOTTY_EXECUTABLE dotty)
 131 if(DOTTY_EXECUTABLE)
 132   set(HAVE_DOTTY 1)
 133   set(LLVM_PATH_DOTTY ${DOTTY_EXECUTABLE})
 134   mark_as_advanced(HAVE_DOTTY)
 135   mark_as_advanced(LLVM_PATH_DOTTY)
 136 endif()
 137
 138 # Define LLVM_MULTITHREADED if gcc atomic builtins exists.
 139 include(CheckAtomic)
 140
 141 include(CheckCXXCompilerFlag)
 142 # On windows all code is position-independent and mingw warns if -fPIC
 143 # is in the command-line.
 144 if( NOT WIN32 )
 145   check_cxx_compiler_flag("-fPIC" SUPPORTS_FPIC_FLAG)
 146 endif()
 147
 148 include(GetTargetTriple)
 149 get_target_triple(LLVM_HOSTTRIPLE)
 150 message(STATUS "LLVM_HOSTTRIPLE: ${LLVM_HOSTTRIPLE}")
 151
 152 # Determine the native architecture.
 153 string(TOLOWER "${LLVM_TARGET_ARCH}" LLVM_NATIVE_ARCH)
 154 if( LLVM_NATIVE_ARCH STREQUAL "host" )
 155   string(REGEX MATCH "^[^-]*" LLVM_NATIVE_ARCH ${LLVM_HOSTTRIPLE})
 156 endif ()
 157
 158 if (LLVM_NATIVE_ARCH MATCHES "i[2-6]86")
 159   set(LLVM_NATIVE_ARCH X86)
 160 elseif (LLVM_NATIVE_ARCH STREQUAL "x86")
 161   set(LLVM_NATIVE_ARCH X86)
 162 elseif (LLVM_NATIVE_ARCH STREQUAL "amd64")
 163   set(LLVM_NATIVE_ARCH X86)
 164 elseif (LLVM_NATIVE_ARCH STREQUAL "x86_64")
 165   set(LLVM_NATIVE_ARCH X86)
 166 elseif (LLVM_NATIVE_ARCH MATCHES "sparc")
 167   set(LLVM_NATIVE_ARCH Sparc)
 168 elseif (LLVM_NATIVE_ARCH MATCHES "powerpc")
 169   set(LLVM_NATIVE_ARCH PowerPC)
 170 elseif (LLVM_NATIVE_ARCH MATCHES "alpha")
 171   set(LLVM_NATIVE_ARCH Alpha)
 172 elseif (LLVM_NATIVE_ARCH MATCHES "arm")
 173   set(LLVM_NATIVE_ARCH ARM)
 174 elseif (LLVM_NATIVE_ARCH MATCHES "mips")
 175   set(LLVM_NATIVE_ARCH Mips)
 176 elseif (LLVM_NATIVE_ARCH MATCHES "pic16")
 177   set(LLVM_NATIVE_ARCH "PIC16")
 178 elseif (LLVM_NATIVE_ARCH MATCHES "xcore")
 179   set(LLVM_NATIVE_ARCH XCore)
 180 elseif (LLVM_NATIVE_ARCH MATCHES "msp430")
 181   set(LLVM_NATIVE_ARCH MSP430)
 182 else ()
 183   message(STATUS
 184     "Unknown architecture ${LLVM_NATIVE_ARCH}; lli will not JIT code")
 185   set(LLVM_NATIVE_ARCH)
 186 endif ()
 187
 188 if (LLVM_NATIVE_ARCH)
 189   list(FIND LLVM_TARGETS_TO_BUILD ${LLVM_NATIVE_ARCH} NATIVE_ARCH_IDX)
 190   if (NATIVE_ARCH_IDX EQUAL -1)
 191     message(STATUS
 192       "Native target ${LLVM_NATIVE_ARCH} is not selected; lli will not JIT code")
 193     set(LLVM_NATIVE_ARCH)
 194   else ()
 195     message(STATUS "Native target architecture is ${LLVM_NATIVE_ARCH}")
 196   endif ()
 197 endif()
 198
 199 if( MINGW )
 200   set(HAVE_LIBIMAGEHLP 1)
 201   set(HAVE_LIBPSAPI 1)
 202   # TODO: Check existence of libraries.
 203   #   include(CheckLibraryExists)
 204   #   CHECK_LIBRARY_EXISTS(imagehlp ??? . HAVE_LIBIMAGEHLP)
 205 endif( MINGW )
 206
 207 if( MSVC )
 208   set(error_t int)
 209   set(mode_t "unsigned short")
 210   set(LTDL_SHLIBPATH_VAR "PATH")
 211   set(LTDL_SYSSEARCHPATH "")
 212   set(LTDL_DLOPEN_DEPLIBS 1)
 213   set(SHLIBEXT ".lib")
 214   set(LTDL_OBJDIR "_libs")
 215   set(HAVE_STRTOLL 1)
 216   set(strtoll "_strtoi64")
 217   set(strtoull "_strtoui64")
 218   set(stricmp "_stricmp")
 219   set(strdup "_strdup")
 220 else( MSVC )
 221   set(LTDL_SHLIBPATH_VAR "LD_LIBRARY_PATH")
 222   set(LTDL_SYSSEARCHPATH "") # TODO
 223   set(LTDL_DLOPEN_DEPLIBS 0)  # TODO
 224 endif( MSVC )
 225
 226 # FIXME: Signal handler return type, currently hardcoded to 'void'
 227 set(RETSIGTYPE void)
 228
 229 if( LLVM_ENABLE_THREADS )
 230   if( HAVE_PTHREAD_H OR WIN32 )
 231     set(ENABLE_THREADS 1)
 232   endif()
 233 endif()
 234
 235 if( ENABLE_THREADS )
 236   message(STATUS "Threads enabled.")
 237 else( ENABLE_THREADS )
 238   message(STATUS "Threads disabled.")
 239 endif()
 240
 241 configure_file(
 242   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/config.h.cmake
 243   ${LLVM_BINARY_DIR}/include/llvm/Config/config.h
 244   )
 245
 246 configure_file(
 247   ${LLVM_MAIN_INCLUDE_DIR}/llvm/System/DataTypes.h.cmake
 248   ${LLVM_BINARY_DIR}/include/llvm/System/DataTypes.h
 249   )
 250