autoconf/configure.ac

   1 dnl === configure.ac --------------------------------------------------------===
   2 dnl                     The LLVM Compiler Infrastructure
   3 dnl
   4 dnl This file was developed by the LLVM research group and is distributed under
   5 dnl the University of Illinois Open Source License. See LICENSE.TXT for details.
   6 dnl
   7 dnl===-----------------------------------------------------------------------===
   8 dnl This is the LLVM configuration script. It is processed by the autoconf
   9 dnl program to produce a script named configure. This script contains the
  10 dnl configuration checks that LLVM needs in order to support multiple platforms.
  11 dnl This file is composed of 10 sections per the recommended organization of
  12 dnl autoconf input defined in the autoconf documentation. As this file evolves,
  13 dnl please keep the various types of checks within their sections. The sections
  14 dnl are as follows:
  15 dnl
  16 dnl SECTION 1: Initialization & Setup
  17 dnl SECTION 2: Architecture, target, and host checks
  18 dnl SECTION 3: Command line arguments for the configure script.
  19 dnl SECTION 4: Check for programs we need and that they are the right version
  20 dnl SECTION 5: Check for libraries
  21 dnl SECTION 6: Check for header files
  22 dnl SECTION 7: Check for types and structures
  23 dnl SECTION 8: Check for specific functions needed
  24 dnl SECTION 9: Additional checks, variables, etc.
  25 dnl SECTION 10: Specify the output files and generate it
  26 dnl
  27 dnl===-----------------------------------------------------------------------===
  28 dnl===
  29 dnl=== SECTION 1: Initialization & Setup
  30 dnl===
  31 dnl===-----------------------------------------------------------------------===
  32 dnl Initialize autoconf and define the package name, version number and
  33 dnl email address for reporting bugs.
  34 AC_INIT([[llvm]],[[1.8cvs]],[llvmbugs@cs.uiuc.edu])
  35
  36 dnl Provide a copyright substitution and ensure the copyright notice is included
  37 dnl in the output of --version option of the generated configure script.
  38 AC_SUBST(LLVM_COPYRIGHT,["Copyright (c) 2003-2005 University of Illinois at Urbana-Champaign."])
  39 AC_COPYRIGHT([Copyright (c) 2003-2005 University of Illinois at Urbana-Champaign.])
  40
  41 dnl Indicate that we require autoconf 2.59 or later. Ths is needed because we
  42 dnl use some autoconf macros only available in 2.59.
  43 AC_PREREQ(2.59)
  44
  45 dnl Verify that the source directory is valid. This makes sure that we are
  46 dnl configuring LLVM and not some other package (it validates --srcdir argument)
  47 AC_CONFIG_SRCDIR([lib/VMCore/Module.cpp])
  48
  49 dnl Place all of the extra autoconf files into the config subdirectory. Tell
  50 dnl various tools where the m4 autoconf macros are.
  51 AC_CONFIG_AUX_DIR([autoconf])
  52
  53 dnl Quit if the source directory has already been configured.
  54 dnl NOTE: This relies upon undocumented autoconf behavior.
  55 if test ${srcdir} != "." ; then
  56   if test -f ${srcdir}/include/llvm/Config/config.h ; then
  57     AC_MSG_ERROR([Already configured in ${srcdir}])
  58   fi
  59 fi
  60
  61 dnl Configure all of the projects present in our source tree. While we could
  62 dnl just AC_CONFIG_SUBDIRS on the set of directories in projects that have a
  63 dnl configure script, that usage of the AC_CONFIG_SUBDIRS macro is deprecated.
  64 dnl Instead we match on the known projects.
  65 for i in `ls ${srcdir}/projects`
  66 do
  67   if test -d ${srcdir}/projects/${i} ; then
  68     case ${i} in
  69       "CVS") ;;
  70       "sample")       AC_CONFIG_SUBDIRS([projects/sample])    ;;
  71       "Stacker")      AC_CONFIG_SUBDIRS([projects/Stacker])   ;;
  72       "llvm-test")    AC_CONFIG_SUBDIRS([projects/llvm-test]) ;;
  73       "llvm-reopt")   AC_CONFIG_SUBDIRS([projects/llvm-reopt]);;
  74       "llvm-gcc")     AC_CONFIG_SUBDIRS([projects/llvm-gcc])  ;;
  75       "llvm-java")    AC_CONFIG_SUBDIRS([projects/llvm-java]) ;;
  76       "llvm-tv")      AC_CONFIG_SUBDIRS([projects/llvm-tv])   ;;
  77       "llvm-poolalloc") AC_CONFIG_SUBDIRS([projects/llvm-poolalloc]) ;;
  78       "llvm-kernel")  AC_CONFIG_SUBDIRS([projects/llvm-kernel]) ;;
  79       *)
  80         AC_MSG_WARN([Unknown project (${i}) won't be configured automatically])
  81         ;;
  82     esac
  83   fi
  84 done
  85
  86 dnl===-----------------------------------------------------------------------===
  87 dnl===
  88 dnl=== SECTION 2: Architecture, target, and host checks
  89 dnl===
  90 dnl===-----------------------------------------------------------------------===
  91
  92 dnl Check the target for which we're compiling and the host that will do the
  93 dnl compilations. This will tell us which LLVM compiler will be used for
  94 dnl compiling SSA into object code. This needs to be done early because
  95 dnl following tests depend on it.
  96 AC_CANONICAL_TARGET
  97
  98 dnl Determine the platform type and cache its value. This helps us configure
  99 dnl the System library to the correct build platform.
 100 AC_CACHE_CHECK([type of operating system we're on],
 101                [llvm_cv_os_type],
 102 [case $build in
 103   *-*-aix*)
 104     llvm_cv_os_type="AIX"
 105     llvm_cv_platform_type="Unix" ;;
 106   *-*-cygwin*)
 107     llvm_cv_os_type="Cygwin"
 108     llvm_cv_platform_type="Unix" ;;
 109   *-*-darwin*)
 110     llvm_cv_os_type="Darwin"
 111     llvm_cv_platform_type="Unix" ;;
 112   *-*-freebsd*)
 113     llvm_cv_os_type="FreeBSD"
 114     llvm_cv_platform_type="Unix" ;;
 115   *-*-openbsd*)
 116     llvm_cv_os_type="OpenBSD"
 117     llvm_cv_platform_type="Unix" ;;
 118   *-*-hpux*)
 119     llvm_cv_os_type="HP-UX"
 120     llvm_cv_platform_type="Unix" ;;
 121   *-*-interix*)
 122     llvm_cv_os_type="Interix"
 123     llvm_cv_platform_type="Unix" ;;
 124   *-*-linux*)
 125     llvm_cv_os_type="Linux"
 126     llvm_cv_platform_type="Unix" ;;
 127   *-*-solaris*)
 128     llvm_cv_os_type="SunOS"
 129     llvm_cv_platform_type="Unix" ;;
 130   *-*-win32*)
 131     llvm_cv_os_type="Win32"
 132     llvm_cv_platform_type="Win32" ;;
 133   *-*-mingw*)
 134     llvm_cv_os_type="MingW"
 135     llvm_cv_platform_type="Win32" ;;
 136   *)
 137     llvm_cv_os_type="Unknown"
 138     llvm_cv_platform_type="Unknown" ;;
 139 esac])
 140
 141 dnl Make sure we aren't attempting to configure for an unknown system
 142 if test "$llvm_cv_os_type" = "Unknown" ; then
 143   AC_MSG_ERROR([Operating system is unknown, configure can't continue])
 144 fi
 145
 146 dnl Set the "OS" Makefile variable based on the platform type so the
 147 dnl makefile can configure itself to specific build hosts
 148 AC_SUBST(OS,$llvm_cv_os_type)
 149
 150 dnl Set the "LLVM_ON_*" variables based on llvm_cvs_platform_type
 151 dnl This is used by lib/System to determine the basic kind of implementation
 152 dnl to use.
 153 case $llvm_cv_platform_type in
 154   Unix)
 155     AC_DEFINE([LLVM_ON_UNIX],[1],[Define if this is Unixish platform])
 156     AC_SUBST(LLVM_ON_UNIX,[1])
 157     AC_SUBST(LLVM_ON_WIN32,[0])
 158     ;;
 159   Win32)
 160     AC_DEFINE([LLVM_ON_WIN32],[1],[Define if this is Win32ish platform])
 161     AC_SUBST(LLVM_ON_UNIX,[0])
 162     AC_SUBST(LLVM_ON_WIN32,[1])
 163     ;;
 164 esac
 165
 166 dnl Determine what our target architecture is and configure accordingly.
 167 dnl This will allow Makefiles to make a distinction between the hardware and
 168 dnl the OS.
 169 AC_CACHE_CHECK([target architecture],[llvm_cv_target_arch],
 170 [case $target in
 171   i?86-*)                 llvm_cv_target_arch="x86" ;;
 172   amd64-* | x86_64-*)     llvm_cv_target_arch="x86_64" ;;
 173   sparc*-*)               llvm_cv_target_arch="Sparc" ;;
 174   powerpc*-*)             llvm_cv_target_arch="PowerPC" ;;
 175   alpha*-*)               llvm_cv_target_arch="Alpha" ;;
 176   ia64-*)                 llvm_cv_target_arch="IA64" ;;
 177   *)                      llvm_cv_target_arch="Unknown" ;;
 178 esac])
 179
 180 if test "$llvm_cv_target_arch" = "Unknown" ; then
 181   AC_MSG_WARN([Configuring LLVM for an unknown target archicture])
 182 fi
 183
 184 dnl Define a substitution, ARCH, for the target architecture
 185 AC_SUBST(ARCH,$llvm_cv_target_arch)
 186
 187 dnl Check for the endianness of the target
 188 AC_C_BIGENDIAN(AC_SUBST([ENDIAN],[big]),AC_SUBST([ENDIAN],[little]))
 189
 190 dnl Check to see if there's a "CVS" directory indicating that this build is
 191 dnl being done from a CVS checkout. This sets up several defaults for the
 192 dnl command line switches. When we build with a CVS directory, we get a
 193 dnl debug with assertions turned on. Without, we assume a source release and we
 194 dnl get an optimized build without assertions. See --enable-optimized and
 195 dnl --enable-assertions below
 196 if test -d "CVS" -o -d "${srcdir}/CVS"; then
 197   cvsbuild="yes"
 198   optimize="no"
 199   AC_SUBST(CVSBUILD,[[CVSBUILD=1]])
 200 else
 201   cvsbuild="no"
 202   optimize="yes"
 203 fi
 204
 205 dnl===-----------------------------------------------------------------------===
 206 dnl===
 207 dnl=== SECTION 3: Command line arguments for the configure script.
 208 dnl===
 209 dnl===-----------------------------------------------------------------------===
 210
 211 dnl --enable-optimized : check whether they want to do an optimized build:
 212 AC_ARG_ENABLE(optimized, AS_HELP_STRING(
 213  [--enable-optimized,Compile with optimizations enabled (default is NO)]),,enableval=$optimize)
 214 if test ${enableval} = "no" ; then
 215   AC_SUBST(ENABLE_OPTIMIZED,[[]])
 216 else
 217   AC_SUBST(ENABLE_OPTIMIZED,[[ENABLE_OPTIMIZED=1]])
 218 fi
 219
 220 dnl --enable-assertions : check whether they want to turn on assertions or not:
 221 AC_ARG_ENABLE(assertions,AS_HELP_STRING(
 222   [--enable-assertions,Compile with assertion checks enabled (default is YES)]),, enableval="yes")
 223 if test ${enableval} = "yes" ; then
 224   AC_SUBST(DISABLE_ASSERTIONS,[[]])
 225 else
 226   AC_SUBST(DISABLE_ASSERTIONS,[[DISABLE_ASSERTIONS=1]])
 227 fi
 228
 229 dnl --enable-debug-runtime : should runtime libraries have debug symbols?
 230 AC_ARG_ENABLE(debug-runtime,
 231    AS_HELP_STRING([--enable-debug-runtime,Build runtime libs with debug symbols (default is NO)]),,enableval=no)
 232 if test ${enableval} = "no" ; then
 233   AC_SUBST(DEBUG_RUNTIME,[[]])
 234 else
 235   AC_SUBST(DEBUG_RUNTIME,[[DEBUG_RUNTIME=1]])
 236 fi
 237
 238 dnl --enable-jit: check whether they want to enable the jit
 239 AC_ARG_ENABLE(jit,
 240   AS_HELP_STRING(--enable-jit,
 241                  [Enable Just In Time Compiling (default is YES)]),,
 242   enableval=default)
 243 if test ${enableval} = "no"
 244 then
 245   AC_SUBST(JIT,[[]])
 246 else
 247   case "$llvm_cv_target_arch" in
 248     x86)     AC_SUBST(TARGET_HAS_JIT,1) ;;
 249     Sparc)   AC_SUBST(TARGET_HAS_JIT,1) ;;
 250     PowerPC) AC_SUBST(TARGET_HAS_JIT,1) ;;
 251     x86_64)  AC_SUBST(TARGET_HAS_JIT,0) ;;
 252     Alpha)   AC_SUBST(TARGET_HAS_JIT,1) ;;
 253     IA64)    AC_SUBST(TARGET_HAS_JIT,0) ;;
 254     *)       AC_SUBST(TARGET_HAS_JIT,0) ;;
 255   esac
 256 fi
 257
 258 dnl Allow enablement of doxygen generated documentation
 259 AC_ARG_ENABLE(doxygen,
 260               AS_HELP_STRING([--enable-doxygen],
 261                              [Build doxygen documentation (default is NO)]),,
 262                              enableval=default)
 263 case "$enableval" in
 264   yes) AC_SUBST(ENABLE_DOXYGEN,[1]) ;;
 265   no)  AC_SUBST(ENABLE_DOXYGEN,[0]) ;;
 266   default) AC_SUBST(ENABLE_DOXYGEN,[0]) ;;
 267   *) AC_MSG_ERROR([Invalid setting for --enable-doxygen. Use "yes" or "no"]) ;;
 268 esac
 269
 270 dnl Allow disablement of threads
 271 AC_ARG_ENABLE(threads,
 272               AS_HELP_STRING([--enable-threads],
 273                              [Use threads if available (default is YES)]),,
 274                              enableval=yes)
 275 case "$enableval" in
 276   yes) AC_SUBST(ENABLE_THREADS,[1]) ;;
 277   no)  AC_SUBST(ENABLE_THREADS,[0]) ;;
 278   *) AC_MSG_ERROR([Invalid setting for --enable-threads. Use "yes" or "no"]) ;;
 279 esac
 280 AC_DEFINE_UNQUOTED([ENABLE_THREADS],$ENABLE_THREADS,[Define if threads enabled])
 281
 282 dnl Allow specific targets to be specified for building (or not)
 283 TARGETS_TO_BUILD=""
 284 AC_ARG_ENABLE([targets],AS_HELP_STRING([--enable-target],
 285     [Build specific host targets: all,host-only,{target-name} (default=all)]),,
 286     enableval=all)
 287 case "$enableval" in
 288   all) TARGETS_TO_BUILD="X86 Sparc PowerPC Alpha IA64 ARM" ;;
 289   host-only)
 290     case "$llvm_cv_target_arch" in
 291       x86)     TARGETS_TO_BUILD="X86" ;;
 292       x86_64)  TARGETS_TO_BUILD="X86" ;;
 293       Sparc)   TARGETS_TO_BUILD="Sparc" ;;
 294       PowerPC) TARGETS_TO_BUILD="PowerPC" ;;
 295       Alpha)   TARGETS_TO_BUILD="Alpha" ;;
 296       IA64)    TARGETS_TO_BUILD="IA64" ;;
 297       *)       AC_MSG_ERROR([Can not set target to build]) ;;
 298     esac
 299     ;;
 300   *)for a_target in `echo $enableval|sed -e 's/,/ /g' ` ; do
 301       case "$a_target" in
 302         x86)     TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 303         x86_64)  TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 304         sparc)   TARGETS_TO_BUILD="Sparc $TARGETS_TO_BUILD" ;;
 305         powerpc) TARGETS_TO_BUILD="PowerPC $TARGETS_TO_BUILD" ;;
 306         alpha)   TARGETS_TO_BUILD="Alpha $TARGETS_TO_BUILD" ;;
 307         ia64)    TARGETS_TO_BUILD="IA64 $TARGETS_TO_BUILD" ;;
 308         *) AC_MSG_ERROR([Unrecognized target $a_target]) ;;
 309       esac
 310   done
 311   ;;
 312 esac
 313 TARGETS_TO_BUILD="CBackend $TARGETS_TO_BUILD"
 314 AC_SUBST(TARGETS_TO_BUILD,$TARGETS_TO_BUILD)
 315
 316 dnl Allow a specific llvm-gcc/llvm-g++ pair to be used with this LLVM config.
 317 AC_ARG_WITH(llvmgccdir,
 318   AS_HELP_STRING([--with-llvmgccdir],
 319     [Specify location of llvm-gcc install dir (default searches PATH)]),,
 320     withval=default)
 321 case "$withval" in
 322   default) WITH_LLVMGCCDIR=default ;;
 323   /* | [[A-Za-z]]:[[\\/]]*)      WITH_LLVMGCCDIR=$withval ;;
 324   *) AC_MSG_ERROR([Invalid path for --with-llvmgccdir. Provide full path]) ;;
 325 esac
 326
 327
 328 dnl===-----------------------------------------------------------------------===
 329 dnl===
 330 dnl=== SECTION 4: Check for programs we need and that they are the right version
 331 dnl===
 332 dnl===-----------------------------------------------------------------------===
 333
 334 dnl Check for compilation tools
 335 AC_PROG_CPP
 336 AC_PROG_CC(gcc)
 337 AC_PROG_CXX(g++)
 338 AC_PROG_FLEX
 339 AC_PROG_BISON
 340
 341 dnl Check for the tools that the makefiles require
 342 AC_CHECK_GNU_MAKE
 343 AC_PROG_LN_S
 344 AC_PATH_PROG(CMP, [cmp], [cmp])
 345 AC_PATH_PROG(CP, [cp], [cp])
 346 AC_PATH_PROG(DATE, [date], [date])
 347 AC_PATH_PROG(FIND, [find], [find])
 348 AC_PATH_PROG(GREP, [grep], [grep])
 349 AC_PATH_PROG(MKDIR,[mkdir],[mkdir])
 350 AC_PATH_PROG(MV,   [mv],   [mv])
 351 AC_PROG_RANLIB
 352 AC_PATH_PROG(RM,   [rm],   [rm])
 353 AC_PATH_PROG(SED,  [sed],  [sed])
 354 AC_PATH_PROG(TAR,  [tar],  [gtar])
 355
 356 dnl Looking for misc. graph plotting software
 357 AC_PATH_PROG(GRAPHVIZ, [Graphviz], [echo Graphviz])
 358 if test "$GRAPHVIZ" != "echo Graphviz" ; then
 359   AC_DEFINE([HAVE_GRAPHVIZ],[1],[Define if the Graphviz program is available])
 360   AC_DEFINE_UNQUOTED([LLVM_PATH_GRAPHVIZ],"$GRAPHVIZ",
 361    [Define to path to Graphviz program if found or 'echo Graphviz' otherwise])
 362 fi
 363 AC_PATH_PROG(GV, [gv], [echo gv])
 364 if test "$GV" != "echo gv" ; then
 365   AC_DEFINE([HAVE_GV],[1],[Define if the gv program is available])
 366   AC_DEFINE_UNQUOTED([LLVM_PATH_GV],"$GV",
 367    [Define to path to gv program if found or 'echo gv' otherwise])
 368 fi
 369 AC_PATH_PROG(DOTTY, [dotty], [echo dotty])
 370 if test "$DOTTY" != "echo dotty" ; then
 371   AC_DEFINE([HAVE_DOTTY],[1],[Define if the dotty program is available])
 372   AC_DEFINE_UNQUOTED([LLVM_PATH_DOTTY],"$DOTTY",
 373    [Define to path to dotty program if found or 'echo dotty' otherwise])
 374 fi
 375
 376 dnl Look for a sufficiently recent version of Perl.
 377 LLVM_PROG_PERL([5.006])
 378 AC_SUBST(PERL)
 379 if test x"$PERL" = xnone; then
 380    AC_SUBST(HAVE_PERL,0)
 381 else
 382    AC_SUBST(HAVE_PERL,1)
 383 fi
 384
 385 dnl Find the install program
 386 AC_PROG_INSTALL
 387
 388 dnl Checks for documentation and testing tools that we can do without. If these
 389 dnl are not found then they are set to "true" which always succeeds but does
 390 dnl nothing. This just lets the build output show that we could have done
 391 dnl something if the tool was available.
 392 AC_PATH_PROG(BZIP2,[bzip2],[echo "Skipped: bzip2 not found"])
 393 AC_PATH_PROG(DOT,[dot],[echo "Skipped: dot not found"])
 394 AC_PATH_PROG(DOXYGEN,[doxygen],[echo "Skipped: doxygen not found"])
 395 AC_PATH_PROG(ETAGS,[etags],[echo "Skipped: etags not found"])
 396 AC_PATH_PROG(GROFF,[groff],[echo "Skipped: groff not found"])
 397 AC_PATH_PROG(GZIP,[gzip],[echo "Skipped: gzip not found"])
 398 AC_PATH_PROG(POD2HTML,[pod2html],[echo "Skipped: pod2html not found"])
 399 AC_PATH_PROG(POD2MAN,[pod2man],[echo "Skipped: pod2man not found"])
 400 AC_PATH_PROG(RUNTEST,[runtest],[echo "Skipped: runtest not found"])
 401 DJ_AC_PATH_TCLSH
 402 AC_PATH_PROG(ZIP,[zip],[echo "Skipped: zip not found"])
 403
 404 dnl Determine if the linker supports the -R option.
 405 AC_LINK_USE_R
 406
 407 dnl Check for libtool and the library that has dlopen function (which must come
 408 dnl before the AC_PROG_LIBTOOL check in order to enable dlopening libraries with
 409 dnl libtool).
 410 AC_LIBTOOL_DLOPEN
 411 AC_LIB_LTDL
 412 AC_PROG_LIBTOOL
 413
 414 if test "$lt_cv_dlopen_self" = "yes" ; then
 415   AC_DEFINE([CAN_DLOPEN_SELF],[1],
 416               [Define if dlopen(0) will open the symbols of the program])
 417 fi
 418
 419 dnl Check if we know how to tell etags we are using C++:
 420 etags_version=`$ETAGS --version 2>&1`
 421 case "$etags_version" in
 422         *[Ee]xuberant*) ETAGSFLAGS="--language-force=c++" ;;
 423         *GNU\ Emacs*) ETAGSFLAGS="-l c++" ;;
 424         *) ETAGSFLAGS="" ;;
 425 esac
 426 AC_SUBST(ETAGSFLAGS,$ETAGSFLAGS)
 427
 428 if test "$WITH_LLVMGCCDIR" = "default" ; then
 429   LLVMGCC="llvm-gcc${EXEEXT}"
 430   LLVMGXX="llvm-g++${EXEEXT}"
 431   AC_PATH_PROG(LLVMGCC, $LLVMGCC, [])
 432   AC_PATH_PROG(LLVMGXX, $LLVMGXX, [])
 433 else
 434   LLVMGCC="$WITH_LLVMGCCDIR/bin/llvm-gcc${EXEEXT}"
 435   LLVMGXX="$WITH_LLVMGCCDIR/bin/llvm-g++${EXEEXT}"
 436   AC_SUBST(LLVMGCC,$LLVMGCC)
 437   AC_SUBST(LLVMGXX,$LLVMGXX)
 438 fi
 439
 440 AC_MSG_CHECKING([tool compatibility])
 441
 442 dnl Ensure that compilation tools are GCC or a GNU compatible compiler such as
 443 dnl ICC; we use GCC specific options in the makefiles so the compiler needs
 444 dnl to support those options.
 445 dnl "icc" emits gcc signatures
 446 dnl "icc -no-gcc" emits no gcc signature BUT is still compatible
 447 ICC=no
 448 IXX=no
 449 case $CC in
 450   icc*|icpc*)
 451     ICC=yes
 452     IXX=yes
 453     ;;
 454    *)
 455     ;;
 456 esac
 457
 458 if test "$GCC" != "yes" && test "$ICC" != "yes"
 459 then
 460   AC_MSG_ERROR([gcc|icc required but not found])
 461 fi
 462
 463 dnl Ensure that compilation tools are GCC; we use GCC specific extensions
 464 if test "$GXX" != "yes" && test "$IXX" != "yes"
 465 then
 466   AC_MSG_ERROR([g++|icc required but not found])
 467 fi
 468
 469 dnl Verify that GCC is version 3.0 or higher
 470 if test "$GCC" = "yes"
 471 then
 472   gccmajor=`$CC --version | head -n 1 | sed 's/[[^0-9]]*\([[0-9.]]\).*/\1/'`
 473   if test "$gccmajor" -lt "3"
 474   then
 475     AC_MSG_ERROR([gcc 3.x required, but you have a lower version])
 476   fi
 477 fi
 478
 479 dnl Check for GNU Make.  We use its extensions, so don't build without it
 480 if test -z "$llvm_cv_gnu_make_command"
 481 then
 482   AC_MSG_ERROR([GNU Make required but not found])
 483 fi
 484
 485 dnl Tool compatibility is okay if we make it here.
 486 AC_MSG_RESULT([ok])
 487
 488 dnl===-----------------------------------------------------------------------===
 489 dnl===
 490 dnl=== SECTION 5: Check for libraries
 491 dnl===
 492 dnl===-----------------------------------------------------------------------===
 493
 494 dnl libelf is for sparc only; we can ignore it if we don't have it
 495 AC_CHECK_LIB(elf, elf_begin)
 496 AC_CHECK_LIB(m,sin)
 497 if test "$llvm_cv_os_type" == "MingW" ; then
 498   AC_CHECK_LIB(imagehlp, main)
 499   AC_CHECK_LIB(psapi, main)
 500 fi
 501
 502 dnl lt_dlopen may be required for plugin support.
 503 AC_SEARCH_LIBS(lt_dlopen,ltdl,AC_DEFINE([HAVE_LT_DLOPEN],[1],
 504               [Define if lt_dlopen() is available on this platform]),
 505               AC_MSG_WARN([lt_dlopen() not found - plugin support might
 506                            not be available]))
 507
 508 dnl dlopen() is required for plugin support.
 509 AC_SEARCH_LIBS(dlopen,dl,AC_DEFINE([HAVE_DLOPEN],[1],
 510                [Define if dlopen() is available on this platform.]),
 511                AC_MSG_WARN([dlopen() not found - disabling plugin support]))
 512
 513 dnl mallinfo is optional; the code can compile (minus features) without it
 514 AC_SEARCH_LIBS(mallinfo,malloc,AC_DEFINE([HAVE_MALLINFO],[1],
 515                [Define if mallinfo() is available on this platform.]))
 516
 517 dnl pthread locking functions are optional - but llvm will not be thread-safe
 518 dnl without locks.
 519 if test "$ENABLE_THREADS" -eq 1 ; then
 520   AC_CHECK_LIB(pthread,pthread_mutex_init)
 521   AC_SEARCH_LIBS(pthread_mutex_lock,pthread,
 522                  AC_DEFINE([HAVE_PTHREAD_MUTEX_LOCK],[1],
 523                            [Have pthread_mutex_lock]))
 524 fi
 525
 526 dnl===-----------------------------------------------------------------------===
 527 dnl===
 528 dnl=== SECTION 6: Check for header files
 529 dnl===
 530 dnl===-----------------------------------------------------------------------===
 531
 532 dnl First, use autoconf provided macros for specific headers that we need
 533 dnl We don't check for ancient stuff or things that are guaranteed to be there
 534 dnl by the C++ standard. We always use the <cfoo> versions of <foo.h> C headers.
 535 dnl Generally we're looking for POSIX headers.
 536 AC_HEADER_DIRENT
 537 AC_HEADER_MMAP_ANONYMOUS
 538 AC_HEADER_STAT
 539 AC_HEADER_STDC
 540 AC_HEADER_SYS_WAIT
 541 AC_HEADER_TIME
 542
 543 AC_CHECK_HEADERS([dlfcn.h execinfo.h fcntl.h inttypes.h limits.h link.h])
 544 AC_CHECK_HEADERS([malloc.h signal.h stdint.h unistd.h utime.h windows.h])
 545 AC_CHECK_HEADERS([sys/mman.h sys/param.h sys/resource.h sys/time.h sys/types.h])
 546 AC_CHECK_HEADERS([malloc/malloc.h])
 547 if test "$ENABLE_THREADS" -eq 1 ; then
 548   AC_CHECK_HEADERS(pthread.h)
 549 fi
 550
 551 dnl===-----------------------------------------------------------------------===
 552 dnl===
 553 dnl=== SECTION 7: Check for types and structures
 554 dnl===
 555 dnl===-----------------------------------------------------------------------===
 556
 557 AC_TYPE_PID_T
 558 AC_TYPE_SIZE_T
 559 AC_TYPE_SIGNAL
 560 AC_STRUCT_TM
 561 AC_CHECK_TYPES([int64_t],,AC_MSG_ERROR([Type int64_t required but not found]))
 562 AC_CHECK_TYPES([uint64_t],,
 563          AC_CHECK_TYPES([u_int64_t],,
 564          AC_MSG_ERROR([Type uint64_t or u_int64_t required but not found])))
 565
 566 dnl===-----------------------------------------------------------------------===
 567 dnl===
 568 dnl=== SECTION 8: Check for specific functions needed
 569 dnl===
 570 dnl===-----------------------------------------------------------------------===
 571
 572 AC_CHECK_FUNCS([backtrace ceilf floorf roundf rintf nearbyintf getcwd ])
 573 AC_CHECK_FUNCS([getpagesize getrusage gettimeofday isatty mkdtemp mkstemp ])
 574 AC_CHECK_FUNCS([mktemp realpath sbrk setrlimit strdup strerror strerror_r ])
 575 AC_CHECK_FUNCS([strtoll strtoq sysconf malloc_zone_statistics ])
 576 AC_C_PRINTF_A
 577 AC_FUNC_ALLOCA
 578 AC_FUNC_RAND48
 579
 580 dnl Check for variations in the Standard C++ library and STL. These macros are
 581 dnl provided by LLVM in the autoconf/m4 directory.
 582 AC_CXX_HAVE_HASH_MAP
 583 AC_CXX_HAVE_HASH_SET
 584 AC_CXX_HAVE_STD_ITERATOR
 585 AC_CXX_HAVE_BI_ITERATOR
 586 AC_CXX_HAVE_FWD_ITERATOR
 587 AC_FUNC_ISNAN
 588 AC_FUNC_ISINF
 589
 590 dnl Check for mmap and mprotect support. We need both to do the JIT and for
 591 dnl bytecode loading, etc. We also need to know if /dev/zero is required to
 592 dnl be opened for allocating RWX memory.
 593 AC_FUNC_MMAP
 594 AC_FUNC_MMAP_FILE
 595 AC_NEED_DEV_ZERO_FOR_MMAP
 596 AC_CHECK_FUNC(mprotect,,
 597               AC_MSG_ERROR([Function mprotect() required but not found]))
 598
 599 if test "$ac_cv_func_mmap_fixed_mapped" = "no"
 600 then
 601   AC_MSG_WARN([mmap() of a fixed address required but not supported])
 602 fi
 603 if test "$ac_cv_func_mmap_file" = "no"
 604 then
 605   AC_MSG_WARN([mmap() of files required but not found])
 606 fi
 607
 608 dnl===-----------------------------------------------------------------------===
 609 dnl===
 610 dnl=== SECTION 9: Additional checks, variables, etc.
 611 dnl===
 612 dnl===-----------------------------------------------------------------------===
 613
 614 dnl See if the llvm-gcc executable can compile to LLVM assembly
 615 AC_CACHE_CHECK([whether llvm-gcc is sane],[llvm_cv_llvmgcc_sanity],
 616 [llvm_cv_llvmgcc_sanity="no"
 617 if test -x "$LLVMGCC" ; then
 618   cp /dev/null conftest.c
 619   "$LLVMGCC" -emit-llvm -S -o - conftest.c | grep implementation > /dev/null 2>&1
 620   if test $? -eq 0 ; then
 621     llvm_cv_llvmgcc_sanity="yes"
 622   fi
 623   rm conftest.c
 624 fi])
 625
 626 dnl Since we have a sane llvm-gcc, identify it and its sub-tools
 627 if test "$llvm_cv_llvmgcc_sanity" = "yes" ; then
 628   llvmcc1path=`"$LLVMGCC" --print-prog-name=cc1`
 629   AC_SUBST(LLVMCC1,$llvmcc1path)
 630   llvmcc1pluspath=`"$LLVMGCC" --print-prog-name=cc1plus`
 631   AC_SUBST(LLVMCC1PLUS,$llvmcc1pluspath)
 632   llvmgccdir=`echo "$llvmcc1path" | sed 's,/libexec/.*,,'`
 633   AC_SUBST(LLVMGCCDIR,$llvmgccdir)
 634   llvmgccversion=[`"$LLVMGCC" -dumpversion 2>&1 | sed 's/^\([0-9.]*\).*/\1/'`]
 635   llvmgccmajvers=[`echo $llvmgccversion | sed 's/^\([0-9]\).*/\1/'`]
 636   AC_SUBST(LLVMGCC_VERSION,$llvmgccversion)
 637   AC_SUBST(LLVMGCC_MAJVERS,$llvmgccmajvers)
 638 fi
 639
 640 dnl Propagate the shared library extension that the libltdl checks did to
 641 dnl the Makefiles so we can use it there too
 642 AC_SUBST(SHLIBEXT,$libltdl_cv_shlibext)
 643
 644 # Translate the various configuration directories and other basic
 645 # information into substitutions that will end up in Makefile.config.in
 646 # that these configured values can be used by the makefiles
 647 if test "${prefix}" == "NONE" ; then
 648   prefix="/usr/local"
 649 fi
 650 eval LLVM_PREFIX="${prefix}";
 651 eval LLVM_BINDIR="${prefix}/bin";
 652 eval LLVM_LIBDIR="${prefix}/lib";
 653 eval LLVM_DATADIR="${prefix}/share/llvm";
 654 eval LLVM_DOCSDIR="${prefix}/docs/llvm";
 655 eval LLVM_ETCDIR="${prefix}/etc/llvm";
 656 eval LLVM_INCLUDEDIR="${prefix}/include";
 657 eval LLVM_INFODIR="${prefix}/info";
 658 eval LLVM_MANDIR="${prefix}/man";
 659 LLVM_CONFIGTIME=`date`
 660 AC_SUBST(LLVM_PREFIX)
 661 AC_SUBST(LLVM_BINDIR)
 662 AC_SUBST(LLVM_LIBDIR)
 663 AC_SUBST(LLVM_DATADIR)
 664 AC_SUBST(LLVM_DOCSDIR)
 665 AC_SUBST(LLVM_ETCDIR)
 666 AC_SUBST(LLVM_INCLUDEDIR)
 667 AC_SUBST(LLVM_INFODIR)
 668 AC_SUBST(LLVM_MANDIR)
 669 AC_SUBST(LLVM_CONFIGTIME)
 670
 671 # Place the various directores into the config.h file as #defines so that we
 672 # can know about the installation paths within LLVM.
 673 AC_DEFINE_UNQUOTED(LLVM_PREFIX,"$LLVM_PREFIX",
 674                    [Installation prefix directory])
 675 AC_DEFINE_UNQUOTED(LLVM_BINDIR, "$LLVM_BINDIR",
 676                    [Installation directory for binary executables])
 677 AC_DEFINE_UNQUOTED(LLVM_LIBDIR, "$LLVM_LIBDIR",
 678                    [Installation directory for libraries])
 679 AC_DEFINE_UNQUOTED(LLVM_DATADIR, "$LLVM_DATADIR",
 680                    [Installation directory for data files])
 681 AC_DEFINE_UNQUOTED(LLVM_DATADIR, "$LLVM_DOCSDIR",
 682                    [Installation directory for documentation])
 683 AC_DEFINE_UNQUOTED(LLVM_ETCDIR, "$LLVM_ETCDIR",
 684                    [Installation directory for config files])
 685 AC_DEFINE_UNQUOTED(LLVM_INCLUDEDIR, "$LLVM_INCLUDEDIR",
 686                    [Installation directory for include files])
 687 AC_DEFINE_UNQUOTED(LLVM_INFODIR, "$LLVM_INFODIR",
 688                    [Installation directory for .info files])
 689 AC_DEFINE_UNQUOTED(LLVM_MANDIR, "$LLVM_MANDIR",
 690                    [Installation directory for man pages])
 691 AC_DEFINE_UNQUOTED(LLVM_CONFIGTIME, "$LLVM_CONFIGTIME",
 692                    [Time at which LLVM was configured])
 693
 694 dnl===-----------------------------------------------------------------------===
 695 dnl===
 696 dnl=== SECTION 10: Specify the output files and generate it
 697 dnl===
 698 dnl===-----------------------------------------------------------------------===
 699
 700 dnl Configure header files
 701 dnl WARNING: dnl If you add or remove any of the following config headers, then
 702 dnl you MUST also update Makefile.rules so that the variable FilesToConfig
 703 dnl contains the same list of files as AC_CONFIG_HEADERS below. This ensures the
 704 dnl files can be updated automatically when their *.in sources change.
 705 AC_CONFIG_HEADERS([include/llvm/Config/config.h])
 706 AC_CONFIG_HEADERS([include/llvm/Support/DataTypes.h])
 707 AC_CONFIG_HEADERS([include/llvm/ADT/hash_map])
 708 AC_CONFIG_HEADERS([include/llvm/ADT/hash_set])
 709 AC_CONFIG_HEADERS([include/llvm/ADT/iterator])
 710
 711 dnl Configure the makefile's configuration data
 712 AC_CONFIG_FILES([Makefile.config])
 713
 714 dnl Configure doxygen's configuration file
 715 AC_CONFIG_FILES([docs/doxygen.cfg])
 716
 717 dnl Do the first stage of configuration for llvm-config.in.
 718 AC_CONFIG_FILES([tools/llvm-config/llvm-config.in])
 719
 720 dnl Do special configuration of Makefiles
 721 AC_CONFIG_COMMANDS([setup],,[llvm_src="${srcdir}"])
 722 AC_CONFIG_MAKEFILE(Makefile)
 723 AC_CONFIG_MAKEFILE(Makefile.common)
 724 AC_CONFIG_MAKEFILE(examples/Makefile)
 725 AC_CONFIG_MAKEFILE(lib/Makefile)
 726 AC_CONFIG_MAKEFILE(runtime/Makefile)
 727 AC_CONFIG_MAKEFILE(test/Makefile)
 728 AC_CONFIG_MAKEFILE(test/Makefile.tests)
 729 AC_CONFIG_MAKEFILE(tools/Makefile)
 730 AC_CONFIG_MAKEFILE(utils/Makefile)
 731 AC_CONFIG_MAKEFILE(projects/Makefile)
 732
 733 dnl Finally, crank out the output
 734 AC_OUTPUT
 735
 736 dnl Warn loudly if llvm-gcc was not obviously working
 737 if test "$llvm_cv_llvmgcc_sanity" = "no" ; then
 738  AC_MSG_WARN([***** llvm-gcc/llvm-g++ was not found, or does not appear to be ])
 739  AC_MSG_WARN([***** working. Please make sure you have llvmgcc and llvmg++ in])
 740  AC_MSG_WARN([***** your path before configuring LLVM. The runtime libraries])
 741  AC_MSG_WARN([***** (llvm/runtime) will not be built but you should be able to])
 742  AC_MSG_WARN([***** build the llvm tools.])
 743 fi