autoconf/configure.ac

   1 dnl === configure.ac --------------------------------------------------------===
   2 dnl                     The LLVM Compiler Infrastructure
   3 dnl
   4 dnl This file is distributed under the University of Illinois Open Source
   5 dnl License. See LICENSE.TXT for details.
   6 dnl
   7 dnl===-----------------------------------------------------------------------===
   8 dnl This is the LLVM configuration script. It is processed by the autoconf
   9 dnl program to produce a script named configure. This script contains the
  10 dnl configuration checks that LLVM needs in order to support multiple platforms.
  11 dnl This file is composed of 10 sections per the recommended organization of
  12 dnl autoconf input defined in the autoconf documentation. As this file evolves,
  13 dnl please keep the various types of checks within their sections. The sections
  14 dnl are as follows:
  15 dnl
  16 dnl SECTION 1: Initialization & Setup
  17 dnl SECTION 2: Architecture, target, and host checks
  18 dnl SECTION 3: Command line arguments for the configure script.
  19 dnl SECTION 4: Check for programs we need and that they are the right version
  20 dnl SECTION 5: Check for libraries
  21 dnl SECTION 6: Check for header files
  22 dnl SECTION 7: Check for types and structures
  23 dnl SECTION 8: Check for specific functions needed
  24 dnl SECTION 9: Additional checks, variables, etc.
  25 dnl SECTION 10: Specify the output files and generate it
  26 dnl
  27 dnl===-----------------------------------------------------------------------===
  28 dnl===
  29 dnl=== SECTION 1: Initialization & Setup
  30 dnl===
  31 dnl===-----------------------------------------------------------------------===
  32 dnl Initialize autoconf and define the package name, version number and
  33 dnl email address for reporting bugs.
  34 AC_INIT([[llvm]],[[2.6svn]],[llvmbugs@cs.uiuc.edu])
  35
  36 dnl Provide a copyright substitution and ensure the copyright notice is included
  37 dnl in the output of --version option of the generated configure script.
  38 AC_SUBST(LLVM_COPYRIGHT,["Copyright (c) 2003-2008 University of Illinois at Urbana-Champaign."])
  39 AC_COPYRIGHT([Copyright (c) 2003-2008 University of Illinois at Urbana-Champaign.])
  40
  41 dnl Indicate that we require autoconf 2.59 or later. Ths is needed because we
  42 dnl use some autoconf macros only available in 2.59.
  43 AC_PREREQ(2.59)
  44
  45 dnl Verify that the source directory is valid. This makes sure that we are
  46 dnl configuring LLVM and not some other package (it validates --srcdir argument)
  47 AC_CONFIG_SRCDIR([lib/VMCore/Module.cpp])
  48
  49 dnl Place all of the extra autoconf files into the config subdirectory. Tell
  50 dnl various tools where the m4 autoconf macros are.
  51 AC_CONFIG_AUX_DIR([autoconf])
  52
  53 dnl Quit if the source directory has already been configured.
  54 dnl NOTE: This relies upon undocumented autoconf behavior.
  55 if test ${srcdir} != "." ; then
  56   if test -f ${srcdir}/include/llvm/Config/config.h ; then
  57     AC_MSG_ERROR([Already configured in ${srcdir}])
  58   fi
  59 fi
  60
  61 dnl Configure all of the projects present in our source tree. While we could
  62 dnl just AC_CONFIG_SUBDIRS on the set of directories in projects that have a
  63 dnl configure script, that usage of the AC_CONFIG_SUBDIRS macro is deprecated.
  64 dnl Instead we match on the known projects.
  65 for i in `ls ${srcdir}/projects`
  66 do
  67   if test -d ${srcdir}/projects/${i} ; then
  68     case ${i} in
  69       CVS) ;;
  70       sample)       AC_CONFIG_SUBDIRS([projects/sample])    ;;
  71       privbracket)  AC_CONFIG_SUBDIRS([projects/privbracket]) ;;
  72       llvm-stacker) AC_CONFIG_SUBDIRS([projects/llvm-stacker]) ;;
  73       # llvm-test is the old name of the test-suite, kept here for backwards
  74       # compatibility
  75       llvm-test)    AC_CONFIG_SUBDIRS([projects/llvm-test]) ;;
  76       test-suite)   AC_CONFIG_SUBDIRS([projects/test-suite]) ;;
  77       llvm-reopt)   AC_CONFIG_SUBDIRS([projects/llvm-reopt]);;
  78       llvm-gcc)     AC_CONFIG_SUBDIRS([projects/llvm-gcc])  ;;
  79       llvm-java)    AC_CONFIG_SUBDIRS([projects/llvm-java]) ;;
  80       llvm-tv)      AC_CONFIG_SUBDIRS([projects/llvm-tv])   ;;
  81       llvm-poolalloc) AC_CONFIG_SUBDIRS([projects/llvm-poolalloc]) ;;
  82       poolalloc)    AC_CONFIG_SUBDIRS([projects/poolalloc]) ;;
  83       llvm-kernel)  AC_CONFIG_SUBDIRS([projects/llvm-kernel]) ;;
  84       *)
  85         AC_MSG_WARN([Unknown project (${i}) won't be configured automatically])
  86         ;;
  87     esac
  88   fi
  89 done
  90
  91 dnl===-----------------------------------------------------------------------===
  92 dnl===
  93 dnl=== SECTION 2: Architecture, target, and host checks
  94 dnl===
  95 dnl===-----------------------------------------------------------------------===
  96
  97 dnl Check the target for which we're compiling and the host that will do the
  98 dnl compilations. This will tell us which LLVM compiler will be used for
  99 dnl compiling SSA into object code. This needs to be done early because
 100 dnl following tests depend on it.
 101 AC_CANONICAL_TARGET
 102
 103 dnl Determine the platform type and cache its value. This helps us configure
 104 dnl the System library to the correct build platform.
 105 AC_CACHE_CHECK([type of operating system we're going to host on],
 106                [llvm_cv_os_type],
 107 [case $host in
 108   *-*-aix*)
 109     llvm_cv_link_all_option="-Wl,--whole-archive"
 110     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 111     llvm_cv_os_type="AIX"
 112     llvm_cv_platform_type="Unix" ;;
 113   *-*-irix*)
 114     llvm_cv_link_all_option="-Wl,--whole-archive"
 115     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 116     llvm_cv_os_type="IRIX"
 117     llvm_cv_platform_type="Unix" ;;
 118   *-*-cygwin*)
 119     llvm_cv_link_all_option="-Wl,--whole-archive"
 120     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 121     llvm_cv_os_type="Cygwin"
 122     llvm_cv_platform_type="Unix" ;;
 123   *-*-darwin*)
 124     llvm_cv_link_all_option="-Wl,-all_load"
 125     llvm_cv_no_link_all_option="-Wl,-noall_load"
 126     llvm_cv_os_type="Darwin"
 127     llvm_cv_platform_type="Unix" ;;
 128   *-*-freebsd*)
 129     llvm_cv_link_all_option="-Wl,--whole-archive"
 130     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 131     llvm_cv_os_type="FreeBSD"
 132     llvm_cv_platform_type="Unix" ;;
 133   *-*-openbsd*)
 134     llvm_cv_link_all_option="-Wl,--whole-archive"
 135     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 136     llvm_cv_os_type="OpenBSD"
 137     llvm_cv_platform_type="Unix" ;;
 138   *-*-netbsd*)
 139     llvm_cv_link_all_option="-Wl,--whole-archive"
 140     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 141     llvm_cv_os_type="NetBSD"
 142     llvm_cv_platform_type="Unix" ;;
 143   *-*-dragonfly*)
 144     llvm_cv_link_all_option="-Wl,--whole-archive"
 145     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 146     llvm_cv_os_type="DragonFly"
 147     llvm_cv_platform_type="Unix" ;;
 148   *-*-hpux*)
 149     llvm_cv_link_all_option="-Wl,--whole-archive"
 150     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 151     llvm_cv_os_type="HP-UX"
 152     llvm_cv_platform_type="Unix" ;;
 153   *-*-interix*)
 154     llvm_cv_link_all_option="-Wl,--whole-archive"
 155     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 156     llvm_cv_os_type="Interix"
 157     llvm_cv_platform_type="Unix" ;;
 158   *-*-linux*)
 159     llvm_cv_link_all_option="-Wl,--whole-archive"
 160     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 161     llvm_cv_os_type="Linux"
 162     llvm_cv_platform_type="Unix" ;;
 163   *-*-solaris*)
 164     llvm_cv_link_all_option="-Wl,-z,allextract"
 165     llvm_cv_no_link_all_option="-Wl,-z,defaultextract"
 166     llvm_cv_os_type="SunOS"
 167     llvm_cv_platform_type="Unix" ;;
 168   *-*-win32*)
 169     llvm_cv_link_all_option="-Wl,--whole-archive"
 170     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 171     llvm_cv_os_type="Win32"
 172     llvm_cv_platform_type="Win32" ;;
 173   *-*-mingw*)
 174     llvm_cv_link_all_option="-Wl,--whole-archive"
 175     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 176     llvm_cv_os_type="MingW"
 177     llvm_cv_platform_type="Win32" ;;
 178   *)
 179     llvm_cv_link_all_option=""
 180     llvm_cv_no_link_all_option=""
 181     llvm_cv_os_type="Unknown"
 182     llvm_cv_platform_type="Unknown" ;;
 183 esac])
 184
 185 dnl Make sure we aren't attempting to configure for an unknown system
 186 if test "$llvm_cv_os_type" = "Unknown" ; then
 187   AC_MSG_ERROR([Operating system is unknown, configure can't continue])
 188 fi
 189
 190 dnl Set the "OS" Makefile variable based on the platform type so the
 191 dnl makefile can configure itself to specific build hosts
 192 AC_SUBST(OS,$llvm_cv_os_type)
 193
 194 dnl Set the LINKALL and NOLINKALL Makefile variables based on the platform
 195 AC_SUBST(LINKALL,$llvm_cv_link_all_option)
 196 AC_SUBST(NOLINKALL,$llvm_cv_no_link_all_option)
 197
 198 dnl Set the "LLVM_ON_*" variables based on llvm_cvs_platform_type
 199 dnl This is used by lib/System to determine the basic kind of implementation
 200 dnl to use.
 201 case $llvm_cv_platform_type in
 202   Unix)
 203     AC_DEFINE([LLVM_ON_UNIX],[1],[Define if this is Unixish platform])
 204     AC_SUBST(LLVM_ON_UNIX,[1])
 205     AC_SUBST(LLVM_ON_WIN32,[0])
 206     ;;
 207   Win32)
 208     AC_DEFINE([LLVM_ON_WIN32],[1],[Define if this is Win32ish platform])
 209     AC_SUBST(LLVM_ON_UNIX,[0])
 210     AC_SUBST(LLVM_ON_WIN32,[1])
 211     ;;
 212 esac
 213
 214 dnl Determine what our target architecture is and configure accordingly.
 215 dnl This will allow Makefiles to make a distinction between the hardware and
 216 dnl the OS.
 217 AC_CACHE_CHECK([target architecture],[llvm_cv_target_arch],
 218 [case $target in
 219   i?86-*)                 llvm_cv_target_arch="x86" ;;
 220   amd64-* | x86_64-*)     llvm_cv_target_arch="x86_64" ;;
 221   sparc*-*)               llvm_cv_target_arch="Sparc" ;;
 222   powerpc*-*)             llvm_cv_target_arch="PowerPC" ;;
 223   alpha*-*)               llvm_cv_target_arch="Alpha" ;;
 224   ia64-*)                 llvm_cv_target_arch="IA64" ;;
 225   arm-*)                  llvm_cv_target_arch="ARM" ;;
 226   mips-*)                 llvm_cv_target_arch="Mips" ;;
 227   pic16-*)                llvm_cv_target_arch="PIC16" ;;
 228   xcore-*)                llvm_cv_target_arch="XCore" ;;
 229   *)                      llvm_cv_target_arch="Unknown" ;;
 230 esac])
 231
 232 if test "$llvm_cv_target_arch" = "Unknown" ; then
 233   AC_MSG_WARN([Configuring LLVM for an unknown target archicture])
 234 fi
 235
 236 dnl Define a substitution, ARCH, for the target architecture
 237 AC_SUBST(ARCH,$llvm_cv_target_arch)
 238
 239 dnl Check for the endianness of the target
 240 AC_C_BIGENDIAN(AC_SUBST([ENDIAN],[big]),AC_SUBST([ENDIAN],[little]))
 241
 242 dnl Check for build platform executable suffix if we're crosscompiling
 243 if test "$cross_compiling" = yes; then
 244   AC_SUBST(LLVM_CROSS_COMPILING, [1])
 245   AC_BUILD_EXEEXT
 246   ac_build_prefix=${build_alias}-
 247   AC_CHECK_PROG(BUILD_CXX, ${ac_build_prefix}g++, ${ac_build_prefix}g++)
 248   if test -z "$BUILD_CXX"; then
 249      AC_CHECK_PROG(BUILD_CXX, g++, g++)
 250      if test -z "$BUILD_CXX"; then
 251        AC_CHECK_PROG(BUILD_CXX, c++, c++, , , /usr/ucb/c++)
 252      fi
 253   fi
 254 else
 255   AC_SUBST(LLVM_CROSS_COMPILING, [0])
 256 fi
 257
 258 dnl Check to see if there's a "CVS" (or .svn or .git) directory indicating
 259 dnl that this build is being done from a checkout. This sets up several
 260 dnl defaults for the command line switches. When we build with a CVS directory,
 261 dnl we get a debug with assertions turned on. Without, we assume a source
 262 dnl release and we get an optimized build without assertions.
 263 dnl See --enable-optimized and --enable-assertions below
 264 if test -d "CVS" -o -d "${srcdir}/CVS" -o -d ".svn" -o -d "${srcdir}/.svn" -o -d ".git" -o -d "${srcdir}/.git"; then
 265   cvsbuild="yes"
 266   optimize="no"
 267   AC_SUBST(CVSBUILD,[[CVSBUILD=1]])
 268 else
 269   cvsbuild="no"
 270   optimize="yes"
 271 fi
 272
 273 dnl===-----------------------------------------------------------------------===
 274 dnl===
 275 dnl=== SECTION 3: Command line arguments for the configure script.
 276 dnl===
 277 dnl===-----------------------------------------------------------------------===
 278
 279 dnl --enable-optimized : check whether they want to do an optimized build:
 280 AC_ARG_ENABLE(optimized, AS_HELP_STRING(
 281  [--enable-optimized,Compile with optimizations enabled (default is NO)]),,enableval=$optimize)
 282 if test ${enableval} = "no" ; then
 283   AC_SUBST(ENABLE_OPTIMIZED,[[]])
 284 else
 285   AC_SUBST(ENABLE_OPTIMIZED,[[ENABLE_OPTIMIZED=1]])
 286 fi
 287
 288 dnl --enable-profiling : check whether they want to do a profile build:
 289 AC_ARG_ENABLE(profiling, AS_HELP_STRING(
 290  [--enable-profiling,Compile with profiling enabled (default is NO)]),,enableval="no")
 291 if test ${enableval} = "no" ; then
 292   AC_SUBST(ENABLE_PROFILING,[[]])
 293 else
 294   AC_SUBST(ENABLE_PROFILING,[[ENABLE_PROFILING=1]])
 295 fi
 296
 297 dnl --enable-assertions : check whether they want to turn on assertions or not:
 298 AC_ARG_ENABLE(assertions,AS_HELP_STRING(
 299   [--enable-assertions,Compile with assertion checks enabled (default is YES)]),, enableval="yes")
 300 if test ${enableval} = "yes" ; then
 301   AC_SUBST(DISABLE_ASSERTIONS,[[]])
 302 else
 303   AC_SUBST(DISABLE_ASSERTIONS,[[DISABLE_ASSERTIONS=1]])
 304 fi
 305
 306 dnl --enable-expensive-checks : check whether they want to turn on expensive debug checks:
 307 AC_ARG_ENABLE(expensive-checks,AS_HELP_STRING(
 308   [--enable-expensive-checks,Compile with expensive debug checks enabled (default is NO)]),, enableval="no")
 309 if test ${enableval} = "yes" ; then
 310   AC_SUBST(ENABLE_EXPENSIVE_CHECKS,[[ENABLE_EXPENSIVE_CHECKS=1]])
 311   AC_SUBST(EXPENSIVE_CHECKS,[[yes]])
 312 else
 313   AC_SUBST(ENABLE_EXPENSIVE_CHECKS,[[]])
 314   AC_SUBST(EXPENSIVE_CHECKS,[[no]])
 315 fi
 316
 317 dnl --enable-debug-runtime : should runtime libraries have debug symbols?
 318 AC_ARG_ENABLE(debug-runtime,
 319    AS_HELP_STRING([--enable-debug-runtime,Build runtime libs with debug symbols (default is NO)]),,enableval=no)
 320 if test ${enableval} = "no" ; then
 321   AC_SUBST(DEBUG_RUNTIME,[[]])
 322 else
 323   AC_SUBST(DEBUG_RUNTIME,[[DEBUG_RUNTIME=1]])
 324 fi
 325
 326 dnl --enable-jit: check whether they want to enable the jit
 327 AC_ARG_ENABLE(jit,
 328   AS_HELP_STRING(--enable-jit,
 329                  [Enable Just In Time Compiling (default is YES)]),,
 330   enableval=default)
 331 if test ${enableval} = "no"
 332 then
 333   AC_SUBST(JIT,[[]])
 334 else
 335   case "$llvm_cv_target_arch" in
 336     x86)     AC_SUBST(TARGET_HAS_JIT,1) ;;
 337     Sparc)   AC_SUBST(TARGET_HAS_JIT,0) ;;
 338     PowerPC) AC_SUBST(TARGET_HAS_JIT,1) ;;
 339     x86_64)  AC_SUBST(TARGET_HAS_JIT,1) ;;
 340     Alpha)   AC_SUBST(TARGET_HAS_JIT,1) ;;
 341     IA64)    AC_SUBST(TARGET_HAS_JIT,0) ;;
 342     ARM)     AC_SUBST(TARGET_HAS_JIT,0) ;;
 343     Mips)    AC_SUBST(TARGET_HAS_JIT,0) ;;
 344     PIC16)   AC_SUBST(TARGET_HAS_JIT,0) ;;
 345     XCore)   AC_SUBST(TARGET_HAS_JIT,0) ;;
 346     *)       AC_SUBST(TARGET_HAS_JIT,0) ;;
 347   esac
 348 fi
 349
 350 dnl Allow enablement of doxygen generated documentation
 351 AC_ARG_ENABLE(doxygen,
 352               AS_HELP_STRING([--enable-doxygen],
 353                              [Build doxygen documentation (default is NO)]),,
 354                              enableval=default)
 355 case "$enableval" in
 356   yes) AC_SUBST(ENABLE_DOXYGEN,[1]) ;;
 357   no)  AC_SUBST(ENABLE_DOXYGEN,[0]) ;;
 358   default) AC_SUBST(ENABLE_DOXYGEN,[0]) ;;
 359   *) AC_MSG_ERROR([Invalid setting for --enable-doxygen. Use "yes" or "no"]) ;;
 360 esac
 361
 362 dnl Allow disablement of threads
 363 AC_ARG_ENABLE(threads,
 364               AS_HELP_STRING([--enable-threads],
 365                              [Use threads if available (default is YES)]),,
 366                              enableval=default)
 367 case "$enableval" in
 368   yes) AC_SUBST(ENABLE_THREADS,[1]) ;;
 369   no)  AC_SUBST(ENABLE_THREADS,[0]) ;;
 370   default) AC_SUBST(ENABLE_THREADS,[1]) ;;
 371   *) AC_MSG_ERROR([Invalid setting for --enable-threads. Use "yes" or "no"]) ;;
 372 esac
 373 AC_DEFINE_UNQUOTED([ENABLE_THREADS],$ENABLE_THREADS,[Define if threads enabled])
 374
 375 dnl Allow building without position independent code
 376 AC_ARG_ENABLE(pic,
 377   AS_HELP_STRING([--enable-pic],
 378                  [Build LLVM with Position Independent Code (default is YES)]),,
 379                  enableval=default)
 380 case "$enableval" in
 381   yes) AC_SUBST(ENABLE_PIC,[1]) ;;
 382   no)  AC_SUBST(ENABLE_PIC,[0]) ;;
 383   default) AC_SUBST(ENABLE_PIC,[1]) ;;
 384   *) AC_MSG_ERROR([Invalid setting for --enable-pic. Use "yes" or "no"]) ;;
 385 esac
 386 AC_DEFINE_UNQUOTED([ENABLE_PIC],$ENABLE_PIC,
 387                    [Define if position independent code is enabled])
 388
 389 dnl Allow specific targets to be specified for building (or not)
 390 TARGETS_TO_BUILD=""
 391 AC_ARG_ENABLE([targets],AS_HELP_STRING([--enable-targets],
 392     [Build specific host targets: all,host-only,{target-name} (default=all)]),,
 393     enableval=all)
 394 case "$enableval" in
 395   all) TARGETS_TO_BUILD="X86 Sparc PowerPC Alpha IA64 ARM Mips CellSPU PIC16 XCore CBackend MSIL CppBackend" ;;
 396   host-only)
 397     case "$llvm_cv_target_arch" in
 398       x86)     TARGETS_TO_BUILD="X86" ;;
 399       x86_64)  TARGETS_TO_BUILD="X86" ;;
 400       Sparc)   TARGETS_TO_BUILD="Sparc" ;;
 401       PowerPC) TARGETS_TO_BUILD="PowerPC" ;;
 402       Alpha)   TARGETS_TO_BUILD="Alpha" ;;
 403       IA64)    TARGETS_TO_BUILD="IA64" ;;
 404       ARM)     TARGETS_TO_BUILD="ARM" ;;
 405       Mips)    TARGETS_TO_BUILD="Mips" ;;
 406       CellSPU|SPU) TARGETS_TO_BUILD="CellSPU" ;;
 407       PIC16)   TARGETS_TO_BUILD="PIC16" ;;
 408       XCore)   TARGETS_TO_BUILD="XCore" ;;
 409       *)       AC_MSG_ERROR([Can not set target to build]) ;;
 410     esac
 411     ;;
 412   *)for a_target in `echo $enableval|sed -e 's/,/ /g' ` ; do
 413       case "$a_target" in
 414         x86)     TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 415         x86_64)  TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 416         sparc)   TARGETS_TO_BUILD="Sparc $TARGETS_TO_BUILD" ;;
 417         powerpc) TARGETS_TO_BUILD="PowerPC $TARGETS_TO_BUILD" ;;
 418         alpha)   TARGETS_TO_BUILD="Alpha $TARGETS_TO_BUILD" ;;
 419         ia64)    TARGETS_TO_BUILD="IA64 $TARGETS_TO_BUILD" ;;
 420         arm)     TARGETS_TO_BUILD="ARM $TARGETS_TO_BUILD" ;;
 421         mips)    TARGETS_TO_BUILD="Mips $TARGETS_TO_BUILD" ;;
 422         spu)     TARGETS_TO_BUILD="CellSPU $TARGETS_TO_BUILD" ;;
 423         pic16)   TARGETS_TO_BUILD="PIC16 $TARGETS_TO_BUILD" ;;
 424         xcore)   TARGETS_TO_BUILD="XCore $TARGETS_TO_BUILD" ;;
 425         cbe)     TARGETS_TO_BUILD="CBackend $TARGETS_TO_BUILD" ;;
 426         msil)    TARGETS_TO_BUILD="MSIL $TARGETS_TO_BUILD" ;;
 427         cpp)     TARGETS_TO_BUILD="CppBackend $TARGETS_TO_BUILD" ;;
 428         *) AC_MSG_ERROR([Unrecognized target $a_target]) ;;
 429       esac
 430   done
 431   ;;
 432 esac
 433 AC_SUBST(TARGETS_TO_BUILD,$TARGETS_TO_BUILD)
 434
 435 dnl Prevent the CBackend from using printf("%a") for floating point so older
 436 dnl C compilers that cannot deal with the 0x0p+0 hex floating point format
 437 dnl can still compile the CBE's output
 438 AC_ARG_ENABLE([cbe-printf-a],AS_HELP_STRING([--enable-cbe-printf-a],
 439   [Enable C Backend output with hex floating point via %a  (default is YES)]),,
 440   enableval=default)
 441 case "$enableval" in
 442   yes) AC_SUBST(ENABLE_CBE_PRINTF_A,[1]) ;;
 443   no)  AC_SUBST(ENABLE_CBE_PRINTF_A,[0]) ;;
 444   default)  AC_SUBST(ENABLE_CBE_PRINTF_A,[1]) ;;
 445   *) AC_MSG_ERROR([Invalid setting for --enable-cbe-printf-a. Use "yes" or "no"]) ;;
 446 esac
 447 AC_DEFINE_UNQUOTED([ENABLE_CBE_PRINTF_A],$ENABLE_CBE_PRINTF_A,
 448                    [Define if CBE is enabled for printf %a output])
 449
 450 dnl Allow a specific llvm-gcc/llvm-g++ pair to be used with this LLVM config.
 451 AC_ARG_WITH(llvmgccdir,
 452   AS_HELP_STRING([--with-llvmgccdir],
 453     [Specify location of llvm-gcc install dir (default searches PATH)]),,
 454     withval=default)
 455 case "$withval" in
 456   default) WITH_LLVMGCCDIR=default ;;
 457   /* | [[A-Za-z]]:[[\\/]]*)      WITH_LLVMGCCDIR=$withval ;;
 458   *) AC_MSG_ERROR([Invalid path for --with-llvmgccdir. Provide full path]) ;;
 459 esac
 460
 461 dnl Allow a specific llvm-gcc compiler to be used with this LLVM config.
 462 AC_ARG_WITH(llvmgcc,
 463   AS_HELP_STRING([--with-llvmgcc],
 464     [Specify location of llvm-gcc driver (default searches PATH)]),
 465     LLVMGCC=$with_llvmgcc
 466       WITH_LLVMGCCDIR="",)
 467
 468 dnl Allow a specific llvm-g++ compiler to be used with this LLVM config.
 469 AC_ARG_WITH(llvmgxx,
 470   AS_HELP_STRING([--with-llvmgxx],
 471     [Specify location of llvm-g++ driver (default searches PATH)]),
 472     LLVMGXX=$with_llvmgxx
 473     WITH_LLVMGCCDIR="",)
 474
 475 if test -n "$LLVMGCC" && test -z "$LLVMGXX"; then
 476    AC_MSG_ERROR([Invalid llvm-g++. Use --with-llvmgxx when --with-llvmgcc is used]);
 477 fi
 478
 479 if test -n "$LLVMGXX" && test -z "$LLVMGCC"; then
 480    AC_MSG_ERROR([Invalid llvm-gcc. Use --with-llvmgcc when --with-llvmgxx is used]);
 481 fi
 482
 483 dnl Specify extra build options
 484 AC_ARG_WITH(extra-options,
 485   AS_HELP_STRING([--with-extra-options],
 486                  [Specify addtional options to compile LLVM with]),,
 487                  withval=default)
 488 case "$withval" in
 489   default) EXTRA_OPTIONS= ;;
 490   *) EXTRA_OPTIONS=$withval ;;
 491 esac
 492 AC_SUBST(EXTRA_OPTIONS,$EXTRA_OPTIONS)
 493
 494 dnl Allow specific bindings to be specified for building (or not)
 495 AC_ARG_ENABLE([bindings],AS_HELP_STRING([--enable-bindings],
 496     [Build specific language bindings: all,auto,none,{binding-name} (default=auto)]),,
 497     enableval=default)
 498 BINDINGS_TO_BUILD=""
 499 case "$enableval" in
 500   yes | default | auto) BINDINGS_TO_BUILD="auto" ;;
 501   all ) BINDINGS_TO_BUILD="ocaml" ;;
 502   none | no) BINDINGS_TO_BUILD="" ;;
 503   *)for a_binding in `echo $enableval|sed -e 's/,/ /g' ` ; do
 504       case "$a_binding" in
 505         ocaml) BINDINGS_TO_BUILD="ocaml $BINDINGS_TO_BUILD" ;;
 506         *) AC_MSG_ERROR([Unrecognized binding $a_binding]) ;;
 507       esac
 508   done
 509   ;;
 510 esac
 511
 512 dnl Allow the ocaml libdir to be overridden. This could go in a configure
 513 dnl script for bindings/ocaml/configure, except that its auto value depends on
 514 dnl OCAMLC, which is found here to support tests.
 515 AC_ARG_WITH([ocaml-libdir],
 516   [AS_HELP_STRING([--with-ocaml-libdir],
 517     [Specify install location for ocaml bindings (default is stdlib)])],
 518   [],
 519   [withval=auto])
 520 case "$withval" in
 521   auto) with_ocaml_libdir="$withval" ;;
 522   /* | [[A-Za-z]]:[[\\/]]*) with_ocaml_libdir="$withval" ;;
 523   *) AC_MSG_ERROR([Invalid path for --with-ocaml-libdir. Provide full path]) ;;
 524 esac
 525
 526 dnl Allow linking of LLVM with GPLv3 binutils code.
 527 AC_ARG_WITH(binutils-include,
 528   AS_HELP_STRING([--with-binutils-include],
 529     [Specify path to binutils/include/ containing plugin-api.h file for gold plugin.]),,
 530   withval=default)
 531 case "$withval" in
 532   default) WITH_BINUTILS_INCDIR=default ;;
 533   /* | [[A-Za-z]]:[[\\/]]*)      WITH_BINUTILS_INCDIR=$withval ;;
 534   *) AC_MSG_ERROR([Invalid path for --with-binutils-include. Provide full path]) ;;
 535 esac
 536 if test "x$WITH_BINUTILS_INCDIR" != xdefault ; then
 537   AC_SUBST(BINUTILS_INCDIR,$WITH_BINUTILS_INCDIR)
 538   if test ! -f "$WITH_BINUTILS_INCDIR/plugin-api.h"; then
 539      echo "$WITH_BINUTILS_INCDIR/plugin-api.h"
 540      AC_MSG_ERROR([Invalid path to directory containing plugin-api.h.]);
 541   fi
 542 fi
 543
 544 dnl===-----------------------------------------------------------------------===
 545 dnl===
 546 dnl=== SECTION 4: Check for programs we need and that they are the right version
 547 dnl===
 548 dnl===-----------------------------------------------------------------------===
 549
 550 dnl Check for compilation tools
 551 AC_PROG_CPP
 552 AC_PROG_CC(gcc)
 553 AC_PROG_CXX(g++)
 554
 555 AC_PROG_NM
 556 AC_SUBST(NM)
 557
 558 dnl Check for the tools that the makefiles require
 559 AC_CHECK_GNU_MAKE
 560 AC_PROG_LN_S
 561 AC_PATH_PROG(CMP, [cmp], [cmp])
 562 AC_PATH_PROG(CP, [cp], [cp])
 563 AC_PATH_PROG(DATE, [date], [date])
 564 AC_PATH_PROG(FIND, [find], [find])
 565 AC_PATH_PROG(GREP, [grep], [grep])
 566 AC_PATH_PROG(MKDIR,[mkdir],[mkdir])
 567 AC_PATH_PROG(MV,   [mv],   [mv])
 568 AC_PROG_RANLIB
 569 AC_PATH_PROG(RM,   [rm],   [rm])
 570 AC_PATH_PROG(SED,  [sed],  [sed])
 571 AC_PATH_PROG(TAR,  [tar],  [gtar])
 572 AC_PATH_PROG(BINPWD,[pwd],  [pwd])
 573
 574 dnl Looking for misc. graph plotting software
 575 AC_PATH_PROG(GRAPHVIZ, [Graphviz], [echo Graphviz])
 576 if test "$GRAPHVIZ" != "echo Graphviz" ; then
 577   AC_DEFINE([HAVE_GRAPHVIZ],[1],[Define if the Graphviz program is available])
 578   dnl If we're targeting for mingw we should emit windows paths, not msys
 579   if test "$llvm_cv_os_type" = "MingW" ; then
 580     GRAPHVIZ=`echo $GRAPHVIZ | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 581   fi
 582   AC_DEFINE_UNQUOTED([LLVM_PATH_GRAPHVIZ],"$GRAPHVIZ${EXEEXT}",
 583    [Define to path to Graphviz program if found or 'echo Graphviz' otherwise])
 584 fi
 585 AC_PATH_PROG(DOT, [dot], [echo dot])
 586 if test "$DOT" != "echo dot" ; then
 587   AC_DEFINE([HAVE_DOT],[1],[Define if the dot program is available])
 588   dnl If we're targeting for mingw we should emit windows paths, not msys
 589   if test "$llvm_cv_os_type" = "MingW" ; then
 590     DOT=`echo $DOT | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 591   fi
 592   AC_DEFINE_UNQUOTED([LLVM_PATH_DOT],"$DOT${EXEEXT}",
 593    [Define to path to dot program if found or 'echo dot' otherwise])
 594 fi
 595 AC_PATH_PROGS(GV, [gv gsview32], [echo gv])
 596 if test "$GV" != "echo gv" ; then
 597   AC_DEFINE([HAVE_GV],[1],[Define if the gv program is available])
 598   dnl If we're targeting for mingw we should emit windows paths, not msys
 599   if test "$llvm_cv_os_type" = "MingW" ; then
 600     GV=`echo $GV | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 601   fi
 602   AC_DEFINE_UNQUOTED([LLVM_PATH_GV],"$GV${EXEEXT}",
 603    [Define to path to gv program if found or 'echo gv' otherwise])
 604 fi
 605 AC_PATH_PROG(DOTTY, [dotty], [echo dotty])
 606 if test "$DOTTY" != "echo dotty" ; then
 607   AC_DEFINE([HAVE_DOTTY],[1],[Define if the dotty program is available])
 608   dnl If we're targeting for mingw we should emit windows paths, not msys
 609   if test "$llvm_cv_os_type" = "MingW" ; then
 610     DOTTY=`echo $DOTTY | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 611   fi
 612   AC_DEFINE_UNQUOTED([LLVM_PATH_DOTTY],"$DOTTY${EXEEXT}",
 613    [Define to path to dotty program if found or 'echo dotty' otherwise])
 614 fi
 615
 616 dnl Look for a sufficiently recent version of Perl.
 617 LLVM_PROG_PERL([5.006])
 618 AC_SUBST(PERL)
 619 if test x"$PERL" = xnone; then
 620    AC_SUBST(HAVE_PERL,0)
 621    AC_MSG_ERROR([perl is required but was not found, please install it])
 622 else
 623    AC_SUBST(HAVE_PERL,1)
 624 fi
 625
 626 dnl Find the install program
 627 AC_PROG_INSTALL
 628
 629 dnl Checks for documentation and testing tools that we can do without. If these
 630 dnl are not found then they are set to "true" which always succeeds but does
 631 dnl nothing. This just lets the build output show that we could have done
 632 dnl something if the tool was available.
 633 AC_PATH_PROG(BZIP2, [bzip2])
 634 AC_PATH_PROG(DOXYGEN, [doxygen])
 635 AC_PATH_PROG(GROFF, [groff])
 636 AC_PATH_PROG(GZIP, [gzip])
 637 AC_PATH_PROG(POD2HTML, [pod2html])
 638 AC_PATH_PROG(POD2MAN, [pod2man])
 639 AC_PATH_PROG(RUNTEST, [runtest])
 640 DJ_AC_PATH_TCLSH
 641 AC_PATH_PROG(ZIP, [zip])
 642 AC_PATH_PROGS(OCAMLC, [ocamlc])
 643 AC_PATH_PROGS(OCAMLOPT, [ocamlopt])
 644 AC_PATH_PROGS(OCAMLDEP, [ocamldep])
 645 AC_PATH_PROGS(OCAMLDOC, [ocamldoc])
 646 AC_PATH_PROGS(GAS, [gas as])
 647
 648 dnl Determine whether the linker supports the -R option.
 649 AC_LINK_USE_R
 650
 651 dnl Determine whether the linker supports the -export-dynamic option.
 652 AC_LINK_EXPORT_DYNAMIC
 653
 654 dnl Check for libtool and the library that has dlopen function (which must come
 655 dnl before the AC_PROG_LIBTOOL check in order to enable dlopening libraries with
 656 dnl libtool).
 657 AC_LIBTOOL_DLOPEN
 658 AC_LIB_LTDL
 659 AC_PROG_LIBTOOL
 660
 661 if test "$lt_cv_dlopen_self" = "yes" ; then
 662   AC_DEFINE([CAN_DLOPEN_SELF],[1],
 663               [Define if dlopen(0) will open the symbols of the program])
 664 fi
 665
 666 if test "$WITH_LLVMGCCDIR" = "default" ; then
 667   LLVMGCC="llvm-gcc${EXEEXT}"
 668   LLVMGXX="llvm-g++${EXEEXT}"
 669   AC_PATH_PROG(LLVMGCC, $LLVMGCC, [])
 670   AC_PATH_PROG(LLVMGXX, $LLVMGXX, [])
 671 else
 672   if test -z "$LLVMGCC"; then
 673     LLVMGCC="$WITH_LLVMGCCDIR/bin/llvm-gcc${EXEEXT}"
 674   fi
 675   if test -z "$LLVMGXX"; then
 676     LLVMGXX="$WITH_LLVMGCCDIR/bin/llvm-g++${EXEEXT}"
 677   fi
 678   AC_SUBST(LLVMGCC,$LLVMGCC)
 679   AC_SUBST(LLVMGXX,$LLVMGXX)
 680 fi
 681
 682 AC_MSG_CHECKING([tool compatibility])
 683
 684 dnl Ensure that compilation tools are GCC or a GNU compatible compiler such as
 685 dnl ICC; we use GCC specific options in the makefiles so the compiler needs
 686 dnl to support those options.
 687 dnl "icc" emits gcc signatures
 688 dnl "icc -no-gcc" emits no gcc signature BUT is still compatible
 689 ICC=no
 690 IXX=no
 691 case $CC in
 692   icc*|icpc*)
 693     ICC=yes
 694     IXX=yes
 695     ;;
 696    *)
 697     ;;
 698 esac
 699
 700 if test "$GCC" != "yes" && test "$ICC" != "yes"
 701 then
 702   AC_MSG_ERROR([gcc|icc required but not found])
 703 fi
 704
 705 dnl Ensure that compilation tools are GCC; we use GCC specific extensions
 706 if test "$GXX" != "yes" && test "$IXX" != "yes"
 707 then
 708   AC_MSG_ERROR([g++|icc required but not found])
 709 fi
 710
 711 dnl Verify that GCC is version 3.0 or higher
 712 if test "$GCC" = "yes"
 713 then
 714   AC_COMPILE_IFELSE([[#if !defined(__GNUC__) || __GNUC__ < 3
 715 #error Unsupported GCC version
 716 #endif
 717 ]], [], [AC_MSG_ERROR([gcc 3.x required, but you have a lower version])])
 718 fi
 719
 720 dnl Check for GNU Make.  We use its extensions, so don't build without it
 721 if test -z "$llvm_cv_gnu_make_command"
 722 then
 723   AC_MSG_ERROR([GNU Make required but not found])
 724 fi
 725
 726 dnl Tool compatibility is okay if we make it here.
 727 AC_MSG_RESULT([ok])
 728
 729 dnl===-----------------------------------------------------------------------===
 730 dnl===
 731 dnl=== SECTION 5: Check for libraries
 732 dnl===
 733 dnl===-----------------------------------------------------------------------===
 734
 735 dnl libelf is for sparc only; we can ignore it if we don't have it
 736 AC_CHECK_LIB(elf, elf_begin)
 737 AC_CHECK_LIB(m,sin)
 738 if test "$llvm_cv_os_type" = "MingW" ; then
 739   AC_CHECK_LIB(imagehlp, main)
 740   AC_CHECK_LIB(psapi, main)
 741 fi
 742
 743 dnl dlopen() is required for plugin support.
 744 AC_SEARCH_LIBS(dlopen,dl,AC_DEFINE([HAVE_DLOPEN],[1],
 745                [Define if dlopen() is available on this platform.]),
 746                AC_MSG_WARN([dlopen() not found - disabling plugin support]))
 747
 748 dnl libffi is optional; used to call external functions from the interpreter
 749 AC_SEARCH_LIBS(ffi_call,ffi,AC_DEFINE([HAVE_FFI_CALL],[1],
 750                [Define if libffi is available on this platform.]),
 751                AC_MSG_WARN([libffi not found - disabling external calls from interpreter]))
 752
 753 dnl mallinfo is optional; the code can compile (minus features) without it
 754 AC_SEARCH_LIBS(mallinfo,malloc,AC_DEFINE([HAVE_MALLINFO],[1],
 755                [Define if mallinfo() is available on this platform.]))
 756
 757 dnl pthread locking functions are optional - but llvm will not be thread-safe
 758 dnl without locks.
 759 if test "$ENABLE_THREADS" -eq 1 ; then
 760   AC_CHECK_LIB(pthread,pthread_mutex_init)
 761   AC_SEARCH_LIBS(pthread_mutex_lock,pthread,
 762                  AC_DEFINE([HAVE_PTHREAD_MUTEX_LOCK],[1],
 763                            [Have pthread_mutex_lock]))
 764 fi
 765
 766 dnl Allow extra x86-disassembler library
 767 AC_ARG_WITH(udis86,
 768   AS_HELP_STRING([--with-udis86=<path>],
 769     [Use udis86 external x86 disassembler library]),
 770     [
 771       AC_SUBST(USE_UDIS86, [1])
 772       case "$withval" in
 773         /usr/lib|yes) ;;
 774         *) LDFLAGS="$LDFLAGS -L${withval}" ;;
 775       esac
 776       AC_CHECK_LIB(udis86, ud_init, [], [
 777         echo "Error! You need to have libudis86 around."
 778         exit -1
 779       ])
 780     ],
 781     AC_SUBST(USE_UDIS86, [0]))
 782 AC_DEFINE_UNQUOTED([USE_UDIS86],$USE_UDIS86,
 783                    [Define if use udis86 library])
 784
 785 dnl===-----------------------------------------------------------------------===
 786 dnl===
 787 dnl=== SECTION 6: Check for header files
 788 dnl===
 789 dnl===-----------------------------------------------------------------------===
 790
 791 dnl First, use autoconf provided macros for specific headers that we need
 792 dnl We don't check for ancient stuff or things that are guaranteed to be there
 793 dnl by the C++ standard. We always use the <cfoo> versions of <foo.h> C headers.
 794 dnl Generally we're looking for POSIX headers.
 795 AC_HEADER_DIRENT
 796 AC_HEADER_MMAP_ANONYMOUS
 797 AC_HEADER_STAT
 798 AC_HEADER_STDC
 799 AC_HEADER_SYS_WAIT
 800 AC_HEADER_TIME
 801
 802 AC_CHECK_HEADERS([dlfcn.h execinfo.h fcntl.h inttypes.h limits.h link.h])
 803 AC_CHECK_HEADERS([malloc.h setjmp.h signal.h stdint.h unistd.h utime.h])
 804 AC_CHECK_HEADERS([windows.h])
 805 AC_CHECK_HEADERS([sys/mman.h sys/param.h sys/resource.h sys/time.h])
 806 AC_CHECK_HEADERS([sys/types.h malloc/malloc.h mach/mach.h])
 807 if test "$ENABLE_THREADS" -eq 1 ; then
 808   AC_CHECK_HEADERS(pthread.h,
 809                    AC_SUBST(HAVE_PTHREAD, 1),
 810                    AC_SUBST(HAVE_PTHREAD, 0))
 811 else
 812   AC_SUBST(HAVE_PTHREAD, 0)
 813 fi
 814
 815 dnl Try to find ffi.h.
 816 AC_CHECK_HEADERS([ffi.h ffi/ffi.h])
 817
 818 dnl===-----------------------------------------------------------------------===
 819 dnl===
 820 dnl=== SECTION 7: Check for types and structures
 821 dnl===
 822 dnl===-----------------------------------------------------------------------===
 823
 824 AC_HUGE_VAL_CHECK
 825 AC_TYPE_PID_T
 826 AC_TYPE_SIZE_T
 827 AC_TYPE_SIGNAL
 828 AC_STRUCT_TM
 829 AC_CHECK_TYPES([int64_t],,AC_MSG_ERROR([Type int64_t required but not found]))
 830 AC_CHECK_TYPES([uint64_t],,
 831          AC_CHECK_TYPES([u_int64_t],,
 832          AC_MSG_ERROR([Type uint64_t or u_int64_t required but not found])))
 833
 834 dnl===-----------------------------------------------------------------------===
 835 dnl===
 836 dnl=== SECTION 8: Check for specific functions needed
 837 dnl===
 838 dnl===-----------------------------------------------------------------------===
 839
 840 AC_CHECK_FUNCS([backtrace ceilf floorf roundf rintf nearbyintf getcwd ])
 841 AC_CHECK_FUNCS([powf fmodf strtof round ])
 842 AC_CHECK_FUNCS([getpagesize getrusage getrlimit setrlimit gettimeofday ])
 843 AC_CHECK_FUNCS([isatty mkdtemp mkstemp ])
 844 AC_CHECK_FUNCS([mktemp realpath sbrk setrlimit strdup strerror strerror_r ])
 845 AC_CHECK_FUNCS([strtoll strtoq sysconf malloc_zone_statistics ])
 846 AC_CHECK_FUNCS([setjmp longjmp sigsetjmp siglongjmp])
 847 AC_C_PRINTF_A
 848 AC_FUNC_ALLOCA
 849 AC_FUNC_RAND48
 850
 851 dnl Check for variations in the Standard C++ library and STL. These macros are
 852 dnl provided by LLVM in the autoconf/m4 directory.
 853 AC_CXX_HAVE_STD_ITERATOR
 854 AC_CXX_HAVE_BI_ITERATOR
 855 AC_CXX_HAVE_FWD_ITERATOR
 856 AC_FUNC_ISNAN
 857 AC_FUNC_ISINF
 858
 859 dnl Check for mmap support.We also need to know if /dev/zero is required to
 860 dnl be opened for allocating RWX memory.
 861 dnl Make sure we aren't attempting to configure for an unknown system
 862 if test "$llvm_cv_platform_type" = "Unix" ; then
 863   AC_FUNC_MMAP
 864   AC_FUNC_MMAP_FILE
 865   AC_NEED_DEV_ZERO_FOR_MMAP
 866
 867   if test "$ac_cv_func_mmap_fixed_mapped" = "no"
 868   then
 869     AC_MSG_WARN([mmap() of a fixed address required but not supported])
 870   fi
 871   if test "$ac_cv_func_mmap_file" = "no"
 872   then
 873     AC_MSG_WARN([mmap() of files required but not found])
 874   fi
 875 fi
 876
 877 dnl===-----------------------------------------------------------------------===
 878 dnl===
 879 dnl=== SECTION 9: Additional checks, variables, etc.
 880 dnl===
 881 dnl===-----------------------------------------------------------------------===
 882
 883 dnl Check, whether __dso_handle is present
 884 AC_CHECK_FUNCS([__dso_handle])
 885
 886 dnl See if the llvm-gcc executable can compile to LLVM assembly
 887 AC_CACHE_CHECK([whether llvm-gcc is sane],[llvm_cv_llvmgcc_sanity],
 888 [llvm_cv_llvmgcc_sanity="no"
 889 if test -x "$LLVMGCC" ; then
 890   cp /dev/null conftest.c
 891   "$LLVMGCC" -emit-llvm -S -o - conftest.c | \
 892       grep 'target datalayout =' > /dev/null 2>&1
 893   if test $? -eq 0 ; then
 894     llvm_cv_llvmgcc_sanity="yes"
 895   fi
 896   rm conftest.c
 897 fi])
 898
 899 dnl Since we have a sane llvm-gcc, identify it and its sub-tools
 900 if test "$llvm_cv_llvmgcc_sanity" = "yes" ; then
 901   AC_MSG_CHECKING([llvm-gcc component support])
 902   llvmcc1path=`"$LLVMGCC" --print-prog-name=cc1`
 903   AC_SUBST(LLVMCC1,$llvmcc1path)
 904   llvmcc1pluspath=`"$LLVMGCC" --print-prog-name=cc1plus`
 905   AC_SUBST(LLVMCC1PLUS,$llvmcc1pluspath)
 906   llvmgccdir=`echo "$llvmcc1path" | sed 's,/libexec/.*,,'`
 907   AC_SUBST(LLVMGCCDIR,$llvmgccdir)
 908   llvmgcclibexec=`echo "$llvmcc1path" | sed 's,/cc1,,'`
 909   AC_SUBST(LLVMGCCLIBEXEC,$llvmgcclibexec)
 910   llvmgccversion=[`"$LLVMGCC" -dumpversion 2>&1 | sed 's/^\([0-9.]*\).*/\1/'`]
 911   llvmgccmajvers=[`echo $llvmgccversion | sed 's/^\([0-9]\).*/\1/'`]
 912   AC_SUBST(LLVMGCC_VERSION,$llvmgccversion)
 913   AC_SUBST(LLVMGCC_MAJVERS,$llvmgccmajvers)
 914   llvmgcclangs=[`"$LLVMGCC" -v --help 2>&1 | grep '^Configured with:' | sed 's/^.*--enable-languages=\([^ ]*\).*/\1/'`]
 915   AC_SUBST(LLVMGCC_LANGS,$llvmgcclangs)
 916   AC_MSG_RESULT([ok])
 917 fi
 918
 919 dnl Propagate the shared library extension that the libltdl checks did to
 920 dnl the Makefiles so we can use it there too
 921 AC_SUBST(SHLIBEXT,$libltdl_cv_shlibext)
 922
 923 # Translate the various configuration directories and other basic
 924 # information into substitutions that will end up in Makefile.config.in
 925 # that these configured values can be used by the makefiles
 926 if test "${prefix}" = "NONE" ; then
 927   prefix="/usr/local"
 928 fi
 929 eval LLVM_PREFIX="${prefix}";
 930 eval LLVM_BINDIR="${prefix}/bin";
 931 eval LLVM_LIBDIR="${prefix}/lib";
 932 eval LLVM_DATADIR="${prefix}/share/llvm";
 933 eval LLVM_DOCSDIR="${prefix}/docs/llvm";
 934 eval LLVM_ETCDIR="${prefix}/etc/llvm";
 935 eval LLVM_INCLUDEDIR="${prefix}/include";
 936 eval LLVM_INFODIR="${prefix}/info";
 937 eval LLVM_MANDIR="${prefix}/man";
 938 LLVM_CONFIGTIME=`date`
 939 AC_SUBST(LLVM_PREFIX)
 940 AC_SUBST(LLVM_BINDIR)
 941 AC_SUBST(LLVM_LIBDIR)
 942 AC_SUBST(LLVM_DATADIR)
 943 AC_SUBST(LLVM_DOCSDIR)
 944 AC_SUBST(LLVM_ETCDIR)
 945 AC_SUBST(LLVM_INCLUDEDIR)
 946 AC_SUBST(LLVM_INFODIR)
 947 AC_SUBST(LLVM_MANDIR)
 948 AC_SUBST(LLVM_CONFIGTIME)
 949
 950 # Place the various directores into the config.h file as #defines so that we
 951 # can know about the installation paths within LLVM.
 952 AC_DEFINE_UNQUOTED(LLVM_PREFIX,"$LLVM_PREFIX",
 953                    [Installation prefix directory])
 954 AC_DEFINE_UNQUOTED(LLVM_BINDIR, "$LLVM_BINDIR",
 955                    [Installation directory for binary executables])
 956 AC_DEFINE_UNQUOTED(LLVM_LIBDIR, "$LLVM_LIBDIR",
 957                    [Installation directory for libraries])
 958 AC_DEFINE_UNQUOTED(LLVM_DATADIR, "$LLVM_DATADIR",
 959                    [Installation directory for data files])
 960 AC_DEFINE_UNQUOTED(LLVM_DOCSDIR, "$LLVM_DOCSDIR",
 961                    [Installation directory for documentation])
 962 AC_DEFINE_UNQUOTED(LLVM_ETCDIR, "$LLVM_ETCDIR",
 963                    [Installation directory for config files])
 964 AC_DEFINE_UNQUOTED(LLVM_INCLUDEDIR, "$LLVM_INCLUDEDIR",
 965                    [Installation directory for include files])
 966 AC_DEFINE_UNQUOTED(LLVM_INFODIR, "$LLVM_INFODIR",
 967                    [Installation directory for .info files])
 968 AC_DEFINE_UNQUOTED(LLVM_MANDIR, "$LLVM_MANDIR",
 969                    [Installation directory for man pages])
 970 AC_DEFINE_UNQUOTED(LLVM_CONFIGTIME, "$LLVM_CONFIGTIME",
 971                    [Time at which LLVM was configured])
 972 AC_DEFINE_UNQUOTED(LLVM_HOSTTRIPLE, "$host",
 973                    [Host triple we were built on])
 974
 975 # Determine which bindings to build.
 976 if test "$BINDINGS_TO_BUILD" = auto ; then
 977   BINDINGS_TO_BUILD=""
 978   if test "x$OCAMLC" != x -a "x$OCAMLDEP" != x ; then
 979     BINDINGS_TO_BUILD="ocaml $BINDINGS_TO_BUILD"
 980   fi
 981 fi
 982 AC_SUBST(BINDINGS_TO_BUILD,$BINDINGS_TO_BUILD)
 983
 984 # This isn't really configurey, but it avoids having to repeat the list in
 985 # other files.
 986 AC_SUBST(ALL_BINDINGS,ocaml)
 987
 988 # Do any work necessary to ensure that bindings have what they need.
 989 binding_prereqs_failed=0
 990 for a_binding in $BINDINGS_TO_BUILD ; do
 991   case "$a_binding" in
 992   ocaml)
 993     if test "x$OCAMLC" = x ; then
 994       AC_MSG_WARN([--enable-bindings=ocaml specified, but ocamlc not found. Try configure OCAMLC=/path/to/ocamlc])
 995       binding_prereqs_failed=1
 996     fi
 997     if test "x$OCAMLDEP" = x ; then
 998       AC_MSG_WARN([--enable-bindings=ocaml specified, but ocamldep not found. Try configure OCAMLDEP=/path/to/ocamldep])
 999       binding_prereqs_failed=1
1000     fi
1001     if test "x$OCAMLOPT" = x ; then
1002       AC_MSG_WARN([--enable-bindings=ocaml specified, but ocamlopt not found. Try configure OCAMLOPT=/path/to/ocamlopt])
1003       dnl ocamlopt is optional!
1004     fi
1005     if test "x$with_ocaml_libdir" != xauto ; then
1006       AC_SUBST(OCAML_LIBDIR,$with_ocaml_libdir)
1007     else
1008       ocaml_stdlib="`"$OCAMLC" -where`"
1009       if test "$LLVM_PREFIX" '<' "$ocaml_stdlib" -a "$ocaml_stdlib" '<' "$LLVM_PREFIX~"
1010       then
1011         # ocaml stdlib is beneath our prefix; use stdlib
1012         AC_SUBST(OCAML_LIBDIR,$ocaml_stdlib)
1013       else
1014         # ocaml stdlib is outside our prefix; use libdir/ocaml
1015         AC_SUBST(OCAML_LIBDIR,$LLVM_LIBDIR/ocaml)
1016       fi
1017     fi
1018     ;;
1019   esac
1020 done
1021 if test "$binding_prereqs_failed" = 1 ; then
1022   AC_MSG_ERROR([Prequisites for bindings not satisfied. Fix them or use configure --disable-bindings.])
1023 fi
1024
1025 dnl Determine whether the compiler supports -fvisibility-inlines-hidden.
1026 AC_CXX_USE_VISIBILITY_INLINES_HIDDEN
1027
1028 dnl Determine linker rpath flag
1029 if test "$llvm_cv_link_use_r" = "yes" ; then
1030   RPATH="-Wl,-R"
1031 else
1032   RPATH="-Wl,-rpath"
1033 fi
1034 AC_SUBST(RPATH)
1035
1036 dnl Determine linker rdynamic flag
1037 if test "$llvm_cv_link_use_export_dynamic" = "yes" ; then
1038   RDYNAMIC="-Wl,-export-dynamic"
1039 else
1040   RDYNAMIC=""
1041 fi
1042 AC_SUBST(RDYNAMIC)
1043
1044 dnl===-----------------------------------------------------------------------===
1045 dnl===
1046 dnl=== SECTION 10: Specify the output files and generate it
1047 dnl===
1048 dnl===-----------------------------------------------------------------------===
1049
1050 dnl Configure header files
1051 dnl WARNING: dnl If you add or remove any of the following config headers, then
1052 dnl you MUST also update Makefile.rules so that the variable FilesToConfig
1053 dnl contains the same list of files as AC_CONFIG_HEADERS below. This ensures the
1054 dnl files can be updated automatically when their *.in sources change.
1055 AC_CONFIG_HEADERS([include/llvm/Config/config.h])
1056 AC_CONFIG_HEADERS([include/llvm/Support/DataTypes.h])
1057 AC_CONFIG_HEADERS([include/llvm/ADT/iterator.h])
1058
1059 dnl Configure the makefile's configuration data
1060 AC_CONFIG_FILES([Makefile.config])
1061
1062 dnl Configure the RPM spec file for LLVM
1063 AC_CONFIG_FILES([llvm.spec])
1064
1065 dnl Configure doxygen's configuration file
1066 AC_CONFIG_FILES([docs/doxygen.cfg])
1067
1068 dnl Do the first stage of configuration for llvm-config.in.
1069 AC_CONFIG_FILES([tools/llvm-config/llvm-config.in])
1070
1071 dnl Do special configuration of Makefiles
1072 AC_CONFIG_COMMANDS([setup],,[llvm_src="${srcdir}"])
1073 AC_CONFIG_MAKEFILE(Makefile)
1074 AC_CONFIG_MAKEFILE(Makefile.common)
1075 AC_CONFIG_MAKEFILE(examples/Makefile)
1076 AC_CONFIG_MAKEFILE(lib/Makefile)
1077 AC_CONFIG_MAKEFILE(runtime/Makefile)
1078 AC_CONFIG_MAKEFILE(test/Makefile)
1079 AC_CONFIG_MAKEFILE(test/Makefile.tests)
1080 AC_CONFIG_MAKEFILE(unittests/Makefile)
1081 AC_CONFIG_MAKEFILE(tools/Makefile)
1082 AC_CONFIG_MAKEFILE(utils/Makefile)
1083 AC_CONFIG_MAKEFILE(projects/Makefile)
1084 AC_CONFIG_MAKEFILE(bindings/Makefile)
1085 AC_CONFIG_MAKEFILE(bindings/ocaml/Makefile.ocaml)
1086
1087 dnl Finally, crank out the output
1088 AC_OUTPUT