autoconf/configure.ac

   1 dnl === configure.ac --------------------------------------------------------===
   2 dnl                     The LLVM Compiler Infrastructure
   3 dnl
   4 dnl This file is distributed under the University of Illinois Open Source
   5 dnl License. See LICENSE.TXT for details.
   6 dnl
   7 dnl===-----------------------------------------------------------------------===
   8 dnl This is the LLVM configuration script. It is processed by the autoconf
   9 dnl program to produce a script named configure. This script contains the
  10 dnl configuration checks that LLVM needs in order to support multiple platforms.
  11 dnl This file is composed of 10 sections per the recommended organization of
  12 dnl autoconf input defined in the autoconf documentation. As this file evolves,
  13 dnl please keep the various types of checks within their sections. The sections
  14 dnl are as follows:
  15 dnl
  16 dnl SECTION 1: Initialization & Setup
  17 dnl SECTION 2: Architecture, target, and host checks
  18 dnl SECTION 3: Command line arguments for the configure script.
  19 dnl SECTION 4: Check for programs we need and that they are the right version
  20 dnl SECTION 5: Check for libraries
  21 dnl SECTION 6: Check for header files
  22 dnl SECTION 7: Check for types and structures
  23 dnl SECTION 8: Check for specific functions needed
  24 dnl SECTION 9: Additional checks, variables, etc.
  25 dnl SECTION 10: Specify the output files and generate it
  26 dnl
  27 dnl===-----------------------------------------------------------------------===
  28 dnl===
  29 dnl=== SECTION 1: Initialization & Setup
  30 dnl===
  31 dnl===-----------------------------------------------------------------------===
  32 dnl Initialize autoconf and define the package name, version number and
  33 dnl email address for reporting bugs.
  34 AC_INIT([[llvm]],[[3.1svn]],[llvmbugs@cs.uiuc.edu])
  35
  36 dnl Provide a copyright substitution and ensure the copyright notice is included
  37 dnl in the output of --version option of the generated configure script.
  38 AC_SUBST(LLVM_COPYRIGHT,["Copyright (c) 2003-2011 University of Illinois at Urbana-Champaign."])
  39 AC_COPYRIGHT([Copyright (c) 2003-2011 University of Illinois at Urbana-Champaign.])
  40
  41 dnl Indicate that we require autoconf 2.60 or later.
  42 AC_PREREQ(2.60)
  43
  44 dnl Verify that the source directory is valid. This makes sure that we are
  45 dnl configuring LLVM and not some other package (it validates --srcdir argument)
  46 AC_CONFIG_SRCDIR([lib/VMCore/Module.cpp])
  47
  48 dnl Place all of the extra autoconf files into the config subdirectory. Tell
  49 dnl various tools where the m4 autoconf macros are.
  50 AC_CONFIG_AUX_DIR([autoconf])
  51
  52 dnl Quit if the source directory has already been configured.
  53 dnl NOTE: This relies upon undocumented autoconf behavior.
  54 if test ${srcdir} != "." ; then
  55   if test -f ${srcdir}/include/llvm/Config/config.h ; then
  56     AC_MSG_ERROR([Already configured in ${srcdir}])
  57   fi
  58 fi
  59
  60 dnl We need to check for the compiler up here to avoid anything else
  61 dnl starting with a different one.
  62 AC_PROG_CC(clang llvm-gcc gcc)
  63 AC_PROG_CXX(clang++ llvm-g++ g++)
  64 AC_PROG_CPP
  65
  66 dnl Configure all of the projects present in our source tree. While we could
  67 dnl just AC_CONFIG_SUBDIRS on the set of directories in projects that have a
  68 dnl configure script, that usage of the AC_CONFIG_SUBDIRS macro is deprecated.
  69 dnl Instead we match on the known projects.
  70
  71 dnl
  72 dnl One tricky part of doing this is that some projects depend upon other
  73 dnl projects.  For example, several projects rely upon the LLVM test suite.
  74 dnl We want to configure those projects first so that their object trees are
  75 dnl created before running the configure scripts of projects that depend upon
  76 dnl them.
  77 dnl
  78
  79 dnl Several projects use llvm-gcc, so configure that first
  80 if test -d ${srcdir}/projects/llvm-gcc ; then
  81   AC_CONFIG_SUBDIRS([projects/llvm-gcc])
  82 fi
  83
  84 dnl Several projects use the LLVM test suite, so configure it next.
  85 if test -d ${srcdir}/projects/test-suite ; then
  86   AC_CONFIG_SUBDIRS([projects/test-suite])
  87 fi
  88
  89 dnl llvm-test is the old name of the test-suite, kept here for backwards
  90 dnl compatibility
  91 if test -d ${srcdir}/projects/llvm-test ; then
  92   AC_CONFIG_SUBDIRS([projects/llvm-test])
  93 fi
  94
  95 dnl Some projects use poolalloc; configure that next
  96 if test -d ${srcdir}/projects/poolalloc ; then
  97   AC_CONFIG_SUBDIRS([projects/poolalloc])
  98 fi
  99
 100 if test -d ${srcdir}/projects/llvm-poolalloc ; then
 101   AC_CONFIG_SUBDIRS([projects/llvm-poolalloc])
 102 fi
 103
 104 dnl Check for all other projects
 105 for i in `ls ${srcdir}/projects`
 106 do
 107   if test -d ${srcdir}/projects/${i} ; then
 108     case ${i} in
 109       sample)       AC_CONFIG_SUBDIRS([projects/sample])    ;;
 110       privbracket)  AC_CONFIG_SUBDIRS([projects/privbracket]) ;;
 111       llvm-stacker) AC_CONFIG_SUBDIRS([projects/llvm-stacker]) ;;
 112       llvm-reopt)   AC_CONFIG_SUBDIRS([projects/llvm-reopt]);;
 113       llvm-java)    AC_CONFIG_SUBDIRS([projects/llvm-java]) ;;
 114       llvm-tv)      AC_CONFIG_SUBDIRS([projects/llvm-tv])   ;;
 115       safecode)     AC_CONFIG_SUBDIRS([projects/safecode]) ;;
 116       llvm-kernel)  AC_CONFIG_SUBDIRS([projects/llvm-kernel]) ;;
 117       compiler-rt)       ;;
 118       llvm-gcc)       ;;
 119       test-suite)     ;;
 120       llvm-test)      ;;
 121       poolalloc)      ;;
 122       llvm-poolalloc) ;;
 123       *)
 124         AC_MSG_WARN([Unknown project (${i}) won't be configured automatically])
 125         ;;
 126     esac
 127   fi
 128 done
 129
 130 dnl Disable the build of polly, even if it is checked out into tools/polly.
 131 AC_ARG_ENABLE(polly,
 132               AS_HELP_STRING([--enable-polly],
 133                              [Use polly if available (default is YES)]),,
 134                              enableval=default)
 135 case "$enableval" in
 136   yes) AC_SUBST(ENABLE_POLLY,[1]) ;;
 137   no)  AC_SUBST(ENABLE_POLLY,[0]) ;;
 138   default) AC_SUBST(ENABLE_POLLY,[1]) ;;
 139   *) AC_MSG_ERROR([Invalid setting for --enable-polly. Use "yes" or "no"]) ;;
 140 esac
 141
 142
 143 dnl Check if polly is checked out into tools/polly and configure it if
 144 dnl available.
 145 if (test -d ${srcdir}/tools/polly) && (test $ENABLE_POLLY -eq 1) ; then
 146   AC_SUBST(LLVM_HAS_POLLY,1)
 147   AC_CONFIG_SUBDIRS([tools/polly])
 148 fi
 149
 150 dnl===-----------------------------------------------------------------------===
 151 dnl===
 152 dnl=== SECTION 2: Architecture, target, and host checks
 153 dnl===
 154 dnl===-----------------------------------------------------------------------===
 155
 156 dnl Check the target for which we're compiling and the host that will do the
 157 dnl compilations. This will tell us which LLVM compiler will be used for
 158 dnl compiling SSA into object code. This needs to be done early because
 159 dnl following tests depend on it.
 160 AC_CANONICAL_TARGET
 161
 162 dnl Determine the platform type and cache its value. This helps us configure
 163 dnl the System library to the correct build platform.
 164 AC_CACHE_CHECK([type of operating system we're going to host on],
 165                [llvm_cv_os_type],
 166 [case $host in
 167   *-*-aix*)
 168     llvm_cv_link_all_option="-Wl,--whole-archive"
 169     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 170     llvm_cv_os_type="AIX"
 171     llvm_cv_platform_type="Unix" ;;
 172   *-*-irix*)
 173     llvm_cv_link_all_option="-Wl,--whole-archive"
 174     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 175     llvm_cv_os_type="IRIX"
 176     llvm_cv_platform_type="Unix" ;;
 177   *-*-cygwin*)
 178     llvm_cv_link_all_option="-Wl,--whole-archive"
 179     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 180     llvm_cv_os_type="Cygwin"
 181     llvm_cv_platform_type="Unix" ;;
 182   *-*-darwin*)
 183     llvm_cv_link_all_option="-Wl,-all_load"
 184     llvm_cv_no_link_all_option="-Wl,-noall_load"
 185     llvm_cv_os_type="Darwin"
 186     llvm_cv_platform_type="Unix" ;;
 187   *-*-minix*)
 188     llvm_cv_link_all_option="-Wl,-all_load"
 189     llvm_cv_no_link_all_option="-Wl,-noall_load"
 190     llvm_cv_os_type="Minix"
 191     llvm_cv_platform_type="Unix" ;;
 192   *-*-freebsd*)
 193     llvm_cv_link_all_option="-Wl,--whole-archive"
 194     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 195     llvm_cv_os_type="FreeBSD"
 196     llvm_cv_platform_type="Unix" ;;
 197   *-*-openbsd*)
 198     llvm_cv_link_all_option="-Wl,--whole-archive"
 199     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 200     llvm_cv_os_type="OpenBSD"
 201     llvm_cv_platform_type="Unix" ;;
 202   *-*-netbsd*)
 203     llvm_cv_link_all_option="-Wl,--whole-archive"
 204     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 205     llvm_cv_os_type="NetBSD"
 206     llvm_cv_platform_type="Unix" ;;
 207   *-*-dragonfly*)
 208     llvm_cv_link_all_option="-Wl,--whole-archive"
 209     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 210     llvm_cv_os_type="DragonFly"
 211     llvm_cv_platform_type="Unix" ;;
 212   *-*-hpux*)
 213     llvm_cv_link_all_option="-Wl,--whole-archive"
 214     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 215     llvm_cv_os_type="HP-UX"
 216     llvm_cv_platform_type="Unix" ;;
 217   *-*-interix*)
 218     llvm_cv_link_all_option="-Wl,--whole-archive"
 219     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 220     llvm_cv_os_type="Interix"
 221     llvm_cv_platform_type="Unix" ;;
 222   *-*-linux*)
 223     llvm_cv_link_all_option="-Wl,--whole-archive"
 224     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 225     llvm_cv_os_type="Linux"
 226     llvm_cv_platform_type="Unix" ;;
 227   *-*-solaris*)
 228     llvm_cv_link_all_option="-Wl,-z,allextract"
 229     llvm_cv_no_link_all_option="-Wl,-z,defaultextract"
 230     llvm_cv_os_type="SunOS"
 231     llvm_cv_platform_type="Unix" ;;
 232   *-*-auroraux*)
 233     llvm_cv_link_all_option="-Wl,-z,allextract"
 234     llvm_cv_link_all_option="-Wl,-z,defaultextract"
 235     llvm_cv_os_type="AuroraUX"
 236     llvm_cv_platform_type="Unix" ;;
 237   *-*-win32*)
 238     llvm_cv_link_all_option="-Wl,--whole-archive"
 239     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 240     llvm_cv_os_type="Win32"
 241     llvm_cv_platform_type="Win32" ;;
 242   *-*-mingw*)
 243     llvm_cv_link_all_option="-Wl,--whole-archive"
 244     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 245     llvm_cv_os_type="MingW"
 246     llvm_cv_platform_type="Win32" ;;
 247   *-*-haiku*)
 248     llvm_cv_link_all_option="-Wl,--whole-archive"
 249     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 250     llvm_cv_os_type="Haiku"
 251     llvm_cv_platform_type="Unix" ;;
 252   *-unknown-eabi*)
 253     llvm_cv_link_all_option="-Wl,--whole-archive"
 254     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 255     llvm_cv_os_type="Freestanding"
 256     llvm_cv_platform_type="Unix" ;;
 257   *-unknown-elf*)
 258     llvm_cv_link_all_option="-Wl,--whole-archive"
 259     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 260     llvm_cv_os_type="Freestanding"
 261     llvm_cv_platform_type="Unix" ;;
 262   *)
 263     llvm_cv_link_all_option=""
 264     llvm_cv_no_link_all_option=""
 265     llvm_cv_os_type="Unknown"
 266     llvm_cv_platform_type="Unknown" ;;
 267 esac])
 268
 269 AC_CACHE_CHECK([type of operating system we're going to target],
 270                [llvm_cv_target_os_type],
 271 [case $target in
 272   *-*-aix*)
 273     llvm_cv_target_os_type="AIX" ;;
 274   *-*-irix*)
 275     llvm_cv_target_os_type="IRIX" ;;
 276   *-*-cygwin*)
 277     llvm_cv_target_os_type="Cygwin" ;;
 278   *-*-darwin*)
 279     llvm_cv_target_os_type="Darwin" ;;
 280   *-*-minix*)
 281     llvm_cv_target_os_type="Minix" ;;
 282   *-*-freebsd*)
 283     llvm_cv_target_os_type="FreeBSD" ;;
 284   *-*-openbsd*)
 285     llvm_cv_target_os_type="OpenBSD" ;;
 286   *-*-netbsd*)
 287     llvm_cv_target_os_type="NetBSD" ;;
 288   *-*-dragonfly*)
 289     llvm_cv_target_os_type="DragonFly" ;;
 290   *-*-hpux*)
 291     llvm_cv_target_os_type="HP-UX" ;;
 292   *-*-interix*)
 293     llvm_cv_target_os_type="Interix" ;;
 294   *-*-linux*)
 295     llvm_cv_target_os_type="Linux" ;;
 296   *-*-solaris*)
 297     llvm_cv_target_os_type="SunOS" ;;
 298   *-*-auroraux*)
 299     llvm_cv_target_os_type="AuroraUX" ;;
 300   *-*-win32*)
 301     llvm_cv_target_os_type="Win32" ;;
 302   *-*-mingw*)
 303     llvm_cv_target_os_type="MingW" ;;
 304   *-*-haiku*)
 305     llvm_cv_target_os_type="Haiku" ;;
 306   *-*-rtems*)
 307     llvm_cv_target_os_type="RTEMS" ;;
 308   *-*-nacl*)
 309     llvm_cv_target_os_type="NativeClient" ;;
 310   *-unknown-eabi*)
 311     llvm_cv_target_os_type="Freestanding" ;;
 312   *)
 313     llvm_cv_target_os_type="Unknown" ;;
 314 esac])
 315
 316 dnl Make sure we aren't attempting to configure for an unknown system
 317 if test "$llvm_cv_os_type" = "Unknown" ; then
 318   AC_MSG_ERROR([Operating system is unknown, configure can't continue])
 319 fi
 320
 321 dnl Set the "OS" Makefile variable based on the platform type so the
 322 dnl makefile can configure itself to specific build hosts
 323 AC_SUBST(OS,$llvm_cv_os_type)
 324 AC_SUBST(HOST_OS,$llvm_cv_os_type)
 325 AC_SUBST(TARGET_OS,$llvm_cv_target_os_type)
 326
 327 dnl Set the LINKALL and NOLINKALL Makefile variables based on the platform
 328 AC_SUBST(LINKALL,$llvm_cv_link_all_option)
 329 AC_SUBST(NOLINKALL,$llvm_cv_no_link_all_option)
 330
 331 dnl Set the "LLVM_ON_*" variables based on llvm_cv_platform_type
 332 dnl This is used by lib/Support to determine the basic kind of implementation
 333 dnl to use.
 334 case $llvm_cv_platform_type in
 335   Unix)
 336     AC_DEFINE([LLVM_ON_UNIX],[1],[Define if this is Unixish platform])
 337     AC_SUBST(LLVM_ON_UNIX,[1])
 338     AC_SUBST(LLVM_ON_WIN32,[0])
 339     ;;
 340   Win32)
 341     AC_DEFINE([LLVM_ON_WIN32],[1],[Define if this is Win32ish platform])
 342     AC_SUBST(LLVM_ON_UNIX,[0])
 343     AC_SUBST(LLVM_ON_WIN32,[1])
 344     ;;
 345 esac
 346
 347 dnl Determine what our target architecture is and configure accordingly.
 348 dnl This will allow Makefiles to make a distinction between the hardware and
 349 dnl the OS.
 350 AC_CACHE_CHECK([target architecture],[llvm_cv_target_arch],
 351 [case $target in
 352   i?86-*)                 llvm_cv_target_arch="x86" ;;
 353   amd64-* | x86_64-*)     llvm_cv_target_arch="x86_64" ;;
 354   sparc*-*)               llvm_cv_target_arch="Sparc" ;;
 355   powerpc*-*)             llvm_cv_target_arch="PowerPC" ;;
 356   arm*-*)                 llvm_cv_target_arch="ARM" ;;
 357   mips-*)                 llvm_cv_target_arch="Mips" ;;
 358   xcore-*)                llvm_cv_target_arch="XCore" ;;
 359   msp430-*)               llvm_cv_target_arch="MSP430" ;;
 360   hexagon-*)              llvm_cv_target_arch="Hexagon" ;;
 361   mblaze-*)               llvm_cv_target_arch="MBlaze" ;;
 362   ptx-*)                  llvm_cv_target_arch="PTX" ;;
 363   *)                      llvm_cv_target_arch="Unknown" ;;
 364 esac])
 365
 366 if test "$llvm_cv_target_arch" = "Unknown" ; then
 367   AC_MSG_WARN([Configuring LLVM for an unknown target archicture])
 368 fi
 369
 370 # Determine the LLVM native architecture for the target
 371 case "$llvm_cv_target_arch" in
 372     x86)     LLVM_NATIVE_ARCH="X86" ;;
 373     x86_64)  LLVM_NATIVE_ARCH="X86" ;;
 374     *)       LLVM_NATIVE_ARCH="$llvm_cv_target_arch" ;;
 375 esac
 376
 377 dnl Define a substitution, ARCH, for the target architecture
 378 AC_SUBST(ARCH,$llvm_cv_target_arch)
 379
 380 dnl Check for the endianness of the target
 381 AC_C_BIGENDIAN(AC_SUBST([ENDIAN],[big]),AC_SUBST([ENDIAN],[little]))
 382
 383 dnl Check for build platform executable suffix if we're crosscompiling
 384 if test "$cross_compiling" = yes; then
 385   AC_SUBST(LLVM_CROSS_COMPILING, [1])
 386   AC_BUILD_EXEEXT
 387   ac_build_prefix=${build_alias}-
 388   AC_CHECK_PROG(BUILD_CXX, ${ac_build_prefix}g++, ${ac_build_prefix}g++)
 389   if test -z "$BUILD_CXX"; then
 390      AC_CHECK_PROG(BUILD_CXX, g++, g++)
 391      if test -z "$BUILD_CXX"; then
 392        AC_CHECK_PROG(BUILD_CXX, c++, c++, , , /usr/ucb/c++)
 393      fi
 394   fi
 395 else
 396   AC_SUBST(LLVM_CROSS_COMPILING, [0])
 397 fi
 398
 399 dnl Check to see if there's a .svn or .git directory indicating that this
 400 dnl build is being done from a checkout. This sets up several defaults for
 401 dnl the command line switches. When we build with a checkout directory,
 402 dnl we get a debug with assertions turned on. Without, we assume a source
 403 dnl release and we get an optimized build without assertions.
 404 dnl See --enable-optimized and --enable-assertions below
 405 if test -d ".svn" -o -d "${srcdir}/.svn" -o -d ".git" -o -d "${srcdir}/.git"; then
 406   cvsbuild="yes"
 407   optimize="no"
 408   AC_SUBST(CVSBUILD,[[CVSBUILD=1]])
 409 else
 410   cvsbuild="no"
 411   optimize="yes"
 412 fi
 413
 414 dnl===-----------------------------------------------------------------------===
 415 dnl===
 416 dnl=== SECTION 3: Command line arguments for the configure script.
 417 dnl===
 418 dnl===-----------------------------------------------------------------------===
 419
 420 dnl --enable-libcpp : check whether or not to use libc++ on the command line
 421 AC_ARG_ENABLE(libcpp,
 422               AS_HELP_STRING([--enable-libcpp],
 423                              [Use libc++ if available (default is NO)]),,
 424                              enableval=default)
 425 case "$enableval" in
 426   yes) AC_SUBST(ENABLE_LIBCPP,[1]) ;;
 427   no)  AC_SUBST(ENABLE_LIBCPP,[0]) ;;
 428   default) AC_SUBST(ENABLE_LIBCPP,[0]);;
 429   *) AC_MSG_ERROR([Invalid setting for --enable-libcpp. Use "yes" or "no"]) ;;
 430 esac
 431
 432 dnl --enable-optimized : check whether they want to do an optimized build:
 433 AC_ARG_ENABLE(optimized, AS_HELP_STRING(
 434  --enable-optimized,[Compile with optimizations enabled (default is NO)]),,enableval=$optimize)
 435 if test ${enableval} = "no" ; then
 436   AC_SUBST(ENABLE_OPTIMIZED,[[]])
 437 else
 438   AC_SUBST(ENABLE_OPTIMIZED,[[ENABLE_OPTIMIZED=1]])
 439 fi
 440
 441 dnl --enable-profiling : check whether they want to do a profile build:
 442 AC_ARG_ENABLE(profiling, AS_HELP_STRING(
 443  --enable-profiling,[Compile with profiling enabled (default is NO)]),,enableval="no")
 444 if test ${enableval} = "no" ; then
 445   AC_SUBST(ENABLE_PROFILING,[[]])
 446 else
 447   AC_SUBST(ENABLE_PROFILING,[[ENABLE_PROFILING=1]])
 448 fi
 449
 450 dnl --enable-assertions : check whether they want to turn on assertions or not:
 451 AC_ARG_ENABLE(assertions,AS_HELP_STRING(
 452   --enable-assertions,[Compile with assertion checks enabled (default is YES)]),, enableval="yes")
 453 if test ${enableval} = "yes" ; then
 454   AC_SUBST(DISABLE_ASSERTIONS,[[]])
 455 else
 456   AC_SUBST(DISABLE_ASSERTIONS,[[DISABLE_ASSERTIONS=1]])
 457 fi
 458
 459 dnl --enable-expensive-checks : check whether they want to turn on expensive debug checks:
 460 AC_ARG_ENABLE(expensive-checks,AS_HELP_STRING(
 461   --enable-expensive-checks,[Compile with expensive debug checks enabled (default is NO)]),, enableval="no")
 462 if test ${enableval} = "yes" ; then
 463   AC_SUBST(ENABLE_EXPENSIVE_CHECKS,[[ENABLE_EXPENSIVE_CHECKS=1]])
 464   AC_SUBST(EXPENSIVE_CHECKS,[[yes]])
 465 else
 466   AC_SUBST(ENABLE_EXPENSIVE_CHECKS,[[]])
 467   AC_SUBST(EXPENSIVE_CHECKS,[[no]])
 468 fi
 469
 470 dnl --enable-debug-runtime : should runtime libraries have debug symbols?
 471 AC_ARG_ENABLE(debug-runtime,
 472    AS_HELP_STRING(--enable-debug-runtime,[Build runtime libs with debug symbols (default is NO)]),,enableval=no)
 473 if test ${enableval} = "no" ; then
 474   AC_SUBST(DEBUG_RUNTIME,[[]])
 475 else
 476   AC_SUBST(DEBUG_RUNTIME,[[DEBUG_RUNTIME=1]])
 477 fi
 478
 479 dnl --enable-debug-symbols : should even optimized compiler libraries
 480 dnl have debug symbols?
 481 AC_ARG_ENABLE(debug-symbols,
 482    AS_HELP_STRING(--enable-debug-symbols,[Build compiler with debug symbols (default is NO if optimization is on and YES if it's off)]),,enableval=no)
 483 if test ${enableval} = "no" ; then
 484   AC_SUBST(DEBUG_SYMBOLS,[[]])
 485 else
 486   AC_SUBST(DEBUG_SYMBOLS,[[DEBUG_SYMBOLS=1]])
 487 fi
 488
 489 dnl --enable-jit: check whether they want to enable the jit
 490 AC_ARG_ENABLE(jit,
 491   AS_HELP_STRING(--enable-jit,
 492                  [Enable Just In Time Compiling (default is YES)]),,
 493   enableval=default)
 494 if test ${enableval} = "no"
 495 then
 496   AC_SUBST(JIT,[[]])
 497 else
 498   case "$llvm_cv_target_arch" in
 499     x86)         AC_SUBST(TARGET_HAS_JIT,1) ;;
 500     Sparc)       AC_SUBST(TARGET_HAS_JIT,0) ;;
 501     PowerPC)     AC_SUBST(TARGET_HAS_JIT,1) ;;
 502     x86_64)      AC_SUBST(TARGET_HAS_JIT,1) ;;
 503     ARM)         AC_SUBST(TARGET_HAS_JIT,1) ;;
 504     Mips)        AC_SUBST(TARGET_HAS_JIT,1) ;;
 505     XCore)       AC_SUBST(TARGET_HAS_JIT,0) ;;
 506     MSP430)      AC_SUBST(TARGET_HAS_JIT,0) ;;
 507     Hexagon)     AC_SUBST(TARGET_HAS_JIT,0) ;;
 508     MBlaze)      AC_SUBST(TARGET_HAS_JIT,0) ;;
 509     PTX)         AC_SUBST(TARGET_HAS_JIT,0) ;;
 510     *)           AC_SUBST(TARGET_HAS_JIT,0) ;;
 511   esac
 512 fi
 513
 514 dnl Allow enablement of building and installing docs
 515 AC_ARG_ENABLE(docs,
 516               AS_HELP_STRING([--enable-docs],
 517                              [Build documents (default is YES)]),,
 518                              enableval=default)
 519 case "$enableval" in
 520   yes) AC_SUBST(ENABLE_DOCS,[1]) ;;
 521   no)  AC_SUBST(ENABLE_DOCS,[0]) ;;
 522   default) AC_SUBST(ENABLE_DOCS,[1]) ;;
 523   *) AC_MSG_ERROR([Invalid setting for --enable-docs. Use "yes" or "no"]) ;;
 524 esac
 525
 526 dnl Allow enablement of doxygen generated documentation
 527 AC_ARG_ENABLE(doxygen,
 528               AS_HELP_STRING([--enable-doxygen],
 529                              [Build doxygen documentation (default is NO)]),,
 530                              enableval=default)
 531 case "$enableval" in
 532   yes) AC_SUBST(ENABLE_DOXYGEN,[1]) ;;
 533   no)  AC_SUBST(ENABLE_DOXYGEN,[0]) ;;
 534   default) AC_SUBST(ENABLE_DOXYGEN,[0]) ;;
 535   *) AC_MSG_ERROR([Invalid setting for --enable-doxygen. Use "yes" or "no"]) ;;
 536 esac
 537
 538 dnl Allow disablement of threads
 539 AC_ARG_ENABLE(threads,
 540               AS_HELP_STRING([--enable-threads],
 541                              [Use threads if available (default is YES)]),,
 542                              enableval=default)
 543 case "$enableval" in
 544   yes) AC_SUBST(LLVM_ENABLE_THREADS,[1]) ;;
 545   no)  AC_SUBST(LLVM_ENABLE_THREADS,[0]) ;;
 546   default) AC_SUBST(LLVM_ENABLE_THREADS,[1]) ;;
 547   *) AC_MSG_ERROR([Invalid setting for --enable-threads. Use "yes" or "no"]) ;;
 548 esac
 549 AC_DEFINE_UNQUOTED([LLVM_ENABLE_THREADS],$LLVM_ENABLE_THREADS,
 550                    [Define if threads enabled])
 551
 552 dnl Allow disablement of pthread.h
 553 AC_ARG_ENABLE(pthreads,
 554               AS_HELP_STRING([--enable-pthreads],
 555                              [Use pthreads if available (default is YES)]),,
 556                              enableval=default)
 557 case "$enableval" in
 558   yes) AC_SUBST(ENABLE_PTHREADS,[1]) ;;
 559   no)  AC_SUBST(ENABLE_PTHREADS,[0]) ;;
 560   default) AC_SUBST(ENABLE_PTHREADS,[1]) ;;
 561   *) AC_MSG_ERROR([Invalid setting for --enable-pthreads. Use "yes" or "no"]) ;;
 562 esac
 563
 564 dnl Allow building without position independent code
 565 AC_ARG_ENABLE(pic,
 566   AS_HELP_STRING([--enable-pic],
 567                  [Build LLVM with Position Independent Code (default is YES)]),,
 568                  enableval=default)
 569 case "$enableval" in
 570   yes) AC_SUBST(ENABLE_PIC,[1]) ;;
 571   no)  AC_SUBST(ENABLE_PIC,[0]) ;;
 572   default) AC_SUBST(ENABLE_PIC,[1]) ;;
 573   *) AC_MSG_ERROR([Invalid setting for --enable-pic. Use "yes" or "no"]) ;;
 574 esac
 575 AC_DEFINE_UNQUOTED([ENABLE_PIC],$ENABLE_PIC,
 576                    [Define if position independent code is enabled])
 577
 578 dnl Allow building a shared library and linking tools against it.
 579 AC_ARG_ENABLE(shared,
 580   AS_HELP_STRING([--enable-shared],
 581                  [Build a shared library and link tools against it (default is NO)]),,
 582                  enableval=default)
 583 case "$enableval" in
 584   yes) AC_SUBST(ENABLE_SHARED,[1]) ;;
 585   no)  AC_SUBST(ENABLE_SHARED,[0]) ;;
 586   default) AC_SUBST(ENABLE_SHARED,[0]) ;;
 587   *) AC_MSG_ERROR([Invalid setting for --enable-shared. Use "yes" or "no"]) ;;
 588 esac
 589
 590 dnl Allow libstdc++ is embedded in LLVM.dll.
 591 AC_ARG_ENABLE(embed-stdcxx,
 592   AS_HELP_STRING([--enable-embed-stdcxx],
 593                  [Build a shared library with embedded libstdc++ for Win32 DLL (default is NO)]),,
 594                  enableval=default)
 595 case "$enableval" in
 596   yes) AC_SUBST(ENABLE_EMBED_STDCXX,[1]) ;;
 597   no)  AC_SUBST(ENABLE_EMBED_STDCXX,[0]) ;;
 598   default) AC_SUBST(ENABLE_EMBED_STDCXX,[0]) ;;
 599   *) AC_MSG_ERROR([Invalid setting for --enable-embed-stdcxx. Use "yes" or "no"]) ;;
 600 esac
 601
 602 dnl Enable embedding timestamp information into build.
 603 AC_ARG_ENABLE(timestamps,
 604   AS_HELP_STRING([--enable-timestamps],
 605                  [Enable embedding timestamp information in build (default is YES)]),,
 606                  enableval=default)
 607 case "$enableval" in
 608   yes) AC_SUBST(ENABLE_TIMESTAMPS,[1]) ;;
 609   no)  AC_SUBST(ENABLE_TIMESTAMPS,[0]) ;;
 610   default) AC_SUBST(ENABLE_TIMESTAMPS,[1]) ;;
 611   *) AC_MSG_ERROR([Invalid setting for --enable-timestamps. Use "yes" or "no"]) ;;
 612 esac
 613 AC_DEFINE_UNQUOTED([ENABLE_TIMESTAMPS],$ENABLE_TIMESTAMPS,
 614                    [Define if timestamp information (e.g., __DATE___) is allowed])
 615
 616 dnl Allow specific targets to be specified for building (or not)
 617 TARGETS_TO_BUILD=""
 618 AC_ARG_ENABLE([targets],AS_HELP_STRING([--enable-targets],
 619     [Build specific host targets: all or target1,target2,... Valid targets are:
 620      host, x86, x86_64, sparc, powerpc, arm, mips, spu, hexagon,
 621      xcore, msp430, ptx, cbe, and cpp (default=all)]),,
 622     enableval=all)
 623 if test "$enableval" = host-only ; then
 624   enableval=host
 625 fi
 626 case "$enableval" in
 627   all) TARGETS_TO_BUILD="X86 Sparc PowerPC ARM Mips CellSPU XCore MSP430 CBackend CppBackend MBlaze PTX Hexagon" ;;
 628   *)for a_target in `echo $enableval|sed -e 's/,/ /g' ` ; do
 629       case "$a_target" in
 630         x86)      TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 631         x86_64)   TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 632         sparc)    TARGETS_TO_BUILD="Sparc $TARGETS_TO_BUILD" ;;
 633         powerpc)  TARGETS_TO_BUILD="PowerPC $TARGETS_TO_BUILD" ;;
 634         arm)      TARGETS_TO_BUILD="ARM $TARGETS_TO_BUILD" ;;
 635         mips)     TARGETS_TO_BUILD="Mips $TARGETS_TO_BUILD" ;;
 636         spu)      TARGETS_TO_BUILD="CellSPU $TARGETS_TO_BUILD" ;;
 637         xcore)    TARGETS_TO_BUILD="XCore $TARGETS_TO_BUILD" ;;
 638         msp430)   TARGETS_TO_BUILD="MSP430 $TARGETS_TO_BUILD" ;;
 639         cbe)      TARGETS_TO_BUILD="CBackend $TARGETS_TO_BUILD" ;;
 640         cpp)      TARGETS_TO_BUILD="CppBackend $TARGETS_TO_BUILD" ;;
 641         hexagon)  TARGETS_TO_BUILD="Hexagon $TARGETS_TO_BUILD" ;;
 642         mblaze)   TARGETS_TO_BUILD="MBlaze $TARGETS_TO_BUILD" ;;
 643         ptx)      TARGETS_TO_BUILD="PTX $TARGETS_TO_BUILD" ;;
 644         host) case "$llvm_cv_target_arch" in
 645             x86)         TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 646             x86_64)      TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 647             Sparc)       TARGETS_TO_BUILD="Sparc $TARGETS_TO_BUILD" ;;
 648             PowerPC)     TARGETS_TO_BUILD="PowerPC $TARGETS_TO_BUILD" ;;
 649             ARM)         TARGETS_TO_BUILD="ARM $TARGETS_TO_BUILD" ;;
 650             Mips)        TARGETS_TO_BUILD="Mips $TARGETS_TO_BUILD" ;;
 651             MBlaze)      TARGETS_TO_BUILD="MBlaze $TARGETS_TO_BUILD" ;;
 652             CellSPU|SPU) TARGETS_TO_BUILD="CellSPU $TARGETS_TO_BUILD" ;;
 653             XCore)       TARGETS_TO_BUILD="XCore $TARGETS_TO_BUILD" ;;
 654             MSP430)      TARGETS_TO_BUILD="MSP430 $TARGETS_TO_BUILD" ;;
 655             Hexagon)     TARGETS_TO_BUILD="Hexagon $TARGETS_TO_BUILD" ;;
 656             PTX)         TARGETS_TO_BUILD="PTX $TARGETS_TO_BUILD" ;;
 657             *)       AC_MSG_ERROR([Can not set target to build]) ;;
 658           esac ;;
 659         *) AC_MSG_ERROR([Unrecognized target $a_target]) ;;
 660       esac
 661   done
 662   ;;
 663 esac
 664 AC_SUBST(TARGETS_TO_BUILD,$TARGETS_TO_BUILD)
 665
 666 # Determine whether we are building LLVM support for the native architecture.
 667 # If so, define LLVM_NATIVE_ARCH to that LLVM target.
 668 for a_target in $TARGETS_TO_BUILD; do
 669   if test "$a_target" = "$LLVM_NATIVE_ARCH"; then
 670     AC_DEFINE_UNQUOTED(LLVM_NATIVE_ARCH, $LLVM_NATIVE_ARCH,
 671       [LLVM architecture name for the native architecture, if available])
 672     LLVM_NATIVE_TARGET="LLVMInitialize${LLVM_NATIVE_ARCH}Target"
 673     LLVM_NATIVE_TARGETINFO="LLVMInitialize${LLVM_NATIVE_ARCH}TargetInfo"
 674     LLVM_NATIVE_TARGETMC="LLVMInitialize${LLVM_NATIVE_ARCH}TargetMC"
 675     LLVM_NATIVE_ASMPRINTER="LLVMInitialize${LLVM_NATIVE_ARCH}AsmPrinter"
 676     if test -f ${srcdir}/lib/Target/${LLVM_NATIVE_ARCH}/AsmParser/Makefile ; then
 677       LLVM_NATIVE_ASMPARSER="LLVMInitialize${LLVM_NATIVE_ARCH}AsmParser"
 678     fi
 679     AC_DEFINE_UNQUOTED(LLVM_NATIVE_TARGET, $LLVM_NATIVE_TARGET,
 680       [LLVM name for the native Target init function, if available])
 681     AC_DEFINE_UNQUOTED(LLVM_NATIVE_TARGETINFO, $LLVM_NATIVE_TARGETINFO,
 682       [LLVM name for the native TargetInfo init function, if available])
 683     AC_DEFINE_UNQUOTED(LLVM_NATIVE_TARGETMC, $LLVM_NATIVE_TARGETMC,
 684       [LLVM name for the native target MC init function, if available])
 685     AC_DEFINE_UNQUOTED(LLVM_NATIVE_ASMPRINTER, $LLVM_NATIVE_ASMPRINTER,
 686       [LLVM name for the native AsmPrinter init function, if available])
 687     if test -f ${srcdir}/lib/Target/${LLVM_NATIVE_ARCH}/AsmParser/Makefile ; then
 688       AC_DEFINE_UNQUOTED(LLVM_NATIVE_ASMPARSER, $LLVM_NATIVE_ASMPARSER,
 689        [LLVM name for the native AsmParser init function, if available])
 690     fi
 691   fi
 692 done
 693
 694 # Build the LLVM_TARGET and LLVM_... macros for Targets.def and the individual
 695 # target feature def files.
 696 LLVM_ENUM_TARGETS=""
 697 LLVM_ENUM_ASM_PRINTERS=""
 698 LLVM_ENUM_ASM_PARSERS=""
 699 LLVM_ENUM_DISASSEMBLERS=""
 700 for target_to_build in $TARGETS_TO_BUILD; do
 701   LLVM_ENUM_TARGETS="LLVM_TARGET($target_to_build) $LLVM_ENUM_TARGETS"
 702   if test -f ${srcdir}/lib/Target/${target_to_build}/*AsmPrinter.cpp ; then
 703     LLVM_ENUM_ASM_PRINTERS="LLVM_ASM_PRINTER($target_to_build) $LLVM_ENUM_ASM_PRINTERS";
 704   fi
 705   if test -f ${srcdir}/lib/Target/${target_to_build}/AsmParser/Makefile ; then
 706     LLVM_ENUM_ASM_PARSERS="LLVM_ASM_PARSER($target_to_build) $LLVM_ENUM_ASM_PARSERS";
 707   fi
 708   if test -f ${srcdir}/lib/Target/${target_to_build}/Disassembler/Makefile ; then
 709     LLVM_ENUM_DISASSEMBLERS="LLVM_DISASSEMBLER($target_to_build) $LLVM_ENUM_DISASSEMBLERS";
 710   fi
 711 done
 712 AC_SUBST(LLVM_ENUM_TARGETS)
 713 AC_SUBST(LLVM_ENUM_ASM_PRINTERS)
 714 AC_SUBST(LLVM_ENUM_ASM_PARSERS)
 715 AC_SUBST(LLVM_ENUM_DISASSEMBLERS)
 716
 717 dnl Prevent the CBackend from using printf("%a") for floating point so older
 718 dnl C compilers that cannot deal with the 0x0p+0 hex floating point format
 719 dnl can still compile the CBE's output
 720 AC_ARG_ENABLE([cbe-printf-a],AS_HELP_STRING([--enable-cbe-printf-a],
 721   [Enable C Backend output with hex floating point via %a  (default is YES)]),,
 722   enableval=default)
 723 case "$enableval" in
 724   yes) AC_SUBST(ENABLE_CBE_PRINTF_A,[1]) ;;
 725   no)  AC_SUBST(ENABLE_CBE_PRINTF_A,[0]) ;;
 726   default)  AC_SUBST(ENABLE_CBE_PRINTF_A,[1]) ;;
 727   *) AC_MSG_ERROR([Invalid setting for --enable-cbe-printf-a. Use "yes" or "no"]) ;;
 728 esac
 729 AC_DEFINE_UNQUOTED([ENABLE_CBE_PRINTF_A],$ENABLE_CBE_PRINTF_A,
 730                    [Define if CBE is enabled for printf %a output])
 731
 732 dnl Override the option to use for optimized builds.
 733 AC_ARG_WITH(optimize-option,
 734   AS_HELP_STRING([--with-optimize-option],
 735                  [Select the compiler options to use for optimized builds]),,
 736                  withval=default)
 737 AC_MSG_CHECKING([optimization flags])
 738 case "$withval" in
 739   default)
 740     case "$llvm_cv_os_type" in
 741     FreeBSD) optimize_option=-O2 ;;
 742     MingW) optimize_option=-O2 ;;
 743     *)     optimize_option=-O3 ;;
 744     esac ;;
 745   *) optimize_option="$withval" ;;
 746 esac
 747 AC_SUBST(OPTIMIZE_OPTION,$optimize_option)
 748 AC_MSG_RESULT([$optimize_option])
 749
 750 dnl Specify extra build options
 751 AC_ARG_WITH(extra-options,
 752   AS_HELP_STRING([--with-extra-options],
 753                  [Specify additional options to compile LLVM with]),,
 754                  withval=default)
 755 case "$withval" in
 756   default) EXTRA_OPTIONS= ;;
 757   *) EXTRA_OPTIONS=$withval ;;
 758 esac
 759 AC_SUBST(EXTRA_OPTIONS,$EXTRA_OPTIONS)
 760
 761 dnl Specify extra linker build options
 762 AC_ARG_WITH(extra-ld-options,
 763   AS_HELP_STRING([--with-extra-ld-options],
 764                  [Specify additional options to link LLVM with]),,
 765                  withval=default)
 766 case "$withval" in
 767   default) EXTRA_LD_OPTIONS= ;;
 768   *) EXTRA_LD_OPTIONS=$withval ;;
 769 esac
 770 AC_SUBST(EXTRA_LD_OPTIONS,$EXTRA_LD_OPTIONS)
 771
 772 dnl Allow specific bindings to be specified for building (or not)
 773 AC_ARG_ENABLE([bindings],AS_HELP_STRING([--enable-bindings],
 774     [Build specific language bindings: all,auto,none,{binding-name} (default=auto)]),,
 775     enableval=default)
 776 BINDINGS_TO_BUILD=""
 777 case "$enableval" in
 778   yes | default | auto) BINDINGS_TO_BUILD="auto" ;;
 779   all ) BINDINGS_TO_BUILD="ocaml" ;;
 780   none | no) BINDINGS_TO_BUILD="" ;;
 781   *)for a_binding in `echo $enableval|sed -e 's/,/ /g' ` ; do
 782       case "$a_binding" in
 783         ocaml) BINDINGS_TO_BUILD="ocaml $BINDINGS_TO_BUILD" ;;
 784         *) AC_MSG_ERROR([Unrecognized binding $a_binding]) ;;
 785       esac
 786   done
 787   ;;
 788 esac
 789
 790 dnl Allow the ocaml libdir to be overridden. This could go in a configure
 791 dnl script for bindings/ocaml/configure, except that its auto value depends on
 792 dnl OCAMLC, which is found here to support tests.
 793 AC_ARG_WITH([ocaml-libdir],
 794   [AS_HELP_STRING([--with-ocaml-libdir],
 795     [Specify install location for ocaml bindings (default is stdlib)])],
 796   [],
 797   [withval=auto])
 798 case "$withval" in
 799   auto) with_ocaml_libdir="$withval" ;;
 800   /* | [[A-Za-z]]:[[\\/]]*) with_ocaml_libdir="$withval" ;;
 801   *) AC_MSG_ERROR([Invalid path for --with-ocaml-libdir. Provide full path]) ;;
 802 esac
 803
 804 AC_ARG_WITH(clang-srcdir,
 805   AS_HELP_STRING([--with-clang-srcdir],
 806     [Directory to the out-of-tree Clang source]),,
 807     withval="-")
 808 case "$withval" in
 809   -) clang_src_root="" ;;
 810   /* | [[A-Za-z]]:[[\\/]]*) clang_src_root="$withval" ;;
 811   *) clang_src_root="$ac_pwd/$withval" ;;
 812 esac
 813 AC_SUBST(CLANG_SRC_ROOT,[$clang_src_root])
 814
 815 AC_ARG_WITH(clang-resource-dir,
 816   AS_HELP_STRING([--with-clang-resource-dir],
 817     [Relative directory from the Clang binary for resource files]),,
 818     withval="")
 819 AC_DEFINE_UNQUOTED(CLANG_RESOURCE_DIR,"$withval",
 820                    [Relative directory for resource files])
 821
 822 AC_ARG_WITH(c-include-dirs,
 823   AS_HELP_STRING([--with-c-include-dirs],
 824     [Colon separated list of directories clang will search for headers]),,
 825     withval="")
 826 AC_DEFINE_UNQUOTED(C_INCLUDE_DIRS,"$withval",
 827                    [Directories clang will search for headers])
 828
 829 AC_ARG_WITH(cxx-include-root,
 830   AS_HELP_STRING([--with-cxx-include-root],
 831     [Directory with the libstdc++ headers.]),,
 832     withval="")
 833 AC_DEFINE_UNQUOTED(CXX_INCLUDE_ROOT,"$withval",
 834                    [Directory with the libstdc++ headers.])
 835
 836 AC_ARG_WITH(cxx-include-arch,
 837   AS_HELP_STRING([--with-cxx-include-arch],
 838     [Architecture of the libstdc++ headers.]),,
 839     withval="")
 840 AC_DEFINE_UNQUOTED(CXX_INCLUDE_ARCH,"$withval",
 841                    [Arch the libstdc++ headers.])
 842
 843 AC_ARG_WITH(cxx-include-32bit-dir,
 844   AS_HELP_STRING([--with-cxx-include-32bit-dir],
 845     [32 bit multilib dir.]),,
 846     withval="")
 847 AC_DEFINE_UNQUOTED(CXX_INCLUDE_32BIT_DIR,"$withval",
 848                    [32 bit multilib directory.])
 849
 850 AC_ARG_WITH(cxx-include-64bit-dir,
 851   AS_HELP_STRING([--with-cxx-include-64bit-dir],
 852     [64 bit multilib directory.]),,
 853     withval="")
 854 AC_DEFINE_UNQUOTED(CXX_INCLUDE_64BIT_DIR,"$withval",
 855                    [64 bit multilib directory.])
 856
 857 dnl Allow linking of LLVM with GPLv3 binutils code.
 858 AC_ARG_WITH(binutils-include,
 859   AS_HELP_STRING([--with-binutils-include],
 860     [Specify path to binutils/include/ containing plugin-api.h file for gold plugin.]),,
 861   withval=default)
 862 case "$withval" in
 863   default) WITH_BINUTILS_INCDIR=default ;;
 864   /* | [[A-Za-z]]:[[\\/]]*)      WITH_BINUTILS_INCDIR=$withval ;;
 865   *) AC_MSG_ERROR([Invalid path for --with-binutils-include. Provide full path]) ;;
 866 esac
 867 if test "x$WITH_BINUTILS_INCDIR" != xdefault ; then
 868   AC_SUBST(BINUTILS_INCDIR,$WITH_BINUTILS_INCDIR)
 869   if test ! -f "$WITH_BINUTILS_INCDIR/plugin-api.h"; then
 870      echo "$WITH_BINUTILS_INCDIR/plugin-api.h"
 871      AC_MSG_ERROR([Invalid path to directory containing plugin-api.h.]);
 872   fi
 873 fi
 874
 875 dnl Specify the URL where bug reports should be submitted.
 876 AC_ARG_WITH(bug-report-url,
 877   AS_HELP_STRING([--with-bug-report-url],
 878     [Specify the URL where bug reports should be submitted (default=http://llvm.org/bugs/)]),,
 879     withval="http://llvm.org/bugs/")
 880 AC_DEFINE_UNQUOTED(BUG_REPORT_URL,"$withval",
 881                    [Bug report URL.])
 882
 883 dnl --enable-libffi : check whether the user wants to turn off libffi:
 884 AC_ARG_ENABLE(libffi,AS_HELP_STRING(
 885   --enable-libffi,[Check for the presence of libffi (default is NO)]),
 886   [case "$enableval" in
 887     yes) llvm_cv_enable_libffi="yes" ;;
 888     no)  llvm_cv_enable_libffi="no"  ;;
 889     *) AC_MSG_ERROR([Invalid setting for --enable-libffi. Use "yes" or "no"]) ;;
 890   esac],
 891   llvm_cv_enable_libffi=no)
 892
 893 AC_ARG_WITH(internal-prefix,
 894   AS_HELP_STRING([--with-internal-prefix],
 895     [Installation directory for internal files]),,
 896     withval="")
 897 AC_SUBST(INTERNAL_PREFIX,[$withval])
 898
 899 dnl===-----------------------------------------------------------------------===
 900 dnl===
 901 dnl=== SECTION 4: Check for programs we need and that they are the right version
 902 dnl===
 903 dnl===-----------------------------------------------------------------------===
 904
 905 AC_PROG_NM
 906 AC_SUBST(NM)
 907
 908 dnl Check for the tools that the makefiles require
 909 AC_CHECK_GNU_MAKE
 910 AC_PROG_LN_S
 911 AC_PATH_PROG(CMP, [cmp], [cmp])
 912 AC_PATH_PROG(CP, [cp], [cp])
 913 AC_PATH_PROG(DATE, [date], [date])
 914 AC_PATH_PROG(FIND, [find], [find])
 915 AC_PATH_PROG(GREP, [grep], [grep])
 916 AC_PATH_PROG(MKDIR,[mkdir],[mkdir])
 917 AC_PATH_PROG(MV,   [mv],   [mv])
 918 AC_PROG_RANLIB
 919 AC_CHECK_TOOL(AR, ar, false)
 920 AC_PATH_PROG(RM,   [rm],   [rm])
 921 AC_PATH_PROG(SED,  [sed],  [sed])
 922 AC_PATH_PROG(TAR,  [tar],  [gtar])
 923 AC_PATH_PROG(BINPWD,[pwd],  [pwd])
 924
 925 dnl Looking for misc. graph plotting software
 926 AC_PATH_PROG(GRAPHVIZ, [Graphviz], [echo Graphviz])
 927 if test "$GRAPHVIZ" != "echo Graphviz" ; then
 928   AC_DEFINE([HAVE_GRAPHVIZ],[1],[Define if the Graphviz program is available])
 929   dnl If we're targeting for mingw we should emit windows paths, not msys
 930   if test "$llvm_cv_os_type" = "MingW" ; then
 931     GRAPHVIZ=`echo $GRAPHVIZ | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 932   fi
 933   AC_DEFINE_UNQUOTED([LLVM_PATH_GRAPHVIZ],"$GRAPHVIZ${EXEEXT}",
 934    [Define to path to Graphviz program if found or 'echo Graphviz' otherwise])
 935 fi
 936 AC_PATH_PROG(DOT, [dot], [echo dot])
 937 if test "$DOT" != "echo dot" ; then
 938   AC_DEFINE([HAVE_DOT],[1],[Define if the dot program is available])
 939   dnl If we're targeting for mingw we should emit windows paths, not msys
 940   if test "$llvm_cv_os_type" = "MingW" ; then
 941     DOT=`echo $DOT | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 942   fi
 943   AC_DEFINE_UNQUOTED([LLVM_PATH_DOT],"$DOT${EXEEXT}",
 944    [Define to path to dot program if found or 'echo dot' otherwise])
 945 fi
 946 AC_PATH_PROG(FDP, [fdp], [echo fdp])
 947 if test "$FDP" != "echo fdp" ; then
 948   AC_DEFINE([HAVE_FDP],[1],[Define if the neat program is available])
 949   dnl If we're targeting for mingw we should emit windows paths, not msys
 950   if test "$llvm_cv_os_type" = "MingW" ; then
 951     FDP=`echo $FDP | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 952   fi
 953   AC_DEFINE_UNQUOTED([LLVM_PATH_FDP],"$FDP${EXEEXT}",
 954    [Define to path to fdp program if found or 'echo fdp' otherwise])
 955 fi
 956 AC_PATH_PROG(NEATO, [neato], [echo neato])
 957 if test "$NEATO" != "echo neato" ; then
 958   AC_DEFINE([HAVE_NEATO],[1],[Define if the neat program is available])
 959   dnl If we're targeting for mingw we should emit windows paths, not msys
 960   if test "$llvm_cv_os_type" = "MingW" ; then
 961     NEATO=`echo $NEATO | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 962   fi
 963   AC_DEFINE_UNQUOTED([LLVM_PATH_NEATO],"$NEATO${EXEEXT}",
 964    [Define to path to neato program if found or 'echo neato' otherwise])
 965 fi
 966 AC_PATH_PROG(TWOPI, [twopi], [echo twopi])
 967 if test "$TWOPI" != "echo twopi" ; then
 968   AC_DEFINE([HAVE_TWOPI],[1],[Define if the neat program is available])
 969   dnl If we're targeting for mingw we should emit windows paths, not msys
 970   if test "$llvm_cv_os_type" = "MingW" ; then
 971     TWOPI=`echo $TWOPI | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 972   fi
 973   AC_DEFINE_UNQUOTED([LLVM_PATH_TWOPI],"$TWOPI${EXEEXT}",
 974    [Define to path to twopi program if found or 'echo twopi' otherwise])
 975 fi
 976 AC_PATH_PROG(CIRCO, [circo], [echo circo])
 977 if test "$CIRCO" != "echo circo" ; then
 978   AC_DEFINE([HAVE_CIRCO],[1],[Define if the neat program is available])
 979   dnl If we're targeting for mingw we should emit windows paths, not msys
 980   if test "$llvm_cv_os_type" = "MingW" ; then
 981     CIRCO=`echo $CIRCO | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 982   fi
 983   AC_DEFINE_UNQUOTED([LLVM_PATH_CIRCO],"$CIRCO${EXEEXT}",
 984    [Define to path to circo program if found or 'echo circo' otherwise])
 985 fi
 986 AC_PATH_PROGS(GV, [gv gsview32], [echo gv])
 987 if test "$GV" != "echo gv" ; then
 988   AC_DEFINE([HAVE_GV],[1],[Define if the gv program is available])
 989   dnl If we're targeting for mingw we should emit windows paths, not msys
 990   if test "$llvm_cv_os_type" = "MingW" ; then
 991     GV=`echo $GV | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 992   fi
 993   AC_DEFINE_UNQUOTED([LLVM_PATH_GV],"$GV${EXEEXT}",
 994    [Define to path to gv program if found or 'echo gv' otherwise])
 995 fi
 996 AC_PATH_PROG(DOTTY, [dotty], [echo dotty])
 997 if test "$DOTTY" != "echo dotty" ; then
 998   AC_DEFINE([HAVE_DOTTY],[1],[Define if the dotty program is available])
 999   dnl If we're targeting for mingw we should emit windows paths, not msys
1000   if test "$llvm_cv_os_type" = "MingW" ; then
1001     DOTTY=`echo $DOTTY | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
1002   fi
1003   AC_DEFINE_UNQUOTED([LLVM_PATH_DOTTY],"$DOTTY${EXEEXT}",
1004    [Define to path to dotty program if found or 'echo dotty' otherwise])
1005 fi
1006 AC_PATH_PROG(XDOT_PY, [xdot.py], [echo xdot.py])
1007 if test "$XDOT_PY" != "echo xdot.py" ; then
1008   AC_DEFINE([HAVE_XDOT_PY],[1],[Define if the xdot.py program is available])
1009   dnl If we're targeting for mingw we should emit windows paths, not msys
1010   if test "$llvm_cv_os_type" = "MingW" ; then
1011     XDOT_PY=`echo $XDOT_PY | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
1012   fi
1013   AC_DEFINE_UNQUOTED([LLVM_PATH_XDOT_PY],"$XDOT_PY${EXEEXT}",
1014    [Define to path to xdot.py program if found or 'echo xdot.py' otherwise])
1015 fi
1016
1017 dnl Look for a sufficiently recent version of Perl.
1018 LLVM_PROG_PERL([5.006])
1019 AC_SUBST(PERL)
1020 if test x"$PERL" = xnone; then
1021    AC_SUBST(HAVE_PERL,0)
1022    AC_MSG_ERROR([perl is required but was not found, please install it])
1023 else
1024    AC_SUBST(HAVE_PERL,1)
1025 fi
1026
1027 dnl Find the install program
1028 AC_PROG_INSTALL
1029 dnl Prepend src dir to install path dir if it's a relative path
1030 dnl This is a hack for installs that take place in something other
1031 dnl than the top level.
1032 case "$INSTALL" in
1033  [[\\/$]]* | ?:[[\\/]]* ) ;;
1034  *)  INSTALL="\\\$(TOPSRCDIR)/$INSTALL" ;;
1035 esac
1036
1037 dnl Checks for documentation and testing tools that we can do without. If these
1038 dnl are not found then they are set to "true" which always succeeds but does
1039 dnl nothing. This just lets the build output show that we could have done
1040 dnl something if the tool was available.
1041 AC_PATH_PROG(BZIP2, [bzip2])
1042 AC_PATH_PROG(CAT, [cat])
1043 AC_PATH_PROG(DOXYGEN, [doxygen])
1044 AC_PATH_PROG(GROFF, [groff])
1045 AC_PATH_PROG(GZIPBIN, [gzip])
1046 AC_PATH_PROG(POD2HTML, [pod2html])
1047 AC_PATH_PROG(POD2MAN, [pod2man])
1048 AC_PATH_PROG(PDFROFF, [pdfroff])
1049 AC_PATH_PROG(RUNTEST, [runtest])
1050 DJ_AC_PATH_TCLSH
1051 AC_PATH_PROG(ZIP, [zip])
1052 AC_PATH_PROGS(OCAMLC, [ocamlc])
1053 AC_PATH_PROGS(OCAMLOPT, [ocamlopt])
1054 AC_PATH_PROGS(OCAMLDEP, [ocamldep])
1055 AC_PATH_PROGS(OCAMLDOC, [ocamldoc])
1056 AC_PATH_PROGS(GAS, [gas as])
1057
1058 dnl Get the version of the linker in use.
1059 AC_LINK_GET_VERSION
1060
1061 dnl Determine whether the linker supports the -R option.
1062 AC_LINK_USE_R
1063
1064 dnl Determine whether the linker supports the -export-dynamic option.
1065 AC_LINK_EXPORT_DYNAMIC
1066
1067 dnl Determine whether the linker supports the --version-script option.
1068 AC_LINK_VERSION_SCRIPT
1069
1070 dnl Check for libtool and the library that has dlopen function (which must come
1071 dnl before the AC_PROG_LIBTOOL check in order to enable dlopening libraries with
1072 dnl libtool).
1073 AC_LIBTOOL_DLOPEN
1074 AC_LIB_LTDL
1075
1076 AC_MSG_CHECKING([tool compatibility])
1077
1078 dnl Ensure that compilation tools are GCC or a GNU compatible compiler such as
1079 dnl ICC; we use GCC specific options in the makefiles so the compiler needs
1080 dnl to support those options.
1081 dnl "icc" emits gcc signatures
1082 dnl "icc -no-gcc" emits no gcc signature BUT is still compatible
1083 ICC=no
1084 IXX=no
1085 case $CC in
1086   icc*|icpc*)
1087     ICC=yes
1088     IXX=yes
1089     ;;
1090    *)
1091     ;;
1092 esac
1093
1094 if test "$GCC" != "yes" && test "$ICC" != "yes"
1095 then
1096   AC_MSG_ERROR([gcc|icc required but not found])
1097 fi
1098
1099 dnl Ensure that compilation tools are compatible with GCC extensions
1100 if test "$GXX" != "yes" && test "$IXX" != "yes"
1101 then
1102   AC_MSG_ERROR([g++|clang++|icc required but not found])
1103 fi
1104
1105 dnl Verify that GCC is version 3.0 or higher
1106 if test "$GCC" = "yes"
1107 then
1108   AC_COMPILE_IFELSE([[#if !defined(__GNUC__) || __GNUC__ < 3
1109 #error Unsupported GCC version
1110 #endif
1111 ]], [], [AC_MSG_ERROR([gcc 3.x required, but you have a lower version])])
1112 fi
1113
1114 dnl Check for GNU Make.  We use its extensions, so don't build without it
1115 if test -z "$llvm_cv_gnu_make_command"
1116 then
1117   AC_MSG_ERROR([GNU Make required but not found])
1118 fi
1119
1120 dnl Tool compatibility is okay if we make it here.
1121 AC_MSG_RESULT([ok])
1122
1123 dnl Check optional compiler flags.
1124 AC_MSG_CHECKING([optional compiler flags])
1125 CXX_FLAG_CHECK(NO_VARIADIC_MACROS, [-Wno-variadic-macros])
1126 CXX_FLAG_CHECK(NO_MISSING_FIELD_INITIALIZERS, [-Wno-missing-field-initializers])
1127 AC_MSG_RESULT([$NO_VARIADIC_MACROS $NO_MISSING_FIELD_INITIALIZERS])
1128
1129 dnl===-----------------------------------------------------------------------===
1130 dnl===
1131 dnl=== SECTION 5: Check for libraries
1132 dnl===
1133 dnl===-----------------------------------------------------------------------===
1134
1135 AC_CHECK_LIB(m,sin)
1136 if test "$llvm_cv_os_type" = "MingW" ; then
1137   AC_CHECK_LIB(imagehlp, main)
1138   AC_CHECK_LIB(psapi, main)
1139 fi
1140
1141 dnl dlopen() is required for plugin support.
1142 AC_SEARCH_LIBS(dlopen,dl,AC_DEFINE([HAVE_DLOPEN],[1],
1143                [Define if dlopen() is available on this platform.]),
1144                AC_MSG_WARN([dlopen() not found - disabling plugin support]))
1145
1146 dnl libffi is optional; used to call external functions from the interpreter
1147 if test "$llvm_cv_enable_libffi" = "yes" ; then
1148   AC_SEARCH_LIBS(ffi_call,ffi,AC_DEFINE([HAVE_FFI_CALL],[1],
1149                  [Define if libffi is available on this platform.]),
1150                  AC_MSG_ERROR([libffi not found - configure without --enable-libffi to compile without it]))
1151 fi
1152
1153 dnl mallinfo is optional; the code can compile (minus features) without it
1154 AC_SEARCH_LIBS(mallinfo,malloc,AC_DEFINE([HAVE_MALLINFO],[1],
1155                [Define if mallinfo() is available on this platform.]))
1156
1157 dnl pthread locking functions are optional - but llvm will not be thread-safe
1158 dnl without locks.
1159 if test "$LLVM_ENABLE_THREADS" -eq 1 && test "$ENABLE_PTHREADS" -eq 1 ; then
1160   AC_CHECK_LIB(pthread, pthread_mutex_init)
1161   AC_SEARCH_LIBS(pthread_mutex_lock,pthread,
1162                  AC_DEFINE([HAVE_PTHREAD_MUTEX_LOCK],[1],
1163                            [Have pthread_mutex_lock]))
1164   AC_SEARCH_LIBS(pthread_rwlock_init,pthread,
1165                  AC_DEFINE([HAVE_PTHREAD_RWLOCK_INIT],[1],
1166                  [Have pthread_rwlock_init]))
1167   AC_SEARCH_LIBS(pthread_getspecific,pthread,
1168                  AC_DEFINE([HAVE_PTHREAD_GETSPECIFIC],[1],
1169                  [Have pthread_getspecific]))
1170 fi
1171
1172 dnl Allow extra x86-disassembler library
1173 AC_ARG_WITH(udis86,
1174   AS_HELP_STRING([--with-udis86=<path>],
1175     [Use udis86 external x86 disassembler library]),
1176     [
1177       AC_SUBST(USE_UDIS86, [1])
1178       case "$withval" in
1179         /usr/lib|yes) ;;
1180         *) LDFLAGS="$LDFLAGS -L${withval}" ;;
1181       esac
1182       AC_CHECK_LIB(udis86, ud_init, [], [
1183         echo "Error! You need to have libudis86 around."
1184         exit -1
1185       ])
1186     ],
1187     AC_SUBST(USE_UDIS86, [0]))
1188 AC_DEFINE_UNQUOTED([USE_UDIS86],$USE_UDIS86,
1189                    [Define if use udis86 library])
1190
1191 dnl Allow OProfile support for JIT output.
1192 AC_ARG_WITH(oprofile,
1193   AS_HELP_STRING([--with-oprofile=<prefix>],
1194     [Tell OProfile >= 0.9.4 how to symbolize JIT output]),
1195     [
1196       AC_SUBST(USE_OPROFILE, [1])
1197       case "$withval" in
1198         /usr|yes) llvm_cv_oppath=/usr/lib/oprofile ;;
1199         no) llvm_cv_oppath=
1200             AC_SUBST(USE_OPROFILE, [0]) ;;
1201         *) llvm_cv_oppath="${withval}/lib/oprofile"
1202            CPPFLAGS="-I${withval}/include";;
1203       esac
1204       if test -n "$llvm_cv_oppath" ; then
1205         LIBS="$LIBS -L${llvm_cv_oppath} -Wl,-rpath,${llvm_cv_oppath}"
1206         dnl Work around http://bugs.debian.org/cgi-bin/bugreport.cgi?bug=537744:
1207         dnl libbfd is not included properly in libopagent in some Debian
1208         dnl versions.  If libbfd isn't found at all, we assume opagent works
1209         dnl anyway.
1210         AC_SEARCH_LIBS(bfd_init, bfd, [], [])
1211         AC_SEARCH_LIBS(op_open_agent, opagent, [], [
1212           echo "Error! You need to have libopagent around."
1213           exit -1
1214         ])
1215         AC_CHECK_HEADER([opagent.h], [], [
1216           echo "Error! You need to have opagent.h around."
1217           exit -1
1218           ])
1219       fi
1220     ],
1221     [
1222       AC_SUBST(USE_OPROFILE, [0])
1223     ])
1224 AC_DEFINE_UNQUOTED([USE_OPROFILE],$USE_OPROFILE,
1225                    [Define if we have the oprofile JIT-support library])
1226
1227 dnl===-----------------------------------------------------------------------===
1228 dnl===
1229 dnl=== SECTION 6: Check for header files
1230 dnl===
1231 dnl===-----------------------------------------------------------------------===
1232
1233 dnl First, use autoconf provided macros for specific headers that we need
1234 dnl We don't check for ancient stuff or things that are guaranteed to be there
1235 dnl by the C++ standard. We always use the <cfoo> versions of <foo.h> C headers.
1236 dnl Generally we're looking for POSIX headers.
1237 AC_HEADER_DIRENT
1238 AC_HEADER_MMAP_ANONYMOUS
1239 AC_HEADER_STAT
1240 AC_HEADER_SYS_WAIT
1241 AC_HEADER_TIME
1242
1243 AC_CHECK_HEADERS([dlfcn.h execinfo.h fcntl.h inttypes.h limits.h link.h])
1244 AC_CHECK_HEADERS([malloc.h setjmp.h signal.h stdint.h termios.h unistd.h])
1245 AC_CHECK_HEADERS([utime.h windows.h])
1246 AC_CHECK_HEADERS([sys/mman.h sys/param.h sys/resource.h sys/time.h sys/uio.h])
1247 AC_CHECK_HEADERS([sys/types.h sys/ioctl.h malloc/malloc.h mach/mach.h])
1248 AC_CHECK_HEADERS([valgrind/valgrind.h])
1249 AC_CHECK_HEADERS([fenv.h])
1250 if test "$LLVM_ENABLE_THREADS" -eq 1 && test "$ENABLE_PTHREADS" -eq 1 ; then
1251   AC_CHECK_HEADERS(pthread.h,
1252                    AC_SUBST(HAVE_PTHREAD, 1),
1253                    AC_SUBST(HAVE_PTHREAD, 0))
1254 else
1255   AC_SUBST(HAVE_PTHREAD, 0)
1256 fi
1257
1258 dnl Try to find ffi.h.
1259 if test "$llvm_cv_enable_libffi" = "yes" ; then
1260   AC_CHECK_HEADERS([ffi.h ffi/ffi.h])
1261 fi
1262
1263 dnl Try to find Darwin specific crash reporting libraries.
1264 AC_CHECK_HEADERS([CrashReporterClient.h])
1265
1266 dnl Try to find Darwin specific crash reporting global.
1267 AC_MSG_CHECKING([__crashreporter_info__])
1268 AC_LINK_IFELSE(
1269   AC_LANG_SOURCE(
1270     [[extern const char *__crashreporter_info__;
1271       int main() {
1272         __crashreporter_info__ = "test";
1273         return 0;
1274       }
1275     ]]),
1276   AC_MSG_RESULT(yes)
1277   AC_DEFINE(HAVE_CRASHREPORTER_INFO, 1, Can use __crashreporter_info__),
1278   AC_MSG_RESULT(no)
1279   AC_DEFINE(HAVE_CRASHREPORTER_INFO, 0,
1280             Define if __crashreporter_info__ exists.))
1281
1282 dnl===-----------------------------------------------------------------------===
1283 dnl===
1284 dnl=== SECTION 7: Check for types and structures
1285 dnl===
1286 dnl===-----------------------------------------------------------------------===
1287
1288 AC_HUGE_VAL_CHECK
1289 AC_TYPE_PID_T
1290 AC_TYPE_SIZE_T
1291 AC_DEFINE_UNQUOTED([RETSIGTYPE],[void],[Define as the return type of signal handlers (`int' or `void').])
1292 AC_STRUCT_TM
1293 AC_CHECK_TYPES([int64_t],,AC_MSG_ERROR([Type int64_t required but not found]))
1294 AC_CHECK_TYPES([uint64_t],,
1295          AC_CHECK_TYPES([u_int64_t],,
1296          AC_MSG_ERROR([Type uint64_t or u_int64_t required but not found])))
1297
1298 dnl===-----------------------------------------------------------------------===
1299 dnl===
1300 dnl=== SECTION 8: Check for specific functions needed
1301 dnl===
1302 dnl===-----------------------------------------------------------------------===
1303
1304 AC_CHECK_FUNCS([backtrace ceilf floorf roundf rintf nearbyintf getcwd ])
1305 AC_CHECK_FUNCS([powf fmodf strtof round ])
1306 AC_CHECK_FUNCS([getpagesize getrusage getrlimit setrlimit gettimeofday ])
1307 AC_CHECK_FUNCS([isatty mkdtemp mkstemp ])
1308 AC_CHECK_FUNCS([mktemp posix_spawn pread realpath sbrk setrlimit strdup ])
1309 AC_CHECK_FUNCS([strerror strerror_r setenv ])
1310 AC_CHECK_FUNCS([strtoll strtoq sysconf malloc_zone_statistics ])
1311 AC_CHECK_FUNCS([setjmp longjmp sigsetjmp siglongjmp writev])
1312 AC_C_PRINTF_A
1313 AC_FUNC_RAND48
1314
1315 dnl Check the declaration "Secure API" on Windows environments.
1316 AC_CHECK_DECLS([strerror_s])
1317
1318 dnl Check symbols in libgcc.a for JIT on Mingw.
1319 if test "$llvm_cv_os_type" = "MingW" ; then
1320   AC_CHECK_LIB(gcc,_alloca,AC_DEFINE([HAVE__ALLOCA],[1],[Have host's _alloca]))
1321   AC_CHECK_LIB(gcc,__alloca,AC_DEFINE([HAVE___ALLOCA],[1],[Have host's __alloca]))
1322   AC_CHECK_LIB(gcc,__chkstk,AC_DEFINE([HAVE___CHKSTK],[1],[Have host's __chkstk]))
1323   AC_CHECK_LIB(gcc,___chkstk,AC_DEFINE([HAVE____CHKSTK],[1],[Have host's ___chkstk]))
1324
1325   AC_CHECK_LIB(gcc,__ashldi3,AC_DEFINE([HAVE___ASHLDI3],[1],[Have host's __ashldi3]))
1326   AC_CHECK_LIB(gcc,__ashrdi3,AC_DEFINE([HAVE___ASHRDI3],[1],[Have host's __ashrdi3]))
1327   AC_CHECK_LIB(gcc,__divdi3,AC_DEFINE([HAVE___DIVDI3],[1],[Have host's __divdi3]))
1328   AC_CHECK_LIB(gcc,__fixdfdi,AC_DEFINE([HAVE___FIXDFDI],[1],[Have host's __fixdfdi]))
1329   AC_CHECK_LIB(gcc,__fixsfdi,AC_DEFINE([HAVE___FIXSFDI],[1],[Have host's __fixsfdi]))
1330   AC_CHECK_LIB(gcc,__floatdidf,AC_DEFINE([HAVE___FLOATDIDF],[1],[Have host's __floatdidf]))
1331   AC_CHECK_LIB(gcc,__lshrdi3,AC_DEFINE([HAVE___LSHRDI3],[1],[Have host's __lshrdi3]))
1332   AC_CHECK_LIB(gcc,__moddi3,AC_DEFINE([HAVE___MODDI3],[1],[Have host's __moddi3]))
1333   AC_CHECK_LIB(gcc,__udivdi3,AC_DEFINE([HAVE___UDIVDI3],[1],[Have host's __udivdi3]))
1334   AC_CHECK_LIB(gcc,__umoddi3,AC_DEFINE([HAVE___UMODDI3],[1],[Have host's __umoddi3]))
1335
1336   AC_CHECK_LIB(gcc,__main,AC_DEFINE([HAVE___MAIN],[1],[Have host's __main]))
1337   AC_CHECK_LIB(gcc,__cmpdi2,AC_DEFINE([HAVE___CMPDI2],[1],[Have host's __cmpdi2]))
1338 fi
1339
1340 dnl Check Win32 API EnumerateLoadedModules.
1341 if test "$llvm_cv_os_type" = "MingW" ; then
1342   AC_MSG_CHECKING([whether EnumerateLoadedModules() accepts new decl])
1343   AC_COMPILE_IFELSE([[#include <windows.h>
1344 #include <imagehlp.h>
1345 extern void foo(PENUMLOADED_MODULES_CALLBACK);
1346 extern void foo(BOOL(CALLBACK*)(PCSTR,ULONG_PTR,ULONG,PVOID));]],
1347 [
1348   AC_MSG_RESULT([yes])
1349   llvm_cv_win32_elmcb_pcstr="PCSTR"
1350 ],
1351 [
1352   AC_MSG_RESULT([no])
1353   llvm_cv_win32_elmcb_pcstr="PSTR"
1354 ])
1355   AC_DEFINE_UNQUOTED([WIN32_ELMCB_PCSTR],$llvm_cv_win32_elmcb_pcstr,[Type of 1st arg on ELM Callback])
1356 fi
1357
1358 dnl Check for variations in the Standard C++ library and STL. These macros are
1359 dnl provided by LLVM in the autoconf/m4 directory.
1360 AC_FUNC_ISNAN
1361 AC_FUNC_ISINF
1362
1363 dnl Check for mmap support.We also need to know if /dev/zero is required to
1364 dnl be opened for allocating RWX memory.
1365 dnl Make sure we aren't attempting to configure for an unknown system
1366 if test "$llvm_cv_platform_type" = "Unix" ; then
1367   AC_FUNC_MMAP
1368   AC_FUNC_MMAP_FILE
1369   AC_NEED_DEV_ZERO_FOR_MMAP
1370
1371   if test "$ac_cv_func_mmap_fixed_mapped" = "no"
1372   then
1373     AC_MSG_WARN([mmap() of a fixed address required but not supported])
1374   fi
1375   if test "$ac_cv_func_mmap_file" = "no"
1376   then
1377     AC_MSG_WARN([mmap() of files required but not found])
1378   fi
1379 fi
1380
1381 dnl atomic builtins are required for threading support.
1382 AC_MSG_CHECKING(for GCC atomic builtins)
1383 dnl Since we'll be using these atomic builtins in C++ files we should test
1384 dnl the C++ compiler.
1385 AC_LANG_PUSH([C++])
1386 AC_LINK_IFELSE(
1387   AC_LANG_SOURCE(
1388     [[int main() {
1389         volatile unsigned long val = 1;
1390         __sync_synchronize();
1391         __sync_val_compare_and_swap(&val, 1, 0);
1392         __sync_add_and_fetch(&val, 1);
1393         __sync_sub_and_fetch(&val, 1);
1394         return 0;
1395       }
1396     ]]),
1397   AC_LANG_POP([C++])
1398   AC_MSG_RESULT(yes)
1399   AC_DEFINE(LLVM_HAS_ATOMICS, 1, Has gcc/MSVC atomic intrinsics),
1400   AC_MSG_RESULT(no)
1401   AC_DEFINE(LLVM_HAS_ATOMICS, 0, Has gcc/MSVC atomic intrinsics)
1402   AC_MSG_WARN([LLVM will be built thread-unsafe because atomic builtins are missing]))
1403
1404 dnl===-----------------------------------------------------------------------===
1405 dnl===
1406 dnl=== SECTION 9: Additional checks, variables, etc.
1407 dnl===
1408 dnl===-----------------------------------------------------------------------===
1409
1410 dnl Handle 32-bit linux systems running a 64-bit kernel.
1411 dnl This has to come after section 4 because it invokes the compiler.
1412 if test "$llvm_cv_os_type" = "Linux" -a "$llvm_cv_target_arch" = "x86_64" ; then
1413   AC_IS_LINUX_MIXED
1414   if test "$llvm_cv_linux_mixed" = "yes"; then
1415     llvm_cv_target_arch="x86"
1416     ARCH="x86"
1417   fi
1418 fi
1419
1420 dnl Check whether __dso_handle is present
1421 AC_CHECK_FUNCS([__dso_handle])
1422
1423 dnl Propagate the shared library extension that the libltdl checks did to
1424 dnl the Makefiles so we can use it there too
1425 AC_SUBST(SHLIBEXT,$libltdl_cv_shlibext)
1426
1427 dnl Propagate the run-time library path variable that the libltdl
1428 dnl checks found to the Makefiles so we can use it there too
1429 AC_SUBST(SHLIBPATH_VAR,$libltdl_cv_shlibpath_var)
1430
1431 # Translate the various configuration directories and other basic
1432 # information into substitutions that will end up in Makefile.config.in
1433 # that these configured values can be used by the makefiles
1434 if test "${prefix}" = "NONE" ; then
1435   prefix="/usr/local"
1436 fi
1437 eval LLVM_PREFIX="${prefix}";
1438 eval LLVM_BINDIR="${prefix}/bin";
1439 eval LLVM_LIBDIR="${prefix}/lib";
1440 eval LLVM_DATADIR="${prefix}/share/llvm";
1441 eval LLVM_DOCSDIR="${prefix}/share/doc/llvm";
1442 eval LLVM_ETCDIR="${prefix}/etc/llvm";
1443 eval LLVM_INCLUDEDIR="${prefix}/include";
1444 eval LLVM_INFODIR="${prefix}/info";
1445 eval LLVM_MANDIR="${prefix}/man";
1446 LLVM_CONFIGTIME=`date`
1447 AC_SUBST(LLVM_PREFIX)
1448 AC_SUBST(LLVM_BINDIR)
1449 AC_SUBST(LLVM_LIBDIR)
1450 AC_SUBST(LLVM_DATADIR)
1451 AC_SUBST(LLVM_DOCSDIR)
1452 AC_SUBST(LLVM_ETCDIR)
1453 AC_SUBST(LLVM_INCLUDEDIR)
1454 AC_SUBST(LLVM_INFODIR)
1455 AC_SUBST(LLVM_MANDIR)
1456 AC_SUBST(LLVM_CONFIGTIME)
1457
1458 # Place the various directores into the config.h file as #defines so that we
1459 # can know about the installation paths within LLVM.
1460 AC_DEFINE_UNQUOTED(LLVM_PREFIX,"$LLVM_PREFIX",
1461                    [Installation prefix directory])
1462 AC_DEFINE_UNQUOTED(LLVM_BINDIR, "$LLVM_BINDIR",
1463                    [Installation directory for binary executables])
1464 AC_DEFINE_UNQUOTED(LLVM_LIBDIR, "$LLVM_LIBDIR",
1465                    [Installation directory for libraries])
1466 AC_DEFINE_UNQUOTED(LLVM_DATADIR, "$LLVM_DATADIR",
1467                    [Installation directory for data files])
1468 AC_DEFINE_UNQUOTED(LLVM_DOCSDIR, "$LLVM_DOCSDIR",
1469                    [Installation directory for documentation])
1470 AC_DEFINE_UNQUOTED(LLVM_ETCDIR, "$LLVM_ETCDIR",
1471                    [Installation directory for config files])
1472 AC_DEFINE_UNQUOTED(LLVM_INCLUDEDIR, "$LLVM_INCLUDEDIR",
1473                    [Installation directory for include files])
1474 AC_DEFINE_UNQUOTED(LLVM_INFODIR, "$LLVM_INFODIR",
1475                    [Installation directory for .info files])
1476 AC_DEFINE_UNQUOTED(LLVM_MANDIR, "$LLVM_MANDIR",
1477                    [Installation directory for man pages])
1478 AC_DEFINE_UNQUOTED(LLVM_CONFIGTIME, "$LLVM_CONFIGTIME",
1479                    [Time at which LLVM was configured])
1480 AC_DEFINE_UNQUOTED(LLVM_DEFAULT_TARGET_TRIPLE, "$target",
1481                    [Target triple LLVM will generate code for by default])
1482
1483 # Determine which bindings to build.
1484 if test "$BINDINGS_TO_BUILD" = auto ; then
1485   BINDINGS_TO_BUILD=""
1486   if test "x$OCAMLC" != x -a "x$OCAMLDEP" != x ; then
1487     BINDINGS_TO_BUILD="ocaml $BINDINGS_TO_BUILD"
1488   fi
1489 fi
1490 AC_SUBST(BINDINGS_TO_BUILD,$BINDINGS_TO_BUILD)
1491
1492 # This isn't really configurey, but it avoids having to repeat the list in
1493 # other files.
1494 AC_SUBST(ALL_BINDINGS,ocaml)
1495
1496 # Do any work necessary to ensure that bindings have what they need.
1497 binding_prereqs_failed=0
1498 for a_binding in $BINDINGS_TO_BUILD ; do
1499   case "$a_binding" in
1500   ocaml)
1501     if test "x$OCAMLC" = x ; then
1502       AC_MSG_WARN([--enable-bindings=ocaml specified, but ocamlc not found. Try configure OCAMLC=/path/to/ocamlc])
1503       binding_prereqs_failed=1
1504     fi
1505     if test "x$OCAMLDEP" = x ; then
1506       AC_MSG_WARN([--enable-bindings=ocaml specified, but ocamldep not found. Try configure OCAMLDEP=/path/to/ocamldep])
1507       binding_prereqs_failed=1
1508     fi
1509     if test "x$OCAMLOPT" = x ; then
1510       AC_MSG_WARN([--enable-bindings=ocaml specified, but ocamlopt not found. Try configure OCAMLOPT=/path/to/ocamlopt])
1511       dnl ocamlopt is optional!
1512     fi
1513     if test "x$with_ocaml_libdir" != xauto ; then
1514       AC_SUBST(OCAML_LIBDIR,$with_ocaml_libdir)
1515     else
1516       ocaml_stdlib="`"$OCAMLC" -where`"
1517       if test "$LLVM_PREFIX" '<' "$ocaml_stdlib" -a "$ocaml_stdlib" '<' "$LLVM_PREFIX~"
1518       then
1519         # ocaml stdlib is beneath our prefix; use stdlib
1520         AC_SUBST(OCAML_LIBDIR,$ocaml_stdlib)
1521       else
1522         # ocaml stdlib is outside our prefix; use libdir/ocaml
1523         AC_SUBST(OCAML_LIBDIR,$LLVM_LIBDIR/ocaml)
1524       fi
1525     fi
1526     ;;
1527   esac
1528 done
1529 if test "$binding_prereqs_failed" = 1 ; then
1530   AC_MSG_ERROR([Prequisites for bindings not satisfied. Fix them or use configure --disable-bindings.])
1531 fi
1532
1533 dnl Determine whether the compiler supports -fvisibility-inlines-hidden.
1534 AC_CXX_USE_VISIBILITY_INLINES_HIDDEN
1535
1536 dnl Determine linker rpath flag
1537 if test "$llvm_cv_link_use_r" = "yes" ; then
1538   RPATH="-Wl,-R"
1539 else
1540   RPATH="-Wl,-rpath"
1541 fi
1542 AC_SUBST(RPATH)
1543
1544 dnl Determine linker rdynamic flag
1545 if test "$llvm_cv_link_use_export_dynamic" = "yes" ; then
1546   RDYNAMIC="-Wl,-export-dynamic"
1547 else
1548   RDYNAMIC=""
1549 fi
1550 AC_SUBST(RDYNAMIC)
1551
1552 dnl===-----------------------------------------------------------------------===
1553 dnl===
1554 dnl=== SECTION 10: Specify the output files and generate it
1555 dnl===
1556 dnl===-----------------------------------------------------------------------===
1557
1558 dnl Configure header files
1559 dnl WARNING: dnl If you add or remove any of the following config headers, then
1560 dnl you MUST also update Makefile.rules so that the variable FilesToConfig
1561 dnl contains the same list of files as AC_CONFIG_HEADERS below. This ensures the
1562 dnl files can be updated automatically when their *.in sources change.
1563 AC_CONFIG_HEADERS([include/llvm/Config/config.h include/llvm/Config/llvm-config.h])
1564 AH_TOP([#ifndef CONFIG_H
1565 #define CONFIG_H])
1566 AH_BOTTOM([#endif])
1567
1568 AC_CONFIG_FILES([include/llvm/Config/Targets.def])
1569 AC_CONFIG_FILES([include/llvm/Config/AsmPrinters.def])
1570 AC_CONFIG_FILES([include/llvm/Config/AsmParsers.def])
1571 AC_CONFIG_FILES([include/llvm/Config/Disassemblers.def])
1572 AC_CONFIG_HEADERS([include/llvm/Support/DataTypes.h])
1573
1574 dnl Configure the makefile's configuration data
1575 AC_CONFIG_FILES([Makefile.config])
1576
1577 dnl Configure the RPM spec file for LLVM
1578 AC_CONFIG_FILES([llvm.spec])
1579
1580 dnl Configure doxygen's configuration file
1581 AC_CONFIG_FILES([docs/doxygen.cfg])
1582 if test -f ${srcdir}/tools/clang/README.txt; then
1583   AC_CONFIG_FILES([tools/clang/docs/doxygen.cfg])
1584 fi
1585
1586 dnl OCaml findlib META file
1587 AC_CONFIG_FILES([bindings/ocaml/llvm/META.llvm])
1588
1589 dnl Do special configuration of Makefiles
1590 AC_CONFIG_COMMANDS([setup],,[llvm_src="${srcdir}"])
1591 AC_CONFIG_MAKEFILE(Makefile)
1592 AC_CONFIG_MAKEFILE(Makefile.common)
1593 AC_CONFIG_MAKEFILE(examples/Makefile)
1594 AC_CONFIG_MAKEFILE(lib/Makefile)
1595 AC_CONFIG_MAKEFILE(runtime/Makefile)
1596 AC_CONFIG_MAKEFILE(test/Makefile)
1597 AC_CONFIG_MAKEFILE(test/Makefile.tests)
1598 AC_CONFIG_MAKEFILE(unittests/Makefile)
1599 AC_CONFIG_MAKEFILE(tools/Makefile)
1600 AC_CONFIG_MAKEFILE(utils/Makefile)
1601 AC_CONFIG_MAKEFILE(projects/Makefile)
1602 AC_CONFIG_MAKEFILE(bindings/Makefile)
1603 AC_CONFIG_MAKEFILE(bindings/ocaml/Makefile.ocaml)
1604
1605 dnl Finally, crank out the output
1606 AC_OUTPUT