autoconf/configure.ac

   1 dnl === configure.ac --------------------------------------------------------===
   2 dnl                     The LLVM Compiler Infrastructure
   3 dnl
   4 dnl This file was developed by the LLVM research group and is distributed under
   5 dnl the University of Illinois Open Source License. See LICENSE.TXT for details.
   6 dnl
   7 dnl===-----------------------------------------------------------------------===
   8 dnl This is the LLVM configuration script. It is processed by the autoconf
   9 dnl program to produce a script named configure. This script contains the
  10 dnl configuration checks that LLVM needs in order to support multiple platforms.
  11 dnl This file is composed of 10 sections per the recommended organization of
  12 dnl autoconf input defined in the autoconf documentation. As this file evolves,
  13 dnl please keep the various types of checks within their sections. The sections
  14 dnl are as follows:
  15 dnl
  16 dnl SECTION 1: Initialization & Setup
  17 dnl SECTION 2: Architecture, target, and host checks
  18 dnl SECTION 3: Command line arguments for the configure script.
  19 dnl SECTION 4: Check for programs we need and that they are the right version
  20 dnl SECTION 5: Check for libraries
  21 dnl SECTION 6: Check for header files
  22 dnl SECTION 7: Check for types and structures
  23 dnl SECTION 8: Check for specific functions needed
  24 dnl SECTION 9: Additional checks, variables, etc.
  25 dnl SECTION 10: Specify the output files and generate it
  26 dnl
  27 dnl===-----------------------------------------------------------------------===
  28 dnl===
  29 dnl=== SECTION 1: Initialization & Setup
  30 dnl===
  31 dnl===-----------------------------------------------------------------------===
  32 dnl Initialize autoconf and define the package name, version number and
  33 dnl email address for reporting bugs.
  34 AC_INIT([[llvm]],[[2.0cvs]],[llvmbugs@cs.uiuc.edu])
  35
  36 dnl Provide a copyright substitution and ensure the copyright notice is included
  37 dnl in the output of --version option of the generated configure script.
  38 AC_SUBST(LLVM_COPYRIGHT,["Copyright (c) 2003-2007 University of Illinois at Urbana-Champaign."])
  39 AC_COPYRIGHT([Copyright (c) 2003-2007 University of Illinois at Urbana-Champaign.])
  40
  41 dnl Indicate that we require autoconf 2.59 or later. Ths is needed because we
  42 dnl use some autoconf macros only available in 2.59.
  43 AC_PREREQ(2.59)
  44
  45 dnl Verify that the source directory is valid. This makes sure that we are
  46 dnl configuring LLVM and not some other package (it validates --srcdir argument)
  47 AC_CONFIG_SRCDIR([lib/VMCore/Module.cpp])
  48
  49 dnl Place all of the extra autoconf files into the config subdirectory. Tell
  50 dnl various tools where the m4 autoconf macros are.
  51 AC_CONFIG_AUX_DIR([autoconf])
  52
  53 dnl Quit if the source directory has already been configured.
  54 dnl NOTE: This relies upon undocumented autoconf behavior.
  55 if test ${srcdir} != "." ; then
  56   if test -f ${srcdir}/include/llvm/Config/config.h ; then
  57     AC_MSG_ERROR([Already configured in ${srcdir}])
  58   fi
  59 fi
  60
  61 dnl Configure all of the projects present in our source tree. While we could
  62 dnl just AC_CONFIG_SUBDIRS on the set of directories in projects that have a
  63 dnl configure script, that usage of the AC_CONFIG_SUBDIRS macro is deprecated.
  64 dnl Instead we match on the known projects.
  65 for i in `ls ${srcdir}/projects`
  66 do
  67   if test -d ${srcdir}/projects/${i} ; then
  68     case ${i} in
  69       CVS) ;;
  70       sample)       AC_CONFIG_SUBDIRS([projects/sample])    ;;
  71       privbracket)  AC_CONFIG_SUBDIRS([projects/privbracket]) ;;
  72       llvm-stacker) AC_CONFIG_SUBDIRS([projects/llvm-stacker]) ;;
  73       llvm-test)    AC_CONFIG_SUBDIRS([projects/llvm-test]) ;;
  74       llvm-reopt)   AC_CONFIG_SUBDIRS([projects/llvm-reopt]);;
  75       llvm-gcc)     AC_CONFIG_SUBDIRS([projects/llvm-gcc])  ;;
  76       llvm-java)    AC_CONFIG_SUBDIRS([projects/llvm-java]) ;;
  77       llvm-tv)      AC_CONFIG_SUBDIRS([projects/llvm-tv])   ;;
  78       llvm-poolalloc) AC_CONFIG_SUBDIRS([projects/llvm-poolalloc]) ;;
  79       llvm-kernel)  AC_CONFIG_SUBDIRS([projects/llvm-kernel]) ;;
  80       *)
  81         AC_MSG_WARN([Unknown project (${i}) won't be configured automatically])
  82         ;;
  83     esac
  84   fi
  85 done
  86
  87 dnl===-----------------------------------------------------------------------===
  88 dnl===
  89 dnl=== SECTION 2: Architecture, target, and host checks
  90 dnl===
  91 dnl===-----------------------------------------------------------------------===
  92
  93 dnl Check the target for which we're compiling and the host that will do the
  94 dnl compilations. This will tell us which LLVM compiler will be used for
  95 dnl compiling SSA into object code. This needs to be done early because
  96 dnl following tests depend on it.
  97 AC_CANONICAL_TARGET
  98
  99 dnl Determine the platform type and cache its value. This helps us configure
 100 dnl the System library to the correct build platform.
 101 AC_CACHE_CHECK([type of operating system we're going to host on],
 102                [llvm_cv_os_type],
 103 [case $host in
 104   *-*-aix*)
 105     llvm_cv_link_all_option="-Wl,--whole-archive"
 106     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 107     llvm_cv_os_type="AIX"
 108     llvm_cv_platform_type="Unix" ;;
 109   *-*-irix*)
 110     llvm_cv_link_all_option="-Wl,--whole-archive"
 111     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 112     llvm_cv_os_type="IRIX"
 113     llvm_cv_platform_type="Unix" ;;
 114   *-*-cygwin*)
 115     llvm_cv_link_all_option="-Wl,--whole-archive"
 116     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 117     llvm_cv_os_type="Cygwin"
 118     llvm_cv_platform_type="Unix" ;;
 119   *-*-darwin*)
 120     llvm_cv_link_all_option="-Wl,-all_load"
 121     llvm_cv_link_all_option="-Wl,-noall_load"
 122     llvm_cv_os_type="Darwin"
 123     llvm_cv_platform_type="Unix" ;;
 124   *-*-freebsd*)
 125     llvm_cv_link_all_option="-Wl,--whole-archive"
 126     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 127     llvm_cv_os_type="FreeBSD"
 128     llvm_cv_platform_type="Unix" ;;
 129   *-*-openbsd*)
 130     llvm_cv_link_all_option="-Wl,--whole-archive"
 131     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 132     llvm_cv_os_type="OpenBSD"
 133     llvm_cv_platform_type="Unix" ;;
 134   *-*-hpux*)
 135     llvm_cv_link_all_option="-Wl,--whole-archive"
 136     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 137     llvm_cv_os_type="HP-UX"
 138     llvm_cv_platform_type="Unix" ;;
 139   *-*-interix*)
 140     llvm_cv_link_all_option="-Wl,--whole-archive"
 141     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 142     llvm_cv_os_type="Interix"
 143     llvm_cv_platform_type="Unix" ;;
 144   *-*-linux*)
 145     llvm_cv_link_all_option="-Wl,--whole-archive"
 146     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 147     llvm_cv_os_type="Linux"
 148     llvm_cv_platform_type="Unix" ;;
 149   *-*-solaris*)
 150     llvm_cv_link_all_option="-Wl,-z,allextract"
 151     llvm_cv_no_link_all_option="-Wl,-z,defaultextract"
 152     llvm_cv_os_type="SunOS"
 153     llvm_cv_platform_type="Unix" ;;
 154   *-*-win32*)
 155     llvm_cv_link_all_option="-Wl,--whole-archive"
 156     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 157     llvm_cv_os_type="Win32"
 158     llvm_cv_platform_type="Win32" ;;
 159   *-*-mingw*)
 160     llvm_cv_link_all_option="-Wl,--whole-archive"
 161     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 162     llvm_cv_os_type="MingW"
 163     llvm_cv_platform_type="Win32" ;;
 164   *)
 165     llvm_cv_link_all_option=""
 166     llvm_cv_no_link_all_option=""
 167     llvm_cv_os_type="Unknown"
 168     llvm_cv_platform_type="Unknown" ;;
 169 esac])
 170
 171 dnl Make sure we aren't attempting to configure for an unknown system
 172 if test "$llvm_cv_os_type" = "Unknown" ; then
 173   AC_MSG_ERROR([Operating system is unknown, configure can't continue])
 174 fi
 175
 176 dnl Set the "OS" Makefile variable based on the platform type so the
 177 dnl makefile can configure itself to specific build hosts
 178 AC_SUBST(OS,$llvm_cv_os_type)
 179
 180 dnl Set the LINKALL and NOLINKALL Makefile variables based on the platform
 181 AC_SUBST(LINKALL,$llvm_cv_link_all_option)
 182 AC_SUBST(NOLINKALL,$llvm_cv_no_link_all_option)
 183
 184 dnl Set the "LLVM_ON_*" variables based on llvm_cvs_platform_type
 185 dnl This is used by lib/System to determine the basic kind of implementation
 186 dnl to use.
 187 case $llvm_cv_platform_type in
 188   Unix)
 189     AC_DEFINE([LLVM_ON_UNIX],[1],[Define if this is Unixish platform])
 190     AC_SUBST(LLVM_ON_UNIX,[1])
 191     AC_SUBST(LLVM_ON_WIN32,[0])
 192     ;;
 193   Win32)
 194     AC_DEFINE([LLVM_ON_WIN32],[1],[Define if this is Win32ish platform])
 195     AC_SUBST(LLVM_ON_UNIX,[0])
 196     AC_SUBST(LLVM_ON_WIN32,[1])
 197     ;;
 198 esac
 199
 200 dnl Determine what our target architecture is and configure accordingly.
 201 dnl This will allow Makefiles to make a distinction between the hardware and
 202 dnl the OS.
 203 AC_CACHE_CHECK([target architecture],[llvm_cv_target_arch],
 204 [case $target in
 205   i?86-*)                 llvm_cv_target_arch="x86" ;;
 206   amd64-* | x86_64-*)     llvm_cv_target_arch="x86_64" ;;
 207   sparc*-*)               llvm_cv_target_arch="Sparc" ;;
 208   powerpc*-*)             llvm_cv_target_arch="PowerPC" ;;
 209   alpha*-*)               llvm_cv_target_arch="Alpha" ;;
 210   ia64-*)                 llvm_cv_target_arch="IA64" ;;
 211   *)                      llvm_cv_target_arch="Unknown" ;;
 212 esac])
 213
 214 if test "$llvm_cv_target_arch" = "Unknown" ; then
 215   AC_MSG_WARN([Configuring LLVM for an unknown target archicture])
 216 fi
 217
 218 dnl Define a substitution, ARCH, for the target architecture
 219 AC_SUBST(ARCH,$llvm_cv_target_arch)
 220
 221 dnl Check for the endianness of the target
 222 AC_C_BIGENDIAN(AC_SUBST([ENDIAN],[big]),AC_SUBST([ENDIAN],[little]))
 223
 224 dnl Check for build platform executable suffix if we're crosscompiling
 225 if test "$cross_compiling" = yes; then
 226   AC_SUBST(LLVM_CROSS_COMPILING, [1])
 227   AC_BUILD_EXEEXT
 228 else
 229   AC_SUBST(LLVM_CROSS_COMPILING, [0])
 230 fi
 231
 232 dnl Check to see if there's a "CVS" directory indicating that this build is
 233 dnl being done from a CVS checkout. This sets up several defaults for the
 234 dnl command line switches. When we build with a CVS directory, we get a
 235 dnl debug with assertions turned on. Without, we assume a source release and we
 236 dnl get an optimized build without assertions. See --enable-optimized and
 237 dnl --enable-assertions below
 238 if test -d "CVS" -o -d "${srcdir}/CVS"; then
 239   cvsbuild="yes"
 240   optimize="no"
 241   AC_SUBST(CVSBUILD,[[CVSBUILD=1]])
 242 else
 243   cvsbuild="no"
 244   optimize="yes"
 245 fi
 246
 247 dnl===-----------------------------------------------------------------------===
 248 dnl===
 249 dnl=== SECTION 3: Command line arguments for the configure script.
 250 dnl===
 251 dnl===-----------------------------------------------------------------------===
 252
 253 dnl --enable-optimized : check whether they want to do an optimized build:
 254 AC_ARG_ENABLE(optimized, AS_HELP_STRING(
 255  [--enable-optimized,Compile with optimizations enabled (default is NO)]),,enableval=$optimize)
 256 if test ${enableval} = "no" ; then
 257   AC_SUBST(ENABLE_OPTIMIZED,[[]])
 258 else
 259   AC_SUBST(ENABLE_OPTIMIZED,[[ENABLE_OPTIMIZED=1]])
 260 fi
 261
 262 dnl --enable-assertions : check whether they want to turn on assertions or not:
 263 AC_ARG_ENABLE(assertions,AS_HELP_STRING(
 264   [--enable-assertions,Compile with assertion checks enabled (default is YES)]),, enableval="yes")
 265 if test ${enableval} = "yes" ; then
 266   AC_SUBST(DISABLE_ASSERTIONS,[[]])
 267 else
 268   AC_SUBST(DISABLE_ASSERTIONS,[[DISABLE_ASSERTIONS=1]])
 269 fi
 270
 271 dnl --enable-debug-runtime : should runtime libraries have debug symbols?
 272 AC_ARG_ENABLE(debug-runtime,
 273    AS_HELP_STRING([--enable-debug-runtime,Build runtime libs with debug symbols (default is NO)]),,enableval=no)
 274 if test ${enableval} = "no" ; then
 275   AC_SUBST(DEBUG_RUNTIME,[[]])
 276 else
 277   AC_SUBST(DEBUG_RUNTIME,[[DEBUG_RUNTIME=1]])
 278 fi
 279
 280 dnl --enable-jit: check whether they want to enable the jit
 281 AC_ARG_ENABLE(jit,
 282   AS_HELP_STRING(--enable-jit,
 283                  [Enable Just In Time Compiling (default is YES)]),,
 284   enableval=default)
 285 if test ${enableval} = "no"
 286 then
 287   AC_SUBST(JIT,[[]])
 288 else
 289   case "$llvm_cv_target_arch" in
 290     x86)     AC_SUBST(TARGET_HAS_JIT,1) ;;
 291     Sparc)   AC_SUBST(TARGET_HAS_JIT,1) ;;
 292     PowerPC) AC_SUBST(TARGET_HAS_JIT,1) ;;
 293     x86_64)  AC_SUBST(TARGET_HAS_JIT,0) ;;
 294     Alpha)   AC_SUBST(TARGET_HAS_JIT,1) ;;
 295     IA64)    AC_SUBST(TARGET_HAS_JIT,0) ;;
 296     *)       AC_SUBST(TARGET_HAS_JIT,0) ;;
 297   esac
 298 fi
 299
 300 dnl Allow enablement of doxygen generated documentation
 301 AC_ARG_ENABLE(doxygen,
 302               AS_HELP_STRING([--enable-doxygen],
 303                              [Build doxygen documentation (default is NO)]),,
 304                              enableval=default)
 305 case "$enableval" in
 306   yes) AC_SUBST(ENABLE_DOXYGEN,[1]) ;;
 307   no)  AC_SUBST(ENABLE_DOXYGEN,[0]) ;;
 308   default) AC_SUBST(ENABLE_DOXYGEN,[0]) ;;
 309   *) AC_MSG_ERROR([Invalid setting for --enable-doxygen. Use "yes" or "no"]) ;;
 310 esac
 311
 312 dnl Allow disablement of threads
 313 AC_ARG_ENABLE(threads,
 314               AS_HELP_STRING([--enable-threads],
 315                              [Use threads if available (default is YES)]),,
 316                              enableval=default)
 317 case "$enableval" in
 318   yes) AC_SUBST(ENABLE_THREADS,[1]) ;;
 319   no)  AC_SUBST(ENABLE_THREADS,[0]) ;;
 320   default) AC_SUBST(ENABLE_THREADS,[1]) ;;
 321   *) AC_MSG_ERROR([Invalid setting for --enable-threads. Use "yes" or "no"]) ;;
 322 esac
 323 AC_DEFINE_UNQUOTED([ENABLE_THREADS],$ENABLE_THREADS,[Define if threads enabled])
 324
 325 dnl Allow building with position independent code
 326 AC_ARG_ENABLE(pic,
 327   AS_HELP_STRING([--enable-pic],
 328                  [Build LLVM with Position Independent Code (default is NO)]),,
 329                  enableval=default)
 330 case "$enableval" in
 331   yes) AC_SUBST(ENABLE_PIC,[1]) ;;
 332   no)  AC_SUBST(ENABLE_PIC,[0]) ;;
 333   default) AC_SUBST(ENABLE_PIC,[0]) ;;
 334   *) AC_MSG_ERROR([Invalid setting for --enable-pic. Use "yes" or "no"]) ;;
 335 esac
 336 AC_DEFINE_UNQUOTED([ENABLE_PIC],$ENABLE_PIC,
 337                    [Define if position independent code is enabled])
 338
 339 dnl Allow specific targets to be specified for building (or not)
 340 TARGETS_TO_BUILD=""
 341 AC_ARG_ENABLE([targets],AS_HELP_STRING([--enable-targets],
 342     [Build specific host targets: all,host-only,{target-name} (default=all)]),,
 343     enableval=all)
 344 case "$enableval" in
 345   all) TARGETS_TO_BUILD="X86 Sparc PowerPC Alpha IA64 ARM" ;;
 346   host-only)
 347     case "$llvm_cv_target_arch" in
 348       x86)     TARGETS_TO_BUILD="X86" ;;
 349       x86_64)  TARGETS_TO_BUILD="X86" ;;
 350       Sparc)   TARGETS_TO_BUILD="Sparc" ;;
 351       PowerPC) TARGETS_TO_BUILD="PowerPC" ;;
 352       Alpha)   TARGETS_TO_BUILD="Alpha" ;;
 353       IA64)    TARGETS_TO_BUILD="IA64" ;;
 354       *)       AC_MSG_ERROR([Can not set target to build]) ;;
 355     esac
 356     ;;
 357   *)for a_target in `echo $enableval|sed -e 's/,/ /g' ` ; do
 358       case "$a_target" in
 359         x86)     TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 360         x86_64)  TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 361         sparc)   TARGETS_TO_BUILD="Sparc $TARGETS_TO_BUILD" ;;
 362         powerpc) TARGETS_TO_BUILD="PowerPC $TARGETS_TO_BUILD" ;;
 363         alpha)   TARGETS_TO_BUILD="Alpha $TARGETS_TO_BUILD" ;;
 364         ia64)    TARGETS_TO_BUILD="IA64 $TARGETS_TO_BUILD" ;;
 365         *) AC_MSG_ERROR([Unrecognized target $a_target]) ;;
 366       esac
 367   done
 368   ;;
 369 esac
 370 TARGETS_TO_BUILD="CBackend $TARGETS_TO_BUILD"
 371 AC_SUBST(TARGETS_TO_BUILD,$TARGETS_TO_BUILD)
 372
 373 dnl Prevent the CBackend from using printf("%a") for floating point so older
 374 dnl C compilers that cannot deal with the 0x0p+0 hex floating point format
 375 dnl can still compile the CBE's output
 376 AC_ARG_ENABLE([cbe-printf-a],AS_HELP_STRING([--enable-cbe-printf-a],
 377   [Enable C Backend output with hex floating point via %a  (default is YES)]),,
 378   enableval=default)
 379 case "$enableval" in
 380   yes) AC_SUBST(ENABLE_CBE_PRINTF_A,[1]) ;;
 381   no)  AC_SUBST(ENABLE_CBE_PRINTF_A,[0]) ;;
 382   default)  AC_SUBST(ENABLE_CBE_PRINTF_A,[1]) ;;
 383   *) AC_MSG_ERROR([Invalid setting for --enable-cbe-printf-a. Use "yes" or "no"]) ;;
 384 esac
 385 AC_DEFINE_UNQUOTED([ENABLE_CBE_PRINTF_A],$ENABLE_CBE_PRINTF_A,
 386                    [Define if CBE is enabled for printf %a output])
 387
 388 dnl Allow a specific llvm-gcc/llvm-g++ pair to be used with this LLVM config.
 389 AC_ARG_WITH(llvmgccdir,
 390   AS_HELP_STRING([--with-llvmgccdir],
 391     [Specify location of llvm-gcc install dir (default searches PATH)]),,
 392     withval=default)
 393 case "$withval" in
 394   default) WITH_LLVMGCCDIR=default ;;
 395   /* | [[A-Za-z]]:[[\\/]]*)      WITH_LLVMGCCDIR=$withval ;;
 396   *) AC_MSG_ERROR([Invalid path for --with-llvmgccdir. Provide full path]) ;;
 397 esac
 398
 399 dnl Specify extra build options
 400 AC_ARG_WITH(extra-options,
 401   AS_HELP_STRING([--with-extra-options],
 402                  [Specify addtional options to compile LLVM with]),,
 403                  withval=default)
 404 case "$withval" in
 405   default) EXTRA_OPTIONS= ;;
 406   *) EXTRA_OPTIONS=$withval ;;
 407 esac
 408 AC_SUBST(EXTRA_OPTIONS,$EXTRA_OPTIONS)
 409
 410 dnl===-----------------------------------------------------------------------===
 411 dnl===
 412 dnl=== SECTION 4: Check for programs we need and that they are the right version
 413 dnl===
 414 dnl===-----------------------------------------------------------------------===
 415
 416 dnl Check for compilation tools
 417 AC_PROG_CPP
 418 AC_PROG_CC(gcc)
 419 AC_PROG_CXX(g++)
 420 AC_PROG_FLEX
 421 AC_PROG_BISON
 422
 423 AC_PROG_NM
 424 AC_SUBST(NM)
 425
 426 dnl Check for the tools that the makefiles require
 427 AC_CHECK_GNU_MAKE
 428 AC_PROG_LN_S
 429 AC_PATH_PROG(CMP, [cmp], [cmp])
 430 AC_PATH_PROG(CP, [cp], [cp])
 431 AC_PATH_PROG(DATE, [date], [date])
 432 AC_PATH_PROG(FIND, [find], [find])
 433 AC_PATH_PROG(GREP, [grep], [grep])
 434 AC_PATH_PROG(MKDIR,[mkdir],[mkdir])
 435 AC_PATH_PROG(MV,   [mv],   [mv])
 436 AC_PROG_RANLIB
 437 AC_PATH_PROG(RM,   [rm],   [rm])
 438 AC_PATH_PROG(SED,  [sed],  [sed])
 439 AC_PATH_PROG(TAR,  [tar],  [gtar])
 440 AC_PATH_PROG(BINPWD,[pwd],  [pwd])
 441
 442 dnl Looking for misc. graph plotting software
 443 AC_PATH_PROG(GRAPHVIZ, [Graphviz], [echo Graphviz])
 444 if test "$GRAPHVIZ" != "echo Graphviz" ; then
 445   AC_DEFINE([HAVE_GRAPHVIZ],[1],[Define if the Graphviz program is available])
 446   dnl If we're targeting for mingw we should emit windows paths, not msys
 447   if test "$llvm_cv_os_type" = "MingW" ; then
 448     GRAPHVIZ=`echo $GRAPHVIZ | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 449   fi
 450   AC_DEFINE_UNQUOTED([LLVM_PATH_GRAPHVIZ],"$GRAPHVIZ${EXEEXT}",
 451    [Define to path to Graphviz program if found or 'echo Graphviz' otherwise])
 452 fi
 453 AC_PATH_PROG(DOT, [dot], [echo dot])
 454 if test "$DOT" != "echo dot" ; then
 455   AC_DEFINE([HAVE_DOT],[1],[Define if the dot program is available])
 456   dnl If we're targeting for mingw we should emit windows paths, not msys
 457   if test "$llvm_cv_os_type" = "MingW" ; then
 458     DOT=`echo $DOT | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 459   fi
 460   AC_DEFINE_UNQUOTED([LLVM_PATH_DOT],"$DOT${EXEEXT}",
 461    [Define to path to dot program if found or 'echo dot' otherwise])
 462 fi
 463 AC_PATH_PROGS(GV, [gv gsview32], [echo gv])
 464 if test "$GV" != "echo gv" ; then
 465   AC_DEFINE([HAVE_GV],[1],[Define if the gv program is available])
 466   dnl If we're targeting for mingw we should emit windows paths, not msys
 467   if test "$llvm_cv_os_type" = "MingW" ; then
 468     GV=`echo $GV | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 469   fi
 470   AC_DEFINE_UNQUOTED([LLVM_PATH_GV],"$GV${EXEEXT}",
 471    [Define to path to gv program if found or 'echo gv' otherwise])
 472 fi
 473 AC_PATH_PROG(DOTTY, [dotty], [echo dotty])
 474 if test "$DOTTY" != "echo dotty" ; then
 475   AC_DEFINE([HAVE_DOTTY],[1],[Define if the dotty program is available])
 476   dnl If we're targeting for mingw we should emit windows paths, not msys
 477   if test "$llvm_cv_os_type" = "MingW" ; then
 478     DOTTY=`echo $DOTTY | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 479   fi
 480   AC_DEFINE_UNQUOTED([LLVM_PATH_DOTTY],"$DOTTY${EXEEXT}",
 481    [Define to path to dotty program if found or 'echo dotty' otherwise])
 482 fi
 483
 484 dnl Look for a sufficiently recent version of Perl.
 485 LLVM_PROG_PERL([5.006])
 486 AC_SUBST(PERL)
 487 if test x"$PERL" = xnone; then
 488    AC_SUBST(HAVE_PERL,0)
 489 else
 490    AC_SUBST(HAVE_PERL,1)
 491 fi
 492
 493 dnl Find the install program
 494 AC_PROG_INSTALL
 495
 496 dnl Checks for documentation and testing tools that we can do without. If these
 497 dnl are not found then they are set to "true" which always succeeds but does
 498 dnl nothing. This just lets the build output show that we could have done
 499 dnl something if the tool was available.
 500 AC_PATH_PROG(BZIP2,[bzip2],[echo "Skipped: bzip2 not found"])
 501 AC_PATH_PROG(DOXYGEN,[doxygen],[echo "Skipped: doxygen not found"])
 502 AC_PATH_PROG(GROFF,[groff],[echo "Skipped: groff not found"])
 503 AC_PATH_PROG(GZIP,[gzip],[echo "Skipped: gzip not found"])
 504 AC_PATH_PROG(POD2HTML,[pod2html],[echo "Skipped: pod2html not found"])
 505 AC_PATH_PROG(POD2MAN,[pod2man],[echo "Skipped: pod2man not found"])
 506 AC_PATH_PROG(RUNTEST,[runtest],[echo "Skipped: runtest not found"])
 507 DJ_AC_PATH_TCLSH
 508 AC_PATH_PROG(ZIP,[zip],[echo "Skipped: zip not found"])
 509
 510 dnl Determine if the linker supports the -R option.
 511 AC_LINK_USE_R
 512
 513 dnl Check for libtool and the library that has dlopen function (which must come
 514 dnl before the AC_PROG_LIBTOOL check in order to enable dlopening libraries with
 515 dnl libtool).
 516 AC_LIBTOOL_DLOPEN
 517 AC_LIB_LTDL
 518 AC_PROG_LIBTOOL
 519
 520 if test "$lt_cv_dlopen_self" = "yes" ; then
 521   AC_DEFINE([CAN_DLOPEN_SELF],[1],
 522               [Define if dlopen(0) will open the symbols of the program])
 523 fi
 524
 525 dnl Check if we know how to tell etags we are using C++:
 526 etags_version=`$ETAGS --version 2>&1`
 527 case "$etags_version" in
 528         *[Ee]xuberant*) ETAGSFLAGS="--language-force=c++" ;;
 529         *GNU\ Emacs*) ETAGSFLAGS="-l c++" ;;
 530         *) ETAGSFLAGS="" ;;
 531 esac
 532 AC_SUBST(ETAGSFLAGS,$ETAGSFLAGS)
 533
 534 if test "$WITH_LLVMGCCDIR" = "default" ; then
 535   LLVMGCC="llvm-gcc${EXEEXT}"
 536   LLVMGXX="llvm-g++${EXEEXT}"
 537   AC_PATH_PROG(LLVMGCC, $LLVMGCC, [])
 538   AC_PATH_PROG(LLVMGXX, $LLVMGXX, [])
 539 else
 540   LLVMGCC="$WITH_LLVMGCCDIR/bin/llvm-gcc${EXEEXT}"
 541   LLVMGXX="$WITH_LLVMGCCDIR/bin/llvm-g++${EXEEXT}"
 542   AC_SUBST(LLVMGCC,$LLVMGCC)
 543   AC_SUBST(LLVMGXX,$LLVMGXX)
 544 fi
 545
 546 AC_MSG_CHECKING([tool compatibility])
 547
 548 dnl Ensure that compilation tools are GCC or a GNU compatible compiler such as
 549 dnl ICC; we use GCC specific options in the makefiles so the compiler needs
 550 dnl to support those options.
 551 dnl "icc" emits gcc signatures
 552 dnl "icc -no-gcc" emits no gcc signature BUT is still compatible
 553 ICC=no
 554 IXX=no
 555 case $CC in
 556   icc*|icpc*)
 557     ICC=yes
 558     IXX=yes
 559     ;;
 560    *)
 561     ;;
 562 esac
 563
 564 if test "$GCC" != "yes" && test "$ICC" != "yes"
 565 then
 566   AC_MSG_ERROR([gcc|icc required but not found])
 567 fi
 568
 569 dnl Ensure that compilation tools are GCC; we use GCC specific extensions
 570 if test "$GXX" != "yes" && test "$IXX" != "yes"
 571 then
 572   AC_MSG_ERROR([g++|icc required but not found])
 573 fi
 574
 575 dnl Verify that GCC is version 3.0 or higher
 576 if test "$GCC" = "yes"
 577 then
 578   gccmajor=`$CC --version | head -n 1 | sed 's/[[^0-9]]*\([[0-9.]]\).*/\1/'`
 579   if test "$gccmajor" -lt "3"
 580   then
 581     AC_MSG_ERROR([gcc 3.x required, but you have a lower version])
 582   fi
 583 fi
 584
 585 dnl Check for GNU Make.  We use its extensions, so don't build without it
 586 if test -z "$llvm_cv_gnu_make_command"
 587 then
 588   AC_MSG_ERROR([GNU Make required but not found])
 589 fi
 590
 591 dnl Tool compatibility is okay if we make it here.
 592 AC_MSG_RESULT([ok])
 593
 594 dnl===-----------------------------------------------------------------------===
 595 dnl===
 596 dnl=== SECTION 5: Check for libraries
 597 dnl===
 598 dnl===-----------------------------------------------------------------------===
 599
 600 dnl libelf is for sparc only; we can ignore it if we don't have it
 601 AC_CHECK_LIB(elf, elf_begin)
 602 AC_CHECK_LIB(m,sin)
 603 if test "$llvm_cv_os_type" = "MingW" ; then
 604   AC_CHECK_LIB(imagehlp, main)
 605   AC_CHECK_LIB(psapi, main)
 606 fi
 607
 608 dnl lt_dlopen may be required for plugin support.
 609 AC_SEARCH_LIBS(lt_dlopen,ltdl,AC_DEFINE([HAVE_LT_DLOPEN],[1],
 610               [Define if lt_dlopen() is available on this platform]),
 611               AC_MSG_WARN([lt_dlopen() not found - plugin support might
 612                            not be available]))
 613
 614 dnl dlopen() is required for plugin support.
 615 AC_SEARCH_LIBS(dlopen,dl,AC_DEFINE([HAVE_DLOPEN],[1],
 616                [Define if dlopen() is available on this platform.]),
 617                AC_MSG_WARN([dlopen() not found - disabling plugin support]))
 618
 619 dnl mallinfo is optional; the code can compile (minus features) without it
 620 AC_SEARCH_LIBS(mallinfo,malloc,AC_DEFINE([HAVE_MALLINFO],[1],
 621                [Define if mallinfo() is available on this platform.]))
 622
 623 dnl pthread locking functions are optional - but llvm will not be thread-safe
 624 dnl without locks.
 625 if test "$ENABLE_THREADS" -eq 1 ; then
 626   AC_CHECK_LIB(pthread,pthread_mutex_init)
 627   AC_SEARCH_LIBS(pthread_mutex_lock,pthread,
 628                  AC_DEFINE([HAVE_PTHREAD_MUTEX_LOCK],[1],
 629                            [Have pthread_mutex_lock]))
 630 fi
 631
 632 dnl Allow extra x86-disassembler library
 633 AC_ARG_WITH(udis86,
 634   AS_HELP_STRING([--with-udis86=<path>],
 635     [Use udis86 external x86 disassembler library]),
 636     [
 637       AC_SUBST(USE_UDIS86, [1])
 638       case "$withval" in
 639         /usr/lib) ;;
 640         *) LDFLAGS="$LDFLAGS -L${withval}" ;;
 641       esac
 642       AC_CHECK_LIB(udis86, ud_init, [], [
 643         echo "Error! You need to have libudis86 around."
 644         exit -1
 645       ])
 646     ],
 647     AC_SUBST(USE_UDIS86, [0]))
 648 AC_DEFINE_UNQUOTED([USE_UDIS86],$USE_UDIS86,
 649                    [Define if use udis86 library])
 650
 651 dnl===-----------------------------------------------------------------------===
 652 dnl===
 653 dnl=== SECTION 6: Check for header files
 654 dnl===
 655 dnl===-----------------------------------------------------------------------===
 656
 657 dnl First, use autoconf provided macros for specific headers that we need
 658 dnl We don't check for ancient stuff or things that are guaranteed to be there
 659 dnl by the C++ standard. We always use the <cfoo> versions of <foo.h> C headers.
 660 dnl Generally we're looking for POSIX headers.
 661 AC_HEADER_DIRENT
 662 AC_HEADER_MMAP_ANONYMOUS
 663 AC_HEADER_STAT
 664 AC_HEADER_STDC
 665 AC_HEADER_SYS_WAIT
 666 AC_HEADER_TIME
 667
 668 AC_CHECK_HEADERS([dlfcn.h execinfo.h fcntl.h inttypes.h limits.h link.h])
 669 AC_CHECK_HEADERS([malloc.h setjmp.h signal.h stdint.h unistd.h utime.h])
 670 AC_CHECK_HEADERS([windows.h sys/mman.h sys/param.h sys/resource.h sys/time.h])
 671 AC_CHECK_HEADERS([sys/types.h malloc/malloc.h mach/mach.h])
 672 if test "$ENABLE_THREADS" -eq 1 ; then
 673   AC_CHECK_HEADER(pthread.h,
 674                   AC_SUBST(HAVE_PTHREAD, 1),
 675                    AC_SUBST(HAVE_PTHREAD, 0))
 676 else
 677   AC_SUBST(HAVE_PTHREAD, 0)
 678 fi
 679
 680 dnl===-----------------------------------------------------------------------===
 681 dnl===
 682 dnl=== SECTION 7: Check for types and structures
 683 dnl===
 684 dnl===-----------------------------------------------------------------------===
 685
 686 AC_HUGE_VAL_CHECK
 687 AC_TYPE_PID_T
 688 AC_TYPE_SIZE_T
 689 AC_TYPE_SIGNAL
 690 AC_STRUCT_TM
 691 AC_CHECK_TYPES([int64_t],,AC_MSG_ERROR([Type int64_t required but not found]))
 692 AC_CHECK_TYPES([uint64_t],,
 693          AC_CHECK_TYPES([u_int64_t],,
 694          AC_MSG_ERROR([Type uint64_t or u_int64_t required but not found])))
 695
 696 dnl===-----------------------------------------------------------------------===
 697 dnl===
 698 dnl=== SECTION 8: Check for specific functions needed
 699 dnl===
 700 dnl===-----------------------------------------------------------------------===
 701
 702 AC_CHECK_FUNCS([backtrace ceilf floorf roundf rintf nearbyintf getcwd ])
 703 AC_CHECK_FUNCS([getpagesize getrusage gettimeofday isatty mkdtemp mkstemp ])
 704 AC_CHECK_FUNCS([mktemp realpath sbrk setrlimit strdup strerror strerror_r ])
 705 AC_CHECK_FUNCS([strtoll strtoq sysconf malloc_zone_statistics ])
 706 AC_CHECK_FUNCS([setjmp longjmp sigsetjmp siglongjmp])
 707 AC_C_PRINTF_A
 708 AC_FUNC_ALLOCA
 709 AC_FUNC_RAND48
 710
 711 dnl Check for variations in the Standard C++ library and STL. These macros are
 712 dnl provided by LLVM in the autoconf/m4 directory.
 713 AC_CXX_HAVE_HASH_MAP
 714 AC_CXX_HAVE_HASH_SET
 715 AC_CXX_HAVE_STD_ITERATOR
 716 AC_CXX_HAVE_BI_ITERATOR
 717 AC_CXX_HAVE_FWD_ITERATOR
 718 AC_FUNC_ISNAN
 719 AC_FUNC_ISINF
 720
 721 dnl Check for mmap and mprotect support. We need both to do the JIT and for
 722 dnl bytecode loading, etc. We also need to know if /dev/zero is required to
 723 dnl be opened for allocating RWX memory.
 724 AC_FUNC_MMAP
 725 AC_FUNC_MMAP_FILE
 726 AC_NEED_DEV_ZERO_FOR_MMAP
 727 AC_CHECK_FUNC(mprotect,,
 728               AC_MSG_ERROR([Function mprotect() required but not found]))
 729
 730 if test "$ac_cv_func_mmap_fixed_mapped" = "no"
 731 then
 732   AC_MSG_WARN([mmap() of a fixed address required but not supported])
 733 fi
 734 if test "$ac_cv_func_mmap_file" = "no"
 735 then
 736   AC_MSG_WARN([mmap() of files required but not found])
 737 fi
 738
 739 dnl===-----------------------------------------------------------------------===
 740 dnl===
 741 dnl=== SECTION 9: Additional checks, variables, etc.
 742 dnl===
 743 dnl===-----------------------------------------------------------------------===
 744
 745 dnl See if the llvm-gcc executable can compile to LLVM assembly
 746 AC_CACHE_CHECK([whether llvm-gcc is sane],[llvm_cv_llvmgcc_sanity],
 747 [llvm_cv_llvmgcc_sanity="no"
 748 if test -x "$LLVMGCC" ; then
 749   cp /dev/null conftest.c
 750   "$LLVMGCC" -emit-llvm -S -o - conftest.c | grep implementation > /dev/null 2>&1
 751   if test $? -eq 0 ; then
 752     llvm_cv_llvmgcc_sanity="yes"
 753   fi
 754   rm conftest.c
 755 fi])
 756
 757 dnl Since we have a sane llvm-gcc, identify it and its sub-tools
 758 if test "$llvm_cv_llvmgcc_sanity" = "yes" ; then
 759   llvmcc1path=`"$LLVMGCC" --print-prog-name=cc1`
 760   AC_SUBST(LLVMCC1,$llvmcc1path)
 761   llvmcc1pluspath=`"$LLVMGCC" --print-prog-name=cc1plus`
 762   AC_SUBST(LLVMCC1PLUS,$llvmcc1pluspath)
 763   llvmgccdir=`echo "$llvmcc1path" | sed 's,/libexec/.*,,'`
 764   AC_SUBST(LLVMGCCDIR,$llvmgccdir)
 765   llvmgcclibexec=`echo "$llvmcc1path" | sed 's,/cc1,,'`
 766   AC_SUBST(LLVMGCCLIBEXEC,$llvmgcclibexec)
 767   llvmgccversion=[`"$LLVMGCC" -dumpversion 2>&1 | sed 's/^\([0-9.]*\).*/\1/'`]
 768   llvmgccmajvers=[`echo $llvmgccversion | sed 's/^\([0-9]\).*/\1/'`]
 769   AC_SUBST(LLVMGCC_VERSION,$llvmgccversion)
 770   AC_SUBST(LLVMGCC_MAJVERS,$llvmgccmajvers)
 771 fi
 772
 773 dnl Propagate the shared library extension that the libltdl checks did to
 774 dnl the Makefiles so we can use it there too
 775 AC_SUBST(SHLIBEXT,$libltdl_cv_shlibext)
 776
 777 # Translate the various configuration directories and other basic
 778 # information into substitutions that will end up in Makefile.config.in
 779 # that these configured values can be used by the makefiles
 780 if test "${prefix}" = "NONE" ; then
 781   prefix="/usr/local"
 782 fi
 783 eval LLVM_PREFIX="${prefix}";
 784 eval LLVM_BINDIR="${prefix}/bin";
 785 eval LLVM_LIBDIR="${prefix}/lib";
 786 eval LLVM_DATADIR="${prefix}/share/llvm";
 787 eval LLVM_DOCSDIR="${prefix}/docs/llvm";
 788 eval LLVM_ETCDIR="${prefix}/etc/llvm";
 789 eval LLVM_INCLUDEDIR="${prefix}/include";
 790 eval LLVM_INFODIR="${prefix}/info";
 791 eval LLVM_MANDIR="${prefix}/man";
 792 LLVM_CONFIGTIME=`date`
 793 AC_SUBST(LLVM_PREFIX)
 794 AC_SUBST(LLVM_BINDIR)
 795 AC_SUBST(LLVM_LIBDIR)
 796 AC_SUBST(LLVM_DATADIR)
 797 AC_SUBST(LLVM_DOCSDIR)
 798 AC_SUBST(LLVM_ETCDIR)
 799 AC_SUBST(LLVM_INCLUDEDIR)
 800 AC_SUBST(LLVM_INFODIR)
 801 AC_SUBST(LLVM_MANDIR)
 802 AC_SUBST(LLVM_CONFIGTIME)
 803
 804 # Place the various directores into the config.h file as #defines so that we
 805 # can know about the installation paths within LLVM.
 806 AC_DEFINE_UNQUOTED(LLVM_PREFIX,"$LLVM_PREFIX",
 807                    [Installation prefix directory])
 808 AC_DEFINE_UNQUOTED(LLVM_BINDIR, "$LLVM_BINDIR",
 809                    [Installation directory for binary executables])
 810 AC_DEFINE_UNQUOTED(LLVM_LIBDIR, "$LLVM_LIBDIR",
 811                    [Installation directory for libraries])
 812 AC_DEFINE_UNQUOTED(LLVM_DATADIR, "$LLVM_DATADIR",
 813                    [Installation directory for data files])
 814 AC_DEFINE_UNQUOTED(LLVM_DATADIR, "$LLVM_DOCSDIR",
 815                    [Installation directory for documentation])
 816 AC_DEFINE_UNQUOTED(LLVM_ETCDIR, "$LLVM_ETCDIR",
 817                    [Installation directory for config files])
 818 AC_DEFINE_UNQUOTED(LLVM_INCLUDEDIR, "$LLVM_INCLUDEDIR",
 819                    [Installation directory for include files])
 820 AC_DEFINE_UNQUOTED(LLVM_INFODIR, "$LLVM_INFODIR",
 821                    [Installation directory for .info files])
 822 AC_DEFINE_UNQUOTED(LLVM_MANDIR, "$LLVM_MANDIR",
 823                    [Installation directory for man pages])
 824 AC_DEFINE_UNQUOTED(LLVM_CONFIGTIME, "$LLVM_CONFIGTIME",
 825                    [Time at which LLVM was configured])
 826
 827 dnl===-----------------------------------------------------------------------===
 828 dnl===
 829 dnl=== SECTION 10: Specify the output files and generate it
 830 dnl===
 831 dnl===-----------------------------------------------------------------------===
 832
 833 dnl Configure header files
 834 dnl WARNING: dnl If you add or remove any of the following config headers, then
 835 dnl you MUST also update Makefile.rules so that the variable FilesToConfig
 836 dnl contains the same list of files as AC_CONFIG_HEADERS below. This ensures the
 837 dnl files can be updated automatically when their *.in sources change.
 838 AC_CONFIG_HEADERS([include/llvm/Config/config.h])
 839 AC_CONFIG_HEADERS([include/llvm/Support/DataTypes.h])
 840 AC_CONFIG_HEADERS([include/llvm/ADT/hash_map])
 841 AC_CONFIG_HEADERS([include/llvm/ADT/hash_set])
 842 AC_CONFIG_HEADERS([include/llvm/ADT/iterator])
 843
 844 dnl Configure the makefile's configuration data
 845 AC_CONFIG_FILES([Makefile.config])
 846
 847 dnl Configure the RPM spec file for LLVM
 848 AC_CONFIG_FILES([llvm.spec])
 849
 850 dnl Configure doxygen's configuration file
 851 AC_CONFIG_FILES([docs/doxygen.cfg])
 852
 853 dnl Do the first stage of configuration for llvm-config.in.
 854 AC_CONFIG_FILES([tools/llvm-config/llvm-config.in])
 855
 856 dnl Do special configuration of Makefiles
 857 AC_CONFIG_COMMANDS([setup],,[llvm_src="${srcdir}"])
 858 AC_CONFIG_MAKEFILE(Makefile)
 859 AC_CONFIG_MAKEFILE(Makefile.common)
 860 AC_CONFIG_MAKEFILE(examples/Makefile)
 861 AC_CONFIG_MAKEFILE(lib/Makefile)
 862 AC_CONFIG_MAKEFILE(runtime/Makefile)
 863 AC_CONFIG_MAKEFILE(test/Makefile)
 864 AC_CONFIG_MAKEFILE(test/Makefile.tests)
 865 AC_CONFIG_MAKEFILE(tools/Makefile)
 866 AC_CONFIG_MAKEFILE(utils/Makefile)
 867 AC_CONFIG_MAKEFILE(projects/Makefile)
 868
 869 dnl Finally, crank out the output
 870 AC_OUTPUT
 871