autoconf/configure.ac

   1 dnl === configure.ac --------------------------------------------------------===
   2 dnl                     The LLVM Compiler Infrastructure
   3 dnl
   4 dnl This file is distributed under the University of Illinois Open Source
   5 dnl License. See LICENSE.TXT for details.
   6 dnl
   7 dnl===-----------------------------------------------------------------------===
   8 dnl This is the LLVM configuration script. It is processed by the autoconf
   9 dnl program to produce a script named configure. This script contains the
  10 dnl configuration checks that LLVM needs in order to support multiple platforms.
  11 dnl This file is composed of 10 sections per the recommended organization of
  12 dnl autoconf input defined in the autoconf documentation. As this file evolves,
  13 dnl please keep the various types of checks within their sections. The sections
  14 dnl are as follows:
  15 dnl
  16 dnl SECTION 1: Initialization & Setup
  17 dnl SECTION 2: Architecture, target, and host checks
  18 dnl SECTION 3: Command line arguments for the configure script.
  19 dnl SECTION 4: Check for programs we need and that they are the right version
  20 dnl SECTION 5: Check for libraries
  21 dnl SECTION 6: Check for header files
  22 dnl SECTION 7: Check for types and structures
  23 dnl SECTION 8: Check for specific functions needed
  24 dnl SECTION 9: Additional checks, variables, etc.
  25 dnl SECTION 10: Specify the output files and generate it
  26 dnl
  27 dnl===-----------------------------------------------------------------------===
  28 dnl===
  29 dnl=== SECTION 1: Initialization & Setup
  30 dnl===
  31 dnl===-----------------------------------------------------------------------===
  32 dnl Initialize autoconf and define the package name, version number and
  33 dnl email address for reporting bugs.
  34 AC_INIT([[llvm]],[[2.7svn]],[llvmbugs@cs.uiuc.edu])
  35
  36 dnl Provide a copyright substitution and ensure the copyright notice is included
  37 dnl in the output of --version option of the generated configure script.
  38 AC_SUBST(LLVM_COPYRIGHT,["Copyright (c) 2003-2009 University of Illinois at Urbana-Champaign."])
  39 AC_COPYRIGHT([Copyright (c) 2003-2009 University of Illinois at Urbana-Champaign.])
  40
  41 dnl Indicate that we require autoconf 2.59 or later. Ths is needed because we
  42 dnl use some autoconf macros only available in 2.59.
  43 AC_PREREQ(2.59)
  44
  45 dnl Verify that the source directory is valid. This makes sure that we are
  46 dnl configuring LLVM and not some other package (it validates --srcdir argument)
  47 AC_CONFIG_SRCDIR([lib/VMCore/Module.cpp])
  48
  49 dnl Place all of the extra autoconf files into the config subdirectory. Tell
  50 dnl various tools where the m4 autoconf macros are.
  51 AC_CONFIG_AUX_DIR([autoconf])
  52
  53 dnl Quit if the source directory has already been configured.
  54 dnl NOTE: This relies upon undocumented autoconf behavior.
  55 if test ${srcdir} != "." ; then
  56   if test -f ${srcdir}/include/llvm/Config/config.h ; then
  57     AC_MSG_ERROR([Already configured in ${srcdir}])
  58   fi
  59 fi
  60
  61 dnl Configure all of the projects present in our source tree. While we could
  62 dnl just AC_CONFIG_SUBDIRS on the set of directories in projects that have a
  63 dnl configure script, that usage of the AC_CONFIG_SUBDIRS macro is deprecated.
  64 dnl Instead we match on the known projects.
  65 for i in `ls ${srcdir}/projects`
  66 do
  67   if test -d ${srcdir}/projects/${i} ; then
  68     case ${i} in
  69       CVS) ;;
  70       sample)       AC_CONFIG_SUBDIRS([projects/sample])    ;;
  71       privbracket)  AC_CONFIG_SUBDIRS([projects/privbracket]) ;;
  72       llvm-stacker) AC_CONFIG_SUBDIRS([projects/llvm-stacker]) ;;
  73       # llvm-test is the old name of the test-suite, kept here for backwards
  74       # compatibility
  75       llvm-test)    AC_CONFIG_SUBDIRS([projects/llvm-test]) ;;
  76       test-suite)   AC_CONFIG_SUBDIRS([projects/test-suite]) ;;
  77       llvm-reopt)   AC_CONFIG_SUBDIRS([projects/llvm-reopt]);;
  78       llvm-gcc)     AC_CONFIG_SUBDIRS([projects/llvm-gcc])  ;;
  79       llvm-java)    AC_CONFIG_SUBDIRS([projects/llvm-java]) ;;
  80       llvm-tv)      AC_CONFIG_SUBDIRS([projects/llvm-tv])   ;;
  81       llvm-poolalloc) AC_CONFIG_SUBDIRS([projects/llvm-poolalloc]) ;;
  82       poolalloc)    AC_CONFIG_SUBDIRS([projects/poolalloc]) ;;
  83       llvm-kernel)  AC_CONFIG_SUBDIRS([projects/llvm-kernel]) ;;
  84       *)
  85         AC_MSG_WARN([Unknown project (${i}) won't be configured automatically])
  86         ;;
  87     esac
  88   fi
  89 done
  90
  91 dnl===-----------------------------------------------------------------------===
  92 dnl===
  93 dnl=== SECTION 2: Architecture, target, and host checks
  94 dnl===
  95 dnl===-----------------------------------------------------------------------===
  96
  97 dnl Check the target for which we're compiling and the host that will do the
  98 dnl compilations. This will tell us which LLVM compiler will be used for
  99 dnl compiling SSA into object code. This needs to be done early because
 100 dnl following tests depend on it.
 101 AC_CANONICAL_TARGET
 102
 103 dnl Determine the platform type and cache its value. This helps us configure
 104 dnl the System library to the correct build platform.
 105 AC_CACHE_CHECK([type of operating system we're going to host on],
 106                [llvm_cv_os_type],
 107 [case $host in
 108   *-*-aix*)
 109     llvm_cv_link_all_option="-Wl,--whole-archive"
 110     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 111     llvm_cv_os_type="AIX"
 112     llvm_cv_platform_type="Unix" ;;
 113   *-*-irix*)
 114     llvm_cv_link_all_option="-Wl,--whole-archive"
 115     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 116     llvm_cv_os_type="IRIX"
 117     llvm_cv_platform_type="Unix" ;;
 118   *-*-cygwin*)
 119     llvm_cv_link_all_option="-Wl,--whole-archive"
 120     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 121     llvm_cv_os_type="Cygwin"
 122     llvm_cv_platform_type="Unix" ;;
 123   *-*-darwin*)
 124     llvm_cv_link_all_option="-Wl,-all_load"
 125     llvm_cv_no_link_all_option="-Wl,-noall_load"
 126     llvm_cv_os_type="Darwin"
 127     llvm_cv_platform_type="Unix" ;;
 128   *-*-freebsd*)
 129     llvm_cv_link_all_option="-Wl,--whole-archive"
 130     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 131     llvm_cv_os_type="FreeBSD"
 132     llvm_cv_platform_type="Unix" ;;
 133   *-*-openbsd*)
 134     llvm_cv_link_all_option="-Wl,--whole-archive"
 135     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 136     llvm_cv_os_type="OpenBSD"
 137     llvm_cv_platform_type="Unix" ;;
 138   *-*-netbsd*)
 139     llvm_cv_link_all_option="-Wl,--whole-archive"
 140     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 141     llvm_cv_os_type="NetBSD"
 142     llvm_cv_platform_type="Unix" ;;
 143   *-*-dragonfly*)
 144     llvm_cv_link_all_option="-Wl,--whole-archive"
 145     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 146     llvm_cv_os_type="DragonFly"
 147     llvm_cv_platform_type="Unix" ;;
 148   *-*-hpux*)
 149     llvm_cv_link_all_option="-Wl,--whole-archive"
 150     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 151     llvm_cv_os_type="HP-UX"
 152     llvm_cv_platform_type="Unix" ;;
 153   *-*-interix*)
 154     llvm_cv_link_all_option="-Wl,--whole-archive"
 155     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 156     llvm_cv_os_type="Interix"
 157     llvm_cv_platform_type="Unix" ;;
 158   *-*-linux*)
 159     llvm_cv_link_all_option="-Wl,--whole-archive"
 160     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 161     llvm_cv_os_type="Linux"
 162     llvm_cv_platform_type="Unix" ;;
 163   *-*-solaris*)
 164     llvm_cv_link_all_option="-Wl,-z,allextract"
 165     llvm_cv_no_link_all_option="-Wl,-z,defaultextract"
 166     llvm_cv_os_type="SunOS"
 167     llvm_cv_platform_type="Unix" ;;
 168   *-*-win32*)
 169     llvm_cv_link_all_option="-Wl,--whole-archive"
 170     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 171     llvm_cv_os_type="Win32"
 172     llvm_cv_platform_type="Win32" ;;
 173   *-*-mingw*)
 174     llvm_cv_link_all_option="-Wl,--whole-archive"
 175     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 176     llvm_cv_os_type="MingW"
 177     llvm_cv_platform_type="Win32" ;;
 178   *-unknown-eabi*)
 179     llvm_cv_link_all_option="-Wl,--whole-archive"
 180     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 181     llvm_cv_os_type="Freestanding"
 182     llvm_cv_platform_type="Unix" ;;
 183   *-unknown-elf*)
 184     llvm_cv_link_all_option="-Wl,--whole-archive"
 185     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 186     llvm_cv_os_type="Freestanding"
 187     llvm_cv_platform_type="Unix" ;;
 188   *)
 189     llvm_cv_link_all_option=""
 190     llvm_cv_no_link_all_option=""
 191     llvm_cv_os_type="Unknown"
 192     llvm_cv_platform_type="Unknown" ;;
 193 esac])
 194
 195 AC_CACHE_CHECK([type of operating system we're going to target],
 196                [llvm_cv_target_os_type],
 197 [case $target in
 198   *-*-aix*)
 199     llvm_cv_target_os_type="AIX" ;;
 200   *-*-irix*)
 201     llvm_cv_target_os_type="IRIX" ;;
 202   *-*-cygwin*)
 203     llvm_cv_target_os_type="Cygwin" ;;
 204   *-*-darwin*)
 205     llvm_cv_target_os_type="Darwin" ;;
 206   *-*-freebsd*)
 207     llvm_cv_target_os_type="FreeBSD" ;;
 208   *-*-openbsd*)
 209     llvm_cv_target_os_type="OpenBSD" ;;
 210   *-*-netbsd*)
 211     llvm_cv_target_os_type="NetBSD" ;;
 212   *-*-dragonfly*)
 213     llvm_cv_target_os_type="DragonFly" ;;
 214   *-*-hpux*)
 215     llvm_cv_target_os_type="HP-UX" ;;
 216   *-*-interix*)
 217     llvm_cv_target_os_type="Interix" ;;
 218   *-*-linux*)
 219     llvm_cv_target_os_type="Linux" ;;
 220   *-*-solaris*)
 221     llvm_cv_target_os_type="SunOS" ;;
 222   *-*-win32*)
 223     llvm_cv_target_os_type="Win32" ;;
 224   *-*-mingw*)
 225     llvm_cv_target_os_type="MingW" ;;
 226   *-unknown-eabi*)
 227     llvm_cv_target_os_type="Freestanding" ;;
 228   *)
 229     llvm_cv_target_os_type="Unknown" ;;
 230 esac])
 231
 232 dnl Make sure we aren't attempting to configure for an unknown system
 233 if test "$llvm_cv_os_type" = "Unknown" ; then
 234   AC_MSG_ERROR([Operating system is unknown, configure can't continue])
 235 fi
 236
 237 dnl Set the "OS" Makefile variable based on the platform type so the
 238 dnl makefile can configure itself to specific build hosts
 239 AC_SUBST(OS,$llvm_cv_os_type)
 240 AC_SUBST(HOST_OS,$llvm_cv_os_type)
 241 AC_SUBST(TARGET_OS,$llvm_cv_target_os_type)
 242
 243 dnl Set the LINKALL and NOLINKALL Makefile variables based on the platform
 244 AC_SUBST(LINKALL,$llvm_cv_link_all_option)
 245 AC_SUBST(NOLINKALL,$llvm_cv_no_link_all_option)
 246
 247 dnl Set the "LLVM_ON_*" variables based on llvm_cvs_platform_type
 248 dnl This is used by lib/System to determine the basic kind of implementation
 249 dnl to use.
 250 case $llvm_cv_platform_type in
 251   Unix)
 252     AC_DEFINE([LLVM_ON_UNIX],[1],[Define if this is Unixish platform])
 253     AC_SUBST(LLVM_ON_UNIX,[1])
 254     AC_SUBST(LLVM_ON_WIN32,[0])
 255     ;;
 256   Win32)
 257     AC_DEFINE([LLVM_ON_WIN32],[1],[Define if this is Win32ish platform])
 258     AC_SUBST(LLVM_ON_UNIX,[0])
 259     AC_SUBST(LLVM_ON_WIN32,[1])
 260     ;;
 261 esac
 262
 263 dnl Determine what our target architecture is and configure accordingly.
 264 dnl This will allow Makefiles to make a distinction between the hardware and
 265 dnl the OS.
 266 AC_CACHE_CHECK([target architecture],[llvm_cv_target_arch],
 267 [case $target in
 268   i?86-*)                 llvm_cv_target_arch="x86" ;;
 269   amd64-* | x86_64-*)     llvm_cv_target_arch="x86_64" ;;
 270   sparc*-*)               llvm_cv_target_arch="Sparc" ;;
 271   powerpc*-*)             llvm_cv_target_arch="PowerPC" ;;
 272   alpha*-*)               llvm_cv_target_arch="Alpha" ;;
 273   arm*-*)                 llvm_cv_target_arch="ARM" ;;
 274   mips-*)                 llvm_cv_target_arch="Mips" ;;
 275   pic16-*)                llvm_cv_target_arch="PIC16" ;;
 276   xcore-*)                llvm_cv_target_arch="XCore" ;;
 277   msp430-*)               llvm_cv_target_arch="MSP430" ;;
 278   s390x-*)                llvm_cv_target_arch="SystemZ" ;;
 279   bfin-*)                 llvm_cv_target_arch="Blackfin" ;;
 280   *)                      llvm_cv_target_arch="Unknown" ;;
 281 esac])
 282
 283 if test "$llvm_cv_target_arch" = "Unknown" ; then
 284   AC_MSG_WARN([Configuring LLVM for an unknown target archicture])
 285 fi
 286
 287 dnl Handle 32-bit linux systems running a 64-bit kernel.
 288 if test "$llvm_cv_os_type" = "Linux" -a "$llvm_cv_target_arch" = "x86_64" ; then
 289   AC_IS_LINUX_MIXED
 290   if test "$llvm_cv_linux_mixed" = "yes"; then
 291     llvm_cv_target_arch="x86"
 292   fi
 293 fi
 294
 295 # Determine the LLVM native architecture for the target
 296 case "$llvm_cv_target_arch" in
 297     x86)     LLVM_NATIVE_ARCH="X86" ;;
 298     x86_64)  LLVM_NATIVE_ARCH="X86" ;;
 299     *)       LLVM_NATIVE_ARCH="$llvm_cv_target_arch" ;;
 300 esac
 301
 302 dnl Define a substitution, ARCH, for the target architecture
 303 AC_SUBST(ARCH,$llvm_cv_target_arch)
 304
 305 dnl Check for the endianness of the target
 306 AC_C_BIGENDIAN(AC_SUBST([ENDIAN],[big]),AC_SUBST([ENDIAN],[little]))
 307
 308 dnl Check for build platform executable suffix if we're crosscompiling
 309 if test "$cross_compiling" = yes; then
 310   AC_SUBST(LLVM_CROSS_COMPILING, [1])
 311   AC_BUILD_EXEEXT
 312   ac_build_prefix=${build_alias}-
 313   AC_CHECK_PROG(BUILD_CXX, ${ac_build_prefix}g++, ${ac_build_prefix}g++)
 314   if test -z "$BUILD_CXX"; then
 315      AC_CHECK_PROG(BUILD_CXX, g++, g++)
 316      if test -z "$BUILD_CXX"; then
 317        AC_CHECK_PROG(BUILD_CXX, c++, c++, , , /usr/ucb/c++)
 318      fi
 319   fi
 320 else
 321   AC_SUBST(LLVM_CROSS_COMPILING, [0])
 322 fi
 323
 324 dnl Check to see if there's a "CVS" (or .svn or .git) directory indicating
 325 dnl that this build is being done from a checkout. This sets up several
 326 dnl defaults for the command line switches. When we build with a CVS directory,
 327 dnl we get a debug with assertions turned on. Without, we assume a source
 328 dnl release and we get an optimized build without assertions.
 329 dnl See --enable-optimized and --enable-assertions below
 330 if test -d "CVS" -o -d "${srcdir}/CVS" -o -d ".svn" -o -d "${srcdir}/.svn" -o -d ".git" -o -d "${srcdir}/.git"; then
 331   cvsbuild="yes"
 332   optimize="no"
 333   AC_SUBST(CVSBUILD,[[CVSBUILD=1]])
 334 else
 335   cvsbuild="no"
 336   optimize="yes"
 337 fi
 338
 339 dnl===-----------------------------------------------------------------------===
 340 dnl===
 341 dnl=== SECTION 3: Command line arguments for the configure script.
 342 dnl===
 343 dnl===-----------------------------------------------------------------------===
 344
 345 dnl --enable-optimized : check whether they want to do an optimized build:
 346 AC_ARG_ENABLE(optimized, AS_HELP_STRING(
 347  --enable-optimized,[Compile with optimizations enabled (default is NO)]),,enableval=$optimize)
 348 if test ${enableval} = "no" ; then
 349   AC_SUBST(ENABLE_OPTIMIZED,[[]])
 350 else
 351   AC_SUBST(ENABLE_OPTIMIZED,[[ENABLE_OPTIMIZED=1]])
 352 fi
 353
 354 dnl --enable-profiling : check whether they want to do a profile build:
 355 AC_ARG_ENABLE(profiling, AS_HELP_STRING(
 356  --enable-profiling,[Compile with profiling enabled (default is NO)]),,enableval="no")
 357 if test ${enableval} = "no" ; then
 358   AC_SUBST(ENABLE_PROFILING,[[]])
 359 else
 360   AC_SUBST(ENABLE_PROFILING,[[ENABLE_PROFILING=1]])
 361 fi
 362
 363 dnl --enable-assertions : check whether they want to turn on assertions or not:
 364 AC_ARG_ENABLE(assertions,AS_HELP_STRING(
 365   --enable-assertions,[Compile with assertion checks enabled (default is YES)]),, enableval="yes")
 366 if test ${enableval} = "yes" ; then
 367   AC_SUBST(DISABLE_ASSERTIONS,[[]])
 368 else
 369   AC_SUBST(DISABLE_ASSERTIONS,[[DISABLE_ASSERTIONS=1]])
 370 fi
 371
 372 dnl --enable-expensive-checks : check whether they want to turn on expensive debug checks:
 373 AC_ARG_ENABLE(expensive-checks,AS_HELP_STRING(
 374   --enable-expensive-checks,[Compile with expensive debug checks enabled (default is NO)]),, enableval="no")
 375 if test ${enableval} = "yes" ; then
 376   AC_SUBST(ENABLE_EXPENSIVE_CHECKS,[[ENABLE_EXPENSIVE_CHECKS=1]])
 377   AC_SUBST(EXPENSIVE_CHECKS,[[yes]])
 378 else
 379   AC_SUBST(ENABLE_EXPENSIVE_CHECKS,[[]])
 380   AC_SUBST(EXPENSIVE_CHECKS,[[no]])
 381 fi
 382
 383 dnl --enable-debug-runtime : should runtime libraries have debug symbols?
 384 AC_ARG_ENABLE(debug-runtime,
 385    AS_HELP_STRING(--enable-debug-runtime,[Build runtime libs with debug symbols (default is NO)]),,enableval=no)
 386 if test ${enableval} = "no" ; then
 387   AC_SUBST(DEBUG_RUNTIME,[[]])
 388 else
 389   AC_SUBST(DEBUG_RUNTIME,[[DEBUG_RUNTIME=1]])
 390 fi
 391
 392 dnl --enable-debug-symbols : should even optimized compiler libraries
 393 dnl have debug symbols?
 394 AC_ARG_ENABLE(debug-symbols,
 395    AS_HELP_STRING(--enable-debug-symbols,[Build compiler with debug symbols (default is NO if optimization is on and YES if it's off)]),,enableval=no)
 396 if test ${enableval} = "no" ; then
 397   AC_SUBST(DEBUG_SYMBOLS,[[]])
 398 else
 399   AC_SUBST(DEBUG_SYMBOLS,[[DEBUG_SYMBOLS=1]])
 400 fi
 401
 402 dnl --enable-jit: check whether they want to enable the jit
 403 AC_ARG_ENABLE(jit,
 404   AS_HELP_STRING(--enable-jit,
 405                  [Enable Just In Time Compiling (default is YES)]),,
 406   enableval=default)
 407 if test ${enableval} = "no"
 408 then
 409   AC_SUBST(JIT,[[]])
 410 else
 411   case "$llvm_cv_target_arch" in
 412     x86)         AC_SUBST(TARGET_HAS_JIT,1) ;;
 413     Sparc)       AC_SUBST(TARGET_HAS_JIT,0) ;;
 414     PowerPC)     AC_SUBST(TARGET_HAS_JIT,1) ;;
 415     x86_64)      AC_SUBST(TARGET_HAS_JIT,1) ;;
 416     Alpha)       AC_SUBST(TARGET_HAS_JIT,1) ;;
 417     ARM)         AC_SUBST(TARGET_HAS_JIT,1) ;;
 418     Mips)        AC_SUBST(TARGET_HAS_JIT,0) ;;
 419     PIC16)       AC_SUBST(TARGET_HAS_JIT,0) ;;
 420     XCore)       AC_SUBST(TARGET_HAS_JIT,0) ;;
 421     MSP430)      AC_SUBST(TARGET_HAS_JIT,0) ;;
 422     SystemZ)     AC_SUBST(TARGET_HAS_JIT,0) ;;
 423     Blackfin)    AC_SUBST(TARGET_HAS_JIT,0) ;;
 424     *)           AC_SUBST(TARGET_HAS_JIT,0) ;;
 425   esac
 426 fi
 427
 428 dnl Allow enablement of doxygen generated documentation
 429 AC_ARG_ENABLE(doxygen,
 430               AS_HELP_STRING([--enable-doxygen],
 431                              [Build doxygen documentation (default is NO)]),,
 432                              enableval=default)
 433 case "$enableval" in
 434   yes) AC_SUBST(ENABLE_DOXYGEN,[1]) ;;
 435   no)  AC_SUBST(ENABLE_DOXYGEN,[0]) ;;
 436   default) AC_SUBST(ENABLE_DOXYGEN,[0]) ;;
 437   *) AC_MSG_ERROR([Invalid setting for --enable-doxygen. Use "yes" or "no"]) ;;
 438 esac
 439
 440 dnl Allow disablement of threads
 441 AC_ARG_ENABLE(threads,
 442               AS_HELP_STRING([--enable-threads],
 443                              [Use threads if available (default is YES)]),,
 444                              enableval=default)
 445 case "$enableval" in
 446   yes) AC_SUBST(ENABLE_THREADS,[1]) ;;
 447   no)  AC_SUBST(ENABLE_THREADS,[0]) ;;
 448   default) AC_SUBST(ENABLE_THREADS,[1]) ;;
 449   *) AC_MSG_ERROR([Invalid setting for --enable-threads. Use "yes" or "no"]) ;;
 450 esac
 451 AC_DEFINE_UNQUOTED([ENABLE_THREADS],$ENABLE_THREADS,[Define if threads enabled])
 452
 453 dnl Allow building without position independent code
 454 AC_ARG_ENABLE(pic,
 455   AS_HELP_STRING([--enable-pic],
 456                  [Build LLVM with Position Independent Code (default is YES)]),,
 457                  enableval=default)
 458 case "$enableval" in
 459   yes) AC_SUBST(ENABLE_PIC,[1]) ;;
 460   no)  AC_SUBST(ENABLE_PIC,[0]) ;;
 461   default) AC_SUBST(ENABLE_PIC,[1]) ;;
 462   *) AC_MSG_ERROR([Invalid setting for --enable-pic. Use "yes" or "no"]) ;;
 463 esac
 464 AC_DEFINE_UNQUOTED([ENABLE_PIC],$ENABLE_PIC,
 465                    [Define if position independent code is enabled])
 466
 467 dnl Allow specific targets to be specified for building (or not)
 468 TARGETS_TO_BUILD=""
 469 AC_ARG_ENABLE([targets],AS_HELP_STRING([--enable-targets],
 470     [Build specific host targets: all or target1,target2,... Valid targets are:
 471      host, x86, x86_64, sparc, powerpc, alpha, arm, mips, spu, pic16,
 472      xcore, msp430, systemz, blackfin, cbe, msil, and cpp (default=all)]),,
 473     enableval=all)
 474 if test "$enableval" = host-only ; then
 475   enableval=host
 476 fi
 477 case "$enableval" in
 478   all) TARGETS_TO_BUILD="X86 Sparc PowerPC Alpha ARM Mips CellSPU PIC16 XCore MSP430 SystemZ Blackfin CBackend MSIL CppBackend" ;;
 479   *)for a_target in `echo $enableval|sed -e 's/,/ /g' ` ; do
 480       case "$a_target" in
 481         x86)      TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 482         x86_64)   TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 483         sparc)    TARGETS_TO_BUILD="Sparc $TARGETS_TO_BUILD" ;;
 484         powerpc)  TARGETS_TO_BUILD="PowerPC $TARGETS_TO_BUILD" ;;
 485         alpha)    TARGETS_TO_BUILD="Alpha $TARGETS_TO_BUILD" ;;
 486         arm)      TARGETS_TO_BUILD="ARM $TARGETS_TO_BUILD" ;;
 487         mips)     TARGETS_TO_BUILD="Mips $TARGETS_TO_BUILD" ;;
 488         spu)      TARGETS_TO_BUILD="CellSPU $TARGETS_TO_BUILD" ;;
 489         pic16)    TARGETS_TO_BUILD="PIC16 $TARGETS_TO_BUILD" ;;
 490         xcore)    TARGETS_TO_BUILD="XCore $TARGETS_TO_BUILD" ;;
 491         msp430)   TARGETS_TO_BUILD="MSP430 $TARGETS_TO_BUILD" ;;
 492         systemz)  TARGETS_TO_BUILD="SystemZ $TARGETS_TO_BUILD" ;;
 493         blackfin) TARGETS_TO_BUILD="Blackfin $TARGETS_TO_BUILD" ;;
 494         cbe)      TARGETS_TO_BUILD="CBackend $TARGETS_TO_BUILD" ;;
 495         msil)     TARGETS_TO_BUILD="MSIL $TARGETS_TO_BUILD" ;;
 496         cpp)      TARGETS_TO_BUILD="CppBackend $TARGETS_TO_BUILD" ;;
 497         host) case "$llvm_cv_target_arch" in
 498             x86)         TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 499             x86_64)      TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 500             Sparc)       TARGETS_TO_BUILD="Sparc $TARGETS_TO_BUILD" ;;
 501             PowerPC)     TARGETS_TO_BUILD="PowerPC $TARGETS_TO_BUILD" ;;
 502             Alpha)       TARGETS_TO_BUILD="Alpha $TARGETS_TO_BUILD" ;;
 503             ARM)         TARGETS_TO_BUILD="ARM $TARGETS_TO_BUILD" ;;
 504             Mips)        TARGETS_TO_BUILD="Mips $TARGETS_TO_BUILD" ;;
 505             CellSPU|SPU) TARGETS_TO_BUILD="CellSPU $TARGETS_TO_BUILD" ;;
 506             PIC16)       TARGETS_TO_BUILD="PIC16 $TARGETS_TO_BUILD" ;;
 507             XCore)       TARGETS_TO_BUILD="XCore $TARGETS_TO_BUILD" ;;
 508             MSP430)      TARGETS_TO_BUILD="MSP430 $TARGETS_TO_BUILD" ;;
 509             SystemZ)     TARGETS_TO_BUILD="SystemZ $TARGETS_TO_BUILD" ;;
 510             Blackfin)    TARGETS_TO_BUILD="Blackfin $TARGETS_TO_BUILD" ;;
 511             *)       AC_MSG_ERROR([Can not set target to build]) ;;
 512           esac ;;
 513         *) AC_MSG_ERROR([Unrecognized target $a_target]) ;;
 514       esac
 515   done
 516   ;;
 517 esac
 518 AC_SUBST(TARGETS_TO_BUILD,$TARGETS_TO_BUILD)
 519
 520 # Determine whether we are building LLVM support for the native architecture.
 521 # If so, define LLVM_NATIVE_ARCH to that LLVM target.
 522 for a_target in $TARGETS_TO_BUILD; do
 523   if test "$a_target" = "$LLVM_NATIVE_ARCH"; then
 524     LLVM_NATIVE_ARCHTARGET="${LLVM_NATIVE_ARCH}Target"
 525     AC_DEFINE_UNQUOTED(LLVM_NATIVE_ARCH,$LLVM_NATIVE_ARCHTARGET,
 526       [LLVM architecture name for the native architecture, if available])
 527   fi
 528 done
 529
 530 # Build the LLVM_TARGET and LLVM_ASM_PRINTER macro uses for
 531 # Targets.def, AsmPrinters.def, and AsmParsers.def.
 532 LLVM_ENUM_TARGETS=""
 533 LLVM_ENUM_ASM_PRINTERS=""
 534 LLVM_ENUM_ASM_PARSERS=""
 535 for target_to_build in $TARGETS_TO_BUILD; do
 536   LLVM_ENUM_TARGETS="LLVM_TARGET($target_to_build) $LLVM_ENUM_TARGETS"
 537   if test -f ${srcdir}/lib/Target/${target_to_build}/AsmPrinter/Makefile ; then
 538     LLVM_ENUM_ASM_PRINTERS="LLVM_ASM_PRINTER($target_to_build) $LLVM_ENUM_ASM_PRINTERS";
 539   fi
 540   if test -f ${srcdir}/lib/Target/${target_to_build}/AsmParser/Makefile ; then
 541     LLVM_ENUM_ASM_PARSERS="LLVM_ASM_PARSER($target_to_build) $LLVM_ENUM_ASM_PARSERS";
 542   fi
 543 done
 544 AC_SUBST(LLVM_ENUM_TARGETS)
 545 AC_SUBST(LLVM_ENUM_ASM_PRINTERS)
 546 AC_SUBST(LLVM_ENUM_ASM_PARSERS)
 547
 548 dnl Prevent the CBackend from using printf("%a") for floating point so older
 549 dnl C compilers that cannot deal with the 0x0p+0 hex floating point format
 550 dnl can still compile the CBE's output
 551 AC_ARG_ENABLE([cbe-printf-a],AS_HELP_STRING([--enable-cbe-printf-a],
 552   [Enable C Backend output with hex floating point via %a  (default is YES)]),,
 553   enableval=default)
 554 case "$enableval" in
 555   yes) AC_SUBST(ENABLE_CBE_PRINTF_A,[1]) ;;
 556   no)  AC_SUBST(ENABLE_CBE_PRINTF_A,[0]) ;;
 557   default)  AC_SUBST(ENABLE_CBE_PRINTF_A,[1]) ;;
 558   *) AC_MSG_ERROR([Invalid setting for --enable-cbe-printf-a. Use "yes" or "no"]) ;;
 559 esac
 560 AC_DEFINE_UNQUOTED([ENABLE_CBE_PRINTF_A],$ENABLE_CBE_PRINTF_A,
 561                    [Define if CBE is enabled for printf %a output])
 562
 563 dnl Allow a specific llvm-gcc/llvm-g++ pair to be used with this LLVM config.
 564 AC_ARG_WITH(llvmgccdir,
 565   AS_HELP_STRING([--with-llvmgccdir],
 566     [Specify location of llvm-gcc install dir (default searches PATH)]),,
 567     withval=default)
 568 case "$withval" in
 569   default) WITH_LLVMGCCDIR=default ;;
 570   /* | [[A-Za-z]]:[[\\/]]*)      WITH_LLVMGCCDIR=$withval ;;
 571   *) AC_MSG_ERROR([Invalid path for --with-llvmgccdir. Provide full path]) ;;
 572 esac
 573
 574 dnl Allow a specific llvm-gcc compiler to be used with this LLVM config.
 575 AC_ARG_WITH(llvmgcc,
 576   AS_HELP_STRING([--with-llvmgcc],
 577     [Specify location of llvm-gcc driver (default searches PATH)]),
 578     LLVMGCC=$with_llvmgcc
 579       WITH_LLVMGCCDIR="",)
 580
 581 dnl Allow a specific llvm-g++ compiler to be used with this LLVM config.
 582 AC_ARG_WITH(llvmgxx,
 583   AS_HELP_STRING([--with-llvmgxx],
 584     [Specify location of llvm-g++ driver (default searches PATH)]),
 585     LLVMGXX=$with_llvmgxx
 586     WITH_LLVMGCCDIR="",)
 587
 588 if test -n "$LLVMGCC"; then
 589    LLVMGCCCOMMAND="$LLVMGCC"
 590 fi
 591
 592 if test -n "$LLVMGXX"; then
 593    LLVMGXXCOMMAND="$LLVMGXX"
 594 fi
 595
 596 if test -n "$LLVMGCC" && test -z "$LLVMGXX"; then
 597    AC_MSG_ERROR([Invalid llvm-g++. Use --with-llvmgxx when --with-llvmgcc is used]);
 598 fi
 599
 600 if test -n "$LLVMGXX" && test -z "$LLVMGCC"; then
 601    AC_MSG_ERROR([Invalid llvm-gcc. Use --with-llvmgcc when --with-llvmgxx is used]);
 602 fi
 603
 604 dnl Specify extra build options
 605 AC_ARG_WITH(extra-options,
 606   AS_HELP_STRING([--with-extra-options],
 607                  [Specify additional options to compile LLVM with]),,
 608                  withval=default)
 609 case "$withval" in
 610   default) EXTRA_OPTIONS= ;;
 611   *) EXTRA_OPTIONS=$withval ;;
 612 esac
 613 AC_SUBST(EXTRA_OPTIONS,$EXTRA_OPTIONS)
 614
 615 dnl Allow specific bindings to be specified for building (or not)
 616 AC_ARG_ENABLE([bindings],AS_HELP_STRING([--enable-bindings],
 617     [Build specific language bindings: all,auto,none,{binding-name} (default=auto)]),,
 618     enableval=default)
 619 BINDINGS_TO_BUILD=""
 620 case "$enableval" in
 621   yes | default | auto) BINDINGS_TO_BUILD="auto" ;;
 622   all ) BINDINGS_TO_BUILD="ocaml" ;;
 623   none | no) BINDINGS_TO_BUILD="" ;;
 624   *)for a_binding in `echo $enableval|sed -e 's/,/ /g' ` ; do
 625       case "$a_binding" in
 626         ocaml) BINDINGS_TO_BUILD="ocaml $BINDINGS_TO_BUILD" ;;
 627         *) AC_MSG_ERROR([Unrecognized binding $a_binding]) ;;
 628       esac
 629   done
 630   ;;
 631 esac
 632
 633 dnl Allow the ocaml libdir to be overridden. This could go in a configure
 634 dnl script for bindings/ocaml/configure, except that its auto value depends on
 635 dnl OCAMLC, which is found here to support tests.
 636 AC_ARG_WITH([ocaml-libdir],
 637   [AS_HELP_STRING([--with-ocaml-libdir],
 638     [Specify install location for ocaml bindings (default is stdlib)])],
 639   [],
 640   [withval=auto])
 641 case "$withval" in
 642   auto) with_ocaml_libdir="$withval" ;;
 643   /* | [[A-Za-z]]:[[\\/]]*) with_ocaml_libdir="$withval" ;;
 644   *) AC_MSG_ERROR([Invalid path for --with-ocaml-libdir. Provide full path]) ;;
 645 esac
 646
 647 dnl Allow linking of LLVM with GPLv3 binutils code.
 648 AC_ARG_WITH(binutils-include,
 649   AS_HELP_STRING([--with-binutils-include],
 650     [Specify path to binutils/include/ containing plugin-api.h file for gold plugin.]),,
 651   withval=default)
 652 case "$withval" in
 653   default) WITH_BINUTILS_INCDIR=default ;;
 654   /* | [[A-Za-z]]:[[\\/]]*)      WITH_BINUTILS_INCDIR=$withval ;;
 655   *) AC_MSG_ERROR([Invalid path for --with-binutils-include. Provide full path]) ;;
 656 esac
 657 if test "x$WITH_BINUTILS_INCDIR" != xdefault ; then
 658   AC_SUBST(BINUTILS_INCDIR,$WITH_BINUTILS_INCDIR)
 659   if test ! -f "$WITH_BINUTILS_INCDIR/plugin-api.h"; then
 660      echo "$WITH_BINUTILS_INCDIR/plugin-api.h"
 661      AC_MSG_ERROR([Invalid path to directory containing plugin-api.h.]);
 662   fi
 663 fi
 664
 665 dnl --enable-libffi : check whether the user wants to turn off libffi:
 666 AC_ARG_ENABLE(libffi,AS_HELP_STRING(
 667   --enable-libffi,[Check for the presence of libffi (default is YES)]),,
 668   enableval=yes)
 669 case "$enableval" in
 670   yes) llvm_cv_enable_libffi="yes" ;;
 671   no)  llvm_cv_enable_libffi="no"  ;;
 672   *) AC_MSG_ERROR([Invalid setting for --enable-libffi. Use "yes" or "no"]) ;;
 673 esac
 674
 675 dnl Only Windows needs dynamic libCompilerDriver to support plugins.
 676 if test "$llvm_cv_os_type" = "Win32" ; then
 677    llvmc_dynamic="yes"
 678 else
 679    llvmc_dynamic="no"
 680 fi
 681
 682 dnl --enable-llvmc-dynamic : should LLVMC link libCompilerDriver dynamically?
 683 AC_ARG_ENABLE(llvmc-dynamic,AS_HELP_STRING(
 684 --enable-llvmc-dynamic,
 685 [Link LLVMC dynamically (default is NO, unless on Win32)]),,
 686 enableval=$llvmc_dynamic)
 687 if test ${enableval} = "yes" && test "$ENABLE_PIC" -eq 1 ; then
 688    AC_SUBST(ENABLE_LLVMC_DYNAMIC,[[ENABLE_LLVMC_DYNAMIC=1]])
 689 else
 690    AC_SUBST(ENABLE_LLVMC_DYNAMIC,[[]])
 691 fi
 692
 693 dnl --enable-llvmc-dynamic-plugins : should LLVMC support dynamic plugins?
 694 AC_ARG_ENABLE(llvmc-dynamic-plugins,AS_HELP_STRING(
 695 --enable-llvmc-dynamic-plugins,
 696 [Enable dynamic LLVMC plugins (default is YES)]),,
 697 enableval=yes)
 698 if test ${enableval} = "yes" ; then
 699    AC_SUBST(ENABLE_LLVMC_DYNAMIC_PLUGINS,[[ENABLE_LLVMC_DYNAMIC_PLUGINS=1]])
 700 else
 701    AC_SUBST(ENABLE_LLVMC_DYNAMIC_PLUGINS,[[]])
 702 fi
 703
 704 dnl===-----------------------------------------------------------------------===
 705 dnl===
 706 dnl=== SECTION 4: Check for programs we need and that they are the right version
 707 dnl===
 708 dnl===-----------------------------------------------------------------------===
 709
 710 dnl Check for compilation tools
 711 AC_PROG_CPP
 712 AC_PROG_CC(gcc)
 713 AC_PROG_CXX(g++)
 714
 715 AC_PROG_NM
 716 AC_SUBST(NM)
 717
 718 dnl Check for the tools that the makefiles require
 719 AC_CHECK_GNU_MAKE
 720 AC_PROG_LN_S
 721 AC_PATH_PROG(CMP, [cmp], [cmp])
 722 AC_PATH_PROG(CP, [cp], [cp])
 723 AC_PATH_PROG(DATE, [date], [date])
 724 AC_PATH_PROG(FIND, [find], [find])
 725 AC_PATH_PROG(GREP, [grep], [grep])
 726 AC_PATH_PROG(MKDIR,[mkdir],[mkdir])
 727 AC_PATH_PROG(MV,   [mv],   [mv])
 728 AC_PROG_RANLIB
 729 AC_PATH_PROG(RM,   [rm],   [rm])
 730 AC_PATH_PROG(SED,  [sed],  [sed])
 731 AC_PATH_PROG(TAR,  [tar],  [gtar])
 732 AC_PATH_PROG(BINPWD,[pwd],  [pwd])
 733
 734 dnl Looking for misc. graph plotting software
 735 AC_PATH_PROG(GRAPHVIZ, [Graphviz], [echo Graphviz])
 736 if test "$GRAPHVIZ" != "echo Graphviz" ; then
 737   AC_DEFINE([HAVE_GRAPHVIZ],[1],[Define if the Graphviz program is available])
 738   dnl If we're targeting for mingw we should emit windows paths, not msys
 739   if test "$llvm_cv_os_type" = "MingW" ; then
 740     GRAPHVIZ=`echo $GRAPHVIZ | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 741   fi
 742   AC_DEFINE_UNQUOTED([LLVM_PATH_GRAPHVIZ],"$GRAPHVIZ${EXEEXT}",
 743    [Define to path to Graphviz program if found or 'echo Graphviz' otherwise])
 744 fi
 745 AC_PATH_PROG(DOT, [dot], [echo dot])
 746 if test "$DOT" != "echo dot" ; then
 747   AC_DEFINE([HAVE_DOT],[1],[Define if the dot program is available])
 748   dnl If we're targeting for mingw we should emit windows paths, not msys
 749   if test "$llvm_cv_os_type" = "MingW" ; then
 750     DOT=`echo $DOT | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 751   fi
 752   AC_DEFINE_UNQUOTED([LLVM_PATH_DOT],"$DOT${EXEEXT}",
 753    [Define to path to dot program if found or 'echo dot' otherwise])
 754 fi
 755 AC_PATH_PROG(FDP, [fdp], [echo fdp])
 756 if test "$FDP" != "echo fdp" ; then
 757   AC_DEFINE([HAVE_FDP],[1],[Define if the neat program is available])
 758   dnl If we're targeting for mingw we should emit windows paths, not msys
 759   if test "$llvm_cv_os_type" = "MingW" ; then
 760     FDP=`echo $FDP | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 761   fi
 762   AC_DEFINE_UNQUOTED([LLVM_PATH_FDP],"$FDP${EXEEXT}",
 763    [Define to path to fdp program if found or 'echo fdp' otherwise])
 764 fi
 765 AC_PATH_PROG(NEATO, [neato], [echo neato])
 766 if test "$NEATO" != "echo neato" ; then
 767   AC_DEFINE([HAVE_NEATO],[1],[Define if the neat program is available])
 768   dnl If we're targeting for mingw we should emit windows paths, not msys
 769   if test "$llvm_cv_os_type" = "MingW" ; then
 770     NEATO=`echo $NEATO | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 771   fi
 772   AC_DEFINE_UNQUOTED([LLVM_PATH_NEATO],"$NEATO${EXEEXT}",
 773    [Define to path to neato program if found or 'echo neato' otherwise])
 774 fi
 775 AC_PATH_PROG(TWOPI, [twopi], [echo twopi])
 776 if test "$TWOPI" != "echo twopi" ; then
 777   AC_DEFINE([HAVE_TWOPI],[1],[Define if the neat program is available])
 778   dnl If we're targeting for mingw we should emit windows paths, not msys
 779   if test "$llvm_cv_os_type" = "MingW" ; then
 780     TWOPI=`echo $TWOPI | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 781   fi
 782   AC_DEFINE_UNQUOTED([LLVM_PATH_TWOPI],"$TWOPI${EXEEXT}",
 783    [Define to path to twopi program if found or 'echo twopi' otherwise])
 784 fi
 785 AC_PATH_PROG(CIRCO, [circo], [echo circo])
 786 if test "$CIRCO" != "echo circo" ; then
 787   AC_DEFINE([HAVE_CIRCO],[1],[Define if the neat program is available])
 788   dnl If we're targeting for mingw we should emit windows paths, not msys
 789   if test "$llvm_cv_os_type" = "MingW" ; then
 790     CIRCO=`echo $CIRCO | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 791   fi
 792   AC_DEFINE_UNQUOTED([LLVM_PATH_CIRCO],"$CIRCO${EXEEXT}",
 793    [Define to path to circo program if found or 'echo circo' otherwise])
 794 fi
 795 AC_PATH_PROGS(GV, [gv gsview32], [echo gv])
 796 if test "$GV" != "echo gv" ; then
 797   AC_DEFINE([HAVE_GV],[1],[Define if the gv program is available])
 798   dnl If we're targeting for mingw we should emit windows paths, not msys
 799   if test "$llvm_cv_os_type" = "MingW" ; then
 800     GV=`echo $GV | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 801   fi
 802   AC_DEFINE_UNQUOTED([LLVM_PATH_GV],"$GV${EXEEXT}",
 803    [Define to path to gv program if found or 'echo gv' otherwise])
 804 fi
 805 AC_PATH_PROG(DOTTY, [dotty], [echo dotty])
 806 if test "$DOTTY" != "echo dotty" ; then
 807   AC_DEFINE([HAVE_DOTTY],[1],[Define if the dotty program is available])
 808   dnl If we're targeting for mingw we should emit windows paths, not msys
 809   if test "$llvm_cv_os_type" = "MingW" ; then
 810     DOTTY=`echo $DOTTY | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 811   fi
 812   AC_DEFINE_UNQUOTED([LLVM_PATH_DOTTY],"$DOTTY${EXEEXT}",
 813    [Define to path to dotty program if found or 'echo dotty' otherwise])
 814 fi
 815
 816 dnl Look for a sufficiently recent version of Perl.
 817 LLVM_PROG_PERL([5.006])
 818 AC_SUBST(PERL)
 819 if test x"$PERL" = xnone; then
 820    AC_SUBST(HAVE_PERL,0)
 821    AC_MSG_ERROR([perl is required but was not found, please install it])
 822 else
 823    AC_SUBST(HAVE_PERL,1)
 824 fi
 825
 826 dnl Find the install program
 827 AC_PROG_INSTALL
 828
 829 dnl Checks for documentation and testing tools that we can do without. If these
 830 dnl are not found then they are set to "true" which always succeeds but does
 831 dnl nothing. This just lets the build output show that we could have done
 832 dnl something if the tool was available.
 833 AC_PATH_PROG(BZIP2, [bzip2])
 834 AC_PATH_PROG(DOXYGEN, [doxygen])
 835 AC_PATH_PROG(GROFF, [groff])
 836 AC_PATH_PROG(GZIP, [gzip])
 837 AC_PATH_PROG(POD2HTML, [pod2html])
 838 AC_PATH_PROG(POD2MAN, [pod2man])
 839 AC_PATH_PROG(RUNTEST, [runtest])
 840 DJ_AC_PATH_TCLSH
 841 AC_PATH_PROG(ZIP, [zip])
 842 AC_PATH_PROGS(OCAMLC, [ocamlc])
 843 AC_PATH_PROGS(OCAMLOPT, [ocamlopt])
 844 AC_PATH_PROGS(OCAMLDEP, [ocamldep])
 845 AC_PATH_PROGS(OCAMLDOC, [ocamldoc])
 846 AC_PATH_PROGS(GAS, [gas as])
 847
 848 dnl Determine whether the linker supports the -R option.
 849 AC_LINK_USE_R
 850
 851 dnl Determine whether the linker supports the -export-dynamic option.
 852 AC_LINK_EXPORT_DYNAMIC
 853
 854 dnl Check for libtool and the library that has dlopen function (which must come
 855 dnl before the AC_PROG_LIBTOOL check in order to enable dlopening libraries with
 856 dnl libtool).
 857 AC_LIBTOOL_DLOPEN
 858 AC_LIB_LTDL
 859 AC_PROG_LIBTOOL
 860
 861 if test "$lt_cv_dlopen_self" = "yes" ; then
 862   AC_DEFINE([CAN_DLOPEN_SELF],[1],
 863               [Define if dlopen(0) will open the symbols of the program])
 864 fi
 865
 866
 867 if test "$WITH_LLVMGCCDIR" = "default" ; then
 868   LLVMGCC="llvm-gcc${EXEEXT}"
 869   LLVMGXX="llvm-g++${EXEEXT}"
 870   LLVMGCCCOMMAND="$LLVMGCC"
 871   LLVMGXXCOMMAND="$LLVMGXX"
 872   AC_SUBST(LLVMGCCCOMMAND,$LLVMGCCCOMMAND)
 873   AC_SUBST(LLVMGXXCOMMAND,$LLVMGXXCOMMAND)
 874   AC_PATH_PROG(LLVMGCC, $LLVMGCC, [])
 875   AC_PATH_PROG(LLVMGXX, $LLVMGXX, [])
 876 else
 877   if test -z "$LLVMGCC"; then
 878     LLVMGCC="$WITH_LLVMGCCDIR/bin/llvm-gcc${EXEEXT}"
 879     LLVMGCCCOMMAND="$LLVMGCC"
 880   fi
 881   if test -z "$LLVMGXX"; then
 882     LLVMGXX="$WITH_LLVMGCCDIR/bin/llvm-g++${EXEEXT}"
 883     LLVMGXXCOMMAND="$LLVMGXX"
 884   fi
 885
 886   AC_SUBST(LLVMGCC,$LLVMGCC)
 887   AC_SUBST(LLVMGXX,$LLVMGXX)
 888   AC_SUBST(LLVMGCCCOMMAND,$LLVMGCCCOMMAND)
 889   AC_SUBST(LLVMGXXCOMMAND,$LLVMGXXCOMMAND)
 890 fi
 891
 892
 893 AC_MSG_CHECKING([tool compatibility])
 894
 895 dnl Ensure that compilation tools are GCC or a GNU compatible compiler such as
 896 dnl ICC; we use GCC specific options in the makefiles so the compiler needs
 897 dnl to support those options.
 898 dnl "icc" emits gcc signatures
 899 dnl "icc -no-gcc" emits no gcc signature BUT is still compatible
 900 ICC=no
 901 IXX=no
 902 case $CC in
 903   icc*|icpc*)
 904     ICC=yes
 905     IXX=yes
 906     ;;
 907    *)
 908     ;;
 909 esac
 910
 911 if test "$GCC" != "yes" && test "$ICC" != "yes"
 912 then
 913   AC_MSG_ERROR([gcc|icc required but not found])
 914 fi
 915
 916 dnl Ensure that compilation tools are GCC; we use GCC specific extensions
 917 if test "$GXX" != "yes" && test "$IXX" != "yes"
 918 then
 919   AC_MSG_ERROR([g++|icc required but not found])
 920 fi
 921
 922 dnl Verify that GCC is version 3.0 or higher
 923 if test "$GCC" = "yes"
 924 then
 925   AC_COMPILE_IFELSE([[#if !defined(__GNUC__) || __GNUC__ < 3
 926 #error Unsupported GCC version
 927 #endif
 928 ]], [], [AC_MSG_ERROR([gcc 3.x required, but you have a lower version])])
 929 fi
 930
 931 dnl Check for GNU Make.  We use its extensions, so don't build without it
 932 if test -z "$llvm_cv_gnu_make_command"
 933 then
 934   AC_MSG_ERROR([GNU Make required but not found])
 935 fi
 936
 937 dnl Tool compatibility is okay if we make it here.
 938 AC_MSG_RESULT([ok])
 939
 940 dnl===-----------------------------------------------------------------------===
 941 dnl===
 942 dnl=== SECTION 5: Check for libraries
 943 dnl===
 944 dnl===-----------------------------------------------------------------------===
 945
 946 AC_CHECK_LIB(m,sin)
 947 if test "$llvm_cv_os_type" = "MingW" ; then
 948   AC_CHECK_LIB(imagehlp, main)
 949   AC_CHECK_LIB(psapi, main)
 950 fi
 951
 952 dnl dlopen() is required for plugin support.
 953 AC_SEARCH_LIBS(dlopen,dl,AC_DEFINE([HAVE_DLOPEN],[1],
 954                [Define if dlopen() is available on this platform.]),
 955                AC_MSG_WARN([dlopen() not found - disabling plugin support]))
 956
 957 dnl libffi is optional; used to call external functions from the interpreter
 958 if test "$llvm_cv_enable_libffi" = "yes" ; then
 959   AC_SEARCH_LIBS(ffi_call,ffi,AC_DEFINE([HAVE_FFI_CALL],[1],
 960                  [Define if libffi is available on this platform.]),
 961                  AC_MSG_WARN([libffi not found - disabling external calls from interpreter]))
 962 fi
 963
 964 dnl mallinfo is optional; the code can compile (minus features) without it
 965 AC_SEARCH_LIBS(mallinfo,malloc,AC_DEFINE([HAVE_MALLINFO],[1],
 966                [Define if mallinfo() is available on this platform.]))
 967
 968 dnl pthread locking functions are optional - but llvm will not be thread-safe
 969 dnl without locks.
 970 if test "$ENABLE_THREADS" -eq 1 ; then
 971   AC_CHECK_LIB(pthread,pthread_mutex_init)
 972   AC_SEARCH_LIBS(pthread_mutex_lock,pthread,
 973                  AC_DEFINE([HAVE_PTHREAD_MUTEX_LOCK],[1],
 974                            [Have pthread_mutex_lock]))
 975   AC_SEARCH_LIBS(pthread_rwlock_init,pthread,
 976                  AC_DEFINE([HAVE_PTHREAD_RWLOCK_INIT],[1],
 977                  [Have pthread_rwlock_init]))
 978   AC_SEARCH_LIBS(pthread_getspecific,pthread,
 979                  AC_DEFINE([HAVE_PTHREAD_GETSPECIFIC],[1],
 980                  [Have pthread_getspecific]))
 981 fi
 982
 983 dnl Allow extra x86-disassembler library
 984 AC_ARG_WITH(udis86,
 985   AS_HELP_STRING([--with-udis86=<path>],
 986     [Use udis86 external x86 disassembler library]),
 987     [
 988       AC_SUBST(USE_UDIS86, [1])
 989       case "$withval" in
 990         /usr/lib|yes) ;;
 991         *) LDFLAGS="$LDFLAGS -L${withval}" ;;
 992       esac
 993       AC_CHECK_LIB(udis86, ud_init, [], [
 994         echo "Error! You need to have libudis86 around."
 995         exit -1
 996       ])
 997     ],
 998     AC_SUBST(USE_UDIS86, [0]))
 999 AC_DEFINE_UNQUOTED([USE_UDIS86],$USE_UDIS86,
1000                    [Define if use udis86 library])
1001
1002 dnl Allow OProfile support for JIT output.
1003 AC_ARG_WITH(oprofile,
1004   AS_HELP_STRING([--with-oprofile=<prefix>],
1005     [Tell OProfile >= 0.9.4 how to symbolize JIT output]),
1006     [
1007       AC_SUBST(USE_OPROFILE, [1])
1008       case "$withval" in
1009         /usr|yes) llvm_cv_oppath=/usr/lib/oprofile ;;
1010         *) llvm_cv_oppath="${withval}/lib/oprofile"
1011            CPPFLAGS="-I${withval}/include";;
1012       esac
1013       LIBS="$LIBS -L${llvm_cv_oppath} -Wl,-rpath,${llvm_cv_oppath}"
1014       AC_SEARCH_LIBS(op_open_agent, opagent, [], [
1015         echo "Error! You need to have libopagent around."
1016         exit -1
1017       ])
1018       AC_CHECK_HEADER([opagent.h], [], [
1019         echo "Error! You need to have opagent.h around."
1020         exit -1
1021       ])
1022     ],
1023     [
1024       llvm_cv_old_LIBS="$LIBS"
1025       LIBS="$LIBS -L/usr/lib/oprofile -Wl,-rpath,/usr/lib/oprofile"
1026       dnl If either the library or header aren't present, omit oprofile support.
1027       AC_SEARCH_LIBS(op_open_agent, opagent,
1028                      [AC_SUBST(USE_OPROFILE, [1])],
1029                      [LIBS="$llvm_cv_old_LIBS"
1030                       AC_SUBST(USE_OPROFILE, [0])])
1031       AC_CHECK_HEADER([opagent.h], [], [
1032         LIBS="$llvm_cv_old_LIBS"
1033         AC_SUBST(USE_OPROFILE, [0])
1034       ])
1035     ])
1036 AC_DEFINE_UNQUOTED([USE_OPROFILE],$USE_OPROFILE,
1037                    [Define if we have the oprofile JIT-support library])
1038
1039 dnl===-----------------------------------------------------------------------===
1040 dnl===
1041 dnl=== SECTION 6: Check for header files
1042 dnl===
1043 dnl===-----------------------------------------------------------------------===
1044
1045 dnl First, use autoconf provided macros for specific headers that we need
1046 dnl We don't check for ancient stuff or things that are guaranteed to be there
1047 dnl by the C++ standard. We always use the <cfoo> versions of <foo.h> C headers.
1048 dnl Generally we're looking for POSIX headers.
1049 AC_HEADER_DIRENT
1050 AC_HEADER_MMAP_ANONYMOUS
1051 AC_HEADER_STAT
1052 AC_HEADER_STDC
1053 AC_HEADER_SYS_WAIT
1054 AC_HEADER_TIME
1055
1056 AC_CHECK_HEADERS([dlfcn.h execinfo.h fcntl.h inttypes.h limits.h link.h])
1057 AC_CHECK_HEADERS([malloc.h setjmp.h signal.h stdint.h termios.h unistd.h])
1058 AC_CHECK_HEADERS([utime.h windows.h])
1059 AC_CHECK_HEADERS([sys/mman.h sys/param.h sys/resource.h sys/time.h])
1060 AC_CHECK_HEADERS([sys/types.h sys/ioctl.h malloc/malloc.h mach/mach.h])
1061 if test "$ENABLE_THREADS" -eq 1 ; then
1062   AC_CHECK_HEADERS(pthread.h,
1063                    AC_SUBST(HAVE_PTHREAD, 1),
1064                    AC_SUBST(HAVE_PTHREAD, 0))
1065 else
1066   AC_SUBST(HAVE_PTHREAD, 0)
1067 fi
1068
1069 dnl Try to find ffi.h.
1070 if test "$llvm_cv_enable_libffi" = "yes" ; then
1071   AC_CHECK_HEADERS([ffi.h ffi/ffi.h])
1072 fi
1073
1074 dnl===-----------------------------------------------------------------------===
1075 dnl===
1076 dnl=== SECTION 7: Check for types and structures
1077 dnl===
1078 dnl===-----------------------------------------------------------------------===
1079
1080 AC_HUGE_VAL_CHECK
1081 AC_TYPE_PID_T
1082 AC_TYPE_SIZE_T
1083 AC_TYPE_SIGNAL
1084 AC_STRUCT_TM
1085 AC_CHECK_TYPES([int64_t],,AC_MSG_ERROR([Type int64_t required but not found]))
1086 AC_CHECK_TYPES([uint64_t],,
1087          AC_CHECK_TYPES([u_int64_t],,
1088          AC_MSG_ERROR([Type uint64_t or u_int64_t required but not found])))
1089
1090 dnl===-----------------------------------------------------------------------===
1091 dnl===
1092 dnl=== SECTION 8: Check for specific functions needed
1093 dnl===
1094 dnl===-----------------------------------------------------------------------===
1095
1096 AC_CHECK_FUNCS([backtrace ceilf floorf roundf rintf nearbyintf getcwd ])
1097 AC_CHECK_FUNCS([powf fmodf strtof round ])
1098 AC_CHECK_FUNCS([getpagesize getrusage getrlimit setrlimit gettimeofday ])
1099 AC_CHECK_FUNCS([isatty mkdtemp mkstemp ])
1100 AC_CHECK_FUNCS([mktemp realpath sbrk setrlimit strdup ])
1101 AC_CHECK_FUNCS([strerror strerror_r strerror_s setenv ])
1102 AC_CHECK_FUNCS([strtoll strtoq sysconf malloc_zone_statistics ])
1103 AC_CHECK_FUNCS([setjmp longjmp sigsetjmp siglongjmp])
1104 AC_C_PRINTF_A
1105 dnl FIXME: This is no longer used, please remove (but test)!!!
1106 AC_FUNC_ALLOCA
1107 AC_FUNC_RAND48
1108
1109 dnl Check for variations in the Standard C++ library and STL. These macros are
1110 dnl provided by LLVM in the autoconf/m4 directory.
1111 AC_CXX_HAVE_STD_ITERATOR
1112 AC_CXX_HAVE_BI_ITERATOR
1113 AC_CXX_HAVE_FWD_ITERATOR
1114 AC_FUNC_ISNAN
1115 AC_FUNC_ISINF
1116
1117 dnl Check for mmap support.We also need to know if /dev/zero is required to
1118 dnl be opened for allocating RWX memory.
1119 dnl Make sure we aren't attempting to configure for an unknown system
1120 if test "$llvm_cv_platform_type" = "Unix" ; then
1121   AC_FUNC_MMAP
1122   AC_FUNC_MMAP_FILE
1123   AC_NEED_DEV_ZERO_FOR_MMAP
1124
1125   if test "$ac_cv_func_mmap_fixed_mapped" = "no"
1126   then
1127     AC_MSG_WARN([mmap() of a fixed address required but not supported])
1128   fi
1129   if test "$ac_cv_func_mmap_file" = "no"
1130   then
1131     AC_MSG_WARN([mmap() of files required but not found])
1132   fi
1133 fi
1134
1135 dnl atomic builtins are required for threading support.
1136 AC_MSG_CHECKING(for GCC atomic builtins)
1137 AC_LINK_IFELSE(
1138   AC_LANG_SOURCE(
1139     [[int main() {
1140         volatile unsigned long val = 1;
1141         __sync_synchronize();
1142         __sync_val_compare_and_swap(&val, 1, 0);
1143         __sync_add_and_fetch(&val, 1);
1144         __sync_sub_and_fetch(&val, 1);
1145         return 0;
1146       }
1147     ]]),
1148   AC_MSG_RESULT(yes)
1149   AC_DEFINE(LLVM_MULTITHREADED, 1, Build multithreading support into LLVM),
1150   AC_MSG_RESULT(no)
1151   AC_DEFINE(LLVM_MULTITHREADED, 0, Build multithreading support into LLVM)
1152   AC_MSG_WARN([LLVM will be built thread-unsafe because atomic builtins are missing]))
1153
1154
1155 dnl===-----------------------------------------------------------------------===
1156 dnl===
1157 dnl=== SECTION 9: Additional checks, variables, etc.
1158 dnl===
1159 dnl===-----------------------------------------------------------------------===
1160
1161 dnl Check, whether __dso_handle is present
1162 AC_CHECK_FUNCS([__dso_handle])
1163
1164 dnl See if the llvm-gcc executable can compile to LLVM assembly
1165 AC_CACHE_CHECK([whether llvm-gcc is sane],[llvm_cv_llvmgcc_sanity],
1166 [llvm_cv_llvmgcc_sanity="no"
1167 if test -x "$LLVMGCC" ; then
1168   cp /dev/null conftest.c
1169   "$LLVMGCC" -emit-llvm -S -o - conftest.c | \
1170       grep 'target datalayout =' > /dev/null 2>&1
1171   if test $? -eq 0 ; then
1172     llvm_cv_llvmgcc_sanity="yes"
1173   fi
1174   rm conftest.c
1175 fi])
1176
1177 dnl Since we have a sane llvm-gcc, identify it and its sub-tools
1178 if test "$llvm_cv_llvmgcc_sanity" = "yes" ; then
1179   AC_MSG_CHECKING([llvm-gcc component support])
1180   llvmcc1path=`"$LLVMGCC" --print-prog-name=cc1`
1181   AC_SUBST(LLVMCC1,$llvmcc1path)
1182   llvmcc1pluspath=`"$LLVMGCC" --print-prog-name=cc1plus`
1183   AC_SUBST(LLVMCC1PLUS,$llvmcc1pluspath)
1184   llvmgccdir=`echo "$llvmcc1path" | sed 's,/libexec/.*,,'`
1185   AC_SUBST(LLVMGCCDIR,$llvmgccdir)
1186   llvmgcclibexec=`echo "$llvmcc1path" | sed 's,/cc1,,'`
1187   AC_SUBST(LLVMGCCLIBEXEC,$llvmgcclibexec)
1188   llvmgccversion=[`"$LLVMGCC" -dumpversion 2>&1 | sed 's/^\([0-9.]*\).*/\1/'`]
1189   llvmgccmajvers=[`echo $llvmgccversion | sed 's/^\([0-9]\).*/\1/'`]
1190   AC_SUBST(LLVMGCC_VERSION,$llvmgccversion)
1191   AC_SUBST(LLVMGCC_MAJVERS,$llvmgccmajvers)
1192   llvmgcclangs=[`"$LLVMGCC" -v --help 2>&1 | grep '^Configured with:' | sed 's/^.*--enable-languages=\([^ ]*\).*/\1/'`]
1193   AC_SUBST(LLVMGCC_LANGS,$llvmgcclangs)
1194   AC_MSG_RESULT([ok])
1195 fi
1196
1197 dnl Propagate the shared library extension that the libltdl checks did to
1198 dnl the Makefiles so we can use it there too
1199 AC_SUBST(SHLIBEXT,$libltdl_cv_shlibext)
1200
1201 # Translate the various configuration directories and other basic
1202 # information into substitutions that will end up in Makefile.config.in
1203 # that these configured values can be used by the makefiles
1204 if test "${prefix}" = "NONE" ; then
1205   prefix="/usr/local"
1206 fi
1207 eval LLVM_PREFIX="${prefix}";
1208 eval LLVM_BINDIR="${prefix}/bin";
1209 eval LLVM_LIBDIR="${prefix}/lib";
1210 eval LLVM_DATADIR="${prefix}/share/llvm";
1211 eval LLVM_DOCSDIR="${prefix}/docs/llvm";
1212 eval LLVM_ETCDIR="${prefix}/etc/llvm";
1213 eval LLVM_INCLUDEDIR="${prefix}/include";
1214 eval LLVM_INFODIR="${prefix}/info";
1215 eval LLVM_MANDIR="${prefix}/man";
1216 LLVM_CONFIGTIME=`date`
1217 AC_SUBST(LLVM_PREFIX)
1218 AC_SUBST(LLVM_BINDIR)
1219 AC_SUBST(LLVM_LIBDIR)
1220 AC_SUBST(LLVM_DATADIR)
1221 AC_SUBST(LLVM_DOCSDIR)
1222 AC_SUBST(LLVM_ETCDIR)
1223 AC_SUBST(LLVM_INCLUDEDIR)
1224 AC_SUBST(LLVM_INFODIR)
1225 AC_SUBST(LLVM_MANDIR)
1226 AC_SUBST(LLVM_CONFIGTIME)
1227
1228 # Place the various directores into the config.h file as #defines so that we
1229 # can know about the installation paths within LLVM.
1230 AC_DEFINE_UNQUOTED(LLVM_PREFIX,"$LLVM_PREFIX",
1231                    [Installation prefix directory])
1232 AC_DEFINE_UNQUOTED(LLVM_BINDIR, "$LLVM_BINDIR",
1233                    [Installation directory for binary executables])
1234 AC_DEFINE_UNQUOTED(LLVM_LIBDIR, "$LLVM_LIBDIR",
1235                    [Installation directory for libraries])
1236 AC_DEFINE_UNQUOTED(LLVM_DATADIR, "$LLVM_DATADIR",
1237                    [Installation directory for data files])
1238 AC_DEFINE_UNQUOTED(LLVM_DOCSDIR, "$LLVM_DOCSDIR",
1239                    [Installation directory for documentation])
1240 AC_DEFINE_UNQUOTED(LLVM_ETCDIR, "$LLVM_ETCDIR",
1241                    [Installation directory for config files])
1242 AC_DEFINE_UNQUOTED(LLVM_INCLUDEDIR, "$LLVM_INCLUDEDIR",
1243                    [Installation directory for include files])
1244 AC_DEFINE_UNQUOTED(LLVM_INFODIR, "$LLVM_INFODIR",
1245                    [Installation directory for .info files])
1246 AC_DEFINE_UNQUOTED(LLVM_MANDIR, "$LLVM_MANDIR",
1247                    [Installation directory for man pages])
1248 AC_DEFINE_UNQUOTED(LLVM_CONFIGTIME, "$LLVM_CONFIGTIME",
1249                    [Time at which LLVM was configured])
1250 AC_DEFINE_UNQUOTED(LLVM_HOSTTRIPLE, "$host",
1251                    [Host triple we were built on])
1252
1253 # Determine which bindings to build.
1254 if test "$BINDINGS_TO_BUILD" = auto ; then
1255   BINDINGS_TO_BUILD=""
1256   if test "x$OCAMLC" != x -a "x$OCAMLDEP" != x ; then
1257     BINDINGS_TO_BUILD="ocaml $BINDINGS_TO_BUILD"
1258   fi
1259 fi
1260 AC_SUBST(BINDINGS_TO_BUILD,$BINDINGS_TO_BUILD)
1261
1262 # This isn't really configurey, but it avoids having to repeat the list in
1263 # other files.
1264 AC_SUBST(ALL_BINDINGS,ocaml)
1265
1266 # Do any work necessary to ensure that bindings have what they need.
1267 binding_prereqs_failed=0
1268 for a_binding in $BINDINGS_TO_BUILD ; do
1269   case "$a_binding" in
1270   ocaml)
1271     if test "x$OCAMLC" = x ; then
1272       AC_MSG_WARN([--enable-bindings=ocaml specified, but ocamlc not found. Try configure OCAMLC=/path/to/ocamlc])
1273       binding_prereqs_failed=1
1274     fi
1275     if test "x$OCAMLDEP" = x ; then
1276       AC_MSG_WARN([--enable-bindings=ocaml specified, but ocamldep not found. Try configure OCAMLDEP=/path/to/ocamldep])
1277       binding_prereqs_failed=1
1278     fi
1279     if test "x$OCAMLOPT" = x ; then
1280       AC_MSG_WARN([--enable-bindings=ocaml specified, but ocamlopt not found. Try configure OCAMLOPT=/path/to/ocamlopt])
1281       dnl ocamlopt is optional!
1282     fi
1283     if test "x$with_ocaml_libdir" != xauto ; then
1284       AC_SUBST(OCAML_LIBDIR,$with_ocaml_libdir)
1285     else
1286       ocaml_stdlib="`"$OCAMLC" -where`"
1287       if test "$LLVM_PREFIX" '<' "$ocaml_stdlib" -a "$ocaml_stdlib" '<' "$LLVM_PREFIX~"
1288       then
1289         # ocaml stdlib is beneath our prefix; use stdlib
1290         AC_SUBST(OCAML_LIBDIR,$ocaml_stdlib)
1291       else
1292         # ocaml stdlib is outside our prefix; use libdir/ocaml
1293         AC_SUBST(OCAML_LIBDIR,$LLVM_LIBDIR/ocaml)
1294       fi
1295     fi
1296     ;;
1297   esac
1298 done
1299 if test "$binding_prereqs_failed" = 1 ; then
1300   AC_MSG_ERROR([Prequisites for bindings not satisfied. Fix them or use configure --disable-bindings.])
1301 fi
1302
1303 dnl Determine whether the compiler supports -fvisibility-inlines-hidden.
1304 AC_CXX_USE_VISIBILITY_INLINES_HIDDEN
1305
1306 dnl Determine linker rpath flag
1307 if test "$llvm_cv_link_use_r" = "yes" ; then
1308   RPATH="-Wl,-R"
1309 else
1310   RPATH="-Wl,-rpath"
1311 fi
1312 AC_SUBST(RPATH)
1313
1314 dnl Determine linker rdynamic flag
1315 if test "$llvm_cv_link_use_export_dynamic" = "yes" ; then
1316   RDYNAMIC="-Wl,-export-dynamic"
1317 else
1318   RDYNAMIC=""
1319 fi
1320 AC_SUBST(RDYNAMIC)
1321
1322 dnl===-----------------------------------------------------------------------===
1323 dnl===
1324 dnl=== SECTION 10: Specify the output files and generate it
1325 dnl===
1326 dnl===-----------------------------------------------------------------------===
1327
1328 dnl Configure header files
1329 dnl WARNING: dnl If you add or remove any of the following config headers, then
1330 dnl you MUST also update Makefile.rules so that the variable FilesToConfig
1331 dnl contains the same list of files as AC_CONFIG_HEADERS below. This ensures the
1332 dnl files can be updated automatically when their *.in sources change.
1333 AC_CONFIG_HEADERS([include/llvm/Config/config.h])
1334 AC_CONFIG_FILES([include/llvm/Config/Targets.def])
1335 AC_CONFIG_FILES([include/llvm/Config/AsmPrinters.def])
1336 AC_CONFIG_FILES([include/llvm/Config/AsmParsers.def])
1337 AC_CONFIG_HEADERS([include/llvm/Support/DataTypes.h])
1338
1339 dnl Configure the makefile's configuration data
1340 AC_CONFIG_FILES([Makefile.config])
1341
1342 dnl Configure the RPM spec file for LLVM
1343 AC_CONFIG_FILES([llvm.spec])
1344
1345 dnl Configure doxygen's configuration file
1346 AC_CONFIG_FILES([docs/doxygen.cfg])
1347
1348 dnl Configure llvmc's Base plugin
1349 AC_CONFIG_FILES([tools/llvmc/plugins/Base/Base.td])
1350
1351 dnl Do the first stage of configuration for llvm-config.in.
1352 AC_CONFIG_FILES([tools/llvm-config/llvm-config.in])
1353
1354 dnl Do special configuration of Makefiles
1355 AC_CONFIG_COMMANDS([setup],,[llvm_src="${srcdir}"])
1356 AC_CONFIG_MAKEFILE(Makefile)
1357 AC_CONFIG_MAKEFILE(Makefile.common)
1358 AC_CONFIG_MAKEFILE(examples/Makefile)
1359 AC_CONFIG_MAKEFILE(lib/Makefile)
1360 AC_CONFIG_MAKEFILE(runtime/Makefile)
1361 AC_CONFIG_MAKEFILE(test/Makefile)
1362 AC_CONFIG_MAKEFILE(test/Makefile.tests)
1363 AC_CONFIG_MAKEFILE(unittests/Makefile)
1364 AC_CONFIG_MAKEFILE(tools/Makefile)
1365 AC_CONFIG_MAKEFILE(utils/Makefile)
1366 AC_CONFIG_MAKEFILE(projects/Makefile)
1367 AC_CONFIG_MAKEFILE(bindings/Makefile)
1368 AC_CONFIG_MAKEFILE(bindings/ocaml/Makefile.ocaml)
1369
1370 dnl Finally, crank out the output
1371 AC_OUTPUT