autoconf/configure.ac

   1 dnl === configure.ac --------------------------------------------------------===
   2 dnl                     The LLVM Compiler Infrastructure
   3 dnl
   4 dnl This file is distributed under the University of Illinois Open Source
   5 dnl License. See LICENSE.TXT for details.
   6 dnl
   7 dnl===-----------------------------------------------------------------------===
   8 dnl This is the LLVM configuration script. It is processed by the autoconf
   9 dnl program to produce a script named configure. This script contains the
  10 dnl configuration checks that LLVM needs in order to support multiple platforms.
  11 dnl This file is composed of 10 sections per the recommended organization of
  12 dnl autoconf input defined in the autoconf documentation. As this file evolves,
  13 dnl please keep the various types of checks within their sections. The sections
  14 dnl are as follows:
  15 dnl
  16 dnl SECTION 1: Initialization & Setup
  17 dnl SECTION 2: Architecture, target, and host checks
  18 dnl SECTION 3: Command line arguments for the configure script.
  19 dnl SECTION 4: Check for programs we need and that they are the right version
  20 dnl SECTION 5: Check for libraries
  21 dnl SECTION 6: Check for header files
  22 dnl SECTION 7: Check for types and structures
  23 dnl SECTION 8: Check for specific functions needed
  24 dnl SECTION 9: Additional checks, variables, etc.
  25 dnl SECTION 10: Specify the output files and generate it
  26 dnl
  27 dnl===-----------------------------------------------------------------------===
  28 dnl===
  29 dnl=== SECTION 1: Initialization & Setup
  30 dnl===
  31 dnl===-----------------------------------------------------------------------===
  32 dnl Initialize autoconf and define the package name, version number and
  33 dnl email address for reporting bugs.
  34 AC_INIT([[llvm]],[[3.1svn]],[llvmbugs@cs.uiuc.edu])
  35
  36 dnl Provide a copyright substitution and ensure the copyright notice is included
  37 dnl in the output of --version option of the generated configure script.
  38 AC_SUBST(LLVM_COPYRIGHT,["Copyright (c) 2003-2011 University of Illinois at Urbana-Champaign."])
  39 AC_COPYRIGHT([Copyright (c) 2003-2011 University of Illinois at Urbana-Champaign.])
  40
  41 dnl Indicate that we require autoconf 2.60 or later.
  42 AC_PREREQ(2.60)
  43
  44 dnl Verify that the source directory is valid. This makes sure that we are
  45 dnl configuring LLVM and not some other package (it validates --srcdir argument)
  46 AC_CONFIG_SRCDIR([lib/VMCore/Module.cpp])
  47
  48 dnl Place all of the extra autoconf files into the config subdirectory. Tell
  49 dnl various tools where the m4 autoconf macros are.
  50 AC_CONFIG_AUX_DIR([autoconf])
  51
  52 dnl Quit if the source directory has already been configured.
  53 dnl NOTE: This relies upon undocumented autoconf behavior.
  54 if test ${srcdir} != "." ; then
  55   if test -f ${srcdir}/include/llvm/Config/config.h ; then
  56     AC_MSG_ERROR([Already configured in ${srcdir}])
  57   fi
  58 fi
  59
  60 dnl We need to check for the compiler up here to avoid anything else
  61 dnl starting with a different one.
  62 AC_PROG_CC(clang llvm-gcc gcc)
  63 AC_PROG_CXX(clang++ llvm-g++ g++)
  64 AC_PROG_CPP
  65
  66 dnl Configure all of the projects present in our source tree. While we could
  67 dnl just AC_CONFIG_SUBDIRS on the set of directories in projects that have a
  68 dnl configure script, that usage of the AC_CONFIG_SUBDIRS macro is deprecated.
  69 dnl Instead we match on the known projects.
  70
  71 dnl
  72 dnl One tricky part of doing this is that some projects depend upon other
  73 dnl projects.  For example, several projects rely upon the LLVM test suite.
  74 dnl We want to configure those projects first so that their object trees are
  75 dnl created before running the configure scripts of projects that depend upon
  76 dnl them.
  77 dnl
  78
  79 dnl Several projects use llvm-gcc, so configure that first
  80 if test -d ${srcdir}/projects/llvm-gcc ; then
  81   AC_CONFIG_SUBDIRS([projects/llvm-gcc])
  82 fi
  83
  84 dnl Several projects use the LLVM test suite, so configure it next.
  85 if test -d ${srcdir}/projects/test-suite ; then
  86   AC_CONFIG_SUBDIRS([projects/test-suite])
  87 fi
  88
  89 dnl llvm-test is the old name of the test-suite, kept here for backwards
  90 dnl compatibility
  91 if test -d ${srcdir}/projects/llvm-test ; then
  92   AC_CONFIG_SUBDIRS([projects/llvm-test])
  93 fi
  94
  95 dnl Some projects use poolalloc; configure that next
  96 if test -d ${srcdir}/projects/poolalloc ; then
  97   AC_CONFIG_SUBDIRS([projects/poolalloc])
  98 fi
  99
 100 if test -d ${srcdir}/projects/llvm-poolalloc ; then
 101   AC_CONFIG_SUBDIRS([projects/llvm-poolalloc])
 102 fi
 103
 104 dnl Check for all other projects
 105 for i in `ls ${srcdir}/projects`
 106 do
 107   if test -d ${srcdir}/projects/${i} ; then
 108     case ${i} in
 109       sample)       AC_CONFIG_SUBDIRS([projects/sample])    ;;
 110       privbracket)  AC_CONFIG_SUBDIRS([projects/privbracket]) ;;
 111       llvm-stacker) AC_CONFIG_SUBDIRS([projects/llvm-stacker]) ;;
 112       llvm-reopt)   AC_CONFIG_SUBDIRS([projects/llvm-reopt]);;
 113       llvm-java)    AC_CONFIG_SUBDIRS([projects/llvm-java]) ;;
 114       llvm-tv)      AC_CONFIG_SUBDIRS([projects/llvm-tv])   ;;
 115       safecode)     AC_CONFIG_SUBDIRS([projects/safecode]) ;;
 116       llvm-kernel)  AC_CONFIG_SUBDIRS([projects/llvm-kernel]) ;;
 117       llvm-gcc)       ;;
 118       test-suite)     ;;
 119       llvm-test)      ;;
 120       poolalloc)      ;;
 121       llvm-poolalloc) ;;
 122       *)
 123         AC_MSG_WARN([Unknown project (${i}) won't be configured automatically])
 124         ;;
 125     esac
 126   fi
 127 done
 128
 129 dnl Disable the build of polly, even if it is checked out into tools/polly.
 130 AC_ARG_ENABLE(polly,
 131               AS_HELP_STRING([--enable-polly],
 132                              [Use polly if available (default is YES)]),,
 133                              enableval=default)
 134 case "$enableval" in
 135   yes) AC_SUBST(ENABLE_POLLY,[1]) ;;
 136   no)  AC_SUBST(ENABLE_POLLY,[0]) ;;
 137   default) AC_SUBST(ENABLE_POLLY,[1]) ;;
 138   *) AC_MSG_ERROR([Invalid setting for --enable-polly. Use "yes" or "no"]) ;;
 139 esac
 140
 141
 142 dnl Check if polly is checked out into tools/polly and configure it if
 143 dnl available.
 144 if (test -d ${srcdir}/tools/polly) && (test $ENABLE_POLLY -eq 1) ; then
 145   AC_SUBST(LLVM_HAS_POLLY,1)
 146   AC_CONFIG_SUBDIRS([tools/polly])
 147 fi
 148
 149 dnl===-----------------------------------------------------------------------===
 150 dnl===
 151 dnl=== SECTION 2: Architecture, target, and host checks
 152 dnl===
 153 dnl===-----------------------------------------------------------------------===
 154
 155 dnl Check the target for which we're compiling and the host that will do the
 156 dnl compilations. This will tell us which LLVM compiler will be used for
 157 dnl compiling SSA into object code. This needs to be done early because
 158 dnl following tests depend on it.
 159 AC_CANONICAL_TARGET
 160
 161 dnl Determine the platform type and cache its value. This helps us configure
 162 dnl the System library to the correct build platform.
 163 AC_CACHE_CHECK([type of operating system we're going to host on],
 164                [llvm_cv_os_type],
 165 [case $host in
 166   *-*-aix*)
 167     llvm_cv_link_all_option="-Wl,--whole-archive"
 168     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 169     llvm_cv_os_type="AIX"
 170     llvm_cv_platform_type="Unix" ;;
 171   *-*-irix*)
 172     llvm_cv_link_all_option="-Wl,--whole-archive"
 173     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 174     llvm_cv_os_type="IRIX"
 175     llvm_cv_platform_type="Unix" ;;
 176   *-*-cygwin*)
 177     llvm_cv_link_all_option="-Wl,--whole-archive"
 178     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 179     llvm_cv_os_type="Cygwin"
 180     llvm_cv_platform_type="Unix" ;;
 181   *-*-darwin*)
 182     llvm_cv_link_all_option="-Wl,-all_load"
 183     llvm_cv_no_link_all_option="-Wl,-noall_load"
 184     llvm_cv_os_type="Darwin"
 185     llvm_cv_platform_type="Unix" ;;
 186   *-*-minix*)
 187     llvm_cv_link_all_option="-Wl,-all_load"
 188     llvm_cv_no_link_all_option="-Wl,-noall_load"
 189     llvm_cv_os_type="Minix"
 190     llvm_cv_platform_type="Unix" ;;
 191   *-*-freebsd*)
 192     llvm_cv_link_all_option="-Wl,--whole-archive"
 193     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 194     llvm_cv_os_type="FreeBSD"
 195     llvm_cv_platform_type="Unix" ;;
 196   *-*-openbsd*)
 197     llvm_cv_link_all_option="-Wl,--whole-archive"
 198     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 199     llvm_cv_os_type="OpenBSD"
 200     llvm_cv_platform_type="Unix" ;;
 201   *-*-netbsd*)
 202     llvm_cv_link_all_option="-Wl,--whole-archive"
 203     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 204     llvm_cv_os_type="NetBSD"
 205     llvm_cv_platform_type="Unix" ;;
 206   *-*-dragonfly*)
 207     llvm_cv_link_all_option="-Wl,--whole-archive"
 208     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 209     llvm_cv_os_type="DragonFly"
 210     llvm_cv_platform_type="Unix" ;;
 211   *-*-hpux*)
 212     llvm_cv_link_all_option="-Wl,--whole-archive"
 213     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 214     llvm_cv_os_type="HP-UX"
 215     llvm_cv_platform_type="Unix" ;;
 216   *-*-interix*)
 217     llvm_cv_link_all_option="-Wl,--whole-archive"
 218     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 219     llvm_cv_os_type="Interix"
 220     llvm_cv_platform_type="Unix" ;;
 221   *-*-linux*)
 222     llvm_cv_link_all_option="-Wl,--whole-archive"
 223     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 224     llvm_cv_os_type="Linux"
 225     llvm_cv_platform_type="Unix" ;;
 226   *-*-solaris*)
 227     llvm_cv_link_all_option="-Wl,-z,allextract"
 228     llvm_cv_no_link_all_option="-Wl,-z,defaultextract"
 229     llvm_cv_os_type="SunOS"
 230     llvm_cv_platform_type="Unix" ;;
 231   *-*-auroraux*)
 232     llvm_cv_link_all_option="-Wl,-z,allextract"
 233     llvm_cv_link_all_option="-Wl,-z,defaultextract"
 234     llvm_cv_os_type="AuroraUX"
 235     llvm_cv_platform_type="Unix" ;;
 236   *-*-win32*)
 237     llvm_cv_link_all_option="-Wl,--whole-archive"
 238     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 239     llvm_cv_os_type="Win32"
 240     llvm_cv_platform_type="Win32" ;;
 241   *-*-mingw*)
 242     llvm_cv_link_all_option="-Wl,--whole-archive"
 243     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 244     llvm_cv_os_type="MingW"
 245     llvm_cv_platform_type="Win32" ;;
 246   *-*-haiku*)
 247     llvm_cv_link_all_option="-Wl,--whole-archive"
 248     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 249     llvm_cv_os_type="Haiku"
 250     llvm_cv_platform_type="Unix" ;;
 251   *-unknown-eabi*)
 252     llvm_cv_link_all_option="-Wl,--whole-archive"
 253     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 254     llvm_cv_os_type="Freestanding"
 255     llvm_cv_platform_type="Unix" ;;
 256   *-unknown-elf*)
 257     llvm_cv_link_all_option="-Wl,--whole-archive"
 258     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 259     llvm_cv_os_type="Freestanding"
 260     llvm_cv_platform_type="Unix" ;;
 261   *)
 262     llvm_cv_link_all_option=""
 263     llvm_cv_no_link_all_option=""
 264     llvm_cv_os_type="Unknown"
 265     llvm_cv_platform_type="Unknown" ;;
 266 esac])
 267
 268 AC_CACHE_CHECK([type of operating system we're going to target],
 269                [llvm_cv_target_os_type],
 270 [case $target in
 271   *-*-aix*)
 272     llvm_cv_target_os_type="AIX" ;;
 273   *-*-irix*)
 274     llvm_cv_target_os_type="IRIX" ;;
 275   *-*-cygwin*)
 276     llvm_cv_target_os_type="Cygwin" ;;
 277   *-*-darwin*)
 278     llvm_cv_target_os_type="Darwin" ;;
 279   *-*-minix*)
 280     llvm_cv_target_os_type="Minix" ;;
 281   *-*-freebsd*)
 282     llvm_cv_target_os_type="FreeBSD" ;;
 283   *-*-openbsd*)
 284     llvm_cv_target_os_type="OpenBSD" ;;
 285   *-*-netbsd*)
 286     llvm_cv_target_os_type="NetBSD" ;;
 287   *-*-dragonfly*)
 288     llvm_cv_target_os_type="DragonFly" ;;
 289   *-*-hpux*)
 290     llvm_cv_target_os_type="HP-UX" ;;
 291   *-*-interix*)
 292     llvm_cv_target_os_type="Interix" ;;
 293   *-*-linux*)
 294     llvm_cv_target_os_type="Linux" ;;
 295   *-*-solaris*)
 296     llvm_cv_target_os_type="SunOS" ;;
 297   *-*-auroraux*)
 298     llvm_cv_target_os_type="AuroraUX" ;;
 299   *-*-win32*)
 300     llvm_cv_target_os_type="Win32" ;;
 301   *-*-mingw*)
 302     llvm_cv_target_os_type="MingW" ;;
 303   *-*-haiku*)
 304     llvm_cv_target_os_type="Haiku" ;;
 305   *-*-rtems*)
 306     llvm_cv_target_os_type="RTEMS" ;;
 307   *-*-nacl*)
 308     llvm_cv_target_os_type="NativeClient" ;;
 309   *-unknown-eabi*)
 310     llvm_cv_target_os_type="Freestanding" ;;
 311   *)
 312     llvm_cv_target_os_type="Unknown" ;;
 313 esac])
 314
 315 dnl Make sure we aren't attempting to configure for an unknown system
 316 if test "$llvm_cv_os_type" = "Unknown" ; then
 317   AC_MSG_ERROR([Operating system is unknown, configure can't continue])
 318 fi
 319
 320 dnl Set the "OS" Makefile variable based on the platform type so the
 321 dnl makefile can configure itself to specific build hosts
 322 AC_SUBST(OS,$llvm_cv_os_type)
 323 AC_SUBST(HOST_OS,$llvm_cv_os_type)
 324 AC_SUBST(TARGET_OS,$llvm_cv_target_os_type)
 325
 326 dnl Set the LINKALL and NOLINKALL Makefile variables based on the platform
 327 AC_SUBST(LINKALL,$llvm_cv_link_all_option)
 328 AC_SUBST(NOLINKALL,$llvm_cv_no_link_all_option)
 329
 330 dnl Set the "LLVM_ON_*" variables based on llvm_cv_platform_type
 331 dnl This is used by lib/Support to determine the basic kind of implementation
 332 dnl to use.
 333 case $llvm_cv_platform_type in
 334   Unix)
 335     AC_DEFINE([LLVM_ON_UNIX],[1],[Define if this is Unixish platform])
 336     AC_SUBST(LLVM_ON_UNIX,[1])
 337     AC_SUBST(LLVM_ON_WIN32,[0])
 338     ;;
 339   Win32)
 340     AC_DEFINE([LLVM_ON_WIN32],[1],[Define if this is Win32ish platform])
 341     AC_SUBST(LLVM_ON_UNIX,[0])
 342     AC_SUBST(LLVM_ON_WIN32,[1])
 343     ;;
 344 esac
 345
 346 dnl Determine what our target architecture is and configure accordingly.
 347 dnl This will allow Makefiles to make a distinction between the hardware and
 348 dnl the OS.
 349 AC_CACHE_CHECK([target architecture],[llvm_cv_target_arch],
 350 [case $target in
 351   i?86-*)                 llvm_cv_target_arch="x86" ;;
 352   amd64-* | x86_64-*)     llvm_cv_target_arch="x86_64" ;;
 353   sparc*-*)               llvm_cv_target_arch="Sparc" ;;
 354   powerpc*-*)             llvm_cv_target_arch="PowerPC" ;;
 355   alpha*-*)               llvm_cv_target_arch="Alpha" ;;
 356   arm*-*)                 llvm_cv_target_arch="ARM" ;;
 357   mips-*)                 llvm_cv_target_arch="Mips" ;;
 358   xcore-*)                llvm_cv_target_arch="XCore" ;;
 359   msp430-*)               llvm_cv_target_arch="MSP430" ;;
 360   mblaze-*)               llvm_cv_target_arch="MBlaze" ;;
 361   ptx-*)                  llvm_cv_target_arch="PTX" ;;
 362   *)                      llvm_cv_target_arch="Unknown" ;;
 363 esac])
 364
 365 if test "$llvm_cv_target_arch" = "Unknown" ; then
 366   AC_MSG_WARN([Configuring LLVM for an unknown target archicture])
 367 fi
 368
 369 # Determine the LLVM native architecture for the target
 370 case "$llvm_cv_target_arch" in
 371     x86)     LLVM_NATIVE_ARCH="X86" ;;
 372     x86_64)  LLVM_NATIVE_ARCH="X86" ;;
 373     *)       LLVM_NATIVE_ARCH="$llvm_cv_target_arch" ;;
 374 esac
 375
 376 dnl Define a substitution, ARCH, for the target architecture
 377 AC_SUBST(ARCH,$llvm_cv_target_arch)
 378
 379 dnl Check for the endianness of the target
 380 AC_C_BIGENDIAN(AC_SUBST([ENDIAN],[big]),AC_SUBST([ENDIAN],[little]))
 381
 382 dnl Check for build platform executable suffix if we're crosscompiling
 383 if test "$cross_compiling" = yes; then
 384   AC_SUBST(LLVM_CROSS_COMPILING, [1])
 385   AC_BUILD_EXEEXT
 386   ac_build_prefix=${build_alias}-
 387   AC_CHECK_PROG(BUILD_CXX, ${ac_build_prefix}g++, ${ac_build_prefix}g++)
 388   if test -z "$BUILD_CXX"; then
 389      AC_CHECK_PROG(BUILD_CXX, g++, g++)
 390      if test -z "$BUILD_CXX"; then
 391        AC_CHECK_PROG(BUILD_CXX, c++, c++, , , /usr/ucb/c++)
 392      fi
 393   fi
 394 else
 395   AC_SUBST(LLVM_CROSS_COMPILING, [0])
 396 fi
 397
 398 dnl Check to see if there's a .svn or .git directory indicating that this
 399 dnl build is being done from a checkout. This sets up several defaults for
 400 dnl the command line switches. When we build with a checkout directory,
 401 dnl we get a debug with assertions turned on. Without, we assume a source
 402 dnl release and we get an optimized build without assertions.
 403 dnl See --enable-optimized and --enable-assertions below
 404 if test -d ".svn" -o -d "${srcdir}/.svn" -o -d ".git" -o -d "${srcdir}/.git"; then
 405   cvsbuild="yes"
 406   optimize="no"
 407   AC_SUBST(CVSBUILD,[[CVSBUILD=1]])
 408 else
 409   cvsbuild="no"
 410   optimize="yes"
 411 fi
 412
 413 dnl===-----------------------------------------------------------------------===
 414 dnl===
 415 dnl=== SECTION 3: Command line arguments for the configure script.
 416 dnl===
 417 dnl===-----------------------------------------------------------------------===
 418
 419 dnl --enable-optimized : check whether they want to do an optimized build:
 420 AC_ARG_ENABLE(optimized, AS_HELP_STRING(
 421  --enable-optimized,[Compile with optimizations enabled (default is NO)]),,enableval=$optimize)
 422 if test ${enableval} = "no" ; then
 423   AC_SUBST(ENABLE_OPTIMIZED,[[]])
 424 else
 425   AC_SUBST(ENABLE_OPTIMIZED,[[ENABLE_OPTIMIZED=1]])
 426 fi
 427
 428 dnl --enable-profiling : check whether they want to do a profile build:
 429 AC_ARG_ENABLE(profiling, AS_HELP_STRING(
 430  --enable-profiling,[Compile with profiling enabled (default is NO)]),,enableval="no")
 431 if test ${enableval} = "no" ; then
 432   AC_SUBST(ENABLE_PROFILING,[[]])
 433 else
 434   AC_SUBST(ENABLE_PROFILING,[[ENABLE_PROFILING=1]])
 435 fi
 436
 437 dnl --enable-assertions : check whether they want to turn on assertions or not:
 438 AC_ARG_ENABLE(assertions,AS_HELP_STRING(
 439   --enable-assertions,[Compile with assertion checks enabled (default is YES)]),, enableval="yes")
 440 if test ${enableval} = "yes" ; then
 441   AC_SUBST(DISABLE_ASSERTIONS,[[]])
 442 else
 443   AC_SUBST(DISABLE_ASSERTIONS,[[DISABLE_ASSERTIONS=1]])
 444 fi
 445
 446 dnl --enable-expensive-checks : check whether they want to turn on expensive debug checks:
 447 AC_ARG_ENABLE(expensive-checks,AS_HELP_STRING(
 448   --enable-expensive-checks,[Compile with expensive debug checks enabled (default is NO)]),, enableval="no")
 449 if test ${enableval} = "yes" ; then
 450   AC_SUBST(ENABLE_EXPENSIVE_CHECKS,[[ENABLE_EXPENSIVE_CHECKS=1]])
 451   AC_SUBST(EXPENSIVE_CHECKS,[[yes]])
 452 else
 453   AC_SUBST(ENABLE_EXPENSIVE_CHECKS,[[]])
 454   AC_SUBST(EXPENSIVE_CHECKS,[[no]])
 455 fi
 456
 457 dnl --enable-debug-runtime : should runtime libraries have debug symbols?
 458 AC_ARG_ENABLE(debug-runtime,
 459    AS_HELP_STRING(--enable-debug-runtime,[Build runtime libs with debug symbols (default is NO)]),,enableval=no)
 460 if test ${enableval} = "no" ; then
 461   AC_SUBST(DEBUG_RUNTIME,[[]])
 462 else
 463   AC_SUBST(DEBUG_RUNTIME,[[DEBUG_RUNTIME=1]])
 464 fi
 465
 466 dnl --enable-debug-symbols : should even optimized compiler libraries
 467 dnl have debug symbols?
 468 AC_ARG_ENABLE(debug-symbols,
 469    AS_HELP_STRING(--enable-debug-symbols,[Build compiler with debug symbols (default is NO if optimization is on and YES if it's off)]),,enableval=no)
 470 if test ${enableval} = "no" ; then
 471   AC_SUBST(DEBUG_SYMBOLS,[[]])
 472 else
 473   AC_SUBST(DEBUG_SYMBOLS,[[DEBUG_SYMBOLS=1]])
 474 fi
 475
 476 dnl --enable-jit: check whether they want to enable the jit
 477 AC_ARG_ENABLE(jit,
 478   AS_HELP_STRING(--enable-jit,
 479                  [Enable Just In Time Compiling (default is YES)]),,
 480   enableval=default)
 481 if test ${enableval} = "no"
 482 then
 483   AC_SUBST(JIT,[[]])
 484 else
 485   case "$llvm_cv_target_arch" in
 486     x86)         AC_SUBST(TARGET_HAS_JIT,1) ;;
 487     Sparc)       AC_SUBST(TARGET_HAS_JIT,0) ;;
 488     PowerPC)     AC_SUBST(TARGET_HAS_JIT,1) ;;
 489     x86_64)      AC_SUBST(TARGET_HAS_JIT,1) ;;
 490     Alpha)       AC_SUBST(TARGET_HAS_JIT,0) ;;
 491     ARM)         AC_SUBST(TARGET_HAS_JIT,1) ;;
 492     Mips)        AC_SUBST(TARGET_HAS_JIT,1) ;;
 493     XCore)       AC_SUBST(TARGET_HAS_JIT,0) ;;
 494     MSP430)      AC_SUBST(TARGET_HAS_JIT,0) ;;
 495     MBlaze)      AC_SUBST(TARGET_HAS_JIT,0) ;;
 496     PTX)         AC_SUBST(TARGET_HAS_JIT,0) ;;
 497     *)           AC_SUBST(TARGET_HAS_JIT,0) ;;
 498   esac
 499 fi
 500
 501 dnl Allow enablement of building and installing docs
 502 AC_ARG_ENABLE(docs,
 503               AS_HELP_STRING([--enable-docs],
 504                              [Build documents (default is YES)]),,
 505                              enableval=default)
 506 case "$enableval" in
 507   yes) AC_SUBST(ENABLE_DOCS,[1]) ;;
 508   no)  AC_SUBST(ENABLE_DOCS,[0]) ;;
 509   default) AC_SUBST(ENABLE_DOCS,[1]) ;;
 510   *) AC_MSG_ERROR([Invalid setting for --enable-docs. Use "yes" or "no"]) ;;
 511 esac
 512
 513 dnl Allow enablement of doxygen generated documentation
 514 AC_ARG_ENABLE(doxygen,
 515               AS_HELP_STRING([--enable-doxygen],
 516                              [Build doxygen documentation (default is NO)]),,
 517                              enableval=default)
 518 case "$enableval" in
 519   yes) AC_SUBST(ENABLE_DOXYGEN,[1]) ;;
 520   no)  AC_SUBST(ENABLE_DOXYGEN,[0]) ;;
 521   default) AC_SUBST(ENABLE_DOXYGEN,[0]) ;;
 522   *) AC_MSG_ERROR([Invalid setting for --enable-doxygen. Use "yes" or "no"]) ;;
 523 esac
 524
 525 dnl Allow disablement of threads
 526 AC_ARG_ENABLE(threads,
 527               AS_HELP_STRING([--enable-threads],
 528                              [Use threads if available (default is YES)]),,
 529                              enableval=default)
 530 case "$enableval" in
 531   yes) AC_SUBST(ENABLE_THREADS,[1]) ;;
 532   no)  AC_SUBST(ENABLE_THREADS,[0]) ;;
 533   default) AC_SUBST(ENABLE_THREADS,[1]) ;;
 534   *) AC_MSG_ERROR([Invalid setting for --enable-threads. Use "yes" or "no"]) ;;
 535 esac
 536 AC_DEFINE_UNQUOTED([ENABLE_THREADS],$ENABLE_THREADS,[Define if threads enabled])
 537
 538 dnl Allow disablement of pthread.h
 539 AC_ARG_ENABLE(pthreads,
 540               AS_HELP_STRING([--enable-pthreads],
 541                              [Use pthreads if available (default is YES)]),,
 542                              enableval=default)
 543 case "$enableval" in
 544   yes) AC_SUBST(ENABLE_PTHREADS,[1]) ;;
 545   no)  AC_SUBST(ENABLE_PTHREADS,[0]) ;;
 546   default) AC_SUBST(ENABLE_PTHREADS,[1]) ;;
 547   *) AC_MSG_ERROR([Invalid setting for --enable-pthreads. Use "yes" or "no"]) ;;
 548 esac
 549
 550 dnl Allow building without position independent code
 551 AC_ARG_ENABLE(pic,
 552   AS_HELP_STRING([--enable-pic],
 553                  [Build LLVM with Position Independent Code (default is YES)]),,
 554                  enableval=default)
 555 case "$enableval" in
 556   yes) AC_SUBST(ENABLE_PIC,[1]) ;;
 557   no)  AC_SUBST(ENABLE_PIC,[0]) ;;
 558   default) AC_SUBST(ENABLE_PIC,[1]) ;;
 559   *) AC_MSG_ERROR([Invalid setting for --enable-pic. Use "yes" or "no"]) ;;
 560 esac
 561 AC_DEFINE_UNQUOTED([ENABLE_PIC],$ENABLE_PIC,
 562                    [Define if position independent code is enabled])
 563
 564 dnl Allow building a shared library and linking tools against it.
 565 AC_ARG_ENABLE(shared,
 566   AS_HELP_STRING([--enable-shared],
 567                  [Build a shared library and link tools against it (default is NO)]),,
 568                  enableval=default)
 569 case "$enableval" in
 570   yes) AC_SUBST(ENABLE_SHARED,[1]) ;;
 571   no)  AC_SUBST(ENABLE_SHARED,[0]) ;;
 572   default) AC_SUBST(ENABLE_SHARED,[0]) ;;
 573   *) AC_MSG_ERROR([Invalid setting for --enable-shared. Use "yes" or "no"]) ;;
 574 esac
 575
 576 dnl Allow libstdc++ is embedded in LLVM.dll.
 577 AC_ARG_ENABLE(embed-stdcxx,
 578   AS_HELP_STRING([--enable-embed-stdcxx],
 579                  [Build a shared library with embedded libstdc++ for Win32 DLL (default is NO)]),,
 580                  enableval=default)
 581 case "$enableval" in
 582   yes) AC_SUBST(ENABLE_EMBED_STDCXX,[1]) ;;
 583   no)  AC_SUBST(ENABLE_EMBED_STDCXX,[0]) ;;
 584   default) AC_SUBST(ENABLE_EMBED_STDCXX,[0]) ;;
 585   *) AC_MSG_ERROR([Invalid setting for --enable-embed-stdcxx. Use "yes" or "no"]) ;;
 586 esac
 587
 588 dnl Enable embedding timestamp information into build.
 589 AC_ARG_ENABLE(timestamps,
 590   AS_HELP_STRING([--enable-timestamps],
 591                  [Enable embedding timestamp information in build (default is YES)]),,
 592                  enableval=default)
 593 case "$enableval" in
 594   yes) AC_SUBST(ENABLE_TIMESTAMPS,[1]) ;;
 595   no)  AC_SUBST(ENABLE_TIMESTAMPS,[0]) ;;
 596   default) AC_SUBST(ENABLE_TIMESTAMPS,[1]) ;;
 597   *) AC_MSG_ERROR([Invalid setting for --enable-timestamps. Use "yes" or "no"]) ;;
 598 esac
 599 AC_DEFINE_UNQUOTED([ENABLE_TIMESTAMPS],$ENABLE_TIMESTAMPS,
 600                    [Define if timestamp information (e.g., __DATE___) is allowed])
 601
 602 dnl Allow specific targets to be specified for building (or not)
 603 TARGETS_TO_BUILD=""
 604 AC_ARG_ENABLE([targets],AS_HELP_STRING([--enable-targets],
 605     [Build specific host targets: all or target1,target2,... Valid targets are:
 606      host, x86, x86_64, sparc, powerpc, alpha, arm, mips, spu,
 607      xcore, msp430, ptx, cbe, and cpp (default=all)]),,
 608     enableval=all)
 609 if test "$enableval" = host-only ; then
 610   enableval=host
 611 fi
 612 case "$enableval" in
 613   all) TARGETS_TO_BUILD="X86 Sparc PowerPC Alpha ARM Mips CellSPU XCore MSP430 CBackend CppBackend MBlaze PTX" ;;
 614   *)for a_target in `echo $enableval|sed -e 's/,/ /g' ` ; do
 615       case "$a_target" in
 616         x86)      TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 617         x86_64)   TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 618         sparc)    TARGETS_TO_BUILD="Sparc $TARGETS_TO_BUILD" ;;
 619         powerpc)  TARGETS_TO_BUILD="PowerPC $TARGETS_TO_BUILD" ;;
 620         alpha)    TARGETS_TO_BUILD="Alpha $TARGETS_TO_BUILD" ;;
 621         arm)      TARGETS_TO_BUILD="ARM $TARGETS_TO_BUILD" ;;
 622         mips)     TARGETS_TO_BUILD="Mips $TARGETS_TO_BUILD" ;;
 623         spu)      TARGETS_TO_BUILD="CellSPU $TARGETS_TO_BUILD" ;;
 624         xcore)    TARGETS_TO_BUILD="XCore $TARGETS_TO_BUILD" ;;
 625         msp430)   TARGETS_TO_BUILD="MSP430 $TARGETS_TO_BUILD" ;;
 626         cbe)      TARGETS_TO_BUILD="CBackend $TARGETS_TO_BUILD" ;;
 627         cpp)      TARGETS_TO_BUILD="CppBackend $TARGETS_TO_BUILD" ;;
 628         mblaze)   TARGETS_TO_BUILD="MBlaze $TARGETS_TO_BUILD" ;;
 629         ptx)      TARGETS_TO_BUILD="PTX $TARGETS_TO_BUILD" ;;
 630         host) case "$llvm_cv_target_arch" in
 631             x86)         TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 632             x86_64)      TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 633             Sparc)       TARGETS_TO_BUILD="Sparc $TARGETS_TO_BUILD" ;;
 634             PowerPC)     TARGETS_TO_BUILD="PowerPC $TARGETS_TO_BUILD" ;;
 635             Alpha)       TARGETS_TO_BUILD="Alpha $TARGETS_TO_BUILD" ;;
 636             ARM)         TARGETS_TO_BUILD="ARM $TARGETS_TO_BUILD" ;;
 637             Mips)        TARGETS_TO_BUILD="Mips $TARGETS_TO_BUILD" ;;
 638             MBlaze)      TARGETS_TO_BUILD="MBlaze $TARGETS_TO_BUILD" ;;
 639             CellSPU|SPU) TARGETS_TO_BUILD="CellSPU $TARGETS_TO_BUILD" ;;
 640             XCore)       TARGETS_TO_BUILD="XCore $TARGETS_TO_BUILD" ;;
 641             MSP430)      TARGETS_TO_BUILD="MSP430 $TARGETS_TO_BUILD" ;;
 642             PTX)         TARGETS_TO_BUILD="PTX $TARGETS_TO_BUILD" ;;
 643             *)       AC_MSG_ERROR([Can not set target to build]) ;;
 644           esac ;;
 645         *) AC_MSG_ERROR([Unrecognized target $a_target]) ;;
 646       esac
 647   done
 648   ;;
 649 esac
 650 AC_SUBST(TARGETS_TO_BUILD,$TARGETS_TO_BUILD)
 651
 652 # Determine whether we are building LLVM support for the native architecture.
 653 # If so, define LLVM_NATIVE_ARCH to that LLVM target.
 654 for a_target in $TARGETS_TO_BUILD; do
 655   if test "$a_target" = "$LLVM_NATIVE_ARCH"; then
 656     AC_DEFINE_UNQUOTED(LLVM_NATIVE_ARCH, $LLVM_NATIVE_ARCH,
 657       [LLVM architecture name for the native architecture, if available])
 658     LLVM_NATIVE_TARGET="LLVMInitialize${LLVM_NATIVE_ARCH}Target"
 659     LLVM_NATIVE_TARGETINFO="LLVMInitialize${LLVM_NATIVE_ARCH}TargetInfo"
 660     LLVM_NATIVE_TARGETMC="LLVMInitialize${LLVM_NATIVE_ARCH}TargetMC"
 661     LLVM_NATIVE_ASMPRINTER="LLVMInitialize${LLVM_NATIVE_ARCH}AsmPrinter"
 662     if test -f ${srcdir}/lib/Target/${LLVM_NATIVE_ARCH}/AsmParser/Makefile ; then
 663       LLVM_NATIVE_ASMPARSER="LLVMInitialize${LLVM_NATIVE_ARCH}AsmParser"
 664     fi
 665     AC_DEFINE_UNQUOTED(LLVM_NATIVE_TARGET, $LLVM_NATIVE_TARGET,
 666       [LLVM name for the native Target init function, if available])
 667     AC_DEFINE_UNQUOTED(LLVM_NATIVE_TARGETINFO, $LLVM_NATIVE_TARGETINFO,
 668       [LLVM name for the native TargetInfo init function, if available])
 669     AC_DEFINE_UNQUOTED(LLVM_NATIVE_TARGETMC, $LLVM_NATIVE_TARGETMC,
 670       [LLVM name for the native target MC init function, if available])
 671     AC_DEFINE_UNQUOTED(LLVM_NATIVE_ASMPRINTER, $LLVM_NATIVE_ASMPRINTER,
 672       [LLVM name for the native AsmPrinter init function, if available])
 673     if test -f ${srcdir}/lib/Target/${LLVM_NATIVE_ARCH}/AsmParser/Makefile ; then
 674       AC_DEFINE_UNQUOTED(LLVM_NATIVE_ASMPARSER, $LLVM_NATIVE_ASMPARSER,
 675        [LLVM name for the native AsmParser init function, if available])
 676     fi
 677   fi
 678 done
 679
 680 # Build the LLVM_TARGET and LLVM_... macros for Targets.def and the individual
 681 # target feature def files.
 682 LLVM_ENUM_TARGETS=""
 683 LLVM_ENUM_ASM_PRINTERS=""
 684 LLVM_ENUM_ASM_PARSERS=""
 685 LLVM_ENUM_DISASSEMBLERS=""
 686 for target_to_build in $TARGETS_TO_BUILD; do
 687   LLVM_ENUM_TARGETS="LLVM_TARGET($target_to_build) $LLVM_ENUM_TARGETS"
 688   if test -f ${srcdir}/lib/Target/${target_to_build}/*AsmPrinter.cpp ; then
 689     LLVM_ENUM_ASM_PRINTERS="LLVM_ASM_PRINTER($target_to_build) $LLVM_ENUM_ASM_PRINTERS";
 690   fi
 691   if test -f ${srcdir}/lib/Target/${target_to_build}/AsmParser/Makefile ; then
 692     LLVM_ENUM_ASM_PARSERS="LLVM_ASM_PARSER($target_to_build) $LLVM_ENUM_ASM_PARSERS";
 693   fi
 694   if test -f ${srcdir}/lib/Target/${target_to_build}/Disassembler/Makefile ; then
 695     LLVM_ENUM_DISASSEMBLERS="LLVM_DISASSEMBLER($target_to_build) $LLVM_ENUM_DISASSEMBLERS";
 696   fi
 697 done
 698 AC_SUBST(LLVM_ENUM_TARGETS)
 699 AC_SUBST(LLVM_ENUM_ASM_PRINTERS)
 700 AC_SUBST(LLVM_ENUM_ASM_PARSERS)
 701 AC_SUBST(LLVM_ENUM_DISASSEMBLERS)
 702
 703 dnl Prevent the CBackend from using printf("%a") for floating point so older
 704 dnl C compilers that cannot deal with the 0x0p+0 hex floating point format
 705 dnl can still compile the CBE's output
 706 AC_ARG_ENABLE([cbe-printf-a],AS_HELP_STRING([--enable-cbe-printf-a],
 707   [Enable C Backend output with hex floating point via %a  (default is YES)]),,
 708   enableval=default)
 709 case "$enableval" in
 710   yes) AC_SUBST(ENABLE_CBE_PRINTF_A,[1]) ;;
 711   no)  AC_SUBST(ENABLE_CBE_PRINTF_A,[0]) ;;
 712   default)  AC_SUBST(ENABLE_CBE_PRINTF_A,[1]) ;;
 713   *) AC_MSG_ERROR([Invalid setting for --enable-cbe-printf-a. Use "yes" or "no"]) ;;
 714 esac
 715 AC_DEFINE_UNQUOTED([ENABLE_CBE_PRINTF_A],$ENABLE_CBE_PRINTF_A,
 716                    [Define if CBE is enabled for printf %a output])
 717
 718 dnl Override the option to use for optimized builds.
 719 AC_ARG_WITH(optimize-option,
 720   AS_HELP_STRING([--with-optimize-option],
 721                  [Select the compiler options to use for optimized builds]),,
 722                  withval=default)
 723 AC_MSG_CHECKING([optimization flags])
 724 case "$withval" in
 725   default)
 726     case "$llvm_cv_os_type" in
 727     FreeBSD) optimize_option=-O2 ;;
 728     MingW) optimize_option=-O2 ;;
 729     *)     optimize_option=-O3 ;;
 730     esac ;;
 731   *) optimize_option="$withval" ;;
 732 esac
 733 AC_SUBST(OPTIMIZE_OPTION,$optimize_option)
 734 AC_MSG_RESULT([$optimize_option])
 735
 736 dnl Specify extra build options
 737 AC_ARG_WITH(extra-options,
 738   AS_HELP_STRING([--with-extra-options],
 739                  [Specify additional options to compile LLVM with]),,
 740                  withval=default)
 741 case "$withval" in
 742   default) EXTRA_OPTIONS= ;;
 743   *) EXTRA_OPTIONS=$withval ;;
 744 esac
 745 AC_SUBST(EXTRA_OPTIONS,$EXTRA_OPTIONS)
 746
 747 dnl Specify extra linker build options
 748 AC_ARG_WITH(extra-ld-options,
 749   AS_HELP_STRING([--with-extra-ld-options],
 750                  [Specify additional options to link LLVM with]),,
 751                  withval=default)
 752 case "$withval" in
 753   default) EXTRA_LD_OPTIONS= ;;
 754   *) EXTRA_LD_OPTIONS=$withval ;;
 755 esac
 756 AC_SUBST(EXTRA_LD_OPTIONS,$EXTRA_LD_OPTIONS)
 757
 758 dnl Allow specific bindings to be specified for building (or not)
 759 AC_ARG_ENABLE([bindings],AS_HELP_STRING([--enable-bindings],
 760     [Build specific language bindings: all,auto,none,{binding-name} (default=auto)]),,
 761     enableval=default)
 762 BINDINGS_TO_BUILD=""
 763 case "$enableval" in
 764   yes | default | auto) BINDINGS_TO_BUILD="auto" ;;
 765   all ) BINDINGS_TO_BUILD="ocaml" ;;
 766   none | no) BINDINGS_TO_BUILD="" ;;
 767   *)for a_binding in `echo $enableval|sed -e 's/,/ /g' ` ; do
 768       case "$a_binding" in
 769         ocaml) BINDINGS_TO_BUILD="ocaml $BINDINGS_TO_BUILD" ;;
 770         *) AC_MSG_ERROR([Unrecognized binding $a_binding]) ;;
 771       esac
 772   done
 773   ;;
 774 esac
 775
 776 dnl Allow the ocaml libdir to be overridden. This could go in a configure
 777 dnl script for bindings/ocaml/configure, except that its auto value depends on
 778 dnl OCAMLC, which is found here to support tests.
 779 AC_ARG_WITH([ocaml-libdir],
 780   [AS_HELP_STRING([--with-ocaml-libdir],
 781     [Specify install location for ocaml bindings (default is stdlib)])],
 782   [],
 783   [withval=auto])
 784 case "$withval" in
 785   auto) with_ocaml_libdir="$withval" ;;
 786   /* | [[A-Za-z]]:[[\\/]]*) with_ocaml_libdir="$withval" ;;
 787   *) AC_MSG_ERROR([Invalid path for --with-ocaml-libdir. Provide full path]) ;;
 788 esac
 789
 790 AC_ARG_WITH(clang-srcdir,
 791   AS_HELP_STRING([--with-clang-srcdir],
 792     [Directory to the out-of-tree Clang source]),,
 793     withval="-")
 794 case "$withval" in
 795   -) clang_src_root="" ;;
 796   /* | [[A-Za-z]]:[[\\/]]*) clang_src_root="$withval" ;;
 797   *) clang_src_root="$ac_pwd/$withval" ;;
 798 esac
 799 AC_SUBST(CLANG_SRC_ROOT,[$clang_src_root])
 800
 801 AC_ARG_WITH(clang-resource-dir,
 802   AS_HELP_STRING([--with-clang-resource-dir],
 803     [Relative directory from the Clang binary for resource files]),,
 804     withval="")
 805 AC_DEFINE_UNQUOTED(CLANG_RESOURCE_DIR,"$withval",
 806                    [Relative directory for resource files])
 807
 808 AC_ARG_WITH(c-include-dirs,
 809   AS_HELP_STRING([--with-c-include-dirs],
 810     [Colon separated list of directories clang will search for headers]),,
 811     withval="")
 812 AC_DEFINE_UNQUOTED(C_INCLUDE_DIRS,"$withval",
 813                    [Directories clang will search for headers])
 814
 815 AC_ARG_WITH(cxx-include-root,
 816   AS_HELP_STRING([--with-cxx-include-root],
 817     [Directory with the libstdc++ headers.]),,
 818     withval="")
 819 AC_DEFINE_UNQUOTED(CXX_INCLUDE_ROOT,"$withval",
 820                    [Directory with the libstdc++ headers.])
 821
 822 AC_ARG_WITH(cxx-include-arch,
 823   AS_HELP_STRING([--with-cxx-include-arch],
 824     [Architecture of the libstdc++ headers.]),,
 825     withval="")
 826 AC_DEFINE_UNQUOTED(CXX_INCLUDE_ARCH,"$withval",
 827                    [Arch the libstdc++ headers.])
 828
 829 AC_ARG_WITH(cxx-include-32bit-dir,
 830   AS_HELP_STRING([--with-cxx-include-32bit-dir],
 831     [32 bit multilib dir.]),,
 832     withval="")
 833 AC_DEFINE_UNQUOTED(CXX_INCLUDE_32BIT_DIR,"$withval",
 834                    [32 bit multilib directory.])
 835
 836 AC_ARG_WITH(cxx-include-64bit-dir,
 837   AS_HELP_STRING([--with-cxx-include-64bit-dir],
 838     [64 bit multilib directory.]),,
 839     withval="")
 840 AC_DEFINE_UNQUOTED(CXX_INCLUDE_64BIT_DIR,"$withval",
 841                    [64 bit multilib directory.])
 842
 843 dnl Allow linking of LLVM with GPLv3 binutils code.
 844 AC_ARG_WITH(binutils-include,
 845   AS_HELP_STRING([--with-binutils-include],
 846     [Specify path to binutils/include/ containing plugin-api.h file for gold plugin.]),,
 847   withval=default)
 848 case "$withval" in
 849   default) WITH_BINUTILS_INCDIR=default ;;
 850   /* | [[A-Za-z]]:[[\\/]]*)      WITH_BINUTILS_INCDIR=$withval ;;
 851   *) AC_MSG_ERROR([Invalid path for --with-binutils-include. Provide full path]) ;;
 852 esac
 853 if test "x$WITH_BINUTILS_INCDIR" != xdefault ; then
 854   AC_SUBST(BINUTILS_INCDIR,$WITH_BINUTILS_INCDIR)
 855   if test ! -f "$WITH_BINUTILS_INCDIR/plugin-api.h"; then
 856      echo "$WITH_BINUTILS_INCDIR/plugin-api.h"
 857      AC_MSG_ERROR([Invalid path to directory containing plugin-api.h.]);
 858   fi
 859 fi
 860
 861 dnl Specify the URL where bug reports should be submitted.
 862 AC_ARG_WITH(bug-report-url,
 863   AS_HELP_STRING([--with-bug-report-url],
 864     [Specify the URL where bug reports should be submitted (default=http://llvm.org/bugs/)]),,
 865     withval="http://llvm.org/bugs/")
 866 AC_DEFINE_UNQUOTED(BUG_REPORT_URL,"$withval",
 867                    [Bug report URL.])
 868
 869 dnl --enable-libffi : check whether the user wants to turn off libffi:
 870 AC_ARG_ENABLE(libffi,AS_HELP_STRING(
 871   --enable-libffi,[Check for the presence of libffi (default is NO)]),
 872   [case "$enableval" in
 873     yes) llvm_cv_enable_libffi="yes" ;;
 874     no)  llvm_cv_enable_libffi="no"  ;;
 875     *) AC_MSG_ERROR([Invalid setting for --enable-libffi. Use "yes" or "no"]) ;;
 876   esac],
 877   llvm_cv_enable_libffi=no)
 878
 879 dnl===-----------------------------------------------------------------------===
 880 dnl===
 881 dnl=== SECTION 4: Check for programs we need and that they are the right version
 882 dnl===
 883 dnl===-----------------------------------------------------------------------===
 884
 885 AC_PROG_NM
 886 AC_SUBST(NM)
 887
 888 dnl Check for the tools that the makefiles require
 889 AC_CHECK_GNU_MAKE
 890 AC_PROG_LN_S
 891 AC_PATH_PROG(CMP, [cmp], [cmp])
 892 AC_PATH_PROG(CP, [cp], [cp])
 893 AC_PATH_PROG(DATE, [date], [date])
 894 AC_PATH_PROG(FIND, [find], [find])
 895 AC_PATH_PROG(GREP, [grep], [grep])
 896 AC_PATH_PROG(MKDIR,[mkdir],[mkdir])
 897 AC_PATH_PROG(MV,   [mv],   [mv])
 898 AC_PROG_RANLIB
 899 AC_CHECK_TOOL(AR, ar, false)
 900 AC_PATH_PROG(RM,   [rm],   [rm])
 901 AC_PATH_PROG(SED,  [sed],  [sed])
 902 AC_PATH_PROG(TAR,  [tar],  [gtar])
 903 AC_PATH_PROG(BINPWD,[pwd],  [pwd])
 904
 905 dnl Looking for misc. graph plotting software
 906 AC_PATH_PROG(GRAPHVIZ, [Graphviz], [echo Graphviz])
 907 if test "$GRAPHVIZ" != "echo Graphviz" ; then
 908   AC_DEFINE([HAVE_GRAPHVIZ],[1],[Define if the Graphviz program is available])
 909   dnl If we're targeting for mingw we should emit windows paths, not msys
 910   if test "$llvm_cv_os_type" = "MingW" ; then
 911     GRAPHVIZ=`echo $GRAPHVIZ | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 912   fi
 913   AC_DEFINE_UNQUOTED([LLVM_PATH_GRAPHVIZ],"$GRAPHVIZ${EXEEXT}",
 914    [Define to path to Graphviz program if found or 'echo Graphviz' otherwise])
 915 fi
 916 AC_PATH_PROG(DOT, [dot], [echo dot])
 917 if test "$DOT" != "echo dot" ; then
 918   AC_DEFINE([HAVE_DOT],[1],[Define if the dot program is available])
 919   dnl If we're targeting for mingw we should emit windows paths, not msys
 920   if test "$llvm_cv_os_type" = "MingW" ; then
 921     DOT=`echo $DOT | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 922   fi
 923   AC_DEFINE_UNQUOTED([LLVM_PATH_DOT],"$DOT${EXEEXT}",
 924    [Define to path to dot program if found or 'echo dot' otherwise])
 925 fi
 926 AC_PATH_PROG(FDP, [fdp], [echo fdp])
 927 if test "$FDP" != "echo fdp" ; then
 928   AC_DEFINE([HAVE_FDP],[1],[Define if the neat program is available])
 929   dnl If we're targeting for mingw we should emit windows paths, not msys
 930   if test "$llvm_cv_os_type" = "MingW" ; then
 931     FDP=`echo $FDP | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 932   fi
 933   AC_DEFINE_UNQUOTED([LLVM_PATH_FDP],"$FDP${EXEEXT}",
 934    [Define to path to fdp program if found or 'echo fdp' otherwise])
 935 fi
 936 AC_PATH_PROG(NEATO, [neato], [echo neato])
 937 if test "$NEATO" != "echo neato" ; then
 938   AC_DEFINE([HAVE_NEATO],[1],[Define if the neat program is available])
 939   dnl If we're targeting for mingw we should emit windows paths, not msys
 940   if test "$llvm_cv_os_type" = "MingW" ; then
 941     NEATO=`echo $NEATO | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 942   fi
 943   AC_DEFINE_UNQUOTED([LLVM_PATH_NEATO],"$NEATO${EXEEXT}",
 944    [Define to path to neato program if found or 'echo neato' otherwise])
 945 fi
 946 AC_PATH_PROG(TWOPI, [twopi], [echo twopi])
 947 if test "$TWOPI" != "echo twopi" ; then
 948   AC_DEFINE([HAVE_TWOPI],[1],[Define if the neat program is available])
 949   dnl If we're targeting for mingw we should emit windows paths, not msys
 950   if test "$llvm_cv_os_type" = "MingW" ; then
 951     TWOPI=`echo $TWOPI | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 952   fi
 953   AC_DEFINE_UNQUOTED([LLVM_PATH_TWOPI],"$TWOPI${EXEEXT}",
 954    [Define to path to twopi program if found or 'echo twopi' otherwise])
 955 fi
 956 AC_PATH_PROG(CIRCO, [circo], [echo circo])
 957 if test "$CIRCO" != "echo circo" ; then
 958   AC_DEFINE([HAVE_CIRCO],[1],[Define if the neat program is available])
 959   dnl If we're targeting for mingw we should emit windows paths, not msys
 960   if test "$llvm_cv_os_type" = "MingW" ; then
 961     CIRCO=`echo $CIRCO | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 962   fi
 963   AC_DEFINE_UNQUOTED([LLVM_PATH_CIRCO],"$CIRCO${EXEEXT}",
 964    [Define to path to circo program if found or 'echo circo' otherwise])
 965 fi
 966 AC_PATH_PROGS(GV, [gv gsview32], [echo gv])
 967 if test "$GV" != "echo gv" ; then
 968   AC_DEFINE([HAVE_GV],[1],[Define if the gv program is available])
 969   dnl If we're targeting for mingw we should emit windows paths, not msys
 970   if test "$llvm_cv_os_type" = "MingW" ; then
 971     GV=`echo $GV | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 972   fi
 973   AC_DEFINE_UNQUOTED([LLVM_PATH_GV],"$GV${EXEEXT}",
 974    [Define to path to gv program if found or 'echo gv' otherwise])
 975 fi
 976 AC_PATH_PROG(DOTTY, [dotty], [echo dotty])
 977 if test "$DOTTY" != "echo dotty" ; then
 978   AC_DEFINE([HAVE_DOTTY],[1],[Define if the dotty program is available])
 979   dnl If we're targeting for mingw we should emit windows paths, not msys
 980   if test "$llvm_cv_os_type" = "MingW" ; then
 981     DOTTY=`echo $DOTTY | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 982   fi
 983   AC_DEFINE_UNQUOTED([LLVM_PATH_DOTTY],"$DOTTY${EXEEXT}",
 984    [Define to path to dotty program if found or 'echo dotty' otherwise])
 985 fi
 986 AC_PATH_PROG(XDOT_PY, [xdot.py], [echo xdot.py])
 987 if test "$XDOT_PY" != "echo xdot.py" ; then
 988   AC_DEFINE([HAVE_XDOT_PY],[1],[Define if the xdot.py program is available])
 989   dnl If we're targeting for mingw we should emit windows paths, not msys
 990   if test "$llvm_cv_os_type" = "MingW" ; then
 991     XDOT_PY=`echo $XDOT_PY | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 992   fi
 993   AC_DEFINE_UNQUOTED([LLVM_PATH_XDOT_PY],"$XDOT_PY${EXEEXT}",
 994    [Define to path to xdot.py program if found or 'echo xdot.py' otherwise])
 995 fi
 996
 997 dnl Look for a sufficiently recent version of Perl.
 998 LLVM_PROG_PERL([5.006])
 999 AC_SUBST(PERL)
1000 if test x"$PERL" = xnone; then
1001    AC_SUBST(HAVE_PERL,0)
1002    AC_MSG_ERROR([perl is required but was not found, please install it])
1003 else
1004    AC_SUBST(HAVE_PERL,1)
1005 fi
1006
1007 dnl Find the install program
1008 AC_PROG_INSTALL
1009 dnl Prepend src dir to install path dir if it's a relative path
1010 dnl This is a hack for installs that take place in something other
1011 dnl than the top level.
1012 case "$INSTALL" in
1013  [[\\/$]]* | ?:[[\\/]]* ) ;;
1014  *)  INSTALL="\\\$(TOPSRCDIR)/$INSTALL" ;;
1015 esac
1016
1017 dnl Checks for documentation and testing tools that we can do without. If these
1018 dnl are not found then they are set to "true" which always succeeds but does
1019 dnl nothing. This just lets the build output show that we could have done
1020 dnl something if the tool was available.
1021 AC_PATH_PROG(BZIP2, [bzip2])
1022 AC_PATH_PROG(CAT, [cat])
1023 AC_PATH_PROG(DOXYGEN, [doxygen])
1024 AC_PATH_PROG(GROFF, [groff])
1025 AC_PATH_PROG(GZIPBIN, [gzip])
1026 AC_PATH_PROG(POD2HTML, [pod2html])
1027 AC_PATH_PROG(POD2MAN, [pod2man])
1028 AC_PATH_PROG(PDFROFF, [pdfroff])
1029 AC_PATH_PROG(RUNTEST, [runtest])
1030 DJ_AC_PATH_TCLSH
1031 AC_PATH_PROG(ZIP, [zip])
1032 AC_PATH_PROGS(OCAMLC, [ocamlc])
1033 AC_PATH_PROGS(OCAMLOPT, [ocamlopt])
1034 AC_PATH_PROGS(OCAMLDEP, [ocamldep])
1035 AC_PATH_PROGS(OCAMLDOC, [ocamldoc])
1036 AC_PATH_PROGS(GAS, [gas as])
1037
1038 dnl Get the version of the linker in use.
1039 AC_LINK_GET_VERSION
1040
1041 dnl Determine whether the linker supports the -R option.
1042 AC_LINK_USE_R
1043
1044 dnl Determine whether the linker supports the -export-dynamic option.
1045 AC_LINK_EXPORT_DYNAMIC
1046
1047 dnl Determine whether the linker supports the --version-script option.
1048 AC_LINK_VERSION_SCRIPT
1049
1050 dnl Check for libtool and the library that has dlopen function (which must come
1051 dnl before the AC_PROG_LIBTOOL check in order to enable dlopening libraries with
1052 dnl libtool).
1053 AC_LIBTOOL_DLOPEN
1054 AC_LIB_LTDL
1055
1056 AC_MSG_CHECKING([tool compatibility])
1057
1058 dnl Ensure that compilation tools are GCC or a GNU compatible compiler such as
1059 dnl ICC; we use GCC specific options in the makefiles so the compiler needs
1060 dnl to support those options.
1061 dnl "icc" emits gcc signatures
1062 dnl "icc -no-gcc" emits no gcc signature BUT is still compatible
1063 ICC=no
1064 IXX=no
1065 case $CC in
1066   icc*|icpc*)
1067     ICC=yes
1068     IXX=yes
1069     ;;
1070    *)
1071     ;;
1072 esac
1073
1074 if test "$GCC" != "yes" && test "$ICC" != "yes"
1075 then
1076   AC_MSG_ERROR([gcc|icc required but not found])
1077 fi
1078
1079 dnl Ensure that compilation tools are compatible with GCC extensions
1080 if test "$GXX" != "yes" && test "$IXX" != "yes"
1081 then
1082   AC_MSG_ERROR([g++|clang++|icc required but not found])
1083 fi
1084
1085 dnl Verify that GCC is version 3.0 or higher
1086 if test "$GCC" = "yes"
1087 then
1088   AC_COMPILE_IFELSE([[#if !defined(__GNUC__) || __GNUC__ < 3
1089 #error Unsupported GCC version
1090 #endif
1091 ]], [], [AC_MSG_ERROR([gcc 3.x required, but you have a lower version])])
1092 fi
1093
1094 dnl Check for GNU Make.  We use its extensions, so don't build without it
1095 if test -z "$llvm_cv_gnu_make_command"
1096 then
1097   AC_MSG_ERROR([GNU Make required but not found])
1098 fi
1099
1100 dnl Tool compatibility is okay if we make it here.
1101 AC_MSG_RESULT([ok])
1102
1103 dnl Check optional compiler flags.
1104 AC_MSG_CHECKING([optional compiler flags])
1105 CXX_FLAG_CHECK(NO_VARIADIC_MACROS, [-Wno-variadic-macros])
1106 CXX_FLAG_CHECK(NO_MISSING_FIELD_INITIALIZERS, [-Wno-missing-field-initializers])
1107 AC_MSG_RESULT([$NO_VARIADIC_MACROS $NO_MISSING_FIELD_INITIALIZERS])
1108
1109 dnl===-----------------------------------------------------------------------===
1110 dnl===
1111 dnl=== SECTION 5: Check for libraries
1112 dnl===
1113 dnl===-----------------------------------------------------------------------===
1114
1115 AC_CHECK_LIB(m,sin)
1116 if test "$llvm_cv_os_type" = "MingW" ; then
1117   AC_CHECK_LIB(imagehlp, main)
1118   AC_CHECK_LIB(psapi, main)
1119 fi
1120
1121 dnl dlopen() is required for plugin support.
1122 AC_SEARCH_LIBS(dlopen,dl,AC_DEFINE([HAVE_DLOPEN],[1],
1123                [Define if dlopen() is available on this platform.]),
1124                AC_MSG_WARN([dlopen() not found - disabling plugin support]))
1125
1126 dnl libffi is optional; used to call external functions from the interpreter
1127 if test "$llvm_cv_enable_libffi" = "yes" ; then
1128   AC_SEARCH_LIBS(ffi_call,ffi,AC_DEFINE([HAVE_FFI_CALL],[1],
1129                  [Define if libffi is available on this platform.]),
1130                  AC_MSG_ERROR([libffi not found - configure without --enable-libffi to compile without it]))
1131 fi
1132
1133 dnl mallinfo is optional; the code can compile (minus features) without it
1134 AC_SEARCH_LIBS(mallinfo,malloc,AC_DEFINE([HAVE_MALLINFO],[1],
1135                [Define if mallinfo() is available on this platform.]))
1136
1137 dnl pthread locking functions are optional - but llvm will not be thread-safe
1138 dnl without locks.
1139 if test "$ENABLE_THREADS" -eq 1 && test "$ENABLE_PTHREADS" -eq 1 ; then
1140   AC_CHECK_LIB(pthread, pthread_mutex_init)
1141   AC_SEARCH_LIBS(pthread_mutex_lock,pthread,
1142                  AC_DEFINE([HAVE_PTHREAD_MUTEX_LOCK],[1],
1143                            [Have pthread_mutex_lock]))
1144   AC_SEARCH_LIBS(pthread_rwlock_init,pthread,
1145                  AC_DEFINE([HAVE_PTHREAD_RWLOCK_INIT],[1],
1146                  [Have pthread_rwlock_init]))
1147   AC_SEARCH_LIBS(pthread_getspecific,pthread,
1148                  AC_DEFINE([HAVE_PTHREAD_GETSPECIFIC],[1],
1149                  [Have pthread_getspecific]))
1150 fi
1151
1152 dnl Allow extra x86-disassembler library
1153 AC_ARG_WITH(udis86,
1154   AS_HELP_STRING([--with-udis86=<path>],
1155     [Use udis86 external x86 disassembler library]),
1156     [
1157       AC_SUBST(USE_UDIS86, [1])
1158       case "$withval" in
1159         /usr/lib|yes) ;;
1160         *) LDFLAGS="$LDFLAGS -L${withval}" ;;
1161       esac
1162       AC_CHECK_LIB(udis86, ud_init, [], [
1163         echo "Error! You need to have libudis86 around."
1164         exit -1
1165       ])
1166     ],
1167     AC_SUBST(USE_UDIS86, [0]))
1168 AC_DEFINE_UNQUOTED([USE_UDIS86],$USE_UDIS86,
1169                    [Define if use udis86 library])
1170
1171 dnl Allow OProfile support for JIT output.
1172 AC_ARG_WITH(oprofile,
1173   AS_HELP_STRING([--with-oprofile=<prefix>],
1174     [Tell OProfile >= 0.9.4 how to symbolize JIT output]),
1175     [
1176       AC_SUBST(USE_OPROFILE, [1])
1177       case "$withval" in
1178         /usr|yes) llvm_cv_oppath=/usr/lib/oprofile ;;
1179         no) llvm_cv_oppath=
1180             AC_SUBST(USE_OPROFILE, [0]) ;;
1181         *) llvm_cv_oppath="${withval}/lib/oprofile"
1182            CPPFLAGS="-I${withval}/include";;
1183       esac
1184       if test -n "$llvm_cv_oppath" ; then
1185         LIBS="$LIBS -L${llvm_cv_oppath} -Wl,-rpath,${llvm_cv_oppath}"
1186         dnl Work around http://bugs.debian.org/cgi-bin/bugreport.cgi?bug=537744:
1187         dnl libbfd is not included properly in libopagent in some Debian
1188         dnl versions.  If libbfd isn't found at all, we assume opagent works
1189         dnl anyway.
1190         AC_SEARCH_LIBS(bfd_init, bfd, [], [])
1191         AC_SEARCH_LIBS(op_open_agent, opagent, [], [
1192           echo "Error! You need to have libopagent around."
1193           exit -1
1194         ])
1195         AC_CHECK_HEADER([opagent.h], [], [
1196           echo "Error! You need to have opagent.h around."
1197           exit -1
1198           ])
1199       fi
1200     ],
1201     [
1202       AC_SUBST(USE_OPROFILE, [0])
1203     ])
1204 AC_DEFINE_UNQUOTED([USE_OPROFILE],$USE_OPROFILE,
1205                    [Define if we have the oprofile JIT-support library])
1206
1207 dnl===-----------------------------------------------------------------------===
1208 dnl===
1209 dnl=== SECTION 6: Check for header files
1210 dnl===
1211 dnl===-----------------------------------------------------------------------===
1212
1213 dnl First, use autoconf provided macros for specific headers that we need
1214 dnl We don't check for ancient stuff or things that are guaranteed to be there
1215 dnl by the C++ standard. We always use the <cfoo> versions of <foo.h> C headers.
1216 dnl Generally we're looking for POSIX headers.
1217 AC_HEADER_DIRENT
1218 AC_HEADER_MMAP_ANONYMOUS
1219 AC_HEADER_STAT
1220 AC_HEADER_SYS_WAIT
1221 AC_HEADER_TIME
1222
1223 AC_CHECK_HEADERS([dlfcn.h execinfo.h fcntl.h inttypes.h limits.h link.h])
1224 AC_CHECK_HEADERS([malloc.h setjmp.h signal.h stdint.h termios.h unistd.h])
1225 AC_CHECK_HEADERS([utime.h windows.h])
1226 AC_CHECK_HEADERS([sys/mman.h sys/param.h sys/resource.h sys/time.h sys/uio.h])
1227 AC_CHECK_HEADERS([sys/types.h sys/ioctl.h malloc/malloc.h mach/mach.h])
1228 AC_CHECK_HEADERS([valgrind/valgrind.h])
1229 AC_CHECK_HEADERS([fenv.h])
1230 if test "$ENABLE_THREADS" -eq 1 && test "$ENABLE_PTHREADS" -eq 1 ; then
1231   AC_CHECK_HEADERS(pthread.h,
1232                    AC_SUBST(HAVE_PTHREAD, 1),
1233                    AC_SUBST(HAVE_PTHREAD, 0))
1234 else
1235   AC_SUBST(HAVE_PTHREAD, 0)
1236 fi
1237
1238 dnl Try to find ffi.h.
1239 if test "$llvm_cv_enable_libffi" = "yes" ; then
1240   AC_CHECK_HEADERS([ffi.h ffi/ffi.h])
1241 fi
1242
1243 dnl Try to find Darwin specific crash reporting libraries.
1244 AC_CHECK_HEADERS([CrashReporterClient.h])
1245
1246 dnl Try to find Darwin specific crash reporting global.
1247 AC_MSG_CHECKING([__crashreporter_info__])
1248 AC_LINK_IFELSE(
1249   AC_LANG_SOURCE(
1250     [[extern const char *__crashreporter_info__;
1251       int main() {
1252         __crashreporter_info__ = "test";
1253         return 0;
1254       }
1255     ]]),
1256   AC_MSG_RESULT(yes)
1257   AC_DEFINE(HAVE_CRASHREPORTER_INFO, 1, Can use __crashreporter_info__),
1258   AC_MSG_RESULT(no)
1259   AC_DEFINE(HAVE_CRASHREPORTER_INFO, 0,
1260             Define if __crashreporter_info__ exists.))
1261
1262 dnl===-----------------------------------------------------------------------===
1263 dnl===
1264 dnl=== SECTION 7: Check for types and structures
1265 dnl===
1266 dnl===-----------------------------------------------------------------------===
1267
1268 AC_HUGE_VAL_CHECK
1269 AC_TYPE_PID_T
1270 AC_TYPE_SIZE_T
1271 AC_DEFINE_UNQUOTED([RETSIGTYPE],[void],[Define as the return type of signal handlers (`int' or `void').])
1272 AC_STRUCT_TM
1273 AC_CHECK_TYPES([int64_t],,AC_MSG_ERROR([Type int64_t required but not found]))
1274 AC_CHECK_TYPES([uint64_t],,
1275          AC_CHECK_TYPES([u_int64_t],,
1276          AC_MSG_ERROR([Type uint64_t or u_int64_t required but not found])))
1277
1278 dnl===-----------------------------------------------------------------------===
1279 dnl===
1280 dnl=== SECTION 8: Check for specific functions needed
1281 dnl===
1282 dnl===-----------------------------------------------------------------------===
1283
1284 AC_CHECK_FUNCS([backtrace ceilf floorf roundf rintf nearbyintf getcwd ])
1285 AC_CHECK_FUNCS([powf fmodf strtof round ])
1286 AC_CHECK_FUNCS([getpagesize getrusage getrlimit setrlimit gettimeofday ])
1287 AC_CHECK_FUNCS([isatty mkdtemp mkstemp ])
1288 AC_CHECK_FUNCS([mktemp posix_spawn realpath sbrk setrlimit strdup ])
1289 AC_CHECK_FUNCS([strerror strerror_r setenv ])
1290 AC_CHECK_FUNCS([strtoll strtoq sysconf malloc_zone_statistics ])
1291 AC_CHECK_FUNCS([setjmp longjmp sigsetjmp siglongjmp writev])
1292 AC_C_PRINTF_A
1293 AC_FUNC_RAND48
1294
1295 dnl Check the declaration "Secure API" on Windows environments.
1296 AC_CHECK_DECLS([strerror_s])
1297
1298 dnl Check symbols in libgcc.a for JIT on Mingw.
1299 if test "$llvm_cv_os_type" = "MingW" ; then
1300   AC_CHECK_LIB(gcc,_alloca,AC_DEFINE([HAVE__ALLOCA],[1],[Have host's _alloca]))
1301   AC_CHECK_LIB(gcc,__alloca,AC_DEFINE([HAVE___ALLOCA],[1],[Have host's __alloca]))
1302   AC_CHECK_LIB(gcc,__chkstk,AC_DEFINE([HAVE___CHKSTK],[1],[Have host's __chkstk]))
1303   AC_CHECK_LIB(gcc,___chkstk,AC_DEFINE([HAVE____CHKSTK],[1],[Have host's ___chkstk]))
1304
1305   AC_CHECK_LIB(gcc,__ashldi3,AC_DEFINE([HAVE___ASHLDI3],[1],[Have host's __ashldi3]))
1306   AC_CHECK_LIB(gcc,__ashrdi3,AC_DEFINE([HAVE___ASHRDI3],[1],[Have host's __ashrdi3]))
1307   AC_CHECK_LIB(gcc,__divdi3,AC_DEFINE([HAVE___DIVDI3],[1],[Have host's __divdi3]))
1308   AC_CHECK_LIB(gcc,__fixdfdi,AC_DEFINE([HAVE___FIXDFDI],[1],[Have host's __fixdfdi]))
1309   AC_CHECK_LIB(gcc,__fixsfdi,AC_DEFINE([HAVE___FIXSFDI],[1],[Have host's __fixsfdi]))
1310   AC_CHECK_LIB(gcc,__floatdidf,AC_DEFINE([HAVE___FLOATDIDF],[1],[Have host's __floatdidf]))
1311   AC_CHECK_LIB(gcc,__lshrdi3,AC_DEFINE([HAVE___LSHRDI3],[1],[Have host's __lshrdi3]))
1312   AC_CHECK_LIB(gcc,__moddi3,AC_DEFINE([HAVE___MODDI3],[1],[Have host's __moddi3]))
1313   AC_CHECK_LIB(gcc,__udivdi3,AC_DEFINE([HAVE___UDIVDI3],[1],[Have host's __udivdi3]))
1314   AC_CHECK_LIB(gcc,__umoddi3,AC_DEFINE([HAVE___UMODDI3],[1],[Have host's __umoddi3]))
1315
1316   AC_CHECK_LIB(gcc,__main,AC_DEFINE([HAVE___MAIN],[1],[Have host's __main]))
1317   AC_CHECK_LIB(gcc,__cmpdi2,AC_DEFINE([HAVE___CMPDI2],[1],[Have host's __cmpdi2]))
1318 fi
1319
1320 dnl Check Win32 API EnumerateLoadedModules.
1321 if test "$llvm_cv_os_type" = "MingW" ; then
1322   AC_MSG_CHECKING([whether EnumerateLoadedModules() accepts new decl])
1323   AC_COMPILE_IFELSE([[#include <windows.h>
1324 #include <imagehlp.h>
1325 extern void foo(PENUMLOADED_MODULES_CALLBACK);
1326 extern void foo(BOOL(CALLBACK*)(PCSTR,ULONG_PTR,ULONG,PVOID));]],
1327 [
1328   AC_MSG_RESULT([yes])
1329   llvm_cv_win32_elmcb_pcstr="PCSTR"
1330 ],
1331 [
1332   AC_MSG_RESULT([no])
1333   llvm_cv_win32_elmcb_pcstr="PSTR"
1334 ])
1335   AC_DEFINE_UNQUOTED([WIN32_ELMCB_PCSTR],$llvm_cv_win32_elmcb_pcstr,[Type of 1st arg on ELM Callback])
1336 fi
1337
1338 dnl Check for variations in the Standard C++ library and STL. These macros are
1339 dnl provided by LLVM in the autoconf/m4 directory.
1340 AC_FUNC_ISNAN
1341 AC_FUNC_ISINF
1342
1343 dnl Check for mmap support.We also need to know if /dev/zero is required to
1344 dnl be opened for allocating RWX memory.
1345 dnl Make sure we aren't attempting to configure for an unknown system
1346 if test "$llvm_cv_platform_type" = "Unix" ; then
1347   AC_FUNC_MMAP
1348   AC_FUNC_MMAP_FILE
1349   AC_NEED_DEV_ZERO_FOR_MMAP
1350
1351   if test "$ac_cv_func_mmap_fixed_mapped" = "no"
1352   then
1353     AC_MSG_WARN([mmap() of a fixed address required but not supported])
1354   fi
1355   if test "$ac_cv_func_mmap_file" = "no"
1356   then
1357     AC_MSG_WARN([mmap() of files required but not found])
1358   fi
1359 fi
1360
1361 dnl atomic builtins are required for threading support.
1362 AC_MSG_CHECKING(for GCC atomic builtins)
1363 dnl Since we'll be using these atomic builtins in C++ files we should test
1364 dnl the C++ compiler.
1365 AC_LANG_PUSH([C++])
1366 AC_LINK_IFELSE(
1367   AC_LANG_SOURCE(
1368     [[int main() {
1369         volatile unsigned long val = 1;
1370         __sync_synchronize();
1371         __sync_val_compare_and_swap(&val, 1, 0);
1372         __sync_add_and_fetch(&val, 1);
1373         __sync_sub_and_fetch(&val, 1);
1374         return 0;
1375       }
1376     ]]),
1377   AC_LANG_POP([C++])
1378   AC_MSG_RESULT(yes)
1379   AC_DEFINE(LLVM_HAS_ATOMICS, 1, Has gcc/MSVC atomic intrinsics),
1380   AC_MSG_RESULT(no)
1381   AC_DEFINE(LLVM_HAS_ATOMICS, 0, Has gcc/MSVC atomic intrinsics)
1382   AC_MSG_WARN([LLVM will be built thread-unsafe because atomic builtins are missing]))
1383
1384 dnl===-----------------------------------------------------------------------===
1385 dnl===
1386 dnl=== SECTION 9: Additional checks, variables, etc.
1387 dnl===
1388 dnl===-----------------------------------------------------------------------===
1389
1390 dnl Handle 32-bit linux systems running a 64-bit kernel.
1391 dnl This has to come after section 4 because it invokes the compiler.
1392 if test "$llvm_cv_os_type" = "Linux" -a "$llvm_cv_target_arch" = "x86_64" ; then
1393   AC_IS_LINUX_MIXED
1394   if test "$llvm_cv_linux_mixed" = "yes"; then
1395     llvm_cv_target_arch="x86"
1396     ARCH="x86"
1397   fi
1398 fi
1399
1400 dnl Check whether __dso_handle is present
1401 AC_CHECK_FUNCS([__dso_handle])
1402
1403 dnl Propagate the shared library extension that the libltdl checks did to
1404 dnl the Makefiles so we can use it there too
1405 AC_SUBST(SHLIBEXT,$libltdl_cv_shlibext)
1406
1407 dnl Propagate the run-time library path variable that the libltdl
1408 dnl checks found to the Makefiles so we can use it there too
1409 AC_SUBST(SHLIBPATH_VAR,$libltdl_cv_shlibpath_var)
1410
1411 # Translate the various configuration directories and other basic
1412 # information into substitutions that will end up in Makefile.config.in
1413 # that these configured values can be used by the makefiles
1414 if test "${prefix}" = "NONE" ; then
1415   prefix="/usr/local"
1416 fi
1417 eval LLVM_PREFIX="${prefix}";
1418 eval LLVM_BINDIR="${prefix}/bin";
1419 eval LLVM_LIBDIR="${prefix}/lib";
1420 eval LLVM_DATADIR="${prefix}/share/llvm";
1421 eval LLVM_DOCSDIR="${prefix}/share/doc/llvm";
1422 eval LLVM_ETCDIR="${prefix}/etc/llvm";
1423 eval LLVM_INCLUDEDIR="${prefix}/include";
1424 eval LLVM_INFODIR="${prefix}/info";
1425 eval LLVM_MANDIR="${prefix}/man";
1426 LLVM_CONFIGTIME=`date`
1427 AC_SUBST(LLVM_PREFIX)
1428 AC_SUBST(LLVM_BINDIR)
1429 AC_SUBST(LLVM_LIBDIR)
1430 AC_SUBST(LLVM_DATADIR)
1431 AC_SUBST(LLVM_DOCSDIR)
1432 AC_SUBST(LLVM_ETCDIR)
1433 AC_SUBST(LLVM_INCLUDEDIR)
1434 AC_SUBST(LLVM_INFODIR)
1435 AC_SUBST(LLVM_MANDIR)
1436 AC_SUBST(LLVM_CONFIGTIME)
1437
1438 # Place the various directores into the config.h file as #defines so that we
1439 # can know about the installation paths within LLVM.
1440 AC_DEFINE_UNQUOTED(LLVM_PREFIX,"$LLVM_PREFIX",
1441                    [Installation prefix directory])
1442 AC_DEFINE_UNQUOTED(LLVM_BINDIR, "$LLVM_BINDIR",
1443                    [Installation directory for binary executables])
1444 AC_DEFINE_UNQUOTED(LLVM_LIBDIR, "$LLVM_LIBDIR",
1445                    [Installation directory for libraries])
1446 AC_DEFINE_UNQUOTED(LLVM_DATADIR, "$LLVM_DATADIR",
1447                    [Installation directory for data files])
1448 AC_DEFINE_UNQUOTED(LLVM_DOCSDIR, "$LLVM_DOCSDIR",
1449                    [Installation directory for documentation])
1450 AC_DEFINE_UNQUOTED(LLVM_ETCDIR, "$LLVM_ETCDIR",
1451                    [Installation directory for config files])
1452 AC_DEFINE_UNQUOTED(LLVM_INCLUDEDIR, "$LLVM_INCLUDEDIR",
1453                    [Installation directory for include files])
1454 AC_DEFINE_UNQUOTED(LLVM_INFODIR, "$LLVM_INFODIR",
1455                    [Installation directory for .info files])
1456 AC_DEFINE_UNQUOTED(LLVM_MANDIR, "$LLVM_MANDIR",
1457                    [Installation directory for man pages])
1458 AC_DEFINE_UNQUOTED(LLVM_CONFIGTIME, "$LLVM_CONFIGTIME",
1459                    [Time at which LLVM was configured])
1460 AC_DEFINE_UNQUOTED(LLVM_HOSTTRIPLE, "$host",
1461                    [Host triple we were built on])
1462
1463 # Determine which bindings to build.
1464 if test "$BINDINGS_TO_BUILD" = auto ; then
1465   BINDINGS_TO_BUILD=""
1466   if test "x$OCAMLC" != x -a "x$OCAMLDEP" != x ; then
1467     BINDINGS_TO_BUILD="ocaml $BINDINGS_TO_BUILD"
1468   fi
1469 fi
1470 AC_SUBST(BINDINGS_TO_BUILD,$BINDINGS_TO_BUILD)
1471
1472 # This isn't really configurey, but it avoids having to repeat the list in
1473 # other files.
1474 AC_SUBST(ALL_BINDINGS,ocaml)
1475
1476 # Do any work necessary to ensure that bindings have what they need.
1477 binding_prereqs_failed=0
1478 for a_binding in $BINDINGS_TO_BUILD ; do
1479   case "$a_binding" in
1480   ocaml)
1481     if test "x$OCAMLC" = x ; then
1482       AC_MSG_WARN([--enable-bindings=ocaml specified, but ocamlc not found. Try configure OCAMLC=/path/to/ocamlc])
1483       binding_prereqs_failed=1
1484     fi
1485     if test "x$OCAMLDEP" = x ; then
1486       AC_MSG_WARN([--enable-bindings=ocaml specified, but ocamldep not found. Try configure OCAMLDEP=/path/to/ocamldep])
1487       binding_prereqs_failed=1
1488     fi
1489     if test "x$OCAMLOPT" = x ; then
1490       AC_MSG_WARN([--enable-bindings=ocaml specified, but ocamlopt not found. Try configure OCAMLOPT=/path/to/ocamlopt])
1491       dnl ocamlopt is optional!
1492     fi
1493     if test "x$with_ocaml_libdir" != xauto ; then
1494       AC_SUBST(OCAML_LIBDIR,$with_ocaml_libdir)
1495     else
1496       ocaml_stdlib="`"$OCAMLC" -where`"
1497       if test "$LLVM_PREFIX" '<' "$ocaml_stdlib" -a "$ocaml_stdlib" '<' "$LLVM_PREFIX~"
1498       then
1499         # ocaml stdlib is beneath our prefix; use stdlib
1500         AC_SUBST(OCAML_LIBDIR,$ocaml_stdlib)
1501       else
1502         # ocaml stdlib is outside our prefix; use libdir/ocaml
1503         AC_SUBST(OCAML_LIBDIR,$LLVM_LIBDIR/ocaml)
1504       fi
1505     fi
1506     ;;
1507   esac
1508 done
1509 if test "$binding_prereqs_failed" = 1 ; then
1510   AC_MSG_ERROR([Prequisites for bindings not satisfied. Fix them or use configure --disable-bindings.])
1511 fi
1512
1513 dnl Determine whether the compiler supports -fvisibility-inlines-hidden.
1514 AC_CXX_USE_VISIBILITY_INLINES_HIDDEN
1515
1516 dnl Determine linker rpath flag
1517 if test "$llvm_cv_link_use_r" = "yes" ; then
1518   RPATH="-Wl,-R"
1519 else
1520   RPATH="-Wl,-rpath"
1521 fi
1522 AC_SUBST(RPATH)
1523
1524 dnl Determine linker rdynamic flag
1525 if test "$llvm_cv_link_use_export_dynamic" = "yes" ; then
1526   RDYNAMIC="-Wl,-export-dynamic"
1527 else
1528   RDYNAMIC=""
1529 fi
1530 AC_SUBST(RDYNAMIC)
1531
1532 dnl===-----------------------------------------------------------------------===
1533 dnl===
1534 dnl=== SECTION 10: Specify the output files and generate it
1535 dnl===
1536 dnl===-----------------------------------------------------------------------===
1537
1538 dnl Configure header files
1539 dnl WARNING: dnl If you add or remove any of the following config headers, then
1540 dnl you MUST also update Makefile.rules so that the variable FilesToConfig
1541 dnl contains the same list of files as AC_CONFIG_HEADERS below. This ensures the
1542 dnl files can be updated automatically when their *.in sources change.
1543 AC_CONFIG_HEADERS([include/llvm/Config/config.h include/llvm/Config/llvm-config.h])
1544 AH_TOP([#ifndef CONFIG_H
1545 #define CONFIG_H])
1546 AH_BOTTOM([#endif])
1547
1548 AC_CONFIG_FILES([include/llvm/Config/Targets.def])
1549 AC_CONFIG_FILES([include/llvm/Config/AsmPrinters.def])
1550 AC_CONFIG_FILES([include/llvm/Config/AsmParsers.def])
1551 AC_CONFIG_FILES([include/llvm/Config/Disassemblers.def])
1552 AC_CONFIG_HEADERS([include/llvm/Support/DataTypes.h])
1553
1554 dnl Configure the makefile's configuration data
1555 AC_CONFIG_FILES([Makefile.config])
1556
1557 dnl Configure the RPM spec file for LLVM
1558 AC_CONFIG_FILES([llvm.spec])
1559
1560 dnl Configure doxygen's configuration file
1561 AC_CONFIG_FILES([docs/doxygen.cfg])
1562 if test -f ${srcdir}/tools/clang/README.txt; then
1563   AC_CONFIG_FILES([tools/clang/docs/doxygen.cfg])
1564 fi
1565
1566 dnl Do the first stage of configuration for llvm-config.in.
1567 AC_CONFIG_FILES([tools/llvm-config/llvm-config.in])
1568
1569 dnl OCaml findlib META file
1570 AC_CONFIG_FILES([bindings/ocaml/llvm/META.llvm])
1571
1572 dnl Do special configuration of Makefiles
1573 AC_CONFIG_COMMANDS([setup],,[llvm_src="${srcdir}"])
1574 AC_CONFIG_MAKEFILE(Makefile)
1575 AC_CONFIG_MAKEFILE(Makefile.common)
1576 AC_CONFIG_MAKEFILE(examples/Makefile)
1577 AC_CONFIG_MAKEFILE(lib/Makefile)
1578 AC_CONFIG_MAKEFILE(runtime/Makefile)
1579 AC_CONFIG_MAKEFILE(test/Makefile)
1580 AC_CONFIG_MAKEFILE(test/Makefile.tests)
1581 AC_CONFIG_MAKEFILE(unittests/Makefile)
1582 AC_CONFIG_MAKEFILE(tools/Makefile)
1583 AC_CONFIG_MAKEFILE(utils/Makefile)
1584 AC_CONFIG_MAKEFILE(projects/Makefile)
1585 AC_CONFIG_MAKEFILE(bindings/Makefile)
1586 AC_CONFIG_MAKEFILE(bindings/ocaml/Makefile.ocaml)
1587
1588 dnl Finally, crank out the output
1589 AC_OUTPUT