autoconf/configure.ac

   1 dnl === configure.ac --------------------------------------------------------===
   2 dnl                     The LLVM Compiler Infrastructure
   3 dnl
   4 dnl This file was developed by the LLVM research group and is distributed under
   5 dnl the University of Illinois Open Source License. See LICENSE.TXT for details.
   6 dnl
   7 dnl===-----------------------------------------------------------------------===
   8 dnl This is the LLVM configuration script. It is processed by the autoconf
   9 dnl program to produce a script named configure. This script contains the
  10 dnl configuration checks that LLVM needs in order to support multiple platforms.
  11 dnl This file is composed of 10 sections per the recommended organization of
  12 dnl autoconf input defined in the autoconf documentation. As this file evolves,
  13 dnl please keep the various types of checks within their sections. The sections
  14 dnl are as follows:
  15 dnl
  16 dnl SECTION 1: Initialization & Setup
  17 dnl SECTION 2: Architecture, target, and host checks
  18 dnl SECTION 3: Command line arguments for the configure script.
  19 dnl SECTION 4: Check for programs we need and that they are the right version
  20 dnl SECTION 5: Check for libraries
  21 dnl SECTION 6: Check for header files
  22 dnl SECTION 7: Check for types and structures
  23 dnl SECTION 8: Check for specific functions needed
  24 dnl SECTION 9: Additional checks, variables, etc.
  25 dnl SECTION 10: Specify the output files and generate it
  26 dnl
  27 dnl===-----------------------------------------------------------------------===
  28 dnl===
  29 dnl=== SECTION 1: Initialization & Setup
  30 dnl===
  31 dnl===-----------------------------------------------------------------------===
  32 dnl Initialize autoconf and define the package name, version number and
  33 dnl email address for reporting bugs.
  34 AC_INIT([[llvm]],[[1.8cvs]],[llvmbugs@cs.uiuc.edu])
  35
  36 dnl Provide a copyright substitution and ensure the copyright notice is included
  37 dnl in the output of --version option of the generated configure script.
  38 AC_SUBST(LLVM_COPYRIGHT,["Copyright (c) 2003-2005 University of Illinois at Urbana-Champaign."])
  39 AC_COPYRIGHT([Copyright (c) 2003-2005 University of Illinois at Urbana-Champaign.])
  40
  41 dnl Indicate that we require autoconf 2.59 or later. Ths is needed because we
  42 dnl use some autoconf macros only available in 2.59.
  43 AC_PREREQ(2.59)
  44
  45 dnl Verify that the source directory is valid. This makes sure that we are
  46 dnl configuring LLVM and not some other package (it validates --srcdir argument)
  47 AC_CONFIG_SRCDIR([lib/VMCore/Module.cpp])
  48
  49 dnl Place all of the extra autoconf files into the config subdirectory. Tell
  50 dnl various tools where the m4 autoconf macros are.
  51 AC_CONFIG_AUX_DIR([autoconf])
  52
  53 dnl Quit if the source directory has already been configured.
  54 dnl NOTE: This relies upon undocumented autoconf behavior.
  55 if test ${srcdir} != "." ; then
  56   if test -f ${srcdir}/include/llvm/Config/config.h ; then
  57     AC_MSG_ERROR([Already configured in ${srcdir}])
  58   fi
  59 fi
  60
  61 dnl Configure all of the projects present in our source tree. While we could
  62 dnl just AC_CONFIG_SUBDIRS on the set of directories in projects that have a
  63 dnl configure script, that usage of the AC_CONFIG_SUBDIRS macro is deprecated.
  64 dnl Instead we match on the known projects.
  65 for i in `ls ${srcdir}/projects`
  66 do
  67   if test -d ${srcdir}/projects/${i} ; then
  68     case ${i} in
  69       "CVS") ;;
  70       "sample")       AC_CONFIG_SUBDIRS([projects/sample])    ;;
  71       "Stacker")      AC_CONFIG_SUBDIRS([projects/Stacker])   ;;
  72       "privbracket")  AC_CONFIG_SUBDIRS([projects/privbracket]) ;;
  73       "llvm-test")    AC_CONFIG_SUBDIRS([projects/llvm-test]) ;;
  74       "llvm-reopt")   AC_CONFIG_SUBDIRS([projects/llvm-reopt]);;
  75       "llvm-gcc")     AC_CONFIG_SUBDIRS([projects/llvm-gcc])  ;;
  76       "llvm-java")    AC_CONFIG_SUBDIRS([projects/llvm-java]) ;;
  77       "llvm-tv")      AC_CONFIG_SUBDIRS([projects/llvm-tv])   ;;
  78       "llvm-poolalloc") AC_CONFIG_SUBDIRS([projects/llvm-poolalloc]) ;;
  79       "llvm-kernel")  AC_CONFIG_SUBDIRS([projects/llvm-kernel]) ;;
  80       *)
  81         AC_MSG_WARN([Unknown project (${i}) won't be configured automatically])
  82         ;;
  83     esac
  84   fi
  85 done
  86
  87 dnl===-----------------------------------------------------------------------===
  88 dnl===
  89 dnl=== SECTION 2: Architecture, target, and host checks
  90 dnl===
  91 dnl===-----------------------------------------------------------------------===
  92
  93 dnl Check the target for which we're compiling and the host that will do the
  94 dnl compilations. This will tell us which LLVM compiler will be used for
  95 dnl compiling SSA into object code. This needs to be done early because
  96 dnl following tests depend on it.
  97 AC_CANONICAL_TARGET
  98
  99 dnl Determine the platform type and cache its value. This helps us configure
 100 dnl the System library to the correct build platform.
 101 AC_CACHE_CHECK([type of operating system we're on],
 102                [llvm_cv_os_type],
 103 [case $build in
 104   *-*-aix*)
 105     llvm_cv_os_type="AIX"
 106     llvm_cv_platform_type="Unix" ;;
 107   *-*-cygwin*)
 108     llvm_cv_os_type="Cygwin"
 109     llvm_cv_platform_type="Unix" ;;
 110   *-*-darwin*)
 111     llvm_cv_os_type="Darwin"
 112     llvm_cv_platform_type="Unix" ;;
 113   *-*-freebsd*)
 114     llvm_cv_os_type="FreeBSD"
 115     llvm_cv_platform_type="Unix" ;;
 116   *-*-openbsd*)
 117     llvm_cv_os_type="OpenBSD"
 118     llvm_cv_platform_type="Unix" ;;
 119   *-*-hpux*)
 120     llvm_cv_os_type="HP-UX"
 121     llvm_cv_platform_type="Unix" ;;
 122   *-*-interix*)
 123     llvm_cv_os_type="Interix"
 124     llvm_cv_platform_type="Unix" ;;
 125   *-*-linux*)
 126     llvm_cv_os_type="Linux"
 127     llvm_cv_platform_type="Unix" ;;
 128   *-*-solaris*)
 129     llvm_cv_os_type="SunOS"
 130     llvm_cv_platform_type="Unix" ;;
 131   *-*-win32*)
 132     llvm_cv_os_type="Win32"
 133     llvm_cv_platform_type="Win32" ;;
 134   *-*-mingw*)
 135     llvm_cv_os_type="MingW"
 136     llvm_cv_platform_type="Win32" ;;
 137   *)
 138     llvm_cv_os_type="Unknown"
 139     llvm_cv_platform_type="Unknown" ;;
 140 esac])
 141
 142 dnl Make sure we aren't attempting to configure for an unknown system
 143 if test "$llvm_cv_os_type" = "Unknown" ; then
 144   AC_MSG_ERROR([Operating system is unknown, configure can't continue])
 145 fi
 146
 147 dnl Set the "OS" Makefile variable based on the platform type so the
 148 dnl makefile can configure itself to specific build hosts
 149 AC_SUBST(OS,$llvm_cv_os_type)
 150
 151 dnl Set the "LLVM_ON_*" variables based on llvm_cvs_platform_type
 152 dnl This is used by lib/System to determine the basic kind of implementation
 153 dnl to use.
 154 case $llvm_cv_platform_type in
 155   Unix)
 156     AC_DEFINE([LLVM_ON_UNIX],[1],[Define if this is Unixish platform])
 157     AC_SUBST(LLVM_ON_UNIX,[1])
 158     AC_SUBST(LLVM_ON_WIN32,[0])
 159     ;;
 160   Win32)
 161     AC_DEFINE([LLVM_ON_WIN32],[1],[Define if this is Win32ish platform])
 162     AC_SUBST(LLVM_ON_UNIX,[0])
 163     AC_SUBST(LLVM_ON_WIN32,[1])
 164     ;;
 165 esac
 166
 167 dnl Determine what our target architecture is and configure accordingly.
 168 dnl This will allow Makefiles to make a distinction between the hardware and
 169 dnl the OS.
 170 AC_CACHE_CHECK([target architecture],[llvm_cv_target_arch],
 171 [case $target in
 172   i?86-*)                 llvm_cv_target_arch="x86" ;;
 173   amd64-* | x86_64-*)     llvm_cv_target_arch="x86_64" ;;
 174   sparc*-*)               llvm_cv_target_arch="Sparc" ;;
 175   powerpc*-*)             llvm_cv_target_arch="PowerPC" ;;
 176   alpha*-*)               llvm_cv_target_arch="Alpha" ;;
 177   ia64-*)                 llvm_cv_target_arch="IA64" ;;
 178   *)                      llvm_cv_target_arch="Unknown" ;;
 179 esac])
 180
 181 if test "$llvm_cv_target_arch" = "Unknown" ; then
 182   AC_MSG_WARN([Configuring LLVM for an unknown target archicture])
 183 fi
 184
 185 dnl Define a substitution, ARCH, for the target architecture
 186 AC_SUBST(ARCH,$llvm_cv_target_arch)
 187
 188 dnl Check for the endianness of the target
 189 AC_C_BIGENDIAN(AC_SUBST([ENDIAN],[big]),AC_SUBST([ENDIAN],[little]))
 190
 191 dnl Check to see if there's a "CVS" directory indicating that this build is
 192 dnl being done from a CVS checkout. This sets up several defaults for the
 193 dnl command line switches. When we build with a CVS directory, we get a
 194 dnl debug with assertions turned on. Without, we assume a source release and we
 195 dnl get an optimized build without assertions. See --enable-optimized and
 196 dnl --enable-assertions below
 197 if test -d "CVS" -o -d "${srcdir}/CVS"; then
 198   cvsbuild="yes"
 199   optimize="no"
 200   AC_SUBST(CVSBUILD,[[CVSBUILD=1]])
 201 else
 202   cvsbuild="no"
 203   optimize="yes"
 204 fi
 205
 206 dnl===-----------------------------------------------------------------------===
 207 dnl===
 208 dnl=== SECTION 3: Command line arguments for the configure script.
 209 dnl===
 210 dnl===-----------------------------------------------------------------------===
 211
 212 dnl --enable-optimized : check whether they want to do an optimized build:
 213 AC_ARG_ENABLE(optimized, AS_HELP_STRING(
 214  [--enable-optimized,Compile with optimizations enabled (default is NO)]),,enableval=$optimize)
 215 if test ${enableval} = "no" ; then
 216   AC_SUBST(ENABLE_OPTIMIZED,[[]])
 217 else
 218   AC_SUBST(ENABLE_OPTIMIZED,[[ENABLE_OPTIMIZED=1]])
 219 fi
 220
 221 dnl --enable-assertions : check whether they want to turn on assertions or not:
 222 AC_ARG_ENABLE(assertions,AS_HELP_STRING(
 223   [--enable-assertions,Compile with assertion checks enabled (default is YES)]),, enableval="yes")
 224 if test ${enableval} = "yes" ; then
 225   AC_SUBST(DISABLE_ASSERTIONS,[[]])
 226 else
 227   AC_SUBST(DISABLE_ASSERTIONS,[[DISABLE_ASSERTIONS=1]])
 228 fi
 229
 230 dnl --enable-debug-runtime : should runtime libraries have debug symbols?
 231 AC_ARG_ENABLE(debug-runtime,
 232    AS_HELP_STRING([--enable-debug-runtime,Build runtime libs with debug symbols (default is NO)]),,enableval=no)
 233 if test ${enableval} = "no" ; then
 234   AC_SUBST(DEBUG_RUNTIME,[[]])
 235 else
 236   AC_SUBST(DEBUG_RUNTIME,[[DEBUG_RUNTIME=1]])
 237 fi
 238
 239 dnl --enable-jit: check whether they want to enable the jit
 240 AC_ARG_ENABLE(jit,
 241   AS_HELP_STRING(--enable-jit,
 242                  [Enable Just In Time Compiling (default is YES)]),,
 243   enableval=default)
 244 if test ${enableval} = "no"
 245 then
 246   AC_SUBST(JIT,[[]])
 247 else
 248   case "$llvm_cv_target_arch" in
 249     x86)     AC_SUBST(TARGET_HAS_JIT,1) ;;
 250     Sparc)   AC_SUBST(TARGET_HAS_JIT,1) ;;
 251     PowerPC) AC_SUBST(TARGET_HAS_JIT,1) ;;
 252     x86_64)  AC_SUBST(TARGET_HAS_JIT,0) ;;
 253     Alpha)   AC_SUBST(TARGET_HAS_JIT,1) ;;
 254     IA64)    AC_SUBST(TARGET_HAS_JIT,0) ;;
 255     *)       AC_SUBST(TARGET_HAS_JIT,0) ;;
 256   esac
 257 fi
 258
 259 dnl Allow enablement of doxygen generated documentation
 260 AC_ARG_ENABLE(doxygen,
 261               AS_HELP_STRING([--enable-doxygen],
 262                              [Build doxygen documentation (default is NO)]),,
 263                              enableval=default)
 264 case "$enableval" in
 265   yes) AC_SUBST(ENABLE_DOXYGEN,[1]) ;;
 266   no)  AC_SUBST(ENABLE_DOXYGEN,[0]) ;;
 267   default) AC_SUBST(ENABLE_DOXYGEN,[0]) ;;
 268   *) AC_MSG_ERROR([Invalid setting for --enable-doxygen. Use "yes" or "no"]) ;;
 269 esac
 270
 271 dnl Allow disablement of threads
 272 AC_ARG_ENABLE(threads,
 273               AS_HELP_STRING([--enable-threads],
 274                              [Use threads if available (default is YES)]),,
 275                              enableval=yes)
 276 case "$enableval" in
 277   yes) AC_SUBST(ENABLE_THREADS,[1]) ;;
 278   no)  AC_SUBST(ENABLE_THREADS,[0]) ;;
 279   *) AC_MSG_ERROR([Invalid setting for --enable-threads. Use "yes" or "no"]) ;;
 280 esac
 281 AC_DEFINE_UNQUOTED([ENABLE_THREADS],$ENABLE_THREADS,[Define if threads enabled])
 282
 283 dnl Allow specific targets to be specified for building (or not)
 284 TARGETS_TO_BUILD=""
 285 AC_ARG_ENABLE([targets],AS_HELP_STRING([--enable-target],
 286     [Build specific host targets: all,host-only,{target-name} (default=all)]),,
 287     enableval=all)
 288 case "$enableval" in
 289   all) TARGETS_TO_BUILD="X86 Sparc PowerPC Alpha IA64 ARM" ;;
 290   host-only)
 291     case "$llvm_cv_target_arch" in
 292       x86)     TARGETS_TO_BUILD="X86" ;;
 293       x86_64)  TARGETS_TO_BUILD="X86" ;;
 294       Sparc)   TARGETS_TO_BUILD="Sparc" ;;
 295       PowerPC) TARGETS_TO_BUILD="PowerPC" ;;
 296       Alpha)   TARGETS_TO_BUILD="Alpha" ;;
 297       IA64)    TARGETS_TO_BUILD="IA64" ;;
 298       *)       AC_MSG_ERROR([Can not set target to build]) ;;
 299     esac
 300     ;;
 301   *)for a_target in `echo $enableval|sed -e 's/,/ /g' ` ; do
 302       case "$a_target" in
 303         x86)     TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 304         x86_64)  TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 305         sparc)   TARGETS_TO_BUILD="Sparc $TARGETS_TO_BUILD" ;;
 306         powerpc) TARGETS_TO_BUILD="PowerPC $TARGETS_TO_BUILD" ;;
 307         alpha)   TARGETS_TO_BUILD="Alpha $TARGETS_TO_BUILD" ;;
 308         ia64)    TARGETS_TO_BUILD="IA64 $TARGETS_TO_BUILD" ;;
 309         *) AC_MSG_ERROR([Unrecognized target $a_target]) ;;
 310       esac
 311   done
 312   ;;
 313 esac
 314 TARGETS_TO_BUILD="CBackend $TARGETS_TO_BUILD"
 315 AC_SUBST(TARGETS_TO_BUILD,$TARGETS_TO_BUILD)
 316
 317 dnl Allow a specific llvm-gcc/llvm-g++ pair to be used with this LLVM config.
 318 AC_ARG_WITH(llvmgccdir,
 319   AS_HELP_STRING([--with-llvmgccdir],
 320     [Specify location of llvm-gcc install dir (default searches PATH)]),,
 321     withval=default)
 322 case "$withval" in
 323   default) WITH_LLVMGCCDIR=default ;;
 324   /* | [[A-Za-z]]:[[\\/]]*)      WITH_LLVMGCCDIR=$withval ;;
 325   *) AC_MSG_ERROR([Invalid path for --with-llvmgccdir. Provide full path]) ;;
 326 esac
 327
 328
 329 dnl===-----------------------------------------------------------------------===
 330 dnl===
 331 dnl=== SECTION 4: Check for programs we need and that they are the right version
 332 dnl===
 333 dnl===-----------------------------------------------------------------------===
 334
 335 dnl Check for compilation tools
 336 AC_PROG_CPP
 337 AC_PROG_CC(gcc)
 338 AC_PROG_CXX(g++)
 339 AC_PROG_FLEX
 340 AC_PROG_BISON
 341
 342 dnl Check for the tools that the makefiles require
 343 AC_CHECK_GNU_MAKE
 344 AC_PROG_LN_S
 345 AC_PATH_PROG(CMP, [cmp], [cmp])
 346 AC_PATH_PROG(CP, [cp], [cp])
 347 AC_PATH_PROG(DATE, [date], [date])
 348 AC_PATH_PROG(FIND, [find], [find])
 349 AC_PATH_PROG(GREP, [grep], [grep])
 350 AC_PATH_PROG(MKDIR,[mkdir],[mkdir])
 351 AC_PATH_PROG(MV,   [mv],   [mv])
 352 AC_PROG_RANLIB
 353 AC_PATH_PROG(RM,   [rm],   [rm])
 354 AC_PATH_PROG(SED,  [sed],  [sed])
 355 AC_PATH_PROG(TAR,  [tar],  [gtar])
 356
 357 dnl Looking for misc. graph plotting software
 358 AC_PATH_PROG(GRAPHVIZ, [Graphviz], [echo Graphviz])
 359 if test "$GRAPHVIZ" != "echo Graphviz" ; then
 360   AC_DEFINE([HAVE_GRAPHVIZ],[1],[Define if the Graphviz program is available])
 361   dnl If we're targeting for mingw we should emit windows paths, not msys
 362   if test "$llvm_cv_os_type" == "MingW" ; then
 363     GRAPHVIZ=`echo $GRAPHVIZ | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 364   fi
 365   AC_DEFINE_UNQUOTED([LLVM_PATH_GRAPHVIZ],"$GRAPHVIZ${EXEEXT}",
 366    [Define to path to Graphviz program if found or 'echo Graphviz' otherwise])
 367 fi
 368 AC_PATH_PROG(DOT, [dot], [echo dot])
 369 if test "$DOT" != "echo dot" ; then
 370   AC_DEFINE([HAVE_DOT],[1],[Define if the dot program is available])
 371   dnl If we're targeting for mingw we should emit windows paths, not msys
 372   if test "$llvm_cv_os_type" == "MingW" ; then
 373     DOT=`echo $DOT | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 374   fi
 375   AC_DEFINE_UNQUOTED([LLVM_PATH_DOT],"$DOT${EXEEXT}",
 376    [Define to path to dot program if found or 'echo dot' otherwise])
 377 fi
 378 AC_PATH_PROGS(GV, [gv gsview32], [echo gv])
 379 if test "$GV" != "echo gv" ; then
 380   AC_DEFINE([HAVE_GV],[1],[Define if the gv program is available])
 381   dnl If we're targeting for mingw we should emit windows paths, not msys
 382   if test "$llvm_cv_os_type" == "MingW" ; then
 383     GV=`echo $GV | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 384   fi
 385   AC_DEFINE_UNQUOTED([LLVM_PATH_GV],"$GV${EXEEXT}",
 386    [Define to path to gv program if found or 'echo gv' otherwise])
 387 fi
 388 AC_PATH_PROG(DOTTY, [dotty], [echo dotty])
 389 if test "$DOTTY" != "echo dotty" ; then
 390   AC_DEFINE([HAVE_DOTTY],[1],[Define if the dotty program is available])
 391   dnl If we're targeting for mingw we should emit windows paths, not msys
 392   if test "$llvm_cv_os_type" == "MingW" ; then
 393     DOTTY=`echo $DOTTY | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 394   fi
 395   AC_DEFINE_UNQUOTED([LLVM_PATH_DOTTY],"$DOTTY${EXEEXT}",
 396    [Define to path to dotty program if found or 'echo dotty' otherwise])
 397 fi
 398
 399 dnl Look for a sufficiently recent version of Perl.
 400 LLVM_PROG_PERL([5.006])
 401 AC_SUBST(PERL)
 402 if test x"$PERL" = xnone; then
 403    AC_SUBST(HAVE_PERL,0)
 404 else
 405    AC_SUBST(HAVE_PERL,1)
 406 fi
 407
 408 dnl Find the install program
 409 AC_PROG_INSTALL
 410
 411 dnl Checks for documentation and testing tools that we can do without. If these
 412 dnl are not found then they are set to "true" which always succeeds but does
 413 dnl nothing. This just lets the build output show that we could have done
 414 dnl something if the tool was available.
 415 AC_PATH_PROG(BZIP2,[bzip2],[echo "Skipped: bzip2 not found"])
 416 AC_PATH_PROG(DOXYGEN,[doxygen],[echo "Skipped: doxygen not found"])
 417 AC_PATH_PROG(ETAGS,[etags],[echo "Skipped: etags not found"])
 418 AC_PATH_PROG(GROFF,[groff],[echo "Skipped: groff not found"])
 419 AC_PATH_PROG(GZIP,[gzip],[echo "Skipped: gzip not found"])
 420 AC_PATH_PROG(POD2HTML,[pod2html],[echo "Skipped: pod2html not found"])
 421 AC_PATH_PROG(POD2MAN,[pod2man],[echo "Skipped: pod2man not found"])
 422 AC_PATH_PROG(RUNTEST,[runtest],[echo "Skipped: runtest not found"])
 423 DJ_AC_PATH_TCLSH
 424 AC_PATH_PROG(ZIP,[zip],[echo "Skipped: zip not found"])
 425
 426 dnl Determine if the linker supports the -R option.
 427 AC_LINK_USE_R
 428
 429 dnl Check for libtool and the library that has dlopen function (which must come
 430 dnl before the AC_PROG_LIBTOOL check in order to enable dlopening libraries with
 431 dnl libtool).
 432 AC_LIBTOOL_DLOPEN
 433 AC_LIB_LTDL
 434 AC_PROG_LIBTOOL
 435
 436 if test "$lt_cv_dlopen_self" = "yes" ; then
 437   AC_DEFINE([CAN_DLOPEN_SELF],[1],
 438               [Define if dlopen(0) will open the symbols of the program])
 439 fi
 440
 441 dnl Check if we know how to tell etags we are using C++:
 442 etags_version=`$ETAGS --version 2>&1`
 443 case "$etags_version" in
 444         *[Ee]xuberant*) ETAGSFLAGS="--language-force=c++" ;;
 445         *GNU\ Emacs*) ETAGSFLAGS="-l c++" ;;
 446         *) ETAGSFLAGS="" ;;
 447 esac
 448 AC_SUBST(ETAGSFLAGS,$ETAGSFLAGS)
 449
 450 if test "$WITH_LLVMGCCDIR" = "default" ; then
 451   LLVMGCC="llvm-gcc${EXEEXT}"
 452   LLVMGXX="llvm-g++${EXEEXT}"
 453   AC_PATH_PROG(LLVMGCC, $LLVMGCC, [])
 454   AC_PATH_PROG(LLVMGXX, $LLVMGXX, [])
 455 else
 456   LLVMGCC="$WITH_LLVMGCCDIR/bin/llvm-gcc${EXEEXT}"
 457   LLVMGXX="$WITH_LLVMGCCDIR/bin/llvm-g++${EXEEXT}"
 458   AC_SUBST(LLVMGCC,$LLVMGCC)
 459   AC_SUBST(LLVMGXX,$LLVMGXX)
 460 fi
 461
 462 AC_MSG_CHECKING([tool compatibility])
 463
 464 dnl Ensure that compilation tools are GCC or a GNU compatible compiler such as
 465 dnl ICC; we use GCC specific options in the makefiles so the compiler needs
 466 dnl to support those options.
 467 dnl "icc" emits gcc signatures
 468 dnl "icc -no-gcc" emits no gcc signature BUT is still compatible
 469 ICC=no
 470 IXX=no
 471 case $CC in
 472   icc*|icpc*)
 473     ICC=yes
 474     IXX=yes
 475     ;;
 476    *)
 477     ;;
 478 esac
 479
 480 if test "$GCC" != "yes" && test "$ICC" != "yes"
 481 then
 482   AC_MSG_ERROR([gcc|icc required but not found])
 483 fi
 484
 485 dnl Ensure that compilation tools are GCC; we use GCC specific extensions
 486 if test "$GXX" != "yes" && test "$IXX" != "yes"
 487 then
 488   AC_MSG_ERROR([g++|icc required but not found])
 489 fi
 490
 491 dnl Verify that GCC is version 3.0 or higher
 492 if test "$GCC" = "yes"
 493 then
 494   gccmajor=`$CC --version | head -n 1 | sed 's/[[^0-9]]*\([[0-9.]]\).*/\1/'`
 495   if test "$gccmajor" -lt "3"
 496   then
 497     AC_MSG_ERROR([gcc 3.x required, but you have a lower version])
 498   fi
 499 fi
 500
 501 dnl Check for GNU Make.  We use its extensions, so don't build without it
 502 if test -z "$llvm_cv_gnu_make_command"
 503 then
 504   AC_MSG_ERROR([GNU Make required but not found])
 505 fi
 506
 507 dnl Tool compatibility is okay if we make it here.
 508 AC_MSG_RESULT([ok])
 509
 510 dnl===-----------------------------------------------------------------------===
 511 dnl===
 512 dnl=== SECTION 5: Check for libraries
 513 dnl===
 514 dnl===-----------------------------------------------------------------------===
 515
 516 dnl libelf is for sparc only; we can ignore it if we don't have it
 517 AC_CHECK_LIB(elf, elf_begin)
 518 AC_CHECK_LIB(m,sin)
 519 if test "$llvm_cv_os_type" == "MingW" ; then
 520   AC_CHECK_LIB(imagehlp, main)
 521   AC_CHECK_LIB(psapi, main)
 522 fi
 523
 524 dnl lt_dlopen may be required for plugin support.
 525 AC_SEARCH_LIBS(lt_dlopen,ltdl,AC_DEFINE([HAVE_LT_DLOPEN],[1],
 526               [Define if lt_dlopen() is available on this platform]),
 527               AC_MSG_WARN([lt_dlopen() not found - plugin support might
 528                            not be available]))
 529
 530 dnl dlopen() is required for plugin support.
 531 AC_SEARCH_LIBS(dlopen,dl,AC_DEFINE([HAVE_DLOPEN],[1],
 532                [Define if dlopen() is available on this platform.]),
 533                AC_MSG_WARN([dlopen() not found - disabling plugin support]))
 534
 535 dnl mallinfo is optional; the code can compile (minus features) without it
 536 AC_SEARCH_LIBS(mallinfo,malloc,AC_DEFINE([HAVE_MALLINFO],[1],
 537                [Define if mallinfo() is available on this platform.]))
 538
 539 dnl pthread locking functions are optional - but llvm will not be thread-safe
 540 dnl without locks.
 541 if test "$ENABLE_THREADS" -eq 1 ; then
 542   AC_CHECK_LIB(pthread,pthread_mutex_init)
 543   AC_SEARCH_LIBS(pthread_mutex_lock,pthread,
 544                  AC_DEFINE([HAVE_PTHREAD_MUTEX_LOCK],[1],
 545                            [Have pthread_mutex_lock]))
 546 fi
 547
 548 dnl===-----------------------------------------------------------------------===
 549 dnl===
 550 dnl=== SECTION 6: Check for header files
 551 dnl===
 552 dnl===-----------------------------------------------------------------------===
 553
 554 dnl First, use autoconf provided macros for specific headers that we need
 555 dnl We don't check for ancient stuff or things that are guaranteed to be there
 556 dnl by the C++ standard. We always use the <cfoo> versions of <foo.h> C headers.
 557 dnl Generally we're looking for POSIX headers.
 558 AC_HEADER_DIRENT
 559 AC_HEADER_MMAP_ANONYMOUS
 560 AC_HEADER_STAT
 561 AC_HEADER_STDC
 562 AC_HEADER_SYS_WAIT
 563 AC_HEADER_TIME
 564
 565 AC_CHECK_HEADERS([dlfcn.h execinfo.h fcntl.h inttypes.h limits.h link.h])
 566 AC_CHECK_HEADERS([malloc.h setjmp.h signal.h stdint.h unistd.h utime.h])
 567 AC_CHECK_HEADERS([windows.h sys/mman.h sys/param.h sys/resource.h sys/time.h])
 568 AC_CHECK_HEADERS([sys/types.h malloc/malloc.h])
 569 if test "$ENABLE_THREADS" -eq 1 ; then
 570   AC_CHECK_HEADERS(pthread.h)
 571 fi
 572
 573 dnl===-----------------------------------------------------------------------===
 574 dnl===
 575 dnl=== SECTION 7: Check for types and structures
 576 dnl===
 577 dnl===-----------------------------------------------------------------------===
 578
 579 AC_TYPE_PID_T
 580 AC_TYPE_SIZE_T
 581 AC_TYPE_SIGNAL
 582 AC_STRUCT_TM
 583 AC_CHECK_TYPES([int64_t],,AC_MSG_ERROR([Type int64_t required but not found]))
 584 AC_CHECK_TYPES([uint64_t],,
 585          AC_CHECK_TYPES([u_int64_t],,
 586          AC_MSG_ERROR([Type uint64_t or u_int64_t required but not found])))
 587
 588 dnl===-----------------------------------------------------------------------===
 589 dnl===
 590 dnl=== SECTION 8: Check for specific functions needed
 591 dnl===
 592 dnl===-----------------------------------------------------------------------===
 593
 594 AC_CHECK_FUNCS([backtrace ceilf floorf roundf rintf nearbyintf getcwd ])
 595 AC_CHECK_FUNCS([getpagesize getrusage gettimeofday isatty mkdtemp mkstemp ])
 596 AC_CHECK_FUNCS([mktemp realpath sbrk setrlimit strdup strerror strerror_r ])
 597 AC_CHECK_FUNCS([strtoll strtoq sysconf malloc_zone_statistics ])
 598 AC_CHECK_FUNCS([_setjmp _longjmp setjmp longjmp sigsetjmp siglongjmp])
 599 AC_C_PRINTF_A
 600 AC_FUNC_ALLOCA
 601 AC_FUNC_RAND48
 602
 603 dnl Check for variations in the Standard C++ library and STL. These macros are
 604 dnl provided by LLVM in the autoconf/m4 directory.
 605 AC_CXX_HAVE_HASH_MAP
 606 AC_CXX_HAVE_HASH_SET
 607 AC_CXX_HAVE_STD_ITERATOR
 608 AC_CXX_HAVE_BI_ITERATOR
 609 AC_CXX_HAVE_FWD_ITERATOR
 610 AC_FUNC_ISNAN
 611 AC_FUNC_ISINF
 612
 613 dnl Check for mmap and mprotect support. We need both to do the JIT and for
 614 dnl bytecode loading, etc. We also need to know if /dev/zero is required to
 615 dnl be opened for allocating RWX memory.
 616 AC_FUNC_MMAP
 617 AC_FUNC_MMAP_FILE
 618 AC_NEED_DEV_ZERO_FOR_MMAP
 619 AC_CHECK_FUNC(mprotect,,
 620               AC_MSG_ERROR([Function mprotect() required but not found]))
 621
 622 if test "$ac_cv_func_mmap_fixed_mapped" = "no"
 623 then
 624   AC_MSG_WARN([mmap() of a fixed address required but not supported])
 625 fi
 626 if test "$ac_cv_func_mmap_file" = "no"
 627 then
 628   AC_MSG_WARN([mmap() of files required but not found])
 629 fi
 630
 631 dnl===-----------------------------------------------------------------------===
 632 dnl===
 633 dnl=== SECTION 9: Additional checks, variables, etc.
 634 dnl===
 635 dnl===-----------------------------------------------------------------------===
 636
 637 dnl See if the llvm-gcc executable can compile to LLVM assembly
 638 AC_CACHE_CHECK([whether llvm-gcc is sane],[llvm_cv_llvmgcc_sanity],
 639 [llvm_cv_llvmgcc_sanity="no"
 640 if test -x "$LLVMGCC" ; then
 641   cp /dev/null conftest.c
 642   "$LLVMGCC" -emit-llvm -S -o - conftest.c | grep implementation > /dev/null 2>&1
 643   if test $? -eq 0 ; then
 644     llvm_cv_llvmgcc_sanity="yes"
 645   fi
 646   rm conftest.c
 647 fi])
 648
 649 dnl Since we have a sane llvm-gcc, identify it and its sub-tools
 650 if test "$llvm_cv_llvmgcc_sanity" = "yes" ; then
 651   llvmcc1path=`"$LLVMGCC" --print-prog-name=cc1`
 652   AC_SUBST(LLVMCC1,$llvmcc1path)
 653   llvmcc1pluspath=`"$LLVMGCC" --print-prog-name=cc1plus`
 654   AC_SUBST(LLVMCC1PLUS,$llvmcc1pluspath)
 655   llvmgccdir=`echo "$llvmcc1path" | sed 's,/libexec/.*,,'`
 656   AC_SUBST(LLVMGCCDIR,$llvmgccdir)
 657   llvmgccversion=[`"$LLVMGCC" -dumpversion 2>&1 | sed 's/^\([0-9.]*\).*/\1/'`]
 658   llvmgccmajvers=[`echo $llvmgccversion | sed 's/^\([0-9]\).*/\1/'`]
 659   AC_SUBST(LLVMGCC_VERSION,$llvmgccversion)
 660   AC_SUBST(LLVMGCC_MAJVERS,$llvmgccmajvers)
 661 fi
 662
 663 dnl Propagate the shared library extension that the libltdl checks did to
 664 dnl the Makefiles so we can use it there too
 665 AC_SUBST(SHLIBEXT,$libltdl_cv_shlibext)
 666
 667 # Translate the various configuration directories and other basic
 668 # information into substitutions that will end up in Makefile.config.in
 669 # that these configured values can be used by the makefiles
 670 if test "${prefix}" == "NONE" ; then
 671   prefix="/usr/local"
 672 fi
 673 eval LLVM_PREFIX="${prefix}";
 674 eval LLVM_BINDIR="${prefix}/bin";
 675 eval LLVM_LIBDIR="${prefix}/lib";
 676 eval LLVM_DATADIR="${prefix}/share/llvm";
 677 eval LLVM_DOCSDIR="${prefix}/docs/llvm";
 678 eval LLVM_ETCDIR="${prefix}/etc/llvm";
 679 eval LLVM_INCLUDEDIR="${prefix}/include";
 680 eval LLVM_INFODIR="${prefix}/info";
 681 eval LLVM_MANDIR="${prefix}/man";
 682 LLVM_CONFIGTIME=`date`
 683 AC_SUBST(LLVM_PREFIX)
 684 AC_SUBST(LLVM_BINDIR)
 685 AC_SUBST(LLVM_LIBDIR)
 686 AC_SUBST(LLVM_DATADIR)
 687 AC_SUBST(LLVM_DOCSDIR)
 688 AC_SUBST(LLVM_ETCDIR)
 689 AC_SUBST(LLVM_INCLUDEDIR)
 690 AC_SUBST(LLVM_INFODIR)
 691 AC_SUBST(LLVM_MANDIR)
 692 AC_SUBST(LLVM_CONFIGTIME)
 693
 694 # Place the various directores into the config.h file as #defines so that we
 695 # can know about the installation paths within LLVM.
 696 AC_DEFINE_UNQUOTED(LLVM_PREFIX,"$LLVM_PREFIX",
 697                    [Installation prefix directory])
 698 AC_DEFINE_UNQUOTED(LLVM_BINDIR, "$LLVM_BINDIR",
 699                    [Installation directory for binary executables])
 700 AC_DEFINE_UNQUOTED(LLVM_LIBDIR, "$LLVM_LIBDIR",
 701                    [Installation directory for libraries])
 702 AC_DEFINE_UNQUOTED(LLVM_DATADIR, "$LLVM_DATADIR",
 703                    [Installation directory for data files])
 704 AC_DEFINE_UNQUOTED(LLVM_DATADIR, "$LLVM_DOCSDIR",
 705                    [Installation directory for documentation])
 706 AC_DEFINE_UNQUOTED(LLVM_ETCDIR, "$LLVM_ETCDIR",
 707                    [Installation directory for config files])
 708 AC_DEFINE_UNQUOTED(LLVM_INCLUDEDIR, "$LLVM_INCLUDEDIR",
 709                    [Installation directory for include files])
 710 AC_DEFINE_UNQUOTED(LLVM_INFODIR, "$LLVM_INFODIR",
 711                    [Installation directory for .info files])
 712 AC_DEFINE_UNQUOTED(LLVM_MANDIR, "$LLVM_MANDIR",
 713                    [Installation directory for man pages])
 714 AC_DEFINE_UNQUOTED(LLVM_CONFIGTIME, "$LLVM_CONFIGTIME",
 715                    [Time at which LLVM was configured])
 716
 717 dnl===-----------------------------------------------------------------------===
 718 dnl===
 719 dnl=== SECTION 10: Specify the output files and generate it
 720 dnl===
 721 dnl===-----------------------------------------------------------------------===
 722
 723 dnl Configure header files
 724 dnl WARNING: dnl If you add or remove any of the following config headers, then
 725 dnl you MUST also update Makefile.rules so that the variable FilesToConfig
 726 dnl contains the same list of files as AC_CONFIG_HEADERS below. This ensures the
 727 dnl files can be updated automatically when their *.in sources change.
 728 AC_CONFIG_HEADERS([include/llvm/Config/config.h])
 729 AC_CONFIG_HEADERS([include/llvm/Support/DataTypes.h])
 730 AC_CONFIG_HEADERS([include/llvm/ADT/hash_map])
 731 AC_CONFIG_HEADERS([include/llvm/ADT/hash_set])
 732 AC_CONFIG_HEADERS([include/llvm/ADT/iterator])
 733
 734 dnl Configure the makefile's configuration data
 735 AC_CONFIG_FILES([Makefile.config])
 736
 737 dnl Configure doxygen's configuration file
 738 AC_CONFIG_FILES([docs/doxygen.cfg])
 739
 740 dnl Do the first stage of configuration for llvm-config.in.
 741 AC_CONFIG_FILES([tools/llvm-config/llvm-config.in])
 742
 743 dnl Do special configuration of Makefiles
 744 AC_CONFIG_COMMANDS([setup],,[llvm_src="${srcdir}"])
 745 AC_CONFIG_MAKEFILE(Makefile)
 746 AC_CONFIG_MAKEFILE(Makefile.common)
 747 AC_CONFIG_MAKEFILE(examples/Makefile)
 748 AC_CONFIG_MAKEFILE(lib/Makefile)
 749 AC_CONFIG_MAKEFILE(runtime/Makefile)
 750 AC_CONFIG_MAKEFILE(test/Makefile)
 751 AC_CONFIG_MAKEFILE(test/Makefile.tests)
 752 AC_CONFIG_MAKEFILE(tools/Makefile)
 753 AC_CONFIG_MAKEFILE(utils/Makefile)
 754 AC_CONFIG_MAKEFILE(projects/Makefile)
 755
 756 dnl Finally, crank out the output
 757 AC_OUTPUT
 758
 759 dnl Warn loudly if llvm-gcc was not obviously working
 760 if test "$llvm_cv_llvmgcc_sanity" = "no" ; then
 761  AC_MSG_WARN([***** llvm-gcc/llvm-g++ was not found, or does not appear to be ])
 762  AC_MSG_WARN([***** working. Please make sure you have llvmgcc and llvmg++ in])
 763  AC_MSG_WARN([***** your path before configuring LLVM. The runtime libraries])
 764  AC_MSG_WARN([***** (llvm/runtime) will not be built but you should be able to])
 765  AC_MSG_WARN([***** build the llvm tools.])
 766 fi