autoconf/configure.ac

   1 dnl === configure.ac --------------------------------------------------------===
   2 dnl                     The LLVM Compiler Infrastructure
   3 dnl
   4 dnl This file was developed by the LLVM research group and is distributed under
   5 dnl the University of Illinois Open Source License. See LICENSE.TXT for details.
   6 dnl
   7 dnl===-----------------------------------------------------------------------===
   8 dnl This is the LLVM configuration script. It is processed by the autoconf
   9 dnl program to produce a script named configure. This script contains the
  10 dnl configuration checks that LLVM needs in order to support multiple platforms.
  11 dnl This file is composed of 10 sections per the recommended organization of
  12 dnl autoconf input defined in the autoconf documentation. As this file evolves,
  13 dnl please keep the various types of checks within their sections. The sections
  14 dnl are as follows:
  15 dnl
  16 dnl SECTION 1: Initialization & Setup
  17 dnl SECTION 2: Architecture, target, and host checks
  18 dnl SECTION 3: Command line arguments for the configure script.
  19 dnl SECTION 4: Check for programs we need and that they are the right version
  20 dnl SECTION 5: Check for libraries
  21 dnl SECTION 6: Check for header files
  22 dnl SECTION 7: Check for types and structures
  23 dnl SECTION 8: Check for specific functions needed
  24 dnl SECTION 9: Additional checks, variables, etc.
  25 dnl SECTION 10: Specify the output files and generate it
  26 dnl
  27 dnl===-----------------------------------------------------------------------===
  28 dnl===
  29 dnl=== SECTION 1: Initialization & Setup
  30 dnl===
  31 dnl===-----------------------------------------------------------------------===
  32 dnl Initialize autoconf and define the package name, version number and
  33 dnl email address for reporting bugs.
  34 AC_INIT([[llvm]],[[2.2svn]],[llvmbugs@cs.uiuc.edu])
  35
  36 dnl Provide a copyright substitution and ensure the copyright notice is included
  37 dnl in the output of --version option of the generated configure script.
  38 AC_SUBST(LLVM_COPYRIGHT,["Copyright (c) 2003-2007 University of Illinois at Urbana-Champaign."])
  39 AC_COPYRIGHT([Copyright (c) 2003-2007 University of Illinois at Urbana-Champaign.])
  40
  41 dnl Indicate that we require autoconf 2.59 or later. Ths is needed because we
  42 dnl use some autoconf macros only available in 2.59.
  43 AC_PREREQ(2.59)
  44
  45 dnl Verify that the source directory is valid. This makes sure that we are
  46 dnl configuring LLVM and not some other package (it validates --srcdir argument)
  47 AC_CONFIG_SRCDIR([lib/VMCore/Module.cpp])
  48
  49 dnl Place all of the extra autoconf files into the config subdirectory. Tell
  50 dnl various tools where the m4 autoconf macros are.
  51 AC_CONFIG_AUX_DIR([autoconf])
  52
  53 dnl Quit if the source directory has already been configured.
  54 dnl NOTE: This relies upon undocumented autoconf behavior.
  55 if test ${srcdir} != "." ; then
  56   if test -f ${srcdir}/include/llvm/Config/config.h ; then
  57     AC_MSG_ERROR([Already configured in ${srcdir}])
  58   fi
  59 fi
  60
  61 dnl Configure all of the projects present in our source tree. While we could
  62 dnl just AC_CONFIG_SUBDIRS on the set of directories in projects that have a
  63 dnl configure script, that usage of the AC_CONFIG_SUBDIRS macro is deprecated.
  64 dnl Instead we match on the known projects.
  65 for i in `ls ${srcdir}/projects`
  66 do
  67   if test -d ${srcdir}/projects/${i} ; then
  68     case ${i} in
  69       CVS) ;;
  70       sample)       AC_CONFIG_SUBDIRS([projects/sample])    ;;
  71       privbracket)  AC_CONFIG_SUBDIRS([projects/privbracket]) ;;
  72       llvm-stacker) AC_CONFIG_SUBDIRS([projects/llvm-stacker]) ;;
  73       llvm-test)    AC_CONFIG_SUBDIRS([projects/llvm-test]) ;;
  74       llvm-reopt)   AC_CONFIG_SUBDIRS([projects/llvm-reopt]);;
  75       llvm-gcc)     AC_CONFIG_SUBDIRS([projects/llvm-gcc])  ;;
  76       llvm-java)    AC_CONFIG_SUBDIRS([projects/llvm-java]) ;;
  77       llvm-tv)      AC_CONFIG_SUBDIRS([projects/llvm-tv])   ;;
  78       llvm-poolalloc) AC_CONFIG_SUBDIRS([projects/llvm-poolalloc]) ;;
  79       poolalloc)    AC_CONFIG_SUBDIRS([projects/poolalloc]) ;;
  80       llvm-kernel)  AC_CONFIG_SUBDIRS([projects/llvm-kernel]) ;;
  81       *)
  82         AC_MSG_WARN([Unknown project (${i}) won't be configured automatically])
  83         ;;
  84     esac
  85   fi
  86 done
  87
  88 dnl===-----------------------------------------------------------------------===
  89 dnl===
  90 dnl=== SECTION 2: Architecture, target, and host checks
  91 dnl===
  92 dnl===-----------------------------------------------------------------------===
  93
  94 dnl Check the target for which we're compiling and the host that will do the
  95 dnl compilations. This will tell us which LLVM compiler will be used for
  96 dnl compiling SSA into object code. This needs to be done early because
  97 dnl following tests depend on it.
  98 AC_CANONICAL_TARGET
  99
 100 dnl Determine the platform type and cache its value. This helps us configure
 101 dnl the System library to the correct build platform.
 102 AC_CACHE_CHECK([type of operating system we're going to host on],
 103                [llvm_cv_os_type],
 104 [case $host in
 105   *-*-aix*)
 106     llvm_cv_link_all_option="-Wl,--whole-archive"
 107     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 108     llvm_cv_os_type="AIX"
 109     llvm_cv_platform_type="Unix" ;;
 110   *-*-irix*)
 111     llvm_cv_link_all_option="-Wl,--whole-archive"
 112     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 113     llvm_cv_os_type="IRIX"
 114     llvm_cv_platform_type="Unix" ;;
 115   *-*-cygwin*)
 116     llvm_cv_link_all_option="-Wl,--whole-archive"
 117     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 118     llvm_cv_os_type="Cygwin"
 119     llvm_cv_platform_type="Unix" ;;
 120   *-*-darwin*)
 121     llvm_cv_link_all_option="-Wl,-all_load"
 122     llvm_cv_link_all_option="-Wl,-noall_load"
 123     llvm_cv_os_type="Darwin"
 124     llvm_cv_platform_type="Unix" ;;
 125   *-*-freebsd*)
 126     llvm_cv_link_all_option="-Wl,--whole-archive"
 127     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 128     llvm_cv_os_type="FreeBSD"
 129     llvm_cv_platform_type="Unix" ;;
 130   *-*-openbsd*)
 131     llvm_cv_link_all_option="-Wl,--whole-archive"
 132     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 133     llvm_cv_os_type="OpenBSD"
 134     llvm_cv_platform_type="Unix" ;;
 135   *-*-netbsd*)
 136     llvm_cv_link_all_option="-Wl,--whole-archive"
 137     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 138     llvm_cv_os_type="NetBSD"
 139     llvm_cv_platform_type="Unix" ;;
 140   *-*-hpux*)
 141     llvm_cv_link_all_option="-Wl,--whole-archive"
 142     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 143     llvm_cv_os_type="HP-UX"
 144     llvm_cv_platform_type="Unix" ;;
 145   *-*-interix*)
 146     llvm_cv_link_all_option="-Wl,--whole-archive"
 147     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 148     llvm_cv_os_type="Interix"
 149     llvm_cv_platform_type="Unix" ;;
 150   *-*-linux*)
 151     llvm_cv_link_all_option="-Wl,--whole-archive"
 152     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 153     llvm_cv_os_type="Linux"
 154     llvm_cv_platform_type="Unix" ;;
 155   *-*-solaris*)
 156     llvm_cv_link_all_option="-Wl,-z,allextract"
 157     llvm_cv_no_link_all_option="-Wl,-z,defaultextract"
 158     llvm_cv_os_type="SunOS"
 159     llvm_cv_platform_type="Unix" ;;
 160   *-*-win32*)
 161     llvm_cv_link_all_option="-Wl,--whole-archive"
 162     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 163     llvm_cv_os_type="Win32"
 164     llvm_cv_platform_type="Win32" ;;
 165   *-*-mingw*)
 166     llvm_cv_link_all_option="-Wl,--whole-archive"
 167     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 168     llvm_cv_os_type="MingW"
 169     llvm_cv_platform_type="Win32" ;;
 170   *)
 171     llvm_cv_link_all_option=""
 172     llvm_cv_no_link_all_option=""
 173     llvm_cv_os_type="Unknown"
 174     llvm_cv_platform_type="Unknown" ;;
 175 esac])
 176
 177 dnl Make sure we aren't attempting to configure for an unknown system
 178 if test "$llvm_cv_os_type" = "Unknown" ; then
 179   AC_MSG_ERROR([Operating system is unknown, configure can't continue])
 180 fi
 181
 182 dnl Set the "OS" Makefile variable based on the platform type so the
 183 dnl makefile can configure itself to specific build hosts
 184 AC_SUBST(OS,$llvm_cv_os_type)
 185
 186 dnl Set the LINKALL and NOLINKALL Makefile variables based on the platform
 187 AC_SUBST(LINKALL,$llvm_cv_link_all_option)
 188 AC_SUBST(NOLINKALL,$llvm_cv_no_link_all_option)
 189
 190 dnl Set the "LLVM_ON_*" variables based on llvm_cvs_platform_type
 191 dnl This is used by lib/System to determine the basic kind of implementation
 192 dnl to use.
 193 case $llvm_cv_platform_type in
 194   Unix)
 195     AC_DEFINE([LLVM_ON_UNIX],[1],[Define if this is Unixish platform])
 196     AC_SUBST(LLVM_ON_UNIX,[1])
 197     AC_SUBST(LLVM_ON_WIN32,[0])
 198     ;;
 199   Win32)
 200     AC_DEFINE([LLVM_ON_WIN32],[1],[Define if this is Win32ish platform])
 201     AC_SUBST(LLVM_ON_UNIX,[0])
 202     AC_SUBST(LLVM_ON_WIN32,[1])
 203     ;;
 204 esac
 205
 206 dnl Determine what our target architecture is and configure accordingly.
 207 dnl This will allow Makefiles to make a distinction between the hardware and
 208 dnl the OS.
 209 AC_CACHE_CHECK([target architecture],[llvm_cv_target_arch],
 210 [case $target in
 211   i?86-*)                 llvm_cv_target_arch="x86" ;;
 212   amd64-* | x86_64-*)     llvm_cv_target_arch="x86_64" ;;
 213   sparc*-*)               llvm_cv_target_arch="Sparc" ;;
 214   powerpc*-*)             llvm_cv_target_arch="PowerPC" ;;
 215   alpha*-*)               llvm_cv_target_arch="Alpha" ;;
 216   ia64-*)                 llvm_cv_target_arch="IA64" ;;
 217   arm-*)                  llvm_cv_target_arch="ARM" ;;
 218   mips-*)                 llvm_cv_target_arch="Mips" ;;
 219   *)                      llvm_cv_target_arch="Unknown" ;;
 220 esac])
 221
 222 if test "$llvm_cv_target_arch" = "Unknown" ; then
 223   AC_MSG_WARN([Configuring LLVM for an unknown target archicture])
 224 fi
 225
 226 dnl Define a substitution, ARCH, for the target architecture
 227 AC_SUBST(ARCH,$llvm_cv_target_arch)
 228
 229 dnl Check for the endianness of the target
 230 AC_C_BIGENDIAN([AC_SUBST([ENDIAN],[big]),
 231                 AC_DEFINE([MSB_FIRST], [1], [Define if this target is big endian])],
 232                [AC_SUBST([ENDIAN],[little]),
 233                 AC_DEFINE([LSB_FIRST], [1], [Define if this target is little endian])])
 234
 235 dnl Check for build platform executable suffix if we're crosscompiling
 236 if test "$cross_compiling" = yes; then
 237   AC_SUBST(LLVM_CROSS_COMPILING, [1])
 238   AC_BUILD_EXEEXT
 239 else
 240   AC_SUBST(LLVM_CROSS_COMPILING, [0])
 241 fi
 242
 243 dnl Check to see if there's a "CVS" (or .svn) directory indicating that this
 244 dnl build is being done from a checkout. This sets up several defaults for the
 245 dnl command line switches. When we build with a CVS directory, we get a
 246 dnl debug with assertions turned on. Without, we assume a source release and we
 247 dnl get an optimized build without assertions. See --enable-optimized and
 248 dnl --enable-assertions below
 249 if test -d "CVS" -o -d "${srcdir}/CVS" -o -d ".svn" -o -d "${srcdir}/.svn"; then
 250   cvsbuild="yes"
 251   optimize="no"
 252   AC_SUBST(CVSBUILD,[[CVSBUILD=1]])
 253 else
 254   cvsbuild="no"
 255   optimize="yes"
 256 fi
 257
 258 dnl===-----------------------------------------------------------------------===
 259 dnl===
 260 dnl=== SECTION 3: Command line arguments for the configure script.
 261 dnl===
 262 dnl===-----------------------------------------------------------------------===
 263
 264 dnl --enable-optimized : check whether they want to do an optimized build:
 265 AC_ARG_ENABLE(optimized, AS_HELP_STRING(
 266  [--enable-optimized,Compile with optimizations enabled (default is NO)]),,enableval=$optimize)
 267 if test ${enableval} = "no" ; then
 268   AC_SUBST(ENABLE_OPTIMIZED,[[]])
 269 else
 270   AC_SUBST(ENABLE_OPTIMIZED,[[ENABLE_OPTIMIZED=1]])
 271 fi
 272
 273 dnl --enable-assertions : check whether they want to turn on assertions or not:
 274 AC_ARG_ENABLE(assertions,AS_HELP_STRING(
 275   [--enable-assertions,Compile with assertion checks enabled (default is YES)]),, enableval="yes")
 276 if test ${enableval} = "yes" ; then
 277   AC_SUBST(DISABLE_ASSERTIONS,[[]])
 278 else
 279   AC_SUBST(DISABLE_ASSERTIONS,[[DISABLE_ASSERTIONS=1]])
 280 fi
 281
 282 dnl --enable-expensive-checks : check whether they want to turn on expensive debug checks:
 283 AC_ARG_ENABLE(expensive-checks,AS_HELP_STRING(
 284   [--enable-expensive-checks,Compile with expensive debug checks enabled (default is NO)]),, enableval="no")
 285 if test ${enableval} = "yes" ; then
 286   AC_SUBST(ENABLE_EXPENSIVE_CHECKS,[[ENABLE_EXPENSIVE_CHECKS=1]])
 287   AC_SUBST(EXPENSIVE_CHECKS,[[yes]])
 288 else
 289   AC_SUBST(ENABLE_EXPENSIVE_CHECKS,[[]])
 290   AC_SUBST(EXPENSIVE_CHECKS,[[no]])
 291 fi
 292
 293 dnl --enable-debug-runtime : should runtime libraries have debug symbols?
 294 AC_ARG_ENABLE(debug-runtime,
 295    AS_HELP_STRING([--enable-debug-runtime,Build runtime libs with debug symbols (default is NO)]),,enableval=no)
 296 if test ${enableval} = "no" ; then
 297   AC_SUBST(DEBUG_RUNTIME,[[]])
 298 else
 299   AC_SUBST(DEBUG_RUNTIME,[[DEBUG_RUNTIME=1]])
 300 fi
 301
 302 dnl --enable-jit: check whether they want to enable the jit
 303 AC_ARG_ENABLE(jit,
 304   AS_HELP_STRING(--enable-jit,
 305                  [Enable Just In Time Compiling (default is YES)]),,
 306   enableval=default)
 307 if test ${enableval} = "no"
 308 then
 309   AC_SUBST(JIT,[[]])
 310 else
 311   case "$llvm_cv_target_arch" in
 312     x86)     AC_SUBST(TARGET_HAS_JIT,1) ;;
 313     Sparc)   AC_SUBST(TARGET_HAS_JIT,0) ;;
 314     PowerPC) AC_SUBST(TARGET_HAS_JIT,1) ;;
 315     x86_64)  AC_SUBST(TARGET_HAS_JIT,1) ;;
 316     Alpha)   AC_SUBST(TARGET_HAS_JIT,1) ;;
 317     IA64)    AC_SUBST(TARGET_HAS_JIT,0) ;;
 318     ARM)     AC_SUBST(TARGET_HAS_JIT,0) ;;
 319     Mips)    AC_SUBST(TARGET_HAS_JIT,0) ;;
 320     *)       AC_SUBST(TARGET_HAS_JIT,0) ;;
 321   esac
 322 fi
 323
 324 dnl Allow enablement of doxygen generated documentation
 325 AC_ARG_ENABLE(doxygen,
 326               AS_HELP_STRING([--enable-doxygen],
 327                              [Build doxygen documentation (default is NO)]),,
 328                              enableval=default)
 329 case "$enableval" in
 330   yes) AC_SUBST(ENABLE_DOXYGEN,[1]) ;;
 331   no)  AC_SUBST(ENABLE_DOXYGEN,[0]) ;;
 332   default) AC_SUBST(ENABLE_DOXYGEN,[0]) ;;
 333   *) AC_MSG_ERROR([Invalid setting for --enable-doxygen. Use "yes" or "no"]) ;;
 334 esac
 335
 336 dnl Allow disablement of threads
 337 AC_ARG_ENABLE(threads,
 338               AS_HELP_STRING([--enable-threads],
 339                              [Use threads if available (default is YES)]),,
 340                              enableval=default)
 341 case "$enableval" in
 342   yes) AC_SUBST(ENABLE_THREADS,[1]) ;;
 343   no)  AC_SUBST(ENABLE_THREADS,[0]) ;;
 344   default) AC_SUBST(ENABLE_THREADS,[1]) ;;
 345   *) AC_MSG_ERROR([Invalid setting for --enable-threads. Use "yes" or "no"]) ;;
 346 esac
 347 AC_DEFINE_UNQUOTED([ENABLE_THREADS],$ENABLE_THREADS,[Define if threads enabled])
 348
 349 dnl Allow building with position independent code
 350 AC_ARG_ENABLE(pic,
 351   AS_HELP_STRING([--enable-pic],
 352                  [Build LLVM with Position Independent Code (default is NO)]),,
 353                  enableval=default)
 354 case "$enableval" in
 355   yes) AC_SUBST(ENABLE_PIC,[1]) ;;
 356   no)  AC_SUBST(ENABLE_PIC,[0]) ;;
 357   default) AC_SUBST(ENABLE_PIC,[0]) ;;
 358   *) AC_MSG_ERROR([Invalid setting for --enable-pic. Use "yes" or "no"]) ;;
 359 esac
 360 AC_DEFINE_UNQUOTED([ENABLE_PIC],$ENABLE_PIC,
 361                    [Define if position independent code is enabled])
 362
 363 dnl Allow specific targets to be specified for building (or not)
 364 TARGETS_TO_BUILD=""
 365 AC_ARG_ENABLE([targets],AS_HELP_STRING([--enable-targets],
 366     [Build specific host targets: all,host-only,{target-name} (default=all)]),,
 367     enableval=all)
 368 case "$enableval" in
 369   all) TARGETS_TO_BUILD="X86 Sparc PowerPC Alpha IA64 ARM Mips CellSPU" ;;
 370   host-only)
 371     case "$llvm_cv_target_arch" in
 372       x86)     TARGETS_TO_BUILD="X86" ;;
 373       x86_64)  TARGETS_TO_BUILD="X86" ;;
 374       Sparc)   TARGETS_TO_BUILD="Sparc" ;;
 375       PowerPC) TARGETS_TO_BUILD="PowerPC" ;;
 376       Alpha)   TARGETS_TO_BUILD="Alpha" ;;
 377       IA64)    TARGETS_TO_BUILD="IA64" ;;
 378       ARM)     TARGETS_TO_BUILD="ARM" ;;
 379       Mips)    TARGETS_TO_BUILD="Mips" ;;
 380       CellSPU|SPU) TARGETS_TO_BUILD="CellSPU" ;;
 381       *)       AC_MSG_ERROR([Can not set target to build]) ;;
 382     esac
 383     ;;
 384   *)for a_target in `echo $enableval|sed -e 's/,/ /g' ` ; do
 385       case "$a_target" in
 386         x86)     TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 387         x86_64)  TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 388         sparc)   TARGETS_TO_BUILD="Sparc $TARGETS_TO_BUILD" ;;
 389         powerpc) TARGETS_TO_BUILD="PowerPC $TARGETS_TO_BUILD" ;;
 390         alpha)   TARGETS_TO_BUILD="Alpha $TARGETS_TO_BUILD" ;;
 391         ia64)    TARGETS_TO_BUILD="IA64 $TARGETS_TO_BUILD" ;;
 392         arm)     TARGETS_TO_BUILD="ARM $TARGETS_TO_BUILD" ;;
 393         mips)    TARGETS_TO_BUILD="Mips $TARGETS_TO_BUILD" ;;
 394         spu)     TARGETS_TO_BUILD="CellSPU $TARGETS_TO_BUILD" ;;
 395         *) AC_MSG_ERROR([Unrecognized target $a_target]) ;;
 396       esac
 397   done
 398   ;;
 399 esac
 400 TARGETS_TO_BUILD="CBackend MSIL $TARGETS_TO_BUILD"
 401 AC_SUBST(TARGETS_TO_BUILD,$TARGETS_TO_BUILD)
 402
 403 dnl Prevent the CBackend from using printf("%a") for floating point so older
 404 dnl C compilers that cannot deal with the 0x0p+0 hex floating point format
 405 dnl can still compile the CBE's output
 406 AC_ARG_ENABLE([cbe-printf-a],AS_HELP_STRING([--enable-cbe-printf-a],
 407   [Enable C Backend output with hex floating point via %a  (default is YES)]),,
 408   enableval=default)
 409 case "$enableval" in
 410   yes) AC_SUBST(ENABLE_CBE_PRINTF_A,[1]) ;;
 411   no)  AC_SUBST(ENABLE_CBE_PRINTF_A,[0]) ;;
 412   default)  AC_SUBST(ENABLE_CBE_PRINTF_A,[1]) ;;
 413   *) AC_MSG_ERROR([Invalid setting for --enable-cbe-printf-a. Use "yes" or "no"]) ;;
 414 esac
 415 AC_DEFINE_UNQUOTED([ENABLE_CBE_PRINTF_A],$ENABLE_CBE_PRINTF_A,
 416                    [Define if CBE is enabled for printf %a output])
 417
 418 dnl Allow a specific llvm-gcc/llvm-g++ pair to be used with this LLVM config.
 419 AC_ARG_WITH(llvmgccdir,
 420   AS_HELP_STRING([--with-llvmgccdir],
 421     [Specify location of llvm-gcc install dir (default searches PATH)]),,
 422     withval=default)
 423 case "$withval" in
 424   default) WITH_LLVMGCCDIR=default ;;
 425   /* | [[A-Za-z]]:[[\\/]]*)      WITH_LLVMGCCDIR=$withval ;;
 426   *) AC_MSG_ERROR([Invalid path for --with-llvmgccdir. Provide full path]) ;;
 427 esac
 428
 429 dnl Allow a specific llvm-gcc compiler to be used with this LLVM config.
 430 AC_ARG_WITH(llvmgcc,
 431   AS_HELP_STRING([--with-llvmgcc],
 432     [Specify location of llvm-gcc driver (default searches PATH)]),
 433     LLVMGCC=$with_llvmgcc
 434       WITH_LLVMGCCDIR="",)
 435
 436 dnl Allow a specific llvm-g++ compiler to be used with this LLVM config.
 437 AC_ARG_WITH(llvmgxx,
 438   AS_HELP_STRING([--with-llvmgxx],
 439     [Specify location of llvm-g++ driver (default searches PATH)]),
 440     LLVMGXX=$with_llvmgxx
 441     WITH_LLVMGCCDIR="",)
 442
 443 if test -n "$LLVMGCC" && test -z "$LLVMGXX"; then
 444    AC_MSG_ERROR([Invalid llvm-g++. Use --with-llvmgxx when --with-llvmgcc is used]);
 445 fi
 446
 447 if test -n "$LLVMGXX" && test -z "$LLVMGCC"; then
 448    AC_MSG_ERROR([Invalid llvm-gcc. Use --with-llvmgcc when --with-llvmgxx is used]);
 449 fi
 450
 451 dnl Specify extra build options
 452 AC_ARG_WITH(extra-options,
 453   AS_HELP_STRING([--with-extra-options],
 454                  [Specify addtional options to compile LLVM with]),,
 455                  withval=default)
 456 case "$withval" in
 457   default) EXTRA_OPTIONS= ;;
 458   *) EXTRA_OPTIONS=$withval ;;
 459 esac
 460 AC_SUBST(EXTRA_OPTIONS,$EXTRA_OPTIONS)
 461
 462 dnl Allow specific bindings to be specified for building (or not)
 463 AC_ARG_ENABLE([bindings],AS_HELP_STRING([--enable-bindings],
 464     [Build specific language bindings: all,auto,none,{binding-name} (default=auto)]),,
 465     enableval=default)
 466 BINDINGS_TO_BUILD=""
 467 case "$enableval" in
 468   yes | default | auto) BINDINGS_TO_BUILD="auto" ;;
 469   all ) BINDINGS_TO_BUILD="ocaml" ;;
 470   none | no) BINDINGS_TO_BUILD="" ;;
 471   *)for a_binding in `echo $enableval|sed -e 's/,/ /g' ` ; do
 472       case "$a_binding" in
 473         ocaml) BINDINGS_TO_BUILD="ocaml $BINDINGS_TO_BUILD" ;;
 474         *) AC_MSG_ERROR([Unrecognized binding $a_binding]) ;;
 475       esac
 476   done
 477   ;;
 478 esac
 479
 480 dnl Allow the ocaml libdir to be overridden. This could go in a configure
 481 dnl script for bindings/ocaml/configure, except that its auto value depends on
 482 dnl OCAMLC, which is found here to support tests.
 483 AC_ARG_WITH([ocaml-libdir],
 484   [AS_HELP_STRING([--with-ocaml-libdir],
 485     [Specify install location for ocaml bindings (default is stdlib)])],
 486   [],
 487   [withval=auto])
 488 case "$withval" in
 489   auto) with_ocaml_libdir="$withval" ;;
 490   /* | [[A-Za-z]]:[[\\/]]*) with_ocaml_libdir="$withval" ;;
 491   *) AC_MSG_ERROR([Invalid path for --with-ocaml-libdir. Provide full path]) ;;
 492 esac
 493
 494 dnl===-----------------------------------------------------------------------===
 495 dnl===
 496 dnl=== SECTION 4: Check for programs we need and that they are the right version
 497 dnl===
 498 dnl===-----------------------------------------------------------------------===
 499
 500 dnl Check for compilation tools
 501 AC_PROG_CPP
 502 AC_PROG_CC(gcc)
 503 AC_PROG_CXX(g++)
 504 AC_PROG_FLEX
 505 AC_PROG_BISON
 506
 507 AC_PROG_NM
 508 AC_SUBST(NM)
 509
 510 dnl Check for the tools that the makefiles require
 511 AC_CHECK_GNU_MAKE
 512 AC_PROG_LN_S
 513 AC_PATH_PROG(CMP, [cmp], [cmp])
 514 AC_PATH_PROG(CP, [cp], [cp])
 515 AC_PATH_PROG(DATE, [date], [date])
 516 AC_PATH_PROG(FIND, [find], [find])
 517 AC_PATH_PROG(GREP, [grep], [grep])
 518 AC_PATH_PROG(MKDIR,[mkdir],[mkdir])
 519 AC_PATH_PROG(MV,   [mv],   [mv])
 520 AC_PROG_RANLIB
 521 AC_PATH_PROG(RM,   [rm],   [rm])
 522 AC_PATH_PROG(SED,  [sed],  [sed])
 523 AC_PATH_PROG(TAR,  [tar],  [gtar])
 524 AC_PATH_PROG(BINPWD,[pwd],  [pwd])
 525
 526 dnl Looking for misc. graph plotting software
 527 AC_PATH_PROG(GRAPHVIZ, [Graphviz], [echo Graphviz])
 528 if test "$GRAPHVIZ" != "echo Graphviz" ; then
 529   AC_DEFINE([HAVE_GRAPHVIZ],[1],[Define if the Graphviz program is available])
 530   dnl If we're targeting for mingw we should emit windows paths, not msys
 531   if test "$llvm_cv_os_type" = "MingW" ; then
 532     GRAPHVIZ=`echo $GRAPHVIZ | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 533   fi
 534   AC_DEFINE_UNQUOTED([LLVM_PATH_GRAPHVIZ],"$GRAPHVIZ${EXEEXT}",
 535    [Define to path to Graphviz program if found or 'echo Graphviz' otherwise])
 536 fi
 537 AC_PATH_PROG(DOT, [dot], [echo dot])
 538 if test "$DOT" != "echo dot" ; then
 539   AC_DEFINE([HAVE_DOT],[1],[Define if the dot program is available])
 540   dnl If we're targeting for mingw we should emit windows paths, not msys
 541   if test "$llvm_cv_os_type" = "MingW" ; then
 542     DOT=`echo $DOT | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 543   fi
 544   AC_DEFINE_UNQUOTED([LLVM_PATH_DOT],"$DOT${EXEEXT}",
 545    [Define to path to dot program if found or 'echo dot' otherwise])
 546 fi
 547 AC_PATH_PROGS(GV, [gv gsview32], [echo gv])
 548 if test "$GV" != "echo gv" ; then
 549   AC_DEFINE([HAVE_GV],[1],[Define if the gv program is available])
 550   dnl If we're targeting for mingw we should emit windows paths, not msys
 551   if test "$llvm_cv_os_type" = "MingW" ; then
 552     GV=`echo $GV | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 553   fi
 554   AC_DEFINE_UNQUOTED([LLVM_PATH_GV],"$GV${EXEEXT}",
 555    [Define to path to gv program if found or 'echo gv' otherwise])
 556 fi
 557 AC_PATH_PROG(DOTTY, [dotty], [echo dotty])
 558 if test "$DOTTY" != "echo dotty" ; then
 559   AC_DEFINE([HAVE_DOTTY],[1],[Define if the dotty program is available])
 560   dnl If we're targeting for mingw we should emit windows paths, not msys
 561   if test "$llvm_cv_os_type" = "MingW" ; then
 562     DOTTY=`echo $DOTTY | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 563   fi
 564   AC_DEFINE_UNQUOTED([LLVM_PATH_DOTTY],"$DOTTY${EXEEXT}",
 565    [Define to path to dotty program if found or 'echo dotty' otherwise])
 566 fi
 567
 568 dnl Look for a sufficiently recent version of Perl.
 569 LLVM_PROG_PERL([5.006])
 570 AC_SUBST(PERL)
 571 if test x"$PERL" = xnone; then
 572    AC_SUBST(HAVE_PERL,0)
 573    AC_MSG_ERROR([perl is required but was not found, please install it])
 574 else
 575    AC_SUBST(HAVE_PERL,1)
 576 fi
 577
 578 dnl Find the install program
 579 AC_PROG_INSTALL
 580
 581 dnl Checks for documentation and testing tools that we can do without. If these
 582 dnl are not found then they are set to "true" which always succeeds but does
 583 dnl nothing. This just lets the build output show that we could have done
 584 dnl something if the tool was available.
 585 AC_PATH_PROG(BZIP2,[bzip2],[echo "Skipped: bzip2 not found"])
 586 AC_PATH_PROG(DOXYGEN,[doxygen],[echo "Skipped: doxygen not found"])
 587 AC_PATH_PROG(GROFF,[groff],[echo "Skipped: groff not found"])
 588 AC_PATH_PROG(GZIP,[gzip],[echo "Skipped: gzip not found"])
 589 AC_PATH_PROG(POD2HTML,[pod2html],[echo "Skipped: pod2html not found"])
 590 AC_PATH_PROG(POD2MAN,[pod2man],[echo "Skipped: pod2man not found"])
 591 AC_PATH_PROG(RUNTEST,[runtest],[echo "Skipped: runtest not found"])
 592 DJ_AC_PATH_TCLSH
 593 AC_PATH_PROG(ZIP,[zip],[echo "Skipped: zip not found"])
 594 AC_PATH_PROG(OCAMLC,[ocamlc],[echo "Skipped: ocamlc not found"])
 595 AC_PATH_PROG(OCAMLOPT,[ocamlopt],[echo "Skipped: ocamlopt not found"])
 596 AC_PATH_PROG(OCAMLDEP,[ocamldep],[echo "Skipped: ocamldep not found"])
 597
 598 dnl Determine if the linker supports the -R option.
 599 AC_LINK_USE_R
 600
 601 dnl Check for libtool and the library that has dlopen function (which must come
 602 dnl before the AC_PROG_LIBTOOL check in order to enable dlopening libraries with
 603 dnl libtool).
 604 AC_LIBTOOL_DLOPEN
 605 AC_LIB_LTDL
 606 AC_PROG_LIBTOOL
 607
 608 if test "$lt_cv_dlopen_self" = "yes" ; then
 609   AC_DEFINE([CAN_DLOPEN_SELF],[1],
 610               [Define if dlopen(0) will open the symbols of the program])
 611 fi
 612
 613 if test "$WITH_LLVMGCCDIR" = "default" ; then
 614   LLVMGCC="llvm-gcc${EXEEXT}"
 615   LLVMGXX="llvm-g++${EXEEXT}"
 616   AC_PATH_PROG(LLVMGCC, $LLVMGCC, [])
 617   AC_PATH_PROG(LLVMGXX, $LLVMGXX, [])
 618 else
 619   if test -z "$LLVMGCC"; then
 620     LLVMGCC="$WITH_LLVMGCCDIR/bin/llvm-gcc${EXEEXT}"
 621   fi
 622   if test -z "$LLVMGXX"; then
 623     LLVMGXX="$WITH_LLVMGCCDIR/bin/llvm-g++${EXEEXT}"
 624   fi
 625   AC_SUBST(LLVMGCC,$LLVMGCC)
 626   AC_SUBST(LLVMGXX,$LLVMGXX)
 627 fi
 628
 629 AC_MSG_CHECKING([tool compatibility])
 630
 631 dnl Ensure that compilation tools are GCC or a GNU compatible compiler such as
 632 dnl ICC; we use GCC specific options in the makefiles so the compiler needs
 633 dnl to support those options.
 634 dnl "icc" emits gcc signatures
 635 dnl "icc -no-gcc" emits no gcc signature BUT is still compatible
 636 ICC=no
 637 IXX=no
 638 case $CC in
 639   icc*|icpc*)
 640     ICC=yes
 641     IXX=yes
 642     ;;
 643    *)
 644     ;;
 645 esac
 646
 647 if test "$GCC" != "yes" && test "$ICC" != "yes"
 648 then
 649   AC_MSG_ERROR([gcc|icc required but not found])
 650 fi
 651
 652 dnl Ensure that compilation tools are GCC; we use GCC specific extensions
 653 if test "$GXX" != "yes" && test "$IXX" != "yes"
 654 then
 655   AC_MSG_ERROR([g++|icc required but not found])
 656 fi
 657
 658 dnl Verify that GCC is version 3.0 or higher
 659 if test "$GCC" = "yes"
 660 then
 661   gccmajor=`$CC --version | head -n 1 | sed 's/[[^0-9]]*\([[0-9.]]\).*/\1/'`
 662   if test "$gccmajor" -lt "3"
 663   then
 664     AC_MSG_ERROR([gcc 3.x required, but you have a lower version])
 665   fi
 666 fi
 667
 668 dnl Check for GNU Make.  We use its extensions, so don't build without it
 669 if test -z "$llvm_cv_gnu_make_command"
 670 then
 671   AC_MSG_ERROR([GNU Make required but not found])
 672 fi
 673
 674 dnl Tool compatibility is okay if we make it here.
 675 AC_MSG_RESULT([ok])
 676
 677 dnl===-----------------------------------------------------------------------===
 678 dnl===
 679 dnl=== SECTION 5: Check for libraries
 680 dnl===
 681 dnl===-----------------------------------------------------------------------===
 682
 683 dnl libelf is for sparc only; we can ignore it if we don't have it
 684 AC_CHECK_LIB(elf, elf_begin)
 685 AC_CHECK_LIB(m,sin)
 686 if test "$llvm_cv_os_type" = "MingW" ; then
 687   AC_CHECK_LIB(imagehlp, main)
 688   AC_CHECK_LIB(psapi, main)
 689 fi
 690
 691 dnl lt_dlopen may be required for plugin support.
 692 AC_SEARCH_LIBS(lt_dlopen,ltdl,AC_DEFINE([HAVE_LT_DLOPEN],[1],
 693               [Define if lt_dlopen() is available on this platform]),
 694               AC_MSG_WARN([lt_dlopen() not found - plugin support might
 695                            not be available]))
 696
 697 dnl dlopen() is required for plugin support.
 698 AC_SEARCH_LIBS(dlopen,dl,AC_DEFINE([HAVE_DLOPEN],[1],
 699                [Define if dlopen() is available on this platform.]),
 700                AC_MSG_WARN([dlopen() not found - disabling plugin support]))
 701
 702 dnl mallinfo is optional; the code can compile (minus features) without it
 703 AC_SEARCH_LIBS(mallinfo,malloc,AC_DEFINE([HAVE_MALLINFO],[1],
 704                [Define if mallinfo() is available on this platform.]))
 705
 706 dnl pthread locking functions are optional - but llvm will not be thread-safe
 707 dnl without locks.
 708 if test "$ENABLE_THREADS" -eq 1 ; then
 709   AC_CHECK_LIB(pthread,pthread_mutex_init)
 710   AC_SEARCH_LIBS(pthread_mutex_lock,pthread,
 711                  AC_DEFINE([HAVE_PTHREAD_MUTEX_LOCK],[1],
 712                            [Have pthread_mutex_lock]))
 713 fi
 714
 715 dnl Allow extra x86-disassembler library
 716 AC_ARG_WITH(udis86,
 717   AS_HELP_STRING([--with-udis86=<path>],
 718     [Use udis86 external x86 disassembler library]),
 719     [
 720       AC_SUBST(USE_UDIS86, [1])
 721       case "$withval" in
 722         /usr/lib|yes) ;;
 723         *) LDFLAGS="$LDFLAGS -L${withval}" ;;
 724       esac
 725       AC_CHECK_LIB(udis86, ud_init, [], [
 726         echo "Error! You need to have libudis86 around."
 727         exit -1
 728       ])
 729     ],
 730     AC_SUBST(USE_UDIS86, [0]))
 731 AC_DEFINE_UNQUOTED([USE_UDIS86],$USE_UDIS86,
 732                    [Define if use udis86 library])
 733
 734 dnl===-----------------------------------------------------------------------===
 735 dnl===
 736 dnl=== SECTION 6: Check for header files
 737 dnl===
 738 dnl===-----------------------------------------------------------------------===
 739
 740 dnl First, use autoconf provided macros for specific headers that we need
 741 dnl We don't check for ancient stuff or things that are guaranteed to be there
 742 dnl by the C++ standard. We always use the <cfoo> versions of <foo.h> C headers.
 743 dnl Generally we're looking for POSIX headers.
 744 AC_HEADER_DIRENT
 745 AC_HEADER_MMAP_ANONYMOUS
 746 AC_HEADER_STAT
 747 AC_HEADER_STDC
 748 AC_HEADER_SYS_WAIT
 749 AC_HEADER_TIME
 750
 751 AC_CHECK_HEADERS([dlfcn.h execinfo.h fcntl.h inttypes.h limits.h link.h])
 752 AC_CHECK_HEADERS([malloc.h setjmp.h signal.h stdint.h unistd.h utime.h])
 753 AC_CHECK_HEADERS([windows.h])
 754 AC_CHECK_HEADERS([sys/mman.h sys/param.h sys/resource.h sys/time.h])
 755 AC_CHECK_HEADERS([sys/types.h malloc/malloc.h mach/mach.h])
 756 if test "$ENABLE_THREADS" -eq 1 ; then
 757   AC_CHECK_HEADERS(pthread.h,
 758                   AC_SUBST(HAVE_PTHREAD, 1),
 759                    AC_SUBST(HAVE_PTHREAD, 0))
 760 else
 761   AC_SUBST(HAVE_PTHREAD, 0)
 762 fi
 763
 764 dnl===-----------------------------------------------------------------------===
 765 dnl===
 766 dnl=== SECTION 7: Check for types and structures
 767 dnl===
 768 dnl===-----------------------------------------------------------------------===
 769
 770 AC_HUGE_VAL_CHECK
 771 AC_TYPE_PID_T
 772 AC_TYPE_SIZE_T
 773 AC_TYPE_SIGNAL
 774 AC_STRUCT_TM
 775 AC_CHECK_TYPES([int64_t],,AC_MSG_ERROR([Type int64_t required but not found]))
 776 AC_CHECK_TYPES([uint64_t],,
 777          AC_CHECK_TYPES([u_int64_t],,
 778          AC_MSG_ERROR([Type uint64_t or u_int64_t required but not found])))
 779
 780 dnl===-----------------------------------------------------------------------===
 781 dnl===
 782 dnl=== SECTION 8: Check for specific functions needed
 783 dnl===
 784 dnl===-----------------------------------------------------------------------===
 785
 786 AC_CHECK_FUNCS([backtrace ceilf floorf roundf rintf nearbyintf getcwd ])
 787 AC_CHECK_FUNCS([powf fmodf strtof round ])
 788 AC_CHECK_FUNCS([getpagesize getrusage getrlimit setrlimit gettimeofday ])
 789 AC_CHECK_FUNCS([isatty mkdtemp mkstemp ])
 790 AC_CHECK_FUNCS([mktemp realpath sbrk setrlimit strdup strerror strerror_r ])
 791 AC_CHECK_FUNCS([strtoll strtoq sysconf malloc_zone_statistics ])
 792 AC_CHECK_FUNCS([setjmp longjmp sigsetjmp siglongjmp])
 793 AC_C_PRINTF_A
 794 AC_FUNC_ALLOCA
 795 AC_FUNC_RAND48
 796
 797 dnl Check for variations in the Standard C++ library and STL. These macros are
 798 dnl provided by LLVM in the autoconf/m4 directory.
 799 AC_CXX_HAVE_HASH_MAP
 800 AC_CXX_HAVE_HASH_SET
 801 AC_CXX_HAVE_STD_ITERATOR
 802 AC_CXX_HAVE_BI_ITERATOR
 803 AC_CXX_HAVE_FWD_ITERATOR
 804 AC_FUNC_ISNAN
 805 AC_FUNC_ISINF
 806
 807 dnl Check for mmap support.We also need to know if /dev/zero is required to
 808 dnl be opened for allocating RWX memory.
 809 dnl Make sure we aren't attempting to configure for an unknown system
 810 if test "$llvm_cv_platform_type" = "Unix" ; then
 811   AC_FUNC_MMAP
 812   AC_FUNC_MMAP_FILE
 813   AC_NEED_DEV_ZERO_FOR_MMAP
 814
 815   if test "$ac_cv_func_mmap_fixed_mapped" = "no"
 816   then
 817     AC_MSG_WARN([mmap() of a fixed address required but not supported])
 818   fi
 819   if test "$ac_cv_func_mmap_file" = "no"
 820   then
 821     AC_MSG_WARN([mmap() of files required but not found])
 822   fi
 823 fi
 824
 825 dnl===-----------------------------------------------------------------------===
 826 dnl===
 827 dnl=== SECTION 9: Additional checks, variables, etc.
 828 dnl===
 829 dnl===-----------------------------------------------------------------------===
 830
 831 dnl Check, whether __dso_handle is present
 832 AC_CHECK_FUNCS([__dso_handle])
 833
 834 dnl See if the llvm-gcc executable can compile to LLVM assembly
 835 AC_CACHE_CHECK([whether llvm-gcc is sane],[llvm_cv_llvmgcc_sanity],
 836 [llvm_cv_llvmgcc_sanity="no"
 837 if test -x "$LLVMGCC" ; then
 838   cp /dev/null conftest.c
 839   "$LLVMGCC" -emit-llvm -S -o - conftest.c | \
 840       grep 'target datalayout =' > /dev/null 2>&1
 841   if test $? -eq 0 ; then
 842     llvm_cv_llvmgcc_sanity="yes"
 843   fi
 844   rm conftest.c
 845 fi])
 846
 847 dnl Since we have a sane llvm-gcc, identify it and its sub-tools
 848 if test "$llvm_cv_llvmgcc_sanity" = "yes" ; then
 849   AC_MSG_CHECKING([llvm-gcc component support])
 850   llvmcc1path=`"$LLVMGCC" --print-prog-name=cc1`
 851   AC_SUBST(LLVMCC1,$llvmcc1path)
 852   llvmcc1pluspath=`"$LLVMGCC" --print-prog-name=cc1plus`
 853   AC_SUBST(LLVMCC1PLUS,$llvmcc1pluspath)
 854   llvmgccdir=`echo "$llvmcc1path" | sed 's,/libexec/.*,,'`
 855   AC_SUBST(LLVMGCCDIR,$llvmgccdir)
 856   llvmgcclibexec=`echo "$llvmcc1path" | sed 's,/cc1,,'`
 857   AC_SUBST(LLVMGCCLIBEXEC,$llvmgcclibexec)
 858   llvmgccversion=[`"$LLVMGCC" -dumpversion 2>&1 | sed 's/^\([0-9.]*\).*/\1/'`]
 859   llvmgccmajvers=[`echo $llvmgccversion | sed 's/^\([0-9]\).*/\1/'`]
 860   AC_SUBST(LLVMGCC_VERSION,$llvmgccversion)
 861   AC_SUBST(LLVMGCC_MAJVERS,$llvmgccmajvers)
 862   llvmgcclangs=[`"$LLVMGCC" -v --help 2>&1 | grep '^Configured with:' | sed 's/^.*--enable-languages=\([^ -]*\).*/\1/'`]
 863   AC_SUBST(LLVMGCC_LANGS,$llvmgcclangs)
 864   AC_MSG_RESULT([ok])
 865 fi
 866
 867 dnl Propagate the shared library extension that the libltdl checks did to
 868 dnl the Makefiles so we can use it there too
 869 AC_SUBST(SHLIBEXT,$libltdl_cv_shlibext)
 870
 871 # Translate the various configuration directories and other basic
 872 # information into substitutions that will end up in Makefile.config.in
 873 # that these configured values can be used by the makefiles
 874 if test "${prefix}" = "NONE" ; then
 875   prefix="/usr/local"
 876 fi
 877 eval LLVM_PREFIX="${prefix}";
 878 eval LLVM_BINDIR="${prefix}/bin";
 879 eval LLVM_LIBDIR="${prefix}/lib";
 880 eval LLVM_DATADIR="${prefix}/share/llvm";
 881 eval LLVM_DOCSDIR="${prefix}/docs/llvm";
 882 eval LLVM_ETCDIR="${prefix}/etc/llvm";
 883 eval LLVM_INCLUDEDIR="${prefix}/include";
 884 eval LLVM_INFODIR="${prefix}/info";
 885 eval LLVM_MANDIR="${prefix}/man";
 886 LLVM_CONFIGTIME=`date`
 887 AC_SUBST(LLVM_PREFIX)
 888 AC_SUBST(LLVM_BINDIR)
 889 AC_SUBST(LLVM_LIBDIR)
 890 AC_SUBST(LLVM_DATADIR)
 891 AC_SUBST(LLVM_DOCSDIR)
 892 AC_SUBST(LLVM_ETCDIR)
 893 AC_SUBST(LLVM_INCLUDEDIR)
 894 AC_SUBST(LLVM_INFODIR)
 895 AC_SUBST(LLVM_MANDIR)
 896 AC_SUBST(LLVM_CONFIGTIME)
 897
 898 # Place the various directores into the config.h file as #defines so that we
 899 # can know about the installation paths within LLVM.
 900 AC_DEFINE_UNQUOTED(LLVM_PREFIX,"$LLVM_PREFIX",
 901                    [Installation prefix directory])
 902 AC_DEFINE_UNQUOTED(LLVM_BINDIR, "$LLVM_BINDIR",
 903                    [Installation directory for binary executables])
 904 AC_DEFINE_UNQUOTED(LLVM_LIBDIR, "$LLVM_LIBDIR",
 905                    [Installation directory for libraries])
 906 AC_DEFINE_UNQUOTED(LLVM_DATADIR, "$LLVM_DATADIR",
 907                    [Installation directory for data files])
 908 AC_DEFINE_UNQUOTED(LLVM_DOCSDIR, "$LLVM_DOCSDIR",
 909                    [Installation directory for documentation])
 910 AC_DEFINE_UNQUOTED(LLVM_ETCDIR, "$LLVM_ETCDIR",
 911                    [Installation directory for config files])
 912 AC_DEFINE_UNQUOTED(LLVM_INCLUDEDIR, "$LLVM_INCLUDEDIR",
 913                    [Installation directory for include files])
 914 AC_DEFINE_UNQUOTED(LLVM_INFODIR, "$LLVM_INFODIR",
 915                    [Installation directory for .info files])
 916 AC_DEFINE_UNQUOTED(LLVM_MANDIR, "$LLVM_MANDIR",
 917                    [Installation directory for man pages])
 918 AC_DEFINE_UNQUOTED(LLVM_CONFIGTIME, "$LLVM_CONFIGTIME",
 919                    [Time at which LLVM was configured])
 920 AC_DEFINE_UNQUOTED(LLVM_HOSTTRIPLE, "$host",
 921                    [Host triple we were built on])
 922
 923 # Determine which bindings to build.
 924 if test "$BINDINGS_TO_BUILD" = auto ; then
 925   BINDINGS_TO_BUILD=""
 926   if test "x$OCAMLC" != x -a "x$OCAMLDEP" != x ; then
 927     BINDINGS_TO_BUILD="ocaml $BINDINGS_TO_BUILD"
 928   fi
 929 fi
 930 AC_SUBST(BINDINGS_TO_BUILD,$BINDINGS_TO_BUILD)
 931
 932 # This isn't really configurey, but it avoids having to repeat the list in
 933 # other files.
 934 AC_SUBST(ALL_BINDINGS,ocaml)
 935
 936 # Do any work necessary to ensure that bindings have what they need.
 937 binding_prereqs_failed=0
 938 for a_binding in $BINDINGS_TO_BUILD ; do
 939   case "$a_binding" in
 940   ocaml)
 941     if test "x$OCAMLC" = x ; then
 942       AC_MSG_WARN([--enable-bindings=ocaml specified, but ocamlc not found. Try configure OCAMLC=/path/to/ocamlc])
 943       binding_prereqs_failed=1
 944     fi
 945     if test "x$OCAMLDEP" = x ; then
 946       AC_MSG_WARN([--enable-bindings=ocaml specified, but ocamldep not found. Try configure OCAMLDEP=/path/to/ocamldep])
 947       binding_prereqs_failed=1
 948     fi
 949     if test "x$OCAMLOPT" = x ; then
 950       AC_MSG_WARN([--enable-bindings=ocaml specified, but ocamlopt not found. Try configure OCAMLOPT=/path/to/ocamlopt])
 951       dnl ocamlopt is optional!
 952     fi
 953     if test "x$with_ocaml_libdir" != xauto ; then
 954       AC_SUBST(OCAML_LIBDIR,$with_ocaml_libdir)
 955     else
 956       ocaml_stdlib="`"$OCAMLC" -where`"
 957       if test "$LLVM_PREFIX" '<' "$ocaml_stdlib" -a "$ocaml_stdlib" '<' "$LLVM_PREFIX~"
 958       then
 959         # ocaml stdlib is beneath our prefix; use stdlib
 960         AC_SUBST(OCAML_LIBDIR,$ocaml_stdlib)
 961       else
 962         # ocaml stdlib is outside our prefix; use libdir/ocaml
 963         AC_SUBST(OCAML_LIBDIR,$LLVM_LIBDIR/ocaml)
 964       fi
 965     fi
 966     ;;
 967   esac
 968 done
 969 if test "$binding_prereqs_failed" = 1 ; then
 970   AC_MSG_ERROR([Prequisites for bindings not satisfied. Fix them or use configure --disable-bindings.])
 971 fi
 972
 973
 974 dnl===-----------------------------------------------------------------------===
 975 dnl===
 976 dnl=== SECTION 10: Specify the output files and generate it
 977 dnl===
 978 dnl===-----------------------------------------------------------------------===
 979
 980 dnl Configure header files
 981 dnl WARNING: dnl If you add or remove any of the following config headers, then
 982 dnl you MUST also update Makefile.rules so that the variable FilesToConfig
 983 dnl contains the same list of files as AC_CONFIG_HEADERS below. This ensures the
 984 dnl files can be updated automatically when their *.in sources change.
 985 AC_CONFIG_HEADERS([include/llvm/Config/config.h])
 986 AC_CONFIG_HEADERS([include/llvm/Support/DataTypes.h])
 987 AC_CONFIG_HEADERS([include/llvm/ADT/hash_map])
 988 AC_CONFIG_HEADERS([include/llvm/ADT/hash_set])
 989 AC_CONFIG_HEADERS([include/llvm/ADT/iterator])
 990
 991 dnl Configure the makefile's configuration data
 992 AC_CONFIG_FILES([Makefile.config])
 993
 994 dnl Configure the RPM spec file for LLVM
 995 AC_CONFIG_FILES([llvm.spec])
 996
 997 dnl Configure doxygen's configuration file
 998 AC_CONFIG_FILES([docs/doxygen.cfg])
 999
1000 dnl Do the first stage of configuration for llvm-config.in.
1001 AC_CONFIG_FILES([tools/llvm-config/llvm-config.in])
1002
1003 dnl Do special configuration of Makefiles
1004 AC_CONFIG_COMMANDS([setup],,[llvm_src="${srcdir}"])
1005 AC_CONFIG_MAKEFILE(Makefile)
1006 AC_CONFIG_MAKEFILE(Makefile.common)
1007 AC_CONFIG_MAKEFILE(examples/Makefile)
1008 AC_CONFIG_MAKEFILE(lib/Makefile)
1009 AC_CONFIG_MAKEFILE(runtime/Makefile)
1010 AC_CONFIG_MAKEFILE(test/Makefile)
1011 AC_CONFIG_MAKEFILE(test/Makefile.tests)
1012 AC_CONFIG_MAKEFILE(tools/Makefile)
1013 AC_CONFIG_MAKEFILE(utils/Makefile)
1014 AC_CONFIG_MAKEFILE(projects/Makefile)
1015 AC_CONFIG_MAKEFILE(bindings/Makefile)
1016 AC_CONFIG_MAKEFILE(bindings/ocaml/Makefile.ocaml)
1017
1018 dnl Finally, crank out the output
1019 AC_OUTPUT