autoconf/configure.ac

   1 dnl === configure.ac --------------------------------------------------------===
   2 dnl                     The LLVM Compiler Infrastructure
   3 dnl
   4 dnl This file is distributed under the University of Illinois Open Source
   5 dnl License. See LICENSE.TXT for details.
   6 dnl
   7 dnl===-----------------------------------------------------------------------===
   8 dnl This is the LLVM configuration script. It is processed by the autoconf
   9 dnl program to produce a script named configure. This script contains the
  10 dnl configuration checks that LLVM needs in order to support multiple platforms.
  11 dnl This file is composed of 10 sections per the recommended organization of
  12 dnl autoconf input defined in the autoconf documentation. As this file evolves,
  13 dnl please keep the various types of checks within their sections. The sections
  14 dnl are as follows:
  15 dnl
  16 dnl SECTION 1: Initialization & Setup
  17 dnl SECTION 2: Architecture, target, and host checks
  18 dnl SECTION 3: Command line arguments for the configure script.
  19 dnl SECTION 4: Check for programs we need and that they are the right version
  20 dnl SECTION 5: Check for libraries
  21 dnl SECTION 6: Check for header files
  22 dnl SECTION 7: Check for types and structures
  23 dnl SECTION 8: Check for specific functions needed
  24 dnl SECTION 9: Additional checks, variables, etc.
  25 dnl SECTION 10: Specify the output files and generate it
  26 dnl
  27 dnl===-----------------------------------------------------------------------===
  28 dnl===
  29 dnl=== SECTION 1: Initialization & Setup
  30 dnl===
  31 dnl===-----------------------------------------------------------------------===
  32 dnl Initialize autoconf and define the package name, version number and
  33 dnl email address for reporting bugs.
  34 AC_INIT([[llvm]],[[2.6svn]],[llvmbugs@cs.uiuc.edu])
  35
  36 dnl Provide a copyright substitution and ensure the copyright notice is included
  37 dnl in the output of --version option of the generated configure script.
  38 AC_SUBST(LLVM_COPYRIGHT,["Copyright (c) 2003-2008 University of Illinois at Urbana-Champaign."])
  39 AC_COPYRIGHT([Copyright (c) 2003-2008 University of Illinois at Urbana-Champaign.])
  40
  41 dnl Indicate that we require autoconf 2.59 or later. Ths is needed because we
  42 dnl use some autoconf macros only available in 2.59.
  43 AC_PREREQ(2.59)
  44
  45 dnl Verify that the source directory is valid. This makes sure that we are
  46 dnl configuring LLVM and not some other package (it validates --srcdir argument)
  47 AC_CONFIG_SRCDIR([lib/VMCore/Module.cpp])
  48
  49 dnl Place all of the extra autoconf files into the config subdirectory. Tell
  50 dnl various tools where the m4 autoconf macros are.
  51 AC_CONFIG_AUX_DIR([autoconf])
  52
  53 dnl Quit if the source directory has already been configured.
  54 dnl NOTE: This relies upon undocumented autoconf behavior.
  55 if test ${srcdir} != "." ; then
  56   if test -f ${srcdir}/include/llvm/Config/config.h ; then
  57     AC_MSG_ERROR([Already configured in ${srcdir}])
  58   fi
  59 fi
  60
  61 dnl Configure all of the projects present in our source tree. While we could
  62 dnl just AC_CONFIG_SUBDIRS on the set of directories in projects that have a
  63 dnl configure script, that usage of the AC_CONFIG_SUBDIRS macro is deprecated.
  64 dnl Instead we match on the known projects.
  65 for i in `ls ${srcdir}/projects`
  66 do
  67   if test -d ${srcdir}/projects/${i} ; then
  68     case ${i} in
  69       CVS) ;;
  70       sample)       AC_CONFIG_SUBDIRS([projects/sample])    ;;
  71       privbracket)  AC_CONFIG_SUBDIRS([projects/privbracket]) ;;
  72       llvm-stacker) AC_CONFIG_SUBDIRS([projects/llvm-stacker]) ;;
  73       # llvm-test is the old name of the test-suite, kept here for backwards
  74       # compatibility
  75       llvm-test)    AC_CONFIG_SUBDIRS([projects/llvm-test]) ;;
  76       test-suite)   AC_CONFIG_SUBDIRS([projects/test-suite]) ;;
  77       llvm-reopt)   AC_CONFIG_SUBDIRS([projects/llvm-reopt]);;
  78       llvm-gcc)     AC_CONFIG_SUBDIRS([projects/llvm-gcc])  ;;
  79       llvm-java)    AC_CONFIG_SUBDIRS([projects/llvm-java]) ;;
  80       llvm-tv)      AC_CONFIG_SUBDIRS([projects/llvm-tv])   ;;
  81       llvm-poolalloc) AC_CONFIG_SUBDIRS([projects/llvm-poolalloc]) ;;
  82       poolalloc)    AC_CONFIG_SUBDIRS([projects/poolalloc]) ;;
  83       llvm-kernel)  AC_CONFIG_SUBDIRS([projects/llvm-kernel]) ;;
  84       *)
  85         AC_MSG_WARN([Unknown project (${i}) won't be configured automatically])
  86         ;;
  87     esac
  88   fi
  89 done
  90
  91 dnl===-----------------------------------------------------------------------===
  92 dnl===
  93 dnl=== SECTION 2: Architecture, target, and host checks
  94 dnl===
  95 dnl===-----------------------------------------------------------------------===
  96
  97 dnl Check the target for which we're compiling and the host that will do the
  98 dnl compilations. This will tell us which LLVM compiler will be used for
  99 dnl compiling SSA into object code. This needs to be done early because
 100 dnl following tests depend on it.
 101 AC_CANONICAL_TARGET
 102
 103 dnl Determine the platform type and cache its value. This helps us configure
 104 dnl the System library to the correct build platform.
 105 AC_CACHE_CHECK([type of operating system we're going to host on],
 106                [llvm_cv_os_type],
 107 [case $host in
 108   *-*-aix*)
 109     llvm_cv_link_all_option="-Wl,--whole-archive"
 110     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 111     llvm_cv_os_type="AIX"
 112     llvm_cv_platform_type="Unix" ;;
 113   *-*-irix*)
 114     llvm_cv_link_all_option="-Wl,--whole-archive"
 115     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 116     llvm_cv_os_type="IRIX"
 117     llvm_cv_platform_type="Unix" ;;
 118   *-*-cygwin*)
 119     llvm_cv_link_all_option="-Wl,--whole-archive"
 120     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 121     llvm_cv_os_type="Cygwin"
 122     llvm_cv_platform_type="Unix" ;;
 123   *-*-darwin*)
 124     llvm_cv_link_all_option="-Wl,-all_load"
 125     llvm_cv_no_link_all_option="-Wl,-noall_load"
 126     llvm_cv_os_type="Darwin"
 127     llvm_cv_platform_type="Unix" ;;
 128   *-*-freebsd*)
 129     llvm_cv_link_all_option="-Wl,--whole-archive"
 130     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 131     llvm_cv_os_type="FreeBSD"
 132     llvm_cv_platform_type="Unix" ;;
 133   *-*-openbsd*)
 134     llvm_cv_link_all_option="-Wl,--whole-archive"
 135     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 136     llvm_cv_os_type="OpenBSD"
 137     llvm_cv_platform_type="Unix" ;;
 138   *-*-netbsd*)
 139     llvm_cv_link_all_option="-Wl,--whole-archive"
 140     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 141     llvm_cv_os_type="NetBSD"
 142     llvm_cv_platform_type="Unix" ;;
 143   *-*-dragonfly*)
 144     llvm_cv_link_all_option="-Wl,--whole-archive"
 145     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 146     llvm_cv_os_type="DragonFly"
 147     llvm_cv_platform_type="Unix" ;;
 148   *-*-hpux*)
 149     llvm_cv_link_all_option="-Wl,--whole-archive"
 150     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 151     llvm_cv_os_type="HP-UX"
 152     llvm_cv_platform_type="Unix" ;;
 153   *-*-interix*)
 154     llvm_cv_link_all_option="-Wl,--whole-archive"
 155     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 156     llvm_cv_os_type="Interix"
 157     llvm_cv_platform_type="Unix" ;;
 158   *-*-linux*)
 159     llvm_cv_link_all_option="-Wl,--whole-archive"
 160     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 161     llvm_cv_os_type="Linux"
 162     llvm_cv_platform_type="Unix" ;;
 163   *-*-solaris*)
 164     llvm_cv_link_all_option="-Wl,-z,allextract"
 165     llvm_cv_no_link_all_option="-Wl,-z,defaultextract"
 166     llvm_cv_os_type="SunOS"
 167     llvm_cv_platform_type="Unix" ;;
 168   *-*-win32*)
 169     llvm_cv_link_all_option="-Wl,--whole-archive"
 170     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 171     llvm_cv_os_type="Win32"
 172     llvm_cv_platform_type="Win32" ;;
 173   *-*-mingw*)
 174     llvm_cv_link_all_option="-Wl,--whole-archive"
 175     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 176     llvm_cv_os_type="MingW"
 177     llvm_cv_platform_type="Win32" ;;
 178   *)
 179     llvm_cv_link_all_option=""
 180     llvm_cv_no_link_all_option=""
 181     llvm_cv_os_type="Unknown"
 182     llvm_cv_platform_type="Unknown" ;;
 183 esac])
 184
 185 dnl Make sure we aren't attempting to configure for an unknown system
 186 if test "$llvm_cv_os_type" = "Unknown" ; then
 187   AC_MSG_ERROR([Operating system is unknown, configure can't continue])
 188 fi
 189
 190 dnl Set the "OS" Makefile variable based on the platform type so the
 191 dnl makefile can configure itself to specific build hosts
 192 AC_SUBST(OS,$llvm_cv_os_type)
 193
 194 dnl Set the LINKALL and NOLINKALL Makefile variables based on the platform
 195 AC_SUBST(LINKALL,$llvm_cv_link_all_option)
 196 AC_SUBST(NOLINKALL,$llvm_cv_no_link_all_option)
 197
 198 dnl Set the "LLVM_ON_*" variables based on llvm_cvs_platform_type
 199 dnl This is used by lib/System to determine the basic kind of implementation
 200 dnl to use.
 201 case $llvm_cv_platform_type in
 202   Unix)
 203     AC_DEFINE([LLVM_ON_UNIX],[1],[Define if this is Unixish platform])
 204     AC_SUBST(LLVM_ON_UNIX,[1])
 205     AC_SUBST(LLVM_ON_WIN32,[0])
 206     ;;
 207   Win32)
 208     AC_DEFINE([LLVM_ON_WIN32],[1],[Define if this is Win32ish platform])
 209     AC_SUBST(LLVM_ON_UNIX,[0])
 210     AC_SUBST(LLVM_ON_WIN32,[1])
 211     ;;
 212 esac
 213
 214 dnl Determine what our target architecture is and configure accordingly.
 215 dnl This will allow Makefiles to make a distinction between the hardware and
 216 dnl the OS.
 217 AC_CACHE_CHECK([target architecture],[llvm_cv_target_arch],
 218 [case $target in
 219   i?86-*)                 llvm_cv_target_arch="x86" ;;
 220   amd64-* | x86_64-*)     llvm_cv_target_arch="x86_64" ;;
 221   sparc*-*)               llvm_cv_target_arch="Sparc" ;;
 222   powerpc*-*)             llvm_cv_target_arch="PowerPC" ;;
 223   alpha*-*)               llvm_cv_target_arch="Alpha" ;;
 224   ia64-*)                 llvm_cv_target_arch="IA64" ;;
 225   arm-*)                  llvm_cv_target_arch="ARM" ;;
 226   mips-*)                 llvm_cv_target_arch="Mips" ;;
 227   pic16-*)                llvm_cv_target_arch="PIC16" ;;
 228   xcore-*)                llvm_cv_target_arch="XCore" ;;
 229   *)                      llvm_cv_target_arch="Unknown" ;;
 230 esac])
 231
 232 if test "$llvm_cv_target_arch" = "Unknown" ; then
 233   AC_MSG_WARN([Configuring LLVM for an unknown target archicture])
 234 fi
 235
 236 dnl Define a substitution, ARCH, for the target architecture
 237 AC_SUBST(ARCH,$llvm_cv_target_arch)
 238
 239 dnl Check for the endianness of the target
 240 AC_C_BIGENDIAN(AC_SUBST([ENDIAN],[big]),AC_SUBST([ENDIAN],[little]))
 241
 242 dnl Check for build platform executable suffix if we're crosscompiling
 243 if test "$cross_compiling" = yes; then
 244   AC_SUBST(LLVM_CROSS_COMPILING, [1])
 245   AC_BUILD_EXEEXT
 246   ac_build_prefix=${build_alias}-
 247   AC_CHECK_PROG(BUILD_CXX, ${ac_build_prefix}g++, ${ac_build_prefix}g++)
 248   if test -z "$BUILD_CXX"; then
 249      AC_CHECK_PROG(BUILD_CXX, g++, g++)
 250      if test -z "$BUILD_CXX"; then
 251        AC_CHECK_PROG(BUILD_CXX, c++, c++, , , /usr/ucb/c++)
 252      fi
 253   fi
 254 else
 255   AC_SUBST(LLVM_CROSS_COMPILING, [0])
 256 fi
 257
 258 dnl Check to see if there's a "CVS" (or .svn) directory indicating that this
 259 dnl build is being done from a checkout. This sets up several defaults for the
 260 dnl command line switches. When we build with a CVS directory, we get a
 261 dnl debug with assertions turned on. Without, we assume a source release and we
 262 dnl get an optimized build without assertions. See --enable-optimized and
 263 dnl --enable-assertions below
 264 if test -d "CVS" -o -d "${srcdir}/CVS" -o -d ".svn" -o -d "${srcdir}/.svn"; then
 265   cvsbuild="yes"
 266   optimize="no"
 267   AC_SUBST(CVSBUILD,[[CVSBUILD=1]])
 268 else
 269   cvsbuild="no"
 270   optimize="yes"
 271 fi
 272
 273 dnl===-----------------------------------------------------------------------===
 274 dnl===
 275 dnl=== SECTION 3: Command line arguments for the configure script.
 276 dnl===
 277 dnl===-----------------------------------------------------------------------===
 278
 279 dnl --enable-optimized : check whether they want to do an optimized build:
 280 AC_ARG_ENABLE(optimized, AS_HELP_STRING(
 281  [--enable-optimized,Compile with optimizations enabled (default is NO)]),,enableval=$optimize)
 282 if test ${enableval} = "no" ; then
 283   AC_SUBST(ENABLE_OPTIMIZED,[[]])
 284 else
 285   AC_SUBST(ENABLE_OPTIMIZED,[[ENABLE_OPTIMIZED=1]])
 286 fi
 287
 288 dnl --enable-assertions : check whether they want to turn on assertions or not:
 289 AC_ARG_ENABLE(assertions,AS_HELP_STRING(
 290   [--enable-assertions,Compile with assertion checks enabled (default is YES)]),, enableval="yes")
 291 if test ${enableval} = "yes" ; then
 292   AC_SUBST(DISABLE_ASSERTIONS,[[]])
 293 else
 294   AC_SUBST(DISABLE_ASSERTIONS,[[DISABLE_ASSERTIONS=1]])
 295 fi
 296
 297 dnl --enable-expensive-checks : check whether they want to turn on expensive debug checks:
 298 AC_ARG_ENABLE(expensive-checks,AS_HELP_STRING(
 299   [--enable-expensive-checks,Compile with expensive debug checks enabled (default is NO)]),, enableval="no")
 300 if test ${enableval} = "yes" ; then
 301   AC_SUBST(ENABLE_EXPENSIVE_CHECKS,[[ENABLE_EXPENSIVE_CHECKS=1]])
 302   AC_SUBST(EXPENSIVE_CHECKS,[[yes]])
 303 else
 304   AC_SUBST(ENABLE_EXPENSIVE_CHECKS,[[]])
 305   AC_SUBST(EXPENSIVE_CHECKS,[[no]])
 306 fi
 307
 308 dnl --enable-debug-runtime : should runtime libraries have debug symbols?
 309 AC_ARG_ENABLE(debug-runtime,
 310    AS_HELP_STRING([--enable-debug-runtime,Build runtime libs with debug symbols (default is NO)]),,enableval=no)
 311 if test ${enableval} = "no" ; then
 312   AC_SUBST(DEBUG_RUNTIME,[[]])
 313 else
 314   AC_SUBST(DEBUG_RUNTIME,[[DEBUG_RUNTIME=1]])
 315 fi
 316
 317 dnl --enable-jit: check whether they want to enable the jit
 318 AC_ARG_ENABLE(jit,
 319   AS_HELP_STRING(--enable-jit,
 320                  [Enable Just In Time Compiling (default is YES)]),,
 321   enableval=default)
 322 if test ${enableval} = "no"
 323 then
 324   AC_SUBST(JIT,[[]])
 325 else
 326   case "$llvm_cv_target_arch" in
 327     x86)     AC_SUBST(TARGET_HAS_JIT,1) ;;
 328     Sparc)   AC_SUBST(TARGET_HAS_JIT,0) ;;
 329     PowerPC) AC_SUBST(TARGET_HAS_JIT,1) ;;
 330     x86_64)  AC_SUBST(TARGET_HAS_JIT,1) ;;
 331     Alpha)   AC_SUBST(TARGET_HAS_JIT,1) ;;
 332     IA64)    AC_SUBST(TARGET_HAS_JIT,0) ;;
 333     ARM)     AC_SUBST(TARGET_HAS_JIT,0) ;;
 334     Mips)    AC_SUBST(TARGET_HAS_JIT,0) ;;
 335     PIC16)   AC_SUBST(TARGET_HAS_JIT,0) ;;
 336     XCore)   AC_SUBST(TARGET_HAS_JIT,0) ;;
 337     *)       AC_SUBST(TARGET_HAS_JIT,0) ;;
 338   esac
 339 fi
 340
 341 dnl Allow enablement of doxygen generated documentation
 342 AC_ARG_ENABLE(doxygen,
 343               AS_HELP_STRING([--enable-doxygen],
 344                              [Build doxygen documentation (default is NO)]),,
 345                              enableval=default)
 346 case "$enableval" in
 347   yes) AC_SUBST(ENABLE_DOXYGEN,[1]) ;;
 348   no)  AC_SUBST(ENABLE_DOXYGEN,[0]) ;;
 349   default) AC_SUBST(ENABLE_DOXYGEN,[0]) ;;
 350   *) AC_MSG_ERROR([Invalid setting for --enable-doxygen. Use "yes" or "no"]) ;;
 351 esac
 352
 353 dnl Allow disablement of threads
 354 AC_ARG_ENABLE(threads,
 355               AS_HELP_STRING([--enable-threads],
 356                              [Use threads if available (default is YES)]),,
 357                              enableval=default)
 358 case "$enableval" in
 359   yes) AC_SUBST(ENABLE_THREADS,[1]) ;;
 360   no)  AC_SUBST(ENABLE_THREADS,[0]) ;;
 361   default) AC_SUBST(ENABLE_THREADS,[1]) ;;
 362   *) AC_MSG_ERROR([Invalid setting for --enable-threads. Use "yes" or "no"]) ;;
 363 esac
 364 AC_DEFINE_UNQUOTED([ENABLE_THREADS],$ENABLE_THREADS,[Define if threads enabled])
 365
 366 dnl Allow building without position independent code
 367 AC_ARG_ENABLE(pic,
 368   AS_HELP_STRING([--enable-pic],
 369                  [Build LLVM with Position Independent Code (default is YES)]),,
 370                  enableval=default)
 371 case "$enableval" in
 372   yes) AC_SUBST(ENABLE_PIC,[1]) ;;
 373   no)  AC_SUBST(ENABLE_PIC,[0]) ;;
 374   default) AC_SUBST(ENABLE_PIC,[1]) ;;
 375   *) AC_MSG_ERROR([Invalid setting for --enable-pic. Use "yes" or "no"]) ;;
 376 esac
 377 AC_DEFINE_UNQUOTED([ENABLE_PIC],$ENABLE_PIC,
 378                    [Define if position independent code is enabled])
 379
 380 dnl Allow specific targets to be specified for building (or not)
 381 TARGETS_TO_BUILD=""
 382 AC_ARG_ENABLE([targets],AS_HELP_STRING([--enable-targets],
 383     [Build specific host targets: all,host-only,{target-name} (default=all)]),,
 384     enableval=all)
 385 case "$enableval" in
 386   all) TARGETS_TO_BUILD="X86 Sparc PowerPC Alpha IA64 ARM Mips CellSPU PIC16 XCore CBackend MSIL CppBackend" ;;
 387   host-only)
 388     case "$llvm_cv_target_arch" in
 389       x86)     TARGETS_TO_BUILD="X86" ;;
 390       x86_64)  TARGETS_TO_BUILD="X86" ;;
 391       Sparc)   TARGETS_TO_BUILD="Sparc" ;;
 392       PowerPC) TARGETS_TO_BUILD="PowerPC" ;;
 393       Alpha)   TARGETS_TO_BUILD="Alpha" ;;
 394       IA64)    TARGETS_TO_BUILD="IA64" ;;
 395       ARM)     TARGETS_TO_BUILD="ARM" ;;
 396       Mips)    TARGETS_TO_BUILD="Mips" ;;
 397       CellSPU|SPU) TARGETS_TO_BUILD="CellSPU" ;;
 398       PIC16)   TARGETS_TO_BUILD="PIC16" ;;
 399       XCore)   TARGETS_TO_BUILD="XCore" ;;
 400       *)       AC_MSG_ERROR([Can not set target to build]) ;;
 401     esac
 402     ;;
 403   *)for a_target in `echo $enableval|sed -e 's/,/ /g' ` ; do
 404       case "$a_target" in
 405         x86)     TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 406         x86_64)  TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 407         sparc)   TARGETS_TO_BUILD="Sparc $TARGETS_TO_BUILD" ;;
 408         powerpc) TARGETS_TO_BUILD="PowerPC $TARGETS_TO_BUILD" ;;
 409         alpha)   TARGETS_TO_BUILD="Alpha $TARGETS_TO_BUILD" ;;
 410         ia64)    TARGETS_TO_BUILD="IA64 $TARGETS_TO_BUILD" ;;
 411         arm)     TARGETS_TO_BUILD="ARM $TARGETS_TO_BUILD" ;;
 412         mips)    TARGETS_TO_BUILD="Mips $TARGETS_TO_BUILD" ;;
 413         spu)     TARGETS_TO_BUILD="CellSPU $TARGETS_TO_BUILD" ;;
 414         pic16)   TARGETS_TO_BUILD="PIC16 $TARGETS_TO_BUILD" ;;
 415         xcore)   TARGETS_TO_BUILD="XCore $TARGETS_TO_BUILD" ;;
 416         cbe)     TARGETS_TO_BUILD="CBackend $TARGETS_TO_BUILD" ;;
 417         msil)    TARGETS_TO_BUILD="MSIL $TARGETS_TO_BUILD" ;;
 418         cpp)     TARGETS_TO_BUILD="CppBackend $TARGETS_TO_BUILD" ;;
 419         *) AC_MSG_ERROR([Unrecognized target $a_target]) ;;
 420       esac
 421   done
 422   ;;
 423 esac
 424 AC_SUBST(TARGETS_TO_BUILD,$TARGETS_TO_BUILD)
 425
 426 dnl Prevent the CBackend from using printf("%a") for floating point so older
 427 dnl C compilers that cannot deal with the 0x0p+0 hex floating point format
 428 dnl can still compile the CBE's output
 429 AC_ARG_ENABLE([cbe-printf-a],AS_HELP_STRING([--enable-cbe-printf-a],
 430   [Enable C Backend output with hex floating point via %a  (default is YES)]),,
 431   enableval=default)
 432 case "$enableval" in
 433   yes) AC_SUBST(ENABLE_CBE_PRINTF_A,[1]) ;;
 434   no)  AC_SUBST(ENABLE_CBE_PRINTF_A,[0]) ;;
 435   default)  AC_SUBST(ENABLE_CBE_PRINTF_A,[1]) ;;
 436   *) AC_MSG_ERROR([Invalid setting for --enable-cbe-printf-a. Use "yes" or "no"]) ;;
 437 esac
 438 AC_DEFINE_UNQUOTED([ENABLE_CBE_PRINTF_A],$ENABLE_CBE_PRINTF_A,
 439                    [Define if CBE is enabled for printf %a output])
 440
 441 dnl Allow a specific llvm-gcc/llvm-g++ pair to be used with this LLVM config.
 442 AC_ARG_WITH(llvmgccdir,
 443   AS_HELP_STRING([--with-llvmgccdir],
 444     [Specify location of llvm-gcc install dir (default searches PATH)]),,
 445     withval=default)
 446 case "$withval" in
 447   default) WITH_LLVMGCCDIR=default ;;
 448   /* | [[A-Za-z]]:[[\\/]]*)      WITH_LLVMGCCDIR=$withval ;;
 449   *) AC_MSG_ERROR([Invalid path for --with-llvmgccdir. Provide full path]) ;;
 450 esac
 451
 452 dnl Allow a specific llvm-gcc compiler to be used with this LLVM config.
 453 AC_ARG_WITH(llvmgcc,
 454   AS_HELP_STRING([--with-llvmgcc],
 455     [Specify location of llvm-gcc driver (default searches PATH)]),
 456     LLVMGCC=$with_llvmgcc
 457       WITH_LLVMGCCDIR="",)
 458
 459 dnl Allow a specific llvm-g++ compiler to be used with this LLVM config.
 460 AC_ARG_WITH(llvmgxx,
 461   AS_HELP_STRING([--with-llvmgxx],
 462     [Specify location of llvm-g++ driver (default searches PATH)]),
 463     LLVMGXX=$with_llvmgxx
 464     WITH_LLVMGCCDIR="",)
 465
 466 if test -n "$LLVMGCC" && test -z "$LLVMGXX"; then
 467    AC_MSG_ERROR([Invalid llvm-g++. Use --with-llvmgxx when --with-llvmgcc is used]);
 468 fi
 469
 470 if test -n "$LLVMGXX" && test -z "$LLVMGCC"; then
 471    AC_MSG_ERROR([Invalid llvm-gcc. Use --with-llvmgcc when --with-llvmgxx is used]);
 472 fi
 473
 474 dnl Specify extra build options
 475 AC_ARG_WITH(extra-options,
 476   AS_HELP_STRING([--with-extra-options],
 477                  [Specify addtional options to compile LLVM with]),,
 478                  withval=default)
 479 case "$withval" in
 480   default) EXTRA_OPTIONS= ;;
 481   *) EXTRA_OPTIONS=$withval ;;
 482 esac
 483 AC_SUBST(EXTRA_OPTIONS,$EXTRA_OPTIONS)
 484
 485 dnl Allow specific bindings to be specified for building (or not)
 486 AC_ARG_ENABLE([bindings],AS_HELP_STRING([--enable-bindings],
 487     [Build specific language bindings: all,auto,none,{binding-name} (default=auto)]),,
 488     enableval=default)
 489 BINDINGS_TO_BUILD=""
 490 case "$enableval" in
 491   yes | default | auto) BINDINGS_TO_BUILD="auto" ;;
 492   all ) BINDINGS_TO_BUILD="ocaml" ;;
 493   none | no) BINDINGS_TO_BUILD="" ;;
 494   *)for a_binding in `echo $enableval|sed -e 's/,/ /g' ` ; do
 495       case "$a_binding" in
 496         ocaml) BINDINGS_TO_BUILD="ocaml $BINDINGS_TO_BUILD" ;;
 497         *) AC_MSG_ERROR([Unrecognized binding $a_binding]) ;;
 498       esac
 499   done
 500   ;;
 501 esac
 502
 503 dnl Allow the ocaml libdir to be overridden. This could go in a configure
 504 dnl script for bindings/ocaml/configure, except that its auto value depends on
 505 dnl OCAMLC, which is found here to support tests.
 506 AC_ARG_WITH([ocaml-libdir],
 507   [AS_HELP_STRING([--with-ocaml-libdir],
 508     [Specify install location for ocaml bindings (default is stdlib)])],
 509   [],
 510   [withval=auto])
 511 case "$withval" in
 512   auto) with_ocaml_libdir="$withval" ;;
 513   /* | [[A-Za-z]]:[[\\/]]*) with_ocaml_libdir="$withval" ;;
 514   *) AC_MSG_ERROR([Invalid path for --with-ocaml-libdir. Provide full path]) ;;
 515 esac
 516
 517 dnl Allow linking of LLVM with GPLv3 binutils code.
 518 AC_ARG_WITH(binutils-include,
 519   AS_HELP_STRING([--with-binutils-include],
 520     [Specify path to binutils/include/ containing plugin-api.h file for gold plugin.]),,
 521   withval=default)
 522 case "$withval" in
 523   default) WITH_BINUTILS_INCDIR=default ;;
 524   /* | [[A-Za-z]]:[[\\/]]*)      WITH_BINUTILS_INCDIR=$withval ;;
 525   *) AC_MSG_ERROR([Invalid path for --with-binutils-include. Provide full path]) ;;
 526 esac
 527 if test "x$WITH_BINUTILS_INCDIR" != xdefault ; then
 528   AC_SUBST(BINUTILS_INCDIR,$WITH_BINUTILS_INCDIR)
 529   if test ! -f "$WITH_BINUTILS_INCDIR/plugin-api.h"; then
 530      echo "$WITH_BINUTILS_INCDIR/plugin-api.h"
 531      AC_MSG_ERROR([Invalid path to directory containing plugin-api.h.]);
 532   fi
 533 fi
 534
 535 dnl===-----------------------------------------------------------------------===
 536 dnl===
 537 dnl=== SECTION 4: Check for programs we need and that they are the right version
 538 dnl===
 539 dnl===-----------------------------------------------------------------------===
 540
 541 dnl Check for compilation tools
 542 AC_PROG_CPP
 543 AC_PROG_CC(gcc)
 544 AC_PROG_CXX(g++)
 545
 546 AC_PROG_NM
 547 AC_SUBST(NM)
 548
 549 dnl Check for the tools that the makefiles require
 550 AC_CHECK_GNU_MAKE
 551 AC_PROG_LN_S
 552 AC_PATH_PROG(CMP, [cmp], [cmp])
 553 AC_PATH_PROG(CP, [cp], [cp])
 554 AC_PATH_PROG(DATE, [date], [date])
 555 AC_PATH_PROG(FIND, [find], [find])
 556 AC_PATH_PROG(GREP, [grep], [grep])
 557 AC_PATH_PROG(MKDIR,[mkdir],[mkdir])
 558 AC_PATH_PROG(MV,   [mv],   [mv])
 559 AC_PROG_RANLIB
 560 AC_PATH_PROG(RM,   [rm],   [rm])
 561 AC_PATH_PROG(SED,  [sed],  [sed])
 562 AC_PATH_PROG(TAR,  [tar],  [gtar])
 563 AC_PATH_PROG(BINPWD,[pwd],  [pwd])
 564
 565 dnl Looking for misc. graph plotting software
 566 AC_PATH_PROG(GRAPHVIZ, [Graphviz], [echo Graphviz])
 567 if test "$GRAPHVIZ" != "echo Graphviz" ; then
 568   AC_DEFINE([HAVE_GRAPHVIZ],[1],[Define if the Graphviz program is available])
 569   dnl If we're targeting for mingw we should emit windows paths, not msys
 570   if test "$llvm_cv_os_type" = "MingW" ; then
 571     GRAPHVIZ=`echo $GRAPHVIZ | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 572   fi
 573   AC_DEFINE_UNQUOTED([LLVM_PATH_GRAPHVIZ],"$GRAPHVIZ${EXEEXT}",
 574    [Define to path to Graphviz program if found or 'echo Graphviz' otherwise])
 575 fi
 576 AC_PATH_PROG(DOT, [dot], [echo dot])
 577 if test "$DOT" != "echo dot" ; then
 578   AC_DEFINE([HAVE_DOT],[1],[Define if the dot program is available])
 579   dnl If we're targeting for mingw we should emit windows paths, not msys
 580   if test "$llvm_cv_os_type" = "MingW" ; then
 581     DOT=`echo $DOT | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 582   fi
 583   AC_DEFINE_UNQUOTED([LLVM_PATH_DOT],"$DOT${EXEEXT}",
 584    [Define to path to dot program if found or 'echo dot' otherwise])
 585 fi
 586 AC_PATH_PROGS(GV, [gv gsview32], [echo gv])
 587 if test "$GV" != "echo gv" ; then
 588   AC_DEFINE([HAVE_GV],[1],[Define if the gv program is available])
 589   dnl If we're targeting for mingw we should emit windows paths, not msys
 590   if test "$llvm_cv_os_type" = "MingW" ; then
 591     GV=`echo $GV | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 592   fi
 593   AC_DEFINE_UNQUOTED([LLVM_PATH_GV],"$GV${EXEEXT}",
 594    [Define to path to gv program if found or 'echo gv' otherwise])
 595 fi
 596 AC_PATH_PROG(DOTTY, [dotty], [echo dotty])
 597 if test "$DOTTY" != "echo dotty" ; then
 598   AC_DEFINE([HAVE_DOTTY],[1],[Define if the dotty program is available])
 599   dnl If we're targeting for mingw we should emit windows paths, not msys
 600   if test "$llvm_cv_os_type" = "MingW" ; then
 601     DOTTY=`echo $DOTTY | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 602   fi
 603   AC_DEFINE_UNQUOTED([LLVM_PATH_DOTTY],"$DOTTY${EXEEXT}",
 604    [Define to path to dotty program if found or 'echo dotty' otherwise])
 605 fi
 606
 607 dnl Look for a sufficiently recent version of Perl.
 608 LLVM_PROG_PERL([5.006])
 609 AC_SUBST(PERL)
 610 if test x"$PERL" = xnone; then
 611    AC_SUBST(HAVE_PERL,0)
 612    AC_MSG_ERROR([perl is required but was not found, please install it])
 613 else
 614    AC_SUBST(HAVE_PERL,1)
 615 fi
 616
 617 dnl Find the install program
 618 AC_PROG_INSTALL
 619
 620 dnl Checks for documentation and testing tools that we can do without. If these
 621 dnl are not found then they are set to "true" which always succeeds but does
 622 dnl nothing. This just lets the build output show that we could have done
 623 dnl something if the tool was available.
 624 AC_PATH_PROG(BZIP2, [bzip2])
 625 AC_PATH_PROG(DOXYGEN, [doxygen])
 626 AC_PATH_PROG(GROFF, [groff])
 627 AC_PATH_PROG(GZIP, [gzip])
 628 AC_PATH_PROG(POD2HTML, [pod2html])
 629 AC_PATH_PROG(POD2MAN, [pod2man])
 630 AC_PATH_PROG(RUNTEST, [runtest])
 631 DJ_AC_PATH_TCLSH
 632 AC_PATH_PROG(ZIP, [zip])
 633 AC_PATH_PROGS(OCAMLC, [ocamlc])
 634 AC_PATH_PROGS(OCAMLOPT, [ocamlopt])
 635 AC_PATH_PROGS(OCAMLDEP, [ocamldep])
 636 AC_PATH_PROGS(OCAMLDOC, [ocamldoc])
 637 AC_PATH_PROGS(GAS, [gas as])
 638
 639 dnl Determine if the linker supports the -R option.
 640 AC_LINK_USE_R
 641
 642 dnl Check for libtool and the library that has dlopen function (which must come
 643 dnl before the AC_PROG_LIBTOOL check in order to enable dlopening libraries with
 644 dnl libtool).
 645 AC_LIBTOOL_DLOPEN
 646 AC_LIB_LTDL
 647 AC_PROG_LIBTOOL
 648
 649 if test "$lt_cv_dlopen_self" = "yes" ; then
 650   AC_DEFINE([CAN_DLOPEN_SELF],[1],
 651               [Define if dlopen(0) will open the symbols of the program])
 652 fi
 653
 654 if test "$WITH_LLVMGCCDIR" = "default" ; then
 655   LLVMGCC="llvm-gcc${EXEEXT}"
 656   LLVMGXX="llvm-g++${EXEEXT}"
 657   AC_PATH_PROG(LLVMGCC, $LLVMGCC, [])
 658   AC_PATH_PROG(LLVMGXX, $LLVMGXX, [])
 659 else
 660   if test -z "$LLVMGCC"; then
 661     LLVMGCC="$WITH_LLVMGCCDIR/bin/llvm-gcc${EXEEXT}"
 662   fi
 663   if test -z "$LLVMGXX"; then
 664     LLVMGXX="$WITH_LLVMGCCDIR/bin/llvm-g++${EXEEXT}"
 665   fi
 666   AC_SUBST(LLVMGCC,$LLVMGCC)
 667   AC_SUBST(LLVMGXX,$LLVMGXX)
 668 fi
 669
 670 AC_MSG_CHECKING([tool compatibility])
 671
 672 dnl Ensure that compilation tools are GCC or a GNU compatible compiler such as
 673 dnl ICC; we use GCC specific options in the makefiles so the compiler needs
 674 dnl to support those options.
 675 dnl "icc" emits gcc signatures
 676 dnl "icc -no-gcc" emits no gcc signature BUT is still compatible
 677 ICC=no
 678 IXX=no
 679 case $CC in
 680   icc*|icpc*)
 681     ICC=yes
 682     IXX=yes
 683     ;;
 684    *)
 685     ;;
 686 esac
 687
 688 if test "$GCC" != "yes" && test "$ICC" != "yes"
 689 then
 690   AC_MSG_ERROR([gcc|icc required but not found])
 691 fi
 692
 693 dnl Ensure that compilation tools are GCC; we use GCC specific extensions
 694 if test "$GXX" != "yes" && test "$IXX" != "yes"
 695 then
 696   AC_MSG_ERROR([g++|icc required but not found])
 697 fi
 698
 699 dnl Verify that GCC is version 3.0 or higher
 700 if test "$GCC" = "yes"
 701 then
 702   AC_COMPILE_IFELSE([[#if !defined(__GNUC__) || __GNUC__ < 3
 703 #error Unsupported GCC version
 704 #endif
 705 ]], [], [AC_MSG_ERROR([gcc 3.x required, but you have a lower version])])
 706 fi
 707
 708 dnl Check for GNU Make.  We use its extensions, so don't build without it
 709 if test -z "$llvm_cv_gnu_make_command"
 710 then
 711   AC_MSG_ERROR([GNU Make required but not found])
 712 fi
 713
 714 dnl Tool compatibility is okay if we make it here.
 715 AC_MSG_RESULT([ok])
 716
 717 dnl===-----------------------------------------------------------------------===
 718 dnl===
 719 dnl=== SECTION 5: Check for libraries
 720 dnl===
 721 dnl===-----------------------------------------------------------------------===
 722
 723 dnl libelf is for sparc only; we can ignore it if we don't have it
 724 AC_CHECK_LIB(elf, elf_begin)
 725 AC_CHECK_LIB(m,sin)
 726 if test "$llvm_cv_os_type" = "MingW" ; then
 727   AC_CHECK_LIB(imagehlp, main)
 728   AC_CHECK_LIB(psapi, main)
 729 fi
 730
 731 dnl dlopen() is required for plugin support.
 732 AC_SEARCH_LIBS(dlopen,dl,AC_DEFINE([HAVE_DLOPEN],[1],
 733                [Define if dlopen() is available on this platform.]),
 734                AC_MSG_WARN([dlopen() not found - disabling plugin support]))
 735
 736 dnl libffi is optional; used to call external functions from the interpreter
 737 AC_CHECK_LIB(ffi,ffi_call,[have_libffi=1],
 738              AC_MSG_WARN([libffi not found - disabling external calls from interpreter]))
 739
 740 dnl mallinfo is optional; the code can compile (minus features) without it
 741 AC_SEARCH_LIBS(mallinfo,malloc,AC_DEFINE([HAVE_MALLINFO],[1],
 742                [Define if mallinfo() is available on this platform.]))
 743
 744 dnl pthread locking functions are optional - but llvm will not be thread-safe
 745 dnl without locks.
 746 if test "$ENABLE_THREADS" -eq 1 ; then
 747   AC_CHECK_LIB(pthread,pthread_mutex_init)
 748   AC_SEARCH_LIBS(pthread_mutex_lock,pthread,
 749                  AC_DEFINE([HAVE_PTHREAD_MUTEX_LOCK],[1],
 750                            [Have pthread_mutex_lock]))
 751 fi
 752
 753 dnl Allow extra x86-disassembler library
 754 AC_ARG_WITH(udis86,
 755   AS_HELP_STRING([--with-udis86=<path>],
 756     [Use udis86 external x86 disassembler library]),
 757     [
 758       AC_SUBST(USE_UDIS86, [1])
 759       case "$withval" in
 760         /usr/lib|yes) ;;
 761         *) LDFLAGS="$LDFLAGS -L${withval}" ;;
 762       esac
 763       AC_CHECK_LIB(udis86, ud_init, [], [
 764         echo "Error! You need to have libudis86 around."
 765         exit -1
 766       ])
 767     ],
 768     AC_SUBST(USE_UDIS86, [0]))
 769 AC_DEFINE_UNQUOTED([USE_UDIS86],$USE_UDIS86,
 770                    [Define if use udis86 library])
 771
 772 dnl===-----------------------------------------------------------------------===
 773 dnl===
 774 dnl=== SECTION 6: Check for header files
 775 dnl===
 776 dnl===-----------------------------------------------------------------------===
 777
 778 dnl First, use autoconf provided macros for specific headers that we need
 779 dnl We don't check for ancient stuff or things that are guaranteed to be there
 780 dnl by the C++ standard. We always use the <cfoo> versions of <foo.h> C headers.
 781 dnl Generally we're looking for POSIX headers.
 782 AC_HEADER_DIRENT
 783 AC_HEADER_MMAP_ANONYMOUS
 784 AC_HEADER_STAT
 785 AC_HEADER_STDC
 786 AC_HEADER_SYS_WAIT
 787 AC_HEADER_TIME
 788
 789 AC_CHECK_HEADERS([dlfcn.h execinfo.h fcntl.h inttypes.h limits.h link.h])
 790 AC_CHECK_HEADERS([malloc.h setjmp.h signal.h stdint.h unistd.h utime.h])
 791 AC_CHECK_HEADERS([windows.h])
 792 AC_CHECK_HEADERS([sys/mman.h sys/param.h sys/resource.h sys/time.h])
 793 AC_CHECK_HEADERS([sys/types.h malloc/malloc.h mach/mach.h])
 794 if test "$ENABLE_THREADS" -eq 1 ; then
 795   AC_CHECK_HEADERS(pthread.h,
 796                    AC_SUBST(HAVE_PTHREAD, 1),
 797                    AC_SUBST(HAVE_PTHREAD, 0))
 798 else
 799   AC_SUBST(HAVE_PTHREAD, 0)
 800 fi
 801
 802 dnl Once we know we have libffi, try to find ffi.h.
 803 if test -n "$have_libffi" ; then
 804   AC_CHECK_HEADERS([ffi.h ffi/ffi.h], [AC_SUBST(HAVE_FFI, 1)])
 805 fi
 806
 807 dnl===-----------------------------------------------------------------------===
 808 dnl===
 809 dnl=== SECTION 7: Check for types and structures
 810 dnl===
 811 dnl===-----------------------------------------------------------------------===
 812
 813 AC_HUGE_VAL_CHECK
 814 AC_TYPE_PID_T
 815 AC_TYPE_SIZE_T
 816 AC_TYPE_SIGNAL
 817 AC_STRUCT_TM
 818 AC_CHECK_TYPES([int64_t],,AC_MSG_ERROR([Type int64_t required but not found]))
 819 AC_CHECK_TYPES([uint64_t],,
 820          AC_CHECK_TYPES([u_int64_t],,
 821          AC_MSG_ERROR([Type uint64_t or u_int64_t required but not found])))
 822
 823 dnl===-----------------------------------------------------------------------===
 824 dnl===
 825 dnl=== SECTION 8: Check for specific functions needed
 826 dnl===
 827 dnl===-----------------------------------------------------------------------===
 828
 829 AC_CHECK_FUNCS([backtrace ceilf floorf roundf rintf nearbyintf getcwd ])
 830 AC_CHECK_FUNCS([powf fmodf strtof round ])
 831 AC_CHECK_FUNCS([getpagesize getrusage getrlimit setrlimit gettimeofday ])
 832 AC_CHECK_FUNCS([isatty mkdtemp mkstemp ])
 833 AC_CHECK_FUNCS([mktemp realpath sbrk setrlimit strdup strerror strerror_r ])
 834 AC_CHECK_FUNCS([strtoll strtoq sysconf malloc_zone_statistics ])
 835 AC_CHECK_FUNCS([setjmp longjmp sigsetjmp siglongjmp])
 836 AC_C_PRINTF_A
 837 AC_FUNC_ALLOCA
 838 AC_FUNC_RAND48
 839
 840 dnl Check for variations in the Standard C++ library and STL. These macros are
 841 dnl provided by LLVM in the autoconf/m4 directory.
 842 AC_CXX_HAVE_HASH_MAP
 843 AC_CXX_HAVE_HASH_SET
 844 AC_CXX_HAVE_STD_ITERATOR
 845 AC_CXX_HAVE_BI_ITERATOR
 846 AC_CXX_HAVE_FWD_ITERATOR
 847 AC_FUNC_ISNAN
 848 AC_FUNC_ISINF
 849
 850 dnl Check for mmap support.We also need to know if /dev/zero is required to
 851 dnl be opened for allocating RWX memory.
 852 dnl Make sure we aren't attempting to configure for an unknown system
 853 if test "$llvm_cv_platform_type" = "Unix" ; then
 854   AC_FUNC_MMAP
 855   AC_FUNC_MMAP_FILE
 856   AC_NEED_DEV_ZERO_FOR_MMAP
 857
 858   if test "$ac_cv_func_mmap_fixed_mapped" = "no"
 859   then
 860     AC_MSG_WARN([mmap() of a fixed address required but not supported])
 861   fi
 862   if test "$ac_cv_func_mmap_file" = "no"
 863   then
 864     AC_MSG_WARN([mmap() of files required but not found])
 865   fi
 866 fi
 867
 868 dnl===-----------------------------------------------------------------------===
 869 dnl===
 870 dnl=== SECTION 9: Additional checks, variables, etc.
 871 dnl===
 872 dnl===-----------------------------------------------------------------------===
 873
 874 dnl Check, whether __dso_handle is present
 875 AC_CHECK_FUNCS([__dso_handle])
 876
 877 dnl See if the llvm-gcc executable can compile to LLVM assembly
 878 AC_CACHE_CHECK([whether llvm-gcc is sane],[llvm_cv_llvmgcc_sanity],
 879 [llvm_cv_llvmgcc_sanity="no"
 880 if test -x "$LLVMGCC" ; then
 881   cp /dev/null conftest.c
 882   "$LLVMGCC" -emit-llvm -S -o - conftest.c | \
 883       grep 'target datalayout =' > /dev/null 2>&1
 884   if test $? -eq 0 ; then
 885     llvm_cv_llvmgcc_sanity="yes"
 886   fi
 887   rm conftest.c
 888 fi])
 889
 890 dnl Since we have a sane llvm-gcc, identify it and its sub-tools
 891 if test "$llvm_cv_llvmgcc_sanity" = "yes" ; then
 892   AC_MSG_CHECKING([llvm-gcc component support])
 893   llvmcc1path=`"$LLVMGCC" --print-prog-name=cc1`
 894   AC_SUBST(LLVMCC1,$llvmcc1path)
 895   llvmcc1pluspath=`"$LLVMGCC" --print-prog-name=cc1plus`
 896   AC_SUBST(LLVMCC1PLUS,$llvmcc1pluspath)
 897   llvmgccdir=`echo "$llvmcc1path" | sed 's,/libexec/.*,,'`
 898   AC_SUBST(LLVMGCCDIR,$llvmgccdir)
 899   llvmgcclibexec=`echo "$llvmcc1path" | sed 's,/cc1,,'`
 900   AC_SUBST(LLVMGCCLIBEXEC,$llvmgcclibexec)
 901   llvmgccversion=[`"$LLVMGCC" -dumpversion 2>&1 | sed 's/^\([0-9.]*\).*/\1/'`]
 902   llvmgccmajvers=[`echo $llvmgccversion | sed 's/^\([0-9]\).*/\1/'`]
 903   AC_SUBST(LLVMGCC_VERSION,$llvmgccversion)
 904   AC_SUBST(LLVMGCC_MAJVERS,$llvmgccmajvers)
 905   llvmgcclangs=[`"$LLVMGCC" -v --help 2>&1 | grep '^Configured with:' | sed 's/^.*--enable-languages=\([^ ]*\).*/\1/'`]
 906   AC_SUBST(LLVMGCC_LANGS,$llvmgcclangs)
 907   AC_MSG_RESULT([ok])
 908 fi
 909
 910 dnl Propagate the shared library extension that the libltdl checks did to
 911 dnl the Makefiles so we can use it there too
 912 AC_SUBST(SHLIBEXT,$libltdl_cv_shlibext)
 913
 914 # Translate the various configuration directories and other basic
 915 # information into substitutions that will end up in Makefile.config.in
 916 # that these configured values can be used by the makefiles
 917 if test "${prefix}" = "NONE" ; then
 918   prefix="/usr/local"
 919 fi
 920 eval LLVM_PREFIX="${prefix}";
 921 eval LLVM_BINDIR="${prefix}/bin";
 922 eval LLVM_LIBDIR="${prefix}/lib";
 923 eval LLVM_DATADIR="${prefix}/share/llvm";
 924 eval LLVM_DOCSDIR="${prefix}/docs/llvm";
 925 eval LLVM_ETCDIR="${prefix}/etc/llvm";
 926 eval LLVM_INCLUDEDIR="${prefix}/include";
 927 eval LLVM_INFODIR="${prefix}/info";
 928 eval LLVM_MANDIR="${prefix}/man";
 929 LLVM_CONFIGTIME=`date`
 930 AC_SUBST(LLVM_PREFIX)
 931 AC_SUBST(LLVM_BINDIR)
 932 AC_SUBST(LLVM_LIBDIR)
 933 AC_SUBST(LLVM_DATADIR)
 934 AC_SUBST(LLVM_DOCSDIR)
 935 AC_SUBST(LLVM_ETCDIR)
 936 AC_SUBST(LLVM_INCLUDEDIR)
 937 AC_SUBST(LLVM_INFODIR)
 938 AC_SUBST(LLVM_MANDIR)
 939 AC_SUBST(LLVM_CONFIGTIME)
 940
 941 # Place the various directores into the config.h file as #defines so that we
 942 # can know about the installation paths within LLVM.
 943 AC_DEFINE_UNQUOTED(LLVM_PREFIX,"$LLVM_PREFIX",
 944                    [Installation prefix directory])
 945 AC_DEFINE_UNQUOTED(LLVM_BINDIR, "$LLVM_BINDIR",
 946                    [Installation directory for binary executables])
 947 AC_DEFINE_UNQUOTED(LLVM_LIBDIR, "$LLVM_LIBDIR",
 948                    [Installation directory for libraries])
 949 AC_DEFINE_UNQUOTED(LLVM_DATADIR, "$LLVM_DATADIR",
 950                    [Installation directory for data files])
 951 AC_DEFINE_UNQUOTED(LLVM_DOCSDIR, "$LLVM_DOCSDIR",
 952                    [Installation directory for documentation])
 953 AC_DEFINE_UNQUOTED(LLVM_ETCDIR, "$LLVM_ETCDIR",
 954                    [Installation directory for config files])
 955 AC_DEFINE_UNQUOTED(LLVM_INCLUDEDIR, "$LLVM_INCLUDEDIR",
 956                    [Installation directory for include files])
 957 AC_DEFINE_UNQUOTED(LLVM_INFODIR, "$LLVM_INFODIR",
 958                    [Installation directory for .info files])
 959 AC_DEFINE_UNQUOTED(LLVM_MANDIR, "$LLVM_MANDIR",
 960                    [Installation directory for man pages])
 961 AC_DEFINE_UNQUOTED(LLVM_CONFIGTIME, "$LLVM_CONFIGTIME",
 962                    [Time at which LLVM was configured])
 963 AC_DEFINE_UNQUOTED(LLVM_HOSTTRIPLE, "$host",
 964                    [Host triple we were built on])
 965
 966 # Determine which bindings to build.
 967 if test "$BINDINGS_TO_BUILD" = auto ; then
 968   BINDINGS_TO_BUILD=""
 969   if test "x$OCAMLC" != x -a "x$OCAMLDEP" != x ; then
 970     BINDINGS_TO_BUILD="ocaml $BINDINGS_TO_BUILD"
 971   fi
 972 fi
 973 AC_SUBST(BINDINGS_TO_BUILD,$BINDINGS_TO_BUILD)
 974
 975 # This isn't really configurey, but it avoids having to repeat the list in
 976 # other files.
 977 AC_SUBST(ALL_BINDINGS,ocaml)
 978
 979 # Do any work necessary to ensure that bindings have what they need.
 980 binding_prereqs_failed=0
 981 for a_binding in $BINDINGS_TO_BUILD ; do
 982   case "$a_binding" in
 983   ocaml)
 984     if test "x$OCAMLC" = x ; then
 985       AC_MSG_WARN([--enable-bindings=ocaml specified, but ocamlc not found. Try configure OCAMLC=/path/to/ocamlc])
 986       binding_prereqs_failed=1
 987     fi
 988     if test "x$OCAMLDEP" = x ; then
 989       AC_MSG_WARN([--enable-bindings=ocaml specified, but ocamldep not found. Try configure OCAMLDEP=/path/to/ocamldep])
 990       binding_prereqs_failed=1
 991     fi
 992     if test "x$OCAMLOPT" = x ; then
 993       AC_MSG_WARN([--enable-bindings=ocaml specified, but ocamlopt not found. Try configure OCAMLOPT=/path/to/ocamlopt])
 994       dnl ocamlopt is optional!
 995     fi
 996     if test "x$with_ocaml_libdir" != xauto ; then
 997       AC_SUBST(OCAML_LIBDIR,$with_ocaml_libdir)
 998     else
 999       ocaml_stdlib="`"$OCAMLC" -where`"
1000       if test "$LLVM_PREFIX" '<' "$ocaml_stdlib" -a "$ocaml_stdlib" '<' "$LLVM_PREFIX~"
1001       then
1002         # ocaml stdlib is beneath our prefix; use stdlib
1003         AC_SUBST(OCAML_LIBDIR,$ocaml_stdlib)
1004       else
1005         # ocaml stdlib is outside our prefix; use libdir/ocaml
1006         AC_SUBST(OCAML_LIBDIR,$LLVM_LIBDIR/ocaml)
1007       fi
1008     fi
1009     ;;
1010   esac
1011 done
1012 if test "$binding_prereqs_failed" = 1 ; then
1013   AC_MSG_ERROR([Prequisites for bindings not satisfied. Fix them or use configure --disable-bindings.])
1014 fi
1015
1016 dnl Determine if the compiler supports -fvisibility-inlines-hidden.
1017 AC_CXX_USE_VISIBILITY_INLINES_HIDDEN
1018
1019 dnl Determine linker rpath flag
1020 case $llvm_cv_os_type in
1021   SunOS) RPATH="-Wl,-R" ;;
1022   *) RPATH="-Wl,-rpath" ;;
1023 esac
1024 AC_SUBST(RPATH)
1025
1026 dnl===-----------------------------------------------------------------------===
1027 dnl===
1028 dnl=== SECTION 10: Specify the output files and generate it
1029 dnl===
1030 dnl===-----------------------------------------------------------------------===
1031
1032 dnl Configure header files
1033 dnl WARNING: dnl If you add or remove any of the following config headers, then
1034 dnl you MUST also update Makefile.rules so that the variable FilesToConfig
1035 dnl contains the same list of files as AC_CONFIG_HEADERS below. This ensures the
1036 dnl files can be updated automatically when their *.in sources change.
1037 AC_CONFIG_HEADERS([include/llvm/Config/config.h])
1038 AC_CONFIG_HEADERS([include/llvm/Support/DataTypes.h])
1039 AC_CONFIG_HEADERS([include/llvm/ADT/hash_map.h])
1040 AC_CONFIG_HEADERS([include/llvm/ADT/hash_set.h])
1041 AC_CONFIG_HEADERS([include/llvm/ADT/iterator.h])
1042
1043 dnl Configure the makefile's configuration data
1044 AC_CONFIG_FILES([Makefile.config])
1045
1046 dnl Configure the RPM spec file for LLVM
1047 AC_CONFIG_FILES([llvm.spec])
1048
1049 dnl Configure doxygen's configuration file
1050 AC_CONFIG_FILES([docs/doxygen.cfg])
1051
1052 dnl Do the first stage of configuration for llvm-config.in.
1053 AC_CONFIG_FILES([tools/llvm-config/llvm-config.in])
1054
1055 dnl Do special configuration of Makefiles
1056 AC_CONFIG_COMMANDS([setup],,[llvm_src="${srcdir}"])
1057 AC_CONFIG_MAKEFILE(Makefile)
1058 AC_CONFIG_MAKEFILE(Makefile.common)
1059 AC_CONFIG_MAKEFILE(examples/Makefile)
1060 AC_CONFIG_MAKEFILE(lib/Makefile)
1061 AC_CONFIG_MAKEFILE(runtime/Makefile)
1062 AC_CONFIG_MAKEFILE(test/Makefile)
1063 AC_CONFIG_MAKEFILE(test/Makefile.tests)
1064 AC_CONFIG_MAKEFILE(unittests/Makefile)
1065 AC_CONFIG_MAKEFILE(tools/Makefile)
1066 AC_CONFIG_MAKEFILE(utils/Makefile)
1067 AC_CONFIG_MAKEFILE(projects/Makefile)
1068 AC_CONFIG_MAKEFILE(bindings/Makefile)
1069 AC_CONFIG_MAKEFILE(bindings/ocaml/Makefile.ocaml)
1070
1071 dnl Finally, crank out the output
1072 AC_OUTPUT