autoconf/configure.ac

   1 dnl === configure.ac --------------------------------------------------------===
   2 dnl                     The LLVM Compiler Infrastructure
   3 dnl
   4 dnl This file is distributed under the University of Illinois Open Source
   5 dnl License. See LICENSE.TXT for details.
   6 dnl
   7 dnl===-----------------------------------------------------------------------===
   8 dnl This is the LLVM configuration script. It is processed by the autoconf
   9 dnl program to produce a script named configure. This script contains the
  10 dnl configuration checks that LLVM needs in order to support multiple platforms.
  11 dnl This file is composed of 10 sections per the recommended organization of
  12 dnl autoconf input defined in the autoconf documentation. As this file evolves,
  13 dnl please keep the various types of checks within their sections. The sections
  14 dnl are as follows:
  15 dnl
  16 dnl SECTION 1: Initialization & Setup
  17 dnl SECTION 2: Architecture, target, and host checks
  18 dnl SECTION 3: Command line arguments for the configure script.
  19 dnl SECTION 4: Check for programs we need and that they are the right version
  20 dnl SECTION 5: Check for libraries
  21 dnl SECTION 6: Check for header files
  22 dnl SECTION 7: Check for types and structures
  23 dnl SECTION 8: Check for specific functions needed
  24 dnl SECTION 9: Additional checks, variables, etc.
  25 dnl SECTION 10: Specify the output files and generate it
  26 dnl
  27 dnl===-----------------------------------------------------------------------===
  28 dnl===
  29 dnl=== SECTION 1: Initialization & Setup
  30 dnl===
  31 dnl===-----------------------------------------------------------------------===
  32 dnl Initialize autoconf and define the package name, version number and
  33 dnl email address for reporting bugs.
  34 AC_INIT([[llvm]],[[2.7svn]],[llvmbugs@cs.uiuc.edu])
  35
  36 dnl Provide a copyright substitution and ensure the copyright notice is included
  37 dnl in the output of --version option of the generated configure script.
  38 AC_SUBST(LLVM_COPYRIGHT,["Copyright (c) 2003-2009 University of Illinois at Urbana-Champaign."])
  39 AC_COPYRIGHT([Copyright (c) 2003-2009 University of Illinois at Urbana-Champaign.])
  40
  41 dnl Indicate that we require autoconf 2.59 or later. Ths is needed because we
  42 dnl use some autoconf macros only available in 2.59.
  43 AC_PREREQ(2.59)
  44
  45 dnl Verify that the source directory is valid. This makes sure that we are
  46 dnl configuring LLVM and not some other package (it validates --srcdir argument)
  47 AC_CONFIG_SRCDIR([lib/VMCore/Module.cpp])
  48
  49 dnl Place all of the extra autoconf files into the config subdirectory. Tell
  50 dnl various tools where the m4 autoconf macros are.
  51 AC_CONFIG_AUX_DIR([autoconf])
  52
  53 dnl Quit if the source directory has already been configured.
  54 dnl NOTE: This relies upon undocumented autoconf behavior.
  55 if test ${srcdir} != "." ; then
  56   if test -f ${srcdir}/include/llvm/Config/config.h ; then
  57     AC_MSG_ERROR([Already configured in ${srcdir}])
  58   fi
  59 fi
  60
  61 dnl Configure all of the projects present in our source tree. While we could
  62 dnl just AC_CONFIG_SUBDIRS on the set of directories in projects that have a
  63 dnl configure script, that usage of the AC_CONFIG_SUBDIRS macro is deprecated.
  64 dnl Instead we match on the known projects.
  65 for i in `ls ${srcdir}/projects`
  66 do
  67   if test -d ${srcdir}/projects/${i} ; then
  68     case ${i} in
  69       CVS) ;;
  70       sample)       AC_CONFIG_SUBDIRS([projects/sample])    ;;
  71       privbracket)  AC_CONFIG_SUBDIRS([projects/privbracket]) ;;
  72       llvm-stacker) AC_CONFIG_SUBDIRS([projects/llvm-stacker]) ;;
  73       # llvm-test is the old name of the test-suite, kept here for backwards
  74       # compatibility
  75       llvm-test)    AC_CONFIG_SUBDIRS([projects/llvm-test]) ;;
  76       test-suite)   AC_CONFIG_SUBDIRS([projects/test-suite]) ;;
  77       llvm-reopt)   AC_CONFIG_SUBDIRS([projects/llvm-reopt]);;
  78       llvm-gcc)     AC_CONFIG_SUBDIRS([projects/llvm-gcc])  ;;
  79       llvm-java)    AC_CONFIG_SUBDIRS([projects/llvm-java]) ;;
  80       llvm-tv)      AC_CONFIG_SUBDIRS([projects/llvm-tv])   ;;
  81       llvm-poolalloc) AC_CONFIG_SUBDIRS([projects/llvm-poolalloc]) ;;
  82       poolalloc)    AC_CONFIG_SUBDIRS([projects/poolalloc]) ;;
  83       llvm-kernel)  AC_CONFIG_SUBDIRS([projects/llvm-kernel]) ;;
  84       *)
  85         AC_MSG_WARN([Unknown project (${i}) won't be configured automatically])
  86         ;;
  87     esac
  88   fi
  89 done
  90
  91 dnl===-----------------------------------------------------------------------===
  92 dnl===
  93 dnl=== SECTION 2: Architecture, target, and host checks
  94 dnl===
  95 dnl===-----------------------------------------------------------------------===
  96
  97 dnl Check the target for which we're compiling and the host that will do the
  98 dnl compilations. This will tell us which LLVM compiler will be used for
  99 dnl compiling SSA into object code. This needs to be done early because
 100 dnl following tests depend on it.
 101 AC_CANONICAL_TARGET
 102
 103 dnl Determine the platform type and cache its value. This helps us configure
 104 dnl the System library to the correct build platform.
 105 AC_CACHE_CHECK([type of operating system we're going to host on],
 106                [llvm_cv_os_type],
 107 [case $host in
 108   *-*-aix*)
 109     llvm_cv_link_all_option="-Wl,--whole-archive"
 110     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 111     llvm_cv_os_type="AIX"
 112     llvm_cv_platform_type="Unix" ;;
 113   *-*-irix*)
 114     llvm_cv_link_all_option="-Wl,--whole-archive"
 115     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 116     llvm_cv_os_type="IRIX"
 117     llvm_cv_platform_type="Unix" ;;
 118   *-*-cygwin*)
 119     llvm_cv_link_all_option="-Wl,--whole-archive"
 120     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 121     llvm_cv_os_type="Cygwin"
 122     llvm_cv_platform_type="Unix" ;;
 123   *-*-darwin*)
 124     llvm_cv_link_all_option="-Wl,-all_load"
 125     llvm_cv_no_link_all_option="-Wl,-noall_load"
 126     llvm_cv_os_type="Darwin"
 127     llvm_cv_platform_type="Unix" ;;
 128   *-*-freebsd*)
 129     llvm_cv_link_all_option="-Wl,--whole-archive"
 130     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 131     llvm_cv_os_type="FreeBSD"
 132     llvm_cv_platform_type="Unix" ;;
 133   *-*-openbsd*)
 134     llvm_cv_link_all_option="-Wl,--whole-archive"
 135     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 136     llvm_cv_os_type="OpenBSD"
 137     llvm_cv_platform_type="Unix" ;;
 138   *-*-netbsd*)
 139     llvm_cv_link_all_option="-Wl,--whole-archive"
 140     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 141     llvm_cv_os_type="NetBSD"
 142     llvm_cv_platform_type="Unix" ;;
 143   *-*-dragonfly*)
 144     llvm_cv_link_all_option="-Wl,--whole-archive"
 145     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 146     llvm_cv_os_type="DragonFly"
 147     llvm_cv_platform_type="Unix" ;;
 148   *-*-hpux*)
 149     llvm_cv_link_all_option="-Wl,--whole-archive"
 150     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 151     llvm_cv_os_type="HP-UX"
 152     llvm_cv_platform_type="Unix" ;;
 153   *-*-interix*)
 154     llvm_cv_link_all_option="-Wl,--whole-archive"
 155     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 156     llvm_cv_os_type="Interix"
 157     llvm_cv_platform_type="Unix" ;;
 158   *-*-linux*)
 159     llvm_cv_link_all_option="-Wl,--whole-archive"
 160     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 161     llvm_cv_os_type="Linux"
 162     llvm_cv_platform_type="Unix" ;;
 163   *-*-solaris*)
 164     llvm_cv_link_all_option="-Wl,-z,allextract"
 165     llvm_cv_no_link_all_option="-Wl,-z,defaultextract"
 166     llvm_cv_os_type="SunOS"
 167     llvm_cv_platform_type="Unix" ;;
 168   *-*-win32*)
 169     llvm_cv_link_all_option="-Wl,--whole-archive"
 170     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 171     llvm_cv_os_type="Win32"
 172     llvm_cv_platform_type="Win32" ;;
 173   *-*-mingw*)
 174     llvm_cv_link_all_option="-Wl,--whole-archive"
 175     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 176     llvm_cv_os_type="MingW"
 177     llvm_cv_platform_type="Win32" ;;
 178   *-unknown-eabi*)
 179     llvm_cv_link_all_option="-Wl,--whole-archive"
 180     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 181     llvm_cv_os_type="Freestanding"
 182     llvm_cv_platform_type="Unix" ;;
 183   *-unknown-elf*)
 184     llvm_cv_link_all_option="-Wl,--whole-archive"
 185     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 186     llvm_cv_os_type="Freestanding"
 187     llvm_cv_platform_type="Unix" ;;
 188   *)
 189     llvm_cv_link_all_option=""
 190     llvm_cv_no_link_all_option=""
 191     llvm_cv_os_type="Unknown"
 192     llvm_cv_platform_type="Unknown" ;;
 193 esac])
 194
 195 AC_CACHE_CHECK([type of operating system we're going to target],
 196                [llvm_cv_target_os_type],
 197 [case $target in
 198   *-*-aix*)
 199     llvm_cv_target_os_type="AIX" ;;
 200   *-*-irix*)
 201     llvm_cv_target_os_type="IRIX" ;;
 202   *-*-cygwin*)
 203     llvm_cv_target_os_type="Cygwin" ;;
 204   *-*-darwin*)
 205     llvm_cv_target_os_type="Darwin" ;;
 206   *-*-freebsd*)
 207     llvm_cv_target_os_type="FreeBSD" ;;
 208   *-*-openbsd*)
 209     llvm_cv_target_os_type="OpenBSD" ;;
 210   *-*-netbsd*)
 211     llvm_cv_target_os_type="NetBSD" ;;
 212   *-*-dragonfly*)
 213     llvm_cv_target_os_type="DragonFly" ;;
 214   *-*-hpux*)
 215     llvm_cv_target_os_type="HP-UX" ;;
 216   *-*-interix*)
 217     llvm_cv_target_os_type="Interix" ;;
 218   *-*-linux*)
 219     llvm_cv_target_os_type="Linux" ;;
 220   *-*-solaris*)
 221     llvm_cv_target_os_type="SunOS" ;;
 222   *-*-win32*)
 223     llvm_cv_target_os_type="Win32" ;;
 224   *-*-mingw*)
 225     llvm_cv_target_os_type="MingW" ;;
 226   *-unknown-eabi*)
 227     llvm_cv_target_os_type="Freestanding" ;;
 228   *)
 229     llvm_cv_target_os_type="Unknown" ;;
 230 esac])
 231
 232 dnl Make sure we aren't attempting to configure for an unknown system
 233 if test "$llvm_cv_os_type" = "Unknown" ; then
 234   AC_MSG_ERROR([Operating system is unknown, configure can't continue])
 235 fi
 236
 237 dnl Set the "OS" Makefile variable based on the platform type so the
 238 dnl makefile can configure itself to specific build hosts
 239 AC_SUBST(OS,$llvm_cv_os_type)
 240 AC_SUBST(HOST_OS,$llvm_cv_os_type)
 241 AC_SUBST(TARGET_OS,$llvm_cv_target_os_type)
 242
 243 dnl Set the LINKALL and NOLINKALL Makefile variables based on the platform
 244 AC_SUBST(LINKALL,$llvm_cv_link_all_option)
 245 AC_SUBST(NOLINKALL,$llvm_cv_no_link_all_option)
 246
 247 dnl Set the "LLVM_ON_*" variables based on llvm_cvs_platform_type
 248 dnl This is used by lib/System to determine the basic kind of implementation
 249 dnl to use.
 250 case $llvm_cv_platform_type in
 251   Unix)
 252     AC_DEFINE([LLVM_ON_UNIX],[1],[Define if this is Unixish platform])
 253     AC_SUBST(LLVM_ON_UNIX,[1])
 254     AC_SUBST(LLVM_ON_WIN32,[0])
 255     ;;
 256   Win32)
 257     AC_DEFINE([LLVM_ON_WIN32],[1],[Define if this is Win32ish platform])
 258     AC_SUBST(LLVM_ON_UNIX,[0])
 259     AC_SUBST(LLVM_ON_WIN32,[1])
 260     ;;
 261 esac
 262
 263 dnl Determine what our target architecture is and configure accordingly.
 264 dnl This will allow Makefiles to make a distinction between the hardware and
 265 dnl the OS.
 266 AC_CACHE_CHECK([target architecture],[llvm_cv_target_arch],
 267 [case $target in
 268   i?86-*)                 llvm_cv_target_arch="x86" ;;
 269   amd64-* | x86_64-*)     llvm_cv_target_arch="x86_64" ;;
 270   sparc*-*)               llvm_cv_target_arch="Sparc" ;;
 271   powerpc*-*)             llvm_cv_target_arch="PowerPC" ;;
 272   alpha*-*)               llvm_cv_target_arch="Alpha" ;;
 273   arm*-*)                 llvm_cv_target_arch="ARM" ;;
 274   mips-*)                 llvm_cv_target_arch="Mips" ;;
 275   pic16-*)                llvm_cv_target_arch="PIC16" ;;
 276   xcore-*)                llvm_cv_target_arch="XCore" ;;
 277   msp430-*)               llvm_cv_target_arch="MSP430" ;;
 278   s390x-*)                llvm_cv_target_arch="SystemZ" ;;
 279   bfin-*)                 llvm_cv_target_arch="Blackfin" ;;
 280   *)                      llvm_cv_target_arch="Unknown" ;;
 281 esac])
 282
 283 if test "$llvm_cv_target_arch" = "Unknown" ; then
 284   AC_MSG_WARN([Configuring LLVM for an unknown target archicture])
 285 fi
 286
 287 # Determine the LLVM native architecture for the target
 288 case "$llvm_cv_target_arch" in
 289     x86)     LLVM_NATIVE_ARCH="X86" ;;
 290     x86_64)  LLVM_NATIVE_ARCH="X86" ;;
 291     *)       LLVM_NATIVE_ARCH="$llvm_cv_target_arch" ;;
 292 esac
 293
 294 dnl Define a substitution, ARCH, for the target architecture
 295 AC_SUBST(ARCH,$llvm_cv_target_arch)
 296
 297 dnl Check for the endianness of the target
 298 AC_C_BIGENDIAN(AC_SUBST([ENDIAN],[big]),AC_SUBST([ENDIAN],[little]))
 299
 300 dnl Check for build platform executable suffix if we're crosscompiling
 301 if test "$cross_compiling" = yes; then
 302   AC_SUBST(LLVM_CROSS_COMPILING, [1])
 303   AC_BUILD_EXEEXT
 304   ac_build_prefix=${build_alias}-
 305   AC_CHECK_PROG(BUILD_CXX, ${ac_build_prefix}g++, ${ac_build_prefix}g++)
 306   if test -z "$BUILD_CXX"; then
 307      AC_CHECK_PROG(BUILD_CXX, g++, g++)
 308      if test -z "$BUILD_CXX"; then
 309        AC_CHECK_PROG(BUILD_CXX, c++, c++, , , /usr/ucb/c++)
 310      fi
 311   fi
 312 else
 313   AC_SUBST(LLVM_CROSS_COMPILING, [0])
 314 fi
 315
 316 dnl Check to see if there's a "CVS" (or .svn or .git) directory indicating
 317 dnl that this build is being done from a checkout. This sets up several
 318 dnl defaults for the command line switches. When we build with a CVS directory,
 319 dnl we get a debug with assertions turned on. Without, we assume a source
 320 dnl release and we get an optimized build without assertions.
 321 dnl See --enable-optimized and --enable-assertions below
 322 if test -d "CVS" -o -d "${srcdir}/CVS" -o -d ".svn" -o -d "${srcdir}/.svn" -o -d ".git" -o -d "${srcdir}/.git"; then
 323   cvsbuild="yes"
 324   optimize="no"
 325   AC_SUBST(CVSBUILD,[[CVSBUILD=1]])
 326 else
 327   cvsbuild="no"
 328   optimize="yes"
 329 fi
 330
 331 dnl===-----------------------------------------------------------------------===
 332 dnl===
 333 dnl=== SECTION 3: Command line arguments for the configure script.
 334 dnl===
 335 dnl===-----------------------------------------------------------------------===
 336
 337 dnl --enable-optimized : check whether they want to do an optimized build:
 338 AC_ARG_ENABLE(optimized, AS_HELP_STRING(
 339  --enable-optimized,[Compile with optimizations enabled (default is NO)]),,enableval=$optimize)
 340 if test ${enableval} = "no" ; then
 341   AC_SUBST(ENABLE_OPTIMIZED,[[]])
 342 else
 343   AC_SUBST(ENABLE_OPTIMIZED,[[ENABLE_OPTIMIZED=1]])
 344 fi
 345
 346 dnl --enable-profiling : check whether they want to do a profile build:
 347 AC_ARG_ENABLE(profiling, AS_HELP_STRING(
 348  --enable-profiling,[Compile with profiling enabled (default is NO)]),,enableval="no")
 349 if test ${enableval} = "no" ; then
 350   AC_SUBST(ENABLE_PROFILING,[[]])
 351 else
 352   AC_SUBST(ENABLE_PROFILING,[[ENABLE_PROFILING=1]])
 353 fi
 354
 355 dnl --enable-assertions : check whether they want to turn on assertions or not:
 356 AC_ARG_ENABLE(assertions,AS_HELP_STRING(
 357   --enable-assertions,[Compile with assertion checks enabled (default is YES)]),, enableval="yes")
 358 if test ${enableval} = "yes" ; then
 359   AC_SUBST(DISABLE_ASSERTIONS,[[]])
 360 else
 361   AC_SUBST(DISABLE_ASSERTIONS,[[DISABLE_ASSERTIONS=1]])
 362 fi
 363
 364 dnl --enable-expensive-checks : check whether they want to turn on expensive debug checks:
 365 AC_ARG_ENABLE(expensive-checks,AS_HELP_STRING(
 366   --enable-expensive-checks,[Compile with expensive debug checks enabled (default is NO)]),, enableval="no")
 367 if test ${enableval} = "yes" ; then
 368   AC_SUBST(ENABLE_EXPENSIVE_CHECKS,[[ENABLE_EXPENSIVE_CHECKS=1]])
 369   AC_SUBST(EXPENSIVE_CHECKS,[[yes]])
 370 else
 371   AC_SUBST(ENABLE_EXPENSIVE_CHECKS,[[]])
 372   AC_SUBST(EXPENSIVE_CHECKS,[[no]])
 373 fi
 374
 375 dnl --enable-debug-runtime : should runtime libraries have debug symbols?
 376 AC_ARG_ENABLE(debug-runtime,
 377    AS_HELP_STRING(--enable-debug-runtime,[Build runtime libs with debug symbols (default is NO)]),,enableval=no)
 378 if test ${enableval} = "no" ; then
 379   AC_SUBST(DEBUG_RUNTIME,[[]])
 380 else
 381   AC_SUBST(DEBUG_RUNTIME,[[DEBUG_RUNTIME=1]])
 382 fi
 383
 384 dnl --enable-debug-symbols : should even optimized compiler libraries
 385 dnl have debug symbols?
 386 AC_ARG_ENABLE(debug-symbols,
 387    AS_HELP_STRING(--enable-debug-symbols,[Build compiler with debug symbols (default is NO if optimization is on and YES if it's off)]),,enableval=no)
 388 if test ${enableval} = "no" ; then
 389   AC_SUBST(DEBUG_SYMBOLS,[[]])
 390 else
 391   AC_SUBST(DEBUG_SYMBOLS,[[DEBUG_SYMBOLS=1]])
 392 fi
 393
 394 dnl --enable-jit: check whether they want to enable the jit
 395 AC_ARG_ENABLE(jit,
 396   AS_HELP_STRING(--enable-jit,
 397                  [Enable Just In Time Compiling (default is YES)]),,
 398   enableval=default)
 399 if test ${enableval} = "no"
 400 then
 401   AC_SUBST(JIT,[[]])
 402 else
 403   case "$llvm_cv_target_arch" in
 404     x86)         AC_SUBST(TARGET_HAS_JIT,1) ;;
 405     Sparc)       AC_SUBST(TARGET_HAS_JIT,0) ;;
 406     PowerPC)     AC_SUBST(TARGET_HAS_JIT,1) ;;
 407     x86_64)      AC_SUBST(TARGET_HAS_JIT,1) ;;
 408     Alpha)       AC_SUBST(TARGET_HAS_JIT,1) ;;
 409     ARM)         AC_SUBST(TARGET_HAS_JIT,1) ;;
 410     Mips)        AC_SUBST(TARGET_HAS_JIT,0) ;;
 411     PIC16)       AC_SUBST(TARGET_HAS_JIT,0) ;;
 412     XCore)       AC_SUBST(TARGET_HAS_JIT,0) ;;
 413     MSP430)      AC_SUBST(TARGET_HAS_JIT,0) ;;
 414     SystemZ)     AC_SUBST(TARGET_HAS_JIT,0) ;;
 415     Blackfin)    AC_SUBST(TARGET_HAS_JIT,0) ;;
 416     *)           AC_SUBST(TARGET_HAS_JIT,0) ;;
 417   esac
 418 fi
 419
 420 dnl Allow enablement of doxygen generated documentation
 421 AC_ARG_ENABLE(doxygen,
 422               AS_HELP_STRING([--enable-doxygen],
 423                              [Build doxygen documentation (default is NO)]),,
 424                              enableval=default)
 425 case "$enableval" in
 426   yes) AC_SUBST(ENABLE_DOXYGEN,[1]) ;;
 427   no)  AC_SUBST(ENABLE_DOXYGEN,[0]) ;;
 428   default) AC_SUBST(ENABLE_DOXYGEN,[0]) ;;
 429   *) AC_MSG_ERROR([Invalid setting for --enable-doxygen. Use "yes" or "no"]) ;;
 430 esac
 431
 432 dnl Allow disablement of threads
 433 AC_ARG_ENABLE(threads,
 434               AS_HELP_STRING([--enable-threads],
 435                              [Use threads if available (default is YES)]),,
 436                              enableval=default)
 437 case "$enableval" in
 438   yes) AC_SUBST(ENABLE_THREADS,[1]) ;;
 439   no)  AC_SUBST(ENABLE_THREADS,[0]) ;;
 440   default) AC_SUBST(ENABLE_THREADS,[1]) ;;
 441   *) AC_MSG_ERROR([Invalid setting for --enable-threads. Use "yes" or "no"]) ;;
 442 esac
 443 AC_DEFINE_UNQUOTED([ENABLE_THREADS],$ENABLE_THREADS,[Define if threads enabled])
 444
 445 dnl Allow building without position independent code
 446 AC_ARG_ENABLE(pic,
 447   AS_HELP_STRING([--enable-pic],
 448                  [Build LLVM with Position Independent Code (default is YES)]),,
 449                  enableval=default)
 450 case "$enableval" in
 451   yes) AC_SUBST(ENABLE_PIC,[1]) ;;
 452   no)  AC_SUBST(ENABLE_PIC,[0]) ;;
 453   default) AC_SUBST(ENABLE_PIC,[1]) ;;
 454   *) AC_MSG_ERROR([Invalid setting for --enable-pic. Use "yes" or "no"]) ;;
 455 esac
 456 AC_DEFINE_UNQUOTED([ENABLE_PIC],$ENABLE_PIC,
 457                    [Define if position independent code is enabled])
 458
 459 dnl Allow specific targets to be specified for building (or not)
 460 TARGETS_TO_BUILD=""
 461 AC_ARG_ENABLE([targets],AS_HELP_STRING([--enable-targets],
 462     [Build specific host targets: all or target1,target2,... Valid targets are:
 463      host, x86, x86_64, sparc, powerpc, alpha, arm, mips, spu, pic16,
 464      xcore, msp430, systemz, blackfin, cbe, msil, and cpp (default=all)]),,
 465     enableval=all)
 466 if test "$enableval" = host-only ; then
 467   enableval=host
 468 fi
 469 case "$enableval" in
 470   all) TARGETS_TO_BUILD="X86 Sparc PowerPC Alpha ARM Mips CellSPU PIC16 XCore MSP430 SystemZ Blackfin CBackend MSIL CppBackend" ;;
 471   *)for a_target in `echo $enableval|sed -e 's/,/ /g' ` ; do
 472       case "$a_target" in
 473         x86)      TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 474         x86_64)   TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 475         sparc)    TARGETS_TO_BUILD="Sparc $TARGETS_TO_BUILD" ;;
 476         powerpc)  TARGETS_TO_BUILD="PowerPC $TARGETS_TO_BUILD" ;;
 477         alpha)    TARGETS_TO_BUILD="Alpha $TARGETS_TO_BUILD" ;;
 478         arm)      TARGETS_TO_BUILD="ARM $TARGETS_TO_BUILD" ;;
 479         mips)     TARGETS_TO_BUILD="Mips $TARGETS_TO_BUILD" ;;
 480         spu)      TARGETS_TO_BUILD="CellSPU $TARGETS_TO_BUILD" ;;
 481         pic16)    TARGETS_TO_BUILD="PIC16 $TARGETS_TO_BUILD" ;;
 482         xcore)    TARGETS_TO_BUILD="XCore $TARGETS_TO_BUILD" ;;
 483         msp430)   TARGETS_TO_BUILD="MSP430 $TARGETS_TO_BUILD" ;;
 484         systemz)  TARGETS_TO_BUILD="SystemZ $TARGETS_TO_BUILD" ;;
 485         blackfin) TARGETS_TO_BUILD="Blackfin $TARGETS_TO_BUILD" ;;
 486         cbe)      TARGETS_TO_BUILD="CBackend $TARGETS_TO_BUILD" ;;
 487         msil)     TARGETS_TO_BUILD="MSIL $TARGETS_TO_BUILD" ;;
 488         cpp)      TARGETS_TO_BUILD="CppBackend $TARGETS_TO_BUILD" ;;
 489         host) case "$llvm_cv_target_arch" in
 490             x86)         TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 491             x86_64)      TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 492             Sparc)       TARGETS_TO_BUILD="Sparc $TARGETS_TO_BUILD" ;;
 493             PowerPC)     TARGETS_TO_BUILD="PowerPC $TARGETS_TO_BUILD" ;;
 494             Alpha)       TARGETS_TO_BUILD="Alpha $TARGETS_TO_BUILD" ;;
 495             ARM)         TARGETS_TO_BUILD="ARM $TARGETS_TO_BUILD" ;;
 496             Mips)        TARGETS_TO_BUILD="Mips $TARGETS_TO_BUILD" ;;
 497             CellSPU|SPU) TARGETS_TO_BUILD="CellSPU $TARGETS_TO_BUILD" ;;
 498             PIC16)       TARGETS_TO_BUILD="PIC16 $TARGETS_TO_BUILD" ;;
 499             XCore)       TARGETS_TO_BUILD="XCore $TARGETS_TO_BUILD" ;;
 500             MSP430)      TARGETS_TO_BUILD="MSP430 $TARGETS_TO_BUILD" ;;
 501             SystemZ)     TARGETS_TO_BUILD="SystemZ $TARGETS_TO_BUILD" ;;
 502             Blackfin)    TARGETS_TO_BUILD="Blackfin $TARGETS_TO_BUILD" ;;
 503             *)       AC_MSG_ERROR([Can not set target to build]) ;;
 504           esac ;;
 505         *) AC_MSG_ERROR([Unrecognized target $a_target]) ;;
 506       esac
 507   done
 508   ;;
 509 esac
 510 AC_SUBST(TARGETS_TO_BUILD,$TARGETS_TO_BUILD)
 511
 512 # Determine whether we are building LLVM support for the native architecture.
 513 # If so, define LLVM_NATIVE_ARCH to that LLVM target.
 514 for a_target in $TARGETS_TO_BUILD; do
 515   if test "$a_target" = "$LLVM_NATIVE_ARCH"; then
 516     LLVM_NATIVE_ARCHTARGET="${LLVM_NATIVE_ARCH}Target"
 517     AC_DEFINE_UNQUOTED(LLVM_NATIVE_ARCH,$LLVM_NATIVE_ARCHTARGET,
 518       [LLVM architecture name for the native architecture, if available])
 519   fi
 520 done
 521
 522 # Build the LLVM_TARGET and LLVM_ASM_PRINTER macro uses for
 523 # Targets.def, AsmPrinters.def, and AsmParsers.def.
 524 LLVM_ENUM_TARGETS=""
 525 LLVM_ENUM_ASM_PRINTERS=""
 526 LLVM_ENUM_ASM_PARSERS=""
 527 for target_to_build in $TARGETS_TO_BUILD; do
 528   LLVM_ENUM_TARGETS="LLVM_TARGET($target_to_build) $LLVM_ENUM_TARGETS"
 529   if test -f ${srcdir}/lib/Target/${target_to_build}/AsmPrinter/Makefile ; then
 530     LLVM_ENUM_ASM_PRINTERS="LLVM_ASM_PRINTER($target_to_build) $LLVM_ENUM_ASM_PRINTERS";
 531   fi
 532   if test -f ${srcdir}/lib/Target/${target_to_build}/AsmParser/Makefile ; then
 533     LLVM_ENUM_ASM_PARSERS="LLVM_ASM_PARSER($target_to_build) $LLVM_ENUM_ASM_PARSERS";
 534   fi
 535 done
 536 AC_SUBST(LLVM_ENUM_TARGETS)
 537 AC_SUBST(LLVM_ENUM_ASM_PRINTERS)
 538 AC_SUBST(LLVM_ENUM_ASM_PARSERS)
 539
 540 dnl Prevent the CBackend from using printf("%a") for floating point so older
 541 dnl C compilers that cannot deal with the 0x0p+0 hex floating point format
 542 dnl can still compile the CBE's output
 543 AC_ARG_ENABLE([cbe-printf-a],AS_HELP_STRING([--enable-cbe-printf-a],
 544   [Enable C Backend output with hex floating point via %a  (default is YES)]),,
 545   enableval=default)
 546 case "$enableval" in
 547   yes) AC_SUBST(ENABLE_CBE_PRINTF_A,[1]) ;;
 548   no)  AC_SUBST(ENABLE_CBE_PRINTF_A,[0]) ;;
 549   default)  AC_SUBST(ENABLE_CBE_PRINTF_A,[1]) ;;
 550   *) AC_MSG_ERROR([Invalid setting for --enable-cbe-printf-a. Use "yes" or "no"]) ;;
 551 esac
 552 AC_DEFINE_UNQUOTED([ENABLE_CBE_PRINTF_A],$ENABLE_CBE_PRINTF_A,
 553                    [Define if CBE is enabled for printf %a output])
 554
 555 dnl Allow a specific llvm-gcc/llvm-g++ pair to be used with this LLVM config.
 556 AC_ARG_WITH(llvmgccdir,
 557   AS_HELP_STRING([--with-llvmgccdir],
 558     [Specify location of llvm-gcc install dir (default searches PATH)]),,
 559     withval=default)
 560 case "$withval" in
 561   default) WITH_LLVMGCCDIR=default ;;
 562   /* | [[A-Za-z]]:[[\\/]]*)      WITH_LLVMGCCDIR=$withval ;;
 563   *) AC_MSG_ERROR([Invalid path for --with-llvmgccdir. Provide full path]) ;;
 564 esac
 565
 566 dnl Allow a specific llvm-gcc compiler to be used with this LLVM config.
 567 AC_ARG_WITH(llvmgcc,
 568   AS_HELP_STRING([--with-llvmgcc],
 569     [Specify location of llvm-gcc driver (default searches PATH)]),
 570     LLVMGCC=$with_llvmgcc
 571       WITH_LLVMGCCDIR="",)
 572
 573 dnl Allow a specific llvm-g++ compiler to be used with this LLVM config.
 574 AC_ARG_WITH(llvmgxx,
 575   AS_HELP_STRING([--with-llvmgxx],
 576     [Specify location of llvm-g++ driver (default searches PATH)]),
 577     LLVMGXX=$with_llvmgxx
 578     WITH_LLVMGCCDIR="",)
 579
 580 if test -n "$LLVMGCC"; then
 581    LLVMGCCCOMMAND="$LLVMGCC"
 582 fi
 583
 584 if test -n "$LLVMGXX"; then
 585    LLVMGXXCOMMAND="$LLVMGXX"
 586 fi
 587
 588 if test -n "$LLVMGCC" && test -z "$LLVMGXX"; then
 589    AC_MSG_ERROR([Invalid llvm-g++. Use --with-llvmgxx when --with-llvmgcc is used]);
 590 fi
 591
 592 if test -n "$LLVMGXX" && test -z "$LLVMGCC"; then
 593    AC_MSG_ERROR([Invalid llvm-gcc. Use --with-llvmgcc when --with-llvmgxx is used]);
 594 fi
 595
 596 dnl Specify extra build options
 597 AC_ARG_WITH(extra-options,
 598   AS_HELP_STRING([--with-extra-options],
 599                  [Specify additional options to compile LLVM with]),,
 600                  withval=default)
 601 case "$withval" in
 602   default) EXTRA_OPTIONS= ;;
 603   *) EXTRA_OPTIONS=$withval ;;
 604 esac
 605 AC_SUBST(EXTRA_OPTIONS,$EXTRA_OPTIONS)
 606
 607 dnl Allow specific bindings to be specified for building (or not)
 608 AC_ARG_ENABLE([bindings],AS_HELP_STRING([--enable-bindings],
 609     [Build specific language bindings: all,auto,none,{binding-name} (default=auto)]),,
 610     enableval=default)
 611 BINDINGS_TO_BUILD=""
 612 case "$enableval" in
 613   yes | default | auto) BINDINGS_TO_BUILD="auto" ;;
 614   all ) BINDINGS_TO_BUILD="ocaml" ;;
 615   none | no) BINDINGS_TO_BUILD="" ;;
 616   *)for a_binding in `echo $enableval|sed -e 's/,/ /g' ` ; do
 617       case "$a_binding" in
 618         ocaml) BINDINGS_TO_BUILD="ocaml $BINDINGS_TO_BUILD" ;;
 619         *) AC_MSG_ERROR([Unrecognized binding $a_binding]) ;;
 620       esac
 621   done
 622   ;;
 623 esac
 624
 625 dnl Allow the ocaml libdir to be overridden. This could go in a configure
 626 dnl script for bindings/ocaml/configure, except that its auto value depends on
 627 dnl OCAMLC, which is found here to support tests.
 628 AC_ARG_WITH([ocaml-libdir],
 629   [AS_HELP_STRING([--with-ocaml-libdir],
 630     [Specify install location for ocaml bindings (default is stdlib)])],
 631   [],
 632   [withval=auto])
 633 case "$withval" in
 634   auto) with_ocaml_libdir="$withval" ;;
 635   /* | [[A-Za-z]]:[[\\/]]*) with_ocaml_libdir="$withval" ;;
 636   *) AC_MSG_ERROR([Invalid path for --with-ocaml-libdir. Provide full path]) ;;
 637 esac
 638
 639 dnl Allow linking of LLVM with GPLv3 binutils code.
 640 AC_ARG_WITH(binutils-include,
 641   AS_HELP_STRING([--with-binutils-include],
 642     [Specify path to binutils/include/ containing plugin-api.h file for gold plugin.]),,
 643   withval=default)
 644 case "$withval" in
 645   default) WITH_BINUTILS_INCDIR=default ;;
 646   /* | [[A-Za-z]]:[[\\/]]*)      WITH_BINUTILS_INCDIR=$withval ;;
 647   *) AC_MSG_ERROR([Invalid path for --with-binutils-include. Provide full path]) ;;
 648 esac
 649 if test "x$WITH_BINUTILS_INCDIR" != xdefault ; then
 650   AC_SUBST(BINUTILS_INCDIR,$WITH_BINUTILS_INCDIR)
 651   if test ! -f "$WITH_BINUTILS_INCDIR/plugin-api.h"; then
 652      echo "$WITH_BINUTILS_INCDIR/plugin-api.h"
 653      AC_MSG_ERROR([Invalid path to directory containing plugin-api.h.]);
 654   fi
 655 fi
 656
 657 dnl --enable-libffi : check whether the user wants to turn off libffi:
 658 AC_ARG_ENABLE(libffi,AS_HELP_STRING(
 659   --enable-libffi,[Check for the presence of libffi (default is YES)]),,
 660   enableval=yes)
 661 case "$enableval" in
 662   yes) llvm_cv_enable_libffi="yes" ;;
 663   no)  llvm_cv_enable_libffi="no"  ;;
 664   *) AC_MSG_ERROR([Invalid setting for --enable-libffi. Use "yes" or "no"]) ;;
 665 esac
 666
 667 dnl Only Windows needs dynamic libCompilerDriver to support plugins.
 668 if test "$llvm_cv_os_type" = "Win32" ; then
 669    llvmc_dynamic="yes"
 670 else
 671    llvmc_dynamic="no"
 672 fi
 673
 674 dnl --enable-llvmc-dynamic : should LLVMC link libCompilerDriver dynamically?
 675 AC_ARG_ENABLE(llvmc-dynamic,AS_HELP_STRING(
 676 --enable-llvmc-dynamic,
 677 [Link LLVMC dynamically (default is NO, unless on Win32)]),,
 678 enableval=$llvmc_dynamic)
 679 if test ${enableval} = "yes" && test "$ENABLE_PIC" -eq 1 ; then
 680    AC_SUBST(ENABLE_LLVMC_DYNAMIC,[[ENABLE_LLVMC_DYNAMIC=1]])
 681 else
 682    AC_SUBST(ENABLE_LLVMC_DYNAMIC,[[]])
 683 fi
 684
 685 dnl --enable-llvmc-dynamic-plugins : should LLVMC support dynamic plugins?
 686 AC_ARG_ENABLE(llvmc-dynamic-plugins,AS_HELP_STRING(
 687 --enable-llvmc-dynamic-plugins,
 688 [Enable dynamic LLVMC plugins (default is YES)]),,
 689 enableval=yes)
 690 if test ${enableval} = "yes" ; then
 691    AC_SUBST(ENABLE_LLVMC_DYNAMIC_PLUGINS,[[ENABLE_LLVMC_DYNAMIC_PLUGINS=1]])
 692 else
 693    AC_SUBST(ENABLE_LLVMC_DYNAMIC_PLUGINS,[[]])
 694 fi
 695
 696 dnl===-----------------------------------------------------------------------===
 697 dnl===
 698 dnl=== SECTION 4: Check for programs we need and that they are the right version
 699 dnl===
 700 dnl===-----------------------------------------------------------------------===
 701
 702 dnl Check for compilation tools
 703 AC_PROG_CPP
 704 AC_PROG_CC(gcc)
 705 AC_PROG_CXX(g++)
 706
 707 AC_PROG_NM
 708 AC_SUBST(NM)
 709
 710 dnl Check for the tools that the makefiles require
 711 AC_CHECK_GNU_MAKE
 712 AC_PROG_LN_S
 713 AC_PATH_PROG(CMP, [cmp], [cmp])
 714 AC_PATH_PROG(CP, [cp], [cp])
 715 AC_PATH_PROG(DATE, [date], [date])
 716 AC_PATH_PROG(FIND, [find], [find])
 717 AC_PATH_PROG(GREP, [grep], [grep])
 718 AC_PATH_PROG(MKDIR,[mkdir],[mkdir])
 719 AC_PATH_PROG(MV,   [mv],   [mv])
 720 AC_PROG_RANLIB
 721 AC_PATH_PROG(RM,   [rm],   [rm])
 722 AC_PATH_PROG(SED,  [sed],  [sed])
 723 AC_PATH_PROG(TAR,  [tar],  [gtar])
 724 AC_PATH_PROG(BINPWD,[pwd],  [pwd])
 725
 726 dnl Looking for misc. graph plotting software
 727 AC_PATH_PROG(GRAPHVIZ, [Graphviz], [echo Graphviz])
 728 if test "$GRAPHVIZ" != "echo Graphviz" ; then
 729   AC_DEFINE([HAVE_GRAPHVIZ],[1],[Define if the Graphviz program is available])
 730   dnl If we're targeting for mingw we should emit windows paths, not msys
 731   if test "$llvm_cv_os_type" = "MingW" ; then
 732     GRAPHVIZ=`echo $GRAPHVIZ | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 733   fi
 734   AC_DEFINE_UNQUOTED([LLVM_PATH_GRAPHVIZ],"$GRAPHVIZ${EXEEXT}",
 735    [Define to path to Graphviz program if found or 'echo Graphviz' otherwise])
 736 fi
 737 AC_PATH_PROG(DOT, [dot], [echo dot])
 738 if test "$DOT" != "echo dot" ; then
 739   AC_DEFINE([HAVE_DOT],[1],[Define if the dot program is available])
 740   dnl If we're targeting for mingw we should emit windows paths, not msys
 741   if test "$llvm_cv_os_type" = "MingW" ; then
 742     DOT=`echo $DOT | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 743   fi
 744   AC_DEFINE_UNQUOTED([LLVM_PATH_DOT],"$DOT${EXEEXT}",
 745    [Define to path to dot program if found or 'echo dot' otherwise])
 746 fi
 747 AC_PATH_PROG(FDP, [fdp], [echo fdp])
 748 if test "$FDP" != "echo fdp" ; then
 749   AC_DEFINE([HAVE_FDP],[1],[Define if the neat program is available])
 750   dnl If we're targeting for mingw we should emit windows paths, not msys
 751   if test "$llvm_cv_os_type" = "MingW" ; then
 752     FDP=`echo $FDP | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 753   fi
 754   AC_DEFINE_UNQUOTED([LLVM_PATH_FDP],"$FDP${EXEEXT}",
 755    [Define to path to fdp program if found or 'echo fdp' otherwise])
 756 fi
 757 AC_PATH_PROG(NEATO, [neato], [echo neato])
 758 if test "$NEATO" != "echo neato" ; then
 759   AC_DEFINE([HAVE_NEATO],[1],[Define if the neat program is available])
 760   dnl If we're targeting for mingw we should emit windows paths, not msys
 761   if test "$llvm_cv_os_type" = "MingW" ; then
 762     NEATO=`echo $NEATO | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 763   fi
 764   AC_DEFINE_UNQUOTED([LLVM_PATH_NEATO],"$NEATO${EXEEXT}",
 765    [Define to path to neato program if found or 'echo neato' otherwise])
 766 fi
 767 AC_PATH_PROG(TWOPI, [twopi], [echo twopi])
 768 if test "$TWOPI" != "echo twopi" ; then
 769   AC_DEFINE([HAVE_TWOPI],[1],[Define if the neat program is available])
 770   dnl If we're targeting for mingw we should emit windows paths, not msys
 771   if test "$llvm_cv_os_type" = "MingW" ; then
 772     TWOPI=`echo $TWOPI | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 773   fi
 774   AC_DEFINE_UNQUOTED([LLVM_PATH_TWOPI],"$TWOPI${EXEEXT}",
 775    [Define to path to twopi program if found or 'echo twopi' otherwise])
 776 fi
 777 AC_PATH_PROG(CIRCO, [circo], [echo circo])
 778 if test "$CIRCO" != "echo circo" ; then
 779   AC_DEFINE([HAVE_CIRCO],[1],[Define if the neat program is available])
 780   dnl If we're targeting for mingw we should emit windows paths, not msys
 781   if test "$llvm_cv_os_type" = "MingW" ; then
 782     CIRCO=`echo $CIRCO | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 783   fi
 784   AC_DEFINE_UNQUOTED([LLVM_PATH_CIRCO],"$CIRCO${EXEEXT}",
 785    [Define to path to circo program if found or 'echo circo' otherwise])
 786 fi
 787 AC_PATH_PROGS(GV, [gv gsview32], [echo gv])
 788 if test "$GV" != "echo gv" ; then
 789   AC_DEFINE([HAVE_GV],[1],[Define if the gv program is available])
 790   dnl If we're targeting for mingw we should emit windows paths, not msys
 791   if test "$llvm_cv_os_type" = "MingW" ; then
 792     GV=`echo $GV | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 793   fi
 794   AC_DEFINE_UNQUOTED([LLVM_PATH_GV],"$GV${EXEEXT}",
 795    [Define to path to gv program if found or 'echo gv' otherwise])
 796 fi
 797 AC_PATH_PROG(DOTTY, [dotty], [echo dotty])
 798 if test "$DOTTY" != "echo dotty" ; then
 799   AC_DEFINE([HAVE_DOTTY],[1],[Define if the dotty program is available])
 800   dnl If we're targeting for mingw we should emit windows paths, not msys
 801   if test "$llvm_cv_os_type" = "MingW" ; then
 802     DOTTY=`echo $DOTTY | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 803   fi
 804   AC_DEFINE_UNQUOTED([LLVM_PATH_DOTTY],"$DOTTY${EXEEXT}",
 805    [Define to path to dotty program if found or 'echo dotty' otherwise])
 806 fi
 807
 808 dnl Look for a sufficiently recent version of Perl.
 809 LLVM_PROG_PERL([5.006])
 810 AC_SUBST(PERL)
 811 if test x"$PERL" = xnone; then
 812    AC_SUBST(HAVE_PERL,0)
 813    AC_MSG_ERROR([perl is required but was not found, please install it])
 814 else
 815    AC_SUBST(HAVE_PERL,1)
 816 fi
 817
 818 dnl Find the install program
 819 AC_PROG_INSTALL
 820
 821 dnl Checks for documentation and testing tools that we can do without. If these
 822 dnl are not found then they are set to "true" which always succeeds but does
 823 dnl nothing. This just lets the build output show that we could have done
 824 dnl something if the tool was available.
 825 AC_PATH_PROG(BZIP2, [bzip2])
 826 AC_PATH_PROG(DOXYGEN, [doxygen])
 827 AC_PATH_PROG(GROFF, [groff])
 828 AC_PATH_PROG(GZIP, [gzip])
 829 AC_PATH_PROG(POD2HTML, [pod2html])
 830 AC_PATH_PROG(POD2MAN, [pod2man])
 831 AC_PATH_PROG(RUNTEST, [runtest])
 832 DJ_AC_PATH_TCLSH
 833 AC_PATH_PROG(ZIP, [zip])
 834 AC_PATH_PROGS(OCAMLC, [ocamlc])
 835 AC_PATH_PROGS(OCAMLOPT, [ocamlopt])
 836 AC_PATH_PROGS(OCAMLDEP, [ocamldep])
 837 AC_PATH_PROGS(OCAMLDOC, [ocamldoc])
 838 AC_PATH_PROGS(GAS, [gas as])
 839
 840 dnl Determine whether the linker supports the -R option.
 841 AC_LINK_USE_R
 842
 843 dnl Determine whether the linker supports the -export-dynamic option.
 844 AC_LINK_EXPORT_DYNAMIC
 845
 846 dnl Check for libtool and the library that has dlopen function (which must come
 847 dnl before the AC_PROG_LIBTOOL check in order to enable dlopening libraries with
 848 dnl libtool).
 849 AC_LIBTOOL_DLOPEN
 850 AC_LIB_LTDL
 851 AC_PROG_LIBTOOL
 852
 853 if test "$lt_cv_dlopen_self" = "yes" ; then
 854   AC_DEFINE([CAN_DLOPEN_SELF],[1],
 855               [Define if dlopen(0) will open the symbols of the program])
 856 fi
 857
 858
 859 if test "$WITH_LLVMGCCDIR" = "default" ; then
 860   LLVMGCC="llvm-gcc${EXEEXT}"
 861   LLVMGXX="llvm-g++${EXEEXT}"
 862   LLVMGCCCOMMAND="$LLVMGCC"
 863   LLVMGXXCOMMAND="$LLVMGXX"
 864   AC_SUBST(LLVMGCCCOMMAND,$LLVMGCCCOMMAND)
 865   AC_SUBST(LLVMGXXCOMMAND,$LLVMGXXCOMMAND)
 866   AC_PATH_PROG(LLVMGCC, $LLVMGCC, [])
 867   AC_PATH_PROG(LLVMGXX, $LLVMGXX, [])
 868 else
 869   if test -z "$LLVMGCC"; then
 870     LLVMGCC="$WITH_LLVMGCCDIR/bin/llvm-gcc${EXEEXT}"
 871     LLVMGCCCOMMAND="$LLVMGCC"
 872   fi
 873   if test -z "$LLVMGXX"; then
 874     LLVMGXX="$WITH_LLVMGCCDIR/bin/llvm-g++${EXEEXT}"
 875     LLVMGXXCOMMAND="$LLVMGXX"
 876   fi
 877
 878   AC_SUBST(LLVMGCC,$LLVMGCC)
 879   AC_SUBST(LLVMGXX,$LLVMGXX)
 880   AC_SUBST(LLVMGCCCOMMAND,$LLVMGCCCOMMAND)
 881   AC_SUBST(LLVMGXXCOMMAND,$LLVMGXXCOMMAND)
 882 fi
 883
 884
 885 AC_MSG_CHECKING([tool compatibility])
 886
 887 dnl Ensure that compilation tools are GCC or a GNU compatible compiler such as
 888 dnl ICC; we use GCC specific options in the makefiles so the compiler needs
 889 dnl to support those options.
 890 dnl "icc" emits gcc signatures
 891 dnl "icc -no-gcc" emits no gcc signature BUT is still compatible
 892 ICC=no
 893 IXX=no
 894 case $CC in
 895   icc*|icpc*)
 896     ICC=yes
 897     IXX=yes
 898     ;;
 899    *)
 900     ;;
 901 esac
 902
 903 if test "$GCC" != "yes" && test "$ICC" != "yes"
 904 then
 905   AC_MSG_ERROR([gcc|icc required but not found])
 906 fi
 907
 908 dnl Ensure that compilation tools are GCC; we use GCC specific extensions
 909 if test "$GXX" != "yes" && test "$IXX" != "yes"
 910 then
 911   AC_MSG_ERROR([g++|icc required but not found])
 912 fi
 913
 914 dnl Verify that GCC is version 3.0 or higher
 915 if test "$GCC" = "yes"
 916 then
 917   AC_COMPILE_IFELSE([[#if !defined(__GNUC__) || __GNUC__ < 3
 918 #error Unsupported GCC version
 919 #endif
 920 ]], [], [AC_MSG_ERROR([gcc 3.x required, but you have a lower version])])
 921 fi
 922
 923 dnl Check for GNU Make.  We use its extensions, so don't build without it
 924 if test -z "$llvm_cv_gnu_make_command"
 925 then
 926   AC_MSG_ERROR([GNU Make required but not found])
 927 fi
 928
 929 dnl Tool compatibility is okay if we make it here.
 930 AC_MSG_RESULT([ok])
 931
 932 dnl===-----------------------------------------------------------------------===
 933 dnl===
 934 dnl=== SECTION 5: Check for libraries
 935 dnl===
 936 dnl===-----------------------------------------------------------------------===
 937
 938 AC_CHECK_LIB(m,sin)
 939 if test "$llvm_cv_os_type" = "MingW" ; then
 940   AC_CHECK_LIB(imagehlp, main)
 941   AC_CHECK_LIB(psapi, main)
 942 fi
 943
 944 dnl dlopen() is required for plugin support.
 945 AC_SEARCH_LIBS(dlopen,dl,AC_DEFINE([HAVE_DLOPEN],[1],
 946                [Define if dlopen() is available on this platform.]),
 947                AC_MSG_WARN([dlopen() not found - disabling plugin support]))
 948
 949 dnl libffi is optional; used to call external functions from the interpreter
 950 if test "$llvm_cv_enable_libffi" = "yes" ; then
 951   AC_SEARCH_LIBS(ffi_call,ffi,AC_DEFINE([HAVE_FFI_CALL],[1],
 952                  [Define if libffi is available on this platform.]),
 953                  AC_MSG_WARN([libffi not found - disabling external calls from interpreter]))
 954 fi
 955
 956 dnl mallinfo is optional; the code can compile (minus features) without it
 957 AC_SEARCH_LIBS(mallinfo,malloc,AC_DEFINE([HAVE_MALLINFO],[1],
 958                [Define if mallinfo() is available on this platform.]))
 959
 960 dnl pthread locking functions are optional - but llvm will not be thread-safe
 961 dnl without locks.
 962 if test "$ENABLE_THREADS" -eq 1 ; then
 963   AC_CHECK_LIB(pthread,pthread_mutex_init)
 964   AC_SEARCH_LIBS(pthread_mutex_lock,pthread,
 965                  AC_DEFINE([HAVE_PTHREAD_MUTEX_LOCK],[1],
 966                            [Have pthread_mutex_lock]))
 967   AC_SEARCH_LIBS(pthread_rwlock_init,pthread,
 968                  AC_DEFINE([HAVE_PTHREAD_RWLOCK_INIT],[1],
 969                  [Have pthread_rwlock_init]))
 970   AC_SEARCH_LIBS(pthread_getspecific,pthread,
 971                  AC_DEFINE([HAVE_PTHREAD_GETSPECIFIC],[1],
 972                  [Have pthread_getspecific]))
 973 fi
 974
 975 dnl Allow extra x86-disassembler library
 976 AC_ARG_WITH(udis86,
 977   AS_HELP_STRING([--with-udis86=<path>],
 978     [Use udis86 external x86 disassembler library]),
 979     [
 980       AC_SUBST(USE_UDIS86, [1])
 981       case "$withval" in
 982         /usr/lib|yes) ;;
 983         *) LDFLAGS="$LDFLAGS -L${withval}" ;;
 984       esac
 985       AC_CHECK_LIB(udis86, ud_init, [], [
 986         echo "Error! You need to have libudis86 around."
 987         exit -1
 988       ])
 989     ],
 990     AC_SUBST(USE_UDIS86, [0]))
 991 AC_DEFINE_UNQUOTED([USE_UDIS86],$USE_UDIS86,
 992                    [Define if use udis86 library])
 993
 994 dnl Allow OProfile support for JIT output.
 995 AC_ARG_WITH(oprofile,
 996   AS_HELP_STRING([--with-oprofile=<prefix>],
 997     [Tell OProfile >= 0.9.4 how to symbolize JIT output]),
 998     [
 999       AC_SUBST(USE_OPROFILE, [1])
1000       case "$withval" in
1001         /usr|yes) llvm_cv_oppath=/usr/lib/oprofile ;;
1002         *) llvm_cv_oppath="${withval}/lib/oprofile"
1003            CPPFLAGS="-I${withval}/include";;
1004       esac
1005       LIBS="$LIBS -L${llvm_cv_oppath} -Wl,-rpath,${llvm_cv_oppath}"
1006       AC_SEARCH_LIBS(op_open_agent, opagent, [], [
1007         echo "Error! You need to have libopagent around."
1008         exit -1
1009       ])
1010       AC_CHECK_HEADER([opagent.h], [], [
1011         echo "Error! You need to have opagent.h around."
1012         exit -1
1013       ])
1014     ],
1015     [
1016       llvm_cv_old_LIBS="$LIBS"
1017       LIBS="$LIBS -L/usr/lib/oprofile -Wl,-rpath,/usr/lib/oprofile"
1018       dnl If either the library or header aren't present, omit oprofile support.
1019       AC_SEARCH_LIBS(op_open_agent, opagent,
1020                      [AC_SUBST(USE_OPROFILE, [1])],
1021                      [LIBS="$llvm_cv_old_LIBS"
1022                       AC_SUBST(USE_OPROFILE, [0])])
1023       AC_CHECK_HEADER([opagent.h], [], [
1024         LIBS="$llvm_cv_old_LIBS"
1025         AC_SUBST(USE_OPROFILE, [0])
1026       ])
1027     ])
1028 AC_DEFINE_UNQUOTED([USE_OPROFILE],$USE_OPROFILE,
1029                    [Define if we have the oprofile JIT-support library])
1030
1031 dnl===-----------------------------------------------------------------------===
1032 dnl===
1033 dnl=== SECTION 6: Check for header files
1034 dnl===
1035 dnl===-----------------------------------------------------------------------===
1036
1037 dnl First, use autoconf provided macros for specific headers that we need
1038 dnl We don't check for ancient stuff or things that are guaranteed to be there
1039 dnl by the C++ standard. We always use the <cfoo> versions of <foo.h> C headers.
1040 dnl Generally we're looking for POSIX headers.
1041 AC_HEADER_DIRENT
1042 AC_HEADER_MMAP_ANONYMOUS
1043 AC_HEADER_STAT
1044 AC_HEADER_STDC
1045 AC_HEADER_SYS_WAIT
1046 AC_HEADER_TIME
1047
1048 AC_CHECK_HEADERS([dlfcn.h execinfo.h fcntl.h inttypes.h limits.h link.h])
1049 AC_CHECK_HEADERS([malloc.h setjmp.h signal.h stdint.h termios.h unistd.h])
1050 AC_CHECK_HEADERS([utime.h windows.h])
1051 AC_CHECK_HEADERS([sys/mman.h sys/param.h sys/resource.h sys/time.h])
1052 AC_CHECK_HEADERS([sys/types.h sys/ioctl.h malloc/malloc.h mach/mach.h])
1053 if test "$ENABLE_THREADS" -eq 1 ; then
1054   AC_CHECK_HEADERS(pthread.h,
1055                    AC_SUBST(HAVE_PTHREAD, 1),
1056                    AC_SUBST(HAVE_PTHREAD, 0))
1057 else
1058   AC_SUBST(HAVE_PTHREAD, 0)
1059 fi
1060
1061 dnl Try to find ffi.h.
1062 if test "$llvm_cv_enable_libffi" = "yes" ; then
1063   AC_CHECK_HEADERS([ffi.h ffi/ffi.h])
1064 fi
1065
1066 dnl===-----------------------------------------------------------------------===
1067 dnl===
1068 dnl=== SECTION 7: Check for types and structures
1069 dnl===
1070 dnl===-----------------------------------------------------------------------===
1071
1072 AC_HUGE_VAL_CHECK
1073 AC_TYPE_PID_T
1074 AC_TYPE_SIZE_T
1075 AC_TYPE_SIGNAL
1076 AC_STRUCT_TM
1077 AC_CHECK_TYPES([int64_t],,AC_MSG_ERROR([Type int64_t required but not found]))
1078 AC_CHECK_TYPES([uint64_t],,
1079          AC_CHECK_TYPES([u_int64_t],,
1080          AC_MSG_ERROR([Type uint64_t or u_int64_t required but not found])))
1081
1082 dnl===-----------------------------------------------------------------------===
1083 dnl===
1084 dnl=== SECTION 8: Check for specific functions needed
1085 dnl===
1086 dnl===-----------------------------------------------------------------------===
1087
1088 AC_CHECK_FUNCS([backtrace ceilf floorf roundf rintf nearbyintf getcwd ])
1089 AC_CHECK_FUNCS([powf fmodf strtof round ])
1090 AC_CHECK_FUNCS([getpagesize getrusage getrlimit setrlimit gettimeofday ])
1091 AC_CHECK_FUNCS([isatty mkdtemp mkstemp ])
1092 AC_CHECK_FUNCS([mktemp realpath sbrk setrlimit strdup ])
1093 AC_CHECK_FUNCS([strerror strerror_r strerror_s setenv ])
1094 AC_CHECK_FUNCS([strtoll strtoq sysconf malloc_zone_statistics ])
1095 AC_CHECK_FUNCS([setjmp longjmp sigsetjmp siglongjmp])
1096 AC_C_PRINTF_A
1097 dnl FIXME: This is no longer used, please remove (but test)!!!
1098 AC_FUNC_ALLOCA
1099 AC_FUNC_RAND48
1100
1101 dnl Check for variations in the Standard C++ library and STL. These macros are
1102 dnl provided by LLVM in the autoconf/m4 directory.
1103 AC_CXX_HAVE_STD_ITERATOR
1104 AC_CXX_HAVE_BI_ITERATOR
1105 AC_CXX_HAVE_FWD_ITERATOR
1106 AC_FUNC_ISNAN
1107 AC_FUNC_ISINF
1108
1109 dnl Check for mmap support.We also need to know if /dev/zero is required to
1110 dnl be opened for allocating RWX memory.
1111 dnl Make sure we aren't attempting to configure for an unknown system
1112 if test "$llvm_cv_platform_type" = "Unix" ; then
1113   AC_FUNC_MMAP
1114   AC_FUNC_MMAP_FILE
1115   AC_NEED_DEV_ZERO_FOR_MMAP
1116
1117   if test "$ac_cv_func_mmap_fixed_mapped" = "no"
1118   then
1119     AC_MSG_WARN([mmap() of a fixed address required but not supported])
1120   fi
1121   if test "$ac_cv_func_mmap_file" = "no"
1122   then
1123     AC_MSG_WARN([mmap() of files required but not found])
1124   fi
1125 fi
1126
1127 dnl atomic builtins are required for threading support.
1128 AC_MSG_CHECKING(for GCC atomic builtins)
1129 AC_LINK_IFELSE(
1130   AC_LANG_SOURCE(
1131     [[int main() {
1132         volatile unsigned long val = 1;
1133         __sync_synchronize();
1134         __sync_val_compare_and_swap(&val, 1, 0);
1135         __sync_add_and_fetch(&val, 1);
1136         __sync_sub_and_fetch(&val, 1);
1137         return 0;
1138       }
1139     ]]),
1140   AC_MSG_RESULT(yes)
1141   AC_DEFINE(LLVM_MULTITHREADED, 1, Build multithreading support into LLVM),
1142   AC_MSG_RESULT(no)
1143   AC_DEFINE(LLVM_MULTITHREADED, 0, Build multithreading support into LLVM)
1144   AC_MSG_WARN([LLVM will be built thread-unsafe because atomic builtins are missing]))
1145
1146
1147 dnl===-----------------------------------------------------------------------===
1148 dnl===
1149 dnl=== SECTION 9: Additional checks, variables, etc.
1150 dnl===
1151 dnl===-----------------------------------------------------------------------===
1152
1153 dnl Handle 32-bit linux systems running a 64-bit kernel.
1154 dnl This has to come after section 4 because it invokes the compiler.
1155 if test "$llvm_cv_os_type" = "Linux" -a "$llvm_cv_target_arch" = "x86_64" ; then
1156   AC_IS_LINUX_MIXED
1157   if test "$llvm_cv_linux_mixed" = "yes"; then
1158     llvm_cv_target_arch="x86"
1159     ARCH="x86"
1160   fi
1161 fi
1162
1163 dnl Check, whether __dso_handle is present
1164 AC_CHECK_FUNCS([__dso_handle])
1165
1166 dnl See if the llvm-gcc executable can compile to LLVM assembly
1167 AC_CACHE_CHECK([whether llvm-gcc is sane],[llvm_cv_llvmgcc_sanity],
1168 [llvm_cv_llvmgcc_sanity="no"
1169 if test -x "$LLVMGCC" ; then
1170   cp /dev/null conftest.c
1171   "$LLVMGCC" -emit-llvm -S -o - conftest.c | \
1172       grep 'target datalayout =' > /dev/null 2>&1
1173   if test $? -eq 0 ; then
1174     llvm_cv_llvmgcc_sanity="yes"
1175   fi
1176   rm conftest.c
1177 fi])
1178
1179 dnl Since we have a sane llvm-gcc, identify it and its sub-tools
1180 if test "$llvm_cv_llvmgcc_sanity" = "yes" ; then
1181   AC_MSG_CHECKING([llvm-gcc component support])
1182   llvmcc1path=`"$LLVMGCC" --print-prog-name=cc1`
1183   AC_SUBST(LLVMCC1,$llvmcc1path)
1184   llvmcc1pluspath=`"$LLVMGCC" --print-prog-name=cc1plus`
1185   AC_SUBST(LLVMCC1PLUS,$llvmcc1pluspath)
1186   llvmgccdir=`echo "$llvmcc1path" | sed 's,/libexec/.*,,'`
1187   AC_SUBST(LLVMGCCDIR,$llvmgccdir)
1188   llvmgcclibexec=`echo "$llvmcc1path" | sed 's,/cc1,,'`
1189   AC_SUBST(LLVMGCCLIBEXEC,$llvmgcclibexec)
1190   llvmgccversion=[`"$LLVMGCC" -dumpversion 2>&1 | sed 's/^\([0-9.]*\).*/\1/'`]
1191   llvmgccmajvers=[`echo $llvmgccversion | sed 's/^\([0-9]\).*/\1/'`]
1192   AC_SUBST(LLVMGCC_VERSION,$llvmgccversion)
1193   AC_SUBST(LLVMGCC_MAJVERS,$llvmgccmajvers)
1194   llvmgcclangs=[`"$LLVMGCC" -v --help 2>&1 | grep '^Configured with:' | sed 's/^.*--enable-languages=\([^ ]*\).*/\1/'`]
1195   AC_SUBST(LLVMGCC_LANGS,$llvmgcclangs)
1196   AC_MSG_RESULT([ok])
1197 fi
1198
1199 dnl Propagate the shared library extension that the libltdl checks did to
1200 dnl the Makefiles so we can use it there too
1201 AC_SUBST(SHLIBEXT,$libltdl_cv_shlibext)
1202
1203 # Translate the various configuration directories and other basic
1204 # information into substitutions that will end up in Makefile.config.in
1205 # that these configured values can be used by the makefiles
1206 if test "${prefix}" = "NONE" ; then
1207   prefix="/usr/local"
1208 fi
1209 eval LLVM_PREFIX="${prefix}";
1210 eval LLVM_BINDIR="${prefix}/bin";
1211 eval LLVM_LIBDIR="${prefix}/lib";
1212 eval LLVM_DATADIR="${prefix}/share/llvm";
1213 eval LLVM_DOCSDIR="${prefix}/docs/llvm";
1214 eval LLVM_ETCDIR="${prefix}/etc/llvm";
1215 eval LLVM_INCLUDEDIR="${prefix}/include";
1216 eval LLVM_INFODIR="${prefix}/info";
1217 eval LLVM_MANDIR="${prefix}/man";
1218 LLVM_CONFIGTIME=`date`
1219 AC_SUBST(LLVM_PREFIX)
1220 AC_SUBST(LLVM_BINDIR)
1221 AC_SUBST(LLVM_LIBDIR)
1222 AC_SUBST(LLVM_DATADIR)
1223 AC_SUBST(LLVM_DOCSDIR)
1224 AC_SUBST(LLVM_ETCDIR)
1225 AC_SUBST(LLVM_INCLUDEDIR)
1226 AC_SUBST(LLVM_INFODIR)
1227 AC_SUBST(LLVM_MANDIR)
1228 AC_SUBST(LLVM_CONFIGTIME)
1229
1230 # Place the various directores into the config.h file as #defines so that we
1231 # can know about the installation paths within LLVM.
1232 AC_DEFINE_UNQUOTED(LLVM_PREFIX,"$LLVM_PREFIX",
1233                    [Installation prefix directory])
1234 AC_DEFINE_UNQUOTED(LLVM_BINDIR, "$LLVM_BINDIR",
1235                    [Installation directory for binary executables])
1236 AC_DEFINE_UNQUOTED(LLVM_LIBDIR, "$LLVM_LIBDIR",
1237                    [Installation directory for libraries])
1238 AC_DEFINE_UNQUOTED(LLVM_DATADIR, "$LLVM_DATADIR",
1239                    [Installation directory for data files])
1240 AC_DEFINE_UNQUOTED(LLVM_DOCSDIR, "$LLVM_DOCSDIR",
1241                    [Installation directory for documentation])
1242 AC_DEFINE_UNQUOTED(LLVM_ETCDIR, "$LLVM_ETCDIR",
1243                    [Installation directory for config files])
1244 AC_DEFINE_UNQUOTED(LLVM_INCLUDEDIR, "$LLVM_INCLUDEDIR",
1245                    [Installation directory for include files])
1246 AC_DEFINE_UNQUOTED(LLVM_INFODIR, "$LLVM_INFODIR",
1247                    [Installation directory for .info files])
1248 AC_DEFINE_UNQUOTED(LLVM_MANDIR, "$LLVM_MANDIR",
1249                    [Installation directory for man pages])
1250 AC_DEFINE_UNQUOTED(LLVM_CONFIGTIME, "$LLVM_CONFIGTIME",
1251                    [Time at which LLVM was configured])
1252 AC_DEFINE_UNQUOTED(LLVM_HOSTTRIPLE, "$host",
1253                    [Host triple we were built on])
1254
1255 # Determine which bindings to build.
1256 if test "$BINDINGS_TO_BUILD" = auto ; then
1257   BINDINGS_TO_BUILD=""
1258   if test "x$OCAMLC" != x -a "x$OCAMLDEP" != x ; then
1259     BINDINGS_TO_BUILD="ocaml $BINDINGS_TO_BUILD"
1260   fi
1261 fi
1262 AC_SUBST(BINDINGS_TO_BUILD,$BINDINGS_TO_BUILD)
1263
1264 # This isn't really configurey, but it avoids having to repeat the list in
1265 # other files.
1266 AC_SUBST(ALL_BINDINGS,ocaml)
1267
1268 # Do any work necessary to ensure that bindings have what they need.
1269 binding_prereqs_failed=0
1270 for a_binding in $BINDINGS_TO_BUILD ; do
1271   case "$a_binding" in
1272   ocaml)
1273     if test "x$OCAMLC" = x ; then
1274       AC_MSG_WARN([--enable-bindings=ocaml specified, but ocamlc not found. Try configure OCAMLC=/path/to/ocamlc])
1275       binding_prereqs_failed=1
1276     fi
1277     if test "x$OCAMLDEP" = x ; then
1278       AC_MSG_WARN([--enable-bindings=ocaml specified, but ocamldep not found. Try configure OCAMLDEP=/path/to/ocamldep])
1279       binding_prereqs_failed=1
1280     fi
1281     if test "x$OCAMLOPT" = x ; then
1282       AC_MSG_WARN([--enable-bindings=ocaml specified, but ocamlopt not found. Try configure OCAMLOPT=/path/to/ocamlopt])
1283       dnl ocamlopt is optional!
1284     fi
1285     if test "x$with_ocaml_libdir" != xauto ; then
1286       AC_SUBST(OCAML_LIBDIR,$with_ocaml_libdir)
1287     else
1288       ocaml_stdlib="`"$OCAMLC" -where`"
1289       if test "$LLVM_PREFIX" '<' "$ocaml_stdlib" -a "$ocaml_stdlib" '<' "$LLVM_PREFIX~"
1290       then
1291         # ocaml stdlib is beneath our prefix; use stdlib
1292         AC_SUBST(OCAML_LIBDIR,$ocaml_stdlib)
1293       else
1294         # ocaml stdlib is outside our prefix; use libdir/ocaml
1295         AC_SUBST(OCAML_LIBDIR,$LLVM_LIBDIR/ocaml)
1296       fi
1297     fi
1298     ;;
1299   esac
1300 done
1301 if test "$binding_prereqs_failed" = 1 ; then
1302   AC_MSG_ERROR([Prequisites for bindings not satisfied. Fix them or use configure --disable-bindings.])
1303 fi
1304
1305 dnl Determine whether the compiler supports -fvisibility-inlines-hidden.
1306 AC_CXX_USE_VISIBILITY_INLINES_HIDDEN
1307
1308 dnl Determine linker rpath flag
1309 if test "$llvm_cv_link_use_r" = "yes" ; then
1310   RPATH="-Wl,-R"
1311 else
1312   RPATH="-Wl,-rpath"
1313 fi
1314 AC_SUBST(RPATH)
1315
1316 dnl Determine linker rdynamic flag
1317 if test "$llvm_cv_link_use_export_dynamic" = "yes" ; then
1318   RDYNAMIC="-Wl,-export-dynamic"
1319 else
1320   RDYNAMIC=""
1321 fi
1322 AC_SUBST(RDYNAMIC)
1323
1324 dnl===-----------------------------------------------------------------------===
1325 dnl===
1326 dnl=== SECTION 10: Specify the output files and generate it
1327 dnl===
1328 dnl===-----------------------------------------------------------------------===
1329
1330 dnl Configure header files
1331 dnl WARNING: dnl If you add or remove any of the following config headers, then
1332 dnl you MUST also update Makefile.rules so that the variable FilesToConfig
1333 dnl contains the same list of files as AC_CONFIG_HEADERS below. This ensures the
1334 dnl files can be updated automatically when their *.in sources change.
1335 AC_CONFIG_HEADERS([include/llvm/Config/config.h])
1336 AC_CONFIG_FILES([include/llvm/Config/Targets.def])
1337 AC_CONFIG_FILES([include/llvm/Config/AsmPrinters.def])
1338 AC_CONFIG_FILES([include/llvm/Config/AsmParsers.def])
1339 AC_CONFIG_HEADERS([include/llvm/Support/DataTypes.h])
1340
1341 dnl Configure the makefile's configuration data
1342 AC_CONFIG_FILES([Makefile.config])
1343
1344 dnl Configure the RPM spec file for LLVM
1345 AC_CONFIG_FILES([llvm.spec])
1346
1347 dnl Configure doxygen's configuration file
1348 AC_CONFIG_FILES([docs/doxygen.cfg])
1349
1350 dnl Configure llvmc's Base plugin
1351 AC_CONFIG_FILES([tools/llvmc/plugins/Base/Base.td])
1352
1353 dnl Do the first stage of configuration for llvm-config.in.
1354 AC_CONFIG_FILES([tools/llvm-config/llvm-config.in])
1355
1356 dnl Do special configuration of Makefiles
1357 AC_CONFIG_COMMANDS([setup],,[llvm_src="${srcdir}"])
1358 AC_CONFIG_MAKEFILE(Makefile)
1359 AC_CONFIG_MAKEFILE(Makefile.common)
1360 AC_CONFIG_MAKEFILE(examples/Makefile)
1361 AC_CONFIG_MAKEFILE(lib/Makefile)
1362 AC_CONFIG_MAKEFILE(runtime/Makefile)
1363 AC_CONFIG_MAKEFILE(test/Makefile)
1364 AC_CONFIG_MAKEFILE(test/Makefile.tests)
1365 AC_CONFIG_MAKEFILE(unittests/Makefile)
1366 AC_CONFIG_MAKEFILE(tools/Makefile)
1367 AC_CONFIG_MAKEFILE(utils/Makefile)
1368 AC_CONFIG_MAKEFILE(projects/Makefile)
1369 AC_CONFIG_MAKEFILE(bindings/Makefile)
1370 AC_CONFIG_MAKEFILE(bindings/ocaml/Makefile.ocaml)
1371
1372 dnl Finally, crank out the output
1373 AC_OUTPUT