autoconf/configure.ac

   1 dnl === configure.ac --------------------------------------------------------===
   2 dnl                     The LLVM Compiler Infrastructure
   3 dnl
   4 dnl This file was developed by the LLVM research group and is distributed under
   5 dnl the University of Illinois Open Source License. See LICENSE.TXT for details.
   6 dnl
   7 dnl===-----------------------------------------------------------------------===
   8 dnl This is the LLVM configuration script. It is processed by the autoconf
   9 dnl program to produce a script named configure. This script contains the
  10 dnl configuration checks that LLVM needs in order to support multiple platforms.
  11 dnl This file is composed of 10 sections per the recommended organization of
  12 dnl autoconf input defined in the autoconf documentation. As this file evolves,
  13 dnl please keep the various types of checks within their sections. The sections
  14 dnl are as follows:
  15 dnl
  16 dnl SECTION 1: Initialization & Setup
  17 dnl SECTION 2: Architecture, target, and host checks
  18 dnl SECTION 3: Command line arguments for the configure script.
  19 dnl SECTION 4: Check for programs we need and that they are the right version
  20 dnl SECTION 5: Check for libraries
  21 dnl SECTION 6: Check for header files
  22 dnl SECTION 7: Check for types and structures
  23 dnl SECTION 8: Check for specific functions needed
  24 dnl SECTION 9: Additional checks, variables, etc.
  25 dnl SECTION 10: Specify the output files and generate it
  26 dnl
  27 dnl===-----------------------------------------------------------------------===
  28 dnl===
  29 dnl=== SECTION 1: Initialization & Setup
  30 dnl===
  31 dnl===-----------------------------------------------------------------------===
  32 dnl Initialize autoconf and define the package name, version number and
  33 dnl email address for reporting bugs.
  34 AC_INIT([[llvm]],[[1.4]],[llvmbugs@cs.uiuc.edu])
  35
  36 dnl Provide a copyright substitution and ensure the copyright notice is included
  37 dnl in the output of --version option of the generated configure script.
  38 AC_SUBST(LLVM_COPYRIGHT,["Copyright (c) 2003-2005 U University of Illinois at Urbana-Champaign."])
  39 AC_COPYRIGHT($LLVM_COPYRIGHT)
  40
  41 dnl Indicate that we require autoconf 2.59 or later. Ths is needed because we
  42 dnl use some autoconf macros only available in 2.59.
  43 AC_PREREQ(2.59)
  44
  45 dnl Verify that the source directory is valid. This makes sure that we are
  46 dnl configuring LLVM and not some other package (it validates --srcdir argument)
  47 AC_CONFIG_SRCDIR([lib/VMCore/Module.cpp])
  48
  49 dnl Place all of the extra autoconf files into the config subdirectory. Tell
  50 dnl various tools where the m4 autoconf macros are.
  51 AC_CONFIG_AUX_DIR([autoconf])
  52
  53 dnl Quit if the source directory has already been configured.
  54 dnl NOTE: This relies upon undocumented autoconf behavior.
  55 if test ${srcdir} != "." ; then
  56   if test -f ${srcdir}/include/llvm/Config/config.h ; then
  57     AC_MSG_ERROR([Already configured in ${srcdir}])
  58   fi
  59 fi
  60
  61 dnl Configure all of the projects present in our source tree. While we could
  62 dnl just AC_CONFIG_SUBDIRS on the set of directories in projects that have a
  63 dnl configure script, that usage of the AC_CONFIG_SUBDIRS macro is deprecated.
  64 dnl Instead we match on the known projects.
  65 for i in `ls ${srcdir}/projects`
  66 do
  67   if test -d ${srcdir}/projects/${i} ; then
  68     case ${i} in
  69       "CVS") ;;
  70       "sample")       AC_CONFIG_SUBDIRS([projects/sample])    ;;
  71       "Stacker")      AC_CONFIG_SUBDIRS([projects/Stacker])   ;;
  72       "llvm-test")    AC_CONFIG_SUBDIRS([projects/llvm-test]) ;;
  73       "llvm-reopt")   AC_CONFIG_SUBDIRS([projects/llvm-reopt]);;
  74       "llvm-gcc")     AC_CONFIG_SUBDIRS([projects/llvm-gcc])  ;;
  75       "Java")         AC_CONFIG_SUBDIRS([projects/Java])      ;;
  76       "llvm-tv")      AC_CONFIG_SUBDIRS([projects/llvm-tv])   ;;
  77       "llvm-fefw")    AC_CONFIG_SUBDIRS([projects/llvm-fefw]) ;;
  78       "poolalloc")    AC_CONFIG_SUBDIRS([projects/poolalloc]) ;;
  79       *)
  80         AC_MSG_WARN([Unknown project (${i}) won't be configured automatically])
  81         ;;
  82     esac
  83   fi
  84 done
  85
  86 dnl===-----------------------------------------------------------------------===
  87 dnl===
  88 dnl=== SECTION 2: Architecture, target, and host checks
  89 dnl===
  90 dnl===-----------------------------------------------------------------------===
  91
  92 dnl Check the target for which we're compiling and the host that will do the
  93 dnl compilations. This will tell us which LLVM compiler will be used for
  94 dnl compiling SSA into object code. This needs to be done early because
  95 dnl following tests depend on it.
  96 AC_CANONICAL_TARGET
  97
  98 dnl Determine the platform type and cache its value. This helps us configure
  99 dnl the System library to the correct build platform.
 100 AC_CACHE_CHECK([type of operating system we're on],
 101                [llvm_cv_os_type],
 102 [case $build in
 103   *-*-aix*)
 104     llvm_cv_os_type="AIX"
 105     llvm_cv_platform_type="Unix" ;;
 106   *-*-cygwin*)
 107     llvm_cv_os_type="Cygwin"
 108     llvm_cv_platform_type="Unix" ;;
 109   *-*-darwin*)
 110     llvm_cv_os_type="Darwin"
 111     llvm_cv_platform_type="Unix" ;;
 112   *-*-freebsd*)
 113     llvm_cv_os_type="FreeBSD"
 114     llvm_cv_platform_type="Unix" ;;
 115   *-*-interix*)
 116     llvm_cv_os_type="Interix"
 117     llvm_cv_platform_type="Unix" ;;
 118   *-*-linux*)
 119     llvm_cv_os_type="Linux"
 120     llvm_cv_platform_type="Unix" ;;
 121   *-*-solaris*)
 122     llvm_cv_os_type="SunOS"
 123     llvm_cv_platform_type="Unix" ;;
 124   *-*-win32*)
 125     llvm_cv_os_type="Win32"
 126     llvm_cv_platform_type="Win32" ;;
 127   *-*-mingw*)
 128     llvm_cv_os_type="MingW"
 129     llvm_cv_platform_type="Win32" ;;
 130   *)
 131     llvm_cv_os_type="Unknown"
 132     llvm_cv_platform_type="Unknown" ;;
 133 esac])
 134
 135 dnl Make sure we aren't attempting to configure for an unknown system
 136 if test "$llvm_cv_os_type" = "Unknown" ; then
 137   AC_MSG_ERROR([Operating system is unknown, configure can't continue])
 138 fi
 139
 140 dnl Set the "OS" Makefile variable based on the platform type so the
 141 dnl makefile can configure itself to specific build hosts
 142 AC_SUBST(OS,$llvm_cv_os_type)
 143
 144 dnl Set the "LLVM_ON_*" variables based on llvm_cvs_platform_type
 145 dnl This is used by lib/System to determine the basic kind of implementation
 146 dnl to use.
 147 case $llvm_cv_platform_type in
 148   Unix)
 149     AC_DEFINE([LLVM_ON_UNIX],[1],[Define if this is Unixish platform])
 150     ;;
 151   Win32)
 152     AC_DEFINE([LLVM_ON_WIN32],[1],[Define if this is Win32ish platform])
 153     ;;
 154 esac
 155
 156 dnl Make a link from lib/System/platform to lib/System/$llvm_cv_os_type
 157 dnl This helps the #inclusion of the system specific include files
 158 dnl for the operating system abstraction library, lib/System.
 159 AC_CONFIG_LINKS(lib/System/platform:lib/System/$llvm_cv_os_type)
 160
 161 dnl If we are targetting a Sparc machine running Solaris, pretend that it is
 162 dnl V9, since that is all that we support at the moment, and autoconf will only
 163 dnl tell us we're a sparc.
 164 case $target in
 165   sparc*-*-solaris*)  AC_SUBST(target,[[sparcv9-sun-solaris2.8]])
 166   ;;
 167 esac
 168
 169 dnl Determine what our target architecture is and configure accordingly.
 170 dnl This will allow Makefiles to make a distinction between the hardware and
 171 dnl the OS.
 172 AC_CACHE_CHECK([target architecture],[llvm_cv_target_arch],
 173 [case $target in
 174   i?86-*)                 llvm_cv_target_arch="x86" ;;
 175   amd64-* | x86_64-*)     llvm_cv_target_arch="AMD64" ;;
 176   sparc*-*)               llvm_cv_target_arch="Sparc" ;;
 177   powerpc*-*)             llvm_cv_target_arch="PowerPC" ;;
 178   *)                      llvm_cv_target_arch="Unknown" ;;
 179 esac])
 180
 181 if test "$llvm_cv_target_arch" = "Unknown" ; then
 182   AC_MSG_WARN([Configuring LLVM for an unknown target archicture])
 183 fi
 184
 185 dnl Define a substitution, ARCH, for the target architecture
 186 AC_SUBST(ARCH,$llvm_cv_target_arch)
 187
 188 dnl Check for the endianness of the target
 189 AC_C_BIGENDIAN(AC_SUBST([ENDIAN],[big]),AC_SUBST([ENDIAN],[little]))
 190
 191 dnl===-----------------------------------------------------------------------===
 192 dnl===
 193 dnl=== SECTION 3: Command line arguments for the configure script.
 194 dnl===
 195 dnl===-----------------------------------------------------------------------===
 196
 197 dnl --enable-optimized : check whether they want to do an optimized build:
 198 AC_ARG_ENABLE(optimized,
 199               AS_HELP_STRING([--enable-optimized,Compile with optimizations enabled (default is NO)]),,enableval=no)
 200 if test ${enableval} = "no" ; then
 201   AC_SUBST(ENABLE_OPTIMIZED,[[]])
 202 else
 203   AC_SUBST(ENABLE_OPTIMIZED,[[ENABLE_OPTIMIZED=1]])
 204 fi
 205
 206 dnl --enable-jit: check whether they want to enable the jit
 207 AC_ARG_ENABLE(jit,
 208   AS_HELP_STRING(--enable-jit,
 209                  [Enable Just In Time Compiling (default is YES)]),,
 210   enableval=default)
 211 if test ${enableval} = "no"
 212 then
 213   AC_SUBST(JIT,[[]])
 214 else
 215   case "$llvm_cv_target_arch" in
 216     x86)     AC_SUBST(JIT,[[TARGET_HAS_JIT=1]]) ;;
 217     Sparc)   AC_SUBST(JIT,[[TARGET_HAS_JIT=1]]) ;;
 218     PowerPC) AC_SUBST(JIT,[[TARGET_HAS_JIT=1]]) ;;
 219     AMD64)   AC_SUBST(JIT,[[]]) ;;
 220     *)       AC_SUBST(JIT,[[]]) ;;
 221   esac
 222 fi
 223
 224 dnl Allow enablement of doxygen generated documentation
 225 AC_ARG_ENABLE(doxygen,
 226               AS_HELP_STRING([--enable-doxygen],
 227                              [Build doxygen documentation (default is NO)]),,
 228                              enableval=default)
 229 case "$enableval" in
 230   yes) AC_SUBST(ENABLE_DOXYGEN,[1]) ;;
 231   no)  AC_SUBST(ENABLE_DOXYGEN,[0]) ;;
 232   default) AC_SUBST(ENABLE_DOXYGEN,[0]) ;;
 233   *) AC_MSG_ERROR([Invalid setting for --enable-doxygen. Use "yes" or "no"]) ;;
 234 esac
 235
 236 dnl===-----------------------------------------------------------------------===
 237 dnl===
 238 dnl=== SECTION 4: Check for programs we need and that they are the right version
 239 dnl===
 240 dnl===-----------------------------------------------------------------------===
 241
 242 dnl Check for compilation tools
 243 AC_PROG_CPP
 244 AC_PROG_CC(gcc)
 245 AC_PROG_CXX(g++)
 246 AC_PROG_FLEX
 247 AC_PROG_BISON
 248
 249 dnl Check for the tools that the makefiles require
 250 AC_CHECK_GNU_MAKE
 251 AC_PROG_LN_S
 252 AC_PATH_PROG(CMP, [cmp], [cmp])
 253 AC_PATH_PROG(CP, [cp], [cp])
 254 AC_PATH_PROG(DATE, [date], [date])
 255 AC_PATH_PROG(FIND, [find], [find])
 256 AC_PATH_PROG(GREP, [grep], [grep])
 257 AC_PATH_PROG(LLVMGCC, [llvm-gcc], [llvm-gcc])
 258 AC_PATH_PROG(LLVMGXX, [llvm-g++], [llvm-g++])
 259 AC_PATH_PROG(MKDIR,[mkdir],[mkdir])
 260 AC_PATH_PROG(MV,   [mv],   [mv])
 261 AC_PATH_PROG(PAX,  [pax],  [pax])
 262 AC_PROG_RANLIB
 263 AC_PATH_PROG(RM,   [rm],   [rm])
 264 AC_PATH_PROG(SED,  [sed],  [sed])
 265 AC_PATH_PROG(TAR,  [tar],  [gtar])
 266
 267 dnl Find the install program
 268 AC_PROG_INSTALL
 269
 270 dnl Checks for documentation and testing tools that we can do without. If these
 271 dnl are not found then they are set to "true" which always succeeds but does
 272 dnl nothing. This just lets the build output show that we could have done
 273 dnl something if the tool was available.
 274 AC_PATH_PROG(BZIP2,[bzip2],[true bzip2])
 275 AC_PATH_PROG(DOT,[dot],[true dot])
 276 AC_PATH_PROG(DOXYGEN,[doxygen],[true doxygen])
 277 AC_PATH_PROG(ETAGS,[etags],[true etags])
 278 AC_PATH_PROG(GROFF,[groff],[true groff])
 279 AC_PATH_PROG(GZIP,[gzip],[true gzip])
 280 AC_PATH_PROG(POD2HTML,[pod2html],[true pod2html])
 281 AC_PATH_PROG(POD2MAN,[pod2man],[true pod2man])
 282 AC_PATH_PROG(RUNTEST,[runtest],[true runtest])
 283 DJ_AC_PATH_TCLSH
 284 AC_PATH_PROG(ZIP,[zip],[true zip])
 285
 286 dnl Determine if the linker supports the -R option.
 287 AC_LINK_USE_R
 288
 289 dnl Check for libtool and the library that has dlopen function (which must come
 290 dnl before the AC_PROG_LIBTOOL check in order to enable dlopening libraries with
 291 dnl libtool).
 292 AC_LIBTOOL_DLOPEN
 293 AC_LIB_LTDL
 294 AC_PROG_LIBTOOL
 295
 296 dnl Check if we know how to tell etags we are using C++:
 297 etags_version=`$ETAGS --version 2>&1`
 298 case "$etags_version" in
 299         *[Ee]xuberant*) ETAGSFLAGS="--language-force=c++" ;;
 300         *GNU\ Emacs*) ETAGSFLAGS="-l c++" ;;
 301         *) ETAGSFLAGS="" ;;
 302 esac
 303 AC_SUBST(ETAGSFLAGS,$ETAGSFLAGS)
 304
 305 AC_MSG_CHECKING([tool compatibility])
 306
 307 dnl Ensure that compilation tools are GCC or a GNU compatible compiler such as
 308 dnl ICC; we use GCC specific options in the makefiles so the compiler needs
 309 dnl to support those options.
 310 dnl "icc" emits gcc signatures
 311 dnl "icc -no-gcc" emits no gcc signature BUT is still compatible
 312 ICC=no
 313 IXX=no
 314 case $CC in
 315   icc*|icpc*)
 316     ICC=yes
 317     IXX=yes
 318     ;;
 319    *)
 320     ;;
 321 esac
 322
 323 if test "$GCC" != "yes" && test "$ICC" != "yes"
 324 then
 325   AC_MSG_ERROR([gcc|icc required but not found])
 326 fi
 327
 328 dnl Ensure that compilation tools are GCC; we use GCC specific extensions
 329 if test "$GXX" != "yes" && test "$IXX" != "yes"
 330 then
 331   AC_MSG_ERROR([g++|icc required but not found])
 332 fi
 333
 334 dnl Verify that GCC is version 3.0 or higher
 335 if test "$GCC" = "yes"
 336 then
 337   gccmajor=`$CC --version | head -n 1 | awk '{print $NF;}' | cut -d. -f1`
 338   if test "$gccmajor" -lt "3"
 339   then
 340     AC_MSG_ERROR([gcc 3.x required, but you have a lower version])
 341   fi
 342 fi
 343
 344 dnl Check for GNU Make.  We use its extensions, so don't build without it
 345 if test -z "$llvm_cv_gnu_make_command"
 346 then
 347   AC_MSG_ERROR([GNU Make required but not found])
 348 fi
 349
 350 dnl Tool compatibility is okay if we make it here.
 351 AC_MSG_RESULT([ok])
 352
 353 dnl===-----------------------------------------------------------------------===
 354 dnl===
 355 dnl=== SECTION 5: Check for libraries
 356 dnl===
 357 dnl===-----------------------------------------------------------------------===
 358
 359 dnl libelf is for sparc only; we can ignore it if we don't have it
 360 AC_CHECK_LIB(elf, elf_begin)
 361
 362 dnl lt_dlopen may be required for plugin support.
 363 AC_SEARCH_LIBS(lt_dlopen,ltdl,AC_DEFINE([HAVE_LT_DLOPEN],[1],
 364               [Define if lt_dlopen() is available on this platform]),
 365               AC_MSG_WARN([lt_dlopen() not found - plugin support might
 366                            not be available]))
 367
 368 dnl dlopen() is required for plugin support.
 369 AC_SEARCH_LIBS(dlopen,dl,AC_DEFINE([HAVE_DLOPEN],[1],
 370                [Define if dlopen() is available on this platform.]),
 371                AC_MSG_WARN([dlopen() not found - disabling plugin support]))
 372
 373 dnl mallinfo is optional; the code can compile (minus features) without it
 374 AC_SEARCH_LIBS(mallinfo,malloc,AC_DEFINE([HAVE_MALLINFO],[1],
 375                [Define if mallinfo() is available on this platform.]))
 376
 377 dnl pthread locking functions are optional - but llvm will not be thread-safe
 378 dnl without locks.
 379 AC_SEARCH_LIBS(pthread_mutex_lock,pthread,
 380                AC_DEFINE([HAVE_PTHREAD_MUTEX_LOCK],[1],
 381                          [Have pthread_mutex_lock]))
 382
 383 dnl===-----------------------------------------------------------------------===
 384 dnl===
 385 dnl=== SECTION 6: Check for header files
 386 dnl===
 387 dnl===-----------------------------------------------------------------------===
 388
 389 dnl We don't check for ancient stuff or things that are guaranteed to be there
 390 dnl by the C++ standard. We always use the <cfoo> versions of <foo.h> C headers.
 391 AC_HEADER_STDC
 392
 393 dnl However, we do need some system specific header files. Generally we're
 394 dnl looking for POSIX headers.
 395 AC_HEADER_SYS_WAIT
 396 AC_CHECK_HEADERS([sys/time.h sys/mman.h sys/resource.h sys/time.h sys/types.h])
 397 AC_CHECK_HEADERS([dlfcn.h execinfo.h fcntl.h limits.h link.h])
 398 AC_CHECK_HEADERS([malloc.h unistd.h windows.h])
 399 AC_HEADER_TIME
 400 AC_HEADER_MMAP_ANONYMOUS
 401
 402 dnl Check for things that need to be included in public headers, and so
 403 dnl for which we may not have access to a HAVE_* preprocessor #define.
 404 dnl (primarily used in DataTypes.h)
 405 AC_CHECK_HEADERS([inttypes.h stdint.h])
 406
 407 dnl===-----------------------------------------------------------------------===
 408 dnl===
 409 dnl=== SECTION 7: Check for types and structures
 410 dnl===
 411 dnl===-----------------------------------------------------------------------===
 412
 413 AC_TYPE_PID_T
 414 AC_TYPE_SIZE_T
 415 AC_TYPE_SIGNAL
 416 AC_STRUCT_TM
 417 AC_CHECK_TYPES([int64_t],,AC_MSG_ERROR([Type int64_t required but not found]))
 418 AC_CHECK_TYPES([uint64_t],,
 419          AC_CHECK_TYPES([u_int64_t],,
 420          AC_MSG_ERROR([Type uint64_t or u_int64_t required but not found])))
 421
 422 dnl===-----------------------------------------------------------------------===
 423 dnl===
 424 dnl=== SECTION 8: Check for specific functions needed
 425 dnl===
 426 dnl===-----------------------------------------------------------------------===
 427
 428 AC_CHECK_FUNCS([backtrace getcwd getpagesize getrusage gettimeofday isatty ])
 429 AC_CHECK_FUNCS([mkdtemp mkstemp mktemp ])
 430 AC_CHECK_FUNCS([realpath strdup strtoq strtoll sysconf ])
 431 AC_C_PRINTF_A
 432 AC_FUNC_ALLOCA
 433 AC_FUNC_RAND48
 434
 435 dnl Check for variations in the Standard C++ library and STL. These macros are
 436 dnl provided by LLVM in the autoconf/m4 directory.
 437 AC_CXX_HAVE_HASH_MAP
 438 AC_CXX_HAVE_HASH_SET
 439 AC_CXX_HAVE_STD_ITERATOR
 440 AC_CXX_HAVE_BI_ITERATOR
 441 AC_CXX_HAVE_FWD_ITERATOR
 442 AC_FUNC_ISNAN
 443 AC_FUNC_ISINF
 444
 445 dnl Check for mmap and mprotect support. We need both to do the JIT and for
 446 dnl bytecode loading, etc.
 447 AC_FUNC_MMAP
 448 AC_FUNC_MMAP_FILE
 449 AC_CHECK_FUNC(mprotect,,
 450               AC_MSG_ERROR([Function mprotect() required but not found]))
 451
 452 if test "$ac_cv_func_mmap_fixed_mapped" = "no"
 453 then
 454   AC_MSG_WARN([mmap() required but not found])
 455 fi
 456 if test "$ac_cv_func_mmap_file" = "no"
 457 then
 458   AC_MSG_WARN([mmap() of files required but not found])
 459 fi
 460
 461 dnl===-----------------------------------------------------------------------===
 462 dnl===
 463 dnl=== SECTION 9: Additional checks, variables, etc.
 464 dnl===
 465 dnl===-----------------------------------------------------------------------===
 466
 467 dnl See if the llvm-gcc executable can compile to LLVM assembly
 468 AC_CACHE_CHECK([whether llvm-gcc is sane],[llvm_cv_llvmgcc_sanity],
 469 [llvm_cv_llvmgcc_sanity="no"
 470 if test -x "$LLVMGCC" ; then
 471   cp /dev/null conftest.c
 472   "$LLVMGCC" -S -o - conftest.c | grep implementation > /dev/null 2>&1
 473   if test $? -eq 0 ; then
 474     llvm_cv_llvmgcc_sanity="yes"
 475   fi
 476   rm conftest.c
 477 fi])
 478
 479 dnl Since we have a sane llvm-gcc, identify it and its sub-tools
 480 if test "$llvm_cv_llvmgcc_sanity" = "yes" ; then
 481   llvmcc1path=`"$LLVMGCC" --print-prog-name=cc1`
 482   AC_SUBST(LLVMCC1,$llvmcc1path)
 483   llvmcc1pluspath=`"$LLVMGCC" --print-prog-name=cc1plus`
 484   AC_SUBST(LLVMCC1PLUS,$llvmcc1pluspath)
 485   llvmgccdir=`echo "$llvmcc1path" | sed 's,/libexec/.*,,'`
 486   AC_SUBST(LLVMGCCDIR,$llvmgccdir)
 487 fi
 488
 489 dnl Propagate the shared library extension that the libltdl checks did to
 490 dnl the Makefiles so we can use it there too
 491 AC_SUBST(SHLIBEXT,$libltdl_cv_shlibext)
 492
 493 # Translate the various configuration directories and other basic
 494 # information into substitutions that will end up in Makefile.config.in
 495 # that these configured values can be used by the makefiles
 496 eval LLVM_PREFIX="${prefix}";
 497 eval LLVM_BINDIR="${prefix}/bin";
 498 eval LLVM_LIBDIR="${prefix}/lib";
 499 eval LLVM_DATADIR="${prefix}/share/llvm";
 500 eval LLVM_DOCSDIR="${prefix}/docs/llvm";
 501 eval LLVM_ETCDIR="${prefix}/etc/llvm";
 502 eval LLVM_INCLUDEDIR="${prefix}/include";
 503 eval LLVM_INFODIR="${prefix}/info";
 504 eval LLVM_MANDIR="${prefix}/man";
 505 LLVM_CONFIGTIME=`date`
 506 AC_SUBST(LLVM_PREFIX)
 507 AC_SUBST(LLVM_BINDIR)
 508 AC_SUBST(LLVM_LIBDIR)
 509 AC_SUBST(LLVM_DATADIR)
 510 AC_SUBST(LLVM_DOCSDIR)
 511 AC_SUBST(LLVM_ETCDIR)
 512 AC_SUBST(LLVM_INCLUDEDIR)
 513 AC_SUBST(LLVM_INFODIR)
 514 AC_SUBST(LLVM_MANDIR)
 515 AC_SUBST(LLVM_CONFIGTIME)
 516
 517 # Place the various directores into the config.h file as #defines so that we
 518 # can know about the installation paths within LLVM.
 519 AC_DEFINE_UNQUOTED(LLVM_PREFIX,"$LLVM_PREFIX",
 520                    [Installation prefix directory])
 521 AC_DEFINE_UNQUOTED(LLVM_BINDIR, "$LLVM_BINDIR",
 522                    [Installation directory for binary executables])
 523 AC_DEFINE_UNQUOTED(LLVM_LIBDIR, "$LLVM_LIBDIR",
 524                    [Installation directory for libraries])
 525 AC_DEFINE_UNQUOTED(LLVM_DATADIR, "$LLVM_DATADIR",
 526                    [Installation directory for data files])
 527 AC_DEFINE_UNQUOTED(LLVM_DATADIR, "$LLVM_DOCSDIR",
 528                    [Installation directory for documentation])
 529 AC_DEFINE_UNQUOTED(LLVM_ETCDIR, "$LLVM_ETCDIR",
 530                    [Installation directory for config files])
 531 AC_DEFINE_UNQUOTED(LLVM_INCLUDEDIR, "$LLVM_INCLUDEDIR",
 532                    [Installation directory for include files])
 533 AC_DEFINE_UNQUOTED(LLVM_INFODIR, "$LLVM_INFODIR",
 534                    [Installation directory for .info files])
 535 AC_DEFINE_UNQUOTED(LLVM_MANDIR, "$LLVM_MANDIR",
 536                    [Installation directory for man pages])
 537 AC_DEFINE_UNQUOTED(LLVM_CONFIGTIME, "$LLVM_CONFIGTIME",
 538                    [Time at which LLVM was configured])
 539
 540 dnl===-----------------------------------------------------------------------===
 541 dnl===
 542 dnl=== SECTION 10: Specify the output files and generate it
 543 dnl===
 544 dnl===-----------------------------------------------------------------------===
 545
 546 dnl Configure header files
 547 AC_CONFIG_HEADERS(include/llvm/Config/config.h)
 548
 549 AC_CONFIG_HEADERS([include/llvm/Support/DataTypes.h])
 550 AC_CONFIG_HEADERS([include/llvm/ADT/hash_map])
 551 AC_CONFIG_HEADERS([include/llvm/ADT/hash_set])
 552 AC_CONFIG_HEADERS([include/llvm/Support/ThreadSupport.h])
 553 AC_CONFIG_HEADERS([include/llvm/ADT/iterator])
 554
 555 dnl Configure the makefile's configuration data
 556 AC_CONFIG_FILES([Makefile.config])
 557
 558 dnl Configure llvmc's configuration files
 559 AC_CONFIG_FILES([tools/llvmc/st tools/llvmc/cpp tools/llvmc/ll tools/llvmc/c])
 560
 561 dnl Configure doxygen's configuration file
 562 AC_CONFIG_FILES([docs/doxygen.cfg])
 563
 564 dnl Do special configuration of Makefiles
 565 AC_CONFIG_MAKEFILE(Makefile)
 566 AC_CONFIG_MAKEFILE(Makefile.common)
 567 AC_CONFIG_MAKEFILE(examples/Makefile)
 568 AC_CONFIG_MAKEFILE(lib/Makefile)
 569 AC_CONFIG_MAKEFILE(runtime/Makefile)
 570 AC_CONFIG_MAKEFILE(test/Makefile)
 571 AC_CONFIG_MAKEFILE(test/Makefile.tests)
 572 AC_CONFIG_MAKEFILE(tools/Makefile)
 573 AC_CONFIG_MAKEFILE(utils/Makefile)
 574 AC_CONFIG_MAKEFILE(projects/Makefile)
 575
 576 dnl Finally, crank out the output
 577 AC_OUTPUT
 578
 579 dnl Warn loudly if llvm-gcc was not obviously working
 580 if test "$llvm_cv_llvmgcc_sanity" = "no" ; then
 581  AC_MSG_WARN([***** llvm-gcc/llvm-g++ was not found, or does not appear to be ])
 582  AC_MSG_WARN([***** working. Please make sure you have llvmgcc and llvmg++ in])
 583  AC_MSG_WARN([***** your path before configuring LLVM. The runtime libraries])
 584  AC_MSG_WARN([***** (llvm/runtime) will not be built but you should be able to])
 585  AC_MSG_WARN([***** build the llvm tools.])
 586 fi