autoconf/configure.ac

   1 dnl === configure.ac --------------------------------------------------------===
   2 dnl                     The LLVM Compiler Infrastructure
   3 dnl
   4 dnl This file was developed by the LLVM research group and is distributed under
   5 dnl the University of Illinois Open Source License. See LICENSE.TXT for details.
   6 dnl
   7 dnl===-----------------------------------------------------------------------===
   8 dnl This is the LLVM configuration script. It is processed by the autoconf
   9 dnl program to produce a script named configure. This script contains the
  10 dnl configuration checks that LLVM needs in order to support multiple platforms.
  11 dnl This file is composed of 10 sections per the recommended organization of
  12 dnl autoconf input defined in the autoconf documentation. As this file evolves,
  13 dnl please keep the various types of checks within their sections. The sections
  14 dnl are as follows:
  15 dnl
  16 dnl SECTION 1: Initialization & Setup
  17 dnl SECTION 2: Architecture, target, and host checks
  18 dnl SECTION 3: Command line arguments for the configure script.
  19 dnl SECTION 4: Check for programs we need and that they are the right version
  20 dnl SECTION 5: Check for libraries
  21 dnl SECTION 6: Check for header files
  22 dnl SECTION 7: Check for types and structures
  23 dnl SECTION 8: Check for specific functions needed
  24 dnl SECTION 9: Additional checks, variables, etc.
  25 dnl SECTION 10: Specify the output files and generate it
  26 dnl
  27 dnl===-----------------------------------------------------------------------===
  28 dnl===
  29 dnl=== SECTION 1: Initialization & Setup
  30 dnl===
  31 dnl===-----------------------------------------------------------------------===
  32 dnl Initialize autoconf and define the package name, version number and
  33 dnl email address for reporting bugs.
  34 AC_INIT([[llvm]],[[1.8cvs]],[llvmbugs@cs.uiuc.edu])
  35
  36 dnl Provide a copyright substitution and ensure the copyright notice is included
  37 dnl in the output of --version option of the generated configure script.
  38 AC_SUBST(LLVM_COPYRIGHT,["Copyright (c) 2003-2005 University of Illinois at Urbana-Champaign."])
  39 AC_COPYRIGHT([Copyright (c) 2003-2005 University of Illinois at Urbana-Champaign.])
  40
  41 dnl Indicate that we require autoconf 2.59 or later. Ths is needed because we
  42 dnl use some autoconf macros only available in 2.59.
  43 AC_PREREQ(2.59)
  44
  45 dnl Verify that the source directory is valid. This makes sure that we are
  46 dnl configuring LLVM and not some other package (it validates --srcdir argument)
  47 AC_CONFIG_SRCDIR([lib/VMCore/Module.cpp])
  48
  49 dnl Place all of the extra autoconf files into the config subdirectory. Tell
  50 dnl various tools where the m4 autoconf macros are.
  51 AC_CONFIG_AUX_DIR([autoconf])
  52
  53 dnl Quit if the source directory has already been configured.
  54 dnl NOTE: This relies upon undocumented autoconf behavior.
  55 if test ${srcdir} != "." ; then
  56   if test -f ${srcdir}/include/llvm/Config/config.h ; then
  57     AC_MSG_ERROR([Already configured in ${srcdir}])
  58   fi
  59 fi
  60
  61 dnl Configure all of the projects present in our source tree. While we could
  62 dnl just AC_CONFIG_SUBDIRS on the set of directories in projects that have a
  63 dnl configure script, that usage of the AC_CONFIG_SUBDIRS macro is deprecated.
  64 dnl Instead we match on the known projects.
  65 for i in `ls ${srcdir}/projects`
  66 do
  67   if test -d ${srcdir}/projects/${i} ; then
  68     case ${i} in
  69       "CVS") ;;
  70       "sample")       AC_CONFIG_SUBDIRS([projects/sample])    ;;
  71       "Stacker")      AC_CONFIG_SUBDIRS([projects/Stacker])   ;;
  72       "llvm-test")    AC_CONFIG_SUBDIRS([projects/llvm-test]) ;;
  73       "llvm-reopt")   AC_CONFIG_SUBDIRS([projects/llvm-reopt]);;
  74       "llvm-gcc")     AC_CONFIG_SUBDIRS([projects/llvm-gcc])  ;;
  75       "llvm-java")    AC_CONFIG_SUBDIRS([projects/llvm-java]) ;;
  76       "llvm-tv")      AC_CONFIG_SUBDIRS([projects/llvm-tv])   ;;
  77       "llvm-poolalloc") AC_CONFIG_SUBDIRS([projects/llvm-poolalloc]) ;;
  78       "llvm-kernel")  AC_CONFIG_SUBDIRS([projects/llvm-kernel]) ;;
  79       *)
  80         AC_MSG_WARN([Unknown project (${i}) won't be configured automatically])
  81         ;;
  82     esac
  83   fi
  84 done
  85
  86 dnl===-----------------------------------------------------------------------===
  87 dnl===
  88 dnl=== SECTION 2: Architecture, target, and host checks
  89 dnl===
  90 dnl===-----------------------------------------------------------------------===
  91
  92 dnl Check the target for which we're compiling and the host that will do the
  93 dnl compilations. This will tell us which LLVM compiler will be used for
  94 dnl compiling SSA into object code. This needs to be done early because
  95 dnl following tests depend on it.
  96 AC_CANONICAL_TARGET
  97
  98 dnl Determine the platform type and cache its value. This helps us configure
  99 dnl the System library to the correct build platform.
 100 AC_CACHE_CHECK([type of operating system we're on],
 101                [llvm_cv_os_type],
 102 [case $build in
 103   *-*-aix*)
 104     llvm_cv_os_type="AIX"
 105     llvm_cv_platform_type="Unix" ;;
 106   *-*-cygwin*)
 107     llvm_cv_os_type="Cygwin"
 108     llvm_cv_platform_type="Unix" ;;
 109   *-*-darwin*)
 110     llvm_cv_os_type="Darwin"
 111     llvm_cv_platform_type="Unix" ;;
 112   *-*-freebsd*)
 113     llvm_cv_os_type="FreeBSD"
 114     llvm_cv_platform_type="Unix" ;;
 115   *-*-hpux*)
 116     llvm_cv_os_type="HP-UX"
 117     llvm_cv_platform_type="Unix" ;;
 118   *-*-interix*)
 119     llvm_cv_os_type="Interix"
 120     llvm_cv_platform_type="Unix" ;;
 121   *-*-linux*)
 122     llvm_cv_os_type="Linux"
 123     llvm_cv_platform_type="Unix" ;;
 124   *-*-solaris*)
 125     llvm_cv_os_type="SunOS"
 126     llvm_cv_platform_type="Unix" ;;
 127   *-*-win32*)
 128     llvm_cv_os_type="Win32"
 129     llvm_cv_platform_type="Win32" ;;
 130   *-*-mingw*)
 131     llvm_cv_os_type="MingW"
 132     llvm_cv_platform_type="Win32" ;;
 133   *)
 134     llvm_cv_os_type="Unknown"
 135     llvm_cv_platform_type="Unknown" ;;
 136 esac])
 137
 138 dnl Make sure we aren't attempting to configure for an unknown system
 139 if test "$llvm_cv_os_type" = "Unknown" ; then
 140   AC_MSG_ERROR([Operating system is unknown, configure can't continue])
 141 fi
 142
 143 dnl Set the "OS" Makefile variable based on the platform type so the
 144 dnl makefile can configure itself to specific build hosts
 145 AC_SUBST(OS,$llvm_cv_os_type)
 146
 147 dnl Set the "LLVM_ON_*" variables based on llvm_cvs_platform_type
 148 dnl This is used by lib/System to determine the basic kind of implementation
 149 dnl to use.
 150 case $llvm_cv_platform_type in
 151   Unix)
 152     AC_DEFINE([LLVM_ON_UNIX],[1],[Define if this is Unixish platform])
 153     AC_SUBST(LLVM_ON_UNIX,[1])
 154     AC_SUBST(LLVM_ON_WIN32,[0])
 155     ;;
 156   Win32)
 157     AC_DEFINE([LLVM_ON_WIN32],[1],[Define if this is Win32ish platform])
 158     AC_SUBST(LLVM_ON_UNIX,[0])
 159     AC_SUBST(LLVM_ON_WIN32,[1])
 160     ;;
 161 esac
 162
 163 dnl Determine what our target architecture is and configure accordingly.
 164 dnl This will allow Makefiles to make a distinction between the hardware and
 165 dnl the OS.
 166 AC_CACHE_CHECK([target architecture],[llvm_cv_target_arch],
 167 [case $target in
 168   i?86-*)                 llvm_cv_target_arch="x86" ;;
 169   amd64-* | x86_64-*)     llvm_cv_target_arch="x86_64" ;;
 170   sparc*-*)               llvm_cv_target_arch="Sparc" ;;
 171   powerpc*-*)             llvm_cv_target_arch="PowerPC" ;;
 172   alpha*-*)               llvm_cv_target_arch="Alpha" ;;
 173   ia64-*)                 llvm_cv_target_arch="IA64" ;;
 174   *)                      llvm_cv_target_arch="Unknown" ;;
 175 esac])
 176
 177 if test "$llvm_cv_target_arch" = "Unknown" ; then
 178   AC_MSG_WARN([Configuring LLVM for an unknown target archicture])
 179 fi
 180
 181 dnl Define a substitution, ARCH, for the target architecture
 182 AC_SUBST(ARCH,$llvm_cv_target_arch)
 183
 184 dnl Check for the endianness of the target
 185 AC_C_BIGENDIAN(AC_SUBST([ENDIAN],[big]),AC_SUBST([ENDIAN],[little]))
 186
 187 dnl Check to see if there's a "CVS" directory indicating that this build is
 188 dnl being done from a CVS checkout. This sets up several defaults for the
 189 dnl command line switches. When we build with a CVS directory, we get a
 190 dnl debug with assertions turned on. Without, we assume a source release and we
 191 dnl get an optimized build without assertions. See --enable-optimized and
 192 dnl --enable-assertions below
 193 if test -d "CVS" -o -d "${srcdir}/CVS"; then
 194   cvsbuild="yes"
 195   optimize="no"
 196   AC_SUBST(CVSBUILD,[[CVSBUILD=1]])
 197 else
 198   cvsbuild="no"
 199   optimize="yes"
 200 fi
 201
 202 dnl===-----------------------------------------------------------------------===
 203 dnl===
 204 dnl=== SECTION 3: Command line arguments for the configure script.
 205 dnl===
 206 dnl===-----------------------------------------------------------------------===
 207
 208 dnl --enable-optimized : check whether they want to do an optimized build:
 209 AC_ARG_ENABLE(optimized, AS_HELP_STRING(
 210  [--enable-optimized,Compile with optimizations enabled (default is NO)]),,enableval=$optimize)
 211 if test ${enableval} = "no" ; then
 212   AC_SUBST(ENABLE_OPTIMIZED,[[]])
 213 else
 214   AC_SUBST(ENABLE_OPTIMIZED,[[ENABLE_OPTIMIZED=1]])
 215 fi
 216
 217 dnl --enable-assertions : check whether they want to turn on assertions or not:
 218 AC_ARG_ENABLE(assertions,AS_HELP_STRING(
 219   [--enable-assertions,Compile with assertion checks enabled (default is YES)]),, enableval="yes")
 220 if test ${enableval} = "yes" ; then
 221   AC_SUBST(DISABLE_ASSERTIONS,[[]])
 222 else
 223   AC_SUBST(DISABLE_ASSERTIONS,[[DISABLE_ASSERTIONS=1]])
 224 fi
 225
 226 dnl --enable-debug-runtime : should runtime libraries have debug symbols?
 227 AC_ARG_ENABLE(debug-runtime,
 228    AS_HELP_STRING([--enable-debug-runtime,Build runtime libs with debug symbols (default is NO)]),,enableval=no)
 229 if test ${enableval} = "no" ; then
 230   AC_SUBST(DEBUG_RUNTIME,[[]])
 231 else
 232   AC_SUBST(DEBUG_RUNTIME,[[DEBUG_RUNTIME=1]])
 233 fi
 234
 235 dnl --enable-jit: check whether they want to enable the jit
 236 AC_ARG_ENABLE(jit,
 237   AS_HELP_STRING(--enable-jit,
 238                  [Enable Just In Time Compiling (default is YES)]),,
 239   enableval=default)
 240 if test ${enableval} = "no"
 241 then
 242   AC_SUBST(JIT,[[]])
 243 else
 244   case "$llvm_cv_target_arch" in
 245     x86)     AC_SUBST(TARGET_HAS_JIT,1) ;;
 246     Sparc)   AC_SUBST(TARGET_HAS_JIT,1) ;;
 247     PowerPC) AC_SUBST(TARGET_HAS_JIT,1) ;;
 248     x86_64)  AC_SUBST(TARGET_HAS_JIT,0) ;;
 249     Alpha)   AC_SUBST(TARGET_HAS_JIT,1) ;;
 250     IA64)    AC_SUBST(TARGET_HAS_JIT,0) ;;
 251     *)       AC_SUBST(TARGET_HAS_JIT,0) ;;
 252   esac
 253 fi
 254
 255 dnl Allow enablement of doxygen generated documentation
 256 AC_ARG_ENABLE(doxygen,
 257               AS_HELP_STRING([--enable-doxygen],
 258                              [Build doxygen documentation (default is NO)]),,
 259                              enableval=default)
 260 case "$enableval" in
 261   yes) AC_SUBST(ENABLE_DOXYGEN,[1]) ;;
 262   no)  AC_SUBST(ENABLE_DOXYGEN,[0]) ;;
 263   default) AC_SUBST(ENABLE_DOXYGEN,[0]) ;;
 264   *) AC_MSG_ERROR([Invalid setting for --enable-doxygen. Use "yes" or "no"]) ;;
 265 esac
 266
 267 dnl Allow disablement of threads
 268 AC_ARG_ENABLE(threads,
 269               AS_HELP_STRING([--enable-threads],
 270                              [Use threads if available (default is YES)]),,
 271                              enableval=yes)
 272 case "$enableval" in
 273   yes) AC_SUBST(ENABLE_THREADS,[1]) ;;
 274   no)  AC_SUBST(ENABLE_THREADS,[0]) ;;
 275   *) AC_MSG_ERROR([Invalid setting for --enable-threads. Use "yes" or "no"]) ;;
 276 esac
 277 AC_DEFINE_UNQUOTED([ENABLE_THREADS],$ENABLE_THREADS,[Define if threads enabled])
 278
 279 dnl Allow specific targets to be specified for building (or not)
 280 TARGETS_TO_BUILD=""
 281 AC_ARG_ENABLE([targets],AS_HELP_STRING([--enable-target],
 282     [Build specific host targets: all,host-only,{target-name} (default=all)]),,
 283     enableval=all)
 284 case "$enableval" in
 285   all) TARGETS_TO_BUILD="X86 Sparc SparcV9 PowerPC Alpha IA64" ;;
 286   host-only)
 287     case "$llvm_cv_target_arch" in
 288       x86)     TARGETS_TO_BUILD="X86" ;;
 289       x86_64)  TARGETS_TO_BUILD="X86" ;;
 290       Sparc)   TARGETS_TO_BUILD="Sparc SparcV9" ;;
 291       PowerPC) TARGETS_TO_BUILD="PowerPC" ;;
 292       Alpha)   TARGETS_TO_BUILD="Alpha" ;;
 293       IA64)    TARGETS_TO_BUILD="IA64" ;;
 294       *)       AC_MSG_ERROR([Can not set target to build]) ;;
 295     esac
 296     ;;
 297   *)for a_target in `echo $enableval|sed -e 's/,/ /g' ` ; do
 298       case "$a_target" in
 299         x86)     TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 300         x86_64)  TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 301         sparc)   TARGETS_TO_BUILD="Sparc SparcV9 $TARGETS_TO_BUILD" ;;
 302         powerpc) TARGETS_TO_BUILD="PowerPC $TARGETS_TO_BUILD" ;;
 303         alpha)   TARGETS_TO_BUILD="Alpha $TARGETS_TO_BUILD" ;;
 304         ia64)    TARGETS_TO_BUILD="IA64 $TARGETS_TO_BUILD" ;;
 305         *) AC_MSG_ERROR([Unrecognized target $a_target]) ;;
 306       esac
 307   done
 308   ;;
 309 esac
 310 TARGETS_TO_BUILD="CBackend $TARGETS_TO_BUILD"
 311 AC_SUBST(TARGETS_TO_BUILD,$TARGETS_TO_BUILD)
 312
 313 dnl Allow a specific llvm-gcc/llvm-g++ pair to be used with this LLVM config.
 314 AC_ARG_WITH(llvmgccdir,
 315   AS_HELP_STRING([--with-llvmgccdir],
 316     [Specify location of llvm-gcc install dir (default searches PATH)]),,
 317     withval=default)
 318 case "$withval" in
 319   default) WITH_LLVMGCCDIR=default ;;
 320   /*)      WITH_LLVMGCCDIR=$withval ;;
 321   *) AC_MSG_ERROR([Invalid path for --with-llvmgccdir. Provide full path]) ;;
 322 esac
 323
 324
 325 dnl===-----------------------------------------------------------------------===
 326 dnl===
 327 dnl=== SECTION 4: Check for programs we need and that they are the right version
 328 dnl===
 329 dnl===-----------------------------------------------------------------------===
 330
 331 dnl Check for compilation tools
 332 AC_PROG_CPP
 333 AC_PROG_CC(gcc)
 334 AC_PROG_CXX(g++)
 335 AC_PROG_FLEX
 336 AC_PROG_BISON
 337
 338 dnl Check for the tools that the makefiles require
 339 AC_CHECK_GNU_MAKE
 340 AC_PROG_LN_S
 341 AC_PATH_PROG(CMP, [cmp], [cmp])
 342 AC_PATH_PROG(CP, [cp], [cp])
 343 AC_PATH_PROG(DATE, [date], [date])
 344 AC_PATH_PROG(FIND, [find], [find])
 345 AC_PATH_PROG(GREP, [grep], [grep])
 346 AC_PATH_PROG(MKDIR,[mkdir],[mkdir])
 347 AC_PATH_PROG(MV,   [mv],   [mv])
 348 AC_PROG_RANLIB
 349 AC_PATH_PROG(RM,   [rm],   [rm])
 350 AC_PATH_PROG(SED,  [sed],  [sed])
 351 AC_PATH_PROG(TAR,  [tar],  [gtar])
 352 AC_PATH_PROG(GRAPHVIZ, [Graphviz], [echo Graphviz])
 353 if test "$GRAPHVIZ" != "echo Graphviz" ; then
 354   AC_DEFINE([HAVE_GRAPHVIZ],[1],[Define if the Graphviz program is available])
 355   AC_DEFINE_UNQUOTED([LLVM_PATH_GRAPHVIZ],"$GRAPHVIZ",
 356    [Define to path to Graphviz program if found or 'echo Graphviz' otherwise])
 357 fi
 358 AC_PATH_PROG(GV, [gv], [echo gv])
 359 if test "$GV" != "echo gv" ; then
 360   AC_DEFINE([HAVE_GV],[1],[Define if the gv program is available])
 361   AC_DEFINE_UNQUOTED([LLVM_PATH_GV],"$GV",
 362    [Define to path to gv program if found or 'echo gv' otherwise])
 363 fi
 364
 365 dnl Look for a sufficiently recent version of Perl.
 366 LLVM_PROG_PERL([5.006])
 367 AC_SUBST(PERL)
 368 if test x"$PERL" = xnone; then
 369    AC_SUBST(HAVE_PERL,0)
 370 else
 371    AC_SUBST(HAVE_PERL,1)
 372 fi
 373
 374 dnl Find the install program
 375 AC_PROG_INSTALL
 376
 377 dnl Checks for documentation and testing tools that we can do without. If these
 378 dnl are not found then they are set to "true" which always succeeds but does
 379 dnl nothing. This just lets the build output show that we could have done
 380 dnl something if the tool was available.
 381 AC_PATH_PROG(BZIP2,[bzip2],[true bzip2])
 382 AC_PATH_PROG(DOT,[dot],[true dot])
 383 AC_PATH_PROG(DOXYGEN,[doxygen],[true doxygen])
 384 AC_PATH_PROG(ETAGS,[etags],[true etags])
 385 AC_PATH_PROG(GROFF,[groff],[true groff])
 386 AC_PATH_PROG(GZIP,[gzip],[true gzip])
 387 AC_PATH_PROG(POD2HTML,[pod2html],[true pod2html])
 388 AC_PATH_PROG(POD2MAN,[pod2man],[true pod2man])
 389 AC_PATH_PROG(RUNTEST,[runtest],[true runtest])
 390 DJ_AC_PATH_TCLSH
 391 AC_PATH_PROG(ZIP,[zip],[true zip])
 392
 393 dnl Determine if the linker supports the -R option.
 394 AC_LINK_USE_R
 395
 396 dnl Check for libtool and the library that has dlopen function (which must come
 397 dnl before the AC_PROG_LIBTOOL check in order to enable dlopening libraries with
 398 dnl libtool).
 399 AC_LIBTOOL_DLOPEN
 400 AC_LIB_LTDL
 401 AC_PROG_LIBTOOL
 402
 403 if test "$lt_cv_dlopen_self" = "yes" ; then
 404   AC_DEFINE([CAN_DLOPEN_SELF],[1],
 405               [Define if dlopen(0) will open the symbols of the program])
 406 fi
 407
 408 dnl Check if we know how to tell etags we are using C++:
 409 etags_version=`$ETAGS --version 2>&1`
 410 case "$etags_version" in
 411         *[Ee]xuberant*) ETAGSFLAGS="--language-force=c++" ;;
 412         *GNU\ Emacs*) ETAGSFLAGS="-l c++" ;;
 413         *) ETAGSFLAGS="" ;;
 414 esac
 415 AC_SUBST(ETAGSFLAGS,$ETAGSFLAGS)
 416
 417 if test "$WITH_LLVMGCCDIR" = "default" ; then
 418   LLVMGCC="llvm-gcc${EXEEXT}"
 419   LLVMGXX="llvm-g++${EXEEXT}"
 420   AC_PATH_PROG(LLVMGCC, $LLVMGCC, [])
 421   AC_PATH_PROG(LLVMGXX, $LLVMGXX, [])
 422 else
 423   LLVMGCC="$WITH_LLVMGCCDIR/bin/llvm-gcc${EXEEXT}"
 424   LLVMGXX="$WITH_LLVMGCCDIR/bin/llvm-g++${EXEEXT}"
 425   AC_SUBST(LLVMGCC,$LLVMGCC)
 426   AC_SUBST(LLVMGXX,$LLVMGXX)
 427 fi
 428
 429 AC_MSG_CHECKING([tool compatibility])
 430
 431 dnl Ensure that compilation tools are GCC or a GNU compatible compiler such as
 432 dnl ICC; we use GCC specific options in the makefiles so the compiler needs
 433 dnl to support those options.
 434 dnl "icc" emits gcc signatures
 435 dnl "icc -no-gcc" emits no gcc signature BUT is still compatible
 436 ICC=no
 437 IXX=no
 438 case $CC in
 439   icc*|icpc*)
 440     ICC=yes
 441     IXX=yes
 442     ;;
 443    *)
 444     ;;
 445 esac
 446
 447 if test "$GCC" != "yes" && test "$ICC" != "yes"
 448 then
 449   AC_MSG_ERROR([gcc|icc required but not found])
 450 fi
 451
 452 dnl Ensure that compilation tools are GCC; we use GCC specific extensions
 453 if test "$GXX" != "yes" && test "$IXX" != "yes"
 454 then
 455   AC_MSG_ERROR([g++|icc required but not found])
 456 fi
 457
 458 dnl Verify that GCC is version 3.0 or higher
 459 if test "$GCC" = "yes"
 460 then
 461   gccmajor=`$CC --version | head -n 1 | sed 's/[[^0-9]]*\([[0-9.]]\).*/\1/'`
 462   if test "$gccmajor" -lt "3"
 463   then
 464     AC_MSG_ERROR([gcc 3.x required, but you have a lower version])
 465   fi
 466 fi
 467
 468 dnl Check for GNU Make.  We use its extensions, so don't build without it
 469 if test -z "$llvm_cv_gnu_make_command"
 470 then
 471   AC_MSG_ERROR([GNU Make required but not found])
 472 fi
 473
 474 dnl Tool compatibility is okay if we make it here.
 475 AC_MSG_RESULT([ok])
 476
 477 dnl===-----------------------------------------------------------------------===
 478 dnl===
 479 dnl=== SECTION 5: Check for libraries
 480 dnl===
 481 dnl===-----------------------------------------------------------------------===
 482
 483 dnl libelf is for sparc only; we can ignore it if we don't have it
 484 AC_CHECK_LIB(elf, elf_begin)
 485 AC_CHECK_LIB(m,sin)
 486
 487 dnl lt_dlopen may be required for plugin support.
 488 AC_SEARCH_LIBS(lt_dlopen,ltdl,AC_DEFINE([HAVE_LT_DLOPEN],[1],
 489               [Define if lt_dlopen() is available on this platform]),
 490               AC_MSG_WARN([lt_dlopen() not found - plugin support might
 491                            not be available]))
 492
 493 dnl dlopen() is required for plugin support.
 494 AC_SEARCH_LIBS(dlopen,dl,AC_DEFINE([HAVE_DLOPEN],[1],
 495                [Define if dlopen() is available on this platform.]),
 496                AC_MSG_WARN([dlopen() not found - disabling plugin support]))
 497
 498 dnl mallinfo is optional; the code can compile (minus features) without it
 499 AC_SEARCH_LIBS(mallinfo,malloc,AC_DEFINE([HAVE_MALLINFO],[1],
 500                [Define if mallinfo() is available on this platform.]))
 501
 502 dnl pthread locking functions are optional - but llvm will not be thread-safe
 503 dnl without locks.
 504 if test "$ENABLE_THREADS" -eq 1 ; then
 505   AC_CHECK_LIB(pthread,pthread_mutex_init)
 506   AC_SEARCH_LIBS(pthread_mutex_lock,pthread,
 507                  AC_DEFINE([HAVE_PTHREAD_MUTEX_LOCK],[1],
 508                            [Have pthread_mutex_lock]))
 509 fi
 510
 511 dnl===-----------------------------------------------------------------------===
 512 dnl===
 513 dnl=== SECTION 6: Check for header files
 514 dnl===
 515 dnl===-----------------------------------------------------------------------===
 516
 517 dnl First, use autoconf provided macros for specific headers that we need
 518 dnl We don't check for ancient stuff or things that are guaranteed to be there
 519 dnl by the C++ standard. We always use the <cfoo> versions of <foo.h> C headers.
 520 dnl Generally we're looking for POSIX headers.
 521 AC_HEADER_DIRENT
 522 AC_HEADER_MMAP_ANONYMOUS
 523 AC_HEADER_STAT
 524 AC_HEADER_STDC
 525 AC_HEADER_SYS_WAIT
 526 AC_HEADER_TIME
 527
 528 AC_CHECK_HEADERS([dlfcn.h execinfo.h fcntl.h inttypes.h limits.h link.h])
 529 AC_CHECK_HEADERS([malloc.h signal.h stdint.h unistd.h utime.h windows.h])
 530 AC_CHECK_HEADERS([sys/mman.h sys/param.h sys/resource.h sys/time.h sys/types.h])
 531 AC_CHECK_HEADERS([malloc/malloc.h])
 532 if test "$ENABLE_THREADS" -eq 1 ; then
 533   AC_CHECK_HEADERS(pthread.h)
 534 fi
 535
 536 dnl===-----------------------------------------------------------------------===
 537 dnl===
 538 dnl=== SECTION 7: Check for types and structures
 539 dnl===
 540 dnl===-----------------------------------------------------------------------===
 541
 542 AC_TYPE_PID_T
 543 AC_TYPE_SIZE_T
 544 AC_TYPE_SIGNAL
 545 AC_STRUCT_TM
 546 AC_CHECK_TYPES([int64_t],,AC_MSG_ERROR([Type int64_t required but not found]))
 547 AC_CHECK_TYPES([uint64_t],,
 548          AC_CHECK_TYPES([u_int64_t],,
 549          AC_MSG_ERROR([Type uint64_t or u_int64_t required but not found])))
 550
 551 dnl===-----------------------------------------------------------------------===
 552 dnl===
 553 dnl=== SECTION 8: Check for specific functions needed
 554 dnl===
 555 dnl===-----------------------------------------------------------------------===
 556
 557 AC_CHECK_FUNCS([backtrace ceilf floorf roundf rintf nearbyintf getcwd ])
 558 AC_CHECK_FUNCS([getpagesize getrusage gettimeofday isatty mkdtemp mkstemp ])
 559 AC_CHECK_FUNCS([mktemp realpath sbrk setrlimit strdup strerror strerror_r ])
 560 AC_CHECK_FUNCS([strtoll strtoq sysconf malloc_zone_statistics ])
 561 AC_C_PRINTF_A
 562 AC_FUNC_ALLOCA
 563 AC_FUNC_RAND48
 564
 565 dnl Check for variations in the Standard C++ library and STL. These macros are
 566 dnl provided by LLVM in the autoconf/m4 directory.
 567 AC_CXX_HAVE_HASH_MAP
 568 AC_CXX_HAVE_HASH_SET
 569 AC_CXX_HAVE_STD_ITERATOR
 570 AC_CXX_HAVE_BI_ITERATOR
 571 AC_CXX_HAVE_FWD_ITERATOR
 572 AC_FUNC_ISNAN
 573 AC_FUNC_ISINF
 574
 575 dnl Check for mmap and mprotect support. We need both to do the JIT and for
 576 dnl bytecode loading, etc. We also need to know if /dev/zero is required to
 577 dnl be opened for allocating RWX memory.
 578 AC_FUNC_MMAP
 579 AC_FUNC_MMAP_FILE
 580 AC_NEED_DEV_ZERO_FOR_MMAP
 581 AC_CHECK_FUNC(mprotect,,
 582               AC_MSG_ERROR([Function mprotect() required but not found]))
 583
 584 if test "$ac_cv_func_mmap_fixed_mapped" = "no"
 585 then
 586   AC_MSG_WARN([mmap() of a fixed address required but not supported])
 587 fi
 588 if test "$ac_cv_func_mmap_file" = "no"
 589 then
 590   AC_MSG_WARN([mmap() of files required but not found])
 591 fi
 592
 593 dnl===-----------------------------------------------------------------------===
 594 dnl===
 595 dnl=== SECTION 9: Additional checks, variables, etc.
 596 dnl===
 597 dnl===-----------------------------------------------------------------------===
 598
 599 dnl See if the llvm-gcc executable can compile to LLVM assembly
 600 AC_CACHE_CHECK([whether llvm-gcc is sane],[llvm_cv_llvmgcc_sanity],
 601 [llvm_cv_llvmgcc_sanity="no"
 602 if test -x "$LLVMGCC" ; then
 603   cp /dev/null conftest.c
 604   "$LLVMGCC" -emit-llvm -S -o - conftest.c | grep implementation > /dev/null 2>&1
 605   if test $? -eq 0 ; then
 606     llvm_cv_llvmgcc_sanity="yes"
 607   fi
 608   rm conftest.c
 609 fi])
 610
 611 dnl Since we have a sane llvm-gcc, identify it and its sub-tools
 612 if test "$llvm_cv_llvmgcc_sanity" = "yes" ; then
 613   llvmcc1path=`"$LLVMGCC" --print-prog-name=cc1`
 614   AC_SUBST(LLVMCC1,$llvmcc1path)
 615   llvmcc1pluspath=`"$LLVMGCC" --print-prog-name=cc1plus`
 616   AC_SUBST(LLVMCC1PLUS,$llvmcc1pluspath)
 617   llvmgccdir=`echo "$llvmcc1path" | sed 's,/libexec/.*,,'`
 618   AC_SUBST(LLVMGCCDIR,$llvmgccdir)
 619   llvmgccversion=[`"$LLVMGCC" -v 2>&1 | grep '^gcc version' | sed 's/^gcc version \([0-9.]*\).*/\1/'`]
 620   llvmgccmajvers=[`echo $llvmgccversion | sed 's/^\([0-9]\).*/\1/'`]
 621   AC_SUBST(LLVMGCC_VERSION,$llvmgccversion)
 622   AC_SUBST(LLVMGCC_MAJVERS,$llvmgccmajvers)
 623 fi
 624
 625 dnl Propagate the shared library extension that the libltdl checks did to
 626 dnl the Makefiles so we can use it there too
 627 AC_SUBST(SHLIBEXT,$libltdl_cv_shlibext)
 628
 629 # Translate the various configuration directories and other basic
 630 # information into substitutions that will end up in Makefile.config.in
 631 # that these configured values can be used by the makefiles
 632 eval LLVM_PREFIX="${prefix}";
 633 eval LLVM_BINDIR="${prefix}/bin";
 634 eval LLVM_LIBDIR="${prefix}/lib";
 635 eval LLVM_DATADIR="${prefix}/share/llvm";
 636 eval LLVM_DOCSDIR="${prefix}/docs/llvm";
 637 eval LLVM_ETCDIR="${prefix}/etc/llvm";
 638 eval LLVM_INCLUDEDIR="${prefix}/include";
 639 eval LLVM_INFODIR="${prefix}/info";
 640 eval LLVM_MANDIR="${prefix}/man";
 641 LLVM_CONFIGTIME=`date`
 642 AC_SUBST(LLVM_PREFIX)
 643 AC_SUBST(LLVM_BINDIR)
 644 AC_SUBST(LLVM_LIBDIR)
 645 AC_SUBST(LLVM_DATADIR)
 646 AC_SUBST(LLVM_DOCSDIR)
 647 AC_SUBST(LLVM_ETCDIR)
 648 AC_SUBST(LLVM_INCLUDEDIR)
 649 AC_SUBST(LLVM_INFODIR)
 650 AC_SUBST(LLVM_MANDIR)
 651 AC_SUBST(LLVM_CONFIGTIME)
 652
 653 # Place the various directores into the config.h file as #defines so that we
 654 # can know about the installation paths within LLVM.
 655 AC_DEFINE_UNQUOTED(LLVM_PREFIX,"$LLVM_PREFIX",
 656                    [Installation prefix directory])
 657 AC_DEFINE_UNQUOTED(LLVM_BINDIR, "$LLVM_BINDIR",
 658                    [Installation directory for binary executables])
 659 AC_DEFINE_UNQUOTED(LLVM_LIBDIR, "$LLVM_LIBDIR",
 660                    [Installation directory for libraries])
 661 AC_DEFINE_UNQUOTED(LLVM_DATADIR, "$LLVM_DATADIR",
 662                    [Installation directory for data files])
 663 AC_DEFINE_UNQUOTED(LLVM_DATADIR, "$LLVM_DOCSDIR",
 664                    [Installation directory for documentation])
 665 AC_DEFINE_UNQUOTED(LLVM_ETCDIR, "$LLVM_ETCDIR",
 666                    [Installation directory for config files])
 667 AC_DEFINE_UNQUOTED(LLVM_INCLUDEDIR, "$LLVM_INCLUDEDIR",
 668                    [Installation directory for include files])
 669 AC_DEFINE_UNQUOTED(LLVM_INFODIR, "$LLVM_INFODIR",
 670                    [Installation directory for .info files])
 671 AC_DEFINE_UNQUOTED(LLVM_MANDIR, "$LLVM_MANDIR",
 672                    [Installation directory for man pages])
 673 AC_DEFINE_UNQUOTED(LLVM_CONFIGTIME, "$LLVM_CONFIGTIME",
 674                    [Time at which LLVM was configured])
 675
 676 dnl===-----------------------------------------------------------------------===
 677 dnl===
 678 dnl=== SECTION 10: Specify the output files and generate it
 679 dnl===
 680 dnl===-----------------------------------------------------------------------===
 681
 682 dnl Configure header files
 683 dnl WARNING: dnl If you add or remove any of the following config headers, then
 684 dnl you MUST also update Makefile.rules so that the variable FilesToConfig
 685 dnl contains the same list of files as AC_CONFIG_HEADERS below. This ensures the
 686 dnl files can be updated automatically when their *.in sources change.
 687 AC_CONFIG_HEADERS([include/llvm/Config/config.h])
 688 AC_CONFIG_HEADERS([include/llvm/Support/DataTypes.h])
 689 AC_CONFIG_HEADERS([include/llvm/ADT/hash_map])
 690 AC_CONFIG_HEADERS([include/llvm/ADT/hash_set])
 691 AC_CONFIG_HEADERS([include/llvm/ADT/iterator])
 692
 693 dnl Configure the makefile's configuration data
 694 AC_CONFIG_FILES([Makefile.config])
 695
 696 dnl Configure doxygen's configuration file
 697 AC_CONFIG_FILES([docs/doxygen.cfg])
 698
 699 dnl Do the first stage of configuration for llvm-config.in.
 700 AC_CONFIG_FILES([utils/llvm-config/llvm-config.in])
 701
 702 dnl Do special configuration of Makefiles
 703 AC_CONFIG_COMMANDS([setup],,[llvm_src="${srcdir}"])
 704 AC_CONFIG_MAKEFILE(Makefile)
 705 AC_CONFIG_MAKEFILE(Makefile.common)
 706 AC_CONFIG_MAKEFILE(examples/Makefile)
 707 AC_CONFIG_MAKEFILE(lib/Makefile)
 708 AC_CONFIG_MAKEFILE(runtime/Makefile)
 709 AC_CONFIG_MAKEFILE(test/Makefile)
 710 AC_CONFIG_MAKEFILE(test/Makefile.tests)
 711 AC_CONFIG_MAKEFILE(tools/Makefile)
 712 AC_CONFIG_MAKEFILE(utils/Makefile)
 713 AC_CONFIG_MAKEFILE(projects/Makefile)
 714
 715 dnl Finally, crank out the output
 716 AC_OUTPUT
 717
 718 dnl Warn loudly if llvm-gcc was not obviously working
 719 if test "$llvm_cv_llvmgcc_sanity" = "no" ; then
 720  AC_MSG_WARN([***** llvm-gcc/llvm-g++ was not found, or does not appear to be ])
 721  AC_MSG_WARN([***** working. Please make sure you have llvmgcc and llvmg++ in])
 722  AC_MSG_WARN([***** your path before configuring LLVM. The runtime libraries])
 723  AC_MSG_WARN([***** (llvm/runtime) will not be built but you should be able to])
 724  AC_MSG_WARN([***** build the llvm tools.])
 725 fi