autoconf/configure.ac

   1 dnl === configure.ac --------------------------------------------------------===
   2 dnl                     The LLVM Compiler Infrastructure
   3 dnl
   4 dnl This file was developed by the LLVM research group and is distributed under
   5 dnl the University of Illinois Open Source License. See LICENSE.TXT for details.
   6 dnl
   7 dnl===-----------------------------------------------------------------------===
   8 dnl This is the LLVM configuration script. It is processed by the autoconf
   9 dnl program to produce a script named configure. This script contains the
  10 dnl configuration checks that LLVM needs in order to support multiple platforms.
  11 dnl This file is composed of 10 sections per the recommended organization of
  12 dnl autoconf input defined in the autoconf documentation. As this file evolves,
  13 dnl please keep the various types of checks within their sections. The sections
  14 dnl are as follows:
  15 dnl
  16 dnl SECTION 1: Initialization & Setup
  17 dnl SECTION 2: Architecture, target, and host checks
  18 dnl SECTION 3: Command line arguments for the configure script.
  19 dnl SECTION 4: Check for programs we need and that they are the right version
  20 dnl SECTION 5: Check for libraries
  21 dnl SECTION 6: Check for header files
  22 dnl SECTION 7: Check for types and structures
  23 dnl SECTION 8: Check for specific functions needed
  24 dnl SECTION 9: Additional checks, variables, etc.
  25 dnl SECTION 10: Specify the output files and generate it
  26 dnl
  27 dnl===-----------------------------------------------------------------------===
  28 dnl===
  29 dnl=== SECTION 1: Initialization & Setup
  30 dnl===
  31 dnl===-----------------------------------------------------------------------===
  32 dnl Initialize autoconf and define the package name, version number and
  33 dnl email address for reporting bugs.
  34 AC_INIT([[llvm]],[[1.4]],[llvmbugs@cs.uiuc.edu])
  35
  36 dnl Provide a copyright substitution and ensure the copyright notice is included
  37 dnl in the output of --version option of the generated configure script.
  38 AC_SUBST(LLVM_COPYRIGHT,["Copyright (c) 2003-2005 U University of Illinois at Urbana-Champaign."])
  39 AC_COPYRIGHT($LLVM_COPYRIGHT)
  40
  41 dnl Indicate that we require autoconf 2.59 or later. Ths is needed because we
  42 dnl use some autoconf macros only available in 2.59.
  43 AC_PREREQ(2.59)
  44
  45 dnl Verify that the source directory is valid. This makes sure that we are
  46 dnl configuring LLVM and not some other package (it validates --srcdir argument)
  47 AC_CONFIG_SRCDIR([lib/VMCore/Module.cpp])
  48
  49 dnl Place all of the extra autoconf files into the config subdirectory. Tell
  50 dnl various tools where the m4 autoconf macros are.
  51 AC_CONFIG_AUX_DIR([autoconf])
  52
  53 dnl Quit if the source directory has already been configured.
  54 dnl NOTE: This relies upon undocumented autoconf behavior.
  55 if test ${srcdir} != "." ; then
  56   if test -f ${srcdir}/include/llvm/Config/config.h ; then
  57     AC_MSG_ERROR([Already configured in ${srcdir}])
  58   fi
  59 fi
  60
  61 dnl Configure all of the projects present in our source tree. While we could
  62 dnl just AC_CONFIG_SUBDIRS on the set of directories in projects that have a
  63 dnl configure script, that usage of the AC_CONFIG_SUBDIRS macro is deprecated.
  64 dnl Instead we match on the known projects.
  65 for i in `ls ${srcdir}/projects`
  66 do
  67   if test -d ${srcdir}/projects/${i} ; then
  68     case ${i} in
  69       "CVS") ;;
  70       "sample")       AC_CONFIG_SUBDIRS([projects/sample])    ;;
  71       "Stacker")      AC_CONFIG_SUBDIRS([projects/Stacker])   ;;
  72       "llvm-test")    AC_CONFIG_SUBDIRS([projects/llvm-test]) ;;
  73       "llvm-reopt")   AC_CONFIG_SUBDIRS([projects/llvm-reopt]);;
  74       "llvm-gcc")     AC_CONFIG_SUBDIRS([projects/llvm-gcc])  ;;
  75       "Java")         AC_CONFIG_SUBDIRS([projects/Java])      ;;
  76       "llvm-tv")      AC_CONFIG_SUBDIRS([projects/llvm-tv])   ;;
  77       "llvm-fefw")    AC_CONFIG_SUBDIRS([projects/llvm-fefw]) ;;
  78       "poolalloc")    AC_CONFIG_SUBDIRS([projects/poolalloc]) ;;
  79       *)
  80         AC_MSG_WARN([Unknown project (${i}) won't be configured automatically])
  81         ;;
  82     esac
  83   fi
  84 done
  85
  86 dnl===-----------------------------------------------------------------------===
  87 dnl===
  88 dnl=== SECTION 2: Architecture, target, and host checks
  89 dnl===
  90 dnl===-----------------------------------------------------------------------===
  91
  92 dnl Check the target for which we're compiling and the host that will do the
  93 dnl compilations. This will tell us which LLVM compiler will be used for
  94 dnl compiling SSA into object code. This needs to be done early because
  95 dnl following tests depend on it.
  96 AC_CANONICAL_TARGET
  97
  98 dnl Determine the platform type and cache its value. This helps us configure
  99 dnl the System library to the correct build platform.
 100 AC_CACHE_CHECK([support for generic build operating system],
 101                [llvm_cv_platform_type],
 102 [case $build in
 103   *-*-aix*) llvm_cv_platform_type="AIX" ;;
 104   *-*-cygwin*) llvm_cv_platform_type="Cygwin" ;;
 105   *-*-darwin*) llvm_cv_platform_type="Darwin" ;;
 106   *-*-freebsd*) llvm_cv_platform_type="FreeBSD" ;;
 107   *-*-interix*) llvm_cv_platform_type="Interix" ;;
 108   *-*-linux*) llvm_cv_platform_type="Linux" ;;
 109   *-*-solaris*) llvm_cv_platform_type="SunOS" ;;
 110   *-*-win32*) llvm_cv_platform_type="Win32" ;;
 111   *-*-mingw*) llvm_cv_platform_type="Win32" ;;
 112   *) llvm_cv_platform_type="Unknown" ;;
 113 esac])
 114
 115 dnl Make sure we aren't attempting to configure for an unknown system
 116 if test "$llvm_cv_platform_type" = "Unknown" ; then
 117   AC_MSG_ERROR([Operating system platform is unknown, configure can't continue])
 118 fi
 119
 120 dnl Set the "OS" Makefile variable based on the platform type so the
 121 dnl makefile can configure itself to specific build hosts
 122 AC_SUBST(OS,$llvm_cv_platform_type)
 123
 124 dnl Make a link from lib/System/platform to lib/System/$llvm_cv_platform_type
 125 dnl This helps the #inclusion of the system specific include files
 126 dnl for the operating system abstraction library, lib/System.
 127 AC_CONFIG_LINKS(lib/System/platform:lib/System/$llvm_cv_platform_type)
 128
 129 dnl If we are targetting a Sparc machine running Solaris, pretend that it is
 130 dnl V9, since that is all that we support at the moment, and autoconf will only
 131 dnl tell us we're a sparc.
 132 case $target in
 133   sparc*-*-solaris*)  AC_SUBST(target,[[sparcv9-sun-solaris2.8]])
 134   ;;
 135 esac
 136
 137 dnl Determine what our target architecture is and configure accordingly.
 138 dnl This will allow Makefiles to make a distinction between the hardware and
 139 dnl the OS.
 140 AC_CACHE_CHECK([target architecture],[llvm_cv_target_arch],
 141 [case $target in
 142   i*86-*)      llvm_cv_target_arch="x86" ;;
 143   sparc*-*)    llvm_cv_target_arch="Sparc" ;;
 144   powerpc*-*)  llvm_cv_target_arch="PowerPC" ;;
 145   *)           llvm_cv_target_arch="Unknown" ;;
 146 esac])
 147
 148 if test "$llvm_cv_target_arch" = "Unknown" ; then
 149   AC_MSG_WARN([Configuring LLVM for an unknown target archicture])
 150 fi
 151
 152 dnl Define a substitution, ARCH, for the target architecture
 153 AC_SUBST(ARCH,$llvm_cv_target_arch)
 154
 155 dnl Check for the endianness of the target
 156 AC_C_BIGENDIAN(AC_SUBST([ENDIAN],[big]),AC_SUBST([ENDIAN],[little]))
 157
 158 dnl===-----------------------------------------------------------------------===
 159 dnl===
 160 dnl=== SECTION 3: Command line arguments for the configure script.
 161 dnl===
 162 dnl===-----------------------------------------------------------------------===
 163
 164 dnl --enable-optimized : check whether they want to do an optimized build:
 165 AC_ARG_ENABLE(optimized,
 166               AS_HELP_STRING([--enable-optimized,Compile with optimizations enabled (default is NO)]),,enableval=no)
 167 if test ${enableval} = "no" ; then
 168   AC_SUBST(ENABLE_OPTIMIZED,[[]])
 169 else
 170   AC_SUBST(ENABLE_OPTIMIZED,[[ENABLE_OPTIMIZED=1]])
 171 fi
 172
 173 dnl --enable-jit: check whether they want to enable the jit
 174 AC_ARG_ENABLE(jit,
 175   AS_HELP_STRING(--enable-jit,
 176                  [Enable Just In Time Compiling (default is YES)]),,
 177   enableval=default)
 178 if test ${enableval} = "no"
 179 then
 180   AC_SUBST(JIT,[[]])
 181 else
 182   case "$llvm_cv_target_arch" in
 183     x86)     AC_SUBST(JIT,[[TARGET_HAS_JIT=1]]) ;;
 184     Sparc)   AC_SUBST(JIT,[[TARGET_HAS_JIT=1]]) ;;
 185     PowerPC) AC_SUBST(JIT,[[TARGET_HAS_JIT=1]]) ;;
 186     *)       AC_SUBST(JIT,[[]]) ;;
 187   esac
 188 fi
 189
 190 dnl Allow enablement of doxygen generated documentation
 191 AC_ARG_ENABLE(doxygen,
 192               AS_HELP_STRING([--enable-doxygen],
 193                              [Build doxygen documentation (default is NO)]),,
 194                              enableval=default)
 195 case "$enableval" in
 196   yes) AC_SUBST(ENABLE_DOXYGEN,[1]) ;;
 197   no)  AC_SUBST(ENABLE_DOXYGEN,[0]) ;;
 198   default) AC_SUBST(ENABLE_DOXYGEN,[0]) ;;
 199   *) AC_MSG_ERROR([Invalid setting for --enable-doxygen. Use "yes" or "no"]) ;;
 200 esac
 201
 202 dnl Find the LLVM GCC-based C/C++ front end
 203 AC_ARG_WITH(llvmgccdir,
 204   AS_HELP_STRING(--with-llvmgccdir,[Location of LLVM GCC front-end]),
 205   AC_SUBST(LLVMGCCDIR,[$withval]))
 206
 207 dnl Provide some defaults for LLVMGCC for UIUC environments.
 208 if test "x$LLVMGCCDIR" = x ; then
 209   case "$llvm_cv_platform_type" in
 210     Linux)
 211       if test -d /home/vadve/lattner/local/x86/llvm-gcc ; then
 212         AC_SUBST(LLVMGCCDIR,[/home/vadve/lattner/local/x86/llvm-gcc/])
 213       fi
 214       ;;
 215     SunOS)
 216       if test -d /home/vadve/lattner/local/sparc/llvm-gcc ; then
 217         AC_SUBST(LLVMGCCDIR,[/home/vadve/lattner/local/sparc/llvm-gcc/])
 218       fi
 219       ;;
 220   esac
 221 fi
 222
 223
 224 dnl===-----------------------------------------------------------------------===
 225 dnl===
 226 dnl=== SECTION 4: Check for programs we need and that they are the right version
 227 dnl===
 228 dnl===-----------------------------------------------------------------------===
 229
 230 dnl Check for compilation tools
 231 AC_PROG_CPP
 232 AC_PROG_CC(gcc)
 233 AC_PROG_CXX(g++)
 234 AC_PROG_FLEX
 235 AC_PROG_BISON
 236
 237 dnl Check for the tools that the makefiles require
 238 AC_CHECK_GNU_MAKE
 239 AC_PROG_LN_S
 240 AC_PATH_PROG(CMP, [cmp], [cmp])
 241 AC_PATH_PROG(CP, [cp], [cp])
 242 AC_PATH_PROG(DATE, [date], [date])
 243 AC_PATH_PROG(FIND, [find], [find])
 244 AC_PATH_PROG(GREP, [grep], [grep])
 245 AC_PATH_PROG(MKDIR,[mkdir],[mkdir])
 246 AC_PATH_PROG(MV,   [mv],   [mv])
 247 AC_PATH_PROG(PAX,  [pax],  [pax])
 248 AC_PROG_RANLIB
 249 AC_PATH_PROG(RM,   [rm],   [rm])
 250 AC_PATH_PROG(SED,  [sed],  [sed])
 251 AC_PATH_PROG(TAR,  [tar],  [gtar])
 252
 253 dnl Find the install program
 254 AC_PROG_INSTALL
 255
 256 dnl Checks for documentation and testing tools that we can do without. If these
 257 dnl are not found then they are set to "true" which always succeeds but does
 258 dnl nothing. This just lets the build output show that we could have done
 259 dnl something if the tool was available.
 260 AC_PATH_PROG(BZIP2,[bzip2],[true bzip2])
 261 AC_PATH_PROG(DOT,[dot],[true dot])
 262 AC_PATH_PROG(DOXYGEN,[doxygen],[true doxygen])
 263 AC_PATH_PROG(ETAGS,[etags],[true etags])
 264 AC_PATH_PROG(GROFF,[groff],[true groff])
 265 AC_PATH_PROG(GZIP,[gzip],[true gzip])
 266 AC_PATH_PROG(POD2HTML,[pod2html],[true pod2html])
 267 AC_PATH_PROG(POD2MAN,[pod2man],[true pod2man])
 268 AC_PATH_PROG(RUNTEST,[runtest],[true runtest])
 269 DJ_AC_PATH_TCLSH
 270 AC_PATH_PROG(ZIP,[zip],[true zip])
 271
 272 dnl Determine if the linker supports the -R option.
 273 AC_LINK_USE_R
 274
 275 dnl Check for libtool and the library that has dlopen function (which must come
 276 dnl before the AC_PROG_LIBTOOL check in order to enable dlopening libraries with
 277 dnl libtool).
 278 AC_LIBTOOL_DLOPEN
 279 AC_LIB_LTDL
 280 AC_PROG_LIBTOOL
 281
 282 dnl Check if we know how to tell etags we are using C++:
 283 etags_version=`$ETAGS --version 2>&1`
 284 case "$etags_version" in
 285         *[Ee]xuberant*) ETAGSFLAGS="--language-force=c++" ;;
 286         *GNU\ Emacs*) ETAGSFLAGS="-l c++" ;;
 287         *) ETAGSFLAGS="" ;;
 288 esac
 289 AC_SUBST(ETAGSFLAGS,$ETAGSFLAGS)
 290
 291 AC_MSG_CHECKING([tool compatibility])
 292
 293 dnl Ensure that compilation tools are GCC or a GNU compatible compiler such as
 294 dnl ICC; we use GCC specific options in the makefiles so the compiler needs
 295 dnl to support those options.
 296 dnl "icc" emits gcc signatures
 297 dnl "icc -no-gcc" emits no gcc signature BUT is still compatible
 298 ICC=no
 299 IXX=no
 300 case $CC in
 301   icc*|icpc*)
 302     ICC=yes
 303     IXX=yes
 304     ;;
 305    *)
 306     ;;
 307 esac
 308
 309 if test "$GCC" != "yes" && test "$ICC" != "yes"
 310 then
 311   AC_MSG_ERROR([gcc|icc required but not found])
 312 fi
 313
 314 dnl Ensure that compilation tools are GCC; we use GCC specific extensions
 315 if test "$GXX" != "yes" && test "$IXX" != "yes"
 316 then
 317   AC_MSG_ERROR([g++|icc required but not found])
 318 fi
 319
 320 dnl Verify that GCC is version 3.0 or higher
 321 if test "$GCC" = "yes"
 322 then
 323   gccmajor=`$CC --version | head -n 1 | awk '{print $NF;}' | cut -d. -f1`
 324   if test "$gccmajor" -lt "3"
 325   then
 326     AC_MSG_ERROR([gcc 3.x required, but you have a lower version])
 327   fi
 328 fi
 329
 330 dnl Check for GNU Make.  We use its extensions, so don't build without it
 331 if test -z "$llvm_cv_gnu_make_command"
 332 then
 333   AC_MSG_ERROR([GNU Make required but not found])
 334 fi
 335
 336 dnl Tool compatibility is okay if we make it here.
 337 AC_MSG_RESULT([ok])
 338
 339 dnl===-----------------------------------------------------------------------===
 340 dnl===
 341 dnl=== SECTION 5: Check for libraries
 342 dnl===
 343 dnl===-----------------------------------------------------------------------===
 344
 345 dnl libelf is for sparc only; we can ignore it if we don't have it
 346 AC_CHECK_LIB(elf, elf_begin)
 347
 348 dnl lt_dlopen may be required for plugin support.
 349 AC_SEARCH_LIBS(lt_dlopen,ltdl,AC_DEFINE([HAVE_LT_DLOPEN],[1],
 350               [Define if lt_dlopen() is available on this platform]),
 351               AC_MSG_WARN([lt_dlopen() not found - plugin support might
 352                            not be available]))
 353
 354 dnl dlopen() is required for plugin support.
 355 AC_SEARCH_LIBS(dlopen,dl,AC_DEFINE([HAVE_DLOPEN],[1],
 356                [Define if dlopen() is available on this platform.]),
 357                AC_MSG_WARN([dlopen() not found - disabling plugin support]))
 358
 359 dnl mallinfo is optional; the code can compile (minus features) without it
 360 AC_SEARCH_LIBS(mallinfo,malloc,AC_DEFINE([HAVE_MALLINFO],[1],
 361                [Define if mallinfo() is available on this platform.]))
 362
 363 dnl pthread locking functions are optional - but llvm will not be thread-safe
 364 dnl without locks.
 365 AC_SEARCH_LIBS(pthread_mutex_lock,pthread,
 366                AC_DEFINE([HAVE_PTHREAD_MUTEX_LOCK],[1],
 367                          [Have pthread_mutex_lock]))
 368
 369 dnl===-----------------------------------------------------------------------===
 370 dnl===
 371 dnl=== SECTION 6: Check for header files
 372 dnl===
 373 dnl===-----------------------------------------------------------------------===
 374
 375 dnl We don't check for ancient stuff or things that are guaranteed to be there
 376 dnl by the C++ standard. We always use the <cfoo> versions of <foo.h> C headers.
 377 AC_HEADER_STDC
 378
 379 dnl However, we do need some system specific header files. Generally we're
 380 dnl looking for POSIX headers.
 381 AC_HEADER_SYS_WAIT
 382 AC_CHECK_HEADERS([sys/time.h sys/mman.h sys/resource.h sys/time.h sys/types.h])
 383 AC_CHECK_HEADERS([dlfcn.h execinfo.h fcntl.h limits.h link.h])
 384 AC_CHECK_HEADERS([malloc.h unistd.h windows.h])
 385 AC_HEADER_TIME
 386 AC_HEADER_MMAP_ANONYMOUS
 387
 388 dnl Check for things that need to be included in public headers, and so
 389 dnl for which we may not have access to a HAVE_* preprocessor #define.
 390 dnl (primarily used in DataTypes.h)
 391 AC_CHECK_HEADERS([inttypes.h stdint.h])
 392
 393 dnl===-----------------------------------------------------------------------===
 394 dnl===
 395 dnl=== SECTION 7: Check for types and structures
 396 dnl===
 397 dnl===-----------------------------------------------------------------------===
 398
 399 AC_TYPE_PID_T
 400 AC_TYPE_SIZE_T
 401 AC_TYPE_SIGNAL
 402 AC_STRUCT_TM
 403 AC_CHECK_TYPES([int64_t],,AC_MSG_ERROR([Type int64_t required but not found]))
 404 AC_CHECK_TYPES([uint64_t],,
 405          AC_CHECK_TYPES([u_int64_t],,
 406          AC_MSG_ERROR([Type uint64_t or u_int64_t required but not found])))
 407
 408 dnl===-----------------------------------------------------------------------===
 409 dnl===
 410 dnl=== SECTION 8: Check for specific functions needed
 411 dnl===
 412 dnl===-----------------------------------------------------------------------===
 413
 414 AC_CHECK_FUNCS([backtrace getcwd getpagesize getrusage gettimeofday isatty ])
 415 AC_CHECK_FUNCS([mkdtemp mkstemp mktemp ])
 416 AC_CHECK_FUNCS([realpath strdup strtoq strtoll sysconf ])
 417 AC_C_PRINTF_A
 418 AC_FUNC_ALLOCA
 419 AC_FUNC_RAND48
 420
 421 dnl Check for variations in the Standard C++ library and STL. These macros are
 422 dnl provided by LLVM in the autoconf/m4 directory.
 423 AC_CXX_HAVE_HASH_MAP
 424 AC_CXX_HAVE_HASH_SET
 425 AC_CXX_HAVE_STD_ITERATOR
 426 AC_CXX_HAVE_BI_ITERATOR
 427 AC_CXX_HAVE_FWD_ITERATOR
 428 AC_FUNC_ISNAN
 429 AC_FUNC_ISINF
 430
 431 dnl Check for mmap and mprotect support. We need both to do the JIT and for
 432 dnl bytecode loading, etc.
 433 AC_FUNC_MMAP
 434 AC_FUNC_MMAP_FILE
 435 AC_CHECK_FUNC(mprotect,,
 436               AC_MSG_ERROR([Function mprotect() required but not found]))
 437
 438 if test "$ac_cv_func_mmap_fixed_mapped" = "no"
 439 then
 440   AC_MSG_WARN([mmap() required but not found])
 441 fi
 442 if test "$ac_cv_func_mmap_file" = "no"
 443 then
 444   AC_MSG_WARN([mmap() of files required but not found])
 445 fi
 446
 447 dnl===-----------------------------------------------------------------------===
 448 dnl===
 449 dnl=== SECTION 9: Additional checks, variables, etc.
 450 dnl===
 451 dnl===-----------------------------------------------------------------------===
 452
 453 dnl Figure out if there's an executable llvm-gcc in the llvmgccdir.
 454 AC_CACHE_CHECK([for llvm-gcc],[llvm_cv_llvmgcc],
 455 [llvm_cv_llvmgcc='llvmgcc_not_found'
 456 if test -d "$LLVMGCCDIR" ; then
 457   if test -x "$LLVMGCCDIR/bin/gcc" ; then
 458     llvm_cv_llvmgcc="$LLVMGCCDIR/bin/gcc"
 459   fi
 460 fi])
 461
 462 dnl See if the llvmgcc executable can compile to LLVM assembly
 463 AC_CACHE_CHECK([whether llvm-gcc is sane],[llvm_cv_llvmgcc_sanity],
 464 [llvm_cv_llvmgcc_sanity="no"
 465 if test -x "$llvm_cv_llvmgcc" ; then
 466   cp /dev/null conftest.c
 467   "$llvm_cv_llvmgcc" -S -o - conftest.c | grep implementation > /dev/null 2>&1
 468   if test $? -eq 0 ; then
 469     llvm_cv_llvmgcc_sanity="yes"
 470   fi
 471   rm conftest.c
 472 fi])
 473
 474 dnl Since we have a sane llvmgcc, identify it and its sub-tools
 475 if test "$llvm_cv_llvmgcc_sanity" = "yes" ; then
 476   AC_SUBST(LLVMGCC,"$llvm_cv_llvmgcc")
 477   llvmcc1path=`"$llvm_cv_llvmgcc" --print-prog-name=cc1`
 478   AC_SUBST(LLVMCC1,$llvmcc1path)
 479   llvmcc1pluspath=`"$llvm_cv_llvmgcc" --print-prog-name=cc1plus`
 480   AC_SUBST(LLVMCC1PLUS,$llvmcc1pluspath)
 481 fi
 482
 483 dnl Propagate the shared library extension that the libltdl checks did to
 484 dnl the Makefiles so we can use it there too
 485 AC_SUBST(SHLIBEXT,$libltdl_cv_shlibext)
 486
 487 # Translate the various configuration directories and other basic
 488 # information into substitutions that will end up in Makefile.config.in
 489 # that these configured values can be used by the makefiles
 490 eval LLVM_PREFIX="${prefix}";
 491 eval LLVM_BINDIR="${prefix}/bin";
 492 eval LLVM_LIBDIR="${prefix}/lib";
 493 eval LLVM_DATADIR="${prefix}/share/llvm";
 494 eval LLVM_DOCSDIR="${prefix}/docs/llvm";
 495 eval LLVM_ETCDIR="${prefix}/etc/llvm";
 496 eval LLVM_INCLUDEDIR="${prefix}/include";
 497 eval LLVM_INFODIR="${prefix}/info";
 498 eval LLVM_MANDIR="${prefix}/man";
 499 LLVM_CONFIGTIME=`date`
 500 AC_SUBST(LLVM_PREFIX)
 501 AC_SUBST(LLVM_BINDIR)
 502 AC_SUBST(LLVM_LIBDIR)
 503 AC_SUBST(LLVM_DATADIR)
 504 AC_SUBST(LLVM_DOCSDIR)
 505 AC_SUBST(LLVM_ETCDIR)
 506 AC_SUBST(LLVM_INCLUDEDIR)
 507 AC_SUBST(LLVM_INFODIR)
 508 AC_SUBST(LLVM_MANDIR)
 509 AC_SUBST(LLVM_CONFIGTIME)
 510
 511 # Place the various directores into the config.h file as #defines so that we
 512 # can know about the installation paths within LLVM.
 513 AC_DEFINE_UNQUOTED(LLVM_PREFIX,"$LLVM_PREFIX",
 514                    [Installation prefix directory])
 515 AC_DEFINE_UNQUOTED(LLVM_BINDIR, "$LLVM_BINDIR",
 516                    [Installation directory for binary executables])
 517 AC_DEFINE_UNQUOTED(LLVM_LIBDIR, "$LLVM_LIBDIR",
 518                    [Installation directory for libraries])
 519 AC_DEFINE_UNQUOTED(LLVM_DATADIR, "$LLVM_DATADIR",
 520                    [Installation directory for data files])
 521 AC_DEFINE_UNQUOTED(LLVM_DATADIR, "$LLVM_DOCSDIR",
 522                    [Installation directory for documentation])
 523 AC_DEFINE_UNQUOTED(LLVM_ETCDIR, "$LLVM_ETCDIR",
 524                    [Installation directory for config files])
 525 AC_DEFINE_UNQUOTED(LLVM_INCLUDEDIR, "$LLVM_INCLUDEDIR",
 526                    [Installation directory for include files])
 527 AC_DEFINE_UNQUOTED(LLVM_INFODIR, "$LLVM_INFODIR",
 528                    [Installation directory for .info files])
 529 AC_DEFINE_UNQUOTED(LLVM_MANDIR, "$LLVM_MANDIR",
 530                    [Installation directory for man pages])
 531 AC_DEFINE_UNQUOTED(LLVM_CONFIGTIME, "$LLVM_CONFIGTIME",
 532                    [Time at which LLVM was configured])
 533
 534 dnl===-----------------------------------------------------------------------===
 535 dnl===
 536 dnl=== SECTION 10: Specify the output files and generate it
 537 dnl===
 538 dnl===-----------------------------------------------------------------------===
 539
 540 dnl Configure header files
 541 AC_CONFIG_HEADERS(include/llvm/Config/config.h)
 542
 543 AC_CONFIG_HEADERS([include/llvm/Support/DataTypes.h])
 544 AC_CONFIG_HEADERS([include/llvm/ADT/hash_map])
 545 AC_CONFIG_HEADERS([include/llvm/ADT/hash_set])
 546 AC_CONFIG_HEADERS([include/llvm/Support/ThreadSupport.h])
 547 AC_CONFIG_HEADERS([include/llvm/ADT/iterator])
 548
 549 dnl Configure the makefile's configuration data
 550 AC_CONFIG_FILES([Makefile.config])
 551
 552 dnl Configure llvmc's configuration files
 553 AC_CONFIG_FILES([tools/llvmc/st tools/llvmc/cpp tools/llvmc/ll tools/llvmc/c])
 554
 555 dnl Configure doxygen's configuration file
 556 AC_CONFIG_FILES([docs/doxygen.cfg])
 557
 558 dnl Do special configuration of Makefiles
 559 AC_CONFIG_MAKEFILE(Makefile)
 560 AC_CONFIG_MAKEFILE(Makefile.common)
 561 AC_CONFIG_MAKEFILE(examples/Makefile)
 562 AC_CONFIG_MAKEFILE(lib/Makefile)
 563 AC_CONFIG_MAKEFILE(runtime/Makefile)
 564 AC_CONFIG_MAKEFILE(test/Makefile)
 565 AC_CONFIG_MAKEFILE(test/Makefile.tests)
 566 AC_CONFIG_MAKEFILE(tools/Makefile)
 567 AC_CONFIG_MAKEFILE(utils/Makefile)
 568 AC_CONFIG_MAKEFILE(projects/Makefile)
 569
 570 dnl Finally, crank out the output
 571 AC_OUTPUT
 572
 573 dnl Warn loudly if llvm-gcc was not obviously working
 574 if test "$llvm_cv_llvmgcc_sanity" = "no" ; then
 575  AC_MSG_WARN([***** llvm C/C++ front end was not found, or does not])
 576  AC_MSG_WARN([***** appear to be working.])
 577  AC_MSG_WARN([***** ])
 578  AC_MSG_WARN([***** Please check configure's --with-llvmgccdir option.])
 579  AC_MSG_WARN([***** Runtime libraries (in llvm/runtime) will not be built,])
 580  AC_MSG_WARN([***** but you should be able to build the llvm tools.])
 581 fi