autoconf/configure.ac

   1 dnl === configure.ac --------------------------------------------------------===
   2 dnl                     The LLVM Compiler Infrastructure
   3 dnl
   4 dnl This file is distributed under the University of Illinois Open Source
   5 dnl License. See LICENSE.TXT for details.
   6 dnl
   7 dnl===-----------------------------------------------------------------------===
   8 dnl This is the LLVM configuration script. It is processed by the autoconf
   9 dnl program to produce a script named configure. This script contains the
  10 dnl configuration checks that LLVM needs in order to support multiple platforms.
  11 dnl This file is composed of 10 sections per the recommended organization of
  12 dnl autoconf input defined in the autoconf documentation. As this file evolves,
  13 dnl please keep the various types of checks within their sections. The sections
  14 dnl are as follows:
  15 dnl
  16 dnl SECTION 1: Initialization & Setup
  17 dnl SECTION 2: Architecture, target, and host checks
  18 dnl SECTION 3: Command line arguments for the configure script.
  19 dnl SECTION 4: Check for programs we need and that they are the right version
  20 dnl SECTION 5: Check for libraries
  21 dnl SECTION 6: Check for header files
  22 dnl SECTION 7: Check for types and structures
  23 dnl SECTION 8: Check for specific functions needed
  24 dnl SECTION 9: Additional checks, variables, etc.
  25 dnl SECTION 10: Specify the output files and generate it
  26 dnl
  27 dnl===-----------------------------------------------------------------------===
  28 dnl===
  29 dnl=== SECTION 1: Initialization & Setup
  30 dnl===
  31 dnl===-----------------------------------------------------------------------===
  32 dnl Initialize autoconf and define the package name, version number and
  33 dnl email address for reporting bugs.
  34 AC_INIT([[llvm]],[[2.5svn]],[llvmbugs@cs.uiuc.edu])
  35
  36 dnl Provide a copyright substitution and ensure the copyright notice is included
  37 dnl in the output of --version option of the generated configure script.
  38 AC_SUBST(LLVM_COPYRIGHT,["Copyright (c) 2003-2008 University of Illinois at Urbana-Champaign."])
  39 AC_COPYRIGHT([Copyright (c) 2003-2008 University of Illinois at Urbana-Champaign.])
  40
  41 dnl Indicate that we require autoconf 2.59 or later. Ths is needed because we
  42 dnl use some autoconf macros only available in 2.59.
  43 AC_PREREQ(2.59)
  44
  45 dnl Verify that the source directory is valid. This makes sure that we are
  46 dnl configuring LLVM and not some other package (it validates --srcdir argument)
  47 AC_CONFIG_SRCDIR([lib/VMCore/Module.cpp])
  48
  49 dnl Place all of the extra autoconf files into the config subdirectory. Tell
  50 dnl various tools where the m4 autoconf macros are.
  51 AC_CONFIG_AUX_DIR([autoconf])
  52
  53 dnl Quit if the source directory has already been configured.
  54 dnl NOTE: This relies upon undocumented autoconf behavior.
  55 if test ${srcdir} != "." ; then
  56   if test -f ${srcdir}/include/llvm/Config/config.h ; then
  57     AC_MSG_ERROR([Already configured in ${srcdir}])
  58   fi
  59 fi
  60
  61 dnl Configure all of the projects present in our source tree. While we could
  62 dnl just AC_CONFIG_SUBDIRS on the set of directories in projects that have a
  63 dnl configure script, that usage of the AC_CONFIG_SUBDIRS macro is deprecated.
  64 dnl Instead we match on the known projects.
  65 for i in `ls ${srcdir}/projects`
  66 do
  67   if test -d ${srcdir}/projects/${i} ; then
  68     case ${i} in
  69       CVS) ;;
  70       sample)       AC_CONFIG_SUBDIRS([projects/sample])    ;;
  71       privbracket)  AC_CONFIG_SUBDIRS([projects/privbracket]) ;;
  72       llvm-stacker) AC_CONFIG_SUBDIRS([projects/llvm-stacker]) ;;
  73       # llvm-test is the old name of the test-suite, kept here for backwards
  74       # compatibility
  75       llvm-test)    AC_CONFIG_SUBDIRS([projects/llvm-test]) ;;
  76       test-suite)   AC_CONFIG_SUBDIRS([projects/test-suite]) ;;
  77       llvm-reopt)   AC_CONFIG_SUBDIRS([projects/llvm-reopt]);;
  78       llvm-gcc)     AC_CONFIG_SUBDIRS([projects/llvm-gcc])  ;;
  79       llvm-java)    AC_CONFIG_SUBDIRS([projects/llvm-java]) ;;
  80       llvm-tv)      AC_CONFIG_SUBDIRS([projects/llvm-tv])   ;;
  81       llvm-poolalloc) AC_CONFIG_SUBDIRS([projects/llvm-poolalloc]) ;;
  82       poolalloc)    AC_CONFIG_SUBDIRS([projects/poolalloc]) ;;
  83       llvm-kernel)  AC_CONFIG_SUBDIRS([projects/llvm-kernel]) ;;
  84       *)
  85         AC_MSG_WARN([Unknown project (${i}) won't be configured automatically])
  86         ;;
  87     esac
  88   fi
  89 done
  90
  91 dnl===-----------------------------------------------------------------------===
  92 dnl===
  93 dnl=== SECTION 2: Architecture, target, and host checks
  94 dnl===
  95 dnl===-----------------------------------------------------------------------===
  96
  97 dnl Check the target for which we're compiling and the host that will do the
  98 dnl compilations. This will tell us which LLVM compiler will be used for
  99 dnl compiling SSA into object code. This needs to be done early because
 100 dnl following tests depend on it.
 101 AC_CANONICAL_TARGET
 102
 103 dnl Determine the platform type and cache its value. This helps us configure
 104 dnl the System library to the correct build platform.
 105 AC_CACHE_CHECK([type of operating system we're going to host on],
 106                [llvm_cv_os_type],
 107 [case $host in
 108   *-*-aix*)
 109     llvm_cv_link_all_option="-Wl,--whole-archive"
 110     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 111     llvm_cv_os_type="AIX"
 112     llvm_cv_platform_type="Unix" ;;
 113   *-*-irix*)
 114     llvm_cv_link_all_option="-Wl,--whole-archive"
 115     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 116     llvm_cv_os_type="IRIX"
 117     llvm_cv_platform_type="Unix" ;;
 118   *-*-cygwin*)
 119     llvm_cv_link_all_option="-Wl,--whole-archive"
 120     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 121     llvm_cv_os_type="Cygwin"
 122     llvm_cv_platform_type="Unix" ;;
 123   *-*-darwin*)
 124     llvm_cv_link_all_option="-Wl,-all_load"
 125     llvm_cv_no_link_all_option="-Wl,-noall_load"
 126     llvm_cv_os_type="Darwin"
 127     llvm_cv_platform_type="Unix" ;;
 128   *-*-freebsd*)
 129     llvm_cv_link_all_option="-Wl,--whole-archive"
 130     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 131     llvm_cv_os_type="FreeBSD"
 132     llvm_cv_platform_type="Unix" ;;
 133   *-*-openbsd*)
 134     llvm_cv_link_all_option="-Wl,--whole-archive"
 135     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 136     llvm_cv_os_type="OpenBSD"
 137     llvm_cv_platform_type="Unix" ;;
 138   *-*-netbsd*)
 139     llvm_cv_link_all_option="-Wl,--whole-archive"
 140     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 141     llvm_cv_os_type="NetBSD"
 142     llvm_cv_platform_type="Unix" ;;
 143   *-*-dragonfly*)
 144     llvm_cv_link_all_option="-Wl,--whole-archive"
 145     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 146     llvm_cv_os_type="DragonFly"
 147     llvm_cv_platform_type="Unix" ;;
 148   *-*-hpux*)
 149     llvm_cv_link_all_option="-Wl,--whole-archive"
 150     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 151     llvm_cv_os_type="HP-UX"
 152     llvm_cv_platform_type="Unix" ;;
 153   *-*-interix*)
 154     llvm_cv_link_all_option="-Wl,--whole-archive"
 155     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 156     llvm_cv_os_type="Interix"
 157     llvm_cv_platform_type="Unix" ;;
 158   *-*-linux*)
 159     llvm_cv_link_all_option="-Wl,--whole-archive"
 160     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 161     llvm_cv_os_type="Linux"
 162     llvm_cv_platform_type="Unix" ;;
 163   *-*-solaris*)
 164     llvm_cv_link_all_option="-Wl,-z,allextract"
 165     llvm_cv_no_link_all_option="-Wl,-z,defaultextract"
 166     llvm_cv_os_type="SunOS"
 167     llvm_cv_platform_type="Unix" ;;
 168   *-*-win32*)
 169     llvm_cv_link_all_option="-Wl,--whole-archive"
 170     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 171     llvm_cv_os_type="Win32"
 172     llvm_cv_platform_type="Win32" ;;
 173   *-*-mingw*)
 174     llvm_cv_link_all_option="-Wl,--whole-archive"
 175     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 176     llvm_cv_os_type="MingW"
 177     llvm_cv_platform_type="Win32" ;;
 178   *)
 179     llvm_cv_link_all_option=""
 180     llvm_cv_no_link_all_option=""
 181     llvm_cv_os_type="Unknown"
 182     llvm_cv_platform_type="Unknown" ;;
 183 esac])
 184
 185 dnl Make sure we aren't attempting to configure for an unknown system
 186 if test "$llvm_cv_os_type" = "Unknown" ; then
 187   AC_MSG_ERROR([Operating system is unknown, configure can't continue])
 188 fi
 189
 190 dnl Set the "OS" Makefile variable based on the platform type so the
 191 dnl makefile can configure itself to specific build hosts
 192 AC_SUBST(OS,$llvm_cv_os_type)
 193
 194 dnl Set the LINKALL and NOLINKALL Makefile variables based on the platform
 195 AC_SUBST(LINKALL,$llvm_cv_link_all_option)
 196 AC_SUBST(NOLINKALL,$llvm_cv_no_link_all_option)
 197
 198 dnl Set the "LLVM_ON_*" variables based on llvm_cvs_platform_type
 199 dnl This is used by lib/System to determine the basic kind of implementation
 200 dnl to use.
 201 case $llvm_cv_platform_type in
 202   Unix)
 203     AC_DEFINE([LLVM_ON_UNIX],[1],[Define if this is Unixish platform])
 204     AC_SUBST(LLVM_ON_UNIX,[1])
 205     AC_SUBST(LLVM_ON_WIN32,[0])
 206     ;;
 207   Win32)
 208     AC_DEFINE([LLVM_ON_WIN32],[1],[Define if this is Win32ish platform])
 209     AC_SUBST(LLVM_ON_UNIX,[0])
 210     AC_SUBST(LLVM_ON_WIN32,[1])
 211     ;;
 212 esac
 213
 214 dnl Determine what our target architecture is and configure accordingly.
 215 dnl This will allow Makefiles to make a distinction between the hardware and
 216 dnl the OS.
 217 AC_CACHE_CHECK([target architecture],[llvm_cv_target_arch],
 218 [case $target in
 219   i?86-*)                 llvm_cv_target_arch="x86" ;;
 220   amd64-* | x86_64-*)     llvm_cv_target_arch="x86_64" ;;
 221   sparc*-*)               llvm_cv_target_arch="Sparc" ;;
 222   powerpc*-*)             llvm_cv_target_arch="PowerPC" ;;
 223   alpha*-*)               llvm_cv_target_arch="Alpha" ;;
 224   ia64-*)                 llvm_cv_target_arch="IA64" ;;
 225   arm-*)                  llvm_cv_target_arch="ARM" ;;
 226   mips-*)                 llvm_cv_target_arch="Mips" ;;
 227   pic16-*)                llvm_cv_target_arch="PIC16" ;;
 228   *)                      llvm_cv_target_arch="Unknown" ;;
 229 esac])
 230
 231 if test "$llvm_cv_target_arch" = "Unknown" ; then
 232   AC_MSG_WARN([Configuring LLVM for an unknown target archicture])
 233 fi
 234
 235 dnl Define a substitution, ARCH, for the target architecture
 236 AC_SUBST(ARCH,$llvm_cv_target_arch)
 237
 238 dnl Check for the endianness of the target
 239 AC_C_BIGENDIAN(AC_SUBST([ENDIAN],[big]),AC_SUBST([ENDIAN],[little]))
 240
 241 dnl Check for build platform executable suffix if we're crosscompiling
 242 if test "$cross_compiling" = yes; then
 243   AC_SUBST(LLVM_CROSS_COMPILING, [1])
 244   AC_BUILD_EXEEXT
 245   ac_build_prefix=${build_alias}-
 246   AC_CHECK_PROG(BUILD_CXX, ${ac_build_prefix}g++, ${ac_build_prefix}g++)
 247   if test -z "$BUILD_CXX"; then
 248      AC_CHECK_PROG(BUILD_CXX, g++, g++)
 249      if test -z "$BUILD_CXX"; then
 250        AC_CHECK_PROG(BUILD_CXX, c++, c++, , , /usr/ucb/c++)
 251      fi
 252   fi
 253 else
 254   AC_SUBST(LLVM_CROSS_COMPILING, [0])
 255 fi
 256
 257 dnl Check to see if there's a "CVS" (or .svn) directory indicating that this
 258 dnl build is being done from a checkout. This sets up several defaults for the
 259 dnl command line switches. When we build with a CVS directory, we get a
 260 dnl debug with assertions turned on. Without, we assume a source release and we
 261 dnl get an optimized build without assertions. See --enable-optimized and
 262 dnl --enable-assertions below
 263 if test -d "CVS" -o -d "${srcdir}/CVS" -o -d ".svn" -o -d "${srcdir}/.svn"; then
 264   cvsbuild="yes"
 265   optimize="no"
 266   AC_SUBST(CVSBUILD,[[CVSBUILD=1]])
 267 else
 268   cvsbuild="no"
 269   optimize="yes"
 270 fi
 271
 272 dnl===-----------------------------------------------------------------------===
 273 dnl===
 274 dnl=== SECTION 3: Command line arguments for the configure script.
 275 dnl===
 276 dnl===-----------------------------------------------------------------------===
 277
 278 dnl --enable-optimized : check whether they want to do an optimized build:
 279 AC_ARG_ENABLE(optimized, AS_HELP_STRING(
 280  [--enable-optimized,Compile with optimizations enabled (default is NO)]),,enableval=$optimize)
 281 if test ${enableval} = "no" ; then
 282   AC_SUBST(ENABLE_OPTIMIZED,[[]])
 283 else
 284   AC_SUBST(ENABLE_OPTIMIZED,[[ENABLE_OPTIMIZED=1]])
 285 fi
 286
 287 dnl --enable-assertions : check whether they want to turn on assertions or not:
 288 AC_ARG_ENABLE(assertions,AS_HELP_STRING(
 289   [--enable-assertions,Compile with assertion checks enabled (default is YES)]),, enableval="yes")
 290 if test ${enableval} = "yes" ; then
 291   AC_SUBST(DISABLE_ASSERTIONS,[[]])
 292 else
 293   AC_SUBST(DISABLE_ASSERTIONS,[[DISABLE_ASSERTIONS=1]])
 294 fi
 295
 296 dnl --enable-expensive-checks : check whether they want to turn on expensive debug checks:
 297 AC_ARG_ENABLE(expensive-checks,AS_HELP_STRING(
 298   [--enable-expensive-checks,Compile with expensive debug checks enabled (default is NO)]),, enableval="no")
 299 if test ${enableval} = "yes" ; then
 300   AC_SUBST(ENABLE_EXPENSIVE_CHECKS,[[ENABLE_EXPENSIVE_CHECKS=1]])
 301   AC_SUBST(EXPENSIVE_CHECKS,[[yes]])
 302 else
 303   AC_SUBST(ENABLE_EXPENSIVE_CHECKS,[[]])
 304   AC_SUBST(EXPENSIVE_CHECKS,[[no]])
 305 fi
 306
 307 dnl --enable-debug-runtime : should runtime libraries have debug symbols?
 308 AC_ARG_ENABLE(debug-runtime,
 309    AS_HELP_STRING([--enable-debug-runtime,Build runtime libs with debug symbols (default is NO)]),,enableval=no)
 310 if test ${enableval} = "no" ; then
 311   AC_SUBST(DEBUG_RUNTIME,[[]])
 312 else
 313   AC_SUBST(DEBUG_RUNTIME,[[DEBUG_RUNTIME=1]])
 314 fi
 315
 316 dnl --enable-jit: check whether they want to enable the jit
 317 AC_ARG_ENABLE(jit,
 318   AS_HELP_STRING(--enable-jit,
 319                  [Enable Just In Time Compiling (default is YES)]),,
 320   enableval=default)
 321 if test ${enableval} = "no"
 322 then
 323   AC_SUBST(JIT,[[]])
 324 else
 325   case "$llvm_cv_target_arch" in
 326     x86)     AC_SUBST(TARGET_HAS_JIT,1) ;;
 327     Sparc)   AC_SUBST(TARGET_HAS_JIT,0) ;;
 328     PowerPC) AC_SUBST(TARGET_HAS_JIT,1) ;;
 329     x86_64)  AC_SUBST(TARGET_HAS_JIT,1) ;;
 330     Alpha)   AC_SUBST(TARGET_HAS_JIT,1) ;;
 331     IA64)    AC_SUBST(TARGET_HAS_JIT,0) ;;
 332     ARM)     AC_SUBST(TARGET_HAS_JIT,0) ;;
 333     Mips)    AC_SUBST(TARGET_HAS_JIT,0) ;;
 334     PIC16)   AC_SUBST(TARGET_HAS_JIT,0) ;;
 335     *)       AC_SUBST(TARGET_HAS_JIT,0) ;;
 336   esac
 337 fi
 338
 339 dnl Allow enablement of doxygen generated documentation
 340 AC_ARG_ENABLE(doxygen,
 341               AS_HELP_STRING([--enable-doxygen],
 342                              [Build doxygen documentation (default is NO)]),,
 343                              enableval=default)
 344 case "$enableval" in
 345   yes) AC_SUBST(ENABLE_DOXYGEN,[1]) ;;
 346   no)  AC_SUBST(ENABLE_DOXYGEN,[0]) ;;
 347   default) AC_SUBST(ENABLE_DOXYGEN,[0]) ;;
 348   *) AC_MSG_ERROR([Invalid setting for --enable-doxygen. Use "yes" or "no"]) ;;
 349 esac
 350
 351 dnl Allow disablement of threads
 352 AC_ARG_ENABLE(threads,
 353               AS_HELP_STRING([--enable-threads],
 354                              [Use threads if available (default is YES)]),,
 355                              enableval=default)
 356 case "$enableval" in
 357   yes) AC_SUBST(ENABLE_THREADS,[1]) ;;
 358   no)  AC_SUBST(ENABLE_THREADS,[0]) ;;
 359   default) AC_SUBST(ENABLE_THREADS,[1]) ;;
 360   *) AC_MSG_ERROR([Invalid setting for --enable-threads. Use "yes" or "no"]) ;;
 361 esac
 362 AC_DEFINE_UNQUOTED([ENABLE_THREADS],$ENABLE_THREADS,[Define if threads enabled])
 363
 364 dnl Allow building with position independent code
 365 AC_ARG_ENABLE(pic,
 366   AS_HELP_STRING([--enable-pic],
 367                  [Build LLVM with Position Independent Code (default is NO)]),,
 368                  enableval=default)
 369 case "$enableval" in
 370   yes) AC_SUBST(ENABLE_PIC,[1]) ;;
 371   no)  AC_SUBST(ENABLE_PIC,[0]) ;;
 372   default) AC_SUBST(ENABLE_PIC,[0]) ;;
 373   *) AC_MSG_ERROR([Invalid setting for --enable-pic. Use "yes" or "no"]) ;;
 374 esac
 375 AC_DEFINE_UNQUOTED([ENABLE_PIC],$ENABLE_PIC,
 376                    [Define if position independent code is enabled])
 377
 378 dnl Allow specific targets to be specified for building (or not)
 379 TARGETS_TO_BUILD=""
 380 AC_ARG_ENABLE([targets],AS_HELP_STRING([--enable-targets],
 381     [Build specific host targets: all,host-only,{target-name} (default=all)]),,
 382     enableval=all)
 383 case "$enableval" in
 384   all) TARGETS_TO_BUILD="X86 Sparc PowerPC Alpha IA64 ARM Mips CellSPU PIC16 CBackend MSIL CppBackend" ;;
 385   host-only)
 386     case "$llvm_cv_target_arch" in
 387       x86)     TARGETS_TO_BUILD="X86" ;;
 388       x86_64)  TARGETS_TO_BUILD="X86" ;;
 389       Sparc)   TARGETS_TO_BUILD="Sparc" ;;
 390       PowerPC) TARGETS_TO_BUILD="PowerPC" ;;
 391       Alpha)   TARGETS_TO_BUILD="Alpha" ;;
 392       IA64)    TARGETS_TO_BUILD="IA64" ;;
 393       ARM)     TARGETS_TO_BUILD="ARM" ;;
 394       Mips)    TARGETS_TO_BUILD="Mips" ;;
 395       CellSPU|SPU) TARGETS_TO_BUILD="CellSPU" ;;
 396       PIC16)   TARGETS_TO_BUILD="PIC16" ;;
 397       *)       AC_MSG_ERROR([Can not set target to build]) ;;
 398     esac
 399     ;;
 400   *)for a_target in `echo $enableval|sed -e 's/,/ /g' ` ; do
 401       case "$a_target" in
 402         x86)     TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 403         x86_64)  TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 404         sparc)   TARGETS_TO_BUILD="Sparc $TARGETS_TO_BUILD" ;;
 405         powerpc) TARGETS_TO_BUILD="PowerPC $TARGETS_TO_BUILD" ;;
 406         alpha)   TARGETS_TO_BUILD="Alpha $TARGETS_TO_BUILD" ;;
 407         ia64)    TARGETS_TO_BUILD="IA64 $TARGETS_TO_BUILD" ;;
 408         arm)     TARGETS_TO_BUILD="ARM $TARGETS_TO_BUILD" ;;
 409         mips)    TARGETS_TO_BUILD="Mips $TARGETS_TO_BUILD" ;;
 410         spu)     TARGETS_TO_BUILD="CellSPU $TARGETS_TO_BUILD" ;;
 411         pic16)   TARGETS_TO_BUILD="PIC16 $TARGETS_TO_BUILD" ;;
 412         cbe)     TARGETS_TO_BUILD="CBackend $TARGETS_TO_BUILD" ;;
 413         msil)    TARGETS_TO_BUILD="MSIL $TARGETS_TO_BUILD" ;;
 414         cpp)     TARGETS_TO_BUILD="CppBackend $TARGETS_TO_BUILD" ;;
 415         *) AC_MSG_ERROR([Unrecognized target $a_target]) ;;
 416       esac
 417   done
 418   ;;
 419 esac
 420 AC_SUBST(TARGETS_TO_BUILD,$TARGETS_TO_BUILD)
 421
 422 dnl Prevent the CBackend from using printf("%a") for floating point so older
 423 dnl C compilers that cannot deal with the 0x0p+0 hex floating point format
 424 dnl can still compile the CBE's output
 425 AC_ARG_ENABLE([cbe-printf-a],AS_HELP_STRING([--enable-cbe-printf-a],
 426   [Enable C Backend output with hex floating point via %a  (default is YES)]),,
 427   enableval=default)
 428 case "$enableval" in
 429   yes) AC_SUBST(ENABLE_CBE_PRINTF_A,[1]) ;;
 430   no)  AC_SUBST(ENABLE_CBE_PRINTF_A,[0]) ;;
 431   default)  AC_SUBST(ENABLE_CBE_PRINTF_A,[1]) ;;
 432   *) AC_MSG_ERROR([Invalid setting for --enable-cbe-printf-a. Use "yes" or "no"]) ;;
 433 esac
 434 AC_DEFINE_UNQUOTED([ENABLE_CBE_PRINTF_A],$ENABLE_CBE_PRINTF_A,
 435                    [Define if CBE is enabled for printf %a output])
 436
 437 dnl Allow a specific llvm-gcc/llvm-g++ pair to be used with this LLVM config.
 438 AC_ARG_WITH(llvmgccdir,
 439   AS_HELP_STRING([--with-llvmgccdir],
 440     [Specify location of llvm-gcc install dir (default searches PATH)]),,
 441     withval=default)
 442 case "$withval" in
 443   default) WITH_LLVMGCCDIR=default ;;
 444   /* | [[A-Za-z]]:[[\\/]]*)      WITH_LLVMGCCDIR=$withval ;;
 445   *) AC_MSG_ERROR([Invalid path for --with-llvmgccdir. Provide full path]) ;;
 446 esac
 447
 448 dnl Allow a specific llvm-gcc compiler to be used with this LLVM config.
 449 AC_ARG_WITH(llvmgcc,
 450   AS_HELP_STRING([--with-llvmgcc],
 451     [Specify location of llvm-gcc driver (default searches PATH)]),
 452     LLVMGCC=$with_llvmgcc
 453       WITH_LLVMGCCDIR="",)
 454
 455 dnl Allow a specific llvm-g++ compiler to be used with this LLVM config.
 456 AC_ARG_WITH(llvmgxx,
 457   AS_HELP_STRING([--with-llvmgxx],
 458     [Specify location of llvm-g++ driver (default searches PATH)]),
 459     LLVMGXX=$with_llvmgxx
 460     WITH_LLVMGCCDIR="",)
 461
 462 if test -n "$LLVMGCC" && test -z "$LLVMGXX"; then
 463    AC_MSG_ERROR([Invalid llvm-g++. Use --with-llvmgxx when --with-llvmgcc is used]);
 464 fi
 465
 466 if test -n "$LLVMGXX" && test -z "$LLVMGCC"; then
 467    AC_MSG_ERROR([Invalid llvm-gcc. Use --with-llvmgcc when --with-llvmgxx is used]);
 468 fi
 469
 470 dnl Specify extra build options
 471 AC_ARG_WITH(extra-options,
 472   AS_HELP_STRING([--with-extra-options],
 473                  [Specify addtional options to compile LLVM with]),,
 474                  withval=default)
 475 case "$withval" in
 476   default) EXTRA_OPTIONS= ;;
 477   *) EXTRA_OPTIONS=$withval ;;
 478 esac
 479 AC_SUBST(EXTRA_OPTIONS,$EXTRA_OPTIONS)
 480
 481 dnl Allow specific bindings to be specified for building (or not)
 482 AC_ARG_ENABLE([bindings],AS_HELP_STRING([--enable-bindings],
 483     [Build specific language bindings: all,auto,none,{binding-name} (default=auto)]),,
 484     enableval=default)
 485 BINDINGS_TO_BUILD=""
 486 case "$enableval" in
 487   yes | default | auto) BINDINGS_TO_BUILD="auto" ;;
 488   all ) BINDINGS_TO_BUILD="ocaml" ;;
 489   none | no) BINDINGS_TO_BUILD="" ;;
 490   *)for a_binding in `echo $enableval|sed -e 's/,/ /g' ` ; do
 491       case "$a_binding" in
 492         ocaml) BINDINGS_TO_BUILD="ocaml $BINDINGS_TO_BUILD" ;;
 493         *) AC_MSG_ERROR([Unrecognized binding $a_binding]) ;;
 494       esac
 495   done
 496   ;;
 497 esac
 498
 499 dnl Allow the ocaml libdir to be overridden. This could go in a configure
 500 dnl script for bindings/ocaml/configure, except that its auto value depends on
 501 dnl OCAMLC, which is found here to support tests.
 502 AC_ARG_WITH([ocaml-libdir],
 503   [AS_HELP_STRING([--with-ocaml-libdir],
 504     [Specify install location for ocaml bindings (default is stdlib)])],
 505   [],
 506   [withval=auto])
 507 case "$withval" in
 508   auto) with_ocaml_libdir="$withval" ;;
 509   /* | [[A-Za-z]]:[[\\/]]*) with_ocaml_libdir="$withval" ;;
 510   *) AC_MSG_ERROR([Invalid path for --with-ocaml-libdir. Provide full path]) ;;
 511 esac
 512
 513 dnl===-----------------------------------------------------------------------===
 514 dnl===
 515 dnl=== SECTION 4: Check for programs we need and that they are the right version
 516 dnl===
 517 dnl===-----------------------------------------------------------------------===
 518
 519 dnl Check for compilation tools
 520 AC_PROG_CPP
 521 AC_PROG_CC(gcc)
 522 AC_PROG_CXX(g++)
 523 AC_PROG_FLEX
 524 AC_PROG_BISON
 525
 526 AC_PROG_NM
 527 AC_SUBST(NM)
 528
 529 dnl Check for the tools that the makefiles require
 530 AC_CHECK_GNU_MAKE
 531 AC_PROG_LN_S
 532 AC_PATH_PROG(CMP, [cmp], [cmp])
 533 AC_PATH_PROG(CP, [cp], [cp])
 534 AC_PATH_PROG(DATE, [date], [date])
 535 AC_PATH_PROG(FIND, [find], [find])
 536 AC_PATH_PROG(GREP, [grep], [grep])
 537 AC_PATH_PROG(MKDIR,[mkdir],[mkdir])
 538 AC_PATH_PROG(MV,   [mv],   [mv])
 539 AC_PROG_RANLIB
 540 AC_PATH_PROG(RM,   [rm],   [rm])
 541 AC_PATH_PROG(SED,  [sed],  [sed])
 542 AC_PATH_PROG(TAR,  [tar],  [gtar])
 543 AC_PATH_PROG(BINPWD,[pwd],  [pwd])
 544
 545 dnl Looking for misc. graph plotting software
 546 AC_PATH_PROG(GRAPHVIZ, [Graphviz], [echo Graphviz])
 547 if test "$GRAPHVIZ" != "echo Graphviz" ; then
 548   AC_DEFINE([HAVE_GRAPHVIZ],[1],[Define if the Graphviz program is available])
 549   dnl If we're targeting for mingw we should emit windows paths, not msys
 550   if test "$llvm_cv_os_type" = "MingW" ; then
 551     GRAPHVIZ=`echo $GRAPHVIZ | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 552   fi
 553   AC_DEFINE_UNQUOTED([LLVM_PATH_GRAPHVIZ],"$GRAPHVIZ${EXEEXT}",
 554    [Define to path to Graphviz program if found or 'echo Graphviz' otherwise])
 555 fi
 556 AC_PATH_PROG(DOT, [dot], [echo dot])
 557 if test "$DOT" != "echo dot" ; then
 558   AC_DEFINE([HAVE_DOT],[1],[Define if the dot program is available])
 559   dnl If we're targeting for mingw we should emit windows paths, not msys
 560   if test "$llvm_cv_os_type" = "MingW" ; then
 561     DOT=`echo $DOT | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 562   fi
 563   AC_DEFINE_UNQUOTED([LLVM_PATH_DOT],"$DOT${EXEEXT}",
 564    [Define to path to dot program if found or 'echo dot' otherwise])
 565 fi
 566 AC_PATH_PROGS(GV, [gv gsview32], [echo gv])
 567 if test "$GV" != "echo gv" ; then
 568   AC_DEFINE([HAVE_GV],[1],[Define if the gv program is available])
 569   dnl If we're targeting for mingw we should emit windows paths, not msys
 570   if test "$llvm_cv_os_type" = "MingW" ; then
 571     GV=`echo $GV | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 572   fi
 573   AC_DEFINE_UNQUOTED([LLVM_PATH_GV],"$GV${EXEEXT}",
 574    [Define to path to gv program if found or 'echo gv' otherwise])
 575 fi
 576 AC_PATH_PROG(DOTTY, [dotty], [echo dotty])
 577 if test "$DOTTY" != "echo dotty" ; then
 578   AC_DEFINE([HAVE_DOTTY],[1],[Define if the dotty program is available])
 579   dnl If we're targeting for mingw we should emit windows paths, not msys
 580   if test "$llvm_cv_os_type" = "MingW" ; then
 581     DOTTY=`echo $DOTTY | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 582   fi
 583   AC_DEFINE_UNQUOTED([LLVM_PATH_DOTTY],"$DOTTY${EXEEXT}",
 584    [Define to path to dotty program if found or 'echo dotty' otherwise])
 585 fi
 586
 587 dnl Look for a sufficiently recent version of Perl.
 588 LLVM_PROG_PERL([5.006])
 589 AC_SUBST(PERL)
 590 if test x"$PERL" = xnone; then
 591    AC_SUBST(HAVE_PERL,0)
 592    AC_MSG_ERROR([perl is required but was not found, please install it])
 593 else
 594    AC_SUBST(HAVE_PERL,1)
 595 fi
 596
 597 dnl Find the install program
 598 AC_PROG_INSTALL
 599
 600 dnl Checks for documentation and testing tools that we can do without. If these
 601 dnl are not found then they are set to "true" which always succeeds but does
 602 dnl nothing. This just lets the build output show that we could have done
 603 dnl something if the tool was available.
 604 AC_PATH_PROG(BZIP2, [bzip2])
 605 AC_PATH_PROG(DOXYGEN, [doxygen])
 606 AC_PATH_PROG(GROFF, [groff])
 607 AC_PATH_PROG(GZIP, [gzip])
 608 AC_PATH_PROG(POD2HTML, [pod2html])
 609 AC_PATH_PROG(POD2MAN, [pod2man])
 610 AC_PATH_PROG(RUNTEST, [runtest])
 611 DJ_AC_PATH_TCLSH
 612 AC_PATH_PROG(ZIP, [zip])
 613 AC_PATH_PROGS(OCAMLC, [ocamlc.opt ocamlc])
 614 AC_PATH_PROGS(OCAMLOPT, [ocamlopt.opt ocamlopt])
 615 AC_PATH_PROGS(OCAMLDEP, [ocamldep.opt ocamldep])
 616 AC_PATH_PROGS(OCAMLDOC, [ocamldoc.opt ocamldoc])
 617
 618 dnl Determine if the linker supports the -R option.
 619 AC_LINK_USE_R
 620
 621 dnl Check for libtool and the library that has dlopen function (which must come
 622 dnl before the AC_PROG_LIBTOOL check in order to enable dlopening libraries with
 623 dnl libtool).
 624 AC_LIBTOOL_DLOPEN
 625 AC_LIB_LTDL
 626 AC_PROG_LIBTOOL
 627
 628 if test "$lt_cv_dlopen_self" = "yes" ; then
 629   AC_DEFINE([CAN_DLOPEN_SELF],[1],
 630               [Define if dlopen(0) will open the symbols of the program])
 631 fi
 632
 633 if test "$WITH_LLVMGCCDIR" = "default" ; then
 634   LLVMGCC="llvm-gcc${EXEEXT}"
 635   LLVMGXX="llvm-g++${EXEEXT}"
 636   AC_PATH_PROG(LLVMGCC, $LLVMGCC, [])
 637   AC_PATH_PROG(LLVMGXX, $LLVMGXX, [])
 638 else
 639   if test -z "$LLVMGCC"; then
 640     LLVMGCC="$WITH_LLVMGCCDIR/bin/llvm-gcc${EXEEXT}"
 641   fi
 642   if test -z "$LLVMGXX"; then
 643     LLVMGXX="$WITH_LLVMGCCDIR/bin/llvm-g++${EXEEXT}"
 644   fi
 645   AC_SUBST(LLVMGCC,$LLVMGCC)
 646   AC_SUBST(LLVMGXX,$LLVMGXX)
 647 fi
 648
 649 AC_MSG_CHECKING([tool compatibility])
 650
 651 dnl Ensure that compilation tools are GCC or a GNU compatible compiler such as
 652 dnl ICC; we use GCC specific options in the makefiles so the compiler needs
 653 dnl to support those options.
 654 dnl "icc" emits gcc signatures
 655 dnl "icc -no-gcc" emits no gcc signature BUT is still compatible
 656 ICC=no
 657 IXX=no
 658 case $CC in
 659   icc*|icpc*)
 660     ICC=yes
 661     IXX=yes
 662     ;;
 663    *)
 664     ;;
 665 esac
 666
 667 if test "$GCC" != "yes" && test "$ICC" != "yes"
 668 then
 669   AC_MSG_ERROR([gcc|icc required but not found])
 670 fi
 671
 672 dnl Ensure that compilation tools are GCC; we use GCC specific extensions
 673 if test "$GXX" != "yes" && test "$IXX" != "yes"
 674 then
 675   AC_MSG_ERROR([g++|icc required but not found])
 676 fi
 677
 678 dnl Verify that GCC is version 3.0 or higher
 679 if test "$GCC" = "yes"
 680 then
 681   AC_COMPILE_IFELSE([[#if !defined(__GNUC__) || __GNUC__ < 3
 682 #error Unsupported GCC version
 683 #endif
 684 ]], [], [AC_MSG_ERROR([gcc 3.x required, but you have a lower version])])
 685 fi
 686
 687 dnl Check for GNU Make.  We use its extensions, so don't build without it
 688 if test -z "$llvm_cv_gnu_make_command"
 689 then
 690   AC_MSG_ERROR([GNU Make required but not found])
 691 fi
 692
 693 dnl Tool compatibility is okay if we make it here.
 694 AC_MSG_RESULT([ok])
 695
 696 dnl===-----------------------------------------------------------------------===
 697 dnl===
 698 dnl=== SECTION 5: Check for libraries
 699 dnl===
 700 dnl===-----------------------------------------------------------------------===
 701
 702 dnl libelf is for sparc only; we can ignore it if we don't have it
 703 AC_CHECK_LIB(elf, elf_begin)
 704 AC_CHECK_LIB(m,sin)
 705 if test "$llvm_cv_os_type" = "MingW" ; then
 706   AC_CHECK_LIB(imagehlp, main)
 707   AC_CHECK_LIB(psapi, main)
 708 fi
 709
 710 dnl dlopen() is required for plugin support.
 711 AC_SEARCH_LIBS(dlopen,dl,AC_DEFINE([HAVE_DLOPEN],[1],
 712                [Define if dlopen() is available on this platform.]),
 713                AC_MSG_WARN([dlopen() not found - disabling plugin support]))
 714
 715 dnl mallinfo is optional; the code can compile (minus features) without it
 716 AC_SEARCH_LIBS(mallinfo,malloc,AC_DEFINE([HAVE_MALLINFO],[1],
 717                [Define if mallinfo() is available on this platform.]))
 718
 719 dnl pthread locking functions are optional - but llvm will not be thread-safe
 720 dnl without locks.
 721 if test "$ENABLE_THREADS" -eq 1 ; then
 722   AC_CHECK_LIB(pthread,pthread_mutex_init)
 723   AC_SEARCH_LIBS(pthread_mutex_lock,pthread,
 724                  AC_DEFINE([HAVE_PTHREAD_MUTEX_LOCK],[1],
 725                            [Have pthread_mutex_lock]))
 726 fi
 727
 728 dnl Allow extra x86-disassembler library
 729 AC_ARG_WITH(udis86,
 730   AS_HELP_STRING([--with-udis86=<path>],
 731     [Use udis86 external x86 disassembler library]),
 732     [
 733       AC_SUBST(USE_UDIS86, [1])
 734       case "$withval" in
 735         /usr/lib|yes) ;;
 736         *) LDFLAGS="$LDFLAGS -L${withval}" ;;
 737       esac
 738       AC_CHECK_LIB(udis86, ud_init, [], [
 739         echo "Error! You need to have libudis86 around."
 740         exit -1
 741       ])
 742     ],
 743     AC_SUBST(USE_UDIS86, [0]))
 744 AC_DEFINE_UNQUOTED([USE_UDIS86],$USE_UDIS86,
 745                    [Define if use udis86 library])
 746
 747 dnl===-----------------------------------------------------------------------===
 748 dnl===
 749 dnl=== SECTION 6: Check for header files
 750 dnl===
 751 dnl===-----------------------------------------------------------------------===
 752
 753 dnl First, use autoconf provided macros for specific headers that we need
 754 dnl We don't check for ancient stuff or things that are guaranteed to be there
 755 dnl by the C++ standard. We always use the <cfoo> versions of <foo.h> C headers.
 756 dnl Generally we're looking for POSIX headers.
 757 AC_HEADER_DIRENT
 758 AC_HEADER_MMAP_ANONYMOUS
 759 AC_HEADER_STAT
 760 AC_HEADER_STDC
 761 AC_HEADER_SYS_WAIT
 762 AC_HEADER_TIME
 763
 764 AC_CHECK_HEADERS([dlfcn.h execinfo.h fcntl.h inttypes.h limits.h link.h])
 765 AC_CHECK_HEADERS([malloc.h setjmp.h signal.h stdint.h unistd.h utime.h])
 766 AC_CHECK_HEADERS([windows.h])
 767 AC_CHECK_HEADERS([sys/mman.h sys/param.h sys/resource.h sys/time.h])
 768 AC_CHECK_HEADERS([sys/types.h malloc/malloc.h mach/mach.h])
 769 if test "$ENABLE_THREADS" -eq 1 ; then
 770   AC_CHECK_HEADERS(pthread.h,
 771                   AC_SUBST(HAVE_PTHREAD, 1),
 772                    AC_SUBST(HAVE_PTHREAD, 0))
 773 else
 774   AC_SUBST(HAVE_PTHREAD, 0)
 775 fi
 776
 777 dnl===-----------------------------------------------------------------------===
 778 dnl===
 779 dnl=== SECTION 7: Check for types and structures
 780 dnl===
 781 dnl===-----------------------------------------------------------------------===
 782
 783 AC_HUGE_VAL_CHECK
 784 AC_TYPE_PID_T
 785 AC_TYPE_SIZE_T
 786 AC_TYPE_SIGNAL
 787 AC_STRUCT_TM
 788 AC_CHECK_TYPES([int64_t],,AC_MSG_ERROR([Type int64_t required but not found]))
 789 AC_CHECK_TYPES([uint64_t],,
 790          AC_CHECK_TYPES([u_int64_t],,
 791          AC_MSG_ERROR([Type uint64_t or u_int64_t required but not found])))
 792
 793 dnl===-----------------------------------------------------------------------===
 794 dnl===
 795 dnl=== SECTION 8: Check for specific functions needed
 796 dnl===
 797 dnl===-----------------------------------------------------------------------===
 798
 799 AC_CHECK_FUNCS([backtrace ceilf floorf roundf rintf nearbyintf getcwd ])
 800 AC_CHECK_FUNCS([powf fmodf strtof round ])
 801 AC_CHECK_FUNCS([getpagesize getrusage getrlimit setrlimit gettimeofday ])
 802 AC_CHECK_FUNCS([isatty mkdtemp mkstemp ])
 803 AC_CHECK_FUNCS([mktemp realpath sbrk setrlimit strdup strerror strerror_r ])
 804 AC_CHECK_FUNCS([strtoll strtoq sysconf malloc_zone_statistics ])
 805 AC_CHECK_FUNCS([setjmp longjmp sigsetjmp siglongjmp])
 806 AC_C_PRINTF_A
 807 AC_FUNC_ALLOCA
 808 AC_FUNC_RAND48
 809
 810 dnl Check for variations in the Standard C++ library and STL. These macros are
 811 dnl provided by LLVM in the autoconf/m4 directory.
 812 AC_CXX_HAVE_HASH_MAP
 813 AC_CXX_HAVE_HASH_SET
 814 AC_CXX_HAVE_STD_ITERATOR
 815 AC_CXX_HAVE_BI_ITERATOR
 816 AC_CXX_HAVE_FWD_ITERATOR
 817 AC_FUNC_ISNAN
 818 AC_FUNC_ISINF
 819
 820 dnl Check for mmap support.We also need to know if /dev/zero is required to
 821 dnl be opened for allocating RWX memory.
 822 dnl Make sure we aren't attempting to configure for an unknown system
 823 if test "$llvm_cv_platform_type" = "Unix" ; then
 824   AC_FUNC_MMAP
 825   AC_FUNC_MMAP_FILE
 826   AC_NEED_DEV_ZERO_FOR_MMAP
 827
 828   if test "$ac_cv_func_mmap_fixed_mapped" = "no"
 829   then
 830     AC_MSG_WARN([mmap() of a fixed address required but not supported])
 831   fi
 832   if test "$ac_cv_func_mmap_file" = "no"
 833   then
 834     AC_MSG_WARN([mmap() of files required but not found])
 835   fi
 836 fi
 837
 838 dnl===-----------------------------------------------------------------------===
 839 dnl===
 840 dnl=== SECTION 9: Additional checks, variables, etc.
 841 dnl===
 842 dnl===-----------------------------------------------------------------------===
 843
 844 dnl Check, whether __dso_handle is present
 845 AC_CHECK_FUNCS([__dso_handle])
 846
 847 dnl See if the llvm-gcc executable can compile to LLVM assembly
 848 AC_CACHE_CHECK([whether llvm-gcc is sane],[llvm_cv_llvmgcc_sanity],
 849 [llvm_cv_llvmgcc_sanity="no"
 850 if test -x "$LLVMGCC" ; then
 851   cp /dev/null conftest.c
 852   "$LLVMGCC" -emit-llvm -S -o - conftest.c | \
 853       grep 'target datalayout =' > /dev/null 2>&1
 854   if test $? -eq 0 ; then
 855     llvm_cv_llvmgcc_sanity="yes"
 856   fi
 857   rm conftest.c
 858 fi])
 859
 860 dnl Since we have a sane llvm-gcc, identify it and its sub-tools
 861 if test "$llvm_cv_llvmgcc_sanity" = "yes" ; then
 862   AC_MSG_CHECKING([llvm-gcc component support])
 863   llvmcc1path=`"$LLVMGCC" --print-prog-name=cc1`
 864   AC_SUBST(LLVMCC1,$llvmcc1path)
 865   llvmcc1pluspath=`"$LLVMGCC" --print-prog-name=cc1plus`
 866   AC_SUBST(LLVMCC1PLUS,$llvmcc1pluspath)
 867   llvmgccdir=`echo "$llvmcc1path" | sed 's,/libexec/.*,,'`
 868   AC_SUBST(LLVMGCCDIR,$llvmgccdir)
 869   llvmgcclibexec=`echo "$llvmcc1path" | sed 's,/cc1,,'`
 870   AC_SUBST(LLVMGCCLIBEXEC,$llvmgcclibexec)
 871   llvmgccversion=[`"$LLVMGCC" -dumpversion 2>&1 | sed 's/^\([0-9.]*\).*/\1/'`]
 872   llvmgccmajvers=[`echo $llvmgccversion | sed 's/^\([0-9]\).*/\1/'`]
 873   AC_SUBST(LLVMGCC_VERSION,$llvmgccversion)
 874   AC_SUBST(LLVMGCC_MAJVERS,$llvmgccmajvers)
 875   llvmgcclangs=[`"$LLVMGCC" -v --help 2>&1 | grep '^Configured with:' | sed 's/^.*--enable-languages=\([^ ]*\).*/\1/'`]
 876   AC_SUBST(LLVMGCC_LANGS,$llvmgcclangs)
 877   AC_MSG_RESULT([ok])
 878 fi
 879
 880 dnl Propagate the shared library extension that the libltdl checks did to
 881 dnl the Makefiles so we can use it there too
 882 AC_SUBST(SHLIBEXT,$libltdl_cv_shlibext)
 883
 884 # Translate the various configuration directories and other basic
 885 # information into substitutions that will end up in Makefile.config.in
 886 # that these configured values can be used by the makefiles
 887 if test "${prefix}" = "NONE" ; then
 888   prefix="/usr/local"
 889 fi
 890 eval LLVM_PREFIX="${prefix}";
 891 eval LLVM_BINDIR="${prefix}/bin";
 892 eval LLVM_LIBDIR="${prefix}/lib";
 893 eval LLVM_DATADIR="${prefix}/share/llvm";
 894 eval LLVM_DOCSDIR="${prefix}/docs/llvm";
 895 eval LLVM_ETCDIR="${prefix}/etc/llvm";
 896 eval LLVM_INCLUDEDIR="${prefix}/include";
 897 eval LLVM_INFODIR="${prefix}/info";
 898 eval LLVM_MANDIR="${prefix}/man";
 899 LLVM_CONFIGTIME=`date`
 900 AC_SUBST(LLVM_PREFIX)
 901 AC_SUBST(LLVM_BINDIR)
 902 AC_SUBST(LLVM_LIBDIR)
 903 AC_SUBST(LLVM_DATADIR)
 904 AC_SUBST(LLVM_DOCSDIR)
 905 AC_SUBST(LLVM_ETCDIR)
 906 AC_SUBST(LLVM_INCLUDEDIR)
 907 AC_SUBST(LLVM_INFODIR)
 908 AC_SUBST(LLVM_MANDIR)
 909 AC_SUBST(LLVM_CONFIGTIME)
 910
 911 # Place the various directores into the config.h file as #defines so that we
 912 # can know about the installation paths within LLVM.
 913 AC_DEFINE_UNQUOTED(LLVM_PREFIX,"$LLVM_PREFIX",
 914                    [Installation prefix directory])
 915 AC_DEFINE_UNQUOTED(LLVM_BINDIR, "$LLVM_BINDIR",
 916                    [Installation directory for binary executables])
 917 AC_DEFINE_UNQUOTED(LLVM_LIBDIR, "$LLVM_LIBDIR",
 918                    [Installation directory for libraries])
 919 AC_DEFINE_UNQUOTED(LLVM_DATADIR, "$LLVM_DATADIR",
 920                    [Installation directory for data files])
 921 AC_DEFINE_UNQUOTED(LLVM_DOCSDIR, "$LLVM_DOCSDIR",
 922                    [Installation directory for documentation])
 923 AC_DEFINE_UNQUOTED(LLVM_ETCDIR, "$LLVM_ETCDIR",
 924                    [Installation directory for config files])
 925 AC_DEFINE_UNQUOTED(LLVM_INCLUDEDIR, "$LLVM_INCLUDEDIR",
 926                    [Installation directory for include files])
 927 AC_DEFINE_UNQUOTED(LLVM_INFODIR, "$LLVM_INFODIR",
 928                    [Installation directory for .info files])
 929 AC_DEFINE_UNQUOTED(LLVM_MANDIR, "$LLVM_MANDIR",
 930                    [Installation directory for man pages])
 931 AC_DEFINE_UNQUOTED(LLVM_CONFIGTIME, "$LLVM_CONFIGTIME",
 932                    [Time at which LLVM was configured])
 933 AC_DEFINE_UNQUOTED(LLVM_HOSTTRIPLE, "$host",
 934                    [Host triple we were built on])
 935
 936 # Determine which bindings to build.
 937 if test "$BINDINGS_TO_BUILD" = auto ; then
 938   BINDINGS_TO_BUILD=""
 939   if test "x$OCAMLC" != x -a "x$OCAMLDEP" != x ; then
 940     BINDINGS_TO_BUILD="ocaml $BINDINGS_TO_BUILD"
 941   fi
 942 fi
 943 AC_SUBST(BINDINGS_TO_BUILD,$BINDINGS_TO_BUILD)
 944
 945 # This isn't really configurey, but it avoids having to repeat the list in
 946 # other files.
 947 AC_SUBST(ALL_BINDINGS,ocaml)
 948
 949 # Do any work necessary to ensure that bindings have what they need.
 950 binding_prereqs_failed=0
 951 for a_binding in $BINDINGS_TO_BUILD ; do
 952   case "$a_binding" in
 953   ocaml)
 954     if test "x$OCAMLC" = x ; then
 955       AC_MSG_WARN([--enable-bindings=ocaml specified, but ocamlc not found. Try configure OCAMLC=/path/to/ocamlc])
 956       binding_prereqs_failed=1
 957     fi
 958     if test "x$OCAMLDEP" = x ; then
 959       AC_MSG_WARN([--enable-bindings=ocaml specified, but ocamldep not found. Try configure OCAMLDEP=/path/to/ocamldep])
 960       binding_prereqs_failed=1
 961     fi
 962     if test "x$OCAMLOPT" = x ; then
 963       AC_MSG_WARN([--enable-bindings=ocaml specified, but ocamlopt not found. Try configure OCAMLOPT=/path/to/ocamlopt])
 964       dnl ocamlopt is optional!
 965     fi
 966     if test "x$with_ocaml_libdir" != xauto ; then
 967       AC_SUBST(OCAML_LIBDIR,$with_ocaml_libdir)
 968     else
 969       ocaml_stdlib="`"$OCAMLC" -where`"
 970       if test "$LLVM_PREFIX" '<' "$ocaml_stdlib" -a "$ocaml_stdlib" '<' "$LLVM_PREFIX~"
 971       then
 972         # ocaml stdlib is beneath our prefix; use stdlib
 973         AC_SUBST(OCAML_LIBDIR,$ocaml_stdlib)
 974       else
 975         # ocaml stdlib is outside our prefix; use libdir/ocaml
 976         AC_SUBST(OCAML_LIBDIR,$LLVM_LIBDIR/ocaml)
 977       fi
 978     fi
 979     ;;
 980   esac
 981 done
 982 if test "$binding_prereqs_failed" = 1 ; then
 983   AC_MSG_ERROR([Prequisites for bindings not satisfied. Fix them or use configure --disable-bindings.])
 984 fi
 985
 986 dnl Determine if the compiler supports -fvisibility-inlines-hidden.
 987 AC_CXX_USE_VISIBILITY_INLINES_HIDDEN
 988
 989 dnl===-----------------------------------------------------------------------===
 990 dnl===
 991 dnl=== SECTION 10: Specify the output files and generate it
 992 dnl===
 993 dnl===-----------------------------------------------------------------------===
 994
 995 dnl Configure header files
 996 dnl WARNING: dnl If you add or remove any of the following config headers, then
 997 dnl you MUST also update Makefile.rules so that the variable FilesToConfig
 998 dnl contains the same list of files as AC_CONFIG_HEADERS below. This ensures the
 999 dnl files can be updated automatically when their *.in sources change.
1000 AC_CONFIG_HEADERS([include/llvm/Config/config.h])
1001 AC_CONFIG_HEADERS([include/llvm/Support/DataTypes.h])
1002 AC_CONFIG_HEADERS([include/llvm/ADT/hash_map.h])
1003 AC_CONFIG_HEADERS([include/llvm/ADT/hash_set.h])
1004 AC_CONFIG_HEADERS([include/llvm/ADT/iterator.h])
1005
1006 dnl Configure the makefile's configuration data
1007 AC_CONFIG_FILES([Makefile.config])
1008
1009 dnl Configure the RPM spec file for LLVM
1010 AC_CONFIG_FILES([llvm.spec])
1011
1012 dnl Configure doxygen's configuration file
1013 AC_CONFIG_FILES([docs/doxygen.cfg])
1014
1015 dnl Do the first stage of configuration for llvm-config.in.
1016 AC_CONFIG_FILES([tools/llvm-config/llvm-config.in])
1017
1018 dnl Do special configuration of Makefiles
1019 AC_CONFIG_COMMANDS([setup],,[llvm_src="${srcdir}"])
1020 AC_CONFIG_MAKEFILE(Makefile)
1021 AC_CONFIG_MAKEFILE(Makefile.common)
1022 AC_CONFIG_MAKEFILE(examples/Makefile)
1023 AC_CONFIG_MAKEFILE(lib/Makefile)
1024 AC_CONFIG_MAKEFILE(runtime/Makefile)
1025 AC_CONFIG_MAKEFILE(test/Makefile)
1026 AC_CONFIG_MAKEFILE(test/Makefile.tests)
1027 AC_CONFIG_MAKEFILE(tools/Makefile)
1028 AC_CONFIG_MAKEFILE(utils/Makefile)
1029 AC_CONFIG_MAKEFILE(projects/Makefile)
1030 AC_CONFIG_MAKEFILE(bindings/Makefile)
1031 AC_CONFIG_MAKEFILE(bindings/ocaml/Makefile.ocaml)
1032
1033 dnl Finally, crank out the output
1034 AC_OUTPUT