autoconf/configure.ac

   1 dnl === configure.ac --------------------------------------------------------===
   2 dnl                     The LLVM Compiler Infrastructure
   3 dnl
   4 dnl This file is distributed under the University of Illinois Open Source
   5 dnl License. See LICENSE.TXT for details.
   6 dnl
   7 dnl===-----------------------------------------------------------------------===
   8 dnl This is the LLVM configuration script. It is processed by the autoconf
   9 dnl program to produce a script named configure. This script contains the
  10 dnl configuration checks that LLVM needs in order to support multiple platforms.
  11 dnl This file is composed of 10 sections per the recommended organization of
  12 dnl autoconf input defined in the autoconf documentation. As this file evolves,
  13 dnl please keep the various types of checks within their sections. The sections
  14 dnl are as follows:
  15 dnl
  16 dnl SECTION 1: Initialization & Setup
  17 dnl SECTION 2: Architecture, target, and host checks
  18 dnl SECTION 3: Command line arguments for the configure script.
  19 dnl SECTION 4: Check for programs we need and that they are the right version
  20 dnl SECTION 5: Check for libraries
  21 dnl SECTION 6: Check for header files
  22 dnl SECTION 7: Check for types and structures
  23 dnl SECTION 8: Check for specific functions needed
  24 dnl SECTION 9: Additional checks, variables, etc.
  25 dnl SECTION 10: Specify the output files and generate it
  26 dnl
  27 dnl===-----------------------------------------------------------------------===
  28 dnl===
  29 dnl=== SECTION 1: Initialization & Setup
  30 dnl===
  31 dnl===-----------------------------------------------------------------------===
  32 dnl Initialize autoconf and define the package name, version number and
  33 dnl email address for reporting bugs.
  34 AC_INIT([[llvm]],[[2.6svn]],[llvmbugs@cs.uiuc.edu])
  35
  36 dnl Provide a copyright substitution and ensure the copyright notice is included
  37 dnl in the output of --version option of the generated configure script.
  38 AC_SUBST(LLVM_COPYRIGHT,["Copyright (c) 2003-2008 University of Illinois at Urbana-Champaign."])
  39 AC_COPYRIGHT([Copyright (c) 2003-2008 University of Illinois at Urbana-Champaign.])
  40
  41 dnl Indicate that we require autoconf 2.59 or later. Ths is needed because we
  42 dnl use some autoconf macros only available in 2.59.
  43 AC_PREREQ(2.59)
  44
  45 dnl Verify that the source directory is valid. This makes sure that we are
  46 dnl configuring LLVM and not some other package (it validates --srcdir argument)
  47 AC_CONFIG_SRCDIR([lib/VMCore/Module.cpp])
  48
  49 dnl Place all of the extra autoconf files into the config subdirectory. Tell
  50 dnl various tools where the m4 autoconf macros are.
  51 AC_CONFIG_AUX_DIR([autoconf])
  52
  53 dnl Quit if the source directory has already been configured.
  54 dnl NOTE: This relies upon undocumented autoconf behavior.
  55 if test ${srcdir} != "." ; then
  56   if test -f ${srcdir}/include/llvm/Config/config.h ; then
  57     AC_MSG_ERROR([Already configured in ${srcdir}])
  58   fi
  59 fi
  60
  61 dnl Configure all of the projects present in our source tree. While we could
  62 dnl just AC_CONFIG_SUBDIRS on the set of directories in projects that have a
  63 dnl configure script, that usage of the AC_CONFIG_SUBDIRS macro is deprecated.
  64 dnl Instead we match on the known projects.
  65 for i in `ls ${srcdir}/projects`
  66 do
  67   if test -d ${srcdir}/projects/${i} ; then
  68     case ${i} in
  69       CVS) ;;
  70       sample)       AC_CONFIG_SUBDIRS([projects/sample])    ;;
  71       privbracket)  AC_CONFIG_SUBDIRS([projects/privbracket]) ;;
  72       llvm-stacker) AC_CONFIG_SUBDIRS([projects/llvm-stacker]) ;;
  73       # llvm-test is the old name of the test-suite, kept here for backwards
  74       # compatibility
  75       llvm-test)    AC_CONFIG_SUBDIRS([projects/llvm-test]) ;;
  76       test-suite)   AC_CONFIG_SUBDIRS([projects/test-suite]) ;;
  77       llvm-reopt)   AC_CONFIG_SUBDIRS([projects/llvm-reopt]);;
  78       llvm-gcc)     AC_CONFIG_SUBDIRS([projects/llvm-gcc])  ;;
  79       llvm-java)    AC_CONFIG_SUBDIRS([projects/llvm-java]) ;;
  80       llvm-tv)      AC_CONFIG_SUBDIRS([projects/llvm-tv])   ;;
  81       llvm-poolalloc) AC_CONFIG_SUBDIRS([projects/llvm-poolalloc]) ;;
  82       poolalloc)    AC_CONFIG_SUBDIRS([projects/poolalloc]) ;;
  83       llvm-kernel)  AC_CONFIG_SUBDIRS([projects/llvm-kernel]) ;;
  84       *)
  85         AC_MSG_WARN([Unknown project (${i}) won't be configured automatically])
  86         ;;
  87     esac
  88   fi
  89 done
  90
  91 dnl===-----------------------------------------------------------------------===
  92 dnl===
  93 dnl=== SECTION 2: Architecture, target, and host checks
  94 dnl===
  95 dnl===-----------------------------------------------------------------------===
  96
  97 dnl Check the target for which we're compiling and the host that will do the
  98 dnl compilations. This will tell us which LLVM compiler will be used for
  99 dnl compiling SSA into object code. This needs to be done early because
 100 dnl following tests depend on it.
 101 AC_CANONICAL_TARGET
 102
 103 dnl Determine the platform type and cache its value. This helps us configure
 104 dnl the System library to the correct build platform.
 105 AC_CACHE_CHECK([type of operating system we're going to host on],
 106                [llvm_cv_os_type],
 107 [case $host in
 108   *-*-aix*)
 109     llvm_cv_link_all_option="-Wl,--whole-archive"
 110     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 111     llvm_cv_os_type="AIX"
 112     llvm_cv_platform_type="Unix" ;;
 113   *-*-irix*)
 114     llvm_cv_link_all_option="-Wl,--whole-archive"
 115     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 116     llvm_cv_os_type="IRIX"
 117     llvm_cv_platform_type="Unix" ;;
 118   *-*-cygwin*)
 119     llvm_cv_link_all_option="-Wl,--whole-archive"
 120     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 121     llvm_cv_os_type="Cygwin"
 122     llvm_cv_platform_type="Unix" ;;
 123   *-*-darwin*)
 124     llvm_cv_link_all_option="-Wl,-all_load"
 125     llvm_cv_no_link_all_option="-Wl,-noall_load"
 126     llvm_cv_os_type="Darwin"
 127     llvm_cv_platform_type="Unix" ;;
 128   *-*-freebsd*)
 129     llvm_cv_link_all_option="-Wl,--whole-archive"
 130     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 131     llvm_cv_os_type="FreeBSD"
 132     llvm_cv_platform_type="Unix" ;;
 133   *-*-openbsd*)
 134     llvm_cv_link_all_option="-Wl,--whole-archive"
 135     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 136     llvm_cv_os_type="OpenBSD"
 137     llvm_cv_platform_type="Unix" ;;
 138   *-*-netbsd*)
 139     llvm_cv_link_all_option="-Wl,--whole-archive"
 140     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 141     llvm_cv_os_type="NetBSD"
 142     llvm_cv_platform_type="Unix" ;;
 143   *-*-dragonfly*)
 144     llvm_cv_link_all_option="-Wl,--whole-archive"
 145     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 146     llvm_cv_os_type="DragonFly"
 147     llvm_cv_platform_type="Unix" ;;
 148   *-*-hpux*)
 149     llvm_cv_link_all_option="-Wl,--whole-archive"
 150     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 151     llvm_cv_os_type="HP-UX"
 152     llvm_cv_platform_type="Unix" ;;
 153   *-*-interix*)
 154     llvm_cv_link_all_option="-Wl,--whole-archive"
 155     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 156     llvm_cv_os_type="Interix"
 157     llvm_cv_platform_type="Unix" ;;
 158   *-*-linux*)
 159     llvm_cv_link_all_option="-Wl,--whole-archive"
 160     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 161     llvm_cv_os_type="Linux"
 162     llvm_cv_platform_type="Unix" ;;
 163   *-*-solaris*)
 164     llvm_cv_link_all_option="-Wl,-z,allextract"
 165     llvm_cv_no_link_all_option="-Wl,-z,defaultextract"
 166     llvm_cv_os_type="SunOS"
 167     llvm_cv_platform_type="Unix" ;;
 168   *-*-win32*)
 169     llvm_cv_link_all_option="-Wl,--whole-archive"
 170     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 171     llvm_cv_os_type="Win32"
 172     llvm_cv_platform_type="Win32" ;;
 173   *-*-mingw*)
 174     llvm_cv_link_all_option="-Wl,--whole-archive"
 175     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 176     llvm_cv_os_type="MingW"
 177     llvm_cv_platform_type="Win32" ;;
 178   *)
 179     llvm_cv_link_all_option=""
 180     llvm_cv_no_link_all_option=""
 181     llvm_cv_os_type="Unknown"
 182     llvm_cv_platform_type="Unknown" ;;
 183 esac])
 184
 185 dnl Make sure we aren't attempting to configure for an unknown system
 186 if test "$llvm_cv_os_type" = "Unknown" ; then
 187   AC_MSG_ERROR([Operating system is unknown, configure can't continue])
 188 fi
 189
 190 dnl Set the "OS" Makefile variable based on the platform type so the
 191 dnl makefile can configure itself to specific build hosts
 192 AC_SUBST(OS,$llvm_cv_os_type)
 193
 194 dnl Set the LINKALL and NOLINKALL Makefile variables based on the platform
 195 AC_SUBST(LINKALL,$llvm_cv_link_all_option)
 196 AC_SUBST(NOLINKALL,$llvm_cv_no_link_all_option)
 197
 198 dnl Set the "LLVM_ON_*" variables based on llvm_cvs_platform_type
 199 dnl This is used by lib/System to determine the basic kind of implementation
 200 dnl to use.
 201 case $llvm_cv_platform_type in
 202   Unix)
 203     AC_DEFINE([LLVM_ON_UNIX],[1],[Define if this is Unixish platform])
 204     AC_SUBST(LLVM_ON_UNIX,[1])
 205     AC_SUBST(LLVM_ON_WIN32,[0])
 206     ;;
 207   Win32)
 208     AC_DEFINE([LLVM_ON_WIN32],[1],[Define if this is Win32ish platform])
 209     AC_SUBST(LLVM_ON_UNIX,[0])
 210     AC_SUBST(LLVM_ON_WIN32,[1])
 211     ;;
 212 esac
 213
 214 dnl Determine what our target architecture is and configure accordingly.
 215 dnl This will allow Makefiles to make a distinction between the hardware and
 216 dnl the OS.
 217 AC_CACHE_CHECK([target architecture],[llvm_cv_target_arch],
 218 [case $target in
 219   i?86-*)                 llvm_cv_target_arch="x86" ;;
 220   amd64-* | x86_64-*)     llvm_cv_target_arch="x86_64" ;;
 221   sparc*-*)               llvm_cv_target_arch="Sparc" ;;
 222   powerpc*-*)             llvm_cv_target_arch="PowerPC" ;;
 223   alpha*-*)               llvm_cv_target_arch="Alpha" ;;
 224   ia64-*)                 llvm_cv_target_arch="IA64" ;;
 225   arm*-*)                 llvm_cv_target_arch="ARM" ;;
 226   mips-*)                 llvm_cv_target_arch="Mips" ;;
 227   pic16-*)                llvm_cv_target_arch="PIC16" ;;
 228   xcore-*)                llvm_cv_target_arch="XCore" ;;
 229   msp430-*)               llvm_cv_target_arch="MSP430" ;;
 230   s390x-*)                llvm_cv_target_arch="SystemZ" ;;
 231   *)                      llvm_cv_target_arch="Unknown" ;;
 232 esac])
 233
 234 if test "$llvm_cv_target_arch" = "Unknown" ; then
 235   AC_MSG_WARN([Configuring LLVM for an unknown target archicture])
 236 fi
 237
 238 # Determine the LLVM native architecture for the target
 239 case "$llvm_cv_target_arch" in
 240     x86)     LLVM_NATIVE_ARCH="X86" ;;
 241     x86_64)  LLVM_NATIVE_ARCH="X86" ;;
 242     *)       LLVM_NATIVE_ARCH="$llvm_cv_target_arch" ;;
 243 esac
 244
 245 dnl Define a substitution, ARCH, for the target architecture
 246 AC_SUBST(ARCH,$llvm_cv_target_arch)
 247
 248 dnl Check for the endianness of the target
 249 AC_C_BIGENDIAN(AC_SUBST([ENDIAN],[big]),AC_SUBST([ENDIAN],[little]))
 250
 251 dnl Check for build platform executable suffix if we're crosscompiling
 252 if test "$cross_compiling" = yes; then
 253   AC_SUBST(LLVM_CROSS_COMPILING, [1])
 254   AC_BUILD_EXEEXT
 255   ac_build_prefix=${build_alias}-
 256   AC_CHECK_PROG(BUILD_CXX, ${ac_build_prefix}g++, ${ac_build_prefix}g++)
 257   if test -z "$BUILD_CXX"; then
 258      AC_CHECK_PROG(BUILD_CXX, g++, g++)
 259      if test -z "$BUILD_CXX"; then
 260        AC_CHECK_PROG(BUILD_CXX, c++, c++, , , /usr/ucb/c++)
 261      fi
 262   fi
 263 else
 264   AC_SUBST(LLVM_CROSS_COMPILING, [0])
 265 fi
 266
 267 dnl Check to see if there's a "CVS" (or .svn or .git) directory indicating
 268 dnl that this build is being done from a checkout. This sets up several
 269 dnl defaults for the command line switches. When we build with a CVS directory,
 270 dnl we get a debug with assertions turned on. Without, we assume a source
 271 dnl release and we get an optimized build without assertions.
 272 dnl See --enable-optimized and --enable-assertions below
 273 if test -d "CVS" -o -d "${srcdir}/CVS" -o -d ".svn" -o -d "${srcdir}/.svn" -o -d ".git" -o -d "${srcdir}/.git"; then
 274   cvsbuild="yes"
 275   optimize="no"
 276   AC_SUBST(CVSBUILD,[[CVSBUILD=1]])
 277 else
 278   cvsbuild="no"
 279   optimize="yes"
 280 fi
 281
 282 dnl===-----------------------------------------------------------------------===
 283 dnl===
 284 dnl=== SECTION 3: Command line arguments for the configure script.
 285 dnl===
 286 dnl===-----------------------------------------------------------------------===
 287
 288 dnl --enable-optimized : check whether they want to do an optimized build:
 289 AC_ARG_ENABLE(optimized, AS_HELP_STRING(
 290  --enable-optimized,[Compile with optimizations enabled (default is NO)]),,enableval=$optimize)
 291 if test ${enableval} = "no" ; then
 292   AC_SUBST(ENABLE_OPTIMIZED,[[]])
 293 else
 294   AC_SUBST(ENABLE_OPTIMIZED,[[ENABLE_OPTIMIZED=1]])
 295 fi
 296
 297 dnl --enable-profiling : check whether they want to do a profile build:
 298 AC_ARG_ENABLE(profiling, AS_HELP_STRING(
 299  --enable-profiling,[Compile with profiling enabled (default is NO)]),,enableval="no")
 300 if test ${enableval} = "no" ; then
 301   AC_SUBST(ENABLE_PROFILING,[[]])
 302 else
 303   AC_SUBST(ENABLE_PROFILING,[[ENABLE_PROFILING=1]])
 304 fi
 305
 306 dnl --enable-assertions : check whether they want to turn on assertions or not:
 307 AC_ARG_ENABLE(assertions,AS_HELP_STRING(
 308   --enable-assertions,[Compile with assertion checks enabled (default is YES)]),, enableval="yes")
 309 if test ${enableval} = "yes" ; then
 310   AC_SUBST(DISABLE_ASSERTIONS,[[]])
 311 else
 312   AC_SUBST(DISABLE_ASSERTIONS,[[DISABLE_ASSERTIONS=1]])
 313 fi
 314
 315 dnl --enable-expensive-checks : check whether they want to turn on expensive debug checks:
 316 AC_ARG_ENABLE(expensive-checks,AS_HELP_STRING(
 317   --enable-expensive-checks,[Compile with expensive debug checks enabled (default is NO)]),, enableval="no")
 318 if test ${enableval} = "yes" ; then
 319   AC_SUBST(ENABLE_EXPENSIVE_CHECKS,[[ENABLE_EXPENSIVE_CHECKS=1]])
 320   AC_SUBST(EXPENSIVE_CHECKS,[[yes]])
 321 else
 322   AC_SUBST(ENABLE_EXPENSIVE_CHECKS,[[]])
 323   AC_SUBST(EXPENSIVE_CHECKS,[[no]])
 324 fi
 325
 326 dnl --enable-debug-runtime : should runtime libraries have debug symbols?
 327 AC_ARG_ENABLE(debug-runtime,
 328    AS_HELP_STRING(--enable-debug-runtime,[Build runtime libs with debug symbols (default is NO)]),,enableval=no)
 329 if test ${enableval} = "no" ; then
 330   AC_SUBST(DEBUG_RUNTIME,[[]])
 331 else
 332   AC_SUBST(DEBUG_RUNTIME,[[DEBUG_RUNTIME=1]])
 333 fi
 334
 335 dnl --enable-jit: check whether they want to enable the jit
 336 AC_ARG_ENABLE(jit,
 337   AS_HELP_STRING(--enable-jit,
 338                  [Enable Just In Time Compiling (default is YES)]),,
 339   enableval=default)
 340 if test ${enableval} = "no"
 341 then
 342   AC_SUBST(JIT,[[]])
 343 else
 344   case "$llvm_cv_target_arch" in
 345     x86)     AC_SUBST(TARGET_HAS_JIT,1) ;;
 346     Sparc)   AC_SUBST(TARGET_HAS_JIT,0) ;;
 347     PowerPC) AC_SUBST(TARGET_HAS_JIT,1) ;;
 348     x86_64)  AC_SUBST(TARGET_HAS_JIT,1) ;;
 349     Alpha)   AC_SUBST(TARGET_HAS_JIT,1) ;;
 350     IA64)    AC_SUBST(TARGET_HAS_JIT,0) ;;
 351     ARM)     AC_SUBST(TARGET_HAS_JIT,0) ;;
 352     Mips)    AC_SUBST(TARGET_HAS_JIT,0) ;;
 353     PIC16)   AC_SUBST(TARGET_HAS_JIT,0) ;;
 354     XCore)   AC_SUBST(TARGET_HAS_JIT,0) ;;
 355     MSP430)  AC_SUBST(TARGET_HAS_JIT,0) ;;
 356     SystemZ) AC_SUBST(TARGET_HAS_JIT,0) ;;
 357     *)       AC_SUBST(TARGET_HAS_JIT,0) ;;
 358   esac
 359 fi
 360
 361 dnl Allow enablement of doxygen generated documentation
 362 AC_ARG_ENABLE(doxygen,
 363               AS_HELP_STRING([--enable-doxygen],
 364                              [Build doxygen documentation (default is NO)]),,
 365                              enableval=default)
 366 case "$enableval" in
 367   yes) AC_SUBST(ENABLE_DOXYGEN,[1]) ;;
 368   no)  AC_SUBST(ENABLE_DOXYGEN,[0]) ;;
 369   default) AC_SUBST(ENABLE_DOXYGEN,[0]) ;;
 370   *) AC_MSG_ERROR([Invalid setting for --enable-doxygen. Use "yes" or "no"]) ;;
 371 esac
 372
 373 dnl Allow disablement of threads
 374 AC_ARG_ENABLE(threads,
 375               AS_HELP_STRING([--enable-threads],
 376                              [Use threads if available (default is YES)]),,
 377                              enableval=default)
 378 case "$enableval" in
 379   yes) AC_SUBST(ENABLE_THREADS,[1]) ;;
 380   no)  AC_SUBST(ENABLE_THREADS,[0]) ;;
 381   default) AC_SUBST(ENABLE_THREADS,[1]) ;;
 382   *) AC_MSG_ERROR([Invalid setting for --enable-threads. Use "yes" or "no"]) ;;
 383 esac
 384 AC_DEFINE_UNQUOTED([ENABLE_THREADS],$ENABLE_THREADS,[Define if threads enabled])
 385
 386 dnl Allow building without position independent code
 387 AC_ARG_ENABLE(pic,
 388   AS_HELP_STRING([--enable-pic],
 389                  [Build LLVM with Position Independent Code (default is YES)]),,
 390                  enableval=default)
 391 case "$enableval" in
 392   yes) AC_SUBST(ENABLE_PIC,[1]) ;;
 393   no)  AC_SUBST(ENABLE_PIC,[0]) ;;
 394   default) AC_SUBST(ENABLE_PIC,[1]) ;;
 395   *) AC_MSG_ERROR([Invalid setting for --enable-pic. Use "yes" or "no"]) ;;
 396 esac
 397 AC_DEFINE_UNQUOTED([ENABLE_PIC],$ENABLE_PIC,
 398                    [Define if position independent code is enabled])
 399
 400 dnl Allow specific targets to be specified for building (or not)
 401 TARGETS_TO_BUILD=""
 402 AC_ARG_ENABLE([targets],AS_HELP_STRING([--enable-targets],
 403     [Build specific host targets: all,host-only,{target-name} (default=all)]),,
 404     enableval=all)
 405 case "$enableval" in
 406   all) TARGETS_TO_BUILD="X86 Sparc PowerPC Alpha IA64 ARM Mips CellSPU PIC16 XCore MSP430 SystemZ CBackend MSIL CppBackend" ;;
 407   host-only)
 408     case "$llvm_cv_target_arch" in
 409       x86)     TARGETS_TO_BUILD="X86" ;;
 410       x86_64)  TARGETS_TO_BUILD="X86" ;;
 411       Sparc)   TARGETS_TO_BUILD="Sparc" ;;
 412       PowerPC) TARGETS_TO_BUILD="PowerPC" ;;
 413       Alpha)   TARGETS_TO_BUILD="Alpha" ;;
 414       IA64)    TARGETS_TO_BUILD="IA64" ;;
 415       ARM)     TARGETS_TO_BUILD="ARM" ;;
 416       Mips)    TARGETS_TO_BUILD="Mips" ;;
 417       CellSPU|SPU) TARGETS_TO_BUILD="CellSPU" ;;
 418       PIC16)   TARGETS_TO_BUILD="PIC16" ;;
 419       XCore)   TARGETS_TO_BUILD="XCore" ;;
 420       MSP430)  TARGETS_TO_BUILD="MSP430" ;;
 421       SystemZ) TARGETS_TO_BUILD="SystemZ" ;;
 422       *)       AC_MSG_ERROR([Can not set target to build]) ;;
 423     esac
 424     ;;
 425   *)for a_target in `echo $enableval|sed -e 's/,/ /g' ` ; do
 426       case "$a_target" in
 427         x86)     TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 428         x86_64)  TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 429         sparc)   TARGETS_TO_BUILD="Sparc $TARGETS_TO_BUILD" ;;
 430         powerpc) TARGETS_TO_BUILD="PowerPC $TARGETS_TO_BUILD" ;;
 431         alpha)   TARGETS_TO_BUILD="Alpha $TARGETS_TO_BUILD" ;;
 432         ia64)    TARGETS_TO_BUILD="IA64 $TARGETS_TO_BUILD" ;;
 433         arm)     TARGETS_TO_BUILD="ARM $TARGETS_TO_BUILD" ;;
 434         mips)    TARGETS_TO_BUILD="Mips $TARGETS_TO_BUILD" ;;
 435         spu)     TARGETS_TO_BUILD="CellSPU $TARGETS_TO_BUILD" ;;
 436         pic16)   TARGETS_TO_BUILD="PIC16 $TARGETS_TO_BUILD" ;;
 437         xcore)   TARGETS_TO_BUILD="XCore $TARGETS_TO_BUILD" ;;
 438         msp430)  TARGETS_TO_BUILD="MSP430 $TARGETS_TO_BUILD" ;;
 439         systemz) TARGETS_TO_BUILD="SystemZ $TARGETS_TO_BUILD" ;;
 440         cbe)     TARGETS_TO_BUILD="CBackend $TARGETS_TO_BUILD" ;;
 441         msil)    TARGETS_TO_BUILD="MSIL $TARGETS_TO_BUILD" ;;
 442         cpp)     TARGETS_TO_BUILD="CppBackend $TARGETS_TO_BUILD" ;;
 443         *) AC_MSG_ERROR([Unrecognized target $a_target]) ;;
 444       esac
 445   done
 446   ;;
 447 esac
 448 AC_SUBST(TARGETS_TO_BUILD,$TARGETS_TO_BUILD)
 449
 450 # Determine whether we are building LLVM support for the native architecture.
 451 # If so, define LLVM_NATIVE_ARCH to that LLVM target.
 452 for a_target in $TARGETS_TO_BUILD; do
 453   if test "$a_target" = "$LLVM_NATIVE_ARCH"; then
 454     LLVM_NATIVE_ARCHTARGET="${LLVM_NATIVE_ARCH}Target"
 455     AC_DEFINE_UNQUOTED(LLVM_NATIVE_ARCH,$LLVM_NATIVE_ARCHTARGET,
 456       [LLVM architecture name for the native architecture, if available])
 457   fi
 458 done
 459
 460 # Build the LLVM_TARGET and LLVM_ASM_PRINTER macro uses for
 461 # Targets.def and AsmPrinters.def.
 462 LLVM_ENUM_TARGETS=""
 463 LLVM_ENUM_ASM_PRINTERS=""
 464 for target_to_build in $TARGETS_TO_BUILD; do
 465   LLVM_ENUM_TARGETS="LLVM_TARGET($target_to_build) $LLVM_ENUM_TARGETS"
 466   if test -f ${srcdir}/lib/Target/${target_to_build}/AsmPrinter/Makefile ; then
 467     LLVM_ENUM_ASM_PRINTERS="LLVM_ASM_PRINTER($target_to_build) $LLVM_ENUM_ASM_PRINTERS";
 468   fi
 469 done
 470 AC_SUBST(LLVM_ENUM_TARGETS)
 471 AC_SUBST(LLVM_ENUM_ASM_PRINTERS)
 472
 473 dnl Prevent the CBackend from using printf("%a") for floating point so older
 474 dnl C compilers that cannot deal with the 0x0p+0 hex floating point format
 475 dnl can still compile the CBE's output
 476 AC_ARG_ENABLE([cbe-printf-a],AS_HELP_STRING([--enable-cbe-printf-a],
 477   [Enable C Backend output with hex floating point via %a  (default is YES)]),,
 478   enableval=default)
 479 case "$enableval" in
 480   yes) AC_SUBST(ENABLE_CBE_PRINTF_A,[1]) ;;
 481   no)  AC_SUBST(ENABLE_CBE_PRINTF_A,[0]) ;;
 482   default)  AC_SUBST(ENABLE_CBE_PRINTF_A,[1]) ;;
 483   *) AC_MSG_ERROR([Invalid setting for --enable-cbe-printf-a. Use "yes" or "no"]) ;;
 484 esac
 485 AC_DEFINE_UNQUOTED([ENABLE_CBE_PRINTF_A],$ENABLE_CBE_PRINTF_A,
 486                    [Define if CBE is enabled for printf %a output])
 487
 488 dnl Allow a specific llvm-gcc/llvm-g++ pair to be used with this LLVM config.
 489 AC_ARG_WITH(llvmgccdir,
 490   AS_HELP_STRING([--with-llvmgccdir],
 491     [Specify location of llvm-gcc install dir (default searches PATH)]),,
 492     withval=default)
 493 case "$withval" in
 494   default) WITH_LLVMGCCDIR=default ;;
 495   /* | [[A-Za-z]]:[[\\/]]*)      WITH_LLVMGCCDIR=$withval ;;
 496   *) AC_MSG_ERROR([Invalid path for --with-llvmgccdir. Provide full path]) ;;
 497 esac
 498
 499 dnl Allow a specific llvm-gcc compiler to be used with this LLVM config.
 500 AC_ARG_WITH(llvmgcc,
 501   AS_HELP_STRING([--with-llvmgcc],
 502     [Specify location of llvm-gcc driver (default searches PATH)]),
 503     LLVMGCC=$with_llvmgcc
 504       WITH_LLVMGCCDIR="",)
 505
 506 dnl Allow a specific llvm-g++ compiler to be used with this LLVM config.
 507 AC_ARG_WITH(llvmgxx,
 508   AS_HELP_STRING([--with-llvmgxx],
 509     [Specify location of llvm-g++ driver (default searches PATH)]),
 510     LLVMGXX=$with_llvmgxx
 511     WITH_LLVMGCCDIR="",)
 512
 513 if test -n "$LLVMGCC"; then
 514    LLVMGCCCOMMAND="$LLVMGCC"
 515 fi
 516
 517 if test -n "$LLVMGXX"; then
 518    LLVMGXXCOMMAND="$LLVMGXX"
 519 fi
 520
 521 if test -n "$LLVMGCC" && test -z "$LLVMGXX"; then
 522    AC_MSG_ERROR([Invalid llvm-g++. Use --with-llvmgxx when --with-llvmgcc is used]);
 523 fi
 524
 525 if test -n "$LLVMGXX" && test -z "$LLVMGCC"; then
 526    AC_MSG_ERROR([Invalid llvm-gcc. Use --with-llvmgcc when --with-llvmgxx is used]);
 527 fi
 528
 529 dnl Specify extra build options
 530 AC_ARG_WITH(extra-options,
 531   AS_HELP_STRING([--with-extra-options],
 532                  [Specify additional options to compile LLVM with]),,
 533                  withval=default)
 534 case "$withval" in
 535   default) EXTRA_OPTIONS= ;;
 536   *) EXTRA_OPTIONS=$withval ;;
 537 esac
 538 AC_SUBST(EXTRA_OPTIONS,$EXTRA_OPTIONS)
 539
 540 dnl Allow specific bindings to be specified for building (or not)
 541 AC_ARG_ENABLE([bindings],AS_HELP_STRING([--enable-bindings],
 542     [Build specific language bindings: all,auto,none,{binding-name} (default=auto)]),,
 543     enableval=default)
 544 BINDINGS_TO_BUILD=""
 545 case "$enableval" in
 546   yes | default | auto) BINDINGS_TO_BUILD="auto" ;;
 547   all ) BINDINGS_TO_BUILD="ocaml" ;;
 548   none | no) BINDINGS_TO_BUILD="" ;;
 549   *)for a_binding in `echo $enableval|sed -e 's/,/ /g' ` ; do
 550       case "$a_binding" in
 551         ocaml) BINDINGS_TO_BUILD="ocaml $BINDINGS_TO_BUILD" ;;
 552         *) AC_MSG_ERROR([Unrecognized binding $a_binding]) ;;
 553       esac
 554   done
 555   ;;
 556 esac
 557
 558 dnl Allow the ocaml libdir to be overridden. This could go in a configure
 559 dnl script for bindings/ocaml/configure, except that its auto value depends on
 560 dnl OCAMLC, which is found here to support tests.
 561 AC_ARG_WITH([ocaml-libdir],
 562   [AS_HELP_STRING([--with-ocaml-libdir],
 563     [Specify install location for ocaml bindings (default is stdlib)])],
 564   [],
 565   [withval=auto])
 566 case "$withval" in
 567   auto) with_ocaml_libdir="$withval" ;;
 568   /* | [[A-Za-z]]:[[\\/]]*) with_ocaml_libdir="$withval" ;;
 569   *) AC_MSG_ERROR([Invalid path for --with-ocaml-libdir. Provide full path]) ;;
 570 esac
 571
 572 dnl Allow linking of LLVM with GPLv3 binutils code.
 573 AC_ARG_WITH(binutils-include,
 574   AS_HELP_STRING([--with-binutils-include],
 575     [Specify path to binutils/include/ containing plugin-api.h file for gold plugin.]),,
 576   withval=default)
 577 case "$withval" in
 578   default) WITH_BINUTILS_INCDIR=default ;;
 579   /* | [[A-Za-z]]:[[\\/]]*)      WITH_BINUTILS_INCDIR=$withval ;;
 580   *) AC_MSG_ERROR([Invalid path for --with-binutils-include. Provide full path]) ;;
 581 esac
 582 if test "x$WITH_BINUTILS_INCDIR" != xdefault ; then
 583   AC_SUBST(BINUTILS_INCDIR,$WITH_BINUTILS_INCDIR)
 584   if test ! -f "$WITH_BINUTILS_INCDIR/plugin-api.h"; then
 585      echo "$WITH_BINUTILS_INCDIR/plugin-api.h"
 586      AC_MSG_ERROR([Invalid path to directory containing plugin-api.h.]);
 587   fi
 588 fi
 589
 590 dnl --enable-libffi : check whether the user wants to turn off libffi:
 591 AC_ARG_ENABLE(libffi,AS_HELP_STRING(
 592   --enable-libffi,[Check for the presence of libffi (default is YES)]),,
 593   enableval=yes)
 594 case "$enableval" in
 595   yes) llvm_cv_enable_libffi="yes" ;;
 596   no)  llvm_cv_enable_libffi="no"  ;;
 597   *) AC_MSG_ERROR([Invalid setting for --enable-libffi. Use "yes" or "no"]) ;;
 598 esac
 599
 600 dnl Only Windows needs dynamic libCompilerDriver to support plugins.
 601 if test "$llvm_cv_os_type" = "Win32" ; then
 602    llvmc_dynamic="yes"
 603 else
 604    llvmc_dynamic="no"
 605 fi
 606
 607 dnl --enable-llvmc-dynamic : should LLVMC link libCompilerDriver dynamically?
 608 AC_ARG_ENABLE(llvmc-dynamic,AS_HELP_STRING(
 609 --enable-llvmc-dynamic,
 610 [Link LLVMC dynamically (default is NO, unless on Win32)]),,
 611 enableval=$llvmc_dynamic)
 612 if test ${enableval} = "yes" && test "$ENABLE_PIC" -eq 1 ; then
 613    AC_SUBST(ENABLE_LLVMC_DYNAMIC,[[ENABLE_LLVMC_DYNAMIC=1]])
 614 else
 615    AC_SUBST(ENABLE_LLVMC_DYNAMIC,[[]])
 616 fi
 617
 618 dnl --enable-llvmc-dynamic-plugins : should LLVMC support dynamic plugins?
 619 AC_ARG_ENABLE(llvmc-dynamic-plugins,AS_HELP_STRING(
 620 --enable-llvmc-dynamic-plugins,
 621 [Enable dynamic LLVMC plugins (default is YES)]),,
 622 enableval=yes)
 623 if test ${enableval} = "yes" ; then
 624    AC_SUBST(ENABLE_LLVMC_DYNAMIC_PLUGINS,[[ENABLE_LLVMC_DYNAMIC_PLUGINS=1]])
 625 else
 626    AC_SUBST(ENABLE_LLVMC_DYNAMIC_PLUGINS,[[]])
 627 fi
 628
 629 dnl===-----------------------------------------------------------------------===
 630 dnl===
 631 dnl=== SECTION 4: Check for programs we need and that they are the right version
 632 dnl===
 633 dnl===-----------------------------------------------------------------------===
 634
 635 dnl Check for compilation tools
 636 AC_PROG_CPP
 637 AC_PROG_CC(gcc)
 638 AC_PROG_CXX(g++)
 639
 640 AC_PROG_NM
 641 AC_SUBST(NM)
 642
 643 dnl Check for the tools that the makefiles require
 644 AC_CHECK_GNU_MAKE
 645 AC_PROG_LN_S
 646 AC_PATH_PROG(CMP, [cmp], [cmp])
 647 AC_PATH_PROG(CP, [cp], [cp])
 648 AC_PATH_PROG(DATE, [date], [date])
 649 AC_PATH_PROG(FIND, [find], [find])
 650 AC_PATH_PROG(GREP, [grep], [grep])
 651 AC_PATH_PROG(MKDIR,[mkdir],[mkdir])
 652 AC_PATH_PROG(MV,   [mv],   [mv])
 653 AC_PROG_RANLIB
 654 AC_PATH_PROG(RM,   [rm],   [rm])
 655 AC_PATH_PROG(SED,  [sed],  [sed])
 656 AC_PATH_PROG(TAR,  [tar],  [gtar])
 657 AC_PATH_PROG(BINPWD,[pwd],  [pwd])
 658
 659 dnl Looking for misc. graph plotting software
 660 AC_PATH_PROG(GRAPHVIZ, [Graphviz], [echo Graphviz])
 661 if test "$GRAPHVIZ" != "echo Graphviz" ; then
 662   AC_DEFINE([HAVE_GRAPHVIZ],[1],[Define if the Graphviz program is available])
 663   dnl If we're targeting for mingw we should emit windows paths, not msys
 664   if test "$llvm_cv_os_type" = "MingW" ; then
 665     GRAPHVIZ=`echo $GRAPHVIZ | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 666   fi
 667   AC_DEFINE_UNQUOTED([LLVM_PATH_GRAPHVIZ],"$GRAPHVIZ${EXEEXT}",
 668    [Define to path to Graphviz program if found or 'echo Graphviz' otherwise])
 669 fi
 670 AC_PATH_PROG(DOT, [dot], [echo dot])
 671 if test "$DOT" != "echo dot" ; then
 672   AC_DEFINE([HAVE_DOT],[1],[Define if the dot program is available])
 673   dnl If we're targeting for mingw we should emit windows paths, not msys
 674   if test "$llvm_cv_os_type" = "MingW" ; then
 675     DOT=`echo $DOT | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 676   fi
 677   AC_DEFINE_UNQUOTED([LLVM_PATH_DOT],"$DOT${EXEEXT}",
 678    [Define to path to dot program if found or 'echo dot' otherwise])
 679 fi
 680 AC_PATH_PROG(FDP, [fdp], [echo fdp])
 681 if test "$FDP" != "echo fdp" ; then
 682   AC_DEFINE([HAVE_FDP],[1],[Define if the neat program is available])
 683   dnl If we're targeting for mingw we should emit windows paths, not msys
 684   if test "$llvm_cv_os_type" = "MingW" ; then
 685     FDP=`echo $FDP | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 686   fi
 687   AC_DEFINE_UNQUOTED([LLVM_PATH_FDP],"$FDP${EXEEXT}",
 688    [Define to path to fdp program if found or 'echo fdp' otherwise])
 689 fi
 690 AC_PATH_PROG(NEATO, [neato], [echo neato])
 691 if test "$NEATO" != "echo neato" ; then
 692   AC_DEFINE([HAVE_NEATO],[1],[Define if the neat program is available])
 693   dnl If we're targeting for mingw we should emit windows paths, not msys
 694   if test "$llvm_cv_os_type" = "MingW" ; then
 695     NEATO=`echo $NEATO | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 696   fi
 697   AC_DEFINE_UNQUOTED([LLVM_PATH_NEATO],"$NEATO${EXEEXT}",
 698    [Define to path to neato program if found or 'echo neato' otherwise])
 699 fi
 700 AC_PATH_PROG(TWOPI, [twopi], [echo twopi])
 701 if test "$TWOPI" != "echo twopi" ; then
 702   AC_DEFINE([HAVE_TWOPI],[1],[Define if the neat program is available])
 703   dnl If we're targeting for mingw we should emit windows paths, not msys
 704   if test "$llvm_cv_os_type" = "MingW" ; then
 705     TWOPI=`echo $TWOPI | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 706   fi
 707   AC_DEFINE_UNQUOTED([LLVM_PATH_TWOPI],"$TWOPI${EXEEXT}",
 708    [Define to path to twopi program if found or 'echo twopi' otherwise])
 709 fi
 710 AC_PATH_PROG(CIRCO, [circo], [echo circo])
 711 if test "$CIRCO" != "echo circo" ; then
 712   AC_DEFINE([HAVE_CIRCO],[1],[Define if the neat program is available])
 713   dnl If we're targeting for mingw we should emit windows paths, not msys
 714   if test "$llvm_cv_os_type" = "MingW" ; then
 715     CIRCO=`echo $CIRCO | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 716   fi
 717   AC_DEFINE_UNQUOTED([LLVM_PATH_CIRCO],"$CIRCO${EXEEXT}",
 718    [Define to path to circo program if found or 'echo circo' otherwise])
 719 fi
 720 AC_PATH_PROGS(GV, [gv gsview32], [echo gv])
 721 if test "$GV" != "echo gv" ; then
 722   AC_DEFINE([HAVE_GV],[1],[Define if the gv program is available])
 723   dnl If we're targeting for mingw we should emit windows paths, not msys
 724   if test "$llvm_cv_os_type" = "MingW" ; then
 725     GV=`echo $GV | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 726   fi
 727   AC_DEFINE_UNQUOTED([LLVM_PATH_GV],"$GV${EXEEXT}",
 728    [Define to path to gv program if found or 'echo gv' otherwise])
 729 fi
 730 AC_PATH_PROG(DOTTY, [dotty], [echo dotty])
 731 if test "$DOTTY" != "echo dotty" ; then
 732   AC_DEFINE([HAVE_DOTTY],[1],[Define if the dotty program is available])
 733   dnl If we're targeting for mingw we should emit windows paths, not msys
 734   if test "$llvm_cv_os_type" = "MingW" ; then
 735     DOTTY=`echo $DOTTY | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 736   fi
 737   AC_DEFINE_UNQUOTED([LLVM_PATH_DOTTY],"$DOTTY${EXEEXT}",
 738    [Define to path to dotty program if found or 'echo dotty' otherwise])
 739 fi
 740
 741 dnl Look for a sufficiently recent version of Perl.
 742 LLVM_PROG_PERL([5.006])
 743 AC_SUBST(PERL)
 744 if test x"$PERL" = xnone; then
 745    AC_SUBST(HAVE_PERL,0)
 746    AC_MSG_ERROR([perl is required but was not found, please install it])
 747 else
 748    AC_SUBST(HAVE_PERL,1)
 749 fi
 750
 751 dnl Find the install program
 752 AC_PROG_INSTALL
 753
 754 dnl Checks for documentation and testing tools that we can do without. If these
 755 dnl are not found then they are set to "true" which always succeeds but does
 756 dnl nothing. This just lets the build output show that we could have done
 757 dnl something if the tool was available.
 758 AC_PATH_PROG(BZIP2, [bzip2])
 759 AC_PATH_PROG(DOXYGEN, [doxygen])
 760 AC_PATH_PROG(GROFF, [groff])
 761 AC_PATH_PROG(GZIP, [gzip])
 762 AC_PATH_PROG(POD2HTML, [pod2html])
 763 AC_PATH_PROG(POD2MAN, [pod2man])
 764 AC_PATH_PROG(RUNTEST, [runtest])
 765 DJ_AC_PATH_TCLSH
 766 AC_PATH_PROG(ZIP, [zip])
 767 AC_PATH_PROGS(OCAMLC, [ocamlc])
 768 AC_PATH_PROGS(OCAMLOPT, [ocamlopt])
 769 AC_PATH_PROGS(OCAMLDEP, [ocamldep])
 770 AC_PATH_PROGS(OCAMLDOC, [ocamldoc])
 771 AC_PATH_PROGS(GAS, [gas as])
 772
 773 dnl Determine whether the linker supports the -R option.
 774 AC_LINK_USE_R
 775
 776 dnl Determine whether the linker supports the -export-dynamic option.
 777 AC_LINK_EXPORT_DYNAMIC
 778
 779 dnl Check for libtool and the library that has dlopen function (which must come
 780 dnl before the AC_PROG_LIBTOOL check in order to enable dlopening libraries with
 781 dnl libtool).
 782 AC_LIBTOOL_DLOPEN
 783 AC_LIB_LTDL
 784 AC_PROG_LIBTOOL
 785
 786 if test "$lt_cv_dlopen_self" = "yes" ; then
 787   AC_DEFINE([CAN_DLOPEN_SELF],[1],
 788               [Define if dlopen(0) will open the symbols of the program])
 789 fi
 790
 791
 792 if test "$WITH_LLVMGCCDIR" = "default" ; then
 793   LLVMGCC="llvm-gcc${EXEEXT}"
 794   LLVMGXX="llvm-g++${EXEEXT}"
 795   LLVMGCCCOMMAND="$LLVMGCC"
 796   LLVMGXXCOMMAND="$LLVMGXX"
 797   AC_SUBST(LLVMGCCCOMMAND,$LLVMGCCCOMMAND)
 798   AC_SUBST(LLVMGXXCOMMAND,$LLVMGXXCOMMAND)
 799   AC_PATH_PROG(LLVMGCC, $LLVMGCC, [])
 800   AC_PATH_PROG(LLVMGXX, $LLVMGXX, [])
 801 else
 802   if test -z "$LLVMGCC"; then
 803     LLVMGCC="$WITH_LLVMGCCDIR/bin/llvm-gcc${EXEEXT}"
 804     LLVMGCCCOMMAND="$LLVMGCC"
 805   fi
 806   if test -z "$LLVMGXX"; then
 807     LLVMGXX="$WITH_LLVMGCCDIR/bin/llvm-g++${EXEEXT}"
 808     LLVMGXXCOMMAND="$LLVMGXX"
 809   fi
 810
 811   AC_SUBST(LLVMGCC,$LLVMGCC)
 812   AC_SUBST(LLVMGXX,$LLVMGXX)
 813   AC_SUBST(LLVMGCCCOMMAND,$LLVMGCCCOMMAND)
 814   AC_SUBST(LLVMGXXCOMMAND,$LLVMGXXCOMMAND)
 815 fi
 816
 817
 818 AC_MSG_CHECKING([tool compatibility])
 819
 820 dnl Ensure that compilation tools are GCC or a GNU compatible compiler such as
 821 dnl ICC; we use GCC specific options in the makefiles so the compiler needs
 822 dnl to support those options.
 823 dnl "icc" emits gcc signatures
 824 dnl "icc -no-gcc" emits no gcc signature BUT is still compatible
 825 ICC=no
 826 IXX=no
 827 case $CC in
 828   icc*|icpc*)
 829     ICC=yes
 830     IXX=yes
 831     ;;
 832    *)
 833     ;;
 834 esac
 835
 836 if test "$GCC" != "yes" && test "$ICC" != "yes"
 837 then
 838   AC_MSG_ERROR([gcc|icc required but not found])
 839 fi
 840
 841 dnl Ensure that compilation tools are GCC; we use GCC specific extensions
 842 if test "$GXX" != "yes" && test "$IXX" != "yes"
 843 then
 844   AC_MSG_ERROR([g++|icc required but not found])
 845 fi
 846
 847 dnl Verify that GCC is version 3.0 or higher
 848 if test "$GCC" = "yes"
 849 then
 850   AC_COMPILE_IFELSE([[#if !defined(__GNUC__) || __GNUC__ < 3
 851 #error Unsupported GCC version
 852 #endif
 853 ]], [], [AC_MSG_ERROR([gcc 3.x required, but you have a lower version])])
 854 fi
 855
 856 dnl Check for GNU Make.  We use its extensions, so don't build without it
 857 if test -z "$llvm_cv_gnu_make_command"
 858 then
 859   AC_MSG_ERROR([GNU Make required but not found])
 860 fi
 861
 862 dnl Tool compatibility is okay if we make it here.
 863 AC_MSG_RESULT([ok])
 864
 865 dnl===-----------------------------------------------------------------------===
 866 dnl===
 867 dnl=== SECTION 5: Check for libraries
 868 dnl===
 869 dnl===-----------------------------------------------------------------------===
 870
 871 AC_CHECK_LIB(m,sin)
 872 if test "$llvm_cv_os_type" = "MingW" ; then
 873   AC_CHECK_LIB(imagehlp, main)
 874   AC_CHECK_LIB(psapi, main)
 875 fi
 876
 877 dnl dlopen() is required for plugin support.
 878 AC_SEARCH_LIBS(dlopen,dl,AC_DEFINE([HAVE_DLOPEN],[1],
 879                [Define if dlopen() is available on this platform.]),
 880                AC_MSG_WARN([dlopen() not found - disabling plugin support]))
 881
 882 dnl libffi is optional; used to call external functions from the interpreter
 883 if test "$llvm_cv_enable_libffi" = "yes" ; then
 884   AC_SEARCH_LIBS(ffi_call,ffi,AC_DEFINE([HAVE_FFI_CALL],[1],
 885                  [Define if libffi is available on this platform.]),
 886                  AC_MSG_WARN([libffi not found - disabling external calls from interpreter]))
 887 fi
 888
 889 dnl mallinfo is optional; the code can compile (minus features) without it
 890 AC_SEARCH_LIBS(mallinfo,malloc,AC_DEFINE([HAVE_MALLINFO],[1],
 891                [Define if mallinfo() is available on this platform.]))
 892
 893 dnl pthread locking functions are optional - but llvm will not be thread-safe
 894 dnl without locks.
 895 if test "$ENABLE_THREADS" -eq 1 ; then
 896   AC_CHECK_LIB(pthread,pthread_mutex_init)
 897   AC_SEARCH_LIBS(pthread_mutex_lock,pthread,
 898                  AC_DEFINE([HAVE_PTHREAD_MUTEX_LOCK],[1],
 899                            [Have pthread_mutex_lock]))
 900   AC_SEARCH_LIBS(pthread_rwlock_init,pthread,
 901                  AC_DEFINE([HAVE_PTHREAD_RWLOCK_INIT],[1],
 902                  [Have pthread_rwlock_init]))
 903   AC_SEARCH_LIBS(pthread_getspecific,pthread,
 904                  AC_DEFINE([HAVE_PTHREAD_GETSPECIFIC],[1],
 905                  [Have pthread_getspecific]))
 906 fi
 907
 908 dnl Allow extra x86-disassembler library
 909 AC_ARG_WITH(udis86,
 910   AS_HELP_STRING([--with-udis86=<path>],
 911     [Use udis86 external x86 disassembler library]),
 912     [
 913       AC_SUBST(USE_UDIS86, [1])
 914       case "$withval" in
 915         /usr/lib|yes) ;;
 916         *) LDFLAGS="$LDFLAGS -L${withval}" ;;
 917       esac
 918       AC_CHECK_LIB(udis86, ud_init, [], [
 919         echo "Error! You need to have libudis86 around."
 920         exit -1
 921       ])
 922     ],
 923     AC_SUBST(USE_UDIS86, [0]))
 924 AC_DEFINE_UNQUOTED([USE_UDIS86],$USE_UDIS86,
 925                    [Define if use udis86 library])
 926
 927 dnl Allow OProfile support for JIT output.
 928 AC_ARG_WITH(oprofile,
 929   AS_HELP_STRING([--with-oprofile=<prefix>],
 930     [Tell OProfile >= 0.9.4 how to symbolize JIT output]),
 931     [
 932       AC_SUBST(USE_OPROFILE, [1])
 933       case "$withval" in
 934         /usr|yes) llvm_cv_oppath=/usr/lib/oprofile ;;
 935         *) llvm_cv_oppath="${withval}/lib/oprofile"
 936            CPPFLAGS="-I${withval}/include";;
 937       esac
 938       LIBS="$LIBS -L${llvm_cv_oppath} -Wl,-rpath,${llvm_cv_oppath}"
 939       AC_SEARCH_LIBS(op_open_agent, opagent, [], [
 940         echo "Error! You need to have libopagent around."
 941         exit -1
 942       ])
 943       AC_CHECK_HEADER([opagent.h], [], [
 944         echo "Error! You need to have opagent.h around."
 945         exit -1
 946       ])
 947     ],
 948     [
 949       llvm_cv_old_LIBS="$LIBS"
 950       LIBS="$LIBS -L/usr/lib/oprofile -Wl,-rpath,/usr/lib/oprofile"
 951       dnl If either the library or header aren't present, omit oprofile support.
 952       AC_SEARCH_LIBS(op_open_agent, opagent,
 953                      [AC_SUBST(USE_OPROFILE, [1])],
 954                      [LIBS="$llvm_cv_old_LIBS"
 955                       AC_SUBST(USE_OPROFILE, [0])])
 956       AC_CHECK_HEADER([opagent.h], [], [
 957         LIBS="$llvm_cv_old_LIBS"
 958         AC_SUBST(USE_OPROFILE, [0])
 959       ])
 960     ])
 961 AC_DEFINE_UNQUOTED([USE_OPROFILE],$USE_OPROFILE,
 962                    [Define if we have the oprofile JIT-support library])
 963
 964 dnl===-----------------------------------------------------------------------===
 965 dnl===
 966 dnl=== SECTION 6: Check for header files
 967 dnl===
 968 dnl===-----------------------------------------------------------------------===
 969
 970 dnl First, use autoconf provided macros for specific headers that we need
 971 dnl We don't check for ancient stuff or things that are guaranteed to be there
 972 dnl by the C++ standard. We always use the <cfoo> versions of <foo.h> C headers.
 973 dnl Generally we're looking for POSIX headers.
 974 AC_HEADER_DIRENT
 975 AC_HEADER_MMAP_ANONYMOUS
 976 AC_HEADER_STAT
 977 AC_HEADER_STDC
 978 AC_HEADER_SYS_WAIT
 979 AC_HEADER_TIME
 980
 981 AC_CHECK_HEADERS([dlfcn.h execinfo.h fcntl.h inttypes.h limits.h link.h])
 982 AC_CHECK_HEADERS([malloc.h setjmp.h signal.h stdint.h termios.h unistd.h])
 983 AC_CHECK_HEADERS([utime.h windows.h])
 984 AC_CHECK_HEADERS([sys/mman.h sys/param.h sys/resource.h sys/time.h])
 985 AC_CHECK_HEADERS([sys/types.h sys/ioctl.h malloc/malloc.h mach/mach.h])
 986 if test "$ENABLE_THREADS" -eq 1 ; then
 987   AC_CHECK_HEADERS(pthread.h,
 988                    AC_SUBST(HAVE_PTHREAD, 1),
 989                    AC_SUBST(HAVE_PTHREAD, 0))
 990 else
 991   AC_SUBST(HAVE_PTHREAD, 0)
 992 fi
 993
 994 dnl Try to find ffi.h.
 995 if test "$llvm_cv_enable_libffi" = "yes" ; then
 996   AC_CHECK_HEADERS([ffi.h ffi/ffi.h])
 997 fi
 998
 999 dnl===-----------------------------------------------------------------------===
1000 dnl===
1001 dnl=== SECTION 7: Check for types and structures
1002 dnl===
1003 dnl===-----------------------------------------------------------------------===
1004
1005 AC_HUGE_VAL_CHECK
1006 AC_TYPE_PID_T
1007 AC_TYPE_SIZE_T
1008 AC_TYPE_SIGNAL
1009 AC_STRUCT_TM
1010 AC_CHECK_TYPES([int64_t],,AC_MSG_ERROR([Type int64_t required but not found]))
1011 AC_CHECK_TYPES([uint64_t],,
1012          AC_CHECK_TYPES([u_int64_t],,
1013          AC_MSG_ERROR([Type uint64_t or u_int64_t required but not found])))
1014
1015 dnl===-----------------------------------------------------------------------===
1016 dnl===
1017 dnl=== SECTION 8: Check for specific functions needed
1018 dnl===
1019 dnl===-----------------------------------------------------------------------===
1020
1021 AC_CHECK_FUNCS([backtrace ceilf floorf roundf rintf nearbyintf getcwd ])
1022 AC_CHECK_FUNCS([powf fmodf strtof round ])
1023 AC_CHECK_FUNCS([getpagesize getrusage getrlimit setrlimit gettimeofday ])
1024 AC_CHECK_FUNCS([isatty mkdtemp mkstemp ])
1025 AC_CHECK_FUNCS([mktemp realpath sbrk setrlimit strdup ])
1026 AC_CHECK_FUNCS([strerror strerror_r strerror_s ])
1027 AC_CHECK_FUNCS([strtoll strtoq sysconf malloc_zone_statistics ])
1028 AC_CHECK_FUNCS([setjmp longjmp sigsetjmp siglongjmp])
1029 AC_C_PRINTF_A
1030 AC_FUNC_ALLOCA
1031 AC_FUNC_RAND48
1032
1033 dnl Check for variations in the Standard C++ library and STL. These macros are
1034 dnl provided by LLVM in the autoconf/m4 directory.
1035 AC_CXX_HAVE_STD_ITERATOR
1036 AC_CXX_HAVE_BI_ITERATOR
1037 AC_CXX_HAVE_FWD_ITERATOR
1038 AC_FUNC_ISNAN
1039 AC_FUNC_ISINF
1040
1041 dnl Check for mmap support.We also need to know if /dev/zero is required to
1042 dnl be opened for allocating RWX memory.
1043 dnl Make sure we aren't attempting to configure for an unknown system
1044 if test "$llvm_cv_platform_type" = "Unix" ; then
1045   AC_FUNC_MMAP
1046   AC_FUNC_MMAP_FILE
1047   AC_NEED_DEV_ZERO_FOR_MMAP
1048
1049   if test "$ac_cv_func_mmap_fixed_mapped" = "no"
1050   then
1051     AC_MSG_WARN([mmap() of a fixed address required but not supported])
1052   fi
1053   if test "$ac_cv_func_mmap_file" = "no"
1054   then
1055     AC_MSG_WARN([mmap() of files required but not found])
1056   fi
1057 fi
1058
1059 dnl atomic builtins are required for threading support.
1060 AC_MSG_CHECKING(for GCC atomic builtins)
1061 AC_LINK_IFELSE(
1062   AC_LANG_SOURCE(
1063     [[int main() {
1064         volatile unsigned long val = 1;
1065         __sync_synchronize();
1066         __sync_val_compare_and_swap(&val, 1, 0);
1067         __sync_add_and_fetch(&val, 1);
1068         __sync_sub_and_fetch(&val, 1);
1069         return 0;
1070       }
1071     ]]),
1072   AC_MSG_RESULT(yes)
1073   AC_DEFINE(LLVM_MULTITHREADED, 1, Build multithreading support into LLVM),
1074   AC_MSG_RESULT(no)
1075   AC_DEFINE(LLVM_MULTITHREADED, 0, Build multithreading support into LLVM)
1076   AC_MSG_WARN([LLVM will be built thread-unsafe because atomic builtins are missing]))
1077
1078
1079 dnl===-----------------------------------------------------------------------===
1080 dnl===
1081 dnl=== SECTION 9: Additional checks, variables, etc.
1082 dnl===
1083 dnl===-----------------------------------------------------------------------===
1084
1085 dnl Check, whether __dso_handle is present
1086 AC_CHECK_FUNCS([__dso_handle])
1087
1088 dnl See if the llvm-gcc executable can compile to LLVM assembly
1089 AC_CACHE_CHECK([whether llvm-gcc is sane],[llvm_cv_llvmgcc_sanity],
1090 [llvm_cv_llvmgcc_sanity="no"
1091 if test -x "$LLVMGCC" ; then
1092   cp /dev/null conftest.c
1093   "$LLVMGCC" -emit-llvm -S -o - conftest.c | \
1094       grep 'target datalayout =' > /dev/null 2>&1
1095   if test $? -eq 0 ; then
1096     llvm_cv_llvmgcc_sanity="yes"
1097   fi
1098   rm conftest.c
1099 fi])
1100
1101 dnl Since we have a sane llvm-gcc, identify it and its sub-tools
1102 if test "$llvm_cv_llvmgcc_sanity" = "yes" ; then
1103   AC_MSG_CHECKING([llvm-gcc component support])
1104   llvmcc1path=`"$LLVMGCC" --print-prog-name=cc1`
1105   AC_SUBST(LLVMCC1,$llvmcc1path)
1106   llvmcc1pluspath=`"$LLVMGCC" --print-prog-name=cc1plus`
1107   AC_SUBST(LLVMCC1PLUS,$llvmcc1pluspath)
1108   llvmgccdir=`echo "$llvmcc1path" | sed 's,/libexec/.*,,'`
1109   AC_SUBST(LLVMGCCDIR,$llvmgccdir)
1110   llvmgcclibexec=`echo "$llvmcc1path" | sed 's,/cc1,,'`
1111   AC_SUBST(LLVMGCCLIBEXEC,$llvmgcclibexec)
1112   llvmgccversion=[`"$LLVMGCC" -dumpversion 2>&1 | sed 's/^\([0-9.]*\).*/\1/'`]
1113   llvmgccmajvers=[`echo $llvmgccversion | sed 's/^\([0-9]\).*/\1/'`]
1114   AC_SUBST(LLVMGCC_VERSION,$llvmgccversion)
1115   AC_SUBST(LLVMGCC_MAJVERS,$llvmgccmajvers)
1116   llvmgcclangs=[`"$LLVMGCC" -v --help 2>&1 | grep '^Configured with:' | sed 's/^.*--enable-languages=\([^ ]*\).*/\1/'`]
1117   AC_SUBST(LLVMGCC_LANGS,$llvmgcclangs)
1118   AC_MSG_RESULT([ok])
1119 fi
1120
1121 dnl Propagate the shared library extension that the libltdl checks did to
1122 dnl the Makefiles so we can use it there too
1123 AC_SUBST(SHLIBEXT,$libltdl_cv_shlibext)
1124
1125 # Translate the various configuration directories and other basic
1126 # information into substitutions that will end up in Makefile.config.in
1127 # that these configured values can be used by the makefiles
1128 if test "${prefix}" = "NONE" ; then
1129   prefix="/usr/local"
1130 fi
1131 eval LLVM_PREFIX="${prefix}";
1132 eval LLVM_BINDIR="${prefix}/bin";
1133 eval LLVM_LIBDIR="${prefix}/lib";
1134 eval LLVM_DATADIR="${prefix}/share/llvm";
1135 eval LLVM_DOCSDIR="${prefix}/docs/llvm";
1136 eval LLVM_ETCDIR="${prefix}/etc/llvm";
1137 eval LLVM_INCLUDEDIR="${prefix}/include";
1138 eval LLVM_INFODIR="${prefix}/info";
1139 eval LLVM_MANDIR="${prefix}/man";
1140 LLVM_CONFIGTIME=`date`
1141 AC_SUBST(LLVM_PREFIX)
1142 AC_SUBST(LLVM_BINDIR)
1143 AC_SUBST(LLVM_LIBDIR)
1144 AC_SUBST(LLVM_DATADIR)
1145 AC_SUBST(LLVM_DOCSDIR)
1146 AC_SUBST(LLVM_ETCDIR)
1147 AC_SUBST(LLVM_INCLUDEDIR)
1148 AC_SUBST(LLVM_INFODIR)
1149 AC_SUBST(LLVM_MANDIR)
1150 AC_SUBST(LLVM_CONFIGTIME)
1151
1152 # Place the various directores into the config.h file as #defines so that we
1153 # can know about the installation paths within LLVM.
1154 AC_DEFINE_UNQUOTED(LLVM_PREFIX,"$LLVM_PREFIX",
1155                    [Installation prefix directory])
1156 AC_DEFINE_UNQUOTED(LLVM_BINDIR, "$LLVM_BINDIR",
1157                    [Installation directory for binary executables])
1158 AC_DEFINE_UNQUOTED(LLVM_LIBDIR, "$LLVM_LIBDIR",
1159                    [Installation directory for libraries])
1160 AC_DEFINE_UNQUOTED(LLVM_DATADIR, "$LLVM_DATADIR",
1161                    [Installation directory for data files])
1162 AC_DEFINE_UNQUOTED(LLVM_DOCSDIR, "$LLVM_DOCSDIR",
1163                    [Installation directory for documentation])
1164 AC_DEFINE_UNQUOTED(LLVM_ETCDIR, "$LLVM_ETCDIR",
1165                    [Installation directory for config files])
1166 AC_DEFINE_UNQUOTED(LLVM_INCLUDEDIR, "$LLVM_INCLUDEDIR",
1167                    [Installation directory for include files])
1168 AC_DEFINE_UNQUOTED(LLVM_INFODIR, "$LLVM_INFODIR",
1169                    [Installation directory for .info files])
1170 AC_DEFINE_UNQUOTED(LLVM_MANDIR, "$LLVM_MANDIR",
1171                    [Installation directory for man pages])
1172 AC_DEFINE_UNQUOTED(LLVM_CONFIGTIME, "$LLVM_CONFIGTIME",
1173                    [Time at which LLVM was configured])
1174 AC_DEFINE_UNQUOTED(LLVM_HOSTTRIPLE, "$host",
1175                    [Host triple we were built on])
1176
1177 # Determine which bindings to build.
1178 if test "$BINDINGS_TO_BUILD" = auto ; then
1179   BINDINGS_TO_BUILD=""
1180   if test "x$OCAMLC" != x -a "x$OCAMLDEP" != x ; then
1181     BINDINGS_TO_BUILD="ocaml $BINDINGS_TO_BUILD"
1182   fi
1183 fi
1184 AC_SUBST(BINDINGS_TO_BUILD,$BINDINGS_TO_BUILD)
1185
1186 # This isn't really configurey, but it avoids having to repeat the list in
1187 # other files.
1188 AC_SUBST(ALL_BINDINGS,ocaml)
1189
1190 # Do any work necessary to ensure that bindings have what they need.
1191 binding_prereqs_failed=0
1192 for a_binding in $BINDINGS_TO_BUILD ; do
1193   case "$a_binding" in
1194   ocaml)
1195     if test "x$OCAMLC" = x ; then
1196       AC_MSG_WARN([--enable-bindings=ocaml specified, but ocamlc not found. Try configure OCAMLC=/path/to/ocamlc])
1197       binding_prereqs_failed=1
1198     fi
1199     if test "x$OCAMLDEP" = x ; then
1200       AC_MSG_WARN([--enable-bindings=ocaml specified, but ocamldep not found. Try configure OCAMLDEP=/path/to/ocamldep])
1201       binding_prereqs_failed=1
1202     fi
1203     if test "x$OCAMLOPT" = x ; then
1204       AC_MSG_WARN([--enable-bindings=ocaml specified, but ocamlopt not found. Try configure OCAMLOPT=/path/to/ocamlopt])
1205       dnl ocamlopt is optional!
1206     fi
1207     if test "x$with_ocaml_libdir" != xauto ; then
1208       AC_SUBST(OCAML_LIBDIR,$with_ocaml_libdir)
1209     else
1210       ocaml_stdlib="`"$OCAMLC" -where`"
1211       if test "$LLVM_PREFIX" '<' "$ocaml_stdlib" -a "$ocaml_stdlib" '<' "$LLVM_PREFIX~"
1212       then
1213         # ocaml stdlib is beneath our prefix; use stdlib
1214         AC_SUBST(OCAML_LIBDIR,$ocaml_stdlib)
1215       else
1216         # ocaml stdlib is outside our prefix; use libdir/ocaml
1217         AC_SUBST(OCAML_LIBDIR,$LLVM_LIBDIR/ocaml)
1218       fi
1219     fi
1220     ;;
1221   esac
1222 done
1223 if test "$binding_prereqs_failed" = 1 ; then
1224   AC_MSG_ERROR([Prequisites for bindings not satisfied. Fix them or use configure --disable-bindings.])
1225 fi
1226
1227 dnl Determine whether the compiler supports -fvisibility-inlines-hidden.
1228 AC_CXX_USE_VISIBILITY_INLINES_HIDDEN
1229
1230 dnl Determine linker rpath flag
1231 if test "$llvm_cv_link_use_r" = "yes" ; then
1232   RPATH="-Wl,-R"
1233 else
1234   RPATH="-Wl,-rpath"
1235 fi
1236 AC_SUBST(RPATH)
1237
1238 dnl Determine linker rdynamic flag
1239 if test "$llvm_cv_link_use_export_dynamic" = "yes" ; then
1240   RDYNAMIC="-Wl,-export-dynamic"
1241 else
1242   RDYNAMIC=""
1243 fi
1244 AC_SUBST(RDYNAMIC)
1245
1246 dnl===-----------------------------------------------------------------------===
1247 dnl===
1248 dnl=== SECTION 10: Specify the output files and generate it
1249 dnl===
1250 dnl===-----------------------------------------------------------------------===
1251
1252 dnl Configure header files
1253 dnl WARNING: dnl If you add or remove any of the following config headers, then
1254 dnl you MUST also update Makefile.rules so that the variable FilesToConfig
1255 dnl contains the same list of files as AC_CONFIG_HEADERS below. This ensures the
1256 dnl files can be updated automatically when their *.in sources change.
1257 AC_CONFIG_HEADERS([include/llvm/Config/config.h])
1258 AC_CONFIG_FILES([include/llvm/Config/Targets.def])
1259 AC_CONFIG_FILES([include/llvm/Config/AsmPrinters.def])
1260 AC_CONFIG_HEADERS([include/llvm/Support/DataTypes.h])
1261 AC_CONFIG_HEADERS([include/llvm/ADT/iterator.h])
1262
1263 dnl Configure the makefile's configuration data
1264 AC_CONFIG_FILES([Makefile.config])
1265
1266 dnl Configure the RPM spec file for LLVM
1267 AC_CONFIG_FILES([llvm.spec])
1268
1269 dnl Configure doxygen's configuration file
1270 AC_CONFIG_FILES([docs/doxygen.cfg])
1271
1272 dnl Configure llvmc's Base plugin
1273 AC_CONFIG_FILES([tools/llvmc/plugins/Base/Base.td])
1274
1275 dnl Do the first stage of configuration for llvm-config.in.
1276 AC_CONFIG_FILES([tools/llvm-config/llvm-config.in])
1277
1278 dnl Do special configuration of Makefiles
1279 AC_CONFIG_COMMANDS([setup],,[llvm_src="${srcdir}"])
1280 AC_CONFIG_MAKEFILE(Makefile)
1281 AC_CONFIG_MAKEFILE(Makefile.common)
1282 AC_CONFIG_MAKEFILE(examples/Makefile)
1283 AC_CONFIG_MAKEFILE(lib/Makefile)
1284 AC_CONFIG_MAKEFILE(runtime/Makefile)
1285 AC_CONFIG_MAKEFILE(test/Makefile)
1286 AC_CONFIG_MAKEFILE(test/Makefile.tests)
1287 AC_CONFIG_MAKEFILE(unittests/Makefile)
1288 AC_CONFIG_MAKEFILE(tools/Makefile)
1289 AC_CONFIG_MAKEFILE(utils/Makefile)
1290 AC_CONFIG_MAKEFILE(projects/Makefile)
1291 AC_CONFIG_MAKEFILE(bindings/Makefile)
1292 AC_CONFIG_MAKEFILE(bindings/ocaml/Makefile.ocaml)
1293
1294 dnl Finally, crank out the output
1295 AC_OUTPUT