CMakeLists.txt

   1 # See docs/CMake.html for instructions about how to build LLVM with CMake.
   2
   3 project(LLVM)
   4 cmake_minimum_required(VERSION 2.8)
   5
   6 # Add path for custom modules
   7 set(CMAKE_MODULE_PATH
   8   ${CMAKE_MODULE_PATH}
   9   "${CMAKE_CURRENT_SOURCE_DIR}/cmake"
  10   "${CMAKE_CURRENT_SOURCE_DIR}/cmake/modules"
  11   )
  12
  13 set(PACKAGE_VERSION "3.0")
  14
  15 set_property(GLOBAL PROPERTY USE_FOLDERS ON)
  16
  17 include(VersionFromVCS)
  18
  19 option(LLVM_APPEND_VC_REV
  20   "Append the version control system revision id to LLVM version" OFF)
  21
  22 if( LLVM_APPEND_VC_REV )
  23   add_version_info_from_vcs(PACKAGE_VERSION)
  24 endif()
  25
  26 set(PACKAGE_NAME llvm)
  27 set(PACKAGE_STRING "${PACKAGE_NAME} ${PACKAGE_VERSION}")
  28 set(PACKAGE_BUGREPORT "llvmbugs@cs.uiuc.edu")
  29
  30 if( CMAKE_SOURCE_DIR STREQUAL CMAKE_BINARY_DIR AND NOT MSVC_IDE )
  31   message(FATAL_ERROR "In-source builds are not allowed.
  32 CMake would overwrite the makefiles distributed with LLVM.
  33 Please create a directory and run cmake from there, passing the path
  34 to this source directory as the last argument.
  35 This process created the file `CMakeCache.txt' and the directory `CMakeFiles'.
  36 Please delete them.")
  37 endif()
  38
  39 string(TOUPPER "${CMAKE_BUILD_TYPE}" uppercase_CMAKE_BUILD_TYPE)
  40
  41 set(LLVM_MAIN_SRC_DIR ${CMAKE_CURRENT_SOURCE_DIR})
  42 set(LLVM_MAIN_INCLUDE_DIR ${LLVM_MAIN_SRC_DIR}/include)
  43 set(LLVM_BINARY_DIR ${CMAKE_CURRENT_BINARY_DIR})
  44 set(LLVM_TOOLS_BINARY_DIR ${LLVM_BINARY_DIR}/bin)
  45 set(LLVM_EXAMPLES_BINARY_DIR ${LLVM_BINARY_DIR}/examples)
  46 set(LLVM_LIBDIR_SUFFIX "" CACHE STRING "Define suffix of library directory name (32/64)" )
  47
  48 if( NOT CMAKE_SOURCE_DIR STREQUAL CMAKE_BINARY_DIR )
  49   file(GLOB_RECURSE
  50     tablegenned_files_on_include_dir
  51     "${LLVM_MAIN_SRC_DIR}/include/llvm/*.gen")
  52   file(GLOB_RECURSE
  53     tablegenned_files_on_lib_dir
  54     "${LLVM_MAIN_SRC_DIR}/lib/Target/*.inc")
  55   if( tablegenned_files_on_include_dir OR tablegenned_files_on_lib_dir)
  56     message(FATAL_ERROR "Apparently there is a previous in-source build,
  57 probably as the result of running `configure' and `make' on
  58 ${LLVM_MAIN_SRC_DIR}.
  59 This may cause problems. The suspicious files are:
  60 ${tablegenned_files_on_lib_dir}
  61 ${tablegenned_files_on_include_dir}
  62 Please clean the source directory.")
  63   endif()
  64 endif()
  65
  66 set(LLVM_ALL_TARGETS
  67   Alpha
  68   ARM
  69   Blackfin
  70   CBackend
  71   CellSPU
  72   CppBackend
  73   Mips
  74   MBlaze
  75   MSP430
  76   PowerPC
  77   PTX
  78   Sparc
  79   X86
  80   XCore
  81   )
  82
  83 # List of targets with JIT support:
  84 set(LLVM_TARGETS_WITH_JIT X86 PowerPC ARM Mips)
  85
  86 if( MSVC )
  87   set(LLVM_TARGETS_TO_BUILD X86
  88     CACHE STRING "Semicolon-separated list of targets to build, or \"all\".")
  89 else( MSVC )
  90   set(LLVM_TARGETS_TO_BUILD ${LLVM_ALL_TARGETS}
  91     CACHE STRING "Semicolon-separated list of targets to build, or \"all\".")
  92 endif( MSVC )
  93
  94 option(LLVM_ENABLE_CBE_PRINTF_A "Set to ON if CBE is enabled for printf %a output" ON)
  95 if(LLVM_ENABLE_CBE_PRINTF_A)
  96   set(ENABLE_CBE_PRINTF_A 1)
  97 endif()
  98
  99 option(LLVM_ENABLE_TIMESTAMPS "Enable embedding timestamp information in build" ON)
 100 if(LLVM_ENABLE_TIMESTAMPS)
 101   set(ENABLE_TIMESTAMPS 1)
 102 endif()
 103
 104 option(LLVM_ENABLE_FFI "Use libffi to call external functions from the interpreter" OFF)
 105 set(FFI_LIBRARY_DIR "" CACHE PATH "Additional directory, where CMake should search for libffi.so")
 106 set(FFI_INCLUDE_DIR "" CACHE PATH "Additional directory, where CMake should search for ffi.h or ffi/ffi.h")
 107
 108 set(LLVM_TARGET_ARCH "host"
 109   CACHE STRING "Set target to use for LLVM JIT or use \"host\" for automatic detection.")
 110
 111 option(LLVM_ENABLE_THREADS "Use threads if available." ON)
 112
 113 if( LLVM_TARGETS_TO_BUILD STREQUAL "all" )
 114   set( LLVM_TARGETS_TO_BUILD ${LLVM_ALL_TARGETS} )
 115 endif()
 116
 117 set(LLVM_ENUM_TARGETS "")
 118 foreach(c ${LLVM_TARGETS_TO_BUILD})
 119   list(FIND LLVM_ALL_TARGETS ${c} idx)
 120   if( idx LESS 0 )
 121     message(FATAL_ERROR "The target `${c}' does not exist.
 122     It should be one of\n${LLVM_ALL_TARGETS}")
 123   else()
 124     set(LLVM_ENUM_TARGETS "${LLVM_ENUM_TARGETS}LLVM_TARGET(${c})\n")
 125   endif()
 126 endforeach(c)
 127
 128 # Produce llvm/Config/Targets.def
 129 configure_file(
 130   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/Targets.def.in
 131   ${LLVM_BINARY_DIR}/include/llvm/Config/Targets.def
 132   )
 133
 134 set(llvm_builded_incs_dir ${LLVM_BINARY_DIR}/include/llvm)
 135
 136 include(AddLLVMDefinitions)
 137
 138 option(LLVM_ENABLE_PIC "Build Position-Independent Code" ON)
 139
 140 # MSVC has a gazillion warnings with this.
 141 if( MSVC )
 142   option(LLVM_ENABLE_WARNINGS "Enable compiler warnings." OFF)
 143 else( MSVC )
 144   option(LLVM_ENABLE_WARNINGS "Enable compiler warnings." ON)
 145 endif()
 146
 147 option(LLVM_ENABLE_PEDANTIC "Compile with pedantic enabled." ON)
 148 option(LLVM_ENABLE_WERROR "Fail and stop if a warning is triggered." OFF)
 149
 150 if( uppercase_CMAKE_BUILD_TYPE STREQUAL "RELEASE" )
 151   option(LLVM_ENABLE_ASSERTIONS "Enable assertions" OFF)
 152 else()
 153   option(LLVM_ENABLE_ASSERTIONS "Enable assertions" ON)
 154 endif()
 155
 156 # All options referred to from HandleLLVMOptions have to be specified
 157 # BEFORE this include, otherwise options will not be correctly set on
 158 # first cmake run
 159 include(config-ix)
 160 include(HandleLLVMOptions)
 161
 162 configure_file(
 163   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/config.h.cmake
 164   ${LLVM_BINARY_DIR}/include/llvm/Config/config.h)
 165
 166 configure_file(
 167   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/llvm-config.h.cmake
 168   ${LLVM_BINARY_DIR}/include/llvm/Config/llvm-config.h)
 169
 170 configure_file(
 171   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Support/DataTypes.h.cmake
 172   ${LLVM_BINARY_DIR}/include/llvm/Support/DataTypes.h)
 173
 174 set( CMAKE_RUNTIME_OUTPUT_DIRECTORY ${LLVM_TOOLS_BINARY_DIR} )
 175 set( CMAKE_LIBRARY_OUTPUT_DIRECTORY ${LLVM_BINARY_DIR}/lib )
 176 set( CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${LLVM_BINARY_DIR}/lib )
 177
 178 set(CMAKE_INCLUDE_CURRENT_DIR ON)
 179
 180 include_directories( ${LLVM_BINARY_DIR}/include ${LLVM_MAIN_INCLUDE_DIR})
 181
 182 if( ${CMAKE_SYSTEM_NAME} MATCHES SunOS )
 183    SET(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -include llvm/Support/Solaris.h")
 184 endif( ${CMAKE_SYSTEM_NAME} MATCHES SunOS )
 185
 186 include(AddLLVM)
 187 include(TableGen)
 188
 189 macro(llvm_tablegen)
 190   tablegen(LLVM ${ARGN})
 191 endmacro()
 192
 193 if( MINGW )
 194   # People report that -O3 is unreliable on MinGW. The traditional
 195   # build also uses -O2 for that reason:
 196   llvm_replace_compiler_option(CMAKE_CXX_FLAGS_RELEASE "-O3" "-O2")
 197 endif()
 198
 199 # Put this before tblgen. Else we have a circular dependence.
 200 add_subdirectory(lib/Support)
 201 add_subdirectory(lib/TableGen)
 202
 203 add_subdirectory(utils/TableGen)
 204
 205 add_subdirectory(include/llvm)
 206
 207 add_subdirectory(lib)
 208
 209 add_subdirectory(utils/FileCheck)
 210 add_subdirectory(utils/FileUpdate)
 211 add_subdirectory(utils/count)
 212 add_subdirectory(utils/not)
 213 add_subdirectory(utils/llvm-lit)
 214
 215 add_subdirectory(projects)
 216
 217 option(LLVM_BUILD_TOOLS
 218   "Build the LLVM tools. If OFF, just generate build targets." ON)
 219 option(LLVM_INCLUDE_TOOLS "Generate build targets for the LLVM tools." ON)
 220 if( LLVM_INCLUDE_TOOLS )
 221   add_subdirectory(tools)
 222 endif()
 223
 224 option(LLVM_BUILD_RUNTIME
 225   "Build the LLVM runtime libraries. If OFF, just generate build targets." ON)
 226 option(LLVM_INCLUDE_RUNTIME "Generate build targets for the LLVM runtimes" ON)
 227 if( LLVM_INCLUDE_RUNTIME )
 228   add_subdirectory(runtime)
 229 endif()
 230
 231 option(LLVM_BUILD_EXAMPLES
 232   "Build the LLVM example programs. If OFF, just generate build targets." OFF)
 233 option(LLVM_INCLUDE_EXAMPLES "Generate build targets for the LLVM examples" ON)
 234 if( LLVM_INCLUDE_EXAMPLES )
 235   add_subdirectory(examples)
 236 endif()
 237
 238 option(LLVM_BUILD_TESTS
 239   "Build LLVM unit tests. If OFF, just generate build targets." OFF)
 240 if( LLVM_INCLUDE_TESTS )
 241   add_subdirectory(test)
 242   add_subdirectory(utils/unittest)
 243   add_subdirectory(unittests)
 244   if (MSVC)
 245     # This utility is used to prevent chrashing tests from calling Dr. Watson on
 246     # Windows.
 247     add_subdirectory(utils/KillTheDoctor)
 248   endif()
 249 endif()
 250
 251 add_subdirectory(cmake/modules)
 252
 253 install(DIRECTORY include/
 254   DESTINATION include
 255   FILES_MATCHING
 256   PATTERN "*.def"
 257   PATTERN "*.h"
 258   PATTERN "*.td"
 259   PATTERN "*.inc"
 260   PATTERN "LICENSE.TXT"
 261   PATTERN ".svn" EXCLUDE
 262   )
 263
 264 install(DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/include/
 265   DESTINATION include
 266   FILES_MATCHING
 267   PATTERN "*.def"
 268   PATTERN "*.h"
 269   PATTERN "*.gen"
 270   PATTERN "*.inc"
 271   # Exclude include/llvm/CMakeFiles/intrinsics_gen.dir, matched by "*.def"
 272   PATTERN "CMakeFiles" EXCLUDE
 273   PATTERN ".svn" EXCLUDE
 274   )
 275
 276 # TODO: make and install documentation.
 277
 278 set(CPACK_PACKAGE_VENDOR "LLVM")
 279 set(CPACK_PACKAGE_VERSION_MAJOR 2)
 280 set(CPACK_PACKAGE_VERSION_MINOR 9)
 281 add_version_info_from_vcs(CPACK_PACKAGE_VERSION_PATCH)
 282 include(CPack)
 283
 284 # Workaround for MSVS10 to avoid the Dialog Hell
 285 # FIXME: This could be removed with future version of CMake.
 286 if(MSVC_VERSION EQUAL 1600)
 287   set(LLVM_SLN_FILENAME "${CMAKE_CURRENT_BINARY_DIR}/LLVM.sln")
 288   if( EXISTS "${LLVM_SLN_FILENAME}" )
 289     file(APPEND "${LLVM_SLN_FILENAME}" "\n# This should be regenerated!\n")
 290   endif()
 291 endif()