CMakeLists.txt

   1 # See docs/CMake.html for instructions about how to build LLVM with CMake.
   2
   3 cmake_minimum_required(VERSION 2.8.8)
   4
   5 # FIXME: It may be removed when we use 2.8.12.
   6 if(CMAKE_VERSION VERSION_LESS 2.8.12)
   7   # Invalidate a couple of keywords.
   8   set(cmake_2_8_12_INTERFACE)
   9   set(cmake_2_8_12_PRIVATE)
  10 else()
  11   # Use ${cmake_2_8_12_KEYWORD} intead of KEYWORD in target_link_libraries().
  12   set(cmake_2_8_12_INTERFACE INTERFACE)
  13   set(cmake_2_8_12_PRIVATE PRIVATE)
  14   if(POLICY CMP0022)
  15     cmake_policy(SET CMP0022 NEW) # automatic when 2.8.12 is required
  16   endif()
  17 endif()
  18
  19 project(LLVM)
  20
  21 # Add path for custom modules
  22 set(CMAKE_MODULE_PATH
  23   ${CMAKE_MODULE_PATH}
  24   "${CMAKE_CURRENT_SOURCE_DIR}/cmake"
  25   "${CMAKE_CURRENT_SOURCE_DIR}/cmake/modules"
  26   )
  27
  28 set(LLVM_VERSION_MAJOR 3)
  29 set(LLVM_VERSION_MINOR 6)
  30 set(LLVM_VERSION_PATCH 0)
  31
  32 if (NOT PACKAGE_VERSION)
  33   set(PACKAGE_VERSION "${LLVM_VERSION_MAJOR}.${LLVM_VERSION_MINOR}.${LLVM_VERSION_PATCH}svn")
  34 endif()
  35
  36 option(LLVM_INSTALL_TOOLCHAIN_ONLY "Only include toolchain files in the 'install' target." OFF)
  37
  38 option(LLVM_USE_FOLDERS "Enable solution folders in Visual Studio. Disable for Express versions." ON)
  39 if ( LLVM_USE_FOLDERS )
  40   set_property(GLOBAL PROPERTY USE_FOLDERS ON)
  41 endif()
  42
  43 include(VersionFromVCS)
  44
  45 option(LLVM_APPEND_VC_REV
  46   "Append the version control system revision id to LLVM version" OFF)
  47
  48 if( LLVM_APPEND_VC_REV )
  49   add_version_info_from_vcs(PACKAGE_VERSION)
  50 endif()
  51
  52 set(PACKAGE_NAME LLVM)
  53 set(PACKAGE_STRING "${PACKAGE_NAME} ${PACKAGE_VERSION}")
  54 set(PACKAGE_BUGREPORT "http://llvm.org/bugs/")
  55
  56 set(BUG_REPORT_URL "${PACKAGE_BUGREPORT}" CACHE STRING
  57   "Default URL where bug reports are to be submitted.")
  58
  59 # Configure CPack.
  60 set(CPACK_PACKAGE_INSTALL_DIRECTORY "LLVM")
  61 set(CPACK_PACKAGE_VENDOR "LLVM")
  62 set(CPACK_PACKAGE_VERSION_MAJOR ${LLVM_VERSION_MAJOR})
  63 set(CPACK_PACKAGE_VERSION_MINOR ${LLVM_VERSION_MINOR})
  64 set(CPACK_PACKAGE_VERSION_PATCH ${LLVM_VERSION_PATCH})
  65 set(CPACK_PACKAGE_VERSION ${PACKAGE_VERSION})
  66 set(CPACK_RESOURCE_FILE_LICENSE "${CMAKE_CURRENT_SOURCE_DIR}/LICENSE.TXT")
  67 if(WIN32 AND NOT UNIX)
  68   set(CPACK_PACKAGE_INSTALL_REGISTRY_KEY "LLVM")
  69   set(CPACK_PACKAGE_ICON "${CMAKE_CURRENT_SOURCE_DIR}\\\\cmake\\\\nsis_logo.bmp")
  70   set(CPACK_NSIS_MUI_ICON "${CMAKE_CURRENT_SOURCE_DIR}\\\\cmake\\\\nsis_icon.ico")
  71   set(CPACK_NSIS_MUI_UNIICON "${CMAKE_CURRENT_SOURCE_DIR}\\\\cmake\\\\nsis_icon.ico")
  72   set(CPACK_NSIS_MODIFY_PATH "ON")
  73   set(CPACK_NSIS_ENABLE_UNINSTALL_BEFORE_INSTALL "ON")
  74   set(CPACK_NSIS_EXTRA_INSTALL_COMMANDS
  75     "ExecWait '$INSTDIR/tools/msbuild/install.bat'")
  76   set(CPACK_NSIS_EXTRA_UNINSTALL_COMMANDS
  77     "ExecWait '$INSTDIR/tools/msbuild/uninstall.bat'")
  78 endif()
  79 include(CPack)
  80
  81 # Sanity check our source directory to make sure that we are not trying to
  82 # generate an in-tree build (unless on MSVC_IDE, where it is ok), and to make
  83 # sure that we don't have any stray generated files lying around in the tree
  84 # (which would end up getting picked up by header search, instead of the correct
  85 # versions).
  86 if( CMAKE_SOURCE_DIR STREQUAL CMAKE_BINARY_DIR AND NOT MSVC_IDE )
  87   message(FATAL_ERROR "In-source builds are not allowed.
  88 CMake would overwrite the makefiles distributed with LLVM.
  89 Please create a directory and run cmake from there, passing the path
  90 to this source directory as the last argument.
  91 This process created the file `CMakeCache.txt' and the directory `CMakeFiles'.
  92 Please delete them.")
  93 endif()
  94 if( NOT CMAKE_SOURCE_DIR STREQUAL CMAKE_BINARY_DIR )
  95   file(GLOB_RECURSE
  96     tablegenned_files_on_include_dir
  97     "${CMAKE_CURRENT_SOURCE_DIR}/include/llvm/*.gen")
  98   file(GLOB_RECURSE
  99     tablegenned_files_on_lib_dir
 100     "${CMAKE_CURRENT_SOURCE_DIR}/lib/Target/*.inc")
 101   if( tablegenned_files_on_include_dir OR tablegenned_files_on_lib_dir)
 102     message(FATAL_ERROR "Apparently there is a previous in-source build,
 103 probably as the result of running `configure' and `make' on
 104 ${CMAKE_CURRENT_SOURCE_DIR}.
 105 This may cause problems. The suspicious files are:
 106 ${tablegenned_files_on_lib_dir}
 107 ${tablegenned_files_on_include_dir}
 108 Please clean the source directory.")
 109   endif()
 110 endif()
 111
 112 string(TOUPPER "${CMAKE_BUILD_TYPE}" uppercase_CMAKE_BUILD_TYPE)
 113
 114 # They are used as destination of target generators.
 115 set(LLVM_RUNTIME_OUTPUT_INTDIR ${CMAKE_CURRENT_BINARY_DIR}/${CMAKE_CFG_INTDIR}/bin)
 116 set(LLVM_LIBRARY_OUTPUT_INTDIR ${CMAKE_CURRENT_BINARY_DIR}/${CMAKE_CFG_INTDIR}/lib)
 117 if(WIN32 OR CYGWIN)
 118   # DLL platform -- put DLLs into bin.
 119   set(LLVM_SHLIB_OUTPUT_INTDIR ${LLVM_RUNTIME_OUTPUT_INTDIR})
 120 else()
 121   set(LLVM_SHLIB_OUTPUT_INTDIR ${LLVM_LIBRARY_OUTPUT_INTDIR})
 122 endif()
 123
 124 # Each of them corresponds to llvm-config's.
 125 set(LLVM_TOOLS_BINARY_DIR ${LLVM_RUNTIME_OUTPUT_INTDIR}) # --bindir
 126 set(LLVM_LIBRARY_DIR      ${LLVM_LIBRARY_OUTPUT_INTDIR}) # --libdir
 127 set(LLVM_MAIN_SRC_DIR     ${CMAKE_CURRENT_SOURCE_DIR}  ) # --src-root
 128 set(LLVM_MAIN_INCLUDE_DIR ${LLVM_MAIN_SRC_DIR}/include ) # --includedir
 129 set(LLVM_BINARY_DIR       ${CMAKE_CURRENT_BINARY_DIR}  ) # --prefix
 130
 131 set(LLVM_EXAMPLES_BINARY_DIR ${LLVM_BINARY_DIR}/examples)
 132 set(LLVM_INCLUDE_DIR ${CMAKE_CURRENT_BINARY_DIR}/include)
 133 set(LLVM_LIBDIR_SUFFIX "" CACHE STRING "Define suffix of library directory name (32/64)" )
 134
 135 set(LLVM_ALL_TARGETS
 136   AArch64
 137   ARM
 138   CppBackend
 139   Hexagon
 140   Mips
 141   MSP430
 142   NVPTX
 143   PowerPC
 144   R600
 145   Sparc
 146   SystemZ
 147   X86
 148   XCore
 149   )
 150
 151 # List of targets with JIT support:
 152 set(LLVM_TARGETS_WITH_JIT X86 PowerPC AArch64 ARM Mips SystemZ)
 153
 154 set(LLVM_TARGETS_TO_BUILD "all"
 155     CACHE STRING "Semicolon-separated list of targets to build, or \"all\".")
 156
 157 set(LLVM_EXPERIMENTAL_TARGETS_TO_BUILD ""
 158   CACHE STRING "Semicolon-separated list of experimental targets to build.")
 159
 160 option(BUILD_SHARED_LIBS
 161   "Build all libraries as shared libraries instead of static" OFF)
 162
 163 option(LLVM_ENABLE_TIMESTAMPS "Enable embedding timestamp information in build" ON)
 164 if(LLVM_ENABLE_TIMESTAMPS)
 165   set(ENABLE_TIMESTAMPS 1)
 166 endif()
 167
 168 option(LLVM_ENABLE_BACKTRACES "Enable embedding backtraces on crash." ON)
 169 if(LLVM_ENABLE_BACKTRACES)
 170   set(ENABLE_BACKTRACES 1)
 171 endif()
 172
 173 option(LLVM_ENABLE_CRASH_OVERRIDES "Enable crash overrides." ON)
 174 if(LLVM_ENABLE_CRASH_OVERRIDES)
 175   set(ENABLE_CRASH_OVERRIDES 1)
 176 endif()
 177
 178 option(LLVM_ENABLE_FFI "Use libffi to call external functions from the interpreter" OFF)
 179 set(FFI_LIBRARY_DIR "" CACHE PATH "Additional directory, where CMake should search for libffi.so")
 180 set(FFI_INCLUDE_DIR "" CACHE PATH "Additional directory, where CMake should search for ffi.h or ffi/ffi.h")
 181
 182 set(LLVM_TARGET_ARCH "host"
 183   CACHE STRING "Set target to use for LLVM JIT or use \"host\" for automatic detection.")
 184
 185 option(LLVM_ENABLE_TERMINFO "Use terminfo database if available." ON)
 186
 187 option(LLVM_ENABLE_THREADS "Use threads if available." ON)
 188
 189 option(LLVM_ENABLE_ZLIB "Use zlib for compression/decompression if available." ON)
 190
 191 if( LLVM_TARGETS_TO_BUILD STREQUAL "all" )
 192   set( LLVM_TARGETS_TO_BUILD ${LLVM_ALL_TARGETS} )
 193 endif()
 194
 195 set(LLVM_TARGETS_TO_BUILD
 196    ${LLVM_TARGETS_TO_BUILD}
 197    ${LLVM_EXPERIMENTAL_TARGETS_TO_BUILD})
 198 list(REMOVE_DUPLICATES LLVM_TARGETS_TO_BUILD)
 199
 200 include(AddLLVMDefinitions)
 201
 202 option(LLVM_ENABLE_PIC "Build Position-Independent Code" ON)
 203
 204 # MSVC has a gazillion warnings with this.
 205 if( MSVC )
 206   option(LLVM_ENABLE_WARNINGS "Enable compiler warnings." OFF)
 207 else()
 208   option(LLVM_ENABLE_WARNINGS "Enable compiler warnings." ON)
 209 endif()
 210
 211 option(LLVM_ENABLE_CXX1Y "Compile with C++1y enabled." OFF)
 212 option(LLVM_ENABLE_LIBCXX "Use libc++ if available." OFF)
 213 option(LLVM_ENABLE_PEDANTIC "Compile with pedantic enabled." ON)
 214 option(LLVM_ENABLE_WERROR "Fail and stop if a warning is triggered." OFF)
 215
 216 if( NOT uppercase_CMAKE_BUILD_TYPE STREQUAL "DEBUG" )
 217   option(LLVM_ENABLE_ASSERTIONS "Enable assertions" OFF)
 218 else()
 219   option(LLVM_ENABLE_ASSERTIONS "Enable assertions" ON)
 220 endif()
 221
 222 option(LLVM_FORCE_USE_OLD_HOST_TOOLCHAIN
 223        "Set to ON to force using an old, unsupported host toolchain." OFF)
 224
 225 option(LLVM_USE_INTEL_JITEVENTS
 226   "Use Intel JIT API to inform Intel(R) VTune(TM) Amplifier XE 2011 about JIT code"
 227   OFF)
 228
 229 if( LLVM_USE_INTEL_JITEVENTS )
 230   # Verify we are on a supported platform
 231   if( NOT CMAKE_SYSTEM_NAME MATCHES "Windows" AND NOT CMAKE_SYSTEM_NAME MATCHES "Linux" )
 232     message(FATAL_ERROR
 233       "Intel JIT API support is available on Linux and Windows only.")
 234   endif()
 235 endif( LLVM_USE_INTEL_JITEVENTS )
 236
 237 option(LLVM_USE_OPROFILE
 238   "Use opagent JIT interface to inform OProfile about JIT code" OFF)
 239
 240 # If enabled, verify we are on a platform that supports oprofile.
 241 if( LLVM_USE_OPROFILE )
 242   if( NOT CMAKE_SYSTEM_NAME MATCHES "Linux" )
 243     message(FATAL_ERROR "OProfile support is available on Linux only.")
 244   endif( NOT CMAKE_SYSTEM_NAME MATCHES "Linux" )
 245 endif( LLVM_USE_OPROFILE )
 246
 247 set(LLVM_USE_SANITIZER "" CACHE STRING
 248   "Define the sanitizer used to build binaries and tests.")
 249
 250 option(LLVM_USE_SPLIT_DWARF
 251   "Use -gsplit-dwarf when compiling llvm." OFF)
 252
 253 option(WITH_POLLY "Build LLVM with Polly" ON)
 254 option(LINK_POLLY_INTO_TOOLS "Static link Polly into tools" OFF)
 255
 256 # Define an option controlling whether we should build for 32-bit on 64-bit
 257 # platforms, where supported.
 258 if( CMAKE_SIZEOF_VOID_P EQUAL 8 AND NOT WIN32 )
 259   # TODO: support other platforms and toolchains.
 260   option(LLVM_BUILD_32_BITS "Build 32 bits executables and libraries." OFF)
 261 endif()
 262
 263 # Define the default arguments to use with 'lit', and an option for the user to
 264 # override.
 265 set(LIT_ARGS_DEFAULT "-sv")
 266 if (MSVC OR XCODE)
 267   set(LIT_ARGS_DEFAULT "${LIT_ARGS_DEFAULT} --no-progress-bar")
 268 endif()
 269 set(LLVM_LIT_ARGS "${LIT_ARGS_DEFAULT}" CACHE STRING "Default options for lit")
 270
 271 # On Win32 hosts, provide an option to specify the path to the GnuWin32 tools.
 272 if( WIN32 AND NOT CYGWIN )
 273   set(LLVM_LIT_TOOLS_DIR "" CACHE PATH "Path to GnuWin32 tools")
 274 endif()
 275
 276 # Define options to control the inclusion and default build behavior for
 277 # components which may not strictly be necessary (tools, examples, and tests).
 278 #
 279 # This is primarily to support building smaller or faster project files.
 280 option(LLVM_INCLUDE_TOOLS "Generate build targets for the LLVM tools." ON)
 281 option(LLVM_BUILD_TOOLS
 282   "Build the LLVM tools. If OFF, just generate build targets." ON)
 283
 284 option(LLVM_INCLUDE_UTILS "Generate build targets for the LLVM utils." ON)
 285
 286 option(LLVM_BUILD_RUNTIME
 287   "Build the LLVM runtime libraries." ON)
 288 option(LLVM_BUILD_EXAMPLES
 289   "Build the LLVM example programs. If OFF, just generate build targets." OFF)
 290 option(LLVM_INCLUDE_EXAMPLES "Generate build targets for the LLVM examples" ON)
 291
 292 option(LLVM_BUILD_TESTS
 293   "Build LLVM unit tests. If OFF, just generate build targets." OFF)
 294 option(LLVM_INCLUDE_TESTS "Generate build targets for the LLVM unit tests." ON)
 295
 296 option (LLVM_BUILD_DOCS "Build the llvm documentation." OFF)
 297 option (LLVM_INCLUDE_DOCS "Generate build targets for llvm documentation." ON)
 298 option (LLVM_ENABLE_DOXYGEN "Use doxygen to generate llvm API documentation." OFF)
 299 option (LLVM_ENABLE_SPHINX "Use Sphinx to generate llvm documentation." OFF)
 300
 301 option (LLVM_BUILD_EXTERNAL_COMPILER_RT
 302   "Build compiler-rt as an external project." OFF)
 303
 304 # All options referred to from HandleLLVMOptions have to be specified
 305 # BEFORE this include, otherwise options will not be correctly set on
 306 # first cmake run
 307 include(config-ix)
 308
 309 # By default, we target the host, but this can be overridden at CMake
 310 # invocation time.
 311 set(LLVM_DEFAULT_TARGET_TRIPLE "${LLVM_HOST_TRIPLE}" CACHE STRING
 312   "Default target for which LLVM will generate code." )
 313 set(TARGET_TRIPLE "${LLVM_DEFAULT_TARGET_TRIPLE}")
 314
 315 include(HandleLLVMOptions)
 316
 317 # Verify that we can find a Python 2 interpreter.  Python 3 is unsupported.
 318 set(Python_ADDITIONAL_VERSIONS 2.7 2.6 2.5)
 319 include(FindPythonInterp)
 320 if( NOT PYTHONINTERP_FOUND )
 321   message(FATAL_ERROR
 322 "Unable to find Python interpreter, required for builds and testing.
 323
 324 Please install Python or specify the PYTHON_EXECUTABLE CMake variable.")
 325 endif()
 326
 327 ######
 328 # LLVMBuild Integration
 329 #
 330 # We use llvm-build to generate all the data required by the CMake based
 331 # build system in one swoop:
 332 #
 333 #  - We generate a file (a CMake fragment) in the object root which contains
 334 #    all the definitions that are required by CMake.
 335 #
 336 #  - We generate the library table used by llvm-config.
 337 #
 338 #  - We generate the dependencies for the CMake fragment, so that we will
 339 #    automatically reconfigure outselves.
 340
 341 set(LLVMBUILDTOOL "${LLVM_MAIN_SRC_DIR}/utils/llvm-build/llvm-build")
 342 set(LLVMCONFIGLIBRARYDEPENDENCIESINC
 343   "${LLVM_BINARY_DIR}/tools/llvm-config/LibraryDependencies.inc")
 344 set(LLVMBUILDCMAKEFRAG
 345   "${LLVM_BINARY_DIR}/LLVMBuild.cmake")
 346
 347 # Create the list of optional components that are enabled
 348 if (LLVM_USE_INTEL_JITEVENTS)
 349   set(LLVMOPTIONALCOMPONENTS IntelJITEvents)
 350 endif (LLVM_USE_INTEL_JITEVENTS)
 351 if (LLVM_USE_OPROFILE)
 352   set(LLVMOPTIONALCOMPONENTS ${LLVMOPTIONALCOMPONENTS} OProfileJIT)
 353 endif (LLVM_USE_OPROFILE)
 354
 355 message(STATUS "Constructing LLVMBuild project information")
 356 execute_process(
 357   COMMAND ${PYTHON_EXECUTABLE} ${LLVMBUILDTOOL}
 358             --native-target "${LLVM_NATIVE_ARCH}"
 359             --enable-targets "${LLVM_TARGETS_TO_BUILD}"
 360             --enable-optional-components "${LLVMOPTIONALCOMPONENTS}"
 361             --write-library-table ${LLVMCONFIGLIBRARYDEPENDENCIESINC}
 362             --write-cmake-fragment ${LLVMBUILDCMAKEFRAG}
 363             OUTPUT_VARIABLE LLVMBUILDOUTPUT
 364             ERROR_VARIABLE LLVMBUILDERRORS
 365             OUTPUT_STRIP_TRAILING_WHITESPACE
 366             ERROR_STRIP_TRAILING_WHITESPACE
 367   RESULT_VARIABLE LLVMBUILDRESULT)
 368
 369 # On Win32, CMake doesn't properly handle piping the default output/error
 370 # streams into the GUI console. So, we explicitly catch and report them.
 371 if( NOT "${LLVMBUILDOUTPUT}" STREQUAL "")
 372   message(STATUS "llvm-build output: ${LLVMBUILDOUTPUT}")
 373 endif()
 374 if( NOT "${LLVMBUILDRESULT}" STREQUAL "0" )
 375   message(FATAL_ERROR
 376     "Unexpected failure executing llvm-build: ${LLVMBUILDERRORS}")
 377 endif()
 378
 379 # Include the generated CMake fragment. This will define properties from the
 380 # LLVMBuild files in a format which is easy to consume from CMake, and will add
 381 # the dependencies so that CMake will reconfigure properly when the LLVMBuild
 382 # files change.
 383 include(${LLVMBUILDCMAKEFRAG})
 384
 385 ######
 386
 387 # Configure all of the various header file fragments LLVM uses which depend on
 388 # configuration variables.
 389 set(LLVM_ENUM_TARGETS "")
 390 set(LLVM_ENUM_ASM_PRINTERS "")
 391 set(LLVM_ENUM_ASM_PARSERS "")
 392 set(LLVM_ENUM_DISASSEMBLERS "")
 393 foreach(t ${LLVM_TARGETS_TO_BUILD})
 394   set( td ${LLVM_MAIN_SRC_DIR}/lib/Target/${t} )
 395
 396   list(FIND LLVM_ALL_TARGETS ${t} idx)
 397   list(FIND LLVM_EXPERIMENTAL_TARGETS_TO_BUILD ${t} idy)
 398   if( idx LESS 0 AND idy LESS 0 )
 399     message(FATAL_ERROR "The target `${t}' does not exist.
 400     It should be one of\n${LLVM_ALL_TARGETS}")
 401   else()
 402     set(LLVM_ENUM_TARGETS "${LLVM_ENUM_TARGETS}LLVM_TARGET(${t})\n")
 403   endif()
 404
 405   file(GLOB asmp_file "${td}/*AsmPrinter.cpp")
 406   if( asmp_file )
 407     set(LLVM_ENUM_ASM_PRINTERS
 408       "${LLVM_ENUM_ASM_PRINTERS}LLVM_ASM_PRINTER(${t})\n")
 409   endif()
 410   if( EXISTS ${td}/AsmParser/CMakeLists.txt )
 411     set(LLVM_ENUM_ASM_PARSERS
 412       "${LLVM_ENUM_ASM_PARSERS}LLVM_ASM_PARSER(${t})\n")
 413   endif()
 414   if( EXISTS ${td}/Disassembler/CMakeLists.txt )
 415     set(LLVM_ENUM_DISASSEMBLERS
 416       "${LLVM_ENUM_DISASSEMBLERS}LLVM_DISASSEMBLER(${t})\n")
 417   endif()
 418 endforeach(t)
 419
 420 # Produce the target definition files, which provide a way for clients to easily
 421 # include various classes of targets.
 422 configure_file(
 423   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/AsmPrinters.def.in
 424   ${LLVM_INCLUDE_DIR}/llvm/Config/AsmPrinters.def
 425   )
 426 configure_file(
 427   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/AsmParsers.def.in
 428   ${LLVM_INCLUDE_DIR}/llvm/Config/AsmParsers.def
 429   )
 430 configure_file(
 431   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/Disassemblers.def.in
 432   ${LLVM_INCLUDE_DIR}/llvm/Config/Disassemblers.def
 433   )
 434 configure_file(
 435   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/Targets.def.in
 436   ${LLVM_INCLUDE_DIR}/llvm/Config/Targets.def
 437   )
 438
 439 # Configure the three LLVM configuration header files.
 440 configure_file(
 441   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/config.h.cmake
 442   ${LLVM_INCLUDE_DIR}/llvm/Config/config.h)
 443 configure_file(
 444   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/llvm-config.h.cmake
 445   ${LLVM_INCLUDE_DIR}/llvm/Config/llvm-config.h)
 446 configure_file(
 447   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Support/DataTypes.h.cmake
 448   ${LLVM_INCLUDE_DIR}/llvm/Support/DataTypes.h)
 449
 450 # They are not referenced. See set_output_directory().
 451 set( CMAKE_RUNTIME_OUTPUT_DIRECTORY ${LLVM_BINARY_DIR}/bin )
 452 set( CMAKE_LIBRARY_OUTPUT_DIRECTORY ${LLVM_BINARY_DIR}/lib )
 453 set( CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${LLVM_BINARY_DIR}/lib )
 454
 455 set(CMAKE_BUILD_WITH_INSTALL_RPATH ON)
 456 if (APPLE)
 457   set(CMAKE_INSTALL_NAME_DIR "@rpath")
 458   set(CMAKE_INSTALL_RPATH "@executable_path/../lib")
 459 else(UNIX)
 460   if(NOT DEFINED CMAKE_INSTALL_RPATH)
 461     set(CMAKE_INSTALL_RPATH "\$ORIGIN/../lib")
 462     if (${CMAKE_SYSTEM_NAME} MATCHES FreeBSD)
 463       set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -Wl,-z,origin")
 464       set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} -Wl,-z,origin")
 465     endif()
 466   endif(NOT DEFINED CMAKE_INSTALL_RPATH)
 467 endif()
 468
 469 set(CMAKE_INCLUDE_CURRENT_DIR ON)
 470
 471 include_directories( ${LLVM_INCLUDE_DIR} ${LLVM_MAIN_INCLUDE_DIR})
 472
 473 # when crosscompiling import the executable targets from a file
 474 if(CMAKE_CROSSCOMPILING)
 475   include(CrossCompile)
 476 endif(CMAKE_CROSSCOMPILING)
 477
 478 if( ${CMAKE_SYSTEM_NAME} MATCHES FreeBSD )
 479   # On FreeBSD, /usr/local/* is not used by default. In order to build LLVM
 480   # with libxml2, iconv.h, etc., we must add /usr/local paths.
 481   include_directories("/usr/local/include")
 482   link_directories("/usr/local/lib")
 483 endif( ${CMAKE_SYSTEM_NAME} MATCHES FreeBSD )
 484
 485 if( ${CMAKE_SYSTEM_NAME} MATCHES SunOS )
 486    SET(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -include llvm/Support/Solaris.h")
 487 endif( ${CMAKE_SYSTEM_NAME} MATCHES SunOS )
 488
 489 # Make sure we don't get -rdynamic in every binary. For those that need it,
 490 # use set_target_properties(target PROPERTIES ENABLE_EXPORTS 1)
 491 set(CMAKE_SHARED_LIBRARY_LINK_CXX_FLAGS "")
 492
 493 include(AddLLVM)
 494 include(TableGen)
 495
 496 if( MINGW )
 497   # People report that -O3 is unreliable on MinGW. The traditional
 498   # build also uses -O2 for that reason:
 499   llvm_replace_compiler_option(CMAKE_CXX_FLAGS_RELEASE "-O3" "-O2")
 500 endif()
 501
 502 # Put this before tblgen. Else we have a circular dependence.
 503 add_subdirectory(lib/Support)
 504 add_subdirectory(lib/TableGen)
 505
 506 add_subdirectory(utils/TableGen)
 507
 508 add_subdirectory(include/llvm)
 509
 510 add_subdirectory(lib)
 511
 512 if( LLVM_INCLUDE_UTILS )
 513   add_subdirectory(utils/FileCheck)
 514   add_subdirectory(utils/PerfectShuffle)
 515   add_subdirectory(utils/count)
 516   add_subdirectory(utils/not)
 517   add_subdirectory(utils/llvm-lit)
 518   add_subdirectory(utils/yaml-bench)
 519 else()
 520   if ( LLVM_INCLUDE_TESTS )
 521     message(FATAL_ERROR "Including tests when not building utils will not work.
 522     Either set LLVM_INCLUDE_UTILS to On, or set LLVM_INCLDE_TESTS to Off.")
 523   endif()
 524 endif()
 525
 526 if(LLVM_INCLUDE_TESTS)
 527   add_subdirectory(utils/unittest)
 528 endif()
 529
 530 add_subdirectory(projects)
 531
 532 if(WITH_POLLY)
 533   if(NOT EXISTS ${LLVM_MAIN_SRC_DIR}/tools/polly/CMakeLists.txt)
 534     set(WITH_POLLY OFF)
 535   endif()
 536 endif(WITH_POLLY)
 537
 538 if( LLVM_INCLUDE_TOOLS )
 539   add_subdirectory(tools)
 540 endif()
 541
 542 if( LLVM_INCLUDE_EXAMPLES )
 543   add_subdirectory(examples)
 544 endif()
 545
 546 if( LLVM_INCLUDE_TESTS )
 547   add_subdirectory(test)
 548   add_subdirectory(unittests)
 549   if (MSVC)
 550     # This utility is used to prevent crashing tests from calling Dr. Watson on
 551     # Windows.
 552     add_subdirectory(utils/KillTheDoctor)
 553   endif()
 554
 555   # Add a global check rule now that all subdirectories have been traversed
 556   # and we know the total set of lit testsuites.
 557   get_property(LLVM_LIT_TESTSUITES GLOBAL PROPERTY LLVM_LIT_TESTSUITES)
 558   get_property(LLVM_LIT_PARAMS GLOBAL PROPERTY LLVM_LIT_PARAMS)
 559   get_property(LLVM_LIT_DEPENDS GLOBAL PROPERTY LLVM_LIT_DEPENDS)
 560   get_property(LLVM_LIT_EXTRA_ARGS GLOBAL PROPERTY LLVM_LIT_EXTRA_ARGS)
 561   add_lit_target(check-all
 562     "Running all regression tests"
 563     ${LLVM_LIT_TESTSUITES}
 564     PARAMS ${LLVM_LIT_PARAMS}
 565     DEPENDS ${LLVM_LIT_DEPENDS}
 566     ARGS ${LLVM_LIT_EXTRA_ARGS}
 567     )
 568 endif()
 569
 570 if (LLVM_INCLUDE_DOCS)
 571   add_subdirectory(docs)
 572 endif()
 573
 574 add_subdirectory(cmake/modules)
 575
 576 if (NOT LLVM_INSTALL_TOOLCHAIN_ONLY)
 577   install(DIRECTORY include/llvm include/llvm-c
 578     DESTINATION include
 579     FILES_MATCHING
 580     PATTERN "*.def"
 581     PATTERN "*.h"
 582     PATTERN "*.td"
 583     PATTERN "*.inc"
 584     PATTERN "LICENSE.TXT"
 585     PATTERN ".svn" EXCLUDE
 586     )
 587
 588   install(DIRECTORY ${LLVM_INCLUDE_DIR}/llvm
 589     DESTINATION include
 590     FILES_MATCHING
 591     PATTERN "*.def"
 592     PATTERN "*.h"
 593     PATTERN "*.gen"
 594     PATTERN "*.inc"
 595     # Exclude include/llvm/CMakeFiles/intrinsics_gen.dir, matched by "*.def"
 596     PATTERN "CMakeFiles" EXCLUDE
 597     PATTERN "config.h" EXCLUDE
 598     PATTERN ".svn" EXCLUDE
 599     )
 600 endif()