CMakeLists.txt

   1 # See docs/CMake.html for instructions about how to build LLVM with CMake.
   2
   3 project(LLVM)
   4 cmake_minimum_required(VERSION 2.8)
   5
   6 # Add path for custom modules
   7 set(CMAKE_MODULE_PATH
   8   ${CMAKE_MODULE_PATH}
   9   "${CMAKE_CURRENT_SOURCE_DIR}/cmake"
  10   "${CMAKE_CURRENT_SOURCE_DIR}/cmake/modules"
  11   )
  12
  13 set(LLVM_VERSION_MAJOR 3)
  14 set(LLVM_VERSION_MINOR 2)
  15
  16 set(PACKAGE_VERSION "${LLVM_VERSION_MAJOR}.${LLVM_VERSION_MINOR}svn")
  17
  18 option(LLVM_USE_FOLDERS "Enable solution folders in Visual Studio. Disable for Express versions." ON)
  19 if ( LLVM_USE_FOLDERS )
  20   set_property(GLOBAL PROPERTY USE_FOLDERS ON)
  21 endif()
  22
  23 include(VersionFromVCS)
  24
  25 option(LLVM_APPEND_VC_REV
  26   "Append the version control system revision id to LLVM version" OFF)
  27
  28 if( LLVM_APPEND_VC_REV )
  29   add_version_info_from_vcs(PACKAGE_VERSION)
  30 endif()
  31
  32 set(PACKAGE_NAME LLVM)
  33 set(PACKAGE_STRING "${PACKAGE_NAME} ${PACKAGE_VERSION}")
  34 set(PACKAGE_BUGREPORT "http://llvm.org/bugs/")
  35
  36 # Sanity check our source directory to make sure that we are not trying to
  37 # generate an in-tree build (unless on MSVC_IDE, where it is ok), and to make
  38 # sure that we don't have any stray generated files lying around in the tree
  39 # (which would end up getting picked up by header search, instead of the correct
  40 # versions).
  41 if( CMAKE_SOURCE_DIR STREQUAL CMAKE_BINARY_DIR AND NOT MSVC_IDE )
  42   message(FATAL_ERROR "In-source builds are not allowed.
  43 CMake would overwrite the makefiles distributed with LLVM.
  44 Please create a directory and run cmake from there, passing the path
  45 to this source directory as the last argument.
  46 This process created the file `CMakeCache.txt' and the directory `CMakeFiles'.
  47 Please delete them.")
  48 endif()
  49 if( NOT CMAKE_SOURCE_DIR STREQUAL CMAKE_BINARY_DIR )
  50   file(GLOB_RECURSE
  51     tablegenned_files_on_include_dir
  52     "${CMAKE_CURRENT_SOURCE_DIR}/include/llvm/*.gen")
  53   file(GLOB_RECURSE
  54     tablegenned_files_on_lib_dir
  55     "${CMAKE_CURRENT_SOURCE_DIR}/lib/Target/*.inc")
  56   if( tablegenned_files_on_include_dir OR tablegenned_files_on_lib_dir)
  57     message(FATAL_ERROR "Apparently there is a previous in-source build,
  58 probably as the result of running `configure' and `make' on
  59 ${CMAKE_CURRENT_SOURCE_DIR}.
  60 This may cause problems. The suspicious files are:
  61 ${tablegenned_files_on_lib_dir}
  62 ${tablegenned_files_on_include_dir}
  63 Please clean the source directory.")
  64   endif()
  65 endif()
  66
  67 string(TOUPPER "${CMAKE_BUILD_TYPE}" uppercase_CMAKE_BUILD_TYPE)
  68
  69 set(LLVM_MAIN_SRC_DIR ${CMAKE_CURRENT_SOURCE_DIR})
  70 set(LLVM_MAIN_INCLUDE_DIR ${LLVM_MAIN_SRC_DIR}/include)
  71 set(LLVM_BINARY_DIR ${CMAKE_CURRENT_BINARY_DIR})
  72 set(LLVM_TOOLS_BINARY_DIR ${LLVM_BINARY_DIR}/bin)
  73 set(LLVM_EXAMPLES_BINARY_DIR ${LLVM_BINARY_DIR}/examples)
  74 set(LLVM_LIBDIR_SUFFIX "" CACHE STRING "Define suffix of library directory name (32/64)" )
  75
  76 set(LLVM_ALL_TARGETS
  77   ARM
  78   CellSPU
  79   CppBackend
  80   Hexagon
  81   Mips
  82   MBlaze
  83   MSP430
  84   NVPTX
  85   PowerPC
  86   Sparc
  87   X86
  88   XCore
  89   )
  90
  91 # List of targets with JIT support:
  92 set(LLVM_TARGETS_WITH_JIT X86 PowerPC ARM Mips)
  93
  94 if( MSVC )
  95   set(LLVM_TARGETS_TO_BUILD X86
  96     CACHE STRING "Semicolon-separated list of targets to build, or \"all\".")
  97 else( MSVC )
  98   set(LLVM_TARGETS_TO_BUILD "all"
  99     CACHE STRING "Semicolon-separated list of targets to build, or \"all\".")
 100 endif( MSVC )
 101
 102 set(LLVM_EXPERIMENTAL_TARGETS_TO_BUILD ""
 103   CACHE STRING "Semicolon-separated list of experimental targets to build.")
 104
 105 option(BUILD_SHARED_LIBS
 106   "Build all libraries as shared libraries instead of static" OFF)
 107
 108 option(LLVM_ENABLE_CBE_PRINTF_A "Set to ON if CBE is enabled for printf %a output" ON)
 109 if(LLVM_ENABLE_CBE_PRINTF_A)
 110   set(ENABLE_CBE_PRINTF_A 1)
 111 endif()
 112
 113 option(LLVM_ENABLE_TIMESTAMPS "Enable embedding timestamp information in build" ON)
 114 if(LLVM_ENABLE_TIMESTAMPS)
 115   set(ENABLE_TIMESTAMPS 1)
 116 endif()
 117
 118 option(LLVM_ENABLE_BACKTRACES "Enable embedding backtraces on crash." ON)
 119 if(LLVM_ENABLE_BACKTRACES)
 120   set(ENABLE_BACKTRACES 1)
 121 endif()
 122
 123 option(LLVM_ENABLE_FFI "Use libffi to call external functions from the interpreter" OFF)
 124 set(FFI_LIBRARY_DIR "" CACHE PATH "Additional directory, where CMake should search for libffi.so")
 125 set(FFI_INCLUDE_DIR "" CACHE PATH "Additional directory, where CMake should search for ffi.h or ffi/ffi.h")
 126
 127 set(LLVM_TARGET_ARCH "host"
 128   CACHE STRING "Set target to use for LLVM JIT or use \"host\" for automatic detection.")
 129
 130 option(LLVM_ENABLE_THREADS "Use threads if available." ON)
 131
 132 if( LLVM_TARGETS_TO_BUILD STREQUAL "all" )
 133   set( LLVM_TARGETS_TO_BUILD ${LLVM_ALL_TARGETS} )
 134 endif()
 135
 136 set(LLVM_TARGETS_TO_BUILD
 137    ${LLVM_TARGETS_TO_BUILD}
 138    ${LLVM_EXPERIMENTAL_TARGETS_TO_BUILD})
 139
 140 set(LLVM_ENUM_TARGETS "")
 141 foreach(c ${LLVM_TARGETS_TO_BUILD})
 142   list(FIND LLVM_ALL_TARGETS ${c} idx)
 143   list(FIND LLVM_EXPERIMENTAL_TARGETS_TO_BUILD ${c} idy)
 144   if( idx LESS 0 AND idy LESS 0 )
 145     message(FATAL_ERROR "The target `${c}' does not exist.
 146     It should be one of\n${LLVM_ALL_TARGETS}")
 147   else()
 148     set(LLVM_ENUM_TARGETS "${LLVM_ENUM_TARGETS}LLVM_TARGET(${c})\n")
 149   endif()
 150 endforeach(c)
 151
 152 set(llvm_builded_incs_dir ${LLVM_BINARY_DIR}/include/llvm)
 153
 154 include(AddLLVMDefinitions)
 155
 156 option(LLVM_ENABLE_PIC "Build Position-Independent Code" ON)
 157
 158 # MSVC has a gazillion warnings with this.
 159 if( MSVC )
 160   option(LLVM_ENABLE_WARNINGS "Enable compiler warnings." OFF)
 161 else( MSVC )
 162   option(LLVM_ENABLE_WARNINGS "Enable compiler warnings." ON)
 163 endif()
 164
 165 option(LLVM_ENABLE_PEDANTIC "Compile with pedantic enabled." ON)
 166 option(LLVM_ENABLE_WERROR "Fail and stop if a warning is triggered." OFF)
 167
 168 if( uppercase_CMAKE_BUILD_TYPE STREQUAL "RELEASE" )
 169   option(LLVM_ENABLE_ASSERTIONS "Enable assertions" OFF)
 170 else()
 171   option(LLVM_ENABLE_ASSERTIONS "Enable assertions" ON)
 172 endif()
 173
 174 option(LLVM_USE_INTEL_JITEVENTS
 175   "Use Intel JIT API to inform Intel(R) VTune(TM) Amplifier XE 2011 about JIT code"
 176   OFF)
 177
 178 if( LLVM_USE_INTEL_JITEVENTS )
 179   # Verify we are on a supported platform
 180   if( CMAKE_SYSTEM_NAME MATCHES "Windows" OR CMAKE_SYSTEM_NAME MATCHES "Linux" )
 181     # Directory where Intel Parallel Amplifier XE 2011 is installed.
 182     if ( WIN32 )
 183       set(LLVM_INTEL_JITEVENTS_DIR $ENV{VTUNE_AMPLIFIER_XE_2011_DIR})
 184     else ( WIN32 )
 185       set(LLVM_INTEL_JITEVENTS_DIR "/opt/intel/vtune_amplifier_xe_2011")
 186     endif ( WIN32 )
 187
 188     # Set include and library search paths for Intel JIT Events API
 189     set(LLVM_INTEL_JITEVENTS_INCDIR "${LLVM_INTEL_JITEVENTS_DIR}/include")
 190
 191     if ( CMAKE_SIZEOF_VOID_P EQUAL 8 )
 192       set(LLVM_INTEL_JITEVENTS_LIBDIR "${LLVM_INTEL_JITEVENTS_DIR}/lib64")
 193     else ( CMAKE_SIZEOF_VOID_P EQUAL 8 )
 194       set(LLVM_INTEL_JITEVENTS_LIBDIR "${LLVM_INTEL_JITEVENTS_DIR}/lib32")
 195     endif ( CMAKE_SIZEOF_VOID_P EQUAL 8 )
 196   else()
 197     message(FATAL_ERROR
 198       "Intel JIT API support is available on Linux and Windows only.")
 199   endif()
 200 endif( LLVM_USE_INTEL_JITEVENTS )
 201
 202 option(LLVM_USE_OPROFILE
 203   "Use opagent JIT interface to inform OProfile about JIT code" OFF)
 204
 205 # If enabled, ierify we are on a platform that supports oprofile.
 206 if( LLVM_USE_OPROFILE )
 207   if( NOT CMAKE_SYSTEM_NAME MATCHES "Linux" )
 208     message(FATAL_ERROR "OProfile support is available on Linux only.")
 209   endif( NOT CMAKE_SYSTEM_NAME MATCHES "Linux" )
 210 endif( LLVM_USE_OPROFILE )
 211
 212 # Define an option controlling whether we should build for 32-bit on 64-bit
 213 # platforms, where supported.
 214 if( CMAKE_SIZEOF_VOID_P EQUAL 8 AND NOT WIN32 )
 215   # TODO: support other platforms and toolchains.
 216   option(LLVM_BUILD_32_BITS "Build 32 bits executables and libraries." OFF)
 217 endif()
 218
 219 # Define the default arguments to use with 'lit', and an option for the user to
 220 # override.
 221 set(LIT_ARGS_DEFAULT "-sv")
 222 if (MSVC OR XCODE)
 223   set(LIT_ARGS_DEFAULT "${LIT_ARGS_DEFAULT} --no-progress-bar")
 224 endif()
 225 set(LLVM_LIT_ARGS "${LIT_ARGS_DEFAULT}" CACHE STRING "Default options for lit")
 226
 227 # On Win32 hosts, provide an option to specify the path to the GnuWin32 tools.
 228 if( WIN32 AND NOT CYGWIN )
 229   set(LLVM_LIT_TOOLS_DIR "" CACHE PATH "Path to GnuWin32 tools")
 230 endif()
 231
 232 # Define options to control the inclusion and default build behavior for
 233 # components which may not strictly be necessary (tools, runtime, examples, and
 234 # tests).
 235 #
 236 # This is primarily to support building smaller or faster project files.
 237 option(LLVM_INCLUDE_TOOLS "Generate build targets for the LLVM tools." ON)
 238 option(LLVM_BUILD_TOOLS
 239   "Build the LLVM tools. If OFF, just generate build targets." ON)
 240
 241 option(LLVM_INCLUDE_RUNTIME "Generate build targets for the LLVM runtimes" ON)
 242 option(LLVM_BUILD_RUNTIME
 243   "Build the LLVM runtime libraries. If OFF, just generate build targets." ON)
 244
 245 option(LLVM_BUILD_EXAMPLES
 246   "Build the LLVM example programs. If OFF, just generate build targets." OFF)
 247 option(LLVM_INCLUDE_EXAMPLES "Generate build targets for the LLVM examples" ON)
 248
 249 option(LLVM_BUILD_TESTS
 250   "Build LLVM unit tests. If OFF, just generate build targets." OFF)
 251 option(LLVM_INCLUDE_TESTS "Generate build targets for the LLVM unit tests." ON)
 252
 253 # All options referred to from HandleLLVMOptions have to be specified
 254 # BEFORE this include, otherwise options will not be correctly set on
 255 # first cmake run
 256 include(config-ix)
 257
 258 # By default, we target the host, but this can be overridden at CMake
 259 # invocation time.
 260 set(LLVM_DEFAULT_TARGET_TRIPLE "${LLVM_HOST_TRIPLE}" CACHE STRING
 261   "Default target for which LLVM will generate code." )
 262 set(TARGET_TRIPLE "${LLVM_DEFAULT_TARGET_TRIPLE}" CACHE STRING
 263   "Default target for which LLVM will generate code." )
 264
 265 include(HandleLLVMOptions)
 266
 267 # Verify that we can find a Python interpreter,
 268 include(FindPythonInterp)
 269 if( NOT PYTHONINTERP_FOUND )
 270   message(FATAL_ERROR
 271 "Unable to find Python interpreter, required for builds and testing.
 272
 273 Please install Python or specify the PYTHON_EXECUTABLE CMake variable.")
 274 endif()
 275
 276 ######
 277 # LLVMBuild Integration
 278 #
 279 # We use llvm-build to generate all the data required by the CMake based
 280 # build system in one swoop:
 281 #
 282 #  - We generate a file (a CMake fragment) in the object root which contains
 283 #    all the definitions that are required by CMake.
 284 #
 285 #  - We generate the library table used by llvm-config.
 286 #
 287 #  - We generate the dependencies for the CMake fragment, so that we will
 288 #    automatically reconfigure outselves.
 289
 290 set(LLVMBUILDTOOL "${LLVM_MAIN_SRC_DIR}/utils/llvm-build/llvm-build")
 291 set(LLVMCONFIGLIBRARYDEPENDENCIESINC
 292   "${LLVM_BINARY_DIR}/tools/llvm-config/LibraryDependencies.inc")
 293 set(LLVMBUILDCMAKEFRAG
 294   "${LLVM_BINARY_DIR}/LLVMBuild.cmake")
 295
 296 # Create the list of optional components that are enabled
 297 if (LLVM_USE_INTEL_JITEVENTS)
 298   set(LLVMOPTIONALCOMPONENTS IntelJITEvents)
 299 endif (LLVM_USE_INTEL_JITEVENTS)
 300 if (LLVM_USE_OPROFILE)
 301   set(LLVMOPTIONALCOMPONENTS ${LLVMOPTIONALCOMPONENTS} OProfileJIT)
 302 endif (LLVM_USE_OPROFILE)
 303
 304 message(STATUS "Constructing LLVMBuild project information")
 305 execute_process(
 306   COMMAND ${PYTHON_EXECUTABLE} ${LLVMBUILDTOOL}
 307             --native-target "${LLVM_NATIVE_ARCH}"
 308             --enable-targets "${LLVM_TARGETS_TO_BUILD}"
 309             --enable-optional-components "${LLVMOPTIONALCOMPONENTS}"
 310             --write-library-table ${LLVMCONFIGLIBRARYDEPENDENCIESINC}
 311             --write-cmake-fragment ${LLVMBUILDCMAKEFRAG}
 312             ERROR_VARIABLE LLVMBUILDOUTPUT
 313             ERROR_VARIABLE LLVMBUILDERRORS
 314             OUTPUT_STRIP_TRAILING_WHITESPACE
 315             ERROR_STRIP_TRAILING_WHITESPACE
 316   RESULT_VARIABLE LLVMBUILDRESULT)
 317
 318 # On Win32, CMake doesn't properly handle piping the default output/error
 319 # streams into the GUI console. So, we explicitly catch and report them.
 320 if( NOT "${LLVMBUILDOUTPUT}" STREQUAL "")
 321   message(STATUS "llvm-build output: ${LLVMBUILDOUTPUT}")
 322 endif()
 323 if( NOT "${LLVMBUILDRESULT}" STREQUAL "0" )
 324   message(FATAL_ERROR
 325     "Unexpected failure executing llvm-build: ${LLVMBUILDERRORS}")
 326 endif()
 327
 328 # Include the generated CMake fragment. This will define properties from the
 329 # LLVMBuild files in a format which is easy to consume from CMake, and will add
 330 # the dependencies so that CMake will reconfigure properly when the LLVMBuild
 331 # files change.
 332 include(${LLVMBUILDCMAKEFRAG})
 333
 334 ######
 335
 336 # Configure all of the various header file fragments LLVM uses which depend on
 337 # configuration variables.
 338 set(LLVM_ENUM_ASM_PRINTERS "")
 339 set(LLVM_ENUM_ASM_PARSERS "")
 340 set(LLVM_ENUM_DISASSEMBLERS "")
 341 foreach(t ${LLVM_TARGETS_TO_BUILD})
 342   set( td ${LLVM_MAIN_SRC_DIR}/lib/Target/${t} )
 343   file(GLOB asmp_file "${td}/*AsmPrinter.cpp")
 344   if( asmp_file )
 345     set(LLVM_ENUM_ASM_PRINTERS
 346       "${LLVM_ENUM_ASM_PRINTERS}LLVM_ASM_PRINTER(${t})\n")
 347   endif()
 348   if( EXISTS ${td}/AsmParser/CMakeLists.txt )
 349     set(LLVM_ENUM_ASM_PARSERS
 350       "${LLVM_ENUM_ASM_PARSERS}LLVM_ASM_PARSER(${t})\n")
 351   endif()
 352   if( EXISTS ${td}/Disassembler/CMakeLists.txt )
 353     set(LLVM_ENUM_DISASSEMBLERS
 354       "${LLVM_ENUM_DISASSEMBLERS}LLVM_DISASSEMBLER(${t})\n")
 355   endif()
 356 endforeach(t)
 357
 358 # Produce the target definition files, which provide a way for clients to easily
 359 # include various classes of targets.
 360 configure_file(
 361   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/AsmPrinters.def.in
 362   ${LLVM_BINARY_DIR}/include/llvm/Config/AsmPrinters.def
 363   )
 364 configure_file(
 365   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/AsmParsers.def.in
 366   ${LLVM_BINARY_DIR}/include/llvm/Config/AsmParsers.def
 367   )
 368 configure_file(
 369   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/Disassemblers.def.in
 370   ${LLVM_BINARY_DIR}/include/llvm/Config/Disassemblers.def
 371   )
 372 configure_file(
 373   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/Targets.def.in
 374   ${LLVM_BINARY_DIR}/include/llvm/Config/Targets.def
 375   )
 376
 377 # Configure the three LLVM configuration header files.
 378 configure_file(
 379   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/config.h.cmake
 380   ${LLVM_BINARY_DIR}/include/llvm/Config/config.h)
 381 configure_file(
 382   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/llvm-config.h.cmake
 383   ${LLVM_BINARY_DIR}/include/llvm/Config/llvm-config.h)
 384 configure_file(
 385   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Support/DataTypes.h.cmake
 386   ${LLVM_BINARY_DIR}/include/llvm/Support/DataTypes.h)
 387
 388 set( CMAKE_RUNTIME_OUTPUT_DIRECTORY ${LLVM_TOOLS_BINARY_DIR} )
 389 set( CMAKE_LIBRARY_OUTPUT_DIRECTORY ${LLVM_BINARY_DIR}/lib )
 390 set( CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${LLVM_BINARY_DIR}/lib )
 391
 392 set(CMAKE_INCLUDE_CURRENT_DIR ON)
 393
 394 include_directories( ${LLVM_BINARY_DIR}/include ${LLVM_MAIN_INCLUDE_DIR})
 395
 396 if( ${CMAKE_SYSTEM_NAME} MATCHES SunOS )
 397    SET(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -include llvm/Support/Solaris.h")
 398 endif( ${CMAKE_SYSTEM_NAME} MATCHES SunOS )
 399
 400 include(AddLLVM)
 401 include(TableGen)
 402
 403 if( MINGW )
 404   # People report that -O3 is unreliable on MinGW. The traditional
 405   # build also uses -O2 for that reason:
 406   llvm_replace_compiler_option(CMAKE_CXX_FLAGS_RELEASE "-O3" "-O2")
 407 endif()
 408
 409 # Put this before tblgen. Else we have a circular dependence.
 410 add_subdirectory(lib/Support)
 411 add_subdirectory(lib/TableGen)
 412
 413 add_subdirectory(utils/TableGen)
 414
 415 add_subdirectory(include/llvm)
 416
 417 add_subdirectory(lib)
 418
 419 add_subdirectory(utils/FileCheck)
 420 add_subdirectory(utils/FileUpdate)
 421 add_subdirectory(utils/count)
 422 add_subdirectory(utils/not)
 423 add_subdirectory(utils/llvm-lit)
 424 add_subdirectory(utils/yaml-bench)
 425 add_subdirectory(utils/obj2yaml)
 426 add_subdirectory(utils/yaml2obj)
 427
 428 add_subdirectory(projects)
 429
 430 if( LLVM_INCLUDE_TOOLS )
 431   add_subdirectory(tools)
 432 endif()
 433
 434 if( LLVM_INCLUDE_RUNTIME )
 435   add_subdirectory(runtime)
 436 endif()
 437
 438 if( LLVM_INCLUDE_EXAMPLES )
 439   add_subdirectory(examples)
 440 endif()
 441
 442 if( LLVM_INCLUDE_TESTS )
 443   add_subdirectory(test)
 444   add_subdirectory(utils/unittest)
 445   add_subdirectory(unittests)
 446   if (MSVC)
 447     # This utility is used to prevent chrashing tests from calling Dr. Watson on
 448     # Windows.
 449     add_subdirectory(utils/KillTheDoctor)
 450   endif()
 451
 452   # Add a global check rule now that all subdirectories have been traversed
 453   # and we know the total set of lit testsuites.
 454   get_property(LLVM_LIT_TESTSUITES GLOBAL PROPERTY LLVM_LIT_TESTSUITES)
 455   get_property(LLVM_LIT_PARAMS GLOBAL PROPERTY LLVM_LIT_PARAMS)
 456   get_property(LLVM_LIT_DEPENDS GLOBAL PROPERTY LLVM_LIT_DEPENDS)
 457   get_property(LLVM_LIT_EXTRA_ARGS GLOBAL PROPERTY LLVM_LIT_EXTRA_ARGS)
 458   add_lit_target(check-all
 459     "Running all regression tests"
 460     ${LLVM_LIT_TESTSUITES}
 461     PARAMS ${LLVM_LIT_PARAMS}
 462     DEPENDS ${LLVM_LIT_DEPENDS}
 463     ARGS ${LLVM_LIT_EXTRA_ARGS}
 464     )
 465 endif()
 466
 467 add_subdirectory(cmake/modules)
 468
 469 install(DIRECTORY include/
 470   DESTINATION include
 471   FILES_MATCHING
 472   PATTERN "*.def"
 473   PATTERN "*.h"
 474   PATTERN "*.td"
 475   PATTERN "*.inc"
 476   PATTERN "LICENSE.TXT"
 477   PATTERN ".svn" EXCLUDE
 478   )
 479
 480 install(DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/include/
 481   DESTINATION include
 482   FILES_MATCHING
 483   PATTERN "*.def"
 484   PATTERN "*.h"
 485   PATTERN "*.gen"
 486   PATTERN "*.inc"
 487   # Exclude include/llvm/CMakeFiles/intrinsics_gen.dir, matched by "*.def"
 488   PATTERN "CMakeFiles" EXCLUDE
 489   PATTERN ".svn" EXCLUDE
 490   )
 491
 492 # TODO: make and install documentation.
 493
 494 set(CPACK_PACKAGE_VENDOR "LLVM")
 495 set(CPACK_PACKAGE_VERSION_MAJOR ${LLVM_VERSION_MAJOR})
 496 set(CPACK_PACKAGE_VERSION_MINOR ${LLVM_VERSION_MINOR})
 497 add_version_info_from_vcs(CPACK_PACKAGE_VERSION_PATCH)
 498 include(CPack)
 499
 500 # Workaround for MSVS10 to avoid the Dialog Hell
 501 # FIXME: This could be removed with future version of CMake.
 502 if(MSVC_VERSION EQUAL 1600)
 503   set(LLVM_SLN_FILENAME "${CMAKE_CURRENT_BINARY_DIR}/LLVM.sln")
 504   if( EXISTS "${LLVM_SLN_FILENAME}" )
 505     file(APPEND "${LLVM_SLN_FILENAME}" "\n# This should be regenerated!\n")
 506   endif()
 507 endif()