CMakeLists.txt

   1 # See docs/CMake.html for instructions about how to build LLVM with CMake.
   2
   3 cmake_minimum_required(VERSION 2.8.8)
   4
   5 # FIXME: It may be removed when we use 2.8.12.
   6 if(CMAKE_VERSION VERSION_LESS 2.8.12)
   7   # Invalidate a couple of keywords.
   8   set(cmake_2_8_12_INTERFACE)
   9   set(cmake_2_8_12_PRIVATE)
  10 else()
  11   # Use ${cmake_2_8_12_KEYWORD} intead of KEYWORD in target_link_libraries().
  12   set(cmake_2_8_12_INTERFACE INTERFACE)
  13   set(cmake_2_8_12_PRIVATE PRIVATE)
  14   if(POLICY CMP0022)
  15     cmake_policy(SET CMP0022 NEW) # automatic when 2.8.12 is required
  16   endif()
  17 endif()
  18
  19 project(LLVM)
  20
  21 # Add path for custom modules
  22 set(CMAKE_MODULE_PATH
  23   ${CMAKE_MODULE_PATH}
  24   "${CMAKE_CURRENT_SOURCE_DIR}/cmake"
  25   "${CMAKE_CURRENT_SOURCE_DIR}/cmake/modules"
  26   )
  27
  28 set(LLVM_VERSION_MAJOR 3)
  29 set(LLVM_VERSION_MINOR 5)
  30 set(LLVM_VERSION_PATCH 0)
  31
  32 if (NOT PACKAGE_VERSION)
  33   set(PACKAGE_VERSION "${LLVM_VERSION_MAJOR}.${LLVM_VERSION_MINOR}.${LLVM_VERSION_PATCH}svn")
  34 endif()
  35
  36 option(LLVM_INSTALL_TOOLCHAIN_ONLY "Only include toolchain files in the 'install' target." OFF)
  37
  38 option(LLVM_USE_FOLDERS "Enable solution folders in Visual Studio. Disable for Express versions." ON)
  39 if ( LLVM_USE_FOLDERS )
  40   set_property(GLOBAL PROPERTY USE_FOLDERS ON)
  41 endif()
  42
  43 include(VersionFromVCS)
  44
  45 option(LLVM_APPEND_VC_REV
  46   "Append the version control system revision id to LLVM version" OFF)
  47
  48 if( LLVM_APPEND_VC_REV )
  49   add_version_info_from_vcs(PACKAGE_VERSION)
  50 endif()
  51
  52 set(PACKAGE_NAME LLVM)
  53 set(PACKAGE_STRING "${PACKAGE_NAME} ${PACKAGE_VERSION}")
  54 set(PACKAGE_BUGREPORT "http://llvm.org/bugs/")
  55
  56 set(BUG_REPORT_URL "${PACKAGE_BUGREPORT}" CACHE STRING
  57   "Default URL where bug reports are to be submitted.")
  58
  59 # Configure CPack.
  60 set(CPACK_PACKAGE_INSTALL_DIRECTORY "LLVM")
  61 set(CPACK_PACKAGE_VENDOR "LLVM")
  62 set(CPACK_PACKAGE_VERSION_MAJOR ${LLVM_VERSION_MAJOR})
  63 set(CPACK_PACKAGE_VERSION_MINOR ${LLVM_VERSION_MINOR})
  64 set(CPACK_PACKAGE_VERSION_PATCH ${LLVM_VERSION_PATCH})
  65 set(CPACK_PACKAGE_VERSION ${PACKAGE_VERSION})
  66 set(CPACK_RESOURCE_FILE_LICENSE "${CMAKE_CURRENT_SOURCE_DIR}/LICENSE.TXT")
  67 if(WIN32 AND NOT UNIX)
  68   set(CPACK_PACKAGE_INSTALL_REGISTRY_KEY "LLVM")
  69   set(CPACK_PACKAGE_ICON "${CMAKE_CURRENT_SOURCE_DIR}\\\\cmake\\\\nsis_logo.bmp")
  70   set(CPACK_NSIS_MUI_ICON "${CMAKE_CURRENT_SOURCE_DIR}\\\\cmake\\\\nsis_icon.ico")
  71   set(CPACK_NSIS_MUI_UNIICON "${CMAKE_CURRENT_SOURCE_DIR}\\\\cmake\\\\nsis_icon.ico")
  72   set(CPACK_NSIS_MODIFY_PATH "ON")
  73   set(CPACK_NSIS_ENABLE_UNINSTALL_BEFORE_INSTALL "ON")
  74   set(CPACK_NSIS_EXTRA_INSTALL_COMMANDS
  75     "ExecWait '$INSTDIR/tools/msbuild/install.bat'")
  76   set(CPACK_NSIS_EXTRA_UNINSTALL_COMMANDS
  77     "ExecWait '$INSTDIR/tools/msbuild/uninstall.bat'")
  78 endif()
  79 include(CPack)
  80
  81 # Sanity check our source directory to make sure that we are not trying to
  82 # generate an in-tree build (unless on MSVC_IDE, where it is ok), and to make
  83 # sure that we don't have any stray generated files lying around in the tree
  84 # (which would end up getting picked up by header search, instead of the correct
  85 # versions).
  86 if( CMAKE_SOURCE_DIR STREQUAL CMAKE_BINARY_DIR AND NOT MSVC_IDE )
  87   message(FATAL_ERROR "In-source builds are not allowed.
  88 CMake would overwrite the makefiles distributed with LLVM.
  89 Please create a directory and run cmake from there, passing the path
  90 to this source directory as the last argument.
  91 This process created the file `CMakeCache.txt' and the directory `CMakeFiles'.
  92 Please delete them.")
  93 endif()
  94 if( NOT CMAKE_SOURCE_DIR STREQUAL CMAKE_BINARY_DIR )
  95   file(GLOB_RECURSE
  96     tablegenned_files_on_include_dir
  97     "${CMAKE_CURRENT_SOURCE_DIR}/include/llvm/*.gen")
  98   file(GLOB_RECURSE
  99     tablegenned_files_on_lib_dir
 100     "${CMAKE_CURRENT_SOURCE_DIR}/lib/Target/*.inc")
 101   if( tablegenned_files_on_include_dir OR tablegenned_files_on_lib_dir)
 102     message(FATAL_ERROR "Apparently there is a previous in-source build,
 103 probably as the result of running `configure' and `make' on
 104 ${CMAKE_CURRENT_SOURCE_DIR}.
 105 This may cause problems. The suspicious files are:
 106 ${tablegenned_files_on_lib_dir}
 107 ${tablegenned_files_on_include_dir}
 108 Please clean the source directory.")
 109   endif()
 110 endif()
 111
 112 string(TOUPPER "${CMAKE_BUILD_TYPE}" uppercase_CMAKE_BUILD_TYPE)
 113
 114 # They are used as destination of target generators.
 115 set(LLVM_RUNTIME_OUTPUT_INTDIR ${CMAKE_CURRENT_BINARY_DIR}/${CMAKE_CFG_INTDIR}/bin)
 116 set(LLVM_LIBRARY_OUTPUT_INTDIR ${CMAKE_CURRENT_BINARY_DIR}/${CMAKE_CFG_INTDIR}/lib)
 117
 118 # Each of them corresponds to llvm-config's.
 119 set(LLVM_TOOLS_BINARY_DIR ${LLVM_RUNTIME_OUTPUT_INTDIR}) # --bindir
 120 set(LLVM_LIBRARY_DIR      ${LLVM_LIBRARY_OUTPUT_INTDIR}) # --libdir
 121 set(LLVM_MAIN_SRC_DIR     ${CMAKE_CURRENT_SOURCE_DIR}  ) # --src-root
 122 set(LLVM_MAIN_INCLUDE_DIR ${LLVM_MAIN_SRC_DIR}/include ) # --includedir
 123 set(LLVM_BINARY_DIR       ${CMAKE_CURRENT_BINARY_DIR}  ) # --prefix
 124
 125 set(LLVM_EXAMPLES_BINARY_DIR ${LLVM_BINARY_DIR}/examples)
 126 set(LLVM_INCLUDE_DIR ${CMAKE_CURRENT_BINARY_DIR}/include)
 127 set(LLVM_LIBDIR_SUFFIX "" CACHE STRING "Define suffix of library directory name (32/64)" )
 128
 129 set(LLVM_ALL_TARGETS
 130   AArch64
 131   ARM64
 132   ARM
 133   CppBackend
 134   Hexagon
 135   Mips
 136   MSP430
 137   NVPTX
 138   PowerPC
 139   R600
 140   Sparc
 141   SystemZ
 142   X86
 143   XCore
 144   )
 145
 146 # List of targets with JIT support:
 147 set(LLVM_TARGETS_WITH_JIT X86 PowerPC AArch64 ARM64 ARM Mips SystemZ)
 148
 149 set(LLVM_TARGETS_TO_BUILD "all"
 150     CACHE STRING "Semicolon-separated list of targets to build, or \"all\".")
 151
 152 set(LLVM_EXPERIMENTAL_TARGETS_TO_BUILD ""
 153   CACHE STRING "Semicolon-separated list of experimental targets to build.")
 154
 155 option(BUILD_SHARED_LIBS
 156   "Build all libraries as shared libraries instead of static" OFF)
 157
 158 option(LLVM_ENABLE_TIMESTAMPS "Enable embedding timestamp information in build" ON)
 159 if(LLVM_ENABLE_TIMESTAMPS)
 160   set(ENABLE_TIMESTAMPS 1)
 161 endif()
 162
 163 option(LLVM_ENABLE_BACKTRACES "Enable embedding backtraces on crash." ON)
 164 if(LLVM_ENABLE_BACKTRACES)
 165   set(ENABLE_BACKTRACES 1)
 166 endif()
 167
 168 option(LLVM_ENABLE_CRASH_OVERRIDES "Enable crash overrides." ON)
 169 if(LLVM_ENABLE_CRASH_OVERRIDES)
 170   set(ENABLE_CRASH_OVERRIDES 1)
 171 endif()
 172
 173 option(LLVM_ENABLE_FFI "Use libffi to call external functions from the interpreter" OFF)
 174 set(FFI_LIBRARY_DIR "" CACHE PATH "Additional directory, where CMake should search for libffi.so")
 175 set(FFI_INCLUDE_DIR "" CACHE PATH "Additional directory, where CMake should search for ffi.h or ffi/ffi.h")
 176
 177 set(LLVM_TARGET_ARCH "host"
 178   CACHE STRING "Set target to use for LLVM JIT or use \"host\" for automatic detection.")
 179
 180 option(LLVM_ENABLE_TERMINFO "Use terminfo database if available." ON)
 181
 182 option(LLVM_ENABLE_THREADS "Use threads if available." ON)
 183
 184 option(LLVM_ENABLE_ZLIB "Use zlib for compression/decompression if available." ON)
 185
 186 if( LLVM_TARGETS_TO_BUILD STREQUAL "all" )
 187   set( LLVM_TARGETS_TO_BUILD ${LLVM_ALL_TARGETS} )
 188 endif()
 189
 190 set(LLVM_TARGETS_TO_BUILD
 191    ${LLVM_TARGETS_TO_BUILD}
 192    ${LLVM_EXPERIMENTAL_TARGETS_TO_BUILD})
 193 list(REMOVE_DUPLICATES LLVM_TARGETS_TO_BUILD)
 194
 195 include(AddLLVMDefinitions)
 196
 197 option(LLVM_ENABLE_PIC "Build Position-Independent Code" ON)
 198
 199 # MSVC has a gazillion warnings with this.
 200 if( MSVC )
 201   option(LLVM_ENABLE_WARNINGS "Enable compiler warnings." OFF)
 202 else()
 203   option(LLVM_ENABLE_WARNINGS "Enable compiler warnings." ON)
 204 endif()
 205
 206 option(LLVM_ENABLE_CXX1Y "Compile with C++1y enabled." OFF)
 207 option(LLVM_ENABLE_LIBCXX "Use libc++ if available." OFF)
 208 option(LLVM_ENABLE_PEDANTIC "Compile with pedantic enabled." ON)
 209 option(LLVM_ENABLE_WERROR "Fail and stop if a warning is triggered." OFF)
 210
 211 if( NOT uppercase_CMAKE_BUILD_TYPE STREQUAL "DEBUG" )
 212   option(LLVM_ENABLE_ASSERTIONS "Enable assertions" OFF)
 213 else()
 214   option(LLVM_ENABLE_ASSERTIONS "Enable assertions" ON)
 215 endif()
 216
 217 option(LLVM_FORCE_USE_OLD_HOST_TOOLCHAIN
 218        "Set to ON to force using an old, unsupported host toolchain." OFF)
 219
 220 option(LLVM_USE_INTEL_JITEVENTS
 221   "Use Intel JIT API to inform Intel(R) VTune(TM) Amplifier XE 2011 about JIT code"
 222   OFF)
 223
 224 if( LLVM_USE_INTEL_JITEVENTS )
 225   # Verify we are on a supported platform
 226   if( NOT CMAKE_SYSTEM_NAME MATCHES "Windows" AND NOT CMAKE_SYSTEM_NAME MATCHES "Linux" )
 227     message(FATAL_ERROR
 228       "Intel JIT API support is available on Linux and Windows only.")
 229   endif()
 230 endif( LLVM_USE_INTEL_JITEVENTS )
 231
 232 option(LLVM_USE_OPROFILE
 233   "Use opagent JIT interface to inform OProfile about JIT code" OFF)
 234
 235 # If enabled, verify we are on a platform that supports oprofile.
 236 if( LLVM_USE_OPROFILE )
 237   if( NOT CMAKE_SYSTEM_NAME MATCHES "Linux" )
 238     message(FATAL_ERROR "OProfile support is available on Linux only.")
 239   endif( NOT CMAKE_SYSTEM_NAME MATCHES "Linux" )
 240 endif( LLVM_USE_OPROFILE )
 241
 242 set(LLVM_USE_SANITIZER "" CACHE STRING
 243   "Define the sanitizer used to build binaries and tests.")
 244
 245 option(LLVM_USE_SPLIT_DWARF
 246   "Use -gsplit-dwarf when compiling llvm." OFF)
 247
 248 # Define an option controlling whether we should build for 32-bit on 64-bit
 249 # platforms, where supported.
 250 if( CMAKE_SIZEOF_VOID_P EQUAL 8 AND NOT WIN32 )
 251   # TODO: support other platforms and toolchains.
 252   option(LLVM_BUILD_32_BITS "Build 32 bits executables and libraries." OFF)
 253 endif()
 254
 255 # Define the default arguments to use with 'lit', and an option for the user to
 256 # override.
 257 set(LIT_ARGS_DEFAULT "-sv")
 258 if (MSVC OR XCODE)
 259   set(LIT_ARGS_DEFAULT "${LIT_ARGS_DEFAULT} --no-progress-bar")
 260 endif()
 261 set(LLVM_LIT_ARGS "${LIT_ARGS_DEFAULT}" CACHE STRING "Default options for lit")
 262
 263 # On Win32 hosts, provide an option to specify the path to the GnuWin32 tools.
 264 if( WIN32 AND NOT CYGWIN )
 265   set(LLVM_LIT_TOOLS_DIR "" CACHE PATH "Path to GnuWin32 tools")
 266 endif()
 267
 268 # Define options to control the inclusion and default build behavior for
 269 # components which may not strictly be necessary (tools, examples, and tests).
 270 #
 271 # This is primarily to support building smaller or faster project files.
 272 option(LLVM_INCLUDE_TOOLS "Generate build targets for the LLVM tools." ON)
 273 option(LLVM_BUILD_TOOLS
 274   "Build the LLVM tools. If OFF, just generate build targets." ON)
 275
 276 option(LLVM_INCLUDE_UTILS "Generate build targets for the LLVM utils." ON)
 277
 278 option(LLVM_BUILD_RUNTIME
 279   "Build the LLVM runtime libraries." ON)
 280 option(LLVM_BUILD_EXAMPLES
 281   "Build the LLVM example programs. If OFF, just generate build targets." OFF)
 282 option(LLVM_INCLUDE_EXAMPLES "Generate build targets for the LLVM examples" ON)
 283
 284 option(LLVM_BUILD_TESTS
 285   "Build LLVM unit tests. If OFF, just generate build targets." OFF)
 286 option(LLVM_INCLUDE_TESTS "Generate build targets for the LLVM unit tests." ON)
 287
 288 option (LLVM_BUILD_DOCS "Build the llvm documentation." OFF)
 289 option (LLVM_INCLUDE_DOCS "Generate build targets for llvm documentation." ON)
 290 option (LLVM_ENABLE_DOXYGEN "Use doxygen to generate llvm API documentation." OFF)
 291 option (LLVM_ENABLE_SPHINX "Use Sphinx to generate llvm documentation." OFF)
 292
 293 option (LLVM_BUILD_EXTERNAL_COMPILER_RT
 294   "Build compiler-rt as an external project." OFF)
 295
 296 # All options referred to from HandleLLVMOptions have to be specified
 297 # BEFORE this include, otherwise options will not be correctly set on
 298 # first cmake run
 299 include(config-ix)
 300
 301 # By default, we target the host, but this can be overridden at CMake
 302 # invocation time.
 303 set(LLVM_DEFAULT_TARGET_TRIPLE "${LLVM_HOST_TRIPLE}" CACHE STRING
 304   "Default target for which LLVM will generate code." )
 305 set(TARGET_TRIPLE "${LLVM_DEFAULT_TARGET_TRIPLE}")
 306
 307 include(HandleLLVMOptions)
 308
 309 # Verify that we can find a Python 2 interpreter.  Python 3 is unsupported.
 310 set(Python_ADDITIONAL_VERSIONS 2.7 2.6 2.5)
 311 include(FindPythonInterp)
 312 if( NOT PYTHONINTERP_FOUND )
 313   message(FATAL_ERROR
 314 "Unable to find Python interpreter, required for builds and testing.
 315
 316 Please install Python or specify the PYTHON_EXECUTABLE CMake variable.")
 317 endif()
 318
 319 ######
 320 # LLVMBuild Integration
 321 #
 322 # We use llvm-build to generate all the data required by the CMake based
 323 # build system in one swoop:
 324 #
 325 #  - We generate a file (a CMake fragment) in the object root which contains
 326 #    all the definitions that are required by CMake.
 327 #
 328 #  - We generate the library table used by llvm-config.
 329 #
 330 #  - We generate the dependencies for the CMake fragment, so that we will
 331 #    automatically reconfigure outselves.
 332
 333 set(LLVMBUILDTOOL "${LLVM_MAIN_SRC_DIR}/utils/llvm-build/llvm-build")
 334 set(LLVMCONFIGLIBRARYDEPENDENCIESINC
 335   "${LLVM_BINARY_DIR}/tools/llvm-config/LibraryDependencies.inc")
 336 set(LLVMBUILDCMAKEFRAG
 337   "${LLVM_BINARY_DIR}/LLVMBuild.cmake")
 338
 339 # Create the list of optional components that are enabled
 340 if (LLVM_USE_INTEL_JITEVENTS)
 341   set(LLVMOPTIONALCOMPONENTS IntelJITEvents)
 342 endif (LLVM_USE_INTEL_JITEVENTS)
 343 if (LLVM_USE_OPROFILE)
 344   set(LLVMOPTIONALCOMPONENTS ${LLVMOPTIONALCOMPONENTS} OProfileJIT)
 345 endif (LLVM_USE_OPROFILE)
 346
 347 message(STATUS "Constructing LLVMBuild project information")
 348 execute_process(
 349   COMMAND ${PYTHON_EXECUTABLE} ${LLVMBUILDTOOL}
 350             --native-target "${LLVM_NATIVE_ARCH}"
 351             --enable-targets "${LLVM_TARGETS_TO_BUILD}"
 352             --enable-optional-components "${LLVMOPTIONALCOMPONENTS}"
 353             --write-library-table ${LLVMCONFIGLIBRARYDEPENDENCIESINC}
 354             --write-cmake-fragment ${LLVMBUILDCMAKEFRAG}
 355             OUTPUT_VARIABLE LLVMBUILDOUTPUT
 356             ERROR_VARIABLE LLVMBUILDERRORS
 357             OUTPUT_STRIP_TRAILING_WHITESPACE
 358             ERROR_STRIP_TRAILING_WHITESPACE
 359   RESULT_VARIABLE LLVMBUILDRESULT)
 360
 361 # On Win32, CMake doesn't properly handle piping the default output/error
 362 # streams into the GUI console. So, we explicitly catch and report them.
 363 if( NOT "${LLVMBUILDOUTPUT}" STREQUAL "")
 364   message(STATUS "llvm-build output: ${LLVMBUILDOUTPUT}")
 365 endif()
 366 if( NOT "${LLVMBUILDRESULT}" STREQUAL "0" )
 367   message(FATAL_ERROR
 368     "Unexpected failure executing llvm-build: ${LLVMBUILDERRORS}")
 369 endif()
 370
 371 # Include the generated CMake fragment. This will define properties from the
 372 # LLVMBuild files in a format which is easy to consume from CMake, and will add
 373 # the dependencies so that CMake will reconfigure properly when the LLVMBuild
 374 # files change.
 375 include(${LLVMBUILDCMAKEFRAG})
 376
 377 ######
 378
 379 # Configure all of the various header file fragments LLVM uses which depend on
 380 # configuration variables.
 381 set(LLVM_ENUM_TARGETS "")
 382 set(LLVM_ENUM_ASM_PRINTERS "")
 383 set(LLVM_ENUM_ASM_PARSERS "")
 384 set(LLVM_ENUM_DISASSEMBLERS "")
 385 foreach(t ${LLVM_TARGETS_TO_BUILD})
 386   set( td ${LLVM_MAIN_SRC_DIR}/lib/Target/${t} )
 387
 388   list(FIND LLVM_ALL_TARGETS ${t} idx)
 389   list(FIND LLVM_EXPERIMENTAL_TARGETS_TO_BUILD ${t} idy)
 390   if( idx LESS 0 AND idy LESS 0 )
 391     message(FATAL_ERROR "The target `${t}' does not exist.
 392     It should be one of\n${LLVM_ALL_TARGETS}")
 393   else()
 394     set(LLVM_ENUM_TARGETS "${LLVM_ENUM_TARGETS}LLVM_TARGET(${t})\n")
 395   endif()
 396
 397   file(GLOB asmp_file "${td}/*AsmPrinter.cpp")
 398   if( asmp_file )
 399     set(LLVM_ENUM_ASM_PRINTERS
 400       "${LLVM_ENUM_ASM_PRINTERS}LLVM_ASM_PRINTER(${t})\n")
 401   endif()
 402   if( EXISTS ${td}/AsmParser/CMakeLists.txt )
 403     set(LLVM_ENUM_ASM_PARSERS
 404       "${LLVM_ENUM_ASM_PARSERS}LLVM_ASM_PARSER(${t})\n")
 405   endif()
 406   if( EXISTS ${td}/Disassembler/CMakeLists.txt )
 407     set(LLVM_ENUM_DISASSEMBLERS
 408       "${LLVM_ENUM_DISASSEMBLERS}LLVM_DISASSEMBLER(${t})\n")
 409   endif()
 410 endforeach(t)
 411
 412 # Produce the target definition files, which provide a way for clients to easily
 413 # include various classes of targets.
 414 configure_file(
 415   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/AsmPrinters.def.in
 416   ${LLVM_INCLUDE_DIR}/llvm/Config/AsmPrinters.def
 417   )
 418 configure_file(
 419   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/AsmParsers.def.in
 420   ${LLVM_INCLUDE_DIR}/llvm/Config/AsmParsers.def
 421   )
 422 configure_file(
 423   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/Disassemblers.def.in
 424   ${LLVM_INCLUDE_DIR}/llvm/Config/Disassemblers.def
 425   )
 426 configure_file(
 427   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/Targets.def.in
 428   ${LLVM_INCLUDE_DIR}/llvm/Config/Targets.def
 429   )
 430
 431 # Configure the three LLVM configuration header files.
 432 configure_file(
 433   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/config.h.cmake
 434   ${LLVM_INCLUDE_DIR}/llvm/Config/config.h)
 435 configure_file(
 436   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/llvm-config.h.cmake
 437   ${LLVM_INCLUDE_DIR}/llvm/Config/llvm-config.h)
 438 configure_file(
 439   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Support/DataTypes.h.cmake
 440   ${LLVM_INCLUDE_DIR}/llvm/Support/DataTypes.h)
 441
 442 # They are not referenced. See set_output_directory().
 443 set( CMAKE_RUNTIME_OUTPUT_DIRECTORY ${LLVM_BINARY_DIR}/bin )
 444 set( CMAKE_LIBRARY_OUTPUT_DIRECTORY ${LLVM_BINARY_DIR}/lib )
 445 set( CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${LLVM_BINARY_DIR}/lib )
 446
 447 set(CMAKE_BUILD_WITH_INSTALL_RPATH ON)
 448 if (APPLE)
 449   set(CMAKE_INSTALL_NAME_DIR "@rpath")
 450   set(CMAKE_INSTALL_RPATH "@executable_path/../lib")
 451 else(UNIX)
 452   if(NOT DEFINED CMAKE_INSTALL_RPATH)
 453     set(CMAKE_INSTALL_RPATH "\$ORIGIN/../lib")
 454     if (${CMAKE_SYSTEM_NAME} MATCHES FreeBSD)
 455       set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -Wl,-z,origin")
 456     endif()
 457   endif(NOT DEFINED CMAKE_INSTALL_RPATH)
 458 endif()
 459
 460 set(CMAKE_INCLUDE_CURRENT_DIR ON)
 461
 462 include_directories( ${LLVM_INCLUDE_DIR} ${LLVM_MAIN_INCLUDE_DIR})
 463
 464 if( ${CMAKE_SYSTEM_NAME} MATCHES FreeBSD )
 465   # On FreeBSD, /usr/local/* is not used by default. In order to build LLVM
 466   # with libxml2, iconv.h, etc., we must add /usr/local paths.
 467   include_directories("/usr/local/include")
 468   link_directories("/usr/local/lib")
 469 endif( ${CMAKE_SYSTEM_NAME} MATCHES FreeBSD )
 470
 471 if( ${CMAKE_SYSTEM_NAME} MATCHES SunOS )
 472    SET(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -include llvm/Support/Solaris.h")
 473 endif( ${CMAKE_SYSTEM_NAME} MATCHES SunOS )
 474
 475 # Make sure we don't get -rdynamic in every binary. For those that need it,
 476 # use set_target_properties(target PROPERTIES ENABLE_EXPORTS 1)
 477 set(CMAKE_SHARED_LIBRARY_LINK_CXX_FLAGS "")
 478
 479 include(AddLLVM)
 480 include(TableGen)
 481
 482 if( MINGW )
 483   # People report that -O3 is unreliable on MinGW. The traditional
 484   # build also uses -O2 for that reason:
 485   llvm_replace_compiler_option(CMAKE_CXX_FLAGS_RELEASE "-O3" "-O2")
 486 endif()
 487
 488 # Put this before tblgen. Else we have a circular dependence.
 489 add_subdirectory(lib/Support)
 490 add_subdirectory(lib/TableGen)
 491
 492 add_subdirectory(utils/TableGen)
 493
 494 add_subdirectory(include/llvm)
 495
 496 add_subdirectory(lib)
 497
 498 if( LLVM_INCLUDE_UTILS )
 499   add_subdirectory(utils/FileCheck)
 500   add_subdirectory(utils/FileUpdate)
 501   add_subdirectory(utils/count)
 502   add_subdirectory(utils/not)
 503   add_subdirectory(utils/llvm-lit)
 504   add_subdirectory(utils/yaml-bench)
 505 else()
 506   if ( LLVM_INCLUDE_TESTS )
 507     message(FATAL_ERROR "Including tests when not building utils will not work.
 508     Either set LLVM_INCLUDE_UTILS to On, or set LLVM_INCLDE_TESTS to Off.")
 509   endif()
 510 endif()
 511
 512 if(LLVM_INCLUDE_TESTS)
 513   add_subdirectory(utils/unittest)
 514 endif()
 515
 516 add_subdirectory(projects)
 517
 518 option(WITH_POLLY "Build LLVM with Polly" ON)
 519 option(LINK_POLLY_INTO_TOOLS "Static link Polly into tools" OFF)
 520
 521 if(WITH_POLLY)
 522   if(NOT EXISTS ${LLVM_MAIN_SRC_DIR}/tools/polly/CMakeLists.txt)
 523     set(WITH_POLLY OFF)
 524   endif()
 525 endif(WITH_POLLY)
 526
 527 if( LLVM_INCLUDE_TOOLS )
 528   add_subdirectory(tools)
 529 endif()
 530
 531 if( LLVM_INCLUDE_EXAMPLES )
 532   add_subdirectory(examples)
 533 endif()
 534
 535 if( LLVM_INCLUDE_TESTS )
 536   add_subdirectory(test)
 537   add_subdirectory(unittests)
 538   if (MSVC)
 539     # This utility is used to prevent crashing tests from calling Dr. Watson on
 540     # Windows.
 541     add_subdirectory(utils/KillTheDoctor)
 542   endif()
 543
 544   # Add a global check rule now that all subdirectories have been traversed
 545   # and we know the total set of lit testsuites.
 546   get_property(LLVM_LIT_TESTSUITES GLOBAL PROPERTY LLVM_LIT_TESTSUITES)
 547   get_property(LLVM_LIT_PARAMS GLOBAL PROPERTY LLVM_LIT_PARAMS)
 548   get_property(LLVM_LIT_DEPENDS GLOBAL PROPERTY LLVM_LIT_DEPENDS)
 549   get_property(LLVM_LIT_EXTRA_ARGS GLOBAL PROPERTY LLVM_LIT_EXTRA_ARGS)
 550   add_lit_target(check-all
 551     "Running all regression tests"
 552     ${LLVM_LIT_TESTSUITES}
 553     PARAMS ${LLVM_LIT_PARAMS}
 554     DEPENDS ${LLVM_LIT_DEPENDS}
 555     ARGS ${LLVM_LIT_EXTRA_ARGS}
 556     )
 557 endif()
 558
 559 if (LLVM_INCLUDE_DOCS)
 560   add_subdirectory(docs)
 561 endif()
 562
 563 add_subdirectory(cmake/modules)
 564
 565 if (NOT LLVM_INSTALL_TOOLCHAIN_ONLY)
 566   install(DIRECTORY include/llvm include/llvm-c
 567     DESTINATION include
 568     FILES_MATCHING
 569     PATTERN "*.def"
 570     PATTERN "*.h"
 571     PATTERN "*.td"
 572     PATTERN "*.inc"
 573     PATTERN "LICENSE.TXT"
 574     PATTERN ".svn" EXCLUDE
 575     )
 576
 577   install(DIRECTORY ${LLVM_INCLUDE_DIR}/llvm
 578     DESTINATION include
 579     FILES_MATCHING
 580     PATTERN "*.def"
 581     PATTERN "*.h"
 582     PATTERN "*.gen"
 583     PATTERN "*.inc"
 584     # Exclude include/llvm/CMakeFiles/intrinsics_gen.dir, matched by "*.def"
 585     PATTERN "CMakeFiles" EXCLUDE
 586     PATTERN ".svn" EXCLUDE
 587     )
 588 endif()