CMakeLists.txt

   1 # See docs/CMake.html for instructions about how to build LLVM with CMake.
   2
   3 cmake_minimum_required(VERSION 2.8.12.2)
   4
   5 if (NOT CMAKE_BUILD_TYPE AND NOT CMAKE_CONFIGURATION_TYPES)
   6   message(STATUS "No build type selected, default to Debug")
   7   set(CMAKE_BUILD_TYPE "Debug")
   8 endif()
   9
  10 if(POLICY CMP0022)
  11   cmake_policy(SET CMP0022 NEW) # automatic when 2.8.12 is required
  12 endif()
  13
  14 if (POLICY CMP0051)
  15   # CMake 3.1 and higher include generator expressions of the form
  16   # $<TARGETLIB:obj> in the SOURCES property.  These need to be
  17   # stripped everywhere that access the SOURCES property, so we just
  18   # defer to the OLD behavior of not including generator expressions
  19   # in the output for now.
  20   cmake_policy(SET CMP0051 OLD)
  21 endif()
  22
  23 if(CMAKE_VERSION VERSION_LESS 3.1.20141117)
  24   set(cmake_3_2_USES_TERMINAL)
  25 else()
  26   set(cmake_3_2_USES_TERMINAL USES_TERMINAL)
  27 endif()
  28
  29 project(LLVM)
  30
  31 # The following only works with the Ninja generator in CMake >= 3.0.
  32 set(LLVM_PARALLEL_COMPILE_JOBS "" CACHE STRING
  33   "Define the maximum number of concurrent compilation jobs.")
  34 if(LLVM_PARALLEL_COMPILE_JOBS)
  35   if(CMAKE_VERSION VERSION_LESS 3.0 OR NOT CMAKE_MAKE_PROGRAM MATCHES "ninja$")
  36     message(WARNING "Job pooling is only available with Ninja generators and CMake 3.0 and later.")
  37   else()
  38     set_property(GLOBAL APPEND PROPERTY JOB_POOLS compile_job_pool=${LLVM_PARALLEL_COMPILE_JOBS})
  39     set(CMAKE_JOB_POOL_COMPILE compile_job_pool)
  40   endif()
  41 endif()
  42
  43 set(LLVM_PARALLEL_LINK_JOBS "" CACHE STRING
  44   "Define the maximum number of concurrent link jobs.")
  45 if(LLVM_PARALLEL_LINK_JOBS)
  46   if(CMAKE_VERSION VERSION_LESS 3.0 OR NOT CMAKE_MAKE_PROGRAM MATCHES "ninja$")
  47     message(WARNING "Job pooling is only available with Ninja generators and CMake 3.0 and later.")
  48   else()
  49     set_property(GLOBAL APPEND PROPERTY JOB_POOLS link_job_pool=${LLVM_PARALLEL_LINK_JOBS})
  50     set(CMAKE_JOB_POOL_LINK link_job_pool)
  51   endif()
  52 endif()
  53
  54 # Add path for custom modules
  55 set(CMAKE_MODULE_PATH
  56   ${CMAKE_MODULE_PATH}
  57   "${CMAKE_CURRENT_SOURCE_DIR}/cmake"
  58   "${CMAKE_CURRENT_SOURCE_DIR}/cmake/modules"
  59   )
  60
  61 set(LLVM_VERSION_MAJOR 3)
  62 set(LLVM_VERSION_MINOR 8)
  63 set(LLVM_VERSION_PATCH 0)
  64 set(LLVM_VERSION_SUFFIX svn)
  65
  66 if (NOT PACKAGE_VERSION)
  67   set(PACKAGE_VERSION
  68     "${LLVM_VERSION_MAJOR}.${LLVM_VERSION_MINOR}.${LLVM_VERSION_PATCH}${LLVM_VERSION_SUFFIX}")
  69 endif()
  70
  71 option(LLVM_INSTALL_UTILS "Include utility binaries in the 'install' target." OFF)
  72
  73 option(LLVM_INSTALL_TOOLCHAIN_ONLY "Only include toolchain files in the 'install' target." OFF)
  74
  75 option(LLVM_USE_FOLDERS "Enable solution folders in Visual Studio. Disable for Express versions." ON)
  76 if ( LLVM_USE_FOLDERS )
  77   set_property(GLOBAL PROPERTY USE_FOLDERS ON)
  78 endif()
  79
  80 include(VersionFromVCS)
  81
  82 option(LLVM_APPEND_VC_REV
  83   "Append the version control system revision id to LLVM version" OFF)
  84
  85 if( LLVM_APPEND_VC_REV )
  86   add_version_info_from_vcs(PACKAGE_VERSION)
  87 endif()
  88
  89 set(PACKAGE_NAME LLVM)
  90 set(PACKAGE_STRING "${PACKAGE_NAME} ${PACKAGE_VERSION}")
  91 set(PACKAGE_BUGREPORT "http://llvm.org/bugs/")
  92
  93 set(BUG_REPORT_URL "${PACKAGE_BUGREPORT}" CACHE STRING
  94   "Default URL where bug reports are to be submitted.")
  95
  96 # Configure CPack.
  97 set(CPACK_PACKAGE_INSTALL_DIRECTORY "LLVM")
  98 set(CPACK_PACKAGE_VENDOR "LLVM")
  99 set(CPACK_PACKAGE_VERSION_MAJOR ${LLVM_VERSION_MAJOR})
 100 set(CPACK_PACKAGE_VERSION_MINOR ${LLVM_VERSION_MINOR})
 101 set(CPACK_PACKAGE_VERSION_PATCH ${LLVM_VERSION_PATCH})
 102 set(CPACK_PACKAGE_VERSION ${PACKAGE_VERSION})
 103 set(CPACK_RESOURCE_FILE_LICENSE "${CMAKE_CURRENT_SOURCE_DIR}/LICENSE.TXT")
 104 set(CPACK_NSIS_COMPRESSOR "/SOLID lzma \r\n SetCompressorDictSize 32")
 105 if(WIN32 AND NOT UNIX)
 106   set(CPACK_PACKAGE_INSTALL_REGISTRY_KEY "LLVM")
 107   set(CPACK_PACKAGE_ICON "${CMAKE_CURRENT_SOURCE_DIR}\\\\cmake\\\\nsis_logo.bmp")
 108   set(CPACK_NSIS_MUI_ICON "${CMAKE_CURRENT_SOURCE_DIR}\\\\cmake\\\\nsis_icon.ico")
 109   set(CPACK_NSIS_MUI_UNIICON "${CMAKE_CURRENT_SOURCE_DIR}\\\\cmake\\\\nsis_icon.ico")
 110   set(CPACK_NSIS_MODIFY_PATH "ON")
 111   set(CPACK_NSIS_ENABLE_UNINSTALL_BEFORE_INSTALL "ON")
 112   set(CPACK_NSIS_EXTRA_INSTALL_COMMANDS
 113     "ExecWait '$INSTDIR/tools/msbuild/install.bat'")
 114   set(CPACK_NSIS_EXTRA_UNINSTALL_COMMANDS
 115     "ExecWait '$INSTDIR/tools/msbuild/uninstall.bat'")
 116   if( CMAKE_CL_64 )
 117     set(CPACK_NSIS_INSTALL_ROOT "$PROGRAMFILES64")
 118   endif()
 119 endif()
 120 include(CPack)
 121
 122 # Sanity check our source directory to make sure that we are not trying to
 123 # generate an in-tree build (unless on MSVC_IDE, where it is ok), and to make
 124 # sure that we don't have any stray generated files lying around in the tree
 125 # (which would end up getting picked up by header search, instead of the correct
 126 # versions).
 127 if( CMAKE_SOURCE_DIR STREQUAL CMAKE_BINARY_DIR AND NOT MSVC_IDE )
 128   message(FATAL_ERROR "In-source builds are not allowed.
 129 CMake would overwrite the makefiles distributed with LLVM.
 130 Please create a directory and run cmake from there, passing the path
 131 to this source directory as the last argument.
 132 This process created the file `CMakeCache.txt' and the directory `CMakeFiles'.
 133 Please delete them.")
 134 endif()
 135 if( NOT CMAKE_SOURCE_DIR STREQUAL CMAKE_BINARY_DIR )
 136   file(GLOB_RECURSE
 137     tablegenned_files_on_include_dir
 138     "${CMAKE_CURRENT_SOURCE_DIR}/include/llvm/*.gen")
 139   file(GLOB_RECURSE
 140     tablegenned_files_on_lib_dir
 141     "${CMAKE_CURRENT_SOURCE_DIR}/lib/Target/*.inc")
 142   if( tablegenned_files_on_include_dir OR tablegenned_files_on_lib_dir)
 143     message(FATAL_ERROR "Apparently there is a previous in-source build,
 144 probably as the result of running `configure' and `make' on
 145 ${CMAKE_CURRENT_SOURCE_DIR}.
 146 This may cause problems. The suspicious files are:
 147 ${tablegenned_files_on_lib_dir}
 148 ${tablegenned_files_on_include_dir}
 149 Please clean the source directory.")
 150   endif()
 151 endif()
 152
 153 string(TOUPPER "${CMAKE_BUILD_TYPE}" uppercase_CMAKE_BUILD_TYPE)
 154
 155 set(LLVM_LIBDIR_SUFFIX "" CACHE STRING "Define suffix of library directory name (32/64)" )
 156
 157 # They are used as destination of target generators.
 158 set(LLVM_RUNTIME_OUTPUT_INTDIR ${CMAKE_CURRENT_BINARY_DIR}/${CMAKE_CFG_INTDIR}/bin)
 159 set(LLVM_LIBRARY_OUTPUT_INTDIR ${CMAKE_CURRENT_BINARY_DIR}/${CMAKE_CFG_INTDIR}/lib${LLVM_LIBDIR_SUFFIX})
 160 if(WIN32 OR CYGWIN)
 161   # DLL platform -- put DLLs into bin.
 162   set(LLVM_SHLIB_OUTPUT_INTDIR ${LLVM_RUNTIME_OUTPUT_INTDIR})
 163 else()
 164   set(LLVM_SHLIB_OUTPUT_INTDIR ${LLVM_LIBRARY_OUTPUT_INTDIR})
 165 endif()
 166
 167 # Each of them corresponds to llvm-config's.
 168 set(LLVM_TOOLS_BINARY_DIR ${LLVM_RUNTIME_OUTPUT_INTDIR}) # --bindir
 169 set(LLVM_LIBRARY_DIR      ${LLVM_LIBRARY_OUTPUT_INTDIR}) # --libdir
 170 set(LLVM_MAIN_SRC_DIR     ${CMAKE_CURRENT_SOURCE_DIR}  ) # --src-root
 171 set(LLVM_MAIN_INCLUDE_DIR ${LLVM_MAIN_SRC_DIR}/include ) # --includedir
 172 set(LLVM_BINARY_DIR       ${CMAKE_CURRENT_BINARY_DIR}  ) # --prefix
 173
 174 set(LLVM_EXAMPLES_BINARY_DIR ${LLVM_BINARY_DIR}/examples)
 175 set(LLVM_INCLUDE_DIR ${CMAKE_CURRENT_BINARY_DIR}/include)
 176
 177 set(LLVM_ALL_TARGETS
 178   AArch64
 179   AMDGPU
 180   ARM
 181   BPF
 182   CppBackend
 183   Hexagon
 184   Mips
 185   MSP430
 186   NVPTX
 187   PowerPC
 188   Sparc
 189   SystemZ
 190   X86
 191   XCore
 192   )
 193
 194 # List of targets with JIT support:
 195 set(LLVM_TARGETS_WITH_JIT X86 PowerPC AArch64 ARM Mips SystemZ)
 196
 197 set(LLVM_TARGETS_TO_BUILD "all"
 198     CACHE STRING "Semicolon-separated list of targets to build, or \"all\".")
 199
 200 set(LLVM_EXPERIMENTAL_TARGETS_TO_BUILD ""
 201   CACHE STRING "Semicolon-separated list of experimental targets to build.")
 202
 203 option(BUILD_SHARED_LIBS
 204   "Build all libraries as shared libraries instead of static" OFF)
 205
 206 option(LLVM_ENABLE_TIMESTAMPS "Enable embedding timestamp information in build" ON)
 207 if(LLVM_ENABLE_TIMESTAMPS)
 208   set(ENABLE_TIMESTAMPS 1)
 209 endif()
 210
 211 option(LLVM_ENABLE_BACKTRACES "Enable embedding backtraces on crash." ON)
 212 if(LLVM_ENABLE_BACKTRACES)
 213   set(ENABLE_BACKTRACES 1)
 214 endif()
 215
 216 option(LLVM_ENABLE_CRASH_OVERRIDES "Enable crash overrides." ON)
 217 if(LLVM_ENABLE_CRASH_OVERRIDES)
 218   set(ENABLE_CRASH_OVERRIDES 1)
 219 endif()
 220
 221 option(LLVM_ENABLE_FFI "Use libffi to call external functions from the interpreter" OFF)
 222 set(FFI_LIBRARY_DIR "" CACHE PATH "Additional directory, where CMake should search for libffi.so")
 223 set(FFI_INCLUDE_DIR "" CACHE PATH "Additional directory, where CMake should search for ffi.h or ffi/ffi.h")
 224
 225 set(LLVM_TARGET_ARCH "host"
 226   CACHE STRING "Set target to use for LLVM JIT or use \"host\" for automatic detection.")
 227
 228 option(LLVM_ENABLE_TERMINFO "Use terminfo database if available." ON)
 229
 230 option(LLVM_ENABLE_THREADS "Use threads if available." ON)
 231
 232 option(LLVM_ENABLE_ZLIB "Use zlib for compression/decompression if available." ON)
 233
 234 if( LLVM_TARGETS_TO_BUILD STREQUAL "all" )
 235   set( LLVM_TARGETS_TO_BUILD ${LLVM_ALL_TARGETS} )
 236 endif()
 237
 238 set(LLVM_TARGETS_TO_BUILD
 239    ${LLVM_TARGETS_TO_BUILD}
 240    ${LLVM_EXPERIMENTAL_TARGETS_TO_BUILD})
 241 list(REMOVE_DUPLICATES LLVM_TARGETS_TO_BUILD)
 242
 243 include(AddLLVMDefinitions)
 244
 245 option(LLVM_ENABLE_PIC "Build Position-Independent Code" ON)
 246 option(LLVM_ENABLE_WARNINGS "Enable compiler warnings." ON)
 247 option(LLVM_ENABLE_MODULES "Compile with C++ modules enabled." OFF)
 248 option(LLVM_ENABLE_CXX1Y "Compile with C++1y enabled." OFF)
 249 option(LLVM_ENABLE_LIBCXX "Use libc++ if available." OFF)
 250 option(LLVM_ENABLE_LIBCXXABI "Use libc++abi when using libc++." OFF)
 251 option(LLVM_ENABLE_PEDANTIC "Compile with pedantic enabled." ON)
 252 option(LLVM_ENABLE_WERROR "Fail and stop if a warning is triggered." OFF)
 253
 254 if( NOT uppercase_CMAKE_BUILD_TYPE STREQUAL "DEBUG" )
 255   option(LLVM_ENABLE_ASSERTIONS "Enable assertions" OFF)
 256 else()
 257   option(LLVM_ENABLE_ASSERTIONS "Enable assertions" ON)
 258 endif()
 259
 260 set(LLVM_ABI_BREAKING_CHECKS "WITH_ASSERTS" CACHE STRING
 261   "Enable abi-breaking checks.  Can be WITH_ASSERTS, FORCE_ON or FORCE_OFF.")
 262
 263 option(LLVM_FORCE_USE_OLD_HOST_TOOLCHAIN
 264        "Set to ON to force using an old, unsupported host toolchain." OFF)
 265
 266 option(LLVM_USE_INTEL_JITEVENTS
 267   "Use Intel JIT API to inform Intel(R) VTune(TM) Amplifier XE 2011 about JIT code"
 268   OFF)
 269
 270 if( LLVM_USE_INTEL_JITEVENTS )
 271   # Verify we are on a supported platform
 272   if( NOT CMAKE_SYSTEM_NAME MATCHES "Windows" AND NOT CMAKE_SYSTEM_NAME MATCHES "Linux" )
 273     message(FATAL_ERROR
 274       "Intel JIT API support is available on Linux and Windows only.")
 275   endif()
 276 endif( LLVM_USE_INTEL_JITEVENTS )
 277
 278 option(LLVM_USE_OPROFILE
 279   "Use opagent JIT interface to inform OProfile about JIT code" OFF)
 280
 281 # If enabled, verify we are on a platform that supports oprofile.
 282 if( LLVM_USE_OPROFILE )
 283   if( NOT CMAKE_SYSTEM_NAME MATCHES "Linux" )
 284     message(FATAL_ERROR "OProfile support is available on Linux only.")
 285   endif( NOT CMAKE_SYSTEM_NAME MATCHES "Linux" )
 286 endif( LLVM_USE_OPROFILE )
 287
 288 set(LLVM_USE_SANITIZER "" CACHE STRING
 289   "Define the sanitizer used to build binaries and tests.")
 290
 291 option(LLVM_USE_SPLIT_DWARF
 292   "Use -gsplit-dwarf when compiling llvm." OFF)
 293
 294 option(WITH_POLLY "Build LLVM with Polly" ON)
 295 option(LINK_POLLY_INTO_TOOLS "Static link Polly into tools" OFF)
 296
 297 # Define an option controlling whether we should build for 32-bit on 64-bit
 298 # platforms, where supported.
 299 if( CMAKE_SIZEOF_VOID_P EQUAL 8 AND NOT WIN32 )
 300   # TODO: support other platforms and toolchains.
 301   option(LLVM_BUILD_32_BITS "Build 32 bits executables and libraries." OFF)
 302 endif()
 303
 304 # Define the default arguments to use with 'lit', and an option for the user to
 305 # override.
 306 set(LIT_ARGS_DEFAULT "-sv")
 307 if (MSVC OR XCODE)
 308   set(LIT_ARGS_DEFAULT "${LIT_ARGS_DEFAULT} --no-progress-bar")
 309 endif()
 310 set(LLVM_LIT_ARGS "${LIT_ARGS_DEFAULT}" CACHE STRING "Default options for lit")
 311
 312 # On Win32 hosts, provide an option to specify the path to the GnuWin32 tools.
 313 if( WIN32 AND NOT CYGWIN )
 314   set(LLVM_LIT_TOOLS_DIR "" CACHE PATH "Path to GnuWin32 tools")
 315 endif()
 316
 317 # Define options to control the inclusion and default build behavior for
 318 # components which may not strictly be necessary (tools, examples, and tests).
 319 #
 320 # This is primarily to support building smaller or faster project files.
 321 option(LLVM_INCLUDE_TOOLS "Generate build targets for the LLVM tools." ON)
 322 option(LLVM_BUILD_TOOLS
 323   "Build the LLVM tools. If OFF, just generate build targets." ON)
 324
 325 option(LLVM_INCLUDE_UTILS "Generate build targets for the LLVM utils." ON)
 326
 327 option(LLVM_BUILD_RUNTIME
 328   "Build the LLVM runtime libraries." ON)
 329 option(LLVM_BUILD_EXAMPLES
 330   "Build the LLVM example programs. If OFF, just generate build targets." OFF)
 331 option(LLVM_INCLUDE_EXAMPLES "Generate build targets for the LLVM examples" ON)
 332
 333 option(LLVM_BUILD_TESTS
 334   "Build LLVM unit tests. If OFF, just generate build targets." OFF)
 335 option(LLVM_INCLUDE_TESTS "Generate build targets for the LLVM unit tests." ON)
 336
 337 option (LLVM_BUILD_DOCS "Build the llvm documentation." OFF)
 338 option (LLVM_INCLUDE_DOCS "Generate build targets for llvm documentation." ON)
 339 option (LLVM_ENABLE_DOXYGEN "Use doxygen to generate llvm API documentation." OFF)
 340 option (LLVM_ENABLE_SPHINX "Use Sphinx to generate llvm documentation." OFF)
 341
 342 option (LLVM_BUILD_EXTERNAL_COMPILER_RT
 343   "Build compiler-rt as an external project." OFF)
 344
 345 option(LLVM_BUILD_LLVM_DYLIB "Build libllvm dynamic library" OFF)
 346 option(LLVM_DYLIB_EXPORT_ALL "Export all symbols from libLLVM.dylib (default is C API only" OFF)
 347 option(LLVM_DISABLE_LLVM_DYLIB_ATEXIT "Disable llvm-shlib's atexit destructors." ON)
 348 if(LLVM_DISABLE_LLVM_DYLIB_ATEXIT)
 349   set(DISABLE_LLVM_DYLIB_ATEXIT 1)
 350 endif()
 351
 352 option(LLVM_OPTIMIZED_TABLEGEN "Force TableGen to be built with optimization" OFF)
 353 if(CMAKE_CROSSCOMPILING OR (LLVM_OPTIMIZED_TABLEGEN AND LLVM_ENABLE_ASSERTIONS))
 354   set(LLVM_USE_HOST_TOOLS ON)
 355 endif()
 356
 357 # All options referred to from HandleLLVMOptions have to be specified
 358 # BEFORE this include, otherwise options will not be correctly set on
 359 # first cmake run
 360 include(config-ix)
 361
 362 # By default, we target the host, but this can be overridden at CMake
 363 # invocation time.
 364 set(LLVM_DEFAULT_TARGET_TRIPLE "${LLVM_HOST_TRIPLE}" CACHE STRING
 365   "Default target for which LLVM will generate code." )
 366 set(TARGET_TRIPLE "${LLVM_DEFAULT_TARGET_TRIPLE}")
 367
 368 include(HandleLLVMOptions)
 369
 370 # Verify that we can find a Python 2 interpreter.  Python 3 is unsupported.
 371 # FIXME: We should support systems with only Python 3, but that requires work
 372 # on LLDB.
 373 set(Python_ADDITIONAL_VERSIONS 2.7)
 374 include(FindPythonInterp)
 375 if( NOT PYTHONINTERP_FOUND )
 376   message(FATAL_ERROR
 377 "Unable to find Python interpreter, required for builds and testing.
 378
 379 Please install Python or specify the PYTHON_EXECUTABLE CMake variable.")
 380 endif()
 381
 382 if( ${PYTHON_VERSION_STRING} VERSION_LESS 2.7 )
 383   message(FATAL_ERROR "Python 2.7 or newer is required")
 384 endif()
 385
 386 ######
 387 # LLVMBuild Integration
 388 #
 389 # We use llvm-build to generate all the data required by the CMake based
 390 # build system in one swoop:
 391 #
 392 #  - We generate a file (a CMake fragment) in the object root which contains
 393 #    all the definitions that are required by CMake.
 394 #
 395 #  - We generate the library table used by llvm-config.
 396 #
 397 #  - We generate the dependencies for the CMake fragment, so that we will
 398 #    automatically reconfigure outselves.
 399
 400 set(LLVMBUILDTOOL "${LLVM_MAIN_SRC_DIR}/utils/llvm-build/llvm-build")
 401 set(LLVMCONFIGLIBRARYDEPENDENCIESINC
 402   "${LLVM_BINARY_DIR}/tools/llvm-config/LibraryDependencies.inc")
 403 set(LLVMBUILDCMAKEFRAG
 404   "${LLVM_BINARY_DIR}/LLVMBuild.cmake")
 405
 406 # Create the list of optional components that are enabled
 407 if (LLVM_USE_INTEL_JITEVENTS)
 408   set(LLVMOPTIONALCOMPONENTS IntelJITEvents)
 409 endif (LLVM_USE_INTEL_JITEVENTS)
 410 if (LLVM_USE_OPROFILE)
 411   set(LLVMOPTIONALCOMPONENTS ${LLVMOPTIONALCOMPONENTS} OProfileJIT)
 412 endif (LLVM_USE_OPROFILE)
 413
 414 message(STATUS "Constructing LLVMBuild project information")
 415 execute_process(
 416   COMMAND ${PYTHON_EXECUTABLE} ${LLVMBUILDTOOL}
 417             --native-target "${LLVM_NATIVE_ARCH}"
 418             --enable-targets "${LLVM_TARGETS_TO_BUILD}"
 419             --enable-optional-components "${LLVMOPTIONALCOMPONENTS}"
 420             --write-library-table ${LLVMCONFIGLIBRARYDEPENDENCIESINC}
 421             --write-cmake-fragment ${LLVMBUILDCMAKEFRAG}
 422             OUTPUT_VARIABLE LLVMBUILDOUTPUT
 423             ERROR_VARIABLE LLVMBUILDERRORS
 424             OUTPUT_STRIP_TRAILING_WHITESPACE
 425             ERROR_STRIP_TRAILING_WHITESPACE
 426   RESULT_VARIABLE LLVMBUILDRESULT)
 427
 428 # On Win32, CMake doesn't properly handle piping the default output/error
 429 # streams into the GUI console. So, we explicitly catch and report them.
 430 if( NOT "${LLVMBUILDOUTPUT}" STREQUAL "")
 431   message(STATUS "llvm-build output: ${LLVMBUILDOUTPUT}")
 432 endif()
 433 if( NOT "${LLVMBUILDRESULT}" STREQUAL "0" )
 434   message(FATAL_ERROR
 435     "Unexpected failure executing llvm-build: ${LLVMBUILDERRORS}")
 436 endif()
 437
 438 # Include the generated CMake fragment. This will define properties from the
 439 # LLVMBuild files in a format which is easy to consume from CMake, and will add
 440 # the dependencies so that CMake will reconfigure properly when the LLVMBuild
 441 # files change.
 442 include(${LLVMBUILDCMAKEFRAG})
 443
 444 ######
 445
 446 # Configure all of the various header file fragments LLVM uses which depend on
 447 # configuration variables.
 448 set(LLVM_ENUM_TARGETS "")
 449 set(LLVM_ENUM_ASM_PRINTERS "")
 450 set(LLVM_ENUM_ASM_PARSERS "")
 451 set(LLVM_ENUM_DISASSEMBLERS "")
 452 foreach(t ${LLVM_TARGETS_TO_BUILD})
 453   set( td ${LLVM_MAIN_SRC_DIR}/lib/Target/${t} )
 454
 455   list(FIND LLVM_ALL_TARGETS ${t} idx)
 456   list(FIND LLVM_EXPERIMENTAL_TARGETS_TO_BUILD ${t} idy)
 457   if( idx LESS 0 AND idy LESS 0 )
 458     message(FATAL_ERROR "The target `${t}' does not exist.
 459     It should be one of\n${LLVM_ALL_TARGETS}")
 460   else()
 461     set(LLVM_ENUM_TARGETS "${LLVM_ENUM_TARGETS}LLVM_TARGET(${t})\n")
 462   endif()
 463
 464   file(GLOB asmp_file "${td}/*AsmPrinter.cpp")
 465   if( asmp_file )
 466     set(LLVM_ENUM_ASM_PRINTERS
 467       "${LLVM_ENUM_ASM_PRINTERS}LLVM_ASM_PRINTER(${t})\n")
 468   endif()
 469   if( EXISTS ${td}/AsmParser/CMakeLists.txt )
 470     set(LLVM_ENUM_ASM_PARSERS
 471       "${LLVM_ENUM_ASM_PARSERS}LLVM_ASM_PARSER(${t})\n")
 472   endif()
 473   if( EXISTS ${td}/Disassembler/CMakeLists.txt )
 474     set(LLVM_ENUM_DISASSEMBLERS
 475       "${LLVM_ENUM_DISASSEMBLERS}LLVM_DISASSEMBLER(${t})\n")
 476   endif()
 477 endforeach(t)
 478
 479 # Produce the target definition files, which provide a way for clients to easily
 480 # include various classes of targets.
 481 configure_file(
 482   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/AsmPrinters.def.in
 483   ${LLVM_INCLUDE_DIR}/llvm/Config/AsmPrinters.def
 484   )
 485 configure_file(
 486   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/AsmParsers.def.in
 487   ${LLVM_INCLUDE_DIR}/llvm/Config/AsmParsers.def
 488   )
 489 configure_file(
 490   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/Disassemblers.def.in
 491   ${LLVM_INCLUDE_DIR}/llvm/Config/Disassemblers.def
 492   )
 493 configure_file(
 494   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/Targets.def.in
 495   ${LLVM_INCLUDE_DIR}/llvm/Config/Targets.def
 496   )
 497
 498 # Configure the three LLVM configuration header files.
 499 configure_file(
 500   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/config.h.cmake
 501   ${LLVM_INCLUDE_DIR}/llvm/Config/config.h)
 502 configure_file(
 503   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/llvm-config.h.cmake
 504   ${LLVM_INCLUDE_DIR}/llvm/Config/llvm-config.h)
 505 configure_file(
 506   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Support/DataTypes.h.cmake
 507   ${LLVM_INCLUDE_DIR}/llvm/Support/DataTypes.h)
 508
 509 # They are not referenced. See set_output_directory().
 510 set( CMAKE_RUNTIME_OUTPUT_DIRECTORY ${LLVM_BINARY_DIR}/bin )
 511 set( CMAKE_LIBRARY_OUTPUT_DIRECTORY ${LLVM_BINARY_DIR}/lib${LLVM_LIBDIR_SUFFIX} )
 512 set( CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${LLVM_BINARY_DIR}/lib${LLVM_LIBDIR_SUFFIX} )
 513
 514 set(CMAKE_BUILD_WITH_INSTALL_RPATH ON)
 515 if (APPLE)
 516   set(CMAKE_INSTALL_NAME_DIR "@rpath")
 517   set(CMAKE_INSTALL_RPATH "@executable_path/../lib")
 518 else(UNIX)
 519   if(NOT DEFINED CMAKE_INSTALL_RPATH)
 520     set(CMAKE_INSTALL_RPATH "\$ORIGIN/../lib${LLVM_LIBDIR_SUFFIX}")
 521     if (${CMAKE_SYSTEM_NAME} MATCHES FreeBSD)
 522       set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -Wl,-z,origin")
 523       set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} -Wl,-z,origin")
 524     endif()
 525   endif(NOT DEFINED CMAKE_INSTALL_RPATH)
 526 endif()
 527
 528 # Work around a broken bfd ld behavior. When linking a binary with a
 529 # foo.so library, it will try to find any library that foo.so uses and
 530 # check its symbols. This is wasteful (the check was done when foo.so
 531 # was created) and can fail since it is not the dynamic linker and
 532 # doesn't know how to handle search paths correctly.
 533 if (UNIX AND NOT APPLE AND NOT ${CMAKE_SYSTEM_NAME} MATCHES "SunOS")
 534   set(CMAKE_EXE_LINKER_FLAGS
 535       "${CMAKE_EXE_LINKER_FLAGS} -Wl,-allow-shlib-undefined")
 536 endif()
 537
 538 set(CMAKE_INCLUDE_CURRENT_DIR ON)
 539
 540 include_directories( ${LLVM_INCLUDE_DIR} ${LLVM_MAIN_INCLUDE_DIR})
 541
 542 # when crosscompiling import the executable targets from a file
 543 if(LLVM_USE_HOST_TOOLS)
 544   include(CrossCompile)
 545 endif(LLVM_USE_HOST_TOOLS)
 546
 547 if( ${CMAKE_SYSTEM_NAME} MATCHES FreeBSD )
 548   # On FreeBSD, /usr/local/* is not used by default. In order to build LLVM
 549   # with libxml2, iconv.h, etc., we must add /usr/local paths.
 550   include_directories("/usr/local/include")
 551   link_directories("/usr/local/lib")
 552 endif( ${CMAKE_SYSTEM_NAME} MATCHES FreeBSD )
 553
 554 if( ${CMAKE_SYSTEM_NAME} MATCHES SunOS )
 555    SET(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -include llvm/Support/Solaris.h")
 556 endif( ${CMAKE_SYSTEM_NAME} MATCHES SunOS )
 557
 558 # Make sure we don't get -rdynamic in every binary. For those that need it,
 559 # use export_executable_symbols(target).
 560 set(CMAKE_SHARED_LIBRARY_LINK_CXX_FLAGS "")
 561
 562 include(AddLLVM)
 563 include(TableGen)
 564
 565 if( MINGW )
 566   # People report that -O3 is unreliable on MinGW. The traditional
 567   # build also uses -O2 for that reason:
 568   llvm_replace_compiler_option(CMAKE_CXX_FLAGS_RELEASE "-O3" "-O2")
 569 endif()
 570
 571 # Put this before tblgen. Else we have a circular dependence.
 572 add_subdirectory(lib/Support)
 573 add_subdirectory(lib/TableGen)
 574
 575 add_subdirectory(utils/TableGen)
 576
 577 add_subdirectory(include/llvm)
 578
 579 add_subdirectory(lib)
 580
 581 if( LLVM_INCLUDE_UTILS )
 582   add_subdirectory(utils/FileCheck)
 583   add_subdirectory(utils/PerfectShuffle)
 584   add_subdirectory(utils/count)
 585   add_subdirectory(utils/not)
 586   add_subdirectory(utils/llvm-lit)
 587   add_subdirectory(utils/yaml-bench)
 588 else()
 589   if ( LLVM_INCLUDE_TESTS )
 590     message(FATAL_ERROR "Including tests when not building utils will not work.
 591     Either set LLVM_INCLUDE_UTILS to On, or set LLVM_INCLDE_TESTS to Off.")
 592   endif()
 593 endif()
 594
 595 if(LLVM_INCLUDE_TESTS)
 596   add_subdirectory(utils/unittest)
 597 endif()
 598
 599 foreach( binding ${LLVM_BINDINGS_LIST} )
 600   if( EXISTS "${LLVM_MAIN_SRC_DIR}/bindings/${binding}/CMakeLists.txt" )
 601     add_subdirectory(bindings/${binding})
 602   endif()
 603 endforeach()
 604
 605 add_subdirectory(projects)
 606
 607 if(WITH_POLLY)
 608   if(NOT EXISTS ${LLVM_MAIN_SRC_DIR}/tools/polly/CMakeLists.txt)
 609     set(WITH_POLLY OFF)
 610   endif()
 611 endif(WITH_POLLY)
 612
 613 if( LLVM_INCLUDE_TOOLS )
 614   add_subdirectory(tools)
 615 endif()
 616
 617 if( LLVM_INCLUDE_EXAMPLES )
 618   add_subdirectory(examples)
 619 endif()
 620
 621 if( LLVM_INCLUDE_TESTS )
 622   add_subdirectory(test)
 623   add_subdirectory(unittests)
 624   if (MSVC)
 625     # This utility is used to prevent crashing tests from calling Dr. Watson on
 626     # Windows.
 627     add_subdirectory(utils/KillTheDoctor)
 628   endif()
 629
 630   # Add a global check rule now that all subdirectories have been traversed
 631   # and we know the total set of lit testsuites.
 632   get_property(LLVM_LIT_TESTSUITES GLOBAL PROPERTY LLVM_LIT_TESTSUITES)
 633   get_property(LLVM_LIT_PARAMS GLOBAL PROPERTY LLVM_LIT_PARAMS)
 634   get_property(LLVM_LIT_DEPENDS GLOBAL PROPERTY LLVM_LIT_DEPENDS)
 635   get_property(LLVM_LIT_EXTRA_ARGS GLOBAL PROPERTY LLVM_LIT_EXTRA_ARGS)
 636   add_lit_target(check-all
 637     "Running all regression tests"
 638     ${LLVM_LIT_TESTSUITES}
 639     PARAMS ${LLVM_LIT_PARAMS}
 640     DEPENDS ${LLVM_LIT_DEPENDS}
 641     ARGS ${LLVM_LIT_EXTRA_ARGS}
 642     )
 643 endif()
 644
 645 if (LLVM_INCLUDE_DOCS)
 646   add_subdirectory(docs)
 647 endif()
 648
 649 add_subdirectory(cmake/modules)
 650
 651 if (NOT LLVM_INSTALL_TOOLCHAIN_ONLY)
 652   install(DIRECTORY include/llvm include/llvm-c
 653     DESTINATION include
 654     COMPONENT llvm-headers
 655     FILES_MATCHING
 656     PATTERN "*.def"
 657     PATTERN "*.h"
 658     PATTERN "*.td"
 659     PATTERN "*.inc"
 660     PATTERN "LICENSE.TXT"
 661     PATTERN ".svn" EXCLUDE
 662     )
 663
 664   install(DIRECTORY ${LLVM_INCLUDE_DIR}/llvm
 665     DESTINATION include
 666     COMPONENT llvm-headers
 667     FILES_MATCHING
 668     PATTERN "*.def"
 669     PATTERN "*.h"
 670     PATTERN "*.gen"
 671     PATTERN "*.inc"
 672     # Exclude include/llvm/CMakeFiles/intrinsics_gen.dir, matched by "*.def"
 673     PATTERN "CMakeFiles" EXCLUDE
 674     PATTERN "config.h" EXCLUDE
 675     PATTERN ".svn" EXCLUDE
 676     )
 677
 678   if (NOT CMAKE_CONFIGURATION_TYPES)
 679     add_custom_target(installhdrs
 680                       DEPENDS ${name}
 681                       COMMAND "${CMAKE_COMMAND}"
 682                               -DCMAKE_INSTALL_COMPONENT=llvm-headers
 683                               -P "${CMAKE_BINARY_DIR}/cmake_install.cmake")
 684   endif()
 685 endif()