tools/llvm-config/llvm-config.in.in

   1 #!@PERL@
   2 ##===- tools/llvm-config ---------------------------------------*- perl -*-===##
   3 #
   4 #                     The LLVM Compiler Infrastructure
   5 #
   6 # This file is distributed under the University of Illinois Open Source
   7 # License. See LICENSE.TXT for details.
   8 #
   9 ##===----------------------------------------------------------------------===##
  10 #
  11 # Synopsis: Prints out compiler options needed to build against an installed
  12 #           copy of LLVM.
  13 #
  14 # Syntax:   llvm-config OPTIONS... [COMPONENTS...]
  15 #
  16 ##===----------------------------------------------------------------------===##
  17
  18 use 5.006;
  19 use strict;
  20 use warnings;
  21 use Cwd 'abs_path';
  22
  23 #---- begin autoconf values ----
  24 my $PACKAGE_NAME        = q{@PACKAGE_NAME@};
  25 my $VERSION             = q{@PACKAGE_VERSION@};
  26 my $PREFIX              = q{@LLVM_PREFIX@};
  27 my $LLVM_CONFIGTIME     = q{@LLVM_CONFIGTIME@};
  28 my $LLVM_SRC_ROOT       = q{@abs_top_srcdir@};
  29 my $LLVM_OBJ_ROOT       = q{@abs_top_builddir@};
  30 my $ARCH                = lc(q{@ARCH@});
  31 my $TARGET_TRIPLE       = q{@target@};
  32 my $TARGETS_TO_BUILD    = q{@TARGETS_TO_BUILD@};
  33 my $TARGET_HAS_JIT      = q{@TARGET_HAS_JIT@};
  34 my @TARGETS_BUILT       = map { lc($_) } qw{@TARGETS_TO_BUILD@};
  35 #---- end autoconf values ----
  36
  37 # Must pretend x86_64 architecture is really x86, otherwise the native backend
  38 # won't get linked in.
  39 $ARCH = "x86" if $ARCH eq "x86_64";
  40
  41 #---- begin Makefile values ----
  42 my $CPPFLAGS            = q{@LLVM_CPPFLAGS@};
  43 my $CFLAGS              = q{@LLVM_CFLAGS@};
  44 my $CXXFLAGS            = q{@LLVM_CXXFLAGS@};
  45 my $LDFLAGS             = q{@LLVM_LDFLAGS@};
  46 my $SYSTEM_LIBS         = q{@LIBS@};
  47 my $LLVM_BUILDMODE      = q{@LLVM_BUILDMODE@};
  48 my $LLVM_OBJ_SUFFIX     = q{@LLVM_OBJ_SUFFIX@};
  49 #---- end Makefile values ----
  50
  51 # Figure out where llvm-config is being run from.  Primarily, we care if it has
  52 # been installed, or is running from the build directory, which changes the
  53 # locations of some files.
  54
  55 # Convert the current executable name into its directory (e.g. ".").
  56 my ($RUN_DIR) = ($0 =~ /^(.*)\/.*$/);
  57
  58 # Turn the directory into an absolute directory on the file system, also pop up
  59 # from "bin" into the build or prefix dir.
  60 my $ABS_RUN_DIR = abs_path("$RUN_DIR/..");
  61 chomp($ABS_RUN_DIR);
  62
  63 # Compute the absolute object directory build, e.g. "foo/llvm/Debug".
  64 my $ABS_OBJ_ROOT = "$LLVM_OBJ_ROOT$LLVM_OBJ_SUFFIX";
  65 $ABS_OBJ_ROOT = abs_path("$ABS_OBJ_ROOT") if (-d $ABS_OBJ_ROOT);
  66 chomp($ABS_OBJ_ROOT);
  67
  68 my $INCLUDEDIR = "$ABS_RUN_DIR/include";
  69 my $INCLUDEOPTION = "-I$INCLUDEDIR";
  70 my $LIBDIR     = "$ABS_RUN_DIR/lib";
  71 my $BINDIR     = "$ABS_RUN_DIR/bin";
  72 if ($ABS_RUN_DIR eq $ABS_OBJ_ROOT) {
  73   # If we are running out of the build directory, the include dir is in the
  74   # srcdir.
  75   $INCLUDEDIR = "$LLVM_SRC_ROOT/include";
  76   # We need include files from both the srcdir and objdir.
  77   $INCLUDEOPTION = "-I$INCLUDEDIR -I$LLVM_OBJ_ROOT/include"
  78 } else {
  79   # If installed, ignore the prefix the tree was configured with, use the
  80   # current prefix.
  81   $PREFIX = $ABS_RUN_DIR;
  82 }
  83
  84 sub usage;
  85 sub fix_library_names (@);
  86 sub fix_library_files (@);
  87 sub expand_dependencies (@);
  88 sub name_map_entries;
  89
  90 # Parse our command-line arguments.
  91 usage if @ARGV == 0;
  92 my @components;
  93 my $has_opt = 0;
  94 my $want_libs = 0;
  95 my $want_libnames = 0;
  96 my $want_libfiles = 0;
  97 my $want_components = 0;
  98 foreach my $arg (@ARGV) {
  99     if ($arg =~ /^-/) {
 100         if ($arg eq "--version") {
 101             $has_opt = 1; print "$VERSION\n";
 102         } elsif ($arg eq "--prefix") {
 103             $has_opt = 1; print "$PREFIX\n";
 104         } elsif ($arg eq "--bindir") {
 105             $has_opt = 1; print "$BINDIR\n";
 106         } elsif ($arg eq "--includedir") {
 107             $has_opt = 1; print "$INCLUDEDIR\n";
 108         } elsif ($arg eq "--libdir") {
 109             $has_opt = 1; print "$LIBDIR\n";
 110         } elsif ($arg eq "--cppflags") {
 111             $has_opt = 1; print "$INCLUDEOPTION $CPPFLAGS\n";
 112         } elsif ($arg eq "--cflags") {
 113             $has_opt = 1; print "$INCLUDEOPTION $CFLAGS\n";
 114         } elsif ($arg eq "--cxxflags") {
 115             $has_opt = 1; print "$INCLUDEOPTION $CXXFLAGS\n";
 116         } elsif ($arg eq "--ldflags") {
 117             $has_opt = 1; print "-L$LIBDIR $LDFLAGS $SYSTEM_LIBS\n";
 118         } elsif ($arg eq "--libs") {
 119             $has_opt = 1; $want_libs = 1;
 120         } elsif ($arg eq "--libnames") {
 121             $has_opt = 1; $want_libnames = 1;
 122         } elsif ($arg eq "--libfiles") {
 123             $has_opt = 1; $want_libfiles = 1;
 124         } elsif ($arg eq "--components") {
 125             $has_opt = 1; print join(' ', name_map_entries), "\n";
 126         } elsif ($arg eq "--targets-built") {
 127             $has_opt = 1; print join(' ', @TARGETS_BUILT), "\n";
 128         } elsif ($arg eq "--host-target") {
 129             $has_opt = 1; print "$TARGET_TRIPLE\n";
 130         } elsif ($arg eq "--build-mode") {
 131             $has_opt = 1; print "$LLVM_BUILDMODE\n";
 132         } elsif ($arg eq "--obj-root") {
 133             $has_opt = 1; print abs_path("$LLVM_OBJ_ROOT/");
 134         } elsif ($arg eq "--src-root") {
 135             $has_opt = 1; print abs_path("$LLVM_SRC_ROOT/");
 136         } else {
 137             usage();
 138         }
 139     } else {
 140         push @components, $arg;
 141     }
 142 }
 143
 144 # If no options were specified, fail.
 145 usage unless $has_opt;
 146
 147 # If no components were specified, default to 'all'.
 148 if (@components == 0) {
 149     push @components, 'all';
 150 }
 151
 152 # Force component names to lower case.
 153 @components = map lc, @components;
 154
 155 # Handle any arguments which require building our dependency graph.
 156 if ($want_libs || $want_libnames || $want_libfiles) {
 157     my @libs = expand_dependencies(@components);
 158     print join(' ', fix_library_names(@libs)), "\n" if ($want_libs);
 159     print join(' ',  @libs), "\n" if ($want_libnames);
 160     print join(' ', fix_library_files(@libs)), "\n" if ($want_libfiles);
 161 }
 162
 163 exit 0;
 164
 165 #==========================================================================
 166 #  Support Routines
 167 #==========================================================================
 168
 169 sub usage {
 170     print STDERR <<__EOD__;
 171 Usage: llvm-config <OPTION>... [<COMPONENT>...]
 172
 173 Get various configuration information needed to compile programs which use
 174 LLVM.  Typically called from 'configure' scripts.  Examples:
 175   llvm-config --cxxflags
 176   llvm-config --ldflags
 177   llvm-config --libs engine bcreader scalaropts
 178
 179 Options:
 180   --version          Print LLVM version.
 181   --prefix           Print the installation prefix.
 182   --src-root         Print the source root LLVM was built from.
 183   --obj-root         Print the object root used to build LLVM.
 184   --bindir           Directory containing LLVM executables.
 185   --includedir       Directory containing LLVM headers.
 186   --libdir           Directory containing LLVM libraries.
 187   --cppflags         C preprocessor flags for files that include LLVM headers.
 188   --cflags           C compiler flags for files that include LLVM headers.
 189   --cxxflags         C++ compiler flags for files that include LLVM headers.
 190   --ldflags          Print Linker flags.
 191   --libs             Libraries needed to link against LLVM components.
 192   --libnames         Bare library names for in-tree builds.
 193   --libfiles         Fully qualified library filenames for makefile depends.
 194   --components       List of all possible components.
 195   --targets-built    List of all targets currently built.
 196   --host-target      Target triple used to configure LLVM.
 197   --build-mode       Print build mode of LLVM tree (e.g. Debug or Release).
 198 Typical components:
 199   all                All LLVM libraries (default).
 200   backend            Either a native backend or the C backend.
 201   engine             Either a native JIT or a bitcode interpreter.
 202 __EOD__
 203     exit(1);
 204 }
 205
 206 # Use -lfoo instead of libfoo.a whenever possible, and add directories to
 207 # files which can't be found using -L.
 208 sub fix_library_names (@) {
 209     my @libs = @_;
 210     my @result;
 211     foreach my $lib (@libs) {
 212         # Transform the bare library name appropriately.
 213         my ($basename) = ($lib =~ /^lib([^.]*)\.a/);
 214         if (defined $basename) {
 215             push @result, "-l$basename";
 216         } else {
 217             push @result, "$LIBDIR/$lib";
 218         }
 219     }
 220     return @result;
 221 }
 222
 223 # Turn the list of libraries into a list of files.
 224 sub fix_library_files(@) {
 225     my @libs = @_;
 226     my @result;
 227     foreach my $lib (@libs) {
 228         # Transform the bare library name into a filename.
 229         push @result, "$LIBDIR/$lib";
 230     }
 231     return @result;
 232 }
 233
 234 #==========================================================================
 235 #  Library Dependency Analysis
 236 #==========================================================================
 237 #  Given a few human-readable library names, find all their dependencies
 238 #  and sort them into an order which the linker will like.  If we packed
 239 #  our libraries into fewer archives, we could make the linker do much
 240 #  of this work for us.
 241 #
 242 #  Libraries have two different types of names in this code: Human-friendly
 243 #  "component" names entered on the command-line, and the raw file names
 244 #  we use internally (and ultimately pass to the linker).
 245 #
 246 #  To understand this code, you'll need a working knowledge of Perl 5,
 247 #  and possibly some quality time with 'man perlref'.
 248
 249 sub load_dependencies;
 250 sub build_name_map;
 251 sub have_native_backend;
 252 sub find_best_engine;
 253 sub expand_names (@);
 254 sub find_all_required_sets (@);
 255 sub find_all_required_sets_helper ($$@);
 256
 257 # Each "set" contains one or more libraries which must be included as a
 258 # group (due to cyclic dependencies).  Sets are represented as a Perl array
 259 # reference pointing to a list of internal library names.
 260 my @SETS;
 261
 262 # Various mapping tables.
 263 my %LIB_TO_SET_MAP; # Maps internal library names to their sets.
 264 my %SET_DEPS;       # Maps sets to a list of libraries they depend on.
 265 my %NAME_MAP;       # Maps human-entered names to internal names.
 266
 267 # Have our dependencies been loaded yet?
 268 my $DEPENDENCIES_LOADED = 0;
 269
 270 # Given a list of human-friendly component names, translate them into a
 271 # complete set of linker arguments.
 272 sub expand_dependencies (@) {
 273     my @libs = @_;
 274     load_dependencies;
 275     my @required_sets = find_all_required_sets(expand_names(@libs));
 276     my @sorted_sets = topologically_sort_sets(@required_sets);
 277
 278     # Expand the library sets into libraries.
 279     my @result;
 280     foreach my $set (@sorted_sets) { push @result, @{$set}; }
 281     return @result;
 282 }
 283
 284 # Load in the raw dependency data stored at the end of this file.
 285 sub load_dependencies {
 286     return if $DEPENDENCIES_LOADED;
 287     $DEPENDENCIES_LOADED = 1;
 288     while (<DATA>) {
 289         # Parse our line.
 290         my ($libs, $deps) = /^\s*([^:]+):\s*(.*)\s*$/;
 291         die "Malformed dependency data" unless defined $deps;
 292         my @libs = split(' ', $libs);
 293         my @deps = split(' ', $deps);
 294
 295         # Record our dependency data.
 296         my $set = \@libs;
 297         push @SETS, $set;
 298         foreach my $lib (@libs) { $LIB_TO_SET_MAP{$lib} = $set; }
 299         $SET_DEPS{$set} = \@deps;
 300     }
 301     build_name_map;
 302 }
 303
 304 # Build a map converting human-friendly component names into internal
 305 # library names.
 306 sub build_name_map {
 307     # Add entries for all the actual libraries.
 308     foreach my $set (@SETS) {
 309         foreach my $lib (sort @$set) {
 310             my $short_name = $lib;
 311             $short_name =~ s/^(lib)?LLVM([^.]*)\..*$/$2/;
 312             $short_name =~ tr/A-Z/a-z/;
 313             $NAME_MAP{$short_name} = [$lib];
 314         }
 315     }
 316
 317     # Add target-specific entries
 318     my @all_targets;
 319     foreach my $target (@TARGETS_BUILT) {
 320         # FIXME: Temporary, until we don't switch all targets
 321         if (defined $NAME_MAP{$target.'asmprinter'}) {
 322             $NAME_MAP{$target} = [$target.'info',
 323                                   $target.'asmprinter',
 324                                   $target.'codegen']
 325         } elsif (defined $NAME_MAP{$target.'codegen'}) {
 326             $NAME_MAP{$target} = [$target.'info',
 327                                   $target.'codegen']
 328         } else {
 329             $NAME_MAP{$target} = [$target.'info',
 330                                   $NAME_MAP{$target}[0]]
 331         }
 332
 333         if (defined $NAME_MAP{$target.'asmparser'}) {
 334             push @{$NAME_MAP{$target}},$target.'asmparser'
 335         }
 336
 337         if (defined $NAME_MAP{$target.'disassembler'}) {
 338             push @{$NAME_MAP{$target}},$target.'disassembler'
 339         }
 340
 341         push @all_targets, $target;
 342     }
 343
 344     # Add virtual entries.
 345     $NAME_MAP{'native'}  = have_native_backend() ? [$ARCH] : [];
 346     $NAME_MAP{'nativecodegen'} = have_native_backend() ? [$ARCH.'codegen'] : [];
 347     $NAME_MAP{'backend'} = have_native_backend() ? ['native'] : ['cbackend'];
 348     $NAME_MAP{'engine'}  = find_best_engine;
 349     $NAME_MAP{'all-targets'}     = \@all_targets;
 350     $NAME_MAP{'all'}     = [name_map_entries];   # Must be last.
 351 }
 352
 353 # Return true if we have a native backend to use.
 354 sub have_native_backend {
 355     my %BUILT;
 356     foreach my $target (@TARGETS_BUILT) { $BUILT{$target} = 1; }
 357     return defined $NAME_MAP{$ARCH} && defined $BUILT{$ARCH};
 358 }
 359
 360 # Find a working subclass of ExecutionEngine for this platform.
 361 sub find_best_engine {
 362     if (have_native_backend && $TARGET_HAS_JIT) {
 363         return ['jit', 'native'];
 364     } else {
 365         return ['interpreter'];
 366     }
 367 }
 368
 369 # Get all the human-friendly component names.
 370 sub name_map_entries {
 371     load_dependencies;
 372     return sort keys %NAME_MAP;
 373 }
 374
 375 # Map human-readable names to internal library names.
 376 sub expand_names (@) {
 377     my @names = @_;
 378     my @result;
 379     foreach my $name (@names) {
 380         if (defined $LIB_TO_SET_MAP{$name}) {
 381             # We've hit bottom: An actual library name.
 382             push @result, $name;
 383         } elsif (defined $NAME_MAP{$name}) {
 384             # We've found a short name to expand.
 385             push @result, expand_names(@{$NAME_MAP{$name}});
 386         } else {
 387             print STDERR "llvm-config: unknown component name: $name\n";
 388             exit(1);
 389         }
 390     }
 391     return @result;
 392 }
 393
 394 # Given a list of internal library names, return all sets of libraries which
 395 # will need to be included by the linker (in no particular order).
 396 sub find_all_required_sets (@) {
 397     my @libs = @_;
 398     my %sets_added;
 399     my @result;
 400     find_all_required_sets_helper(\%sets_added, \@result, @libs);
 401     return @result;
 402 }
 403
 404 # Recursive closures are pretty broken in Perl, so we're going to separate
 405 # this function from find_all_required_sets and pass in the state we need
 406 # manually, as references.  Yes, this is fairly unpleasant.
 407 sub find_all_required_sets_helper ($$@) {
 408     my ($sets_added, $result, @libs) = @_;
 409     foreach my $lib (@libs) {
 410         my $set = $LIB_TO_SET_MAP{$lib};
 411         next if defined $$sets_added{$set};
 412         $$sets_added{$set} = 1;
 413         push @$result, $set;
 414         find_all_required_sets_helper($sets_added, $result, @{$SET_DEPS{$set}});
 415     }
 416 }
 417
 418 # Print a list of sets, with a label.  Used for debugging.
 419 sub print_sets ($@) {
 420     my ($label, @sets) = @_;
 421     my @output;
 422     foreach my $set (@sets) { push @output, join(',', @$set); }
 423     print "$label: ", join(';', @output), "\n";
 424 }
 425
 426 # Returns true if $lib is a key in $added.
 427 sub has_lib_been_added ($$) {
 428     my ($added, $lib) = @_;
 429     return defined $$added{$LIB_TO_SET_MAP{$lib}};
 430 }
 431
 432 # Returns true if all the dependencies of $set appear in $added.
 433 sub have_all_deps_been_added ($$) {
 434     my ($added, $set) = @_;
 435     #print_sets("  Checking", $set);
 436     #print_sets("     Wants", $SET_DEPS{$set});
 437     foreach my $lib (@{$SET_DEPS{$set}}) {
 438         return 0 unless has_lib_been_added($added, $lib);
 439     }
 440     return 1;
 441 }
 442
 443 # Given a list of sets, topologically sort them using dependencies.
 444 sub topologically_sort_sets (@) {
 445     my @sets = @_;
 446     my %added;
 447     my @result;
 448     SCAN: while (@sets) { # We'll delete items from @sets as we go.
 449         #print_sets("So far", reverse(@result));
 450         #print_sets("Remaining", @sets);
 451         for (my $i = 0; $i < @sets; ++$i) {
 452             my $set = $sets[$i];
 453             if (have_all_deps_been_added(\%added, $set)) {
 454                 push @result, $set;
 455                 $added{$set} = 1;
 456                 #print "Removing $i.\n";
 457                 splice(@sets, $i, 1);
 458                 next SCAN; # Restart our scan.
 459             }
 460         }
 461         die "Can't find a library with no dependencies";
 462     }
 463     return reverse(@result);
 464 }
 465
 466 # Our library dependency data will be added after the '__END__' token, and will
 467 # be read through the magic <DATA> filehandle.
 468 __END__