test/Transforms/LoopUnroll/full-unroll-heuristics.ll

   1 ; In this test we check how heuristics for complete unrolling work. We have
   2 ; three knobs:
   3 ;  1) -unroll-threshold
   4 ;  2) -unroll-absolute-threshold and
   5 ;  3) -unroll-percent-of-optimized-for-complete-unroll
   6 ;
   7 ; They control loop-unrolling according to the following rules:
   8 ;  * If size of unrolled loop exceeds the absoulte threshold, we don't unroll
   9 ;    this loop under any circumstances.
  10 ;  * If size of unrolled loop is below the '-unroll-threshold', then we'll
  11 ;    consider this loop as a very small one, and completely unroll it.
  12 ;  * If a loop size is between these two tresholds, we only do complete unroll
  13 ;    it if estimated number of potentially optimized instructions is high (we
  14 ;    specify the minimal percent of such instructions).
  15
  16 ; In this particular test-case, complete unrolling will allow later
  17 ; optimizations to remove ~55% of the instructions, the loop body size is 9,
  18 ; and unrolled size is 65.
  19
  20 ; RUN: opt < %s -S -loop-unroll -unroll-max-iteration-count-to-analyze=1000 -unroll-absolute-threshold=10  -unroll-threshold=10  -unroll-percent-of-optimized-for-complete-unroll=20 | FileCheck %s -check-prefix=TEST1
  21 ; RUN: opt < %s -S -loop-unroll -unroll-max-iteration-count-to-analyze=1000 -unroll-absolute-threshold=100 -unroll-threshold=10  -unroll-percent-of-optimized-for-complete-unroll=20 | FileCheck %s -check-prefix=TEST2
  22 ; RUN: opt < %s -S -loop-unroll -unroll-max-iteration-count-to-analyze=1000 -unroll-absolute-threshold=100 -unroll-threshold=10  -unroll-percent-of-optimized-for-complete-unroll=80 | FileCheck %s -check-prefix=TEST3
  23 ; RUN: opt < %s -S -loop-unroll -unroll-max-iteration-count-to-analyze=1000 -unroll-absolute-threshold=100 -unroll-threshold=100 -unroll-percent-of-optimized-for-complete-unroll=80 | FileCheck %s -check-prefix=TEST4
  24
  25 ; If the absolute threshold is too low, or if we can't optimize away requested
  26 ; percent of instructions, we shouldn't unroll:
  27 ; TEST1: %array_const_idx = getelementptr inbounds [9 x i32], [9 x i32]* @known_constant, i64 0, i64 %iv
  28 ; TEST3: %array_const_idx = getelementptr inbounds [9 x i32], [9 x i32]* @known_constant, i64 0, i64 %iv
  29
  30 ; Otherwise, we should:
  31 ; TEST2-NOT: %array_const_idx = getelementptr inbounds [9 x i32], [9 x i32]* @known_constant, i64 0, i64 %iv
  32
  33 ; Also, we should unroll if the 'unroll-threshold' is big enough:
  34 ; TEST4-NOT: %array_const_idx = getelementptr inbounds [9 x i32], [9 x i32]* @known_constant, i64 0, i64 %iv
  35
  36 ; And check that we don't crash when we're not allowed to do any analysis.
  37 ; RUN: opt < %s -loop-unroll -unroll-max-iteration-count-to-analyze=0 -disable-output
  38 target datalayout = "e-m:o-i64:64-f80:128-n8:16:32:64-S128"
  39
  40 @known_constant = internal unnamed_addr constant [9 x i32] [i32 0, i32 -1, i32 0, i32 -1, i32 5, i32 -1, i32 0, i32 -1, i32 0], align 16
  41
  42 define i32 @foo(i32* noalias nocapture readonly %src) {
  43 entry:
  44   br label %loop
  45
  46 loop:                                                ; preds = %loop, %entry
  47   %iv = phi i64 [ 0, %entry ], [ %inc, %loop ]
  48   %r  = phi i32 [ 0, %entry ], [ %add, %loop ]
  49   %arrayidx = getelementptr inbounds i32, i32* %src, i64 %iv
  50   %src_element = load i32, i32* %arrayidx, align 4
  51   %array_const_idx = getelementptr inbounds [9 x i32], [9 x i32]* @known_constant, i64 0, i64 %iv
  52   %const_array_element = load i32, i32* %array_const_idx, align 4
  53   %mul = mul nsw i32 %src_element, %const_array_element
  54   %add = add nsw i32 %mul, %r
  55   %inc = add nuw nsw i64 %iv, 1
  56   %exitcond86.i = icmp eq i64 %inc, 9
  57   br i1 %exitcond86.i, label %loop.end, label %loop
  58
  59 loop.end:                                            ; preds = %loop
  60   %r.lcssa = phi i32 [ %r, %loop ]
  61   ret i32 %r.lcssa
  62 }