test/CMakeLists.txt

   1 # Set up some variables specifically used by lit.
   2 set(LD_EXECUTABLE ${CMAKE_LINKER})
   3
   4 configure_lit_site_cfg(
   5   ${CMAKE_CURRENT_SOURCE_DIR}/lit.site.cfg.in
   6   ${CMAKE_CURRENT_BINARY_DIR}/lit.site.cfg
   7   )
   8 configure_lit_site_cfg(
   9   ${CMAKE_CURRENT_SOURCE_DIR}/Unit/lit.site.cfg.in
  10   ${CMAKE_CURRENT_BINARY_DIR}/Unit/lit.site.cfg
  11   )
  12
  13 # Don't include check-llvm into check-all without LLVM_BUILD_TOOLS.
  14 if(NOT LLVM_BUILD_TOOLS)
  15   set(EXCLUDE_FROM_ALL ON)
  16 endif()
  17
  18 # Set the depends list as a variable so that it can grow conditionally.
  19 # NOTE: Sync the substitutions in test/lit.cfg when adding to this list.
  20 set(LLVM_TEST_DEPENDS
  21           llvm-config
  22           UnitTests
  23           BugpointPasses
  24           LLVMHello
  25           bugpoint
  26           llc
  27           lli
  28           lli-child-target
  29           llvm-ar
  30           llvm-as
  31           llvm-bcanalyzer
  32           llvm-c-test
  33           llvm-cov
  34           llvm-diff
  35           llvm-dis
  36           llvm-dsymutil
  37           llvm-dwarfdump
  38           llvm-extract
  39           llvm-link
  40           llvm-lto
  41           llvm-mc
  42           llvm-mcmarkup
  43           llvm-nm
  44           llvm-objdump
  45           llvm-profdata
  46           llvm-ranlib
  47           llvm-readobj
  48           llvm-rtdyld
  49           llvm-size
  50           llvm-symbolizer
  51           llvm-tblgen
  52           llvm-vtabledump
  53           macho-dump
  54           opt
  55           FileCheck
  56           count
  57           not
  58           yaml2obj
  59           obj2yaml
  60           verify-uselistorder
  61         )
  62
  63 # If Intel JIT events are supported, depend on a tool that tests the listener.
  64 if( LLVM_USE_INTEL_JITEVENTS )
  65   set(LLVM_TEST_DEPENDS ${LLVM_TEST_DEPENDS} llvm-jitlistener)
  66 endif( LLVM_USE_INTEL_JITEVENTS )
  67
  68 if(TARGET LLVMgold)
  69   set(LLVM_TEST_DEPENDS ${LLVM_TEST_DEPENDS} LLVMgold)
  70 endif()
  71
  72 if(TARGET llvm-go)
  73   set(LLVM_TEST_DEPENDS ${LLVM_TEST_DEPENDS} llvm-go)
  74 endif()
  75
  76 if(TARGET ocaml_llvm)
  77   set(LLVM_TEST_DEPENDS ${LLVM_TEST_DEPENDS}
  78           ocaml_llvm
  79           ocaml_llvm_all_backends
  80           ocaml_llvm_analysis
  81           ocaml_llvm_bitreader
  82           ocaml_llvm_bitwriter
  83           ocaml_llvm_executionengine
  84           ocaml_llvm_irreader
  85           ocaml_llvm_linker
  86           ocaml_llvm_target
  87           ocaml_llvm_ipo
  88           ocaml_llvm_passmgr_builder
  89           ocaml_llvm_scalar_opts
  90           ocaml_llvm_transform_utils
  91           ocaml_llvm_vectorize
  92         )
  93 endif()
  94
  95 add_lit_testsuite(check-llvm "Running the LLVM regression tests"
  96   ${CMAKE_CURRENT_BINARY_DIR}
  97   PARAMS llvm_site_config=${CMAKE_CURRENT_BINARY_DIR}/lit.site.cfg
  98          llvm_unit_site_config=${CMAKE_CURRENT_BINARY_DIR}/Unit/lit.site.cfg
  99   DEPENDS ${LLVM_TEST_DEPENDS}
 100   )
 101 set_target_properties(check-llvm PROPERTIES FOLDER "Tests")
 102
 103 # Setup a legacy alias for 'check-llvm'. This will likely change to be an
 104 # alias for 'check-all' at some point in the future.
 105 add_custom_target(check)
 106 add_dependencies(check check-llvm)
 107 set_target_properties(check PROPERTIES FOLDER "Tests")