projects/sample/autoconf/configure.ac

   1 dnl **************************************************************************
   2 dnl * Initialize
   3 dnl **************************************************************************
   4 AC_INIT([[[SAMPLE]]],[[[x.xx]]],[bugs@yourdomain])
   5
   6 dnl Identify where LLVM source tree is
   7 LLVM_SRC_ROOT="../.."
   8 LLVM_OBJ_ROOT="../.."
   9
  10 dnl Find absolute paths to LLVM source and object trees
  11 LLVM_ABS_SRC_ROOT="`cd $srcdir ; cd $LLVM_SRC_ROOT ; pwd`"
  12 LLVM_ABS_OBJ_ROOT="`cd $LLVM_OBJ_ROOT ; pwd`"
  13
  14 dnl Tell autoconf that this is an LLVM project being configured
  15 dnl This provides the --with-llvmsrc and --with-llvmobj options
  16 LLVM_CONFIG_PROJECT($LLVM_ABS_SRC_ROOT,$LLVM_ABS_OBJ_ROOT)
  17
  18 dnl Try and find an llvm-config in the build directory. We are only using this
  19 dnl to detect the package level LLVM information (currently just the version),
  20 dnl so we just whatever one we find regardless of build mode.
  21 AC_MSG_CHECKING([llvm-config])
  22 llvm_config_path="`ls -1 $llvm_obj/*/bin/llvm-config 2> /dev/null | head -1`"
  23 if ! test -f "$llvm_config_path" ; then
  24    llvm_config_path="no"
  25 fi
  26 AC_MSG_RESULT([$llvm_config_path])
  27
  28 dnl Determine the LLVM version, which may be required by the current Makefile
  29 dnl rules.
  30 AC_MSG_CHECKING([LLVM package version])
  31 if test "$llvm_config_path" != no ; then
  32   llvm_package_version=`$llvm_config_path --version`
  33 else
  34   llvm_package_version="unknown";
  35 fi
  36 AC_MSG_RESULT([$llvm_package_version])
  37 AC_SUBST(LLVM_VERSION, [$llvm_package_version])
  38
  39 dnl Verify that the source directory is valid
  40 AC_CONFIG_SRCDIR(["Makefile.common.in"])
  41
  42 dnl Place all of the extra autoconf files into the config subdirectory. Tell
  43 dnl various tools where the m4 autoconf macros are.
  44 AC_CONFIG_AUX_DIR([autoconf])
  45
  46 dnl **************************************************************************
  47 dnl Begin LLVM configure.ac Import
  48 dnl **************************************************************************
  49 dnl
  50 dnl Derived from LLVM's configure.ac. This was imported directly here so that we
  51 dnl could reuse LLVM's build infrastructure without introducing a direct source
  52 dnl dependency on the LLVM files.
  53
  54 dnl We need to check for the compiler up here to avoid anything else
  55 dnl starting with a different one.
  56 AC_PROG_CC(clang llvm-gcc gcc)
  57 AC_PROG_CXX(clang++ llvm-g++ g++)
  58 AC_PROG_CPP
  59
  60 dnl Configure all of the projects present in our source tree. While we could
  61 dnl just AC_CONFIG_SUBDIRS on the set of directories in projects that have a
  62 dnl configure script, that usage of the AC_CONFIG_SUBDIRS macro is deprecated.
  63 dnl Instead we match on the known projects.
  64
  65 dnl
  66 dnl One tricky part of doing this is that some projects depend upon other
  67 dnl projects.  For example, several projects rely upon the LLVM test suite.
  68 dnl We want to configure those projects first so that their object trees are
  69 dnl created before running the configure scripts of projects that depend upon
  70 dnl them.
  71 dnl
  72
  73 dnl Disable the build of polly, even if it is checked out into tools/polly.
  74 AC_ARG_ENABLE(polly,
  75               AS_HELP_STRING([--enable-polly],
  76                              [Use polly if available (default is YES)]),,
  77                              enableval=default)
  78 case "$enableval" in
  79   yes) AC_SUBST(ENABLE_POLLY,[1]) ;;
  80   no)  AC_SUBST(ENABLE_POLLY,[0]) ;;
  81   default) AC_SUBST(ENABLE_POLLY,[1]) ;;
  82   *) AC_MSG_ERROR([Invalid setting for --enable-polly. Use "yes" or "no"]) ;;
  83 esac
  84
  85
  86 dnl Check if polly is checked out into tools/polly and configure it if
  87 dnl available.
  88 if (test -d ${srcdir}/tools/polly) && (test $ENABLE_POLLY -eq 1) ; then
  89   AC_SUBST(LLVM_HAS_POLLY,1)
  90   AC_CONFIG_SUBDIRS([tools/polly])
  91 fi
  92
  93 dnl===-----------------------------------------------------------------------===
  94 dnl===
  95 dnl=== SECTION 2: Architecture, target, and host checks
  96 dnl===
  97 dnl===-----------------------------------------------------------------------===
  98
  99 dnl Check the target for which we're compiling and the host that will do the
 100 dnl compilations. This will tell us which LLVM compiler will be used for
 101 dnl compiling SSA into object code. This needs to be done early because
 102 dnl following tests depend on it.
 103 AC_CANONICAL_TARGET
 104
 105 dnl Determine the platform type and cache its value. This helps us configure
 106 dnl the System library to the correct build platform.
 107 AC_CACHE_CHECK([type of operating system we're going to host on],
 108                [llvm_cv_os_type],
 109 [case $host in
 110   *-*-aix*)
 111     llvm_cv_link_all_option="-Wl,--whole-archive"
 112     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 113     llvm_cv_os_type="AIX"
 114     llvm_cv_platform_type="Unix" ;;
 115   *-*-irix*)
 116     llvm_cv_link_all_option="-Wl,--whole-archive"
 117     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 118     llvm_cv_os_type="IRIX"
 119     llvm_cv_platform_type="Unix" ;;
 120   *-*-cygwin*)
 121     llvm_cv_link_all_option="-Wl,--whole-archive"
 122     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 123     llvm_cv_os_type="Cygwin"
 124     llvm_cv_platform_type="Unix" ;;
 125   *-*-darwin*)
 126     llvm_cv_link_all_option="-Wl,-all_load"
 127     llvm_cv_no_link_all_option="-Wl,-noall_load"
 128     llvm_cv_os_type="Darwin"
 129     llvm_cv_platform_type="Unix" ;;
 130   *-*-minix*)
 131     llvm_cv_link_all_option="-Wl,-all_load"
 132     llvm_cv_no_link_all_option="-Wl,-noall_load"
 133     llvm_cv_os_type="Minix"
 134     llvm_cv_platform_type="Unix" ;;
 135   *-*-freebsd* | *-*-kfreebsd-gnu)
 136     llvm_cv_link_all_option="-Wl,--whole-archive"
 137     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 138     llvm_cv_os_type="FreeBSD"
 139     llvm_cv_platform_type="Unix" ;;
 140   *-*-openbsd*)
 141     llvm_cv_link_all_option="-Wl,--whole-archive"
 142     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 143     llvm_cv_os_type="OpenBSD"
 144     llvm_cv_platform_type="Unix" ;;
 145   *-*-netbsd*)
 146     llvm_cv_link_all_option="-Wl,--whole-archive"
 147     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 148     llvm_cv_os_type="NetBSD"
 149     llvm_cv_platform_type="Unix" ;;
 150   *-*-dragonfly*)
 151     llvm_cv_link_all_option="-Wl,--whole-archive"
 152     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 153     llvm_cv_os_type="DragonFly"
 154     llvm_cv_platform_type="Unix" ;;
 155   *-*-hpux*)
 156     llvm_cv_link_all_option="-Wl,--whole-archive"
 157     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 158     llvm_cv_os_type="HP-UX"
 159     llvm_cv_platform_type="Unix" ;;
 160   *-*-interix*)
 161     llvm_cv_link_all_option="-Wl,--whole-archive"
 162     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 163     llvm_cv_os_type="Interix"
 164     llvm_cv_platform_type="Unix" ;;
 165   *-*-linux*)
 166     llvm_cv_link_all_option="-Wl,--whole-archive"
 167     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 168     llvm_cv_os_type="Linux"
 169     llvm_cv_platform_type="Unix" ;;
 170   *-*-gnu*)
 171     llvm_cv_link_all_option="-Wl,--whole-archive"
 172     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 173     llvm_cv_os_type="GNU"
 174     llvm_cv_platform_type="Unix" ;;
 175   *-*-solaris*)
 176     llvm_cv_link_all_option="-Wl,-z,allextract"
 177     llvm_cv_no_link_all_option="-Wl,-z,defaultextract"
 178     llvm_cv_os_type="SunOS"
 179     llvm_cv_platform_type="Unix" ;;
 180   *-*-auroraux*)
 181     llvm_cv_link_all_option="-Wl,-z,allextract"
 182     llvm_cv_link_all_option="-Wl,-z,defaultextract"
 183     llvm_cv_os_type="AuroraUX"
 184     llvm_cv_platform_type="Unix" ;;
 185   *-*-win32*)
 186     llvm_cv_link_all_option="-Wl,--whole-archive"
 187     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 188     llvm_cv_os_type="Win32"
 189     llvm_cv_platform_type="Win32" ;;
 190   *-*-mingw*)
 191     llvm_cv_link_all_option="-Wl,--whole-archive"
 192     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 193     llvm_cv_os_type="MingW"
 194     llvm_cv_platform_type="Win32" ;;
 195   *-*-haiku*)
 196     llvm_cv_link_all_option="-Wl,--whole-archive"
 197     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 198     llvm_cv_os_type="Haiku"
 199     llvm_cv_platform_type="Unix" ;;
 200   *-unknown-eabi*)
 201     llvm_cv_link_all_option="-Wl,--whole-archive"
 202     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 203     llvm_cv_os_type="Freestanding"
 204     llvm_cv_platform_type="Unix" ;;
 205   *-unknown-elf*)
 206     llvm_cv_link_all_option="-Wl,--whole-archive"
 207     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 208     llvm_cv_os_type="Freestanding"
 209     llvm_cv_platform_type="Unix" ;;
 210   *)
 211     llvm_cv_link_all_option=""
 212     llvm_cv_no_link_all_option=""
 213     llvm_cv_os_type="Unknown"
 214     llvm_cv_platform_type="Unknown" ;;
 215 esac])
 216
 217 AC_CACHE_CHECK([type of operating system we're going to target],
 218                [llvm_cv_target_os_type],
 219 [case $target in
 220   *-*-aix*)
 221     llvm_cv_target_os_type="AIX" ;;
 222   *-*-irix*)
 223     llvm_cv_target_os_type="IRIX" ;;
 224   *-*-cygwin*)
 225     llvm_cv_target_os_type="Cygwin" ;;
 226   *-*-darwin*)
 227     llvm_cv_target_os_type="Darwin" ;;
 228   *-*-minix*)
 229     llvm_cv_target_os_type="Minix" ;;
 230   *-*-freebsd* | *-*-kfreebsd-gnu)
 231     llvm_cv_target_os_type="FreeBSD" ;;
 232   *-*-openbsd*)
 233     llvm_cv_target_os_type="OpenBSD" ;;
 234   *-*-netbsd*)
 235     llvm_cv_target_os_type="NetBSD" ;;
 236   *-*-dragonfly*)
 237     llvm_cv_target_os_type="DragonFly" ;;
 238   *-*-hpux*)
 239     llvm_cv_target_os_type="HP-UX" ;;
 240   *-*-interix*)
 241     llvm_cv_target_os_type="Interix" ;;
 242   *-*-linux*)
 243     llvm_cv_target_os_type="Linux" ;;
 244   *-*-gnu*)
 245     llvm_cv_target_os_type="GNU" ;;
 246   *-*-solaris*)
 247     llvm_cv_target_os_type="SunOS" ;;
 248   *-*-auroraux*)
 249     llvm_cv_target_os_type="AuroraUX" ;;
 250   *-*-win32*)
 251     llvm_cv_target_os_type="Win32" ;;
 252   *-*-mingw*)
 253     llvm_cv_target_os_type="MingW" ;;
 254   *-*-haiku*)
 255     llvm_cv_target_os_type="Haiku" ;;
 256   *-*-rtems*)
 257     llvm_cv_target_os_type="RTEMS" ;;
 258   *-*-nacl*)
 259     llvm_cv_target_os_type="NativeClient" ;;
 260   *-unknown-eabi*)
 261     llvm_cv_target_os_type="Freestanding" ;;
 262   *)
 263     llvm_cv_target_os_type="Unknown" ;;
 264 esac])
 265
 266 dnl Make sure we aren't attempting to configure for an unknown system
 267 if test "$llvm_cv_os_type" = "Unknown" ; then
 268   AC_MSG_ERROR([Operating system is unknown, configure can't continue])
 269 fi
 270
 271 dnl Set the "OS" Makefile variable based on the platform type so the
 272 dnl makefile can configure itself to specific build hosts
 273 AC_SUBST(OS,$llvm_cv_os_type)
 274 AC_SUBST(HOST_OS,$llvm_cv_os_type)
 275 AC_SUBST(TARGET_OS,$llvm_cv_target_os_type)
 276
 277 dnl Set the LINKALL and NOLINKALL Makefile variables based on the platform
 278 AC_SUBST(LINKALL,$llvm_cv_link_all_option)
 279 AC_SUBST(NOLINKALL,$llvm_cv_no_link_all_option)
 280
 281 dnl Set the "LLVM_ON_*" variables based on llvm_cv_platform_type
 282 dnl This is used by lib/Support to determine the basic kind of implementation
 283 dnl to use.
 284 case $llvm_cv_platform_type in
 285   Unix)
 286     AC_DEFINE([LLVM_ON_UNIX],[1],[Define if this is Unixish platform])
 287     AC_SUBST(LLVM_ON_UNIX,[1])
 288     AC_SUBST(LLVM_ON_WIN32,[0])
 289     ;;
 290   Win32)
 291     AC_DEFINE([LLVM_ON_WIN32],[1],[Define if this is Win32ish platform])
 292     AC_SUBST(LLVM_ON_UNIX,[0])
 293     AC_SUBST(LLVM_ON_WIN32,[1])
 294     ;;
 295 esac
 296
 297 dnl Determine what our target architecture is and configure accordingly.
 298 dnl This will allow Makefiles to make a distinction between the hardware and
 299 dnl the OS.
 300 AC_CACHE_CHECK([target architecture],[llvm_cv_target_arch],
 301 [case $target in
 302   i?86-*)                 llvm_cv_target_arch="x86" ;;
 303   amd64-* | x86_64-*)     llvm_cv_target_arch="x86_64" ;;
 304   sparc*-*)               llvm_cv_target_arch="Sparc" ;;
 305   powerpc*-*)             llvm_cv_target_arch="PowerPC" ;;
 306   arm*-*)                 llvm_cv_target_arch="ARM" ;;
 307   aarch64*-*)             llvm_cv_target_arch="AArch64" ;;
 308   mips-* | mips64-*)      llvm_cv_target_arch="Mips" ;;
 309   mipsel-* | mips64el-*)  llvm_cv_target_arch="Mips" ;;
 310   xcore-*)                llvm_cv_target_arch="XCore" ;;
 311   msp430-*)               llvm_cv_target_arch="MSP430" ;;
 312   hexagon-*)              llvm_cv_target_arch="Hexagon" ;;
 313   nvptx-*)                llvm_cv_target_arch="NVPTX" ;;
 314   s390x-*)                llvm_cv_target_arch="SystemZ" ;;
 315   *)                      llvm_cv_target_arch="Unknown" ;;
 316 esac])
 317
 318 if test "$llvm_cv_target_arch" = "Unknown" ; then
 319   AC_MSG_WARN([Configuring LLVM for an unknown target archicture])
 320 fi
 321
 322 # Determine the LLVM native architecture for the target
 323 case "$llvm_cv_target_arch" in
 324     x86)     LLVM_NATIVE_ARCH="X86" ;;
 325     x86_64)  LLVM_NATIVE_ARCH="X86" ;;
 326     *)       LLVM_NATIVE_ARCH="$llvm_cv_target_arch" ;;
 327 esac
 328
 329 dnl Define a substitution, ARCH, for the target architecture
 330 AC_SUBST(ARCH,$llvm_cv_target_arch)
 331
 332 dnl Check for the endianness of the target
 333 AC_C_BIGENDIAN(AC_SUBST([ENDIAN],[big]),AC_SUBST([ENDIAN],[little]))
 334
 335 dnl Check for build platform executable suffix if we're crosscompiling
 336 if test "$cross_compiling" = yes; then
 337   AC_SUBST(LLVM_CROSS_COMPILING, [1])
 338   AC_BUILD_EXEEXT
 339   ac_build_prefix=${build_alias}-
 340   AC_CHECK_PROG(BUILD_CXX, ${ac_build_prefix}g++, ${ac_build_prefix}g++)
 341   if test -z "$BUILD_CXX"; then
 342      AC_CHECK_PROG(BUILD_CXX, g++, g++)
 343      if test -z "$BUILD_CXX"; then
 344        AC_CHECK_PROG(BUILD_CXX, c++, c++, , , /usr/ucb/c++)
 345      fi
 346   fi
 347 else
 348   AC_SUBST(LLVM_CROSS_COMPILING, [0])
 349 fi
 350
 351 dnl Check to see if there's a .svn or .git directory indicating that this
 352 dnl build is being done from a checkout. This sets up several defaults for
 353 dnl the command line switches. When we build with a checkout directory,
 354 dnl we get a debug with assertions turned on. Without, we assume a source
 355 dnl release and we get an optimized build without assertions.
 356 dnl See --enable-optimized and --enable-assertions below
 357 if test -d ".svn" -o -d "${srcdir}/.svn" -o -d ".git" -o -d "${srcdir}/.git"; then
 358   cvsbuild="yes"
 359   optimize="no"
 360   AC_SUBST(CVSBUILD,[[CVSBUILD=1]])
 361 else
 362   cvsbuild="no"
 363   optimize="yes"
 364 fi
 365
 366 dnl===-----------------------------------------------------------------------===
 367 dnl===
 368 dnl=== SECTION 3: Command line arguments for the configure script.
 369 dnl===
 370 dnl===-----------------------------------------------------------------------===
 371
 372 dnl --enable-libcpp : check whether or not to use libc++ on the command line
 373 AC_ARG_ENABLE(libcpp,
 374               AS_HELP_STRING([--enable-libcpp],
 375                              [Use libc++ if available (default is NO)]),,
 376                              enableval=default)
 377 case "$enableval" in
 378   yes) AC_SUBST(ENABLE_LIBCPP,[1]) ;;
 379   no)  AC_SUBST(ENABLE_LIBCPP,[0]) ;;
 380   default) AC_SUBST(ENABLE_LIBCPP,[0]);;
 381   *) AC_MSG_ERROR([Invalid setting for --enable-libcpp. Use "yes" or "no"]) ;;
 382 esac
 383
 384 dnl --enable-cxx11 : check whether or not to use -std=c++11 on the command line
 385 AC_ARG_ENABLE(cxx11,
 386               AS_HELP_STRING([--enable-cxx11],
 387                              [Use c++11 if available (default is NO)]),,
 388                              enableval=default)
 389 case "$enableval" in
 390   yes) AC_SUBST(ENABLE_CXX11,[1]) ;;
 391   no)  AC_SUBST(ENABLE_CXX11,[0]) ;;
 392   default) AC_SUBST(ENABLE_CXX11,[0]);;
 393   *) AC_MSG_ERROR([Invalid setting for --enable-cxx11. Use "yes" or "no"]) ;;
 394 esac
 395
 396 dnl --enable-optimized : check whether they want to do an optimized build:
 397 AC_ARG_ENABLE(optimized, AS_HELP_STRING(
 398  --enable-optimized,[Compile with optimizations enabled (default is NO)]),,enableval=$optimize)
 399 if test ${enableval} = "no" ; then
 400   AC_SUBST(ENABLE_OPTIMIZED,[[]])
 401 else
 402   AC_SUBST(ENABLE_OPTIMIZED,[[ENABLE_OPTIMIZED=1]])
 403 fi
 404
 405 dnl --enable-profiling : check whether they want to do a profile build:
 406 AC_ARG_ENABLE(profiling, AS_HELP_STRING(
 407  --enable-profiling,[Compile with profiling enabled (default is NO)]),,enableval="no")
 408 if test ${enableval} = "no" ; then
 409   AC_SUBST(ENABLE_PROFILING,[[]])
 410 else
 411   AC_SUBST(ENABLE_PROFILING,[[ENABLE_PROFILING=1]])
 412 fi
 413
 414 dnl --enable-assertions : check whether they want to turn on assertions or not:
 415 AC_ARG_ENABLE(assertions,AS_HELP_STRING(
 416   --enable-assertions,[Compile with assertion checks enabled (default is YES)]),, enableval="yes")
 417 if test ${enableval} = "yes" ; then
 418   AC_SUBST(DISABLE_ASSERTIONS,[[]])
 419 else
 420   AC_SUBST(DISABLE_ASSERTIONS,[[DISABLE_ASSERTIONS=1]])
 421 fi
 422
 423 dnl --enable-werror : check whether we want Werror on by default
 424 AC_ARG_ENABLE(werror,AS_HELP_STRING(
 425   --enable-werror,[Compile with -Werror enabled (default is NO)]),, enableval="no")
 426 case "$enableval" in
 427   yes) AC_SUBST(ENABLE_WERROR,[1]) ;;
 428   no)  AC_SUBST(ENABLE_WERROR,[0]) ;;
 429   default) AC_SUBST(ENABLE_WERROR,[0]);;
 430   *) AC_MSG_ERROR([Invalid setting for --enable-werror. Use "yes" or "no"]) ;;
 431 esac
 432
 433 dnl --enable-expensive-checks : check whether they want to turn on expensive debug checks:
 434 AC_ARG_ENABLE(expensive-checks,AS_HELP_STRING(
 435   --enable-expensive-checks,[Compile with expensive debug checks enabled (default is NO)]),, enableval="no")
 436 if test ${enableval} = "yes" ; then
 437   AC_SUBST(ENABLE_EXPENSIVE_CHECKS,[[ENABLE_EXPENSIVE_CHECKS=1]])
 438   AC_SUBST(EXPENSIVE_CHECKS,[[yes]])
 439 else
 440   AC_SUBST(ENABLE_EXPENSIVE_CHECKS,[[]])
 441   AC_SUBST(EXPENSIVE_CHECKS,[[no]])
 442 fi
 443
 444 dnl --enable-debug-runtime : should runtime libraries have debug symbols?
 445 AC_ARG_ENABLE(debug-runtime,
 446    AS_HELP_STRING(--enable-debug-runtime,[Build runtime libs with debug symbols (default is NO)]),,enableval=no)
 447 if test ${enableval} = "no" ; then
 448   AC_SUBST(DEBUG_RUNTIME,[[]])
 449 else
 450   AC_SUBST(DEBUG_RUNTIME,[[DEBUG_RUNTIME=1]])
 451 fi
 452
 453 dnl --enable-debug-symbols : should even optimized compiler libraries
 454 dnl have debug symbols?
 455 AC_ARG_ENABLE(debug-symbols,
 456    AS_HELP_STRING(--enable-debug-symbols,[Build compiler with debug symbols (default is NO if optimization is on and YES if it's off)]),,enableval=no)
 457 if test ${enableval} = "no" ; then
 458   AC_SUBST(DEBUG_SYMBOLS,[[]])
 459 else
 460   AC_SUBST(DEBUG_SYMBOLS,[[DEBUG_SYMBOLS=1]])
 461 fi
 462
 463 dnl --enable-jit: check whether they want to enable the jit
 464 AC_ARG_ENABLE(jit,
 465   AS_HELP_STRING(--enable-jit,
 466                  [Enable Just In Time Compiling (default is YES)]),,
 467   enableval=default)
 468 if test ${enableval} = "no"
 469 then
 470   AC_SUBST(JIT,[[]])
 471 else
 472   case "$llvm_cv_target_arch" in
 473     x86)         AC_SUBST(TARGET_HAS_JIT,1) ;;
 474     Sparc)       AC_SUBST(TARGET_HAS_JIT,0) ;;
 475     PowerPC)     AC_SUBST(TARGET_HAS_JIT,1) ;;
 476     x86_64)      AC_SUBST(TARGET_HAS_JIT,1) ;;
 477     ARM)         AC_SUBST(TARGET_HAS_JIT,1) ;;
 478     AArch64)     AC_SUBST(TARGET_HAS_JIT,0) ;;
 479     Mips)        AC_SUBST(TARGET_HAS_JIT,1) ;;
 480     XCore)       AC_SUBST(TARGET_HAS_JIT,0) ;;
 481     MSP430)      AC_SUBST(TARGET_HAS_JIT,0) ;;
 482     Hexagon)     AC_SUBST(TARGET_HAS_JIT,0) ;;
 483     NVPTX)       AC_SUBST(TARGET_HAS_JIT,0) ;;
 484     SystemZ)     AC_SUBST(TARGET_HAS_JIT,1) ;;
 485     *)           AC_SUBST(TARGET_HAS_JIT,0) ;;
 486   esac
 487 fi
 488
 489 dnl Allow enablement of building and installing docs
 490 AC_ARG_ENABLE(docs,
 491               AS_HELP_STRING([--enable-docs],
 492                              [Build documents (default is YES)]),,
 493                              enableval=default)
 494 case "$enableval" in
 495   yes) AC_SUBST(ENABLE_DOCS,[1]) ;;
 496   no)  AC_SUBST(ENABLE_DOCS,[0]) ;;
 497   default) AC_SUBST(ENABLE_DOCS,[1]) ;;
 498   *) AC_MSG_ERROR([Invalid setting for --enable-docs. Use "yes" or "no"]) ;;
 499 esac
 500
 501 dnl Allow enablement of doxygen generated documentation
 502 AC_ARG_ENABLE(doxygen,
 503               AS_HELP_STRING([--enable-doxygen],
 504                              [Build doxygen documentation (default is NO)]),,
 505                              enableval=default)
 506 case "$enableval" in
 507   yes) AC_SUBST(ENABLE_DOXYGEN,[1]) ;;
 508   no)  AC_SUBST(ENABLE_DOXYGEN,[0]) ;;
 509   default) AC_SUBST(ENABLE_DOXYGEN,[0]) ;;
 510   *) AC_MSG_ERROR([Invalid setting for --enable-doxygen. Use "yes" or "no"]) ;;
 511 esac
 512
 513 dnl Allow disablement of threads
 514 AC_ARG_ENABLE(threads,
 515               AS_HELP_STRING([--enable-threads],
 516                              [Use threads if available (default is YES)]),,
 517                              enableval=default)
 518 case "$enableval" in
 519   yes) AC_SUBST(ENABLE_THREADS,[1]) ;;
 520   no)  AC_SUBST(ENABLE_THREADS,[0]) ;;
 521   default) AC_SUBST(ENABLE_THREADS,[1]) ;;
 522   *) AC_MSG_ERROR([Invalid setting for --enable-threads. Use "yes" or "no"]) ;;
 523 esac
 524 AC_DEFINE_UNQUOTED([ENABLE_THREADS],$ENABLE_THREADS,[Define if threads enabled])
 525
 526 dnl Allow disablement of pthread.h
 527 AC_ARG_ENABLE(pthreads,
 528               AS_HELP_STRING([--enable-pthreads],
 529                              [Use pthreads if available (default is YES)]),,
 530                              enableval=default)
 531 case "$enableval" in
 532   yes) AC_SUBST(ENABLE_PTHREADS,[1]) ;;
 533   no)  AC_SUBST(ENABLE_PTHREADS,[0]) ;;
 534   default) AC_SUBST(ENABLE_PTHREADS,[1]) ;;
 535   *) AC_MSG_ERROR([Invalid setting for --enable-pthreads. Use "yes" or "no"]) ;;
 536 esac
 537
 538 dnl Allow disablement of zlib
 539 AC_ARG_ENABLE(zlib,
 540               AS_HELP_STRING([--enable-zlib],
 541                              [Use zlib for compression/decompression if
 542                               available (default is YES)]),,
 543                               enableval=default)
 544 case "$enableval" in
 545   yes) AC_SUBST(LLVM_ENABLE_ZLIB,[1]) ;;
 546   no)  AC_SUBST(LLVM_ENABLE_ZLIB,[0]) ;;
 547   default) AC_SUBST(LLVM_ENABLE_ZLIB,[1]) ;;
 548   *) AC_MSG_ERROR([Invalid setting for --enable-zlib. Use "yes" or "no"]) ;;
 549 esac
 550 AC_DEFINE_UNQUOTED([LLVM_ENABLE_ZLIB],$LLVM_ENABLE_ZLIB,
 551                    [Define if zlib is enabled])
 552
 553 dnl Allow building without position independent code
 554 AC_ARG_ENABLE(pic,
 555   AS_HELP_STRING([--enable-pic],
 556                  [Build LLVM with Position Independent Code (default is YES)]),,
 557                  enableval=default)
 558 case "$enableval" in
 559   yes) AC_SUBST(ENABLE_PIC,[1]) ;;
 560   no)  AC_SUBST(ENABLE_PIC,[0]) ;;
 561   default) AC_SUBST(ENABLE_PIC,[1]) ;;
 562   *) AC_MSG_ERROR([Invalid setting for --enable-pic. Use "yes" or "no"]) ;;
 563 esac
 564 AC_DEFINE_UNQUOTED([ENABLE_PIC],$ENABLE_PIC,
 565                    [Define if position independent code is enabled])
 566
 567 dnl Allow building a shared library and linking tools against it.
 568 AC_ARG_ENABLE(shared,
 569   AS_HELP_STRING([--enable-shared],
 570                  [Build a shared library and link tools against it (default is NO)]),,
 571                  enableval=default)
 572 case "$enableval" in
 573   yes) AC_SUBST(ENABLE_SHARED,[1]) ;;
 574   no)  AC_SUBST(ENABLE_SHARED,[0]) ;;
 575   default) AC_SUBST(ENABLE_SHARED,[0]) ;;
 576   *) AC_MSG_ERROR([Invalid setting for --enable-shared. Use "yes" or "no"]) ;;
 577 esac
 578
 579 dnl Allow libstdc++ is embedded in LLVM.dll.
 580 AC_ARG_ENABLE(embed-stdcxx,
 581   AS_HELP_STRING([--enable-embed-stdcxx],
 582                  [Build a shared library with embedded libstdc++ for Win32 DLL (default is YES)]),,
 583                  enableval=default)
 584 case "$enableval" in
 585   yes) AC_SUBST(ENABLE_EMBED_STDCXX,[1]) ;;
 586   no)  AC_SUBST(ENABLE_EMBED_STDCXX,[0]) ;;
 587   default) AC_SUBST(ENABLE_EMBED_STDCXX,[1]) ;;
 588   *) AC_MSG_ERROR([Invalid setting for --enable-embed-stdcxx. Use "yes" or "no"]) ;;
 589 esac
 590
 591 dnl Enable embedding timestamp information into build.
 592 AC_ARG_ENABLE(timestamps,
 593   AS_HELP_STRING([--enable-timestamps],
 594                  [Enable embedding timestamp information in build (default is YES)]),,
 595                  enableval=default)
 596 case "$enableval" in
 597   yes) AC_SUBST(ENABLE_TIMESTAMPS,[1]) ;;
 598   no)  AC_SUBST(ENABLE_TIMESTAMPS,[0]) ;;
 599   default) AC_SUBST(ENABLE_TIMESTAMPS,[1]) ;;
 600   *) AC_MSG_ERROR([Invalid setting for --enable-timestamps. Use "yes" or "no"]) ;;
 601 esac
 602 AC_DEFINE_UNQUOTED([ENABLE_TIMESTAMPS],$ENABLE_TIMESTAMPS,
 603                    [Define if timestamp information (e.g., __DATE___) is allowed])
 604
 605 dnl Allow specific targets to be specified for building (or not)
 606 TARGETS_TO_BUILD=""
 607 AC_ARG_ENABLE([targets],AS_HELP_STRING([--enable-targets],
 608     [Build specific host targets: all or target1,target2,... Valid targets are:
 609      host, x86, x86_64, sparc, powerpc, arm, aarch64, mips, hexagon,
 610      xcore, msp430, nvptx, systemz, r600, and cpp (default=all)]),,
 611     enableval=all)
 612 if test "$enableval" = host-only ; then
 613   enableval=host
 614 fi
 615 case "$enableval" in
 616   all) TARGETS_TO_BUILD="X86 Sparc PowerPC AArch64 ARM Mips XCore MSP430 CppBackend NVPTX Hexagon SystemZ R600" ;;
 617   *)for a_target in `echo $enableval|sed -e 's/,/ /g' ` ; do
 618       case "$a_target" in
 619         x86)      TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 620         x86_64)   TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 621         sparc)    TARGETS_TO_BUILD="Sparc $TARGETS_TO_BUILD" ;;
 622         powerpc)  TARGETS_TO_BUILD="PowerPC $TARGETS_TO_BUILD" ;;
 623         aarch64)  TARGETS_TO_BUILD="AArch64 $TARGETS_TO_BUILD" ;;
 624         arm)      TARGETS_TO_BUILD="ARM $TARGETS_TO_BUILD" ;;
 625         mips)     TARGETS_TO_BUILD="Mips $TARGETS_TO_BUILD" ;;
 626         mipsel)   TARGETS_TO_BUILD="Mips $TARGETS_TO_BUILD" ;;
 627         mips64)   TARGETS_TO_BUILD="Mips $TARGETS_TO_BUILD" ;;
 628         mips64el) TARGETS_TO_BUILD="Mips $TARGETS_TO_BUILD" ;;
 629         xcore)    TARGETS_TO_BUILD="XCore $TARGETS_TO_BUILD" ;;
 630         msp430)   TARGETS_TO_BUILD="MSP430 $TARGETS_TO_BUILD" ;;
 631         cpp)      TARGETS_TO_BUILD="CppBackend $TARGETS_TO_BUILD" ;;
 632         hexagon)  TARGETS_TO_BUILD="Hexagon $TARGETS_TO_BUILD" ;;
 633         nvptx)    TARGETS_TO_BUILD="NVPTX $TARGETS_TO_BUILD" ;;
 634         systemz)  TARGETS_TO_BUILD="SystemZ $TARGETS_TO_BUILD" ;;
 635         r600)     TARGETS_TO_BUILD="R600 $TARGETS_TO_BUILD" ;;
 636         host) case "$llvm_cv_target_arch" in
 637             x86)         TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 638             x86_64)      TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 639             Sparc)       TARGETS_TO_BUILD="Sparc $TARGETS_TO_BUILD" ;;
 640             PowerPC)     TARGETS_TO_BUILD="PowerPC $TARGETS_TO_BUILD" ;;
 641             AArch64)     TARGETS_TO_BUILD="AArch64 $TARGETS_TO_BUILD" ;;
 642             ARM)         TARGETS_TO_BUILD="ARM $TARGETS_TO_BUILD" ;;
 643             Mips)        TARGETS_TO_BUILD="Mips $TARGETS_TO_BUILD" ;;
 644             XCore)       TARGETS_TO_BUILD="XCore $TARGETS_TO_BUILD" ;;
 645             MSP430)      TARGETS_TO_BUILD="MSP430 $TARGETS_TO_BUILD" ;;
 646             Hexagon)     TARGETS_TO_BUILD="Hexagon $TARGETS_TO_BUILD" ;;
 647             NVPTX)       TARGETS_TO_BUILD="NVPTX $TARGETS_TO_BUILD" ;;
 648             SystemZ)     TARGETS_TO_BUILD="SystemZ $TARGETS_TO_BUILD" ;;
 649             *)       AC_MSG_ERROR([Can not set target to build]) ;;
 650           esac ;;
 651         *) AC_MSG_ERROR([Unrecognized target $a_target]) ;;
 652       esac
 653   done
 654   ;;
 655 esac
 656 AC_SUBST(TARGETS_TO_BUILD,$TARGETS_TO_BUILD)
 657
 658 # Determine whether we are building LLVM support for the native architecture.
 659 # If so, define LLVM_NATIVE_ARCH to that LLVM target.
 660 for a_target in $TARGETS_TO_BUILD; do
 661   if test "$a_target" = "$LLVM_NATIVE_ARCH"; then
 662     AC_DEFINE_UNQUOTED(LLVM_NATIVE_ARCH, $LLVM_NATIVE_ARCH,
 663       [LLVM architecture name for the native architecture, if available])
 664     LLVM_NATIVE_TARGET="LLVMInitialize${LLVM_NATIVE_ARCH}Target"
 665     LLVM_NATIVE_TARGETINFO="LLVMInitialize${LLVM_NATIVE_ARCH}TargetInfo"
 666     LLVM_NATIVE_TARGETMC="LLVMInitialize${LLVM_NATIVE_ARCH}TargetMC"
 667     LLVM_NATIVE_ASMPRINTER="LLVMInitialize${LLVM_NATIVE_ARCH}AsmPrinter"
 668     if test -f ${srcdir}/lib/Target/${LLVM_NATIVE_ARCH}/AsmParser/Makefile ; then
 669       LLVM_NATIVE_ASMPARSER="LLVMInitialize${LLVM_NATIVE_ARCH}AsmParser"
 670     fi
 671     if test -f ${srcdir}/lib/Target/${LLVM_NATIVE_ARCH}/Disassembler/Makefile ; then
 672       LLVM_NATIVE_DISASSEMBLER="LLVMInitialize${LLVM_NATIVE_ARCH}Disassembler"
 673     fi
 674     AC_DEFINE_UNQUOTED(LLVM_NATIVE_TARGET, $LLVM_NATIVE_TARGET,
 675       [LLVM name for the native Target init function, if available])
 676     AC_DEFINE_UNQUOTED(LLVM_NATIVE_TARGETINFO, $LLVM_NATIVE_TARGETINFO,
 677       [LLVM name for the native TargetInfo init function, if available])
 678     AC_DEFINE_UNQUOTED(LLVM_NATIVE_TARGETMC, $LLVM_NATIVE_TARGETMC,
 679       [LLVM name for the native target MC init function, if available])
 680     AC_DEFINE_UNQUOTED(LLVM_NATIVE_ASMPRINTER, $LLVM_NATIVE_ASMPRINTER,
 681       [LLVM name for the native AsmPrinter init function, if available])
 682     if test -f ${srcdir}/lib/Target/${LLVM_NATIVE_ARCH}/AsmParser/Makefile ; then
 683       AC_DEFINE_UNQUOTED(LLVM_NATIVE_ASMPARSER, $LLVM_NATIVE_ASMPARSER,
 684        [LLVM name for the native AsmParser init function, if available])
 685     fi
 686     if test -f ${srcdir}/lib/Target/${LLVM_NATIVE_ARCH}/Disassembler/Makefile ; then
 687       AC_DEFINE_UNQUOTED(LLVM_NATIVE_DISASSEMBLER, $LLVM_NATIVE_DISASSEMBLER,
 688        [LLVM name for the native Disassembler init function, if available])
 689     fi
 690   fi
 691 done
 692
 693 # Build the LLVM_TARGET and LLVM_... macros for Targets.def and the individual
 694 # target feature def files.
 695 LLVM_ENUM_TARGETS=""
 696 LLVM_ENUM_ASM_PRINTERS=""
 697 LLVM_ENUM_ASM_PARSERS=""
 698 LLVM_ENUM_DISASSEMBLERS=""
 699 for target_to_build in $TARGETS_TO_BUILD; do
 700   LLVM_ENUM_TARGETS="LLVM_TARGET($target_to_build) $LLVM_ENUM_TARGETS"
 701   if test -f ${srcdir}/lib/Target/${target_to_build}/*AsmPrinter.cpp ; then
 702     LLVM_ENUM_ASM_PRINTERS="LLVM_ASM_PRINTER($target_to_build) $LLVM_ENUM_ASM_PRINTERS";
 703   fi
 704   if test -f ${srcdir}/lib/Target/${target_to_build}/AsmParser/Makefile ; then
 705     LLVM_ENUM_ASM_PARSERS="LLVM_ASM_PARSER($target_to_build) $LLVM_ENUM_ASM_PARSERS";
 706   fi
 707   if test -f ${srcdir}/lib/Target/${target_to_build}/Disassembler/Makefile ; then
 708     LLVM_ENUM_DISASSEMBLERS="LLVM_DISASSEMBLER($target_to_build) $LLVM_ENUM_DISASSEMBLERS";
 709   fi
 710 done
 711 AC_SUBST(LLVM_ENUM_TARGETS)
 712 AC_SUBST(LLVM_ENUM_ASM_PRINTERS)
 713 AC_SUBST(LLVM_ENUM_ASM_PARSERS)
 714 AC_SUBST(LLVM_ENUM_DISASSEMBLERS)
 715
 716 dnl Override the option to use for optimized builds.
 717 AC_ARG_WITH(optimize-option,
 718   AS_HELP_STRING([--with-optimize-option],
 719                  [Select the compiler options to use for optimized builds]),,
 720                  withval=default)
 721 AC_MSG_CHECKING([optimization flags])
 722 case "$withval" in
 723   default)
 724     case "$llvm_cv_os_type" in
 725     FreeBSD) optimize_option=-O2 ;;
 726     MingW) optimize_option=-O2 ;;
 727     *)     optimize_option=-O3 ;;
 728     esac ;;
 729   *) optimize_option="$withval" ;;
 730 esac
 731 AC_SUBST(OPTIMIZE_OPTION,$optimize_option)
 732 AC_MSG_RESULT([$optimize_option])
 733
 734 dnl Specify extra build options
 735 AC_ARG_WITH(extra-options,
 736   AS_HELP_STRING([--with-extra-options],
 737                  [Specify additional options to compile LLVM with]),,
 738                  withval=default)
 739 case "$withval" in
 740   default) EXTRA_OPTIONS= ;;
 741   *) EXTRA_OPTIONS=$withval ;;
 742 esac
 743 AC_SUBST(EXTRA_OPTIONS,$EXTRA_OPTIONS)
 744
 745 dnl Specify extra linker build options
 746 AC_ARG_WITH(extra-ld-options,
 747   AS_HELP_STRING([--with-extra-ld-options],
 748                  [Specify additional options to link LLVM with]),,
 749                  withval=default)
 750 case "$withval" in
 751   default) EXTRA_LD_OPTIONS= ;;
 752   *) EXTRA_LD_OPTIONS=$withval ;;
 753 esac
 754 AC_SUBST(EXTRA_LD_OPTIONS,$EXTRA_LD_OPTIONS)
 755
 756 dnl Allow specific bindings to be specified for building (or not)
 757 AC_ARG_ENABLE([bindings],AS_HELP_STRING([--enable-bindings],
 758     [Build specific language bindings: all,auto,none,{binding-name} (default=auto)]),,
 759     enableval=default)
 760 BINDINGS_TO_BUILD=""
 761 case "$enableval" in
 762   yes | default | auto) BINDINGS_TO_BUILD="auto" ;;
 763   all ) BINDINGS_TO_BUILD="ocaml" ;;
 764   none | no) BINDINGS_TO_BUILD="" ;;
 765   *)for a_binding in `echo $enableval|sed -e 's/,/ /g' ` ; do
 766       case "$a_binding" in
 767         ocaml) BINDINGS_TO_BUILD="ocaml $BINDINGS_TO_BUILD" ;;
 768         *) AC_MSG_ERROR([Unrecognized binding $a_binding]) ;;
 769       esac
 770   done
 771   ;;
 772 esac
 773
 774 dnl Allow the ocaml libdir to be overridden. This could go in a configure
 775 dnl script for bindings/ocaml/configure, except that its auto value depends on
 776 dnl OCAMLC, which is found here to support tests.
 777 AC_ARG_WITH([ocaml-libdir],
 778   [AS_HELP_STRING([--with-ocaml-libdir],
 779     [Specify install location for ocaml bindings (default is stdlib)])],
 780   [],
 781   [withval=auto])
 782 case "$withval" in
 783   auto) with_ocaml_libdir="$withval" ;;
 784   /* | [[A-Za-z]]:[[\\/]]*) with_ocaml_libdir="$withval" ;;
 785   *) AC_MSG_ERROR([Invalid path for --with-ocaml-libdir. Provide full path]) ;;
 786 esac
 787
 788 AC_ARG_WITH(clang-resource-dir,
 789   AS_HELP_STRING([--with-clang-resource-dir],
 790     [Relative directory from the Clang binary for resource files]),,
 791     withval="")
 792 AC_DEFINE_UNQUOTED(CLANG_RESOURCE_DIR,"$withval",
 793                    [Relative directory for resource files])
 794
 795 AC_ARG_WITH(c-include-dirs,
 796   AS_HELP_STRING([--with-c-include-dirs],
 797     [Colon separated list of directories clang will search for headers]),,
 798     withval="")
 799 AC_DEFINE_UNQUOTED(C_INCLUDE_DIRS,"$withval",
 800                    [Directories clang will search for headers])
 801
 802 # Clang normally uses the system c++ headers and libraries. With this option,
 803 # clang will use the ones provided by a gcc installation instead. This option should
 804 # be passed the same value that was used with --prefix when configuring gcc.
 805 AC_ARG_WITH(gcc-toolchain,
 806   AS_HELP_STRING([--with-gcc-toolchain],
 807     [Directory where gcc is installed.]),,
 808     withval="")
 809 AC_DEFINE_UNQUOTED(GCC_INSTALL_PREFIX,"$withval",
 810                    [Directory where gcc is installed.])
 811
 812 dnl Allow linking of LLVM with GPLv3 binutils code.
 813 AC_ARG_WITH(binutils-include,
 814   AS_HELP_STRING([--with-binutils-include],
 815     [Specify path to binutils/include/ containing plugin-api.h file for gold plugin.]),,
 816   withval=default)
 817 case "$withval" in
 818   default) WITH_BINUTILS_INCDIR=default ;;
 819   /* | [[A-Za-z]]:[[\\/]]*)      WITH_BINUTILS_INCDIR=$withval ;;
 820   *) AC_MSG_ERROR([Invalid path for --with-binutils-include. Provide full path]) ;;
 821 esac
 822 if test "x$WITH_BINUTILS_INCDIR" != xdefault ; then
 823   AC_SUBST(BINUTILS_INCDIR,$WITH_BINUTILS_INCDIR)
 824   if test ! -f "$WITH_BINUTILS_INCDIR/plugin-api.h"; then
 825      echo "$WITH_BINUTILS_INCDIR/plugin-api.h"
 826      AC_MSG_ERROR([Invalid path to directory containing plugin-api.h.]);
 827   fi
 828 fi
 829
 830 dnl Specify the URL where bug reports should be submitted.
 831 AC_ARG_WITH(bug-report-url,
 832   AS_HELP_STRING([--with-bug-report-url],
 833     [Specify the URL where bug reports should be submitted (default=http://llvm.org/bugs/)]),,
 834     withval="http://llvm.org/bugs/")
 835 AC_DEFINE_UNQUOTED(BUG_REPORT_URL,"$withval",
 836                    [Bug report URL.])
 837
 838 dnl --enable-terminfo: check whether the user wants to control use of terminfo:
 839 AC_ARG_ENABLE(terminfo,AS_HELP_STRING(
 840   [--enable-terminfo],
 841   [Query the terminfo database if available (default is YES)]),
 842   [case "$enableval" in
 843     yes) llvm_cv_enable_terminfo="yes" ;;
 844     no)  llvm_cv_enable_terminfo="no"  ;;
 845     *) AC_MSG_ERROR([Invalid setting for --enable-terminfo. Use "yes" or "no"]) ;;
 846   esac],
 847   llvm_cv_enable_terminfo="yes")
 848
 849 dnl --enable-libffi : check whether the user wants to turn off libffi:
 850 AC_ARG_ENABLE(libffi,AS_HELP_STRING(
 851   --enable-libffi,[Check for the presence of libffi (default is NO)]),
 852   [case "$enableval" in
 853     yes) llvm_cv_enable_libffi="yes" ;;
 854     no)  llvm_cv_enable_libffi="no"  ;;
 855     *) AC_MSG_ERROR([Invalid setting for --enable-libffi. Use "yes" or "no"]) ;;
 856   esac],
 857   llvm_cv_enable_libffi=no)
 858
 859 dnl===-----------------------------------------------------------------------===
 860 dnl===
 861 dnl=== SECTION 4: Check for programs we need and that they are the right version
 862 dnl===
 863 dnl===-----------------------------------------------------------------------===
 864
 865 AC_PROG_NM
 866 AC_SUBST(NM)
 867
 868 dnl Check for the tools that the makefiles require
 869 AC_CHECK_GNU_MAKE
 870 AC_PROG_LN_S
 871 AC_PATH_PROG(CMP, [cmp], [cmp])
 872 AC_PATH_PROG(CP, [cp], [cp])
 873 AC_PATH_PROG(DATE, [date], [date])
 874 AC_PATH_PROG(FIND, [find], [find])
 875 AC_PATH_PROG(GREP, [grep], [grep])
 876 AC_PATH_PROG(MKDIR,[mkdir],[mkdir])
 877 AC_PATH_PROG(MV,   [mv],   [mv])
 878 AC_PROG_RANLIB
 879 AC_CHECK_TOOL(AR, ar, false)
 880 AC_PATH_PROG(RM,   [rm],   [rm])
 881 AC_PATH_PROG(SED,  [sed],  [sed])
 882 AC_PATH_PROG(TAR,  [tar],  [gtar])
 883 AC_PATH_PROG(BINPWD,[pwd],  [pwd])
 884
 885 dnl Looking for misc. graph plotting software
 886 AC_PATH_PROG(GRAPHVIZ, [Graphviz], [echo Graphviz])
 887 if test "$GRAPHVIZ" != "echo Graphviz" ; then
 888   AC_DEFINE([HAVE_GRAPHVIZ],[1],[Define if the Graphviz program is available])
 889   dnl If we're targeting for mingw we should emit windows paths, not msys
 890   if test "$llvm_cv_os_type" = "MingW" ; then
 891     GRAPHVIZ=`echo $GRAPHVIZ | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 892   fi
 893   AC_DEFINE_UNQUOTED([LLVM_PATH_GRAPHVIZ],"$GRAPHVIZ${EXEEXT}",
 894    [Define to path to Graphviz program if found or 'echo Graphviz' otherwise])
 895 fi
 896 AC_PATH_PROG(DOT, [dot], [echo dot])
 897 if test "$DOT" != "echo dot" ; then
 898   AC_DEFINE([HAVE_DOT],[1],[Define if the dot program is available])
 899   dnl If we're targeting for mingw we should emit windows paths, not msys
 900   if test "$llvm_cv_os_type" = "MingW" ; then
 901     DOT=`echo $DOT | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 902   fi
 903   AC_DEFINE_UNQUOTED([LLVM_PATH_DOT],"$DOT${EXEEXT}",
 904    [Define to path to dot program if found or 'echo dot' otherwise])
 905 fi
 906 AC_PATH_PROG(FDP, [fdp], [echo fdp])
 907 if test "$FDP" != "echo fdp" ; then
 908   AC_DEFINE([HAVE_FDP],[1],[Define if the neat program is available])
 909   dnl If we're targeting for mingw we should emit windows paths, not msys
 910   if test "$llvm_cv_os_type" = "MingW" ; then
 911     FDP=`echo $FDP | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 912   fi
 913   AC_DEFINE_UNQUOTED([LLVM_PATH_FDP],"$FDP${EXEEXT}",
 914    [Define to path to fdp program if found or 'echo fdp' otherwise])
 915 fi
 916 AC_PATH_PROG(NEATO, [neato], [echo neato])
 917 if test "$NEATO" != "echo neato" ; then
 918   AC_DEFINE([HAVE_NEATO],[1],[Define if the neat program is available])
 919   dnl If we're targeting for mingw we should emit windows paths, not msys
 920   if test "$llvm_cv_os_type" = "MingW" ; then
 921     NEATO=`echo $NEATO | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 922   fi
 923   AC_DEFINE_UNQUOTED([LLVM_PATH_NEATO],"$NEATO${EXEEXT}",
 924    [Define to path to neato program if found or 'echo neato' otherwise])
 925 fi
 926 AC_PATH_PROG(TWOPI, [twopi], [echo twopi])
 927 if test "$TWOPI" != "echo twopi" ; then
 928   AC_DEFINE([HAVE_TWOPI],[1],[Define if the neat program is available])
 929   dnl If we're targeting for mingw we should emit windows paths, not msys
 930   if test "$llvm_cv_os_type" = "MingW" ; then
 931     TWOPI=`echo $TWOPI | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 932   fi
 933   AC_DEFINE_UNQUOTED([LLVM_PATH_TWOPI],"$TWOPI${EXEEXT}",
 934    [Define to path to twopi program if found or 'echo twopi' otherwise])
 935 fi
 936 AC_PATH_PROG(CIRCO, [circo], [echo circo])
 937 if test "$CIRCO" != "echo circo" ; then
 938   AC_DEFINE([HAVE_CIRCO],[1],[Define if the neat program is available])
 939   dnl If we're targeting for mingw we should emit windows paths, not msys
 940   if test "$llvm_cv_os_type" = "MingW" ; then
 941     CIRCO=`echo $CIRCO | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 942   fi
 943   AC_DEFINE_UNQUOTED([LLVM_PATH_CIRCO],"$CIRCO${EXEEXT}",
 944    [Define to path to circo program if found or 'echo circo' otherwise])
 945 fi
 946 AC_PATH_PROGS(GV, [gv gsview32], [echo gv])
 947 if test "$GV" != "echo gv" ; then
 948   AC_DEFINE([HAVE_GV],[1],[Define if the gv program is available])
 949   dnl If we're targeting for mingw we should emit windows paths, not msys
 950   if test "$llvm_cv_os_type" = "MingW" ; then
 951     GV=`echo $GV | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 952   fi
 953   AC_DEFINE_UNQUOTED([LLVM_PATH_GV],"$GV${EXEEXT}",
 954    [Define to path to gv program if found or 'echo gv' otherwise])
 955 fi
 956 AC_PATH_PROG(DOTTY, [dotty], [echo dotty])
 957 if test "$DOTTY" != "echo dotty" ; then
 958   AC_DEFINE([HAVE_DOTTY],[1],[Define if the dotty program is available])
 959   dnl If we're targeting for mingw we should emit windows paths, not msys
 960   if test "$llvm_cv_os_type" = "MingW" ; then
 961     DOTTY=`echo $DOTTY | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 962   fi
 963   AC_DEFINE_UNQUOTED([LLVM_PATH_DOTTY],"$DOTTY${EXEEXT}",
 964    [Define to path to dotty program if found or 'echo dotty' otherwise])
 965 fi
 966 AC_PATH_PROG(XDOT_PY, [xdot.py], [echo xdot.py])
 967 if test "$XDOT_PY" != "echo xdot.py" ; then
 968   AC_DEFINE([HAVE_XDOT_PY],[1],[Define if the xdot.py program is available])
 969   dnl If we're targeting for mingw we should emit windows paths, not msys
 970   if test "$llvm_cv_os_type" = "MingW" ; then
 971     XDOT_PY=`echo $XDOT_PY | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 972   fi
 973   AC_DEFINE_UNQUOTED([LLVM_PATH_XDOT_PY],"$XDOT_PY${EXEEXT}",
 974    [Define to path to xdot.py program if found or 'echo xdot.py' otherwise])
 975 fi
 976
 977 dnl Find the install program
 978 AC_PROG_INSTALL
 979 dnl Prepend src dir to install path dir if it's a relative path
 980 dnl This is a hack for installs that take place in something other
 981 dnl than the top level.
 982 case "$INSTALL" in
 983  [[\\/$]]* | ?:[[\\/]]* ) ;;
 984  *)  INSTALL="\\\$(TOPSRCDIR)/$INSTALL" ;;
 985 esac
 986
 987 dnl Checks for documentation and testing tools that we can do without. If these
 988 dnl are not found then they are set to "true" which always succeeds but does
 989 dnl nothing. This just lets the build output show that we could have done
 990 dnl something if the tool was available.
 991 AC_PATH_PROG(BZIP2, [bzip2])
 992 AC_PATH_PROG(CAT, [cat])
 993 AC_PATH_PROG(DOXYGEN, [doxygen])
 994 AC_PATH_PROG(GROFF, [groff])
 995 AC_PATH_PROG(GZIPBIN, [gzip])
 996 AC_PATH_PROG(POD2HTML, [pod2html])
 997 AC_PATH_PROG(POD2MAN, [pod2man])
 998 AC_PATH_PROG(PDFROFF, [pdfroff])
 999 AC_PATH_PROG(RUNTEST, [runtest])
1000 DJ_AC_PATH_TCLSH
1001 AC_PATH_PROG(ZIP, [zip])
1002 AC_PATH_PROGS(OCAMLC, [ocamlc])
1003 AC_PATH_PROGS(OCAMLOPT, [ocamlopt])
1004 AC_PATH_PROGS(OCAMLDEP, [ocamldep])
1005 AC_PATH_PROGS(OCAMLDOC, [ocamldoc])
1006 AC_PATH_PROGS(GAS, [gas as])
1007
1008 dnl Get the version of the linker in use.
1009 AC_LINK_GET_VERSION
1010
1011 dnl Determine whether the linker supports the -R option.
1012 AC_LINK_USE_R
1013
1014 dnl Determine whether the compiler supports the -rdynamic option.
1015 AC_LINK_EXPORT_DYNAMIC
1016
1017 dnl Determine whether the linker supports the --version-script option.
1018 AC_LINK_VERSION_SCRIPT
1019
1020 AC_MSG_CHECKING([tool compatibility])
1021
1022 dnl Ensure that compilation tools are GCC or a GNU compatible compiler such as
1023 dnl ICC; we use GCC specific options in the makefiles so the compiler needs
1024 dnl to support those options.
1025 dnl "icc" emits gcc signatures
1026 dnl "icc -no-gcc" emits no gcc signature BUT is still compatible
1027 ICC=no
1028 IXX=no
1029 case $CC in
1030   icc*|icpc*)
1031     ICC=yes
1032     IXX=yes
1033     ;;
1034    *)
1035     ;;
1036 esac
1037
1038 if test "$GCC" != "yes" && test "$ICC" != "yes"
1039 then
1040   AC_MSG_ERROR([gcc|icc required but not found])
1041 fi
1042
1043 dnl Ensure that compilation tools are compatible with GCC extensions
1044 if test "$GXX" != "yes" && test "$IXX" != "yes"
1045 then
1046   AC_MSG_ERROR([g++|clang++|icc required but not found])
1047 fi
1048
1049 dnl Verify that GCC is version 3.0 or higher
1050 if test "$GCC" = "yes"
1051 then
1052   AC_COMPILE_IFELSE([[#if !defined(__GNUC__) || __GNUC__ < 3
1053 #error Unsupported GCC version
1054 #endif
1055 ]], [], [AC_MSG_ERROR([gcc 3.x required, but you have a lower version])])
1056 fi
1057
1058 dnl Check for GNU Make.  We use its extensions, so don't build without it
1059 if test -z "$llvm_cv_gnu_make_command"
1060 then
1061   AC_MSG_ERROR([GNU Make required but not found])
1062 fi
1063
1064 dnl Tool compatibility is okay if we make it here.
1065 AC_MSG_RESULT([ok])
1066
1067 dnl Check optional compiler flags.
1068 AC_MSG_CHECKING([optional compiler flags])
1069 CXX_FLAG_CHECK(NO_VARIADIC_MACROS, [-Wno-variadic-macros])
1070 CXX_FLAG_CHECK(NO_MISSING_FIELD_INITIALIZERS, [-Wno-missing-field-initializers])
1071 CXX_FLAG_CHECK(COVERED_SWITCH_DEFAULT, [-Wcovered-switch-default])
1072 AC_MSG_RESULT([$NO_VARIADIC_MACROS $NO_MISSING_FIELD_INITIALIZERS $COVERED_SWITCH_DEFAULT])
1073
1074 dnl===-----------------------------------------------------------------------===
1075 dnl===
1076 dnl=== SECTION 5: Check for libraries
1077 dnl===
1078 dnl===-----------------------------------------------------------------------===
1079
1080 AC_CHECK_LIB(m,sin)
1081 if test "$llvm_cv_os_type" = "MingW" ; then
1082   AC_CHECK_LIB(imagehlp, main)
1083   AC_CHECK_LIB(psapi, main)
1084   AC_CHECK_LIB(shell32, main)
1085 fi
1086
1087 dnl dlopen() is required for plugin support.
1088 AC_SEARCH_LIBS(dlopen,dl,AC_DEFINE([HAVE_DLOPEN],[1],
1089                [Define if dlopen() is available on this platform.]),
1090                AC_MSG_WARN([dlopen() not found - disabling plugin support]))
1091
1092 dnl Search for the clock_gettime() function. Note that we rely on the POSIX
1093 dnl macros to detect whether clock_gettime is available, this just finds the
1094 dnl right libraries to link with.
1095 AC_SEARCH_LIBS(clock_gettime,rt)
1096
1097 dnl The curses library is optional; used for querying terminal info
1098 if test "$llvm_cv_enable_terminfo" = "yes" ; then
1099   dnl We need the has_color functionality in curses for it to be useful.
1100   AC_SEARCH_LIBS(setupterm,tinfo curses ncurses ncursesw,
1101                  AC_DEFINE([HAVE_TERMINFO],[1],
1102                            [Define if the setupterm() function is supported this platform.]))
1103 fi
1104
1105 dnl libffi is optional; used to call external functions from the interpreter
1106 if test "$llvm_cv_enable_libffi" = "yes" ; then
1107   AC_SEARCH_LIBS(ffi_call,ffi,AC_DEFINE([HAVE_FFI_CALL],[1],
1108                  [Define if libffi is available on this platform.]),
1109                  AC_MSG_ERROR([libffi not found - configure without --enable-libffi to compile without it]))
1110 fi
1111
1112 dnl mallinfo is optional; the code can compile (minus features) without it
1113 AC_SEARCH_LIBS(mallinfo,malloc,AC_DEFINE([HAVE_MALLINFO],[1],
1114                [Define if mallinfo() is available on this platform.]))
1115
1116 dnl pthread locking functions are optional - but llvm will not be thread-safe
1117 dnl without locks.
1118 if test "$ENABLE_THREADS" -eq 1 && test "$ENABLE_PTHREADS" -eq 1 ; then
1119   AC_CHECK_LIB(pthread, pthread_mutex_init)
1120   AC_SEARCH_LIBS(pthread_mutex_lock,pthread,
1121                  AC_DEFINE([HAVE_PTHREAD_MUTEX_LOCK],[1],
1122                            [Have pthread_mutex_lock]))
1123   AC_SEARCH_LIBS(pthread_rwlock_init,pthread,
1124                  AC_DEFINE([HAVE_PTHREAD_RWLOCK_INIT],[1],
1125                  [Have pthread_rwlock_init]))
1126   AC_SEARCH_LIBS(pthread_getspecific,pthread,
1127                  AC_DEFINE([HAVE_PTHREAD_GETSPECIFIC],[1],
1128                  [Have pthread_getspecific]))
1129 fi
1130
1131 dnl zlib is optional; used for compression/uncompression
1132 if test "$LLVM_ENABLE_ZLIB" -eq 1 ; then
1133   AC_CHECK_LIB(z, compress2)
1134 fi
1135
1136 dnl Allow extra x86-disassembler library
1137 AC_ARG_WITH(udis86,
1138   AS_HELP_STRING([--with-udis86=<path>],
1139     [Use udis86 external x86 disassembler library]),
1140     [
1141       AC_SUBST(USE_UDIS86, [1])
1142       case "$withval" in
1143         /usr/lib|yes) ;;
1144         *) LDFLAGS="$LDFLAGS -L${withval}" ;;
1145       esac
1146       AC_CHECK_LIB(udis86, ud_init, [], [
1147         echo "Error! You need to have libudis86 around."
1148         exit -1
1149       ])
1150     ],
1151     AC_SUBST(USE_UDIS86, [0]))
1152 AC_DEFINE_UNQUOTED([USE_UDIS86],$USE_UDIS86,
1153                    [Define if use udis86 library])
1154
1155 dnl Allow OProfile support for JIT output.
1156 AC_ARG_WITH(oprofile,
1157   AS_HELP_STRING([--with-oprofile=<prefix>],
1158     [Tell OProfile >= 0.9.4 how to symbolize JIT output]),
1159     [
1160       AC_SUBST(USE_OPROFILE, [1])
1161       case "$withval" in
1162         /usr|yes) llvm_cv_oppath=/usr/lib/oprofile ;;
1163         no) llvm_cv_oppath=
1164             AC_SUBST(USE_OPROFILE, [0]) ;;
1165         *) llvm_cv_oppath="${withval}/lib/oprofile"
1166            CPPFLAGS="-I${withval}/include";;
1167       esac
1168       if test -n "$llvm_cv_oppath" ; then
1169         LIBS="$LIBS -L${llvm_cv_oppath} -Wl,-rpath,${llvm_cv_oppath}"
1170         dnl Work around http://bugs.debian.org/cgi-bin/bugreport.cgi?bug=537744:
1171         dnl libbfd is not included properly in libopagent in some Debian
1172         dnl versions.  If libbfd isn't found at all, we assume opagent works
1173         dnl anyway.
1174         AC_SEARCH_LIBS(bfd_init, bfd, [], [])
1175         AC_SEARCH_LIBS(op_open_agent, opagent, [], [
1176           echo "Error! You need to have libopagent around."
1177           exit -1
1178         ])
1179         AC_CHECK_HEADER([opagent.h], [], [
1180           echo "Error! You need to have opagent.h around."
1181           exit -1
1182           ])
1183       fi
1184     ],
1185     [
1186       AC_SUBST(USE_OPROFILE, [0])
1187     ])
1188 AC_DEFINE_UNQUOTED([USE_OPROFILE],$USE_OPROFILE,
1189                    [Define if we have the oprofile JIT-support library])
1190
1191 dnl===-----------------------------------------------------------------------===
1192 dnl===
1193 dnl=== SECTION 6: Check for header files
1194 dnl===
1195 dnl===-----------------------------------------------------------------------===
1196
1197 dnl First, use autoconf provided macros for specific headers that we need
1198 dnl We don't check for ancient stuff or things that are guaranteed to be there
1199 dnl by the C++ standard. We always use the <cfoo> versions of <foo.h> C headers.
1200 dnl Generally we're looking for POSIX headers.
1201 AC_HEADER_DIRENT
1202 AC_HEADER_MMAP_ANONYMOUS
1203 AC_HEADER_STAT
1204 AC_HEADER_SYS_WAIT
1205 AC_HEADER_TIME
1206
1207 AC_CHECK_HEADERS([dlfcn.h execinfo.h fcntl.h inttypes.h limits.h link.h])
1208 AC_CHECK_HEADERS([malloc.h setjmp.h signal.h stdint.h termios.h unistd.h])
1209 AC_CHECK_HEADERS([utime.h windows.h])
1210 AC_CHECK_HEADERS([sys/mman.h sys/param.h sys/resource.h sys/time.h sys/uio.h])
1211 AC_CHECK_HEADERS([sys/types.h sys/ioctl.h malloc/malloc.h mach/mach.h])
1212 AC_CHECK_HEADERS([valgrind/valgrind.h])
1213 AC_CHECK_HEADERS([fenv.h])
1214 if test "$ENABLE_THREADS" -eq 1 && test "$ENABLE_PTHREADS" -eq 1 ; then
1215   AC_CHECK_HEADERS(pthread.h,
1216                    AC_SUBST(HAVE_PTHREAD, 1),
1217                    AC_SUBST(HAVE_PTHREAD, 0))
1218 else
1219   AC_SUBST(HAVE_PTHREAD, 0)
1220 fi
1221 if test "$LLVM_ENABLE_ZLIB" -eq 1 ; then
1222   AC_CHECK_HEADERS(zlib.h,
1223                    AC_SUBST(HAVE_LIBZ, 1),
1224                    AC_SUBST(HAVE_LIBZ, 0))
1225 else
1226   AC_SUBST(HAVE_LIBZ, 0)
1227 fi
1228
1229 dnl Try to find ffi.h.
1230 if test "$llvm_cv_enable_libffi" = "yes" ; then
1231   AC_CHECK_HEADERS([ffi.h ffi/ffi.h])
1232 fi
1233
1234 dnl Try to find Darwin specific crash reporting libraries.
1235 AC_CHECK_HEADERS([CrashReporterClient.h])
1236
1237 dnl Try to find Darwin specific crash reporting global.
1238 AC_MSG_CHECKING([__crashreporter_info__])
1239 AC_LINK_IFELSE(
1240   AC_LANG_SOURCE(
1241     [[extern const char *__crashreporter_info__;
1242       int main() {
1243         __crashreporter_info__ = "test";
1244         return 0;
1245       }
1246     ]]),
1247   AC_MSG_RESULT(yes)
1248   AC_DEFINE(HAVE_CRASHREPORTER_INFO, 1, Can use __crashreporter_info__),
1249   AC_MSG_RESULT(no)
1250   AC_DEFINE(HAVE_CRASHREPORTER_INFO, 0,
1251             Define if __crashreporter_info__ exists.))
1252
1253 dnl===-----------------------------------------------------------------------===
1254 dnl===
1255 dnl=== SECTION 7: Check for types and structures
1256 dnl===
1257 dnl===-----------------------------------------------------------------------===
1258
1259 AC_HUGE_VAL_CHECK
1260 AC_TYPE_PID_T
1261 AC_TYPE_SIZE_T
1262 AC_DEFINE_UNQUOTED([RETSIGTYPE],[void],[Define as the return type of signal handlers (`int' or `void').])
1263 AC_STRUCT_TM
1264 AC_CHECK_TYPES([int64_t],,AC_MSG_ERROR([Type int64_t required but not found]))
1265 AC_CHECK_TYPES([uint64_t],,
1266          AC_CHECK_TYPES([u_int64_t],,
1267          AC_MSG_ERROR([Type uint64_t or u_int64_t required but not found])))
1268
1269 dnl===-----------------------------------------------------------------------===
1270 dnl===
1271 dnl=== SECTION 8: Check for specific functions needed
1272 dnl===
1273 dnl===-----------------------------------------------------------------------===
1274
1275 AC_CHECK_FUNCS([backtrace ceilf floorf roundf rintf nearbyintf getcwd ])
1276 AC_CHECK_FUNCS([powf fmodf strtof round ])
1277 AC_CHECK_FUNCS([getpagesize getrusage getrlimit setrlimit gettimeofday ])
1278 AC_CHECK_FUNCS([isatty mkdtemp mkstemp ])
1279 AC_CHECK_FUNCS([mktemp posix_spawn realpath sbrk setrlimit strdup ])
1280 AC_CHECK_FUNCS([strerror strerror_r setenv ])
1281 AC_CHECK_FUNCS([strtoll strtoq sysconf malloc_zone_statistics ])
1282 AC_CHECK_FUNCS([setjmp longjmp sigsetjmp siglongjmp writev])
1283 AC_C_PRINTF_A
1284 AC_FUNC_RAND48
1285
1286 dnl Check the declaration "Secure API" on Windows environments.
1287 AC_CHECK_DECLS([strerror_s])
1288
1289 dnl Check symbols in libgcc.a for JIT on Mingw.
1290 if test "$llvm_cv_os_type" = "MingW" ; then
1291   AC_CHECK_LIB(gcc,_alloca,AC_DEFINE([HAVE__ALLOCA],[1],[Have host's _alloca]))
1292   AC_CHECK_LIB(gcc,__alloca,AC_DEFINE([HAVE___ALLOCA],[1],[Have host's __alloca]))
1293   AC_CHECK_LIB(gcc,__chkstk,AC_DEFINE([HAVE___CHKSTK],[1],[Have host's __chkstk]))
1294   AC_CHECK_LIB(gcc,___chkstk,AC_DEFINE([HAVE____CHKSTK],[1],[Have host's ___chkstk]))
1295
1296   AC_CHECK_LIB(gcc,__ashldi3,AC_DEFINE([HAVE___ASHLDI3],[1],[Have host's __ashldi3]))
1297   AC_CHECK_LIB(gcc,__ashrdi3,AC_DEFINE([HAVE___ASHRDI3],[1],[Have host's __ashrdi3]))
1298   AC_CHECK_LIB(gcc,__divdi3,AC_DEFINE([HAVE___DIVDI3],[1],[Have host's __divdi3]))
1299   AC_CHECK_LIB(gcc,__fixdfdi,AC_DEFINE([HAVE___FIXDFDI],[1],[Have host's __fixdfdi]))
1300   AC_CHECK_LIB(gcc,__fixsfdi,AC_DEFINE([HAVE___FIXSFDI],[1],[Have host's __fixsfdi]))
1301   AC_CHECK_LIB(gcc,__floatdidf,AC_DEFINE([HAVE___FLOATDIDF],[1],[Have host's __floatdidf]))
1302   AC_CHECK_LIB(gcc,__lshrdi3,AC_DEFINE([HAVE___LSHRDI3],[1],[Have host's __lshrdi3]))
1303   AC_CHECK_LIB(gcc,__moddi3,AC_DEFINE([HAVE___MODDI3],[1],[Have host's __moddi3]))
1304   AC_CHECK_LIB(gcc,__udivdi3,AC_DEFINE([HAVE___UDIVDI3],[1],[Have host's __udivdi3]))
1305   AC_CHECK_LIB(gcc,__umoddi3,AC_DEFINE([HAVE___UMODDI3],[1],[Have host's __umoddi3]))
1306
1307   AC_CHECK_LIB(gcc,__main,AC_DEFINE([HAVE___MAIN],[1],[Have host's __main]))
1308   AC_CHECK_LIB(gcc,__cmpdi2,AC_DEFINE([HAVE___CMPDI2],[1],[Have host's __cmpdi2]))
1309 fi
1310
1311 dnl Check Win32 API EnumerateLoadedModules.
1312 if test "$llvm_cv_os_type" = "MingW" ; then
1313   AC_MSG_CHECKING([whether EnumerateLoadedModules() accepts new decl])
1314   AC_COMPILE_IFELSE([[#include <windows.h>
1315 #include <imagehlp.h>
1316 extern void foo(PENUMLOADED_MODULES_CALLBACK);
1317 extern void foo(BOOL(CALLBACK*)(PCSTR,ULONG_PTR,ULONG,PVOID));]],
1318 [
1319   AC_MSG_RESULT([yes])
1320   llvm_cv_win32_elmcb_pcstr="PCSTR"
1321 ],
1322 [
1323   AC_MSG_RESULT([no])
1324   llvm_cv_win32_elmcb_pcstr="PSTR"
1325 ])
1326   AC_DEFINE_UNQUOTED([WIN32_ELMCB_PCSTR],$llvm_cv_win32_elmcb_pcstr,[Type of 1st arg on ELM Callback])
1327 fi
1328
1329 dnl Check for variations in the Standard C++ library and STL. These macros are
1330 dnl provided by LLVM in the autoconf/m4 directory.
1331 AC_FUNC_ISNAN
1332 AC_FUNC_ISINF
1333
1334 dnl Check for mmap support.We also need to know if /dev/zero is required to
1335 dnl be opened for allocating RWX memory.
1336 dnl Make sure we aren't attempting to configure for an unknown system
1337 if test "$llvm_cv_platform_type" = "Unix" ; then
1338   AC_FUNC_MMAP
1339   AC_FUNC_MMAP_FILE
1340   AC_NEED_DEV_ZERO_FOR_MMAP
1341
1342   if test "$ac_cv_func_mmap_fixed_mapped" = "no"
1343   then
1344     AC_MSG_WARN([mmap() of a fixed address required but not supported])
1345   fi
1346   if test "$ac_cv_func_mmap_file" = "no"
1347   then
1348     AC_MSG_WARN([mmap() of files required but not found])
1349   fi
1350 fi
1351
1352 dnl atomic builtins are required for threading support.
1353 AC_MSG_CHECKING(for GCC atomic builtins)
1354 dnl Since we'll be using these atomic builtins in C++ files we should test
1355 dnl the C++ compiler.
1356 AC_LANG_PUSH([C++])
1357 AC_LINK_IFELSE(
1358   AC_LANG_SOURCE(
1359     [[int main() {
1360         volatile unsigned long val = 1;
1361         __sync_synchronize();
1362         __sync_val_compare_and_swap(&val, 1, 0);
1363         __sync_add_and_fetch(&val, 1);
1364         __sync_sub_and_fetch(&val, 1);
1365         return 0;
1366       }
1367     ]]),
1368   AC_LANG_POP([C++])
1369   AC_MSG_RESULT(yes)
1370   AC_DEFINE(LLVM_HAS_ATOMICS, 1, Has gcc/MSVC atomic intrinsics),
1371   AC_MSG_RESULT(no)
1372   AC_DEFINE(LLVM_HAS_ATOMICS, 0, Has gcc/MSVC atomic intrinsics)
1373   AC_MSG_WARN([LLVM will be built thread-unsafe because atomic builtins are missing]))
1374
1375 dnl===-----------------------------------------------------------------------===
1376 dnl===
1377 dnl=== SECTION 9: Additional checks, variables, etc.
1378 dnl===
1379 dnl===-----------------------------------------------------------------------===
1380
1381 dnl Handle 32-bit linux systems running a 64-bit kernel.
1382 dnl This has to come after section 4 because it invokes the compiler.
1383 if test "$llvm_cv_os_type" = "Linux" -a "$llvm_cv_target_arch" = "x86_64" ; then
1384   AC_IS_LINUX_MIXED
1385   if test "$llvm_cv_linux_mixed" = "yes"; then
1386     llvm_cv_target_arch="x86"
1387     ARCH="x86"
1388   fi
1389 fi
1390
1391 dnl Check whether __dso_handle is present
1392 AC_CHECK_FUNCS([__dso_handle])
1393
1394 dnl Propagate the shared library extension that the libltdl checks did to
1395 dnl the Makefiles so we can use it there too
1396 AC_SUBST(SHLIBEXT,$libltdl_cv_shlibext)
1397
1398 # Translate the various configuration directories and other basic
1399 # information into substitutions that will end up in Makefile.config.in
1400 # that these configured values can be used by the makefiles
1401 if test "${prefix}" = "NONE" ; then
1402   prefix="/usr/local"
1403 fi
1404 eval LLVM_PREFIX="${prefix}";
1405 eval LLVM_BINDIR="${prefix}/bin";
1406 eval LLVM_DATADIR="${prefix}/share/llvm";
1407 eval LLVM_DOCSDIR="${prefix}/share/doc/llvm";
1408 eval LLVM_ETCDIR="${prefix}/etc/llvm";
1409 eval LLVM_INCLUDEDIR="${prefix}/include";
1410 eval LLVM_INFODIR="${prefix}/info";
1411 eval LLVM_MANDIR="${prefix}/man";
1412 LLVM_CONFIGTIME=`date`
1413 AC_SUBST(LLVM_PREFIX)
1414 AC_SUBST(LLVM_BINDIR)
1415 AC_SUBST(LLVM_DATADIR)
1416 AC_SUBST(LLVM_DOCSDIR)
1417 AC_SUBST(LLVM_ETCDIR)
1418 AC_SUBST(LLVM_INCLUDEDIR)
1419 AC_SUBST(LLVM_INFODIR)
1420 AC_SUBST(LLVM_MANDIR)
1421 AC_SUBST(LLVM_CONFIGTIME)
1422
1423 # Place the various directores into the config.h file as #defines so that we
1424 # can know about the installation paths within LLVM.
1425 AC_DEFINE_UNQUOTED(LLVM_PREFIX,"$LLVM_PREFIX",
1426                    [Installation prefix directory])
1427 AC_DEFINE_UNQUOTED(LLVM_BINDIR, "$LLVM_BINDIR",
1428                    [Installation directory for binary executables])
1429 AC_DEFINE_UNQUOTED(LLVM_DATADIR, "$LLVM_DATADIR",
1430                    [Installation directory for data files])
1431 AC_DEFINE_UNQUOTED(LLVM_DOCSDIR, "$LLVM_DOCSDIR",
1432                    [Installation directory for documentation])
1433 AC_DEFINE_UNQUOTED(LLVM_ETCDIR, "$LLVM_ETCDIR",
1434                    [Installation directory for config files])
1435 AC_DEFINE_UNQUOTED(LLVM_INCLUDEDIR, "$LLVM_INCLUDEDIR",
1436                    [Installation directory for include files])
1437 AC_DEFINE_UNQUOTED(LLVM_INFODIR, "$LLVM_INFODIR",
1438                    [Installation directory for .info files])
1439 AC_DEFINE_UNQUOTED(LLVM_MANDIR, "$LLVM_MANDIR",
1440                    [Installation directory for man pages])
1441 AC_DEFINE_UNQUOTED(LLVM_CONFIGTIME, "$LLVM_CONFIGTIME",
1442                    [Time at which LLVM was configured])
1443 AC_DEFINE_UNQUOTED(LLVM_DEFAULT_TARGET_TRIPLE, "$target",
1444                    [Target triple LLVM will generate code for by default])
1445
1446 # Determine which bindings to build.
1447 if test "$BINDINGS_TO_BUILD" = auto ; then
1448   BINDINGS_TO_BUILD=""
1449   if test "x$OCAMLC" != x -a "x$OCAMLDEP" != x ; then
1450     BINDINGS_TO_BUILD="ocaml $BINDINGS_TO_BUILD"
1451   fi
1452 fi
1453 AC_SUBST(BINDINGS_TO_BUILD,$BINDINGS_TO_BUILD)
1454
1455 # This isn't really configurey, but it avoids having to repeat the list in
1456 # other files.
1457 AC_SUBST(ALL_BINDINGS,ocaml)
1458
1459 # Do any work necessary to ensure that bindings have what they need.
1460 binding_prereqs_failed=0
1461 for a_binding in $BINDINGS_TO_BUILD ; do
1462   case "$a_binding" in
1463   ocaml)
1464     if test "x$OCAMLC" = x ; then
1465       AC_MSG_WARN([--enable-bindings=ocaml specified, but ocamlc not found. Try configure OCAMLC=/path/to/ocamlc])
1466       binding_prereqs_failed=1
1467     fi
1468     if test "x$OCAMLDEP" = x ; then
1469       AC_MSG_WARN([--enable-bindings=ocaml specified, but ocamldep not found. Try configure OCAMLDEP=/path/to/ocamldep])
1470       binding_prereqs_failed=1
1471     fi
1472     if test "x$OCAMLOPT" = x ; then
1473       AC_MSG_WARN([--enable-bindings=ocaml specified, but ocamlopt not found. Try configure OCAMLOPT=/path/to/ocamlopt])
1474       dnl ocamlopt is optional!
1475     fi
1476     if test "x$with_ocaml_libdir" != xauto ; then
1477       AC_SUBST(OCAML_LIBDIR,$with_ocaml_libdir)
1478     else
1479       ocaml_stdlib="`"$OCAMLC" -where`"
1480       if test "$LLVM_PREFIX" '<' "$ocaml_stdlib" -a "$ocaml_stdlib" '<' "$LLVM_PREFIX~"
1481       then
1482         # ocaml stdlib is beneath our prefix; use stdlib
1483         AC_SUBST(OCAML_LIBDIR,$ocaml_stdlib)
1484       else
1485         # ocaml stdlib is outside our prefix; use libdir/ocaml
1486         AC_SUBST(OCAML_LIBDIR,${prefix}/lib/ocaml)
1487       fi
1488     fi
1489     ;;
1490   esac
1491 done
1492 if test "$binding_prereqs_failed" = 1 ; then
1493   AC_MSG_ERROR([Prequisites for bindings not satisfied. Fix them or use configure --disable-bindings.])
1494 fi
1495
1496 dnl Determine whether the compiler supports -fvisibility-inlines-hidden.
1497 AC_CXX_USE_VISIBILITY_INLINES_HIDDEN
1498
1499 dnl Determine linker rpath flag
1500 if test "$llvm_cv_link_use_r" = "yes" ; then
1501   RPATH="-Wl,-R"
1502 else
1503   RPATH="-Wl,-rpath"
1504 fi
1505 AC_SUBST(RPATH)
1506
1507 dnl Determine linker rdynamic flag
1508 if test "$llvm_cv_link_use_export_dynamic" = "yes" ; then
1509   RDYNAMIC="-rdynamic"
1510 else
1511   RDYNAMIC=""
1512 fi
1513 AC_SUBST(RDYNAMIC)
1514
1515 dnl===-----------------------------------------------------------------------===
1516 dnl===
1517 dnl=== SECTION 10: Specify the output files and generate it
1518 dnl===
1519 dnl===-----------------------------------------------------------------------===
1520
1521 dnl **************************************************************************
1522 dnl End LLVM configure.ac Import
1523 dnl **************************************************************************
1524
1525 dnl Configure a common Makefile
1526 AC_CONFIG_FILES(Makefile.common)
1527 AC_CONFIG_FILES(Makefile.llvm.config)
1528
1529 dnl Configure project makefiles
1530 dnl List every Makefile that exists within your source tree
1531 AC_CONFIG_MAKEFILE(Makefile)
1532 AC_CONFIG_MAKEFILE(lib/Makefile)
1533 AC_CONFIG_MAKEFILE(lib/sample/Makefile)
1534 AC_CONFIG_MAKEFILE(tools/Makefile)
1535 AC_CONFIG_MAKEFILE(tools/sample/Makefile)
1536
1537 dnl This must be last
1538 AC_OUTPUT