lib/Target/X86/X86InstrMMX.td

   1 //====- X86InstrMMX.td - Describe the X86 Instruction Set --*- tablegen -*-===//
   2 //
   3 //                     The LLVM Compiler Infrastructure
   4 //
   5 // This file is distributed under the University of Illinois Open Source
   6 // License. See LICENSE.TXT for details.
   7 //
   8 //===----------------------------------------------------------------------===//
   9 //
  10 // This file describes the X86 MMX instruction set, defining the instructions,
  11 // and properties of the instructions which are needed for code generation,
  12 // machine code emission, and analysis.
  13 //
  14 //===----------------------------------------------------------------------===//
  15
  16 //===----------------------------------------------------------------------===//
  17 // MMX Pattern Fragments
  18 //===----------------------------------------------------------------------===//
  19
  20 def load_mmx : PatFrag<(ops node:$ptr), (v1i64 (load node:$ptr))>;
  21
  22 def bc_v8i8  : PatFrag<(ops node:$in), (v8i8  (bitconvert node:$in))>;
  23 def bc_v4i16 : PatFrag<(ops node:$in), (v4i16 (bitconvert node:$in))>;
  24 def bc_v2i32 : PatFrag<(ops node:$in), (v2i32 (bitconvert node:$in))>;
  25 def bc_v1i64 : PatFrag<(ops node:$in), (v1i64 (bitconvert node:$in))>;
  26
  27 //===----------------------------------------------------------------------===//
  28 // MMX Masks
  29 //===----------------------------------------------------------------------===//
  30
  31 // MMX_SHUFFLE_get_shuf_imm xform function: convert vector_shuffle mask to
  32 // PSHUFW imm.
  33 def MMX_SHUFFLE_get_shuf_imm : SDNodeXForm<build_vector, [{
  34   return getI8Imm(X86::getShuffleSHUFImmediate(N));
  35 }]>;
  36
  37 // Patterns for: vector_shuffle v1, v2, <2, 6, 3, 7, ...>
  38 def MMX_UNPCKH_shuffle_mask : PatLeaf<(build_vector), [{
  39   return X86::isUNPCKHMask(N);
  40 }]>;
  41
  42 // Patterns for: vector_shuffle v1, v2, <0, 4, 2, 5, ...>
  43 def MMX_UNPCKL_shuffle_mask : PatLeaf<(build_vector), [{
  44   return X86::isUNPCKLMask(N);
  45 }]>;
  46
  47 // Patterns for: vector_shuffle v1, <undef>, <0, 0, 1, 1, ...>
  48 def MMX_UNPCKH_v_undef_shuffle_mask : PatLeaf<(build_vector), [{
  49   return X86::isUNPCKH_v_undef_Mask(N);
  50 }]>;
  51
  52 // Patterns for: vector_shuffle v1, <undef>, <2, 2, 3, 3, ...>
  53 def MMX_UNPCKL_v_undef_shuffle_mask : PatLeaf<(build_vector), [{
  54   return X86::isUNPCKL_v_undef_Mask(N);
  55 }]>;
  56
  57 // Patterns for shuffling.
  58 def MMX_PSHUFW_shuffle_mask : PatLeaf<(build_vector), [{
  59   return X86::isPSHUFDMask(N);
  60 }], MMX_SHUFFLE_get_shuf_imm>;
  61
  62 //===----------------------------------------------------------------------===//
  63 // MMX Multiclasses
  64 //===----------------------------------------------------------------------===//
  65
  66 let isTwoAddress = 1 in {
  67   // MMXI_binop_rm - Simple MMX binary operator.
  68   multiclass MMXI_binop_rm<bits<8> opc, string OpcodeStr, SDNode OpNode,
  69                            ValueType OpVT, bit Commutable = 0> {
  70     def rr : MMXI<opc, MRMSrcReg, (outs VR64:$dst), (ins VR64:$src1, VR64:$src2),
  71                   !strconcat(OpcodeStr, "\t{$src2, $dst|$dst, $src2}"),
  72                   [(set VR64:$dst, (OpVT (OpNode VR64:$src1, VR64:$src2)))]> {
  73       let isCommutable = Commutable;
  74     }
  75     def rm : MMXI<opc, MRMSrcMem, (outs VR64:$dst), (ins VR64:$src1, i64mem:$src2),
  76                   !strconcat(OpcodeStr, "\t{$src2, $dst|$dst, $src2}"),
  77                   [(set VR64:$dst, (OpVT (OpNode VR64:$src1,
  78                                          (bitconvert
  79                                           (load_mmx addr:$src2)))))]>;
  80   }
  81
  82   multiclass MMXI_binop_rm_int<bits<8> opc, string OpcodeStr, Intrinsic IntId,
  83                                bit Commutable = 0> {
  84     def rr : MMXI<opc, MRMSrcReg, (outs VR64:$dst), (ins VR64:$src1, VR64:$src2),
  85                  !strconcat(OpcodeStr, "\t{$src2, $dst|$dst, $src2}"),
  86                  [(set VR64:$dst, (IntId VR64:$src1, VR64:$src2))]> {
  87       let isCommutable = Commutable;
  88     }
  89     def rm : MMXI<opc, MRMSrcMem, (outs VR64:$dst), (ins VR64:$src1, i64mem:$src2),
  90                  !strconcat(OpcodeStr, "\t{$src2, $dst|$dst, $src2}"),
  91                  [(set VR64:$dst, (IntId VR64:$src1,
  92                                    (bitconvert (load_mmx addr:$src2))))]>;
  93   }
  94
  95   // MMXI_binop_rm_v1i64 - Simple MMX binary operator whose type is v1i64.
  96   //
  97   // FIXME: we could eliminate this and use MMXI_binop_rm instead if tblgen knew
  98   // to collapse (bitconvert VT to VT) into its operand.
  99   //
 100   multiclass MMXI_binop_rm_v1i64<bits<8> opc, string OpcodeStr, SDNode OpNode,
 101                                  bit Commutable = 0> {
 102     def rr : MMXI<opc, MRMSrcReg, (outs VR64:$dst),
 103                                   (ins VR64:$src1, VR64:$src2),
 104                   !strconcat(OpcodeStr, "\t{$src2, $dst|$dst, $src2}"),
 105                   [(set VR64:$dst, (v1i64 (OpNode VR64:$src1, VR64:$src2)))]> {
 106       let isCommutable = Commutable;
 107     }
 108     def rm : MMXI<opc, MRMSrcMem, (outs VR64:$dst),
 109                                   (ins VR64:$src1, i64mem:$src2),
 110                   !strconcat(OpcodeStr, "\t{$src2, $dst|$dst, $src2}"),
 111                   [(set VR64:$dst,
 112                     (OpNode VR64:$src1,(load_mmx addr:$src2)))]>;
 113   }
 114
 115   multiclass MMXI_binop_rmi_int<bits<8> opc, bits<8> opc2, Format ImmForm,
 116                                 string OpcodeStr, Intrinsic IntId,
 117                                 Intrinsic IntId2> {
 118     def rr : MMXI<opc, MRMSrcReg, (outs VR64:$dst),
 119                                   (ins VR64:$src1, VR64:$src2),
 120                   !strconcat(OpcodeStr, "\t{$src2, $dst|$dst, $src2}"),
 121                   [(set VR64:$dst, (IntId VR64:$src1, VR64:$src2))]>;
 122     def rm : MMXI<opc, MRMSrcMem, (outs VR64:$dst),
 123                                   (ins VR64:$src1, i64mem:$src2),
 124                   !strconcat(OpcodeStr, "\t{$src2, $dst|$dst, $src2}"),
 125                   [(set VR64:$dst, (IntId VR64:$src1,
 126                                     (bitconvert (load_mmx addr:$src2))))]>;
 127     def ri : MMXIi8<opc2, ImmForm, (outs VR64:$dst),
 128                                    (ins VR64:$src1, i32i8imm:$src2),
 129                     !strconcat(OpcodeStr, "\t{$src2, $dst|$dst, $src2}"),
 130            [(set VR64:$dst, (IntId2 VR64:$src1, (i32 imm:$src2)))]>;
 131   }
 132 }
 133
 134 //===----------------------------------------------------------------------===//
 135 // MMX EMMS & FEMMS Instructions
 136 //===----------------------------------------------------------------------===//
 137
 138 def MMX_EMMS  : MMXI<0x77, RawFrm, (outs), (ins), "emms",  [(int_x86_mmx_emms)]>;
 139 def MMX_FEMMS : MMXI<0x0E, RawFrm, (outs), (ins), "femms", [(int_x86_mmx_femms)]>;
 140
 141 //===----------------------------------------------------------------------===//
 142 // MMX Scalar Instructions
 143 //===----------------------------------------------------------------------===//
 144
 145 // Data Transfer Instructions
 146 def MMX_MOVD64rr : MMXI<0x6E, MRMSrcReg, (outs VR64:$dst), (ins GR32:$src),
 147                         "movd\t{$src, $dst|$dst, $src}",
 148                         [(set VR64:$dst, (v2i32 (scalar_to_vector GR32:$src)))]>;
 149 let canFoldAsLoad = 1, isReMaterializable = 1 in
 150 def MMX_MOVD64rm : MMXI<0x6E, MRMSrcMem, (outs VR64:$dst), (ins i32mem:$src),
 151                         "movd\t{$src, $dst|$dst, $src}",
 152               [(set VR64:$dst, (v2i32 (scalar_to_vector (loadi32 addr:$src))))]>;
 153 let mayStore = 1 in
 154 def MMX_MOVD64mr : MMXI<0x7E, MRMDestMem, (outs), (ins i32mem:$dst, VR64:$src),
 155                         "movd\t{$src, $dst|$dst, $src}", []>;
 156
 157 let neverHasSideEffects = 1 in
 158 def MMX_MOVD64to64rr : MMXRI<0x6E, MRMSrcReg, (outs VR64:$dst), (ins GR64:$src),
 159                              "movd\t{$src, $dst|$dst, $src}", []>;
 160
 161 let neverHasSideEffects = 1 in
 162 def MMX_MOVD64from64rr : MMXRI<0x7E, MRMSrcReg, (outs GR64:$dst), (ins VR64:$src),
 163                                "movd\t{$src, $dst|$dst, $src}", []>;
 164
 165 let neverHasSideEffects = 1 in
 166 def MMX_MOVQ64rr : MMXI<0x6F, MRMSrcReg, (outs VR64:$dst), (ins VR64:$src),
 167                         "movq\t{$src, $dst|$dst, $src}", []>;
 168 let canFoldAsLoad = 1, isReMaterializable = 1, mayHaveSideEffects = 1 in
 169 def MMX_MOVQ64rm : MMXI<0x6F, MRMSrcMem, (outs VR64:$dst), (ins i64mem:$src),
 170                         "movq\t{$src, $dst|$dst, $src}",
 171                         [(set VR64:$dst, (load_mmx addr:$src))]>;
 172 def MMX_MOVQ64mr : MMXI<0x7F, MRMDestMem, (outs), (ins i64mem:$dst, VR64:$src),
 173                         "movq\t{$src, $dst|$dst, $src}",
 174                         [(store (v1i64 VR64:$src), addr:$dst)]>;
 175
 176 def MMX_MOVDQ2Qrr : SDIi8<0xD6, MRMDestMem, (outs VR64:$dst), (ins VR128:$src),
 177                           "movdq2q\t{$src, $dst|$dst, $src}",
 178                           [(set VR64:$dst,
 179                             (v1i64 (bitconvert
 180                             (i64 (vector_extract (v2i64 VR128:$src),
 181                                   (iPTR 0))))))]>;
 182
 183 def MMX_MOVQ2DQrr : SSDIi8<0xD6, MRMDestMem, (outs VR128:$dst), (ins VR64:$src),
 184                            "movq2dq\t{$src, $dst|$dst, $src}",
 185           [(set VR128:$dst,
 186                 (v2i64 (vector_shuffle immAllZerosV,
 187                         (v2i64 (scalar_to_vector (i64 (bitconvert VR64:$src)))),
 188                         MOVL_shuffle_mask)))]>;
 189
 190 def MMX_MOVNTQmr  : MMXI<0xE7, MRMDestMem, (outs), (ins i64mem:$dst, VR64:$src),
 191                          "movntq\t{$src, $dst|$dst, $src}",
 192                          [(int_x86_mmx_movnt_dq addr:$dst, VR64:$src)]>;
 193
 194 let AddedComplexity = 15 in
 195 // movd to MMX register zero-extends
 196 def MMX_MOVZDI2PDIrr : MMXI<0x6E, MRMSrcReg, (outs VR64:$dst), (ins GR32:$src),
 197                              "movd\t{$src, $dst|$dst, $src}",
 198               [(set VR64:$dst,
 199                     (v2i32 (X86vzmovl (v2i32 (scalar_to_vector GR32:$src)))))]>;
 200 let AddedComplexity = 20 in
 201 def MMX_MOVZDI2PDIrm : MMXI<0x6E, MRMSrcMem, (outs VR64:$dst), (ins i32mem:$src),
 202                              "movd\t{$src, $dst|$dst, $src}",
 203           [(set VR64:$dst,
 204                 (v2i32 (X86vzmovl (v2i32
 205                                    (scalar_to_vector (loadi32 addr:$src))))))]>;
 206
 207 // Arithmetic Instructions
 208
 209 // -- Addition
 210 defm MMX_PADDB : MMXI_binop_rm<0xFC, "paddb", add, v8i8,  1>;
 211 defm MMX_PADDW : MMXI_binop_rm<0xFD, "paddw", add, v4i16, 1>;
 212 defm MMX_PADDD : MMXI_binop_rm<0xFE, "paddd", add, v2i32, 1>;
 213 defm MMX_PADDQ : MMXI_binop_rm<0xD4, "paddq", add, v1i64, 1>;
 214
 215 defm MMX_PADDSB  : MMXI_binop_rm_int<0xEC, "paddsb" , int_x86_mmx_padds_b, 1>;
 216 defm MMX_PADDSW  : MMXI_binop_rm_int<0xED, "paddsw" , int_x86_mmx_padds_w, 1>;
 217
 218 defm MMX_PADDUSB : MMXI_binop_rm_int<0xDC, "paddusb", int_x86_mmx_paddus_b, 1>;
 219 defm MMX_PADDUSW : MMXI_binop_rm_int<0xDD, "paddusw", int_x86_mmx_paddus_w, 1>;
 220
 221 // -- Subtraction
 222 defm MMX_PSUBB : MMXI_binop_rm<0xF8, "psubb", sub, v8i8>;
 223 defm MMX_PSUBW : MMXI_binop_rm<0xF9, "psubw", sub, v4i16>;
 224 defm MMX_PSUBD : MMXI_binop_rm<0xFA, "psubd", sub, v2i32>;
 225 defm MMX_PSUBQ : MMXI_binop_rm<0xFB, "psubq", sub, v1i64>;
 226
 227 defm MMX_PSUBSB  : MMXI_binop_rm_int<0xE8, "psubsb" , int_x86_mmx_psubs_b>;
 228 defm MMX_PSUBSW  : MMXI_binop_rm_int<0xE9, "psubsw" , int_x86_mmx_psubs_w>;
 229
 230 defm MMX_PSUBUSB : MMXI_binop_rm_int<0xD8, "psubusb", int_x86_mmx_psubus_b>;
 231 defm MMX_PSUBUSW : MMXI_binop_rm_int<0xD9, "psubusw", int_x86_mmx_psubus_w>;
 232
 233 // -- Multiplication
 234 defm MMX_PMULLW  : MMXI_binop_rm<0xD5, "pmullw", mul, v4i16, 1>;
 235
 236 defm MMX_PMULHW  : MMXI_binop_rm_int<0xE5, "pmulhw",  int_x86_mmx_pmulh_w,  1>;
 237 defm MMX_PMULHUW : MMXI_binop_rm_int<0xE4, "pmulhuw", int_x86_mmx_pmulhu_w, 1>;
 238 defm MMX_PMULUDQ : MMXI_binop_rm_int<0xF4, "pmuludq", int_x86_mmx_pmulu_dq, 1>;
 239
 240 // -- Miscellanea
 241 defm MMX_PMADDWD : MMXI_binop_rm_int<0xF5, "pmaddwd", int_x86_mmx_pmadd_wd, 1>;
 242
 243 defm MMX_PAVGB   : MMXI_binop_rm_int<0xE0, "pavgb", int_x86_mmx_pavg_b, 1>;
 244 defm MMX_PAVGW   : MMXI_binop_rm_int<0xE3, "pavgw", int_x86_mmx_pavg_w, 1>;
 245
 246 defm MMX_PMINUB  : MMXI_binop_rm_int<0xDA, "pminub", int_x86_mmx_pminu_b, 1>;
 247 defm MMX_PMINSW  : MMXI_binop_rm_int<0xEA, "pminsw", int_x86_mmx_pmins_w, 1>;
 248
 249 defm MMX_PMAXUB  : MMXI_binop_rm_int<0xDE, "pmaxub", int_x86_mmx_pmaxu_b, 1>;
 250 defm MMX_PMAXSW  : MMXI_binop_rm_int<0xEE, "pmaxsw", int_x86_mmx_pmaxs_w, 1>;
 251
 252 defm MMX_PSADBW  : MMXI_binop_rm_int<0xE0, "psadbw", int_x86_mmx_psad_bw, 1>;
 253
 254 // Logical Instructions
 255 defm MMX_PAND : MMXI_binop_rm_v1i64<0xDB, "pand", and, 1>;
 256 defm MMX_POR  : MMXI_binop_rm_v1i64<0xEB, "por" , or,  1>;
 257 defm MMX_PXOR : MMXI_binop_rm_v1i64<0xEF, "pxor", xor, 1>;
 258
 259 let isTwoAddress = 1 in {
 260   def MMX_PANDNrr : MMXI<0xDF, MRMSrcReg,
 261                          (outs VR64:$dst), (ins VR64:$src1, VR64:$src2),
 262                          "pandn\t{$src2, $dst|$dst, $src2}",
 263                          [(set VR64:$dst, (v1i64 (and (vnot VR64:$src1),
 264                                                   VR64:$src2)))]>;
 265   def MMX_PANDNrm : MMXI<0xDF, MRMSrcMem,
 266                          (outs VR64:$dst), (ins VR64:$src1, i64mem:$src2),
 267                          "pandn\t{$src2, $dst|$dst, $src2}",
 268                          [(set VR64:$dst, (v1i64 (and (vnot VR64:$src1),
 269                                                   (load addr:$src2))))]>;
 270 }
 271
 272 // Shift Instructions
 273 defm MMX_PSRLW : MMXI_binop_rmi_int<0xD1, 0x71, MRM2r, "psrlw",
 274                                     int_x86_mmx_psrl_w, int_x86_mmx_psrli_w>;
 275 defm MMX_PSRLD : MMXI_binop_rmi_int<0xD2, 0x72, MRM2r, "psrld",
 276                                     int_x86_mmx_psrl_d, int_x86_mmx_psrli_d>;
 277 defm MMX_PSRLQ : MMXI_binop_rmi_int<0xD3, 0x73, MRM2r, "psrlq",
 278                                     int_x86_mmx_psrl_q, int_x86_mmx_psrli_q>;
 279
 280 defm MMX_PSLLW : MMXI_binop_rmi_int<0xF1, 0x71, MRM6r, "psllw",
 281                                     int_x86_mmx_psll_w, int_x86_mmx_pslli_w>;
 282 defm MMX_PSLLD : MMXI_binop_rmi_int<0xF2, 0x72, MRM6r, "pslld",
 283                                     int_x86_mmx_psll_d, int_x86_mmx_pslli_d>;
 284 defm MMX_PSLLQ : MMXI_binop_rmi_int<0xF3, 0x73, MRM6r, "psllq",
 285                                     int_x86_mmx_psll_q, int_x86_mmx_pslli_q>;
 286
 287 defm MMX_PSRAW : MMXI_binop_rmi_int<0xE1, 0x71, MRM4r, "psraw",
 288                                     int_x86_mmx_psra_w, int_x86_mmx_psrai_w>;
 289 defm MMX_PSRAD : MMXI_binop_rmi_int<0xE2, 0x72, MRM4r, "psrad",
 290                                     int_x86_mmx_psra_d, int_x86_mmx_psrai_d>;
 291
 292 // Shift up / down and insert zero's.
 293 def : Pat<(v1i64 (X86vshl     VR64:$src, (i8 imm:$amt))),
 294           (v1i64 (MMX_PSLLQri VR64:$src, imm:$amt))>;
 295 def : Pat<(v1i64 (X86vshr     VR64:$src, (i8 imm:$amt))),
 296           (v1i64 (MMX_PSRLQri VR64:$src, imm:$amt))>;
 297
 298 // Comparison Instructions
 299 defm MMX_PCMPEQB : MMXI_binop_rm_int<0x74, "pcmpeqb", int_x86_mmx_pcmpeq_b>;
 300 defm MMX_PCMPEQW : MMXI_binop_rm_int<0x75, "pcmpeqw", int_x86_mmx_pcmpeq_w>;
 301 defm MMX_PCMPEQD : MMXI_binop_rm_int<0x76, "pcmpeqd", int_x86_mmx_pcmpeq_d>;
 302
 303 defm MMX_PCMPGTB : MMXI_binop_rm_int<0x64, "pcmpgtb", int_x86_mmx_pcmpgt_b>;
 304 defm MMX_PCMPGTW : MMXI_binop_rm_int<0x65, "pcmpgtw", int_x86_mmx_pcmpgt_w>;
 305 defm MMX_PCMPGTD : MMXI_binop_rm_int<0x66, "pcmpgtd", int_x86_mmx_pcmpgt_d>;
 306
 307 // Conversion Instructions
 308
 309 // -- Unpack Instructions
 310 let isTwoAddress = 1 in {
 311   // Unpack High Packed Data Instructions
 312   def MMX_PUNPCKHBWrr : MMXI<0x68, MRMSrcReg,
 313                              (outs VR64:$dst), (ins VR64:$src1, VR64:$src2),
 314                              "punpckhbw\t{$src2, $dst|$dst, $src2}",
 315                              [(set VR64:$dst,
 316                                (v8i8 (vector_shuffle VR64:$src1, VR64:$src2,
 317                                       MMX_UNPCKH_shuffle_mask)))]>;
 318   def MMX_PUNPCKHBWrm : MMXI<0x68, MRMSrcMem,
 319                              (outs VR64:$dst), (ins VR64:$src1, i64mem:$src2),
 320                              "punpckhbw\t{$src2, $dst|$dst, $src2}",
 321                              [(set VR64:$dst,
 322                                (v8i8 (vector_shuffle VR64:$src1,
 323                                       (bc_v8i8 (load_mmx addr:$src2)),
 324                                       MMX_UNPCKH_shuffle_mask)))]>;
 325
 326   def MMX_PUNPCKHWDrr : MMXI<0x69, MRMSrcReg,
 327                              (outs VR64:$dst), (ins VR64:$src1, VR64:$src2),
 328                              "punpckhwd\t{$src2, $dst|$dst, $src2}",
 329                              [(set VR64:$dst,
 330                                (v4i16 (vector_shuffle VR64:$src1, VR64:$src2,
 331                                        MMX_UNPCKH_shuffle_mask)))]>;
 332   def MMX_PUNPCKHWDrm : MMXI<0x69, MRMSrcMem,
 333                              (outs VR64:$dst), (ins VR64:$src1, i64mem:$src2),
 334                              "punpckhwd\t{$src2, $dst|$dst, $src2}",
 335                              [(set VR64:$dst,
 336                                (v4i16 (vector_shuffle VR64:$src1,
 337                                        (bc_v4i16 (load_mmx addr:$src2)),
 338                                        MMX_UNPCKH_shuffle_mask)))]>;
 339
 340   def MMX_PUNPCKHDQrr : MMXI<0x6A, MRMSrcReg,
 341                              (outs VR64:$dst), (ins VR64:$src1, VR64:$src2),
 342                              "punpckhdq\t{$src2, $dst|$dst, $src2}",
 343                              [(set VR64:$dst,
 344                                (v2i32 (vector_shuffle VR64:$src1, VR64:$src2,
 345                                        MMX_UNPCKH_shuffle_mask)))]>;
 346   def MMX_PUNPCKHDQrm : MMXI<0x6A, MRMSrcMem,
 347                              (outs VR64:$dst), (ins VR64:$src1, i64mem:$src2),
 348                              "punpckhdq\t{$src2, $dst|$dst, $src2}",
 349                              [(set VR64:$dst,
 350                                (v2i32 (vector_shuffle VR64:$src1,
 351                                        (bc_v2i32 (load_mmx addr:$src2)),
 352                                        MMX_UNPCKH_shuffle_mask)))]>;
 353
 354   // Unpack Low Packed Data Instructions
 355   def MMX_PUNPCKLBWrr : MMXI<0x60, MRMSrcReg,
 356                              (outs VR64:$dst), (ins VR64:$src1, VR64:$src2),
 357                              "punpcklbw\t{$src2, $dst|$dst, $src2}",
 358                              [(set VR64:$dst,
 359                                (v8i8 (vector_shuffle VR64:$src1, VR64:$src2,
 360                                       MMX_UNPCKL_shuffle_mask)))]>;
 361   def MMX_PUNPCKLBWrm : MMXI<0x60, MRMSrcMem,
 362                              (outs VR64:$dst), (ins VR64:$src1, i64mem:$src2),
 363                              "punpcklbw\t{$src2, $dst|$dst, $src2}",
 364                              [(set VR64:$dst,
 365                                (v8i8 (vector_shuffle VR64:$src1,
 366                                       (bc_v8i8 (load_mmx addr:$src2)),
 367                                       MMX_UNPCKL_shuffle_mask)))]>;
 368
 369   def MMX_PUNPCKLWDrr : MMXI<0x61, MRMSrcReg,
 370                              (outs VR64:$dst), (ins VR64:$src1, VR64:$src2),
 371                              "punpcklwd\t{$src2, $dst|$dst, $src2}",
 372                              [(set VR64:$dst,
 373                                (v4i16 (vector_shuffle VR64:$src1, VR64:$src2,
 374                                        MMX_UNPCKL_shuffle_mask)))]>;
 375   def MMX_PUNPCKLWDrm : MMXI<0x61, MRMSrcMem,
 376                              (outs VR64:$dst), (ins VR64:$src1, i64mem:$src2),
 377                              "punpcklwd\t{$src2, $dst|$dst, $src2}",
 378                              [(set VR64:$dst,
 379                                (v4i16 (vector_shuffle VR64:$src1,
 380                                        (bc_v4i16 (load_mmx addr:$src2)),
 381                                        MMX_UNPCKL_shuffle_mask)))]>;
 382
 383   def MMX_PUNPCKLDQrr : MMXI<0x62, MRMSrcReg,
 384                              (outs VR64:$dst), (ins VR64:$src1, VR64:$src2),
 385                              "punpckldq\t{$src2, $dst|$dst, $src2}",
 386                              [(set VR64:$dst,
 387                                (v2i32 (vector_shuffle VR64:$src1, VR64:$src2,
 388                                        MMX_UNPCKL_shuffle_mask)))]>;
 389   def MMX_PUNPCKLDQrm : MMXI<0x62, MRMSrcMem,
 390                              (outs VR64:$dst), (ins VR64:$src1, i64mem:$src2),
 391                              "punpckldq\t{$src2, $dst|$dst, $src2}",
 392                              [(set VR64:$dst,
 393                                (v2i32 (vector_shuffle VR64:$src1,
 394                                        (bc_v2i32 (load_mmx addr:$src2)),
 395                                        MMX_UNPCKL_shuffle_mask)))]>;
 396 }
 397
 398 // -- Pack Instructions
 399 defm MMX_PACKSSWB : MMXI_binop_rm_int<0x63, "packsswb", int_x86_mmx_packsswb>;
 400 defm MMX_PACKSSDW : MMXI_binop_rm_int<0x6B, "packssdw", int_x86_mmx_packssdw>;
 401 defm MMX_PACKUSWB : MMXI_binop_rm_int<0x67, "packuswb", int_x86_mmx_packuswb>;
 402
 403 // -- Shuffle Instructions
 404 def MMX_PSHUFWri : MMXIi8<0x70, MRMSrcReg,
 405                           (outs VR64:$dst), (ins VR64:$src1, i8imm:$src2),
 406                           "pshufw\t{$src2, $src1, $dst|$dst, $src1, $src2}",
 407                           [(set VR64:$dst,
 408                             (v4i16 (vector_shuffle
 409                                     VR64:$src1, (undef),
 410                                     MMX_PSHUFW_shuffle_mask:$src2)))]>;
 411 def MMX_PSHUFWmi : MMXIi8<0x70, MRMSrcMem,
 412                           (outs VR64:$dst), (ins i64mem:$src1, i8imm:$src2),
 413                           "pshufw\t{$src2, $src1, $dst|$dst, $src1, $src2}",
 414                           [(set VR64:$dst,
 415                             (v4i16 (vector_shuffle
 416                                     (bc_v4i16 (load_mmx addr:$src1)),
 417                                     (undef),
 418                                     MMX_PSHUFW_shuffle_mask:$src2)))]>;
 419
 420 // -- Conversion Instructions
 421 let neverHasSideEffects = 1 in {
 422 def MMX_CVTPD2PIrr  : MMX2I<0x2D, MRMSrcReg, (outs VR64:$dst), (ins VR128:$src),
 423                             "cvtpd2pi\t{$src, $dst|$dst, $src}", []>;
 424 let mayLoad = 1 in
 425 def MMX_CVTPD2PIrm  : MMX2I<0x2D, MRMSrcMem, (outs VR64:$dst), (ins f128mem:$src),
 426                             "cvtpd2pi\t{$src, $dst|$dst, $src}", []>;
 427
 428 def MMX_CVTPI2PDrr  : MMX2I<0x2A, MRMSrcReg, (outs VR128:$dst), (ins VR64:$src),
 429                             "cvtpi2pd\t{$src, $dst|$dst, $src}", []>;
 430 let mayLoad = 1 in
 431 def MMX_CVTPI2PDrm  : MMX2I<0x2A, MRMSrcMem, (outs VR128:$dst), (ins i64mem:$src),
 432                             "cvtpi2pd\t{$src, $dst|$dst, $src}", []>;
 433
 434 def MMX_CVTPI2PSrr  : MMXI<0x2A, MRMSrcReg, (outs VR128:$dst), (ins VR64:$src),
 435                            "cvtpi2ps\t{$src, $dst|$dst, $src}", []>;
 436 let mayLoad = 1 in
 437 def MMX_CVTPI2PSrm  : MMXI<0x2A, MRMSrcMem, (outs VR128:$dst), (ins i64mem:$src),
 438                            "cvtpi2ps\t{$src, $dst|$dst, $src}", []>;
 439
 440 def MMX_CVTPS2PIrr  : MMXI<0x2D, MRMSrcReg, (outs VR64:$dst), (ins VR128:$src),
 441                            "cvtps2pi\t{$src, $dst|$dst, $src}", []>;
 442 let mayLoad = 1 in
 443 def MMX_CVTPS2PIrm  : MMXI<0x2D, MRMSrcMem, (outs VR64:$dst), (ins f64mem:$src),
 444                            "cvtps2pi\t{$src, $dst|$dst, $src}", []>;
 445
 446 def MMX_CVTTPD2PIrr : MMX2I<0x2C, MRMSrcReg, (outs VR64:$dst), (ins VR128:$src),
 447                             "cvttpd2pi\t{$src, $dst|$dst, $src}", []>;
 448 let mayLoad = 1 in
 449 def MMX_CVTTPD2PIrm : MMX2I<0x2C, MRMSrcMem, (outs VR64:$dst), (ins f128mem:$src),
 450                             "cvttpd2pi\t{$src, $dst|$dst, $src}", []>;
 451
 452 def MMX_CVTTPS2PIrr : MMXI<0x2C, MRMSrcReg, (outs VR64:$dst), (ins VR128:$src),
 453                            "cvttps2pi\t{$src, $dst|$dst, $src}", []>;
 454 let mayLoad = 1 in
 455 def MMX_CVTTPS2PIrm : MMXI<0x2C, MRMSrcMem, (outs VR64:$dst), (ins f64mem:$src),
 456                            "cvttps2pi\t{$src, $dst|$dst, $src}", []>;
 457 } // end neverHasSideEffects
 458
 459
 460 // Extract / Insert
 461 def MMX_X86pextrw : SDNode<"X86ISD::PEXTRW", SDTypeProfile<1, 2, []>, []>;
 462 def MMX_X86pinsrw : SDNode<"X86ISD::PINSRW", SDTypeProfile<1, 3, []>, []>;
 463
 464 def MMX_PEXTRWri  : MMXIi8<0xC5, MRMSrcReg,
 465                            (outs GR32:$dst), (ins VR64:$src1, i16i8imm:$src2),
 466                            "pextrw\t{$src2, $src1, $dst|$dst, $src1, $src2}",
 467                            [(set GR32:$dst, (MMX_X86pextrw (v4i16 VR64:$src1),
 468                                              (iPTR imm:$src2)))]>;
 469 let isTwoAddress = 1 in {
 470   def MMX_PINSRWrri : MMXIi8<0xC4, MRMSrcReg,
 471                       (outs VR64:$dst), (ins VR64:$src1, GR32:$src2, i16i8imm:$src3),
 472                       "pinsrw\t{$src3, $src2, $dst|$dst, $src2, $src3}",
 473                       [(set VR64:$dst, (v4i16 (MMX_X86pinsrw (v4i16 VR64:$src1),
 474                                                GR32:$src2, (iPTR imm:$src3))))]>;
 475   def MMX_PINSRWrmi : MMXIi8<0xC4, MRMSrcMem,
 476                      (outs VR64:$dst), (ins VR64:$src1, i16mem:$src2, i16i8imm:$src3),
 477                      "pinsrw\t{$src3, $src2, $dst|$dst, $src2, $src3}",
 478                      [(set VR64:$dst,
 479                        (v4i16 (MMX_X86pinsrw (v4i16 VR64:$src1),
 480                                (i32 (anyext (loadi16 addr:$src2))),
 481                                (iPTR imm:$src3))))]>;
 482 }
 483
 484 // Mask creation
 485 def MMX_PMOVMSKBrr : MMXI<0xD7, MRMSrcReg, (outs GR32:$dst), (ins VR64:$src),
 486                           "pmovmskb\t{$src, $dst|$dst, $src}",
 487                           [(set GR32:$dst, (int_x86_mmx_pmovmskb VR64:$src))]>;
 488
 489 // Misc.
 490 let Uses = [EDI] in
 491 def MMX_MASKMOVQ : MMXI<0xF7, MRMDestMem, (outs), (ins VR64:$src, VR64:$mask),
 492                         "maskmovq\t{$mask, $src|$src, $mask}",
 493                         [(int_x86_mmx_maskmovq VR64:$src, VR64:$mask, EDI)]>;
 494 let Uses = [RDI] in
 495 def MMX_MASKMOVQ64: MMXI64<0xF7, MRMDestMem, (outs), (ins VR64:$src, VR64:$mask),
 496                            "maskmovq\t{$mask, $src|$src, $mask}",
 497                            [(int_x86_mmx_maskmovq VR64:$src, VR64:$mask, RDI)]>;
 498
 499 //===----------------------------------------------------------------------===//
 500 // Alias Instructions
 501 //===----------------------------------------------------------------------===//
 502
 503 // Alias instructions that map zero vector to pxor.
 504 let isReMaterializable = 1 in {
 505   def MMX_V_SET0       : MMXI<0xEF, MRMInitReg, (outs VR64:$dst), (ins),
 506                               "pxor\t$dst, $dst",
 507                               [(set VR64:$dst, (v2i32 immAllZerosV))]>;
 508   def MMX_V_SETALLONES : MMXI<0x76, MRMInitReg, (outs VR64:$dst), (ins),
 509                               "pcmpeqd\t$dst, $dst",
 510                               [(set VR64:$dst, (v2i32 immAllOnesV))]>;
 511 }
 512
 513 let Predicates = [HasMMX] in {
 514   def : Pat<(v1i64 immAllZerosV), (MMX_V_SET0)>;
 515   def : Pat<(v4i16 immAllZerosV), (MMX_V_SET0)>;
 516   def : Pat<(v8i8  immAllZerosV), (MMX_V_SET0)>;
 517 }
 518
 519 //===----------------------------------------------------------------------===//
 520 // Non-Instruction Patterns
 521 //===----------------------------------------------------------------------===//
 522
 523 // Store 64-bit integer vector values.
 524 def : Pat<(store (v8i8  VR64:$src), addr:$dst),
 525           (MMX_MOVQ64mr addr:$dst, VR64:$src)>;
 526 def : Pat<(store (v4i16 VR64:$src), addr:$dst),
 527           (MMX_MOVQ64mr addr:$dst, VR64:$src)>;
 528 def : Pat<(store (v2i32 VR64:$src), addr:$dst),
 529           (MMX_MOVQ64mr addr:$dst, VR64:$src)>;
 530 def : Pat<(store (v2f32 VR64:$src), addr:$dst),
 531           (MMX_MOVQ64mr addr:$dst, VR64:$src)>;
 532 def : Pat<(store (v1i64 VR64:$src), addr:$dst),
 533           (MMX_MOVQ64mr addr:$dst, VR64:$src)>;
 534
 535 // Bit convert.
 536 def : Pat<(v8i8  (bitconvert (v1i64 VR64:$src))), (v8i8  VR64:$src)>;
 537 def : Pat<(v8i8  (bitconvert (v2i32 VR64:$src))), (v8i8  VR64:$src)>;
 538 def : Pat<(v8i8  (bitconvert (v2f32 VR64:$src))), (v8i8  VR64:$src)>;
 539 def : Pat<(v8i8  (bitconvert (v4i16 VR64:$src))), (v8i8  VR64:$src)>;
 540 def : Pat<(v4i16 (bitconvert (v1i64 VR64:$src))), (v4i16 VR64:$src)>;
 541 def : Pat<(v4i16 (bitconvert (v2i32 VR64:$src))), (v4i16 VR64:$src)>;
 542 def : Pat<(v4i16 (bitconvert (v2f32 VR64:$src))), (v4i16 VR64:$src)>;
 543 def : Pat<(v4i16 (bitconvert (v8i8  VR64:$src))), (v4i16 VR64:$src)>;
 544 def : Pat<(v2i32 (bitconvert (v1i64 VR64:$src))), (v2i32 VR64:$src)>;
 545 def : Pat<(v2i32 (bitconvert (v2f32 VR64:$src))), (v2i32 VR64:$src)>;
 546 def : Pat<(v2i32 (bitconvert (v4i16 VR64:$src))), (v2i32 VR64:$src)>;
 547 def : Pat<(v2i32 (bitconvert (v8i8  VR64:$src))), (v2i32 VR64:$src)>;
 548 def : Pat<(v2f32 (bitconvert (v1i64 VR64:$src))), (v2f32 VR64:$src)>;
 549 def : Pat<(v2f32 (bitconvert (v2i32 VR64:$src))), (v2f32 VR64:$src)>;
 550 def : Pat<(v2f32 (bitconvert (v4i16 VR64:$src))), (v2f32 VR64:$src)>;
 551 def : Pat<(v2f32 (bitconvert (v8i8  VR64:$src))), (v2f32 VR64:$src)>;
 552 def : Pat<(v1i64 (bitconvert (v2i32 VR64:$src))), (v1i64 VR64:$src)>;
 553 def : Pat<(v1i64 (bitconvert (v2f32 VR64:$src))), (v1i64 VR64:$src)>;
 554 def : Pat<(v1i64 (bitconvert (v4i16 VR64:$src))), (v1i64 VR64:$src)>;
 555 def : Pat<(v1i64 (bitconvert (v8i8  VR64:$src))), (v1i64 VR64:$src)>;
 556
 557 // 64-bit bit convert.
 558 def : Pat<(v1i64 (bitconvert (i64 GR64:$src))),
 559           (MMX_MOVD64to64rr GR64:$src)>;
 560 def : Pat<(v2i32 (bitconvert (i64 GR64:$src))),
 561           (MMX_MOVD64to64rr GR64:$src)>;
 562 def : Pat<(v2f32 (bitconvert (i64 GR64:$src))),
 563           (MMX_MOVD64to64rr GR64:$src)>;
 564 def : Pat<(v4i16 (bitconvert (i64 GR64:$src))),
 565           (MMX_MOVD64to64rr GR64:$src)>;
 566 def : Pat<(v8i8  (bitconvert (i64 GR64:$src))),
 567           (MMX_MOVD64to64rr GR64:$src)>;
 568 def : Pat<(i64 (bitconvert (v1i64 VR64:$src))),
 569           (MMX_MOVD64from64rr VR64:$src)>;
 570 def : Pat<(i64 (bitconvert (v2i32 VR64:$src))),
 571           (MMX_MOVD64from64rr VR64:$src)>;
 572 def : Pat<(i64 (bitconvert (v2f32 VR64:$src))),
 573           (MMX_MOVD64from64rr VR64:$src)>;
 574 def : Pat<(i64 (bitconvert (v4i16 VR64:$src))),
 575           (MMX_MOVD64from64rr VR64:$src)>;
 576 def : Pat<(i64  (bitconvert (v8i8 VR64:$src))),
 577           (MMX_MOVD64from64rr VR64:$src)>;
 578
 579 // Move scalar to XMM zero-extended
 580 // movd to XMM register zero-extends
 581 let AddedComplexity = 15 in {
 582   def : Pat<(v8i8 (X86vzmovl (bc_v8i8 (v2i32 (scalar_to_vector GR32:$src))))),
 583            (MMX_MOVZDI2PDIrr GR32:$src)>;
 584   def : Pat<(v4i16 (X86vzmovl (bc_v4i16 (v2i32 (scalar_to_vector GR32:$src))))),
 585            (MMX_MOVZDI2PDIrr GR32:$src)>;
 586 }
 587
 588 let AddedComplexity = 20 in {
 589   def : Pat<(v8i8 (X86vzmovl (bc_v8i8 (load_mmx addr:$src)))),
 590             (MMX_MOVZDI2PDIrm addr:$src)>;
 591   def : Pat<(v4i16 (X86vzmovl (bc_v4i16 (load_mmx addr:$src)))),
 592             (MMX_MOVZDI2PDIrm addr:$src)>;
 593   def : Pat<(v2i32 (X86vzmovl (bc_v2i32 (load_mmx addr:$src)))),
 594             (MMX_MOVZDI2PDIrm addr:$src)>;
 595 }
 596
 597 // Clear top half.
 598 let AddedComplexity = 15 in {
 599   def : Pat<(v8i8 (X86vzmovl VR64:$src)),
 600             (MMX_PUNPCKLDQrr VR64:$src, (MMX_V_SET0))>;
 601   def : Pat<(v4i16 (X86vzmovl VR64:$src)),
 602             (MMX_PUNPCKLDQrr VR64:$src, (MMX_V_SET0))>;
 603   def : Pat<(v2i32 (X86vzmovl VR64:$src)),
 604             (MMX_PUNPCKLDQrr VR64:$src, (MMX_V_SET0))>;
 605 }
 606
 607 // Scalar to v4i16 / v8i8. The source may be a GR32, but only the lower
 608 // 8 or 16-bits matter.
 609 def : Pat<(bc_v8i8  (v2i32 (scalar_to_vector GR32:$src))),
 610           (MMX_MOVD64rr GR32:$src)>;
 611 def : Pat<(bc_v4i16 (v2i32 (scalar_to_vector GR32:$src))),
 612           (MMX_MOVD64rr GR32:$src)>;
 613
 614 // Patterns to perform canonical versions of vector shuffling.
 615 let AddedComplexity = 10 in {
 616   def : Pat<(v8i8  (vector_shuffle VR64:$src, (undef),
 617                     MMX_UNPCKL_v_undef_shuffle_mask)),
 618             (MMX_PUNPCKLBWrr VR64:$src, VR64:$src)>;
 619   def : Pat<(v4i16 (vector_shuffle VR64:$src, (undef),
 620                     MMX_UNPCKL_v_undef_shuffle_mask)),
 621             (MMX_PUNPCKLWDrr VR64:$src, VR64:$src)>;
 622   def : Pat<(v2i32 (vector_shuffle VR64:$src, (undef),
 623                     MMX_UNPCKL_v_undef_shuffle_mask)),
 624             (MMX_PUNPCKLDQrr VR64:$src, VR64:$src)>;
 625 }
 626
 627 let AddedComplexity = 10 in {
 628   def : Pat<(v8i8  (vector_shuffle VR64:$src, (undef),
 629                     MMX_UNPCKH_v_undef_shuffle_mask)),
 630             (MMX_PUNPCKHBWrr VR64:$src, VR64:$src)>;
 631   def : Pat<(v4i16 (vector_shuffle VR64:$src, (undef),
 632                     MMX_UNPCKH_v_undef_shuffle_mask)),
 633             (MMX_PUNPCKHWDrr VR64:$src, VR64:$src)>;
 634   def : Pat<(v2i32 (vector_shuffle VR64:$src, (undef),
 635                     MMX_UNPCKH_v_undef_shuffle_mask)),
 636             (MMX_PUNPCKHDQrr VR64:$src, VR64:$src)>;
 637 }
 638
 639 // Patterns to perform vector shuffling with a zeroed out vector.
 640 let AddedComplexity = 20 in {
 641   def : Pat<(bc_v2i32 (vector_shuffle immAllZerosV,
 642                        (v2i32 (scalar_to_vector (load_mmx addr:$src))),
 643                        MMX_UNPCKL_shuffle_mask)),
 644             (MMX_PUNPCKLDQrm VR64:$src, VR64:$src)>;
 645 }
 646
 647 // Some special case PANDN patterns.
 648 // FIXME: Get rid of these.
 649 def : Pat<(v1i64 (and (xor VR64:$src1, (bc_v1i64 (v2i32 immAllOnesV))),
 650                   VR64:$src2)),
 651           (MMX_PANDNrr VR64:$src1, VR64:$src2)>;
 652 def : Pat<(v1i64 (and (xor VR64:$src1, (bc_v1i64 (v4i16 immAllOnesV_bc))),
 653                   VR64:$src2)),
 654           (MMX_PANDNrr VR64:$src1, VR64:$src2)>;
 655 def : Pat<(v1i64 (and (xor VR64:$src1, (bc_v1i64 (v8i8  immAllOnesV_bc))),
 656                   VR64:$src2)),
 657           (MMX_PANDNrr VR64:$src1, VR64:$src2)>;
 658
 659 def : Pat<(v1i64 (and (xor VR64:$src1, (bc_v1i64 (v2i32 immAllOnesV))),
 660                   (load addr:$src2))),
 661           (MMX_PANDNrm VR64:$src1, addr:$src2)>;
 662 def : Pat<(v1i64 (and (xor VR64:$src1, (bc_v1i64 (v4i16 immAllOnesV_bc))),
 663                   (load addr:$src2))),
 664           (MMX_PANDNrm VR64:$src1, addr:$src2)>;
 665 def : Pat<(v1i64 (and (xor VR64:$src1, (bc_v1i64 (v8i8  immAllOnesV_bc))),
 666                   (load addr:$src2))),
 667           (MMX_PANDNrm VR64:$src1, addr:$src2)>;
 668
 669 // Move MMX to lower 64-bit of XMM
 670 def : Pat<(v2i64 (scalar_to_vector (i64 (bitconvert VR64:$src)))),
 671           (v2i64 (MMX_MOVQ2DQrr VR64:$src))>;
 672
 673 // Move lower 64-bit of XMM to MMX.
 674 def : Pat<(v2i32 (bitconvert (i64 (vector_extract (v2i64 VR128:$src),
 675                                                   (iPTR 0))))),
 676           (v2i32 (MMX_MOVDQ2Qrr VR128:$src))>;
 677 def : Pat<(v4i16 (bitconvert (i64 (vector_extract (v2i64 VR128:$src),
 678                                                   (iPTR 0))))),
 679           (v4i16 (MMX_MOVDQ2Qrr VR128:$src))>;
 680 def : Pat<(v8i8 (bitconvert (i64 (vector_extract (v2i64 VR128:$src),
 681                                                   (iPTR 0))))),
 682           (v8i8 (MMX_MOVDQ2Qrr VR128:$src))>;
 683