lib/Target/X86/X86InstrFPStack.td

   1 //==- X86InstrFPStack.td - Describe the X86 Instruction Set -------*- C++ -*-=//
   2 //
   3 //                     The LLVM Compiler Infrastructure
   4 //
   5 // This file was developed by the Evan Cheng and is distributed under
   6 // the University of Illinois Open Source License. See LICENSE.TXT for details.
   7 //
   8 //===----------------------------------------------------------------------===//
   9 //
  10 // This file describes the X86 x87 FPU instruction set, defining the
  11 // instructions, and properties of the instructions which are needed for code
  12 // generation, machine code emission, and analysis.
  13 //
  14 //===----------------------------------------------------------------------===//
  15
  16 //===----------------------------------------------------------------------===//
  17 // FPStack specific DAG Nodes.
  18 //===----------------------------------------------------------------------===//
  19
  20 def SDTX86FpGet     : SDTypeProfile<1, 0, [SDTCisFP<0>]>;
  21 def SDTX86FpSet     : SDTypeProfile<0, 1, [SDTCisFP<0>]>;
  22 def SDTX86Fld       : SDTypeProfile<1, 2, [SDTCisFP<0>,
  23                                            SDTCisPtrTy<1>,
  24                                            SDTCisVT<2, OtherVT>]>;
  25 def SDTX86Fst       : SDTypeProfile<0, 3, [SDTCisFP<0>,
  26                                            SDTCisPtrTy<1>,
  27                                            SDTCisVT<2, OtherVT>]>;
  28 def SDTX86Fild      : SDTypeProfile<1, 2, [SDTCisFP<0>, SDTCisPtrTy<1>,
  29                                            SDTCisVT<2, OtherVT>]>;
  30 def SDTX86FpToIMem  : SDTypeProfile<0, 2, [SDTCisFP<0>, SDTCisPtrTy<1>]>;
  31
  32 def X86fpget        : SDNode<"X86ISD::FP_GET_RESULT", SDTX86FpGet,
  33                         [SDNPHasChain, SDNPInFlag, SDNPOutFlag]>;
  34 def X86fpset        : SDNode<"X86ISD::FP_SET_RESULT", SDTX86FpSet,
  35                         [SDNPHasChain, SDNPOutFlag]>;
  36 def X86fld          : SDNode<"X86ISD::FLD",      SDTX86Fld,
  37                         [SDNPHasChain]>;
  38 def X86fst          : SDNode<"X86ISD::FST",      SDTX86Fst,
  39                         [SDNPHasChain, SDNPInFlag]>;
  40 def X86fild         : SDNode<"X86ISD::FILD",     SDTX86Fild,
  41                         [SDNPHasChain]>;
  42 def X86fildflag     : SDNode<"X86ISD::FILD_FLAG",SDTX86Fild,
  43                         [SDNPHasChain, SDNPOutFlag]>;
  44 def X86fp_to_i16mem : SDNode<"X86ISD::FP_TO_INT16_IN_MEM", SDTX86FpToIMem,
  45                         [SDNPHasChain]>;
  46 def X86fp_to_i32mem : SDNode<"X86ISD::FP_TO_INT32_IN_MEM", SDTX86FpToIMem,
  47                         [SDNPHasChain]>;
  48 def X86fp_to_i64mem : SDNode<"X86ISD::FP_TO_INT64_IN_MEM", SDTX86FpToIMem,
  49                         [SDNPHasChain]>;
  50
  51 def extloadf80f32  : PatFrag<(ops node:$ptr), (f80 (extloadf32 node:$ptr))>;
  52 def extloadf80f64  : PatFrag<(ops node:$ptr), (f80 (extloadf64 node:$ptr))>;
  53 def extloadf64f32  : PatFrag<(ops node:$ptr), (f64 (extloadf32 node:$ptr))>;
  54
  55 //===----------------------------------------------------------------------===//
  56 // FPStack pattern fragments
  57 //===----------------------------------------------------------------------===//
  58
  59 def fpimm0 : PatLeaf<(fpimm), [{
  60   return N->isExactlyValue(+0.0);
  61 }]>;
  62
  63 def fpimmneg0 : PatLeaf<(fpimm), [{
  64   return N->isExactlyValue(-0.0);
  65 }]>;
  66
  67 def fpimm1 : PatLeaf<(fpimm), [{
  68   return N->isExactlyValue(+1.0);
  69 }]>;
  70
  71 def fpimmneg1 : PatLeaf<(fpimm), [{
  72   return N->isExactlyValue(-1.0);
  73 }]>;
  74
  75 // Some 'special' instructions
  76 let usesCustomDAGSchedInserter = 1 in {  // Expanded by the scheduler.
  77   def FP32_TO_INT16_IN_MEM : I<0, Pseudo,
  78                               (outs), (ins i16mem:$dst, RFP32:$src),
  79                               "#FP32_TO_INT16_IN_MEM PSEUDO!",
  80                               [(X86fp_to_i16mem RFP32:$src, addr:$dst)]>;
  81   def FP32_TO_INT32_IN_MEM : I<0, Pseudo,
  82                               (outs), (ins i32mem:$dst, RFP32:$src),
  83                               "#FP32_TO_INT32_IN_MEM PSEUDO!",
  84                               [(X86fp_to_i32mem RFP32:$src, addr:$dst)]>;
  85   def FP32_TO_INT64_IN_MEM : I<0, Pseudo,
  86                               (outs), (ins i64mem:$dst, RFP32:$src),
  87                               "#FP32_TO_INT64_IN_MEM PSEUDO!",
  88                               [(X86fp_to_i64mem RFP32:$src, addr:$dst)]>;
  89   def FP64_TO_INT16_IN_MEM : I<0, Pseudo,
  90                               (outs), (ins i16mem:$dst, RFP64:$src),
  91                               "#FP64_TO_INT16_IN_MEM PSEUDO!",
  92                               [(X86fp_to_i16mem RFP64:$src, addr:$dst)]>;
  93   def FP64_TO_INT32_IN_MEM : I<0, Pseudo,
  94                               (outs), (ins i32mem:$dst, RFP64:$src),
  95                               "#FP64_TO_INT32_IN_MEM PSEUDO!",
  96                               [(X86fp_to_i32mem RFP64:$src, addr:$dst)]>;
  97   def FP64_TO_INT64_IN_MEM : I<0, Pseudo,
  98                               (outs), (ins i64mem:$dst, RFP64:$src),
  99                               "#FP64_TO_INT64_IN_MEM PSEUDO!",
 100                               [(X86fp_to_i64mem RFP64:$src, addr:$dst)]>;
 101 }
 102
 103 let isTerminator = 1 in
 104   let Defs = [FP0, FP1, FP2, FP3, FP4, FP5, FP6] in
 105     def FP_REG_KILL  : I<0, Pseudo, (outs), (ins), "#FP_REG_KILL", []>;
 106
 107 // All FP Stack operations are represented with three instructions here.  The
 108 // first two instructions, generated by the instruction selector, uses "RFP32"
 109 // or "RFP64" registers: traditional register files to reference 32-bit or
 110 // 64-bit floating point values.  These sizes apply to the values, not the
 111 // registers, which are always 64 bits; RFP32 and RFP64 can be copied to
 112 // each other without losing information.  These instructions are all psuedo
 113 // instructions and use the "_Fp" suffix.
 114 // In some cases there are additional variants with a mixture of 32-bit and
 115 // 64-bit registers.
 116 // The second instruction is defined with FPI, which is the actual instruction
 117 // emitted by the assembler.  These use "RST" registers, although frequently
 118 // the actual register(s) used are implicit.  These are always 64-bits.
 119 // The FP stackifier pass converts one to the other after register allocation
 120 // occurs.
 121 //
 122 // Note that the FpI instruction should have instruction selection info (e.g.
 123 // a pattern) and the FPI instruction should have emission info (e.g. opcode
 124 // encoding and asm printing info).
 125
 126 // Random Pseudo Instructions.
 127 def FpGETRESULT32 : FpI_<(outs RFP32:$dst), (ins), SpecialFP,
 128                       [(set RFP32:$dst, X86fpget)]>;           // FPR = ST(0)
 129
 130 def FpGETRESULT64 : FpI_<(outs RFP64:$dst), (ins), SpecialFP,
 131                       [(set RFP64:$dst, X86fpget)]>;           // FPR = ST(0)
 132
 133 def FpSETRESULT32 : FpI_<(outs), (ins RFP32:$src), SpecialFP,
 134                       [(X86fpset RFP32:$src)]>, Imp<[], [ST0]>;// ST(0) = FPR
 135
 136 def FpSETRESULT64 : FpI_<(outs), (ins RFP64:$src), SpecialFP,
 137                       [(X86fpset RFP64:$src)]>, Imp<[], [ST0]>;// ST(0) = FPR
 138
 139 // FpI - Floating Point Psuedo Instruction template. Predicated on FPStack.
 140 class FpI<dag outs, dag ins, FPFormat fp, list<dag> pattern> :
 141   FpI_<outs, ins, fp, pattern>, Requires<[FPStack]>;
 142
 143 // Register copies.  Just copies, the shortening ones do not truncate.
 144 def MOV_Fp3232       : FpI<(outs RFP32:$dst), (ins RFP32:$src), SpecialFP, []>;
 145 def MOV_Fp3264       : FpI<(outs RFP64:$dst), (ins RFP32:$src), SpecialFP, []>;
 146 def MOV_Fp6432       : FpI<(outs RFP32:$dst), (ins RFP64:$src), SpecialFP, []>;
 147 def MOV_Fp6464       : FpI<(outs RFP64:$dst), (ins RFP64:$src), SpecialFP, []>;
 148 def MOV_Fp8032       : FpI<(outs RFP32:$dst), (ins RFP80:$src), SpecialFP, []>;
 149 def MOV_Fp3280       : FpI<(outs RFP80:$dst), (ins RFP32:$src), SpecialFP, []>;
 150 def MOV_Fp8064       : FpI<(outs RFP64:$dst), (ins RFP80:$src), SpecialFP, []>;
 151 def MOV_Fp6480       : FpI<(outs RFP80:$dst), (ins RFP64:$src), SpecialFP, []>;
 152 def MOV_Fp8080       : FpI<(outs RFP80:$dst), (ins RFP80:$src), SpecialFP, []>;
 153
 154 // Factoring for arithmetic.
 155 multiclass FPBinary_rr<SDNode OpNode> {
 156 // Register op register -> register
 157 // These are separated out because they have no reversed form.
 158 def _Fp32 : FpI<(outs RFP32:$dst), (ins RFP32:$src1, RFP32:$src2), TwoArgFP,
 159                 [(set RFP32:$dst, (OpNode RFP32:$src1, RFP32:$src2))]>;
 160 def _Fp64 : FpI<(outs RFP64:$dst), (ins RFP64:$src1, RFP64:$src2), TwoArgFP,
 161                 [(set RFP64:$dst, (OpNode RFP64:$src1, RFP64:$src2))]>;
 162 def _Fp80 : FpI<(outs RFP80:$dst), (ins RFP80:$src1, RFP80:$src2), TwoArgFP,
 163                 [(set RFP80:$dst, (OpNode RFP80:$src1, RFP80:$src2))]>;
 164 }
 165 // The FopST0 series are not included here because of the irregularities
 166 // in where the 'r' goes in assembly output.
 167 // These instructions cannot address 80-bit memory.
 168 multiclass FPBinary<SDNode OpNode, Format fp, string asmstring> {
 169 // ST(0) = ST(0) + [mem]
 170 def _Fp32m  : FpI<(outs RFP32:$dst), (ins RFP32:$src1, f32mem:$src2), OneArgFPRW,
 171                   [(set RFP32:$dst,
 172                     (OpNode RFP32:$src1, (loadf32 addr:$src2)))]>;
 173 def _Fp64m  : FpI<(outs RFP64:$dst), (ins RFP64:$src1, f64mem:$src2), OneArgFPRW,
 174                   [(set RFP64:$dst,
 175                     (OpNode RFP64:$src1, (loadf64 addr:$src2)))]>;
 176 def _Fp64m32: FpI<(outs RFP64:$dst), (ins RFP64:$src1, f32mem:$src2), OneArgFPRW,
 177                   [(set RFP64:$dst,
 178                     (OpNode RFP64:$src1, (extloadf64f32 addr:$src2)))]>;
 179 def _Fp80m32: FpI<(outs RFP80:$dst), (ins RFP80:$src1, f32mem:$src2), OneArgFPRW,
 180                   [(set RFP80:$dst,
 181                     (OpNode RFP80:$src1, (extloadf80f32 addr:$src2)))]>;
 182 def _Fp80m64: FpI<(outs RFP80:$dst), (ins RFP80:$src1, f64mem:$src2), OneArgFPRW,
 183                   [(set RFP80:$dst,
 184                     (OpNode RFP80:$src1, (extloadf80f64 addr:$src2)))]>;
 185 def _F32m  : FPI<0xD8, fp, (outs), (ins f32mem:$src),
 186                  !strconcat("f", !strconcat(asmstring, "{s}\t$src"))>;
 187 def _F64m  : FPI<0xDC, fp, (outs), (ins f64mem:$src),
 188                  !strconcat("f", !strconcat(asmstring, "{l}\t$src"))>;
 189 // ST(0) = ST(0) + [memint]
 190 def _FpI16m32 : FpI<(outs RFP32:$dst), (ins RFP32:$src1, i16mem:$src2), OneArgFPRW,
 191                     [(set RFP32:$dst, (OpNode RFP32:$src1,
 192                                        (X86fild addr:$src2, i16)))]>;
 193 def _FpI32m32 : FpI<(outs RFP32:$dst), (ins RFP32:$src1, i32mem:$src2), OneArgFPRW,
 194                     [(set RFP32:$dst, (OpNode RFP32:$src1,
 195                                        (X86fild addr:$src2, i32)))]>;
 196 def _FpI16m64 : FpI<(outs RFP64:$dst), (ins RFP64:$src1, i16mem:$src2), OneArgFPRW,
 197                     [(set RFP64:$dst, (OpNode RFP64:$src1,
 198                                        (X86fild addr:$src2, i16)))]>;
 199 def _FpI32m64 : FpI<(outs RFP64:$dst), (ins RFP64:$src1, i32mem:$src2), OneArgFPRW,
 200                     [(set RFP64:$dst, (OpNode RFP64:$src1,
 201                                        (X86fild addr:$src2, i32)))]>;
 202 def _FpI16m80 : FpI<(outs RFP80:$dst), (ins RFP80:$src1, i16mem:$src2), OneArgFPRW,
 203                     [(set RFP80:$dst, (OpNode RFP80:$src1,
 204                                        (X86fild addr:$src2, i16)))]>;
 205 def _FpI32m80 : FpI<(outs RFP80:$dst), (ins RFP80:$src1, i32mem:$src2), OneArgFPRW,
 206                     [(set RFP80:$dst, (OpNode RFP80:$src1,
 207                                        (X86fild addr:$src2, i32)))]>;
 208 def _FI16m  : FPI<0xDE, fp, (outs), (ins i16mem:$src),
 209                   !strconcat("fi", !strconcat(asmstring, "{s}\t$src"))>;
 210 def _FI32m  : FPI<0xDA, fp, (outs), (ins i32mem:$src),
 211                   !strconcat("fi", !strconcat(asmstring, "{l}\t$src"))>;
 212 }
 213
 214 defm ADD : FPBinary_rr<fadd>;
 215 defm SUB : FPBinary_rr<fsub>;
 216 defm MUL : FPBinary_rr<fmul>;
 217 defm DIV : FPBinary_rr<fdiv>;
 218 defm ADD : FPBinary<fadd, MRM0m, "add">;
 219 defm SUB : FPBinary<fsub, MRM4m, "sub">;
 220 defm SUBR: FPBinary<fsub ,MRM5m, "subr">;
 221 defm MUL : FPBinary<fmul, MRM1m, "mul">;
 222 defm DIV : FPBinary<fdiv, MRM6m, "div">;
 223 defm DIVR: FPBinary<fdiv, MRM7m, "divr">;
 224
 225 class FPST0rInst<bits<8> o, string asm>
 226   : FPI<o, AddRegFrm, (outs), (ins RST:$op), asm>, D8;
 227 class FPrST0Inst<bits<8> o, string asm>
 228   : FPI<o, AddRegFrm, (outs), (ins RST:$op), asm>, DC;
 229 class FPrST0PInst<bits<8> o, string asm>
 230   : FPI<o, AddRegFrm, (outs), (ins RST:$op), asm>, DE;
 231
 232 // NOTE: GAS and apparently all other AT&T style assemblers have a broken notion
 233 // of some of the 'reverse' forms of the fsub and fdiv instructions.  As such,
 234 // we have to put some 'r's in and take them out of weird places.
 235 def ADD_FST0r   : FPST0rInst <0xC0, "fadd\t$op">;
 236 def ADD_FrST0   : FPrST0Inst <0xC0, "fadd\t{%st(0), $op|$op, %ST(0)}">;
 237 def ADD_FPrST0  : FPrST0PInst<0xC0, "faddp\t$op">;
 238 def SUBR_FST0r  : FPST0rInst <0xE8, "fsubr\t$op">;
 239 def SUB_FrST0   : FPrST0Inst <0xE8, "fsub{r}\t{%st(0), $op|$op, %ST(0)}">;
 240 def SUB_FPrST0  : FPrST0PInst<0xE8, "fsub{r}p\t$op">;
 241 def SUB_FST0r   : FPST0rInst <0xE0, "fsub\t$op">;
 242 def SUBR_FrST0  : FPrST0Inst <0xE0, "fsub{|r}\t{%st(0), $op|$op, %ST(0)}">;
 243 def SUBR_FPrST0 : FPrST0PInst<0xE0, "fsub{|r}p\t$op">;
 244 def MUL_FST0r   : FPST0rInst <0xC8, "fmul\t$op">;
 245 def MUL_FrST0   : FPrST0Inst <0xC8, "fmul\t{%st(0), $op|$op, %ST(0)}">;
 246 def MUL_FPrST0  : FPrST0PInst<0xC8, "fmulp\t$op">;
 247 def DIVR_FST0r  : FPST0rInst <0xF8, "fdivr\t$op">;
 248 def DIV_FrST0   : FPrST0Inst <0xF8, "fdiv{r}\t{%st(0), $op|$op, %ST(0)}">;
 249 def DIV_FPrST0  : FPrST0PInst<0xF8, "fdiv{r}p\t$op">;
 250 def DIV_FST0r   : FPST0rInst <0xF0, "fdiv\t$op">;
 251 def DIVR_FrST0  : FPrST0Inst <0xF0, "fdiv{|r}\t{%st(0), $op|$op, %ST(0)}">;
 252 def DIVR_FPrST0 : FPrST0PInst<0xF0, "fdiv{|r}p\t$op">;
 253
 254 // Unary operations.
 255 multiclass FPUnary<SDNode OpNode, bits<8> opcode, string asmstring> {
 256 def _Fp32  : FpI<(outs RFP32:$dst), (ins RFP32:$src), OneArgFPRW,
 257                  [(set RFP32:$dst, (OpNode RFP32:$src))]>;
 258 def _Fp64  : FpI<(outs RFP64:$dst), (ins RFP64:$src), OneArgFPRW,
 259                  [(set RFP64:$dst, (OpNode RFP64:$src))]>;
 260 def _Fp80  : FpI<(outs RFP80:$dst), (ins RFP80:$src), OneArgFPRW,
 261                  [(set RFP80:$dst, (OpNode RFP80:$src))]>;
 262 def _F     : FPI<opcode, RawFrm, (outs), (ins), asmstring>, D9;
 263 }
 264
 265 defm CHS : FPUnary<fneg, 0xE0, "fchs">;
 266 defm ABS : FPUnary<fabs, 0xE1, "fabs">;
 267 defm SQRT: FPUnary<fsqrt,0xFA, "fsqrt">;
 268 defm SIN : FPUnary<fsin, 0xFE, "fsin">;
 269 defm COS : FPUnary<fcos, 0xFF, "fcos">;
 270
 271 def TST_Fp32  : FpI<(outs), (ins RFP32:$src), OneArgFP,
 272                  []>;
 273 def TST_Fp64  : FpI<(outs), (ins RFP64:$src), OneArgFP,
 274                  []>;
 275 def TST_Fp80  : FpI<(outs), (ins RFP80:$src), OneArgFP,
 276                  []>;
 277 def TST_F  : FPI<0xE4, RawFrm, (outs), (ins), "ftst">, D9;
 278
 279 // Floating point cmovs.
 280 multiclass FPCMov<PatLeaf cc> {
 281   def _Fp32  : FpI<(outs RFP32:$dst), (ins RFP32:$src1, RFP32:$src2), CondMovFP,
 282                      [(set RFP32:$dst, (X86cmov RFP32:$src1, RFP32:$src2,
 283                                         cc))]>;
 284   def _Fp64  : FpI<(outs RFP64:$dst), (ins RFP64:$src1, RFP64:$src2), CondMovFP,
 285                      [(set RFP64:$dst, (X86cmov RFP64:$src1, RFP64:$src2,
 286                                         cc))]>;
 287   def _Fp80  : FpI<(outs RFP80:$dst), (ins RFP80:$src1, RFP80:$src2), CondMovFP,
 288                      [(set RFP80:$dst, (X86cmov RFP80:$src1, RFP80:$src2,
 289                                         cc))]>;
 290 }
 291 let isTwoAddress = 1 in {
 292 defm CMOVB  : FPCMov<X86_COND_B>;
 293 defm CMOVBE : FPCMov<X86_COND_BE>;
 294 defm CMOVE  : FPCMov<X86_COND_E>;
 295 defm CMOVP  : FPCMov<X86_COND_P>;
 296 defm CMOVNB : FPCMov<X86_COND_AE>;
 297 defm CMOVNBE: FPCMov<X86_COND_A>;
 298 defm CMOVNE : FPCMov<X86_COND_NE>;
 299 defm CMOVNP : FPCMov<X86_COND_NP>;
 300 }
 301
 302 // These are not factored because there's no clean way to pass DA/DB.
 303 def CMOVB_F  : FPI<0xC0, AddRegFrm, (outs RST:$op), (ins),
 304                   "fcmovb\t{$op, %st(0)|%ST(0), $op}">, DA;
 305 def CMOVBE_F : FPI<0xD0, AddRegFrm, (outs RST:$op), (ins),
 306                   "fcmovbe\t{$op, %st(0)|%ST(0), $op}">, DA;
 307 def CMOVE_F  : FPI<0xC8, AddRegFrm, (outs RST:$op), (ins),
 308                   "fcmove\t{$op, %st(0)|%ST(0), $op}">, DA;
 309 def CMOVP_F  : FPI<0xD8, AddRegFrm, (outs RST:$op), (ins),
 310                   "fcmovu\t {$op, %st(0)|%ST(0), $op}">, DA;
 311 def CMOVNB_F : FPI<0xC0, AddRegFrm, (outs RST:$op), (ins),
 312                   "fcmovnb\t{$op, %st(0)|%ST(0), $op}">, DB;
 313 def CMOVNBE_F: FPI<0xD0, AddRegFrm, (outs RST:$op), (ins),
 314                   "fcmovnbe\t{$op, %st(0)|%ST(0), $op}">, DB;
 315 def CMOVNE_F : FPI<0xC8, AddRegFrm, (outs RST:$op), (ins),
 316                   "fcmovne\t{$op, %st(0)|%ST(0), $op}">, DB;
 317 def CMOVNP_F : FPI<0xD8, AddRegFrm, (outs RST:$op), (ins),
 318                   "fcmovnu\t{$op, %st(0)|%ST(0), $op}">, DB;
 319
 320 // Floating point loads & stores.
 321 def LD_Fp32m   : FpI<(outs RFP32:$dst), (ins f32mem:$src), ZeroArgFP,
 322                   [(set RFP32:$dst, (loadf32 addr:$src))]>;
 323 def LD_Fp64m   : FpI<(outs RFP64:$dst), (ins f64mem:$src), ZeroArgFP,
 324                   [(set RFP64:$dst, (loadf64 addr:$src))]>;
 325 def LD_Fp80m   : FpI<(outs RFP80:$dst), (ins f80mem:$src), ZeroArgFP,
 326                   [(set RFP80:$dst, (loadf80 addr:$src))]>;
 327 def ILD_Fp16m32: FpI<(outs RFP32:$dst), (ins i16mem:$src), ZeroArgFP,
 328                   [(set RFP32:$dst, (X86fild addr:$src, i16))]>;
 329 def ILD_Fp32m32: FpI<(outs RFP32:$dst), (ins i32mem:$src), ZeroArgFP,
 330                   [(set RFP32:$dst, (X86fild addr:$src, i32))]>;
 331 def ILD_Fp64m32: FpI<(outs RFP32:$dst), (ins i64mem:$src), ZeroArgFP,
 332                   [(set RFP32:$dst, (X86fild addr:$src, i64))]>;
 333 def ILD_Fp16m64: FpI<(outs RFP64:$dst), (ins i16mem:$src), ZeroArgFP,
 334                   [(set RFP64:$dst, (X86fild addr:$src, i16))]>;
 335 def ILD_Fp32m64: FpI<(outs RFP64:$dst), (ins i32mem:$src), ZeroArgFP,
 336                   [(set RFP64:$dst, (X86fild addr:$src, i32))]>;
 337 def ILD_Fp64m64: FpI<(outs RFP64:$dst), (ins i64mem:$src), ZeroArgFP,
 338                   [(set RFP64:$dst, (X86fild addr:$src, i64))]>;
 339 def ILD_Fp16m80: FpI<(outs RFP80:$dst), (ins i16mem:$src), ZeroArgFP,
 340                   [(set RFP80:$dst, (X86fild addr:$src, i16))]>;
 341 def ILD_Fp32m80: FpI<(outs RFP80:$dst), (ins i32mem:$src), ZeroArgFP,
 342                   [(set RFP80:$dst, (X86fild addr:$src, i32))]>;
 343 def ILD_Fp64m80: FpI<(outs RFP80:$dst), (ins i64mem:$src), ZeroArgFP,
 344                   [(set RFP80:$dst, (X86fild addr:$src, i64))]>;
 345
 346 def ST_Fp32m   : FpI<(outs), (ins f32mem:$op, RFP32:$src), OneArgFP,
 347                   [(store RFP32:$src, addr:$op)]>;
 348 def ST_Fp64m32 : FpI<(outs), (ins f32mem:$op, RFP64:$src), OneArgFP,
 349                   [(truncstoref32 RFP64:$src, addr:$op)]>;
 350 def ST_Fp64m   : FpI<(outs), (ins f64mem:$op, RFP64:$src), OneArgFP,
 351                   [(store RFP64:$src, addr:$op)]>;
 352 def ST_Fp80m32 : FpI<(outs), (ins f32mem:$op, RFP80:$src), OneArgFP,
 353                   [(truncstoref32 RFP80:$src, addr:$op)]>;
 354 def ST_Fp80m64 : FpI<(outs), (ins f64mem:$op, RFP80:$src), OneArgFP,
 355                   [(truncstoref64 RFP80:$src, addr:$op)]>;
 356 // FST does not support 80-bit memory target; FSTP must be used.
 357
 358 def ST_FpP32m    : FpI<(outs), (ins f32mem:$op, RFP32:$src), OneArgFP, []>;
 359 def ST_FpP64m32  : FpI<(outs), (ins f32mem:$op, RFP64:$src), OneArgFP, []>;
 360 def ST_FpP64m    : FpI<(outs), (ins f64mem:$op, RFP64:$src), OneArgFP, []>;
 361 def ST_FpP80m32  : FpI<(outs), (ins f32mem:$op, RFP80:$src), OneArgFP, []>;
 362 def ST_FpP80m64  : FpI<(outs), (ins f64mem:$op, RFP80:$src), OneArgFP, []>;
 363 def ST_FpP80m    : FpI<(outs), (ins f80mem:$op, RFP80:$src), OneArgFP,
 364                     [(store RFP80:$src, addr:$op)]>;
 365 def IST_Fp16m32  : FpI<(outs), (ins i16mem:$op, RFP32:$src), OneArgFP, []>;
 366 def IST_Fp32m32  : FpI<(outs), (ins i32mem:$op, RFP32:$src), OneArgFP, []>;
 367 def IST_Fp64m32  : FpI<(outs), (ins i64mem:$op, RFP32:$src), OneArgFP, []>;
 368 def IST_Fp16m64  : FpI<(outs), (ins i16mem:$op, RFP64:$src), OneArgFP, []>;
 369 def IST_Fp32m64  : FpI<(outs), (ins i32mem:$op, RFP64:$src), OneArgFP, []>;
 370 def IST_Fp64m64  : FpI<(outs), (ins i64mem:$op, RFP64:$src), OneArgFP, []>;
 371 def IST_Fp16m80  : FpI<(outs), (ins i16mem:$op, RFP80:$src), OneArgFP, []>;
 372 def IST_Fp32m80  : FpI<(outs), (ins i32mem:$op, RFP80:$src), OneArgFP, []>;
 373 def IST_Fp64m80  : FpI<(outs), (ins i64mem:$op, RFP80:$src), OneArgFP, []>;
 374
 375 def LD_F32m   : FPI<0xD9, MRM0m, (outs), (ins f32mem:$src), "fld{s}\t$src">;
 376 def LD_F64m   : FPI<0xDD, MRM0m, (outs), (ins f64mem:$src), "fld{l}\t$src">;
 377 def LD_F80m   : FPI<0xDB, MRM5m, (outs), (ins f80mem:$src), "fld{t}\t$src">;
 378 def ILD_F16m  : FPI<0xDF, MRM0m, (outs), (ins i16mem:$src), "fild{s}\t$src">;
 379 def ILD_F32m  : FPI<0xDB, MRM0m, (outs), (ins i32mem:$src), "fild{l}\t$src">;
 380 def ILD_F64m  : FPI<0xDF, MRM5m, (outs), (ins i64mem:$src), "fild{ll}\t$src">;
 381 def ST_F32m   : FPI<0xD9, MRM2m, (outs), (ins f32mem:$dst), "fst{s}\t$dst">;
 382 def ST_F64m   : FPI<0xDD, MRM2m, (outs), (ins f64mem:$dst), "fst{l}\t$dst">;
 383 def ST_FP32m  : FPI<0xD9, MRM3m, (outs), (ins f32mem:$dst), "fstp{s}\t$dst">;
 384 def ST_FP64m  : FPI<0xDD, MRM3m, (outs), (ins f64mem:$dst), "fstp{l}\t$dst">;
 385 def ST_FP80m  : FPI<0xDB, MRM7m, (outs), (ins f80mem:$dst), "fstp{t}\t$dst">;
 386 def IST_F16m  : FPI<0xDF, MRM2m, (outs), (ins i16mem:$dst), "fist{s}\t$dst">;
 387 def IST_F32m  : FPI<0xDB, MRM2m, (outs), (ins i32mem:$dst), "fist{l}\t$dst">;
 388 def IST_FP16m : FPI<0xDF, MRM3m, (outs), (ins i16mem:$dst), "fistp{s}\t$dst">;
 389 def IST_FP32m : FPI<0xDB, MRM3m, (outs), (ins i32mem:$dst), "fistp{l}\t$dst">;
 390 def IST_FP64m : FPI<0xDF, MRM7m, (outs), (ins i64mem:$dst), "fistp{ll}\t$dst">;
 391
 392 // FISTTP requires SSE3 even though it's a FPStack op.
 393 def ISTT_Fp16m32 : FpI_<(outs), (ins i16mem:$op, RFP32:$src), OneArgFP,
 394                     [(X86fp_to_i16mem RFP32:$src, addr:$op)]>,
 395                     Requires<[HasSSE3]>;
 396 def ISTT_Fp32m32 : FpI_<(outs), (ins i32mem:$op, RFP32:$src), OneArgFP,
 397                     [(X86fp_to_i32mem RFP32:$src, addr:$op)]>,
 398                     Requires<[HasSSE3]>;
 399 def ISTT_Fp64m32 : FpI_<(outs), (ins i64mem:$op, RFP32:$src), OneArgFP,
 400                     [(X86fp_to_i64mem RFP32:$src, addr:$op)]>,
 401                     Requires<[HasSSE3]>;
 402 def ISTT_Fp16m64 : FpI_<(outs), (ins i16mem:$op, RFP64:$src), OneArgFP,
 403                     [(X86fp_to_i16mem RFP64:$src, addr:$op)]>,
 404                     Requires<[HasSSE3]>;
 405 def ISTT_Fp32m64 : FpI_<(outs), (ins i32mem:$op, RFP64:$src), OneArgFP,
 406                     [(X86fp_to_i32mem RFP64:$src, addr:$op)]>,
 407                     Requires<[HasSSE3]>;
 408 def ISTT_Fp64m64 : FpI_<(outs), (ins i64mem:$op, RFP64:$src), OneArgFP,
 409                     [(X86fp_to_i64mem RFP64:$src, addr:$op)]>,
 410                     Requires<[HasSSE3]>;
 411
 412 def ISTT_FP16m : FPI<0xDF, MRM1m, (outs), (ins i16mem:$dst), "fisttp{s}\t$dst">;
 413 def ISTT_FP32m : FPI<0xDB, MRM1m, (outs), (ins i32mem:$dst), "fisttp{l}\t$dst">;
 414 def ISTT_FP64m : FPI<0xDD, MRM1m, (outs), (ins i64mem:$dst), "fisttp{ll}\t$dst">;
 415
 416 // FP Stack manipulation instructions.
 417 def LD_Frr   : FPI<0xC0, AddRegFrm, (outs), (ins RST:$op), "fld\t$op">, D9;
 418 def ST_Frr   : FPI<0xD0, AddRegFrm, (outs), (ins RST:$op), "fst\t$op">, DD;
 419 def ST_FPrr  : FPI<0xD8, AddRegFrm, (outs), (ins RST:$op), "fstp\t$op">, DD;
 420 def XCH_F    : FPI<0xC8, AddRegFrm, (outs), (ins RST:$op), "fxch\t$op">, D9;
 421
 422 // Floating point constant loads.
 423 let isReMaterializable = 1 in {
 424 def LD_Fp032 : FpI<(outs RFP32:$dst), (ins), ZeroArgFP,
 425                 [(set RFP32:$dst, fpimm0)]>;
 426 def LD_Fp132 : FpI<(outs RFP32:$dst), (ins), ZeroArgFP,
 427                 [(set RFP32:$dst, fpimm1)]>;
 428 def LD_Fp064 : FpI<(outs RFP64:$dst), (ins), ZeroArgFP,
 429                 [(set RFP64:$dst, fpimm0)]>;
 430 def LD_Fp164 : FpI<(outs RFP64:$dst), (ins), ZeroArgFP,
 431                 [(set RFP64:$dst, fpimm1)]>;
 432 def LD_Fp080 : FpI<(outs RFP80:$dst), (ins), ZeroArgFP,
 433                 [(set RFP80:$dst, fpimm0)]>;
 434 def LD_Fp180 : FpI<(outs RFP80:$dst), (ins), ZeroArgFP,
 435                 [(set RFP80:$dst, fpimm1)]>;
 436 }
 437
 438 def LD_F0 : FPI<0xEE, RawFrm, (outs), (ins), "fldz">, D9;
 439 def LD_F1 : FPI<0xE8, RawFrm, (outs), (ins), "fld1">, D9;
 440
 441
 442 // Floating point compares.
 443 def UCOM_Fpr32 : FpI<(outs), (ins RFP32:$lhs, RFP32:$rhs), CompareFP,
 444                   []>;  // FPSW = cmp ST(0) with ST(i)
 445 def UCOM_FpIr32: FpI<(outs), (ins RFP32:$lhs, RFP32:$rhs), CompareFP,
 446                   [(X86cmp RFP32:$lhs, RFP32:$rhs)]>; // CC = ST(0) cmp ST(i)
 447 def UCOM_Fpr64 : FpI<(outs), (ins RFP64:$lhs, RFP64:$rhs), CompareFP,
 448                   []>;  // FPSW = cmp ST(0) with ST(i)
 449 def UCOM_FpIr64: FpI<(outs), (ins RFP64:$lhs, RFP64:$rhs), CompareFP,
 450                   [(X86cmp RFP64:$lhs, RFP64:$rhs)]>; // CC = ST(0) cmp ST(i)
 451 def UCOM_Fpr80 : FpI<(outs), (ins RFP80:$lhs, RFP80:$rhs), CompareFP,
 452                   []>;  // FPSW = cmp ST(0) with ST(i)
 453 def UCOM_FpIr80: FpI<(outs), (ins RFP80:$lhs, RFP80:$rhs), CompareFP,
 454                   [(X86cmp RFP80:$lhs, RFP80:$rhs)]>; // CC = ST(0) cmp ST(i)
 455
 456 def UCOM_Fr    : FPI<0xE0, AddRegFrm,    // FPSW = cmp ST(0) with ST(i)
 457                     (outs), (ins RST:$reg),
 458                     "fucom\t$reg">, DD, Imp<[ST0],[]>;
 459 def UCOM_FPr   : FPI<0xE8, AddRegFrm,    // FPSW = cmp ST(0) with ST(i), pop
 460                     (outs), (ins RST:$reg),
 461                     "fucomp\t$reg">, DD, Imp<[ST0],[]>;
 462 def UCOM_FPPr  : FPI<0xE9, RawFrm,       // cmp ST(0) with ST(1), pop, pop
 463                     (outs), (ins),
 464                     "fucompp">, DA, Imp<[ST0],[]>;
 465
 466 def UCOM_FIr   : FPI<0xE8, AddRegFrm,     // CC = cmp ST(0) with ST(i)
 467                     (outs), (ins RST:$reg),
 468                     "fucomi\t{$reg, %st(0)|%ST(0), $reg}">, DB, Imp<[ST0],[]>;
 469 def UCOM_FIPr  : FPI<0xE8, AddRegFrm,     // CC = cmp ST(0) with ST(i), pop
 470                     (outs), (ins RST:$reg),
 471                     "fucomip\t{$reg, %st(0)|%ST(0), $reg}">, DF, Imp<[ST0],[]>;
 472
 473 // Floating point flag ops.
 474 def FNSTSW8r  : I<0xE0, RawFrm,                  // AX = fp flags
 475                   (outs), (ins), "fnstsw", []>, DF, Imp<[],[AX]>;
 476
 477 def FNSTCW16m : I<0xD9, MRM7m,                   // [mem16] = X87 control world
 478                   (outs), (ins i16mem:$dst), "fnstcw\t$dst", []>;
 479 def FLDCW16m  : I<0xD9, MRM5m,                   // X87 control world = [mem16]
 480                   (outs), (ins i16mem:$dst), "fldcw\t$dst", []>;
 481
 482 //===----------------------------------------------------------------------===//
 483 // Non-Instruction Patterns
 484 //===----------------------------------------------------------------------===//
 485
 486 // Required for RET of f32 / f64 values.
 487 def : Pat<(X86fld addr:$src, f32), (LD_Fp32m addr:$src)>;
 488 def : Pat<(X86fld addr:$src, f64), (LD_Fp64m addr:$src)>;
 489 def : Pat<(X86fld addr:$src, f80), (LD_Fp80m addr:$src)>;
 490
 491 // Required for CALL which return f32 / f64 values.
 492 def : Pat<(X86fst RFP32:$src, addr:$op, f32), (ST_Fp32m addr:$op, RFP32:$src)>;
 493 def : Pat<(X86fst RFP64:$src, addr:$op, f32), (ST_Fp64m32 addr:$op, RFP64:$src)>;
 494 def : Pat<(X86fst RFP64:$src, addr:$op, f64), (ST_Fp64m addr:$op, RFP64:$src)>;
 495
 496 // Floating point constant -0.0 and -1.0
 497 def : Pat<(f32 fpimmneg0), (CHS_Fp32 (LD_Fp032))>, Requires<[FPStack]>;
 498 def : Pat<(f32 fpimmneg1), (CHS_Fp32 (LD_Fp132))>, Requires<[FPStack]>;
 499 def : Pat<(f64 fpimmneg0), (CHS_Fp64 (LD_Fp064))>, Requires<[FPStack]>;
 500 def : Pat<(f64 fpimmneg1), (CHS_Fp64 (LD_Fp164))>, Requires<[FPStack]>;
 501 def : Pat<(f80 fpimmneg0), (CHS_Fp80 (LD_Fp080))>, Requires<[FPStack]>;
 502 def : Pat<(f80 fpimmneg1), (CHS_Fp80 (LD_Fp180))>, Requires<[FPStack]>;
 503
 504 // Used to conv. i64 to f64 since there isn't a SSE version.
 505 def : Pat<(X86fildflag addr:$src, i64), (ILD_Fp64m64 addr:$src)>;
 506
 507 def : Pat<(extloadf80f32 addr:$src),
 508            (MOV_Fp3280 (LD_Fp32m addr:$src))>, Requires<[FPStack]>;
 509 def : Pat<(extloadf80f64 addr:$src),
 510            (MOV_Fp6480 (LD_Fp64m addr:$src))>, Requires<[FPStack]>;
 511 def : Pat<(extloadf64f32 addr:$src),
 512            (MOV_Fp3264 (LD_Fp32m addr:$src))>, Requires<[FPStack]>;
 513
 514 def : Pat<(f64 (fextend RFP32:$src)), (MOV_Fp3264 RFP32:$src)>, Requires<[FPStack]>;
 515 def : Pat<(f80 (fextend RFP32:$src)), (MOV_Fp3280 RFP32:$src)>, Requires<[FPStack]>;
 516 def : Pat<(f80 (fextend RFP64:$src)), (MOV_Fp6480 RFP64:$src)>, Requires<[FPStack]>;