lib/Target/X86/X86InstrFPStack.td

   1 //==- X86InstrFPStack.td - Describe the X86 Instruction Set --*- tablegen -*-=//
   2 //
   3 //                     The LLVM Compiler Infrastructure
   4 //
   5 // This file is distributed under the University of Illinois Open Source
   6 // License. See LICENSE.TXT for details.
   7 //
   8 //===----------------------------------------------------------------------===//
   9 //
  10 // This file describes the X86 x87 FPU instruction set, defining the
  11 // instructions, and properties of the instructions which are needed for code
  12 // generation, machine code emission, and analysis.
  13 //
  14 //===----------------------------------------------------------------------===//
  15
  16 //===----------------------------------------------------------------------===//
  17 // FPStack specific DAG Nodes.
  18 //===----------------------------------------------------------------------===//
  19
  20 def SDTX86FpGet2    : SDTypeProfile<2, 0, [SDTCisVT<0, f80>,
  21                                            SDTCisVT<1, f80>]>;
  22 def SDTX86Fld       : SDTypeProfile<1, 2, [SDTCisFP<0>,
  23                                            SDTCisPtrTy<1>,
  24                                            SDTCisVT<2, OtherVT>]>;
  25 def SDTX86Fst       : SDTypeProfile<0, 3, [SDTCisFP<0>,
  26                                            SDTCisPtrTy<1>,
  27                                            SDTCisVT<2, OtherVT>]>;
  28 def SDTX86Fild      : SDTypeProfile<1, 2, [SDTCisFP<0>, SDTCisPtrTy<1>,
  29                                            SDTCisVT<2, OtherVT>]>;
  30 def SDTX86FpToIMem  : SDTypeProfile<0, 2, [SDTCisFP<0>, SDTCisPtrTy<1>]>;
  31
  32 def SDTX86CwdStore  : SDTypeProfile<0, 1, [SDTCisPtrTy<0>]>;
  33
  34 def X86fld          : SDNode<"X86ISD::FLD", SDTX86Fld,
  35                              [SDNPHasChain, SDNPMayLoad]>;
  36 def X86fst          : SDNode<"X86ISD::FST", SDTX86Fst,
  37                              [SDNPHasChain, SDNPInFlag, SDNPMayStore]>;
  38 def X86fild         : SDNode<"X86ISD::FILD", SDTX86Fild,
  39                              [SDNPHasChain, SDNPMayLoad]>;
  40 def X86fildflag     : SDNode<"X86ISD::FILD_FLAG", SDTX86Fild,
  41                              [SDNPHasChain, SDNPOutFlag, SDNPMayLoad]>;
  42 def X86fp_to_i16mem : SDNode<"X86ISD::FP_TO_INT16_IN_MEM", SDTX86FpToIMem,
  43                              [SDNPHasChain, SDNPMayStore]>;
  44 def X86fp_to_i32mem : SDNode<"X86ISD::FP_TO_INT32_IN_MEM", SDTX86FpToIMem,
  45                              [SDNPHasChain, SDNPMayStore]>;
  46 def X86fp_to_i64mem : SDNode<"X86ISD::FP_TO_INT64_IN_MEM", SDTX86FpToIMem,
  47                              [SDNPHasChain, SDNPMayStore]>;
  48 def X86fp_cwd_get16 : SDNode<"X86ISD::FNSTCW16m",          SDTX86CwdStore,
  49                              [SDNPHasChain, SDNPMayStore, SDNPSideEffect]>;
  50
  51 //===----------------------------------------------------------------------===//
  52 // FPStack pattern fragments
  53 //===----------------------------------------------------------------------===//
  54
  55 def fpimm0 : PatLeaf<(fpimm), [{
  56   return N->isExactlyValue(+0.0);
  57 }]>;
  58
  59 def fpimmneg0 : PatLeaf<(fpimm), [{
  60   return N->isExactlyValue(-0.0);
  61 }]>;
  62
  63 def fpimm1 : PatLeaf<(fpimm), [{
  64   return N->isExactlyValue(+1.0);
  65 }]>;
  66
  67 def fpimmneg1 : PatLeaf<(fpimm), [{
  68   return N->isExactlyValue(-1.0);
  69 }]>;
  70
  71 // Some 'special' instructions
  72 let usesCustomDAGSchedInserter = 1 in {  // Expanded by the scheduler.
  73   def FP32_TO_INT16_IN_MEM : I<0, Pseudo,
  74                               (outs), (ins i16mem:$dst, RFP32:$src),
  75                               "#FP32_TO_INT16_IN_MEM PSEUDO!",
  76                               [(X86fp_to_i16mem RFP32:$src, addr:$dst)]>;
  77   def FP32_TO_INT32_IN_MEM : I<0, Pseudo,
  78                               (outs), (ins i32mem:$dst, RFP32:$src),
  79                               "#FP32_TO_INT32_IN_MEM PSEUDO!",
  80                               [(X86fp_to_i32mem RFP32:$src, addr:$dst)]>;
  81   def FP32_TO_INT64_IN_MEM : I<0, Pseudo,
  82                               (outs), (ins i64mem:$dst, RFP32:$src),
  83                               "#FP32_TO_INT64_IN_MEM PSEUDO!",
  84                               [(X86fp_to_i64mem RFP32:$src, addr:$dst)]>;
  85   def FP64_TO_INT16_IN_MEM : I<0, Pseudo,
  86                               (outs), (ins i16mem:$dst, RFP64:$src),
  87                               "#FP64_TO_INT16_IN_MEM PSEUDO!",
  88                               [(X86fp_to_i16mem RFP64:$src, addr:$dst)]>;
  89   def FP64_TO_INT32_IN_MEM : I<0, Pseudo,
  90                               (outs), (ins i32mem:$dst, RFP64:$src),
  91                               "#FP64_TO_INT32_IN_MEM PSEUDO!",
  92                               [(X86fp_to_i32mem RFP64:$src, addr:$dst)]>;
  93   def FP64_TO_INT64_IN_MEM : I<0, Pseudo,
  94                               (outs), (ins i64mem:$dst, RFP64:$src),
  95                               "#FP64_TO_INT64_IN_MEM PSEUDO!",
  96                               [(X86fp_to_i64mem RFP64:$src, addr:$dst)]>;
  97   def FP80_TO_INT16_IN_MEM : I<0, Pseudo,
  98                               (outs), (ins i16mem:$dst, RFP80:$src),
  99                               "#FP80_TO_INT16_IN_MEM PSEUDO!",
 100                               [(X86fp_to_i16mem RFP80:$src, addr:$dst)]>;
 101   def FP80_TO_INT32_IN_MEM : I<0, Pseudo,
 102                               (outs), (ins i32mem:$dst, RFP80:$src),
 103                               "#FP80_TO_INT32_IN_MEM PSEUDO!",
 104                               [(X86fp_to_i32mem RFP80:$src, addr:$dst)]>;
 105   def FP80_TO_INT64_IN_MEM : I<0, Pseudo,
 106                               (outs), (ins i64mem:$dst, RFP80:$src),
 107                               "#FP80_TO_INT64_IN_MEM PSEUDO!",
 108                               [(X86fp_to_i64mem RFP80:$src, addr:$dst)]>;
 109 }
 110
 111 let isTerminator = 1 in
 112   let Defs = [FP0, FP1, FP2, FP3, FP4, FP5, FP6] in
 113     def FP_REG_KILL  : I<0, Pseudo, (outs), (ins), "#FP_REG_KILL", []>;
 114
 115 // All FP Stack operations are represented with four instructions here.  The
 116 // first three instructions, generated by the instruction selector, use "RFP32"
 117 // "RFP64" or "RFP80" registers: traditional register files to reference 32-bit,
 118 // 64-bit or 80-bit floating point values.  These sizes apply to the values,
 119 // not the registers, which are always 80 bits; RFP32, RFP64 and RFP80 can be
 120 // copied to each other without losing information.  These instructions are all
 121 // pseudo instructions and use the "_Fp" suffix.
 122 // In some cases there are additional variants with a mixture of different
 123 // register sizes.
 124 // The second instruction is defined with FPI, which is the actual instruction
 125 // emitted by the assembler.  These use "RST" registers, although frequently
 126 // the actual register(s) used are implicit.  These are always 80 bits.
 127 // The FP stackifier pass converts one to the other after register allocation
 128 // occurs.
 129 //
 130 // Note that the FpI instruction should have instruction selection info (e.g.
 131 // a pattern) and the FPI instruction should have emission info (e.g. opcode
 132 // encoding and asm printing info).
 133
 134 // Pseudo Instructions for FP stack return values.
 135 def FpGET_ST0_32 : FpI_<(outs RFP32:$dst), (ins), SpecialFP, []>; // FPR = ST(0)
 136 def FpGET_ST0_64 : FpI_<(outs RFP64:$dst), (ins), SpecialFP, []>; // FPR = ST(0)
 137 def FpGET_ST0_80 : FpI_<(outs RFP80:$dst), (ins), SpecialFP, []>; // FPR = ST(0)
 138
 139 // FpGET_ST1* should only be issued *after* an FpGET_ST0* has been issued when
 140 // there are two values live out on the stack from a call or inlineasm.  This
 141 // magic is handled by the stackifier.  It is not valid to emit FpGET_ST1* and
 142 // then FpGET_ST0*.  In addition, it is invalid for any FP-using operations to
 143 // occur between them.
 144 def FpGET_ST1_32 : FpI_<(outs RFP32:$dst), (ins), SpecialFP, []>; // FPR = ST(1)
 145 def FpGET_ST1_64 : FpI_<(outs RFP64:$dst), (ins), SpecialFP, []>; // FPR = ST(1)
 146 def FpGET_ST1_80 : FpI_<(outs RFP80:$dst), (ins), SpecialFP, []>; // FPR = ST(1)
 147
 148 def FpGET_ST0_ST1 : FpI_<(outs RFP80:$dst1, RFP80:$dst2), (ins), SpecialFP,
 149                          []>;                        // FPR = ST(0), FPR = ST(1)
 150
 151
 152 let Defs = [ST0] in {
 153 def FpSET_ST0_32 : FpI_<(outs), (ins RFP32:$src), SpecialFP, []>; // ST(0) = FPR
 154 def FpSET_ST0_64 : FpI_<(outs), (ins RFP64:$src), SpecialFP, []>; // ST(0) = FPR
 155 def FpSET_ST0_80 : FpI_<(outs), (ins RFP80:$src), SpecialFP, []>; // ST(0) = FPR
 156 }
 157
 158 // FpIf32, FpIf64 - Floating Point Psuedo Instruction template.
 159 // f32 instructions can use SSE1 and are predicated on FPStackf32 == !SSE1.
 160 // f64 instructions can use SSE2 and are predicated on FPStackf64 == !SSE2.
 161 // f80 instructions cannot use SSE and use neither of these.
 162 class FpIf32<dag outs, dag ins, FPFormat fp, list<dag> pattern> :
 163   FpI_<outs, ins, fp, pattern>, Requires<[FPStackf32]>;
 164 class FpIf64<dag outs, dag ins, FPFormat fp, list<dag> pattern> :
 165   FpI_<outs, ins, fp, pattern>, Requires<[FPStackf64]>;
 166
 167 // Register copies.  Just copies, the shortening ones do not truncate.
 168 let neverHasSideEffects = 1 in {
 169   def MOV_Fp3232 : FpIf32<(outs RFP32:$dst), (ins RFP32:$src), SpecialFP, []>;
 170   def MOV_Fp3264 : FpIf32<(outs RFP64:$dst), (ins RFP32:$src), SpecialFP, []>;
 171   def MOV_Fp6432 : FpIf32<(outs RFP32:$dst), (ins RFP64:$src), SpecialFP, []>;
 172   def MOV_Fp6464 : FpIf64<(outs RFP64:$dst), (ins RFP64:$src), SpecialFP, []>;
 173   def MOV_Fp8032 : FpIf32<(outs RFP32:$dst), (ins RFP80:$src), SpecialFP, []>;
 174   def MOV_Fp3280 : FpIf32<(outs RFP80:$dst), (ins RFP32:$src), SpecialFP, []>;
 175   def MOV_Fp8064 : FpIf64<(outs RFP64:$dst), (ins RFP80:$src), SpecialFP, []>;
 176   def MOV_Fp6480 : FpIf64<(outs RFP80:$dst), (ins RFP64:$src), SpecialFP, []>;
 177   def MOV_Fp8080 : FpI_  <(outs RFP80:$dst), (ins RFP80:$src), SpecialFP, []>;
 178 }
 179
 180 // Factoring for arithmetic.
 181 multiclass FPBinary_rr<SDNode OpNode> {
 182 // Register op register -> register
 183 // These are separated out because they have no reversed form.
 184 def _Fp32 : FpIf32<(outs RFP32:$dst), (ins RFP32:$src1, RFP32:$src2), TwoArgFP,
 185                 [(set RFP32:$dst, (OpNode RFP32:$src1, RFP32:$src2))]>;
 186 def _Fp64 : FpIf64<(outs RFP64:$dst), (ins RFP64:$src1, RFP64:$src2), TwoArgFP,
 187                 [(set RFP64:$dst, (OpNode RFP64:$src1, RFP64:$src2))]>;
 188 def _Fp80 : FpI_<(outs RFP80:$dst), (ins RFP80:$src1, RFP80:$src2), TwoArgFP,
 189                 [(set RFP80:$dst, (OpNode RFP80:$src1, RFP80:$src2))]>;
 190 }
 191 // The FopST0 series are not included here because of the irregularities
 192 // in where the 'r' goes in assembly output.
 193 // These instructions cannot address 80-bit memory.
 194 multiclass FPBinary<SDNode OpNode, Format fp, string asmstring> {
 195 // ST(0) = ST(0) + [mem]
 196 def _Fp32m  : FpIf32<(outs RFP32:$dst), (ins RFP32:$src1, f32mem:$src2), OneArgFPRW,
 197                   [(set RFP32:$dst,
 198                     (OpNode RFP32:$src1, (loadf32 addr:$src2)))]>;
 199 def _Fp64m  : FpIf64<(outs RFP64:$dst), (ins RFP64:$src1, f64mem:$src2), OneArgFPRW,
 200                   [(set RFP64:$dst,
 201                     (OpNode RFP64:$src1, (loadf64 addr:$src2)))]>;
 202 def _Fp64m32: FpIf64<(outs RFP64:$dst), (ins RFP64:$src1, f32mem:$src2), OneArgFPRW,
 203                   [(set RFP64:$dst,
 204                     (OpNode RFP64:$src1, (f64 (extloadf32 addr:$src2))))]>;
 205 def _Fp80m32: FpI_<(outs RFP80:$dst), (ins RFP80:$src1, f32mem:$src2), OneArgFPRW,
 206                   [(set RFP80:$dst,
 207                     (OpNode RFP80:$src1, (f80 (extloadf32 addr:$src2))))]>;
 208 def _Fp80m64: FpI_<(outs RFP80:$dst), (ins RFP80:$src1, f64mem:$src2), OneArgFPRW,
 209                   [(set RFP80:$dst,
 210                     (OpNode RFP80:$src1, (f80 (extloadf64 addr:$src2))))]>;
 211 def _F32m  : FPI<0xD8, fp, (outs), (ins f32mem:$src),
 212                  !strconcat("f", !strconcat(asmstring, "{s}\t$src"))> { let mayLoad = 1; }
 213 def _F64m  : FPI<0xDC, fp, (outs), (ins f64mem:$src),
 214                  !strconcat("f", !strconcat(asmstring, "{l}\t$src"))> { let mayLoad = 1; }
 215 // ST(0) = ST(0) + [memint]
 216 def _FpI16m32 : FpIf32<(outs RFP32:$dst), (ins RFP32:$src1, i16mem:$src2), OneArgFPRW,
 217                     [(set RFP32:$dst, (OpNode RFP32:$src1,
 218                                        (X86fild addr:$src2, i16)))]>;
 219 def _FpI32m32 : FpIf32<(outs RFP32:$dst), (ins RFP32:$src1, i32mem:$src2), OneArgFPRW,
 220                     [(set RFP32:$dst, (OpNode RFP32:$src1,
 221                                        (X86fild addr:$src2, i32)))]>;
 222 def _FpI16m64 : FpIf64<(outs RFP64:$dst), (ins RFP64:$src1, i16mem:$src2), OneArgFPRW,
 223                     [(set RFP64:$dst, (OpNode RFP64:$src1,
 224                                        (X86fild addr:$src2, i16)))]>;
 225 def _FpI32m64 : FpIf64<(outs RFP64:$dst), (ins RFP64:$src1, i32mem:$src2), OneArgFPRW,
 226                     [(set RFP64:$dst, (OpNode RFP64:$src1,
 227                                        (X86fild addr:$src2, i32)))]>;
 228 def _FpI16m80 : FpI_<(outs RFP80:$dst), (ins RFP80:$src1, i16mem:$src2), OneArgFPRW,
 229                     [(set RFP80:$dst, (OpNode RFP80:$src1,
 230                                        (X86fild addr:$src2, i16)))]>;
 231 def _FpI32m80 : FpI_<(outs RFP80:$dst), (ins RFP80:$src1, i32mem:$src2), OneArgFPRW,
 232                     [(set RFP80:$dst, (OpNode RFP80:$src1,
 233                                        (X86fild addr:$src2, i32)))]>;
 234 def _FI16m  : FPI<0xDE, fp, (outs), (ins i16mem:$src),
 235                   !strconcat("fi", !strconcat(asmstring, "{s}\t$src"))> { let mayLoad = 1; }
 236 def _FI32m  : FPI<0xDA, fp, (outs), (ins i32mem:$src),
 237                   !strconcat("fi", !strconcat(asmstring, "{l}\t$src"))> { let mayLoad = 1; }
 238 }
 239
 240 defm ADD : FPBinary_rr<fadd>;
 241 defm SUB : FPBinary_rr<fsub>;
 242 defm MUL : FPBinary_rr<fmul>;
 243 defm DIV : FPBinary_rr<fdiv>;
 244 defm ADD : FPBinary<fadd, MRM0m, "add">;
 245 defm SUB : FPBinary<fsub, MRM4m, "sub">;
 246 defm SUBR: FPBinary<fsub ,MRM5m, "subr">;
 247 defm MUL : FPBinary<fmul, MRM1m, "mul">;
 248 defm DIV : FPBinary<fdiv, MRM6m, "div">;
 249 defm DIVR: FPBinary<fdiv, MRM7m, "divr">;
 250
 251 class FPST0rInst<bits<8> o, string asm>
 252   : FPI<o, AddRegFrm, (outs), (ins RST:$op), asm>, D8;
 253 class FPrST0Inst<bits<8> o, string asm>
 254   : FPI<o, AddRegFrm, (outs), (ins RST:$op), asm>, DC;
 255 class FPrST0PInst<bits<8> o, string asm>
 256   : FPI<o, AddRegFrm, (outs), (ins RST:$op), asm>, DE;
 257
 258 // NOTE: GAS and apparently all other AT&T style assemblers have a broken notion
 259 // of some of the 'reverse' forms of the fsub and fdiv instructions.  As such,
 260 // we have to put some 'r's in and take them out of weird places.
 261 def ADD_FST0r   : FPST0rInst <0xC0, "fadd\t$op">;
 262 def ADD_FrST0   : FPrST0Inst <0xC0, "fadd\t{%st(0), $op|$op, %ST(0)}">;
 263 def ADD_FPrST0  : FPrST0PInst<0xC0, "faddp\t$op">;
 264 def SUBR_FST0r  : FPST0rInst <0xE8, "fsubr\t$op">;
 265 def SUB_FrST0   : FPrST0Inst <0xE8, "fsub{r}\t{%st(0), $op|$op, %ST(0)}">;
 266 def SUB_FPrST0  : FPrST0PInst<0xE8, "fsub{r}p\t$op">;
 267 def SUB_FST0r   : FPST0rInst <0xE0, "fsub\t$op">;
 268 def SUBR_FrST0  : FPrST0Inst <0xE0, "fsub{|r}\t{%st(0), $op|$op, %ST(0)}">;
 269 def SUBR_FPrST0 : FPrST0PInst<0xE0, "fsub{|r}p\t$op">;
 270 def MUL_FST0r   : FPST0rInst <0xC8, "fmul\t$op">;
 271 def MUL_FrST0   : FPrST0Inst <0xC8, "fmul\t{%st(0), $op|$op, %ST(0)}">;
 272 def MUL_FPrST0  : FPrST0PInst<0xC8, "fmulp\t$op">;
 273 def DIVR_FST0r  : FPST0rInst <0xF8, "fdivr\t$op">;
 274 def DIV_FrST0   : FPrST0Inst <0xF8, "fdiv{r}\t{%st(0), $op|$op, %ST(0)}">;
 275 def DIV_FPrST0  : FPrST0PInst<0xF8, "fdiv{r}p\t$op">;
 276 def DIV_FST0r   : FPST0rInst <0xF0, "fdiv\t$op">;
 277 def DIVR_FrST0  : FPrST0Inst <0xF0, "fdiv{|r}\t{%st(0), $op|$op, %ST(0)}">;
 278 def DIVR_FPrST0 : FPrST0PInst<0xF0, "fdiv{|r}p\t$op">;
 279
 280 // Unary operations.
 281 multiclass FPUnary<SDNode OpNode, bits<8> opcode, string asmstring> {
 282 def _Fp32  : FpIf32<(outs RFP32:$dst), (ins RFP32:$src), OneArgFPRW,
 283                  [(set RFP32:$dst, (OpNode RFP32:$src))]>;
 284 def _Fp64  : FpIf64<(outs RFP64:$dst), (ins RFP64:$src), OneArgFPRW,
 285                  [(set RFP64:$dst, (OpNode RFP64:$src))]>;
 286 def _Fp80  : FpI_<(outs RFP80:$dst), (ins RFP80:$src), OneArgFPRW,
 287                  [(set RFP80:$dst, (OpNode RFP80:$src))]>;
 288 def _F     : FPI<opcode, RawFrm, (outs), (ins), asmstring>, D9;
 289 }
 290
 291 defm CHS : FPUnary<fneg, 0xE0, "fchs">;
 292 defm ABS : FPUnary<fabs, 0xE1, "fabs">;
 293 defm SQRT: FPUnary<fsqrt,0xFA, "fsqrt">;
 294 defm SIN : FPUnary<fsin, 0xFE, "fsin">;
 295 defm COS : FPUnary<fcos, 0xFF, "fcos">;
 296
 297 let neverHasSideEffects = 1 in {
 298 def TST_Fp32  : FpIf32<(outs), (ins RFP32:$src), OneArgFP, []>;
 299 def TST_Fp64  : FpIf64<(outs), (ins RFP64:$src), OneArgFP, []>;
 300 def TST_Fp80  : FpI_<(outs), (ins RFP80:$src), OneArgFP, []>;
 301 }
 302 def TST_F  : FPI<0xE4, RawFrm, (outs), (ins), "ftst">, D9;
 303
 304 // Floating point cmovs.
 305 multiclass FPCMov<PatLeaf cc> {
 306   def _Fp32  : FpIf32<(outs RFP32:$dst), (ins RFP32:$src1, RFP32:$src2),
 307                        CondMovFP,
 308                      [(set RFP32:$dst, (X86cmov RFP32:$src1, RFP32:$src2,
 309                                         cc, EFLAGS))]>;
 310   def _Fp64  : FpIf64<(outs RFP64:$dst), (ins RFP64:$src1, RFP64:$src2),
 311                        CondMovFP,
 312                      [(set RFP64:$dst, (X86cmov RFP64:$src1, RFP64:$src2,
 313                                         cc, EFLAGS))]>;
 314   def _Fp80  : FpI_<(outs RFP80:$dst), (ins RFP80:$src1, RFP80:$src2),
 315                      CondMovFP,
 316                      [(set RFP80:$dst, (X86cmov RFP80:$src1, RFP80:$src2,
 317                                         cc, EFLAGS))]>;
 318 }
 319 let Uses = [EFLAGS], isTwoAddress = 1 in {
 320 defm CMOVB  : FPCMov<X86_COND_B>;
 321 defm CMOVBE : FPCMov<X86_COND_BE>;
 322 defm CMOVE  : FPCMov<X86_COND_E>;
 323 defm CMOVP  : FPCMov<X86_COND_P>;
 324 defm CMOVNB : FPCMov<X86_COND_AE>;
 325 defm CMOVNBE: FPCMov<X86_COND_A>;
 326 defm CMOVNE : FPCMov<X86_COND_NE>;
 327 defm CMOVNP : FPCMov<X86_COND_NP>;
 328 }
 329
 330 // These are not factored because there's no clean way to pass DA/DB.
 331 def CMOVB_F  : FPI<0xC0, AddRegFrm, (outs RST:$op), (ins),
 332                   "fcmovb\t{$op, %st(0)|%ST(0), $op}">, DA;
 333 def CMOVBE_F : FPI<0xD0, AddRegFrm, (outs RST:$op), (ins),
 334                   "fcmovbe\t{$op, %st(0)|%ST(0), $op}">, DA;
 335 def CMOVE_F  : FPI<0xC8, AddRegFrm, (outs RST:$op), (ins),
 336                   "fcmove\t{$op, %st(0)|%ST(0), $op}">, DA;
 337 def CMOVP_F  : FPI<0xD8, AddRegFrm, (outs RST:$op), (ins),
 338                   "fcmovu\t {$op, %st(0)|%ST(0), $op}">, DA;
 339 def CMOVNB_F : FPI<0xC0, AddRegFrm, (outs RST:$op), (ins),
 340                   "fcmovnb\t{$op, %st(0)|%ST(0), $op}">, DB;
 341 def CMOVNBE_F: FPI<0xD0, AddRegFrm, (outs RST:$op), (ins),
 342                   "fcmovnbe\t{$op, %st(0)|%ST(0), $op}">, DB;
 343 def CMOVNE_F : FPI<0xC8, AddRegFrm, (outs RST:$op), (ins),
 344                   "fcmovne\t{$op, %st(0)|%ST(0), $op}">, DB;
 345 def CMOVNP_F : FPI<0xD8, AddRegFrm, (outs RST:$op), (ins),
 346                   "fcmovnu\t{$op, %st(0)|%ST(0), $op}">, DB;
 347
 348 // Floating point loads & stores.
 349 let isSimpleLoad = 1 in {
 350 def LD_Fp32m   : FpIf32<(outs RFP32:$dst), (ins f32mem:$src), ZeroArgFP,
 351                   [(set RFP32:$dst, (loadf32 addr:$src))]>;
 352 let isReMaterializable = 1, mayHaveSideEffects = 1 in
 353   def LD_Fp64m : FpIf64<(outs RFP64:$dst), (ins f64mem:$src), ZeroArgFP,
 354                   [(set RFP64:$dst, (loadf64 addr:$src))]>;
 355 def LD_Fp80m   : FpI_<(outs RFP80:$dst), (ins f80mem:$src), ZeroArgFP,
 356                   [(set RFP80:$dst, (loadf80 addr:$src))]>;
 357 }
 358 def LD_Fp32m64 : FpIf64<(outs RFP64:$dst), (ins f32mem:$src), ZeroArgFP,
 359                   [(set RFP64:$dst, (f64 (extloadf32 addr:$src)))]>;
 360 def LD_Fp64m80 : FpI_<(outs RFP80:$dst), (ins f64mem:$src), ZeroArgFP,
 361                   [(set RFP80:$dst, (f80 (extloadf64 addr:$src)))]>;
 362 def LD_Fp32m80 : FpI_<(outs RFP80:$dst), (ins f32mem:$src), ZeroArgFP,
 363                   [(set RFP80:$dst, (f80 (extloadf32 addr:$src)))]>;
 364 def ILD_Fp16m32: FpIf32<(outs RFP32:$dst), (ins i16mem:$src), ZeroArgFP,
 365                   [(set RFP32:$dst, (X86fild addr:$src, i16))]>;
 366 def ILD_Fp32m32: FpIf32<(outs RFP32:$dst), (ins i32mem:$src), ZeroArgFP,
 367                   [(set RFP32:$dst, (X86fild addr:$src, i32))]>;
 368 def ILD_Fp64m32: FpIf32<(outs RFP32:$dst), (ins i64mem:$src), ZeroArgFP,
 369                   [(set RFP32:$dst, (X86fild addr:$src, i64))]>;
 370 def ILD_Fp16m64: FpIf64<(outs RFP64:$dst), (ins i16mem:$src), ZeroArgFP,
 371                   [(set RFP64:$dst, (X86fild addr:$src, i16))]>;
 372 def ILD_Fp32m64: FpIf64<(outs RFP64:$dst), (ins i32mem:$src), ZeroArgFP,
 373                   [(set RFP64:$dst, (X86fild addr:$src, i32))]>;
 374 def ILD_Fp64m64: FpIf64<(outs RFP64:$dst), (ins i64mem:$src), ZeroArgFP,
 375                   [(set RFP64:$dst, (X86fild addr:$src, i64))]>;
 376 def ILD_Fp16m80: FpI_<(outs RFP80:$dst), (ins i16mem:$src), ZeroArgFP,
 377                   [(set RFP80:$dst, (X86fild addr:$src, i16))]>;
 378 def ILD_Fp32m80: FpI_<(outs RFP80:$dst), (ins i32mem:$src), ZeroArgFP,
 379                   [(set RFP80:$dst, (X86fild addr:$src, i32))]>;
 380 def ILD_Fp64m80: FpI_<(outs RFP80:$dst), (ins i64mem:$src), ZeroArgFP,
 381                   [(set RFP80:$dst, (X86fild addr:$src, i64))]>;
 382
 383 def ST_Fp32m   : FpIf32<(outs), (ins f32mem:$op, RFP32:$src), OneArgFP,
 384                   [(store RFP32:$src, addr:$op)]>;
 385 def ST_Fp64m32 : FpIf64<(outs), (ins f32mem:$op, RFP64:$src), OneArgFP,
 386                   [(truncstoref32 RFP64:$src, addr:$op)]>;
 387 def ST_Fp64m   : FpIf64<(outs), (ins f64mem:$op, RFP64:$src), OneArgFP,
 388                   [(store RFP64:$src, addr:$op)]>;
 389 def ST_Fp80m32 : FpI_<(outs), (ins f32mem:$op, RFP80:$src), OneArgFP,
 390                   [(truncstoref32 RFP80:$src, addr:$op)]>;
 391 def ST_Fp80m64 : FpI_<(outs), (ins f64mem:$op, RFP80:$src), OneArgFP,
 392                   [(truncstoref64 RFP80:$src, addr:$op)]>;
 393 // FST does not support 80-bit memory target; FSTP must be used.
 394
 395 let mayStore = 1, neverHasSideEffects = 1 in {
 396 def ST_FpP32m    : FpIf32<(outs), (ins f32mem:$op, RFP32:$src), OneArgFP, []>;
 397 def ST_FpP64m32  : FpIf64<(outs), (ins f32mem:$op, RFP64:$src), OneArgFP, []>;
 398 def ST_FpP64m    : FpIf64<(outs), (ins f64mem:$op, RFP64:$src), OneArgFP, []>;
 399 def ST_FpP80m32  : FpI_<(outs), (ins f32mem:$op, RFP80:$src), OneArgFP, []>;
 400 def ST_FpP80m64  : FpI_<(outs), (ins f64mem:$op, RFP80:$src), OneArgFP, []>;
 401 }
 402 def ST_FpP80m    : FpI_<(outs), (ins f80mem:$op, RFP80:$src), OneArgFP,
 403                     [(store RFP80:$src, addr:$op)]>;
 404 let mayStore = 1, neverHasSideEffects = 1 in {
 405 def IST_Fp16m32  : FpIf32<(outs), (ins i16mem:$op, RFP32:$src), OneArgFP, []>;
 406 def IST_Fp32m32  : FpIf32<(outs), (ins i32mem:$op, RFP32:$src), OneArgFP, []>;
 407 def IST_Fp64m32  : FpIf32<(outs), (ins i64mem:$op, RFP32:$src), OneArgFP, []>;
 408 def IST_Fp16m64  : FpIf64<(outs), (ins i16mem:$op, RFP64:$src), OneArgFP, []>;
 409 def IST_Fp32m64  : FpIf64<(outs), (ins i32mem:$op, RFP64:$src), OneArgFP, []>;
 410 def IST_Fp64m64  : FpIf64<(outs), (ins i64mem:$op, RFP64:$src), OneArgFP, []>;
 411 def IST_Fp16m80  : FpI_<(outs), (ins i16mem:$op, RFP80:$src), OneArgFP, []>;
 412 def IST_Fp32m80  : FpI_<(outs), (ins i32mem:$op, RFP80:$src), OneArgFP, []>;
 413 def IST_Fp64m80  : FpI_<(outs), (ins i64mem:$op, RFP80:$src), OneArgFP, []>;
 414 }
 415
 416 let mayLoad = 1 in {
 417 def LD_F32m   : FPI<0xD9, MRM0m, (outs), (ins f32mem:$src), "fld{s}\t$src">;
 418 def LD_F64m   : FPI<0xDD, MRM0m, (outs), (ins f64mem:$src), "fld{l}\t$src">;
 419 def LD_F80m   : FPI<0xDB, MRM5m, (outs), (ins f80mem:$src), "fld{t}\t$src">;
 420 def ILD_F16m  : FPI<0xDF, MRM0m, (outs), (ins i16mem:$src), "fild{s}\t$src">;
 421 def ILD_F32m  : FPI<0xDB, MRM0m, (outs), (ins i32mem:$src), "fild{l}\t$src">;
 422 def ILD_F64m  : FPI<0xDF, MRM5m, (outs), (ins i64mem:$src), "fild{ll}\t$src">;
 423 }
 424 let mayStore = 1 in {
 425 def ST_F32m   : FPI<0xD9, MRM2m, (outs), (ins f32mem:$dst), "fst{s}\t$dst">;
 426 def ST_F64m   : FPI<0xDD, MRM2m, (outs), (ins f64mem:$dst), "fst{l}\t$dst">;
 427 def ST_FP32m  : FPI<0xD9, MRM3m, (outs), (ins f32mem:$dst), "fstp{s}\t$dst">;
 428 def ST_FP64m  : FPI<0xDD, MRM3m, (outs), (ins f64mem:$dst), "fstp{l}\t$dst">;
 429 def ST_FP80m  : FPI<0xDB, MRM7m, (outs), (ins f80mem:$dst), "fstp{t}\t$dst">;
 430 def IST_F16m  : FPI<0xDF, MRM2m, (outs), (ins i16mem:$dst), "fist{s}\t$dst">;
 431 def IST_F32m  : FPI<0xDB, MRM2m, (outs), (ins i32mem:$dst), "fist{l}\t$dst">;
 432 def IST_FP16m : FPI<0xDF, MRM3m, (outs), (ins i16mem:$dst), "fistp{s}\t$dst">;
 433 def IST_FP32m : FPI<0xDB, MRM3m, (outs), (ins i32mem:$dst), "fistp{l}\t$dst">;
 434 def IST_FP64m : FPI<0xDF, MRM7m, (outs), (ins i64mem:$dst), "fistp{ll}\t$dst">;
 435 }
 436
 437 // FISTTP requires SSE3 even though it's a FPStack op.
 438 def ISTT_Fp16m32 : FpI_<(outs), (ins i16mem:$op, RFP32:$src), OneArgFP,
 439                     [(X86fp_to_i16mem RFP32:$src, addr:$op)]>,
 440                     Requires<[HasSSE3]>;
 441 def ISTT_Fp32m32 : FpI_<(outs), (ins i32mem:$op, RFP32:$src), OneArgFP,
 442                     [(X86fp_to_i32mem RFP32:$src, addr:$op)]>,
 443                     Requires<[HasSSE3]>;
 444 def ISTT_Fp64m32 : FpI_<(outs), (ins i64mem:$op, RFP32:$src), OneArgFP,
 445                     [(X86fp_to_i64mem RFP32:$src, addr:$op)]>,
 446                     Requires<[HasSSE3]>;
 447 def ISTT_Fp16m64 : FpI_<(outs), (ins i16mem:$op, RFP64:$src), OneArgFP,
 448                     [(X86fp_to_i16mem RFP64:$src, addr:$op)]>,
 449                     Requires<[HasSSE3]>;
 450 def ISTT_Fp32m64 : FpI_<(outs), (ins i32mem:$op, RFP64:$src), OneArgFP,
 451                     [(X86fp_to_i32mem RFP64:$src, addr:$op)]>,
 452                     Requires<[HasSSE3]>;
 453 def ISTT_Fp64m64 : FpI_<(outs), (ins i64mem:$op, RFP64:$src), OneArgFP,
 454                     [(X86fp_to_i64mem RFP64:$src, addr:$op)]>,
 455                     Requires<[HasSSE3]>;
 456 def ISTT_Fp16m80 : FpI_<(outs), (ins i16mem:$op, RFP80:$src), OneArgFP,
 457                     [(X86fp_to_i16mem RFP80:$src, addr:$op)]>,
 458                     Requires<[HasSSE3]>;
 459 def ISTT_Fp32m80 : FpI_<(outs), (ins i32mem:$op, RFP80:$src), OneArgFP,
 460                     [(X86fp_to_i32mem RFP80:$src, addr:$op)]>,
 461                     Requires<[HasSSE3]>;
 462 def ISTT_Fp64m80 : FpI_<(outs), (ins i64mem:$op, RFP80:$src), OneArgFP,
 463                     [(X86fp_to_i64mem RFP80:$src, addr:$op)]>,
 464                     Requires<[HasSSE3]>;
 465
 466 let mayStore = 1 in {
 467 def ISTT_FP16m : FPI<0xDF, MRM1m, (outs), (ins i16mem:$dst), "fisttp{s}\t$dst">;
 468 def ISTT_FP32m : FPI<0xDB, MRM1m, (outs), (ins i32mem:$dst), "fisttp{l}\t$dst">;
 469 def ISTT_FP64m : FPI<0xDD, MRM1m, (outs), (ins i64mem:$dst), "fisttp{ll}\t$dst">;
 470 }
 471
 472 // FP Stack manipulation instructions.
 473 def LD_Frr   : FPI<0xC0, AddRegFrm, (outs), (ins RST:$op), "fld\t$op">, D9;
 474 def ST_Frr   : FPI<0xD0, AddRegFrm, (outs), (ins RST:$op), "fst\t$op">, DD;
 475 def ST_FPrr  : FPI<0xD8, AddRegFrm, (outs), (ins RST:$op), "fstp\t$op">, DD;
 476 def XCH_F    : FPI<0xC8, AddRegFrm, (outs), (ins RST:$op), "fxch\t$op">, D9;
 477
 478 // Floating point constant loads.
 479 let isReMaterializable = 1 in {
 480 def LD_Fp032 : FpIf32<(outs RFP32:$dst), (ins), ZeroArgFP,
 481                 [(set RFP32:$dst, fpimm0)]>;
 482 def LD_Fp132 : FpIf32<(outs RFP32:$dst), (ins), ZeroArgFP,
 483                 [(set RFP32:$dst, fpimm1)]>;
 484 def LD_Fp064 : FpIf64<(outs RFP64:$dst), (ins), ZeroArgFP,
 485                 [(set RFP64:$dst, fpimm0)]>;
 486 def LD_Fp164 : FpIf64<(outs RFP64:$dst), (ins), ZeroArgFP,
 487                 [(set RFP64:$dst, fpimm1)]>;
 488 def LD_Fp080 : FpI_<(outs RFP80:$dst), (ins), ZeroArgFP,
 489                 [(set RFP80:$dst, fpimm0)]>;
 490 def LD_Fp180 : FpI_<(outs RFP80:$dst), (ins), ZeroArgFP,
 491                 [(set RFP80:$dst, fpimm1)]>;
 492 }
 493
 494 def LD_F0 : FPI<0xEE, RawFrm, (outs), (ins), "fldz">, D9;
 495 def LD_F1 : FPI<0xE8, RawFrm, (outs), (ins), "fld1">, D9;
 496
 497
 498 // Floating point compares.
 499 let Defs = [EFLAGS] in {
 500 def UCOM_Fpr32 : FpIf32<(outs), (ins RFP32:$lhs, RFP32:$rhs), CompareFP,
 501                         []>;  // FPSW = cmp ST(0) with ST(i)
 502 def UCOM_Fpr64 : FpIf64<(outs), (ins RFP64:$lhs, RFP64:$rhs), CompareFP,
 503                         []>;  // FPSW = cmp ST(0) with ST(i)
 504 def UCOM_Fpr80 : FpI_  <(outs), (ins RFP80:$lhs, RFP80:$rhs), CompareFP,
 505                         []>;  // FPSW = cmp ST(0) with ST(i)
 506
 507 def UCOM_FpIr32: FpIf32<(outs), (ins RFP32:$lhs, RFP32:$rhs), CompareFP,
 508                   [(X86cmp RFP32:$lhs, RFP32:$rhs),
 509                    (implicit EFLAGS)]>; // CC = ST(0) cmp ST(i)
 510 def UCOM_FpIr64: FpIf64<(outs), (ins RFP64:$lhs, RFP64:$rhs), CompareFP,
 511                   [(X86cmp RFP64:$lhs, RFP64:$rhs),
 512                    (implicit EFLAGS)]>; // CC = ST(0) cmp ST(i)
 513 def UCOM_FpIr80: FpI_<(outs), (ins RFP80:$lhs, RFP80:$rhs), CompareFP,
 514                   [(X86cmp RFP80:$lhs, RFP80:$rhs),
 515                    (implicit EFLAGS)]>; // CC = ST(0) cmp ST(i)
 516 }
 517
 518 let Defs = [EFLAGS], Uses = [ST0] in {
 519 def UCOM_Fr    : FPI<0xE0, AddRegFrm,    // FPSW = cmp ST(0) with ST(i)
 520                     (outs), (ins RST:$reg),
 521                     "fucom\t$reg">, DD;
 522 def UCOM_FPr   : FPI<0xE8, AddRegFrm,    // FPSW = cmp ST(0) with ST(i), pop
 523                     (outs), (ins RST:$reg),
 524                     "fucomp\t$reg">, DD;
 525 def UCOM_FPPr  : FPI<0xE9, RawFrm,       // cmp ST(0) with ST(1), pop, pop
 526                     (outs), (ins),
 527                     "fucompp">, DA;
 528
 529 def UCOM_FIr   : FPI<0xE8, AddRegFrm,     // CC = cmp ST(0) with ST(i)
 530                     (outs), (ins RST:$reg),
 531                     "fucomi\t{$reg, %st(0)|%ST(0), $reg}">, DB;
 532 def UCOM_FIPr  : FPI<0xE8, AddRegFrm,     // CC = cmp ST(0) with ST(i), pop
 533                     (outs), (ins RST:$reg),
 534                     "fucomip\t{$reg, %st(0)|%ST(0), $reg}">, DF;
 535 }
 536
 537 // Floating point flag ops.
 538 let Defs = [AX] in
 539 def FNSTSW8r  : I<0xE0, RawFrm,                  // AX = fp flags
 540                   (outs), (ins), "fnstsw", []>, DF;
 541
 542 def FNSTCW16m : I<0xD9, MRM7m,                   // [mem16] = X87 control world
 543                   (outs), (ins i16mem:$dst), "fnstcw\t$dst",
 544                   [(X86fp_cwd_get16 addr:$dst)]>;
 545
 546 let mayLoad = 1 in
 547 def FLDCW16m  : I<0xD9, MRM5m,                   // X87 control world = [mem16]
 548                   (outs), (ins i16mem:$dst), "fldcw\t$dst", []>;
 549
 550 //===----------------------------------------------------------------------===//
 551 // Non-Instruction Patterns
 552 //===----------------------------------------------------------------------===//
 553
 554 // Required for RET of f32 / f64 / f80 values.
 555 def : Pat<(X86fld addr:$src, f32), (LD_Fp32m addr:$src)>;
 556 def : Pat<(X86fld addr:$src, f64), (LD_Fp64m addr:$src)>;
 557 def : Pat<(X86fld addr:$src, f80), (LD_Fp80m addr:$src)>;
 558
 559 // Required for CALL which return f32 / f64 / f80 values.
 560 def : Pat<(X86fst RFP32:$src, addr:$op, f32), (ST_Fp32m addr:$op, RFP32:$src)>;
 561 def : Pat<(X86fst RFP64:$src, addr:$op, f32), (ST_Fp64m32 addr:$op, RFP64:$src)>;
 562 def : Pat<(X86fst RFP64:$src, addr:$op, f64), (ST_Fp64m addr:$op, RFP64:$src)>;
 563 def : Pat<(X86fst RFP80:$src, addr:$op, f32), (ST_Fp80m32 addr:$op, RFP80:$src)>;
 564 def : Pat<(X86fst RFP80:$src, addr:$op, f64), (ST_Fp80m64 addr:$op, RFP80:$src)>;
 565 def : Pat<(X86fst RFP80:$src, addr:$op, f80), (ST_FpP80m addr:$op, RFP80:$src)>;
 566
 567 // Floating point constant -0.0 and -1.0
 568 def : Pat<(f32 fpimmneg0), (CHS_Fp32 (LD_Fp032))>, Requires<[FPStackf32]>;
 569 def : Pat<(f32 fpimmneg1), (CHS_Fp32 (LD_Fp132))>, Requires<[FPStackf32]>;
 570 def : Pat<(f64 fpimmneg0), (CHS_Fp64 (LD_Fp064))>, Requires<[FPStackf64]>;
 571 def : Pat<(f64 fpimmneg1), (CHS_Fp64 (LD_Fp164))>, Requires<[FPStackf64]>;
 572 def : Pat<(f80 fpimmneg0), (CHS_Fp80 (LD_Fp080))>;
 573 def : Pat<(f80 fpimmneg1), (CHS_Fp80 (LD_Fp180))>;
 574
 575 // Used to conv. i64 to f64 since there isn't a SSE version.
 576 def : Pat<(X86fildflag addr:$src, i64), (ILD_Fp64m64 addr:$src)>;
 577
 578 // FP extensions map onto simple pseudo-value conversions if they are to/from
 579 // the FP stack.
 580 def : Pat<(f64 (fextend RFP32:$src)), (MOV_Fp3264 RFP32:$src)>,
 581           Requires<[FPStackf32]>;
 582 def : Pat<(f80 (fextend RFP32:$src)), (MOV_Fp3280 RFP32:$src)>,
 583            Requires<[FPStackf32]>;
 584 def : Pat<(f80 (fextend RFP64:$src)), (MOV_Fp6480 RFP64:$src)>,
 585            Requires<[FPStackf64]>;
 586
 587 // FP truncations map onto simple pseudo-value conversions if they are to/from
 588 // the FP stack.  We have validated that only value-preserving truncations make
 589 // it through isel.
 590 def : Pat<(f32 (fround RFP64:$src)), (MOV_Fp6432 RFP64:$src)>,
 591           Requires<[FPStackf32]>;
 592 def : Pat<(f32 (fround RFP80:$src)), (MOV_Fp8032 RFP80:$src)>,
 593            Requires<[FPStackf32]>;
 594 def : Pat<(f64 (fround RFP80:$src)), (MOV_Fp8064 RFP80:$src)>,
 595            Requires<[FPStackf64]>;