lib/Target/X86/X86CallingConv.td

   1 //===- X86CallingConv.td - Calling Conventions X86 32/64 ---*- tablegen -*-===//
   2 //
   3 //                     The LLVM Compiler Infrastructure
   4 //
   5 // This file is distributed under the University of Illinois Open Source
   6 // License. See LICENSE.TXT for details.
   7 //
   8 //===----------------------------------------------------------------------===//
   9 //
  10 // This describes the calling conventions for the X86-32 and X86-64
  11 // architectures.
  12 //
  13 //===----------------------------------------------------------------------===//
  14
  15 /// CCIfSubtarget - Match if the current subtarget has a feature F.
  16 class CCIfSubtarget<string F, CCAction A>
  17  : CCIf<!strconcat("State.getTarget().getSubtarget<X86Subtarget>().", F), A>;
  18
  19 //===----------------------------------------------------------------------===//
  20 // Return Value Calling Conventions
  21 //===----------------------------------------------------------------------===//
  22
  23 // Return-value conventions common to all X86 CC's.
  24 def RetCC_X86Common : CallingConv<[
  25   // Scalar values are returned in AX first, then DX.
  26   CCIfType<[i8] , CCAssignToReg<[AL]>>,
  27   CCIfType<[i16], CCAssignToReg<[AX, DX]>>,
  28   CCIfType<[i32], CCAssignToReg<[EAX, EDX]>>,
  29   CCIfType<[i64], CCAssignToReg<[RAX, RDX]>>,
  30
  31   // Vector types are returned in XMM0 and XMM1, when they fit.  If the target
  32   // doesn't have XMM registers, it won't have vector types.
  33   CCIfType<[v16i8, v8i16, v4i32, v2i64, v4f32, v2f64],
  34             CCAssignToReg<[XMM0,XMM1]>>,
  35
  36   // MMX vector types are always returned in MM0. If the target doesn't have
  37   // MM0, it doesn't support these vector types.
  38   CCIfType<[v8i8, v4i16, v2i32, v1i64], CCAssignToReg<[MM0]>>,
  39
  40   // Long double types are always returned in ST0 (even with SSE).
  41   CCIfType<[f80], CCAssignToReg<[ST0, ST1]>>
  42 ]>;
  43
  44 // X86-32 C return-value convention.
  45 def RetCC_X86_32_C : CallingConv<[
  46   // The X86-32 calling convention returns FP values in ST0, otherwise it is the
  47   // same as the common X86 calling conv.
  48   CCIfType<[f32], CCAssignToReg<[ST0, ST1]>>,
  49   CCIfType<[f64], CCAssignToReg<[ST0, ST1]>>,
  50   CCDelegateTo<RetCC_X86Common>
  51 ]>;
  52
  53 // X86-32 FastCC return-value convention.
  54 def RetCC_X86_32_Fast : CallingConv<[
  55   // The X86-32 fastcc returns 1, 2, or 3 FP values in XMM0-2 if the target has
  56   // SSE2, otherwise it is the the C calling conventions.
  57   // This can happen when a float, 2 x float, or 3 x float vector is split by
  58   // target lowering, and is returned in 1-3 sse regs.
  59   CCIfType<[f32], CCIfSubtarget<"hasSSE2()", CCAssignToReg<[XMM0,XMM1,XMM2]>>>,
  60   CCIfType<[f64], CCIfSubtarget<"hasSSE2()", CCAssignToReg<[XMM0,XMM1,XMM2]>>>,
  61   CCDelegateTo<RetCC_X86Common>
  62 ]>;
  63
  64 // X86-32 SSEregparm return-value convention.
  65 def RetCC_X86_32_SSE : CallingConv<[
  66   // The X86-32 sseregparm calling convention returns FP values in XMM0 if the
  67   // target has SSE2, otherwise it is the C calling convention.
  68   CCIfType<[f32], CCIfSubtarget<"hasSSE2()", CCAssignToReg<[XMM0, XMM1]>>>,
  69   CCIfType<[f64], CCIfSubtarget<"hasSSE2()", CCAssignToReg<[XMM0, XMM1]>>>,
  70   CCDelegateTo<RetCC_X86Common>
  71 ]>;
  72
  73 // X86-64 C return-value convention.
  74 def RetCC_X86_64_C : CallingConv<[
  75   // The X86-64 calling convention always returns FP values in XMM0.
  76   CCIfType<[f32], CCAssignToReg<[XMM0, XMM1]>>,
  77   CCIfType<[f64], CCAssignToReg<[XMM0, XMM1]>>,
  78   CCDelegateTo<RetCC_X86Common>
  79 ]>;
  80
  81 // X86-Win64 C return-value convention.
  82 def RetCC_X86_Win64_C : CallingConv<[
  83   // The X86-Win64 calling convention always returns __m64 values in RAX.
  84   CCIfType<[v8i8, v4i16, v2i32, v1i64], CCAssignToReg<[RAX]>>,
  85
  86   // Otherwise, everything is the same as 'normal' X86-64 C CC.
  87   CCDelegateTo<RetCC_X86_64_C>
  88 ]>;
  89
  90
  91 // This is the root return-value convention for the X86-32 backend.
  92 def RetCC_X86_32 : CallingConv<[
  93   // If FastCC, use RetCC_X86_32_Fast.
  94   CCIfCC<"CallingConv::Fast", CCDelegateTo<RetCC_X86_32_Fast>>,
  95   // If SSECC, use RetCC_X86_32_SSE.
  96   CCIfCC<"CallingConv::X86_SSECall", CCDelegateTo<RetCC_X86_32_SSE>>,
  97   // Otherwise, use RetCC_X86_32_C.
  98   CCDelegateTo<RetCC_X86_32_C>
  99 ]>;
 100
 101 // This is the root return-value convention for the X86-64 backend.
 102 def RetCC_X86_64 : CallingConv<[
 103   // Mingw64 and native Win64 use Win64 CC
 104   CCIfSubtarget<"isTargetWin64()", CCDelegateTo<RetCC_X86_Win64_C>>,
 105
 106   // Otherwise, drop to normal X86-64 CC
 107   CCDelegateTo<RetCC_X86_64_C>
 108 ]>;
 109
 110 // This is the return-value convention used for the entire X86 backend.
 111 def RetCC_X86 : CallingConv<[
 112   CCIfSubtarget<"is64Bit()", CCDelegateTo<RetCC_X86_64>>,
 113   CCDelegateTo<RetCC_X86_32>
 114 ]>;
 115
 116 //===----------------------------------------------------------------------===//
 117 // X86-64 Argument Calling Conventions
 118 //===----------------------------------------------------------------------===//
 119
 120 def CC_X86_64_C : CallingConv<[
 121   // Handles byval parameters.
 122   CCIfByVal<CCPassByVal<8, 8>>,
 123
 124   // Promote i8/i16 arguments to i32.
 125   CCIfType<[i8, i16], CCPromoteToType<i32>>,
 126
 127   // The 'nest' parameter, if any, is passed in R10.
 128   CCIfNest<CCAssignToReg<[R10]>>,
 129
 130   // The first 6 integer arguments are passed in integer registers.
 131   CCIfType<[i32], CCAssignToReg<[EDI, ESI, EDX, ECX, R8D, R9D]>>,
 132   CCIfType<[i64], CCAssignToReg<[RDI, RSI, RDX, RCX, R8 , R9 ]>>,
 133
 134   // The first 8 FP/Vector arguments are passed in XMM registers.
 135   CCIfType<[f32, f64, v16i8, v8i16, v4i32, v2i64, v4f32, v2f64],
 136             CCAssignToReg<[XMM0, XMM1, XMM2, XMM3, XMM4, XMM5, XMM6, XMM7]>>,
 137
 138   // The first 8 MMX (except for v1i64) vector arguments are passed in XMM
 139   // registers on Darwin.
 140   CCIfType<[v8i8, v4i16, v2i32],
 141             CCIfSubtarget<"isTargetDarwin()",
 142             CCIfSubtarget<"hasSSE2()",
 143             CCAssignToReg<[XMM0, XMM1, XMM2, XMM3, XMM4, XMM5, XMM6, XMM7]>>>>,
 144
 145   // The first 8 v1i64 vector arguments are passed in GPRs on Darwin.
 146   CCIfType<[v1i64],
 147             CCIfSubtarget<"isTargetDarwin()",
 148             CCAssignToReg<[RDI, RSI, RDX, RCX, R8]>>>,
 149
 150   // Integer/FP values get stored in stack slots that are 8 bytes in size and
 151   // 8-byte aligned if there are no more registers to hold them.
 152   CCIfType<[i32, i64, f32, f64], CCAssignToStack<8, 8>>,
 153
 154   // Long doubles get stack slots whose size and alignment depends on the
 155   // subtarget.
 156   CCIfType<[f80], CCAssignToStack<0, 0>>,
 157
 158   // Vectors get 16-byte stack slots that are 16-byte aligned.
 159   CCIfType<[v16i8, v8i16, v4i32, v2i64, v4f32, v2f64], CCAssignToStack<16, 16>>,
 160
 161   // __m64 vectors get 8-byte stack slots that are 8-byte aligned.
 162   CCIfType<[v8i8, v4i16, v2i32, v1i64], CCAssignToStack<8, 8>>
 163 ]>;
 164
 165 // Calling convention used on Win64
 166 def CC_X86_Win64_C : CallingConv<[
 167   // FIXME: Handle byval stuff.
 168   // FIXME: Handle fp80.
 169   // FIXME: Handle varargs.
 170
 171   // Promote i8/i16 arguments to i32.
 172   CCIfType<[i8, i16], CCPromoteToType<i32>>,
 173
 174   // The 'nest' parameter, if any, is passed in R10.
 175   CCIfNest<CCAssignToReg<[R10]>>,
 176
 177   // The first 4 integer arguments are passed in integer registers.
 178   CCIfType<[i32], CCAssignToRegWithShadow<[ECX , EDX , R8D , R9D ],
 179                                           [XMM0, XMM1, XMM2, XMM3]>>,
 180   CCIfType<[i64], CCAssignToRegWithShadow<[RCX , RDX , R8  , R9  ],
 181                                           [XMM0, XMM1, XMM2, XMM3]>>,
 182
 183   // The first 4 FP/Vector arguments are passed in XMM registers.
 184   CCIfType<[f32, f64, v16i8, v8i16, v4i32, v2i64, v4f32, v2f64],
 185            CCAssignToRegWithShadow<[XMM0, XMM1, XMM2, XMM3],
 186                                    [RCX , RDX , R8  , R9  ]>>,
 187
 188   // The first 4 MMX vector arguments are passed in GPRs.
 189   CCIfType<[v8i8, v4i16, v2i32, v1i64],
 190            CCAssignToRegWithShadow<[RCX , RDX , R8  , R9  ],
 191                                    [XMM0, XMM1, XMM2, XMM3]>>,
 192
 193   // Integer/FP values get stored in stack slots that are 8 bytes in size and
 194   // 16-byte aligned if there are no more registers to hold them.
 195   CCIfType<[i32, i64, f32, f64], CCAssignToStack<8, 16>>,
 196
 197   // Vectors get 16-byte stack slots that are 16-byte aligned.
 198   CCIfType<[v16i8, v8i16, v4i32, v2i64, v4f32, v2f64], CCAssignToStack<16, 16>>,
 199
 200   // __m64 vectors get 8-byte stack slots that are 16-byte aligned.
 201   CCIfType<[v8i8, v4i16, v2i32, v1i64], CCAssignToStack<8, 16>>
 202 ]>;
 203
 204 // Tail call convention (fast): One register is reserved for target address,
 205 // namely R9
 206 def CC_X86_64_TailCall : CallingConv<[
 207   // Handles byval parameters.
 208   CCIfByVal<CCPassByVal<8, 8>>,
 209
 210   // Promote i8/i16 arguments to i32.
 211   CCIfType<[i8, i16], CCPromoteToType<i32>>,
 212
 213   // The 'nest' parameter, if any, is passed in R10.
 214   CCIfNest<CCAssignToReg<[R10]>>,
 215
 216   // The first 6 integer arguments are passed in integer registers.
 217   CCIfType<[i32], CCAssignToReg<[EDI, ESI, EDX, ECX, R8D]>>,
 218   CCIfType<[i64], CCAssignToReg<[RDI, RSI, RDX, RCX, R8]>>,
 219
 220   // The first 8 FP/Vector arguments are passed in XMM registers.
 221   CCIfType<[f32, f64, v16i8, v8i16, v4i32, v2i64, v4f32, v2f64],
 222             CCAssignToReg<[XMM0, XMM1, XMM2, XMM3, XMM4, XMM5, XMM6, XMM7]>>,
 223
 224   // The first 8 MMX (except for v1i64) vector arguments are passed in XMM
 225   // registers on Darwin.
 226   CCIfType<[v8i8, v4i16, v2i32],
 227             CCIfSubtarget<"isTargetDarwin()",
 228             CCAssignToReg<[XMM0, XMM1, XMM2, XMM3, XMM4, XMM5, XMM6, XMM7]>>>,
 229
 230   // The first 8 v1i64 vector arguments are passed in GPRs on Darwin.
 231   CCIfType<[v1i64],
 232             CCIfSubtarget<"isTargetDarwin()",
 233             CCAssignToReg<[RDI, RSI, RDX, RCX, R8]>>>,
 234
 235   // Integer/FP values get stored in stack slots that are 8 bytes in size and
 236   // 8-byte aligned if there are no more registers to hold them.
 237   CCIfType<[i32, i64, f32, f64], CCAssignToStack<8, 8>>,
 238
 239   // Vectors get 16-byte stack slots that are 16-byte aligned.
 240   CCIfType<[v16i8, v8i16, v4i32, v2i64, v4f32, v2f64], CCAssignToStack<16, 16>>,
 241
 242   // __m64 vectors get 8-byte stack slots that are 8-byte aligned.
 243   CCIfType<[v8i8, v4i16, v2i32, v1i64], CCAssignToStack<8, 8>>
 244 ]>;
 245
 246
 247 //===----------------------------------------------------------------------===//
 248 // X86 C Calling Convention
 249 //===----------------------------------------------------------------------===//
 250
 251 /// CC_X86_32_Common - In all X86-32 calling conventions, extra integers and FP
 252 /// values are spilled on the stack, and the first 4 vector values go in XMM
 253 /// regs.
 254 def CC_X86_32_Common : CallingConv<[
 255   // Handles byval parameters.
 256   CCIfByVal<CCPassByVal<4, 4>>,
 257
 258   // The first 3 float or double arguments, if marked 'inreg' and if the call
 259   // is not a vararg call and if SSE2 is available, are passed in SSE registers.
 260   CCIfNotVarArg<CCIfInReg<CCIfType<[f32,f64],
 261                 CCIfSubtarget<"hasSSE2()",
 262                 CCAssignToReg<[XMM0,XMM1,XMM2]>>>>>,
 263
 264   // The first 3 __m64 (except for v1i64) vector arguments are passed in mmx
 265   // registers if the call is not a vararg call.
 266   CCIfNotVarArg<CCIfType<[v8i8, v4i16, v2i32],
 267                 CCAssignToReg<[MM0, MM1, MM2]>>>,
 268
 269   // Integer/Float values get stored in stack slots that are 4 bytes in
 270   // size and 4-byte aligned.
 271   CCIfType<[i32, f32], CCAssignToStack<4, 4>>,
 272
 273   // Doubles get 8-byte slots that are 4-byte aligned.
 274   CCIfType<[f64], CCAssignToStack<8, 4>>,
 275
 276   // Long doubles get slots whose size depends on the subtarget.
 277   CCIfType<[f80], CCAssignToStack<0, 4>>,
 278
 279   // The first 4 SSE vector arguments are passed in XMM registers.
 280   CCIfNotVarArg<CCIfType<[v16i8, v8i16, v4i32, v2i64, v4f32, v2f64],
 281                 CCAssignToReg<[XMM0, XMM1, XMM2, XMM3]>>>,
 282
 283   // Other SSE vectors get 16-byte stack slots that are 16-byte aligned.
 284   CCIfType<[v16i8, v8i16, v4i32, v2i64, v4f32, v2f64], CCAssignToStack<16, 16>>,
 285
 286   // __m64 vectors get 8-byte stack slots that are 4-byte aligned. They are
 287   // passed in the parameter area.
 288   CCIfType<[v8i8, v4i16, v2i32, v1i64], CCAssignToStack<8, 4>>]>;
 289
 290 def CC_X86_32_C : CallingConv<[
 291   // Promote i8/i16 arguments to i32.
 292   CCIfType<[i8, i16], CCPromoteToType<i32>>,
 293
 294   // The 'nest' parameter, if any, is passed in ECX.
 295   CCIfNest<CCAssignToReg<[ECX]>>,
 296
 297   // The first 3 integer arguments, if marked 'inreg' and if the call is not
 298   // a vararg call, are passed in integer registers.
 299   CCIfNotVarArg<CCIfInReg<CCIfType<[i32], CCAssignToReg<[EAX, EDX, ECX]>>>>,
 300
 301   // Otherwise, same as everything else.
 302   CCDelegateTo<CC_X86_32_Common>
 303 ]>;
 304
 305 /// Same as C calling convention except for non-free ECX which is used for storing
 306 /// a potential pointer to the tail called function.
 307 def CC_X86_32_TailCall : CallingConv<[
 308   // Promote i8/i16 arguments to i32.
 309   CCIfType<[i8, i16], CCPromoteToType<i32>>,
 310
 311   // Nested function trampolines are currently not supported by fastcc.
 312
 313   // The first 3 integer arguments, if marked 'inreg' and if the call is not
 314   // a vararg call, are passed in integer registers.
 315   CCIfNotVarArg<CCIfInReg<CCIfType<[i32], CCAssignToReg<[EAX, EDX]>>>>,
 316
 317   // Otherwise, same as everything else.
 318   CCDelegateTo<CC_X86_32_Common>
 319 ]>;
 320
 321 def CC_X86_32_FastCall : CallingConv<[
 322   // Promote i8/i16 arguments to i32.
 323   CCIfType<[i8, i16], CCPromoteToType<i32>>,
 324
 325   // The 'nest' parameter, if any, is passed in EAX.
 326   CCIfNest<CCAssignToReg<[EAX]>>,
 327
 328   // The first 2 integer arguments are passed in ECX/EDX
 329   CCIfType<[i32], CCAssignToReg<[ECX, EDX]>>,
 330
 331   // Otherwise, same as everything else.
 332   CCDelegateTo<CC_X86_32_Common>
 333 ]>;