lib/Target/X86/X86CallingConv.td

   1 //===- X86CallingConv.td - Calling Conventions X86 32/64 ---*- tablegen -*-===//
   2 //
   3 //                     The LLVM Compiler Infrastructure
   4 //
   5 // This file is distributed under the University of Illinois Open Source
   6 // License. See LICENSE.TXT for details.
   7 //
   8 //===----------------------------------------------------------------------===//
   9 //
  10 // This describes the calling conventions for the X86-32 and X86-64
  11 // architectures.
  12 //
  13 //===----------------------------------------------------------------------===//
  14
  15 /// CCIfSubtarget - Match if the current subtarget has a feature F.
  16 class CCIfSubtarget<string F, CCAction A>
  17  : CCIf<!strconcat("State.getTarget().getSubtarget<X86Subtarget>().", F), A>;
  18
  19 //===----------------------------------------------------------------------===//
  20 // Return Value Calling Conventions
  21 //===----------------------------------------------------------------------===//
  22
  23 // Return-value conventions common to all X86 CC's.
  24 def RetCC_X86Common : CallingConv<[
  25   // Scalar values are returned in AX first, then DX.
  26   CCIfType<[i8] , CCAssignToReg<[AL]>>,
  27   CCIfType<[i16], CCAssignToReg<[AX]>>,
  28   CCIfType<[i32], CCAssignToReg<[EAX, EDX]>>,
  29   CCIfType<[i64], CCAssignToReg<[RAX, RDX]>>,
  30
  31   // Vector types are returned in XMM0 and XMM1, when they fit.  If the target
  32   // doesn't have XMM registers, it won't have vector types.
  33   CCIfType<[v16i8, v8i16, v4i32, v2i64, v4f32, v2f64],
  34             CCAssignToReg<[XMM0,XMM1]>>,
  35
  36   // MMX vector types are always returned in MM0. If the target doesn't have
  37   // MM0, it doesn't support these vector types.
  38   CCIfType<[v8i8, v4i16, v2i32, v1i64], CCAssignToReg<[MM0]>>,
  39
  40   // Long double types are always returned in ST0 (even with SSE).
  41   CCIfType<[f80], CCAssignToReg<[ST0]>>
  42 ]>;
  43
  44 // X86-32 C return-value convention.
  45 def RetCC_X86_32_C : CallingConv<[
  46   // The X86-32 calling convention returns FP values in ST0, otherwise it is the
  47   // same as the common X86 calling conv.
  48   CCIfType<[f32], CCAssignToReg<[ST0]>>,
  49   CCIfType<[f64], CCAssignToReg<[ST0]>>,
  50   CCDelegateTo<RetCC_X86Common>
  51 ]>;
  52
  53 // X86-32 FastCC return-value convention.
  54 def RetCC_X86_32_Fast : CallingConv<[
  55   // The X86-32 fastcc returns 1, 2, or 3 FP values in XMM0-2 if the target has
  56   // SSE2, otherwise it is the the C calling conventions.
  57   // This can happen when a float, 2 x float, or 3 x float vector is split by
  58   // target lowering, and is returned in 1-3 sse regs.
  59   CCIfType<[f32], CCIfSubtarget<"hasSSE2()", CCAssignToReg<[XMM0,XMM1,XMM2]>>>,
  60   CCIfType<[f64], CCIfSubtarget<"hasSSE2()", CCAssignToReg<[XMM0,XMM1,XMM2]>>>,
  61   CCDelegateTo<RetCC_X86Common>
  62 ]>;
  63
  64 // X86-64 C return-value convention.
  65 def RetCC_X86_64_C : CallingConv<[
  66   // The X86-64 calling convention always returns FP values in XMM0.
  67   CCIfType<[f32], CCAssignToReg<[XMM0]>>,
  68   CCIfType<[f64], CCAssignToReg<[XMM0]>>,
  69   CCDelegateTo<RetCC_X86Common>
  70 ]>;
  71
  72
  73
  74 // This is the root return-value convention for the X86-32 backend.
  75 def RetCC_X86_32 : CallingConv<[
  76   // If FastCC, use RetCC_X86_32_Fast.
  77   CCIfCC<"CallingConv::Fast", CCDelegateTo<RetCC_X86_32_Fast>>,
  78   // Otherwise, use RetCC_X86_32_C.
  79   CCDelegateTo<RetCC_X86_32_C>
  80 ]>;
  81
  82 // This is the root return-value convention for the X86-64 backend.
  83 def RetCC_X86_64 : CallingConv<[
  84   // Always just the same as C calling conv for X86-64.
  85   CCDelegateTo<RetCC_X86_64_C>
  86 ]>;
  87
  88 // This is the return-value convention used for the entire X86 backend.
  89 def RetCC_X86 : CallingConv<[
  90   CCIfSubtarget<"is64Bit()", CCDelegateTo<RetCC_X86_64>>,
  91   CCDelegateTo<RetCC_X86_32>
  92 ]>;
  93
  94 //===----------------------------------------------------------------------===//
  95 // X86-64 Argument Calling Conventions
  96 //===----------------------------------------------------------------------===//
  97
  98 def CC_X86_64_C : CallingConv<[
  99   // Handles byval parameters.
 100   CCIfByVal<CCPassByVal<8, 8>>,
 101
 102   // Promote i8/i16 arguments to i32.
 103   CCIfType<[i8, i16], CCPromoteToType<i32>>,
 104
 105   // The 'nest' parameter, if any, is passed in R10.
 106   CCIfNest<CCAssignToReg<[R10]>>,
 107
 108   // The first 6 integer arguments are passed in integer registers.
 109   CCIfType<[i32], CCAssignToReg<[EDI, ESI, EDX, ECX, R8D, R9D]>>,
 110   CCIfType<[i64], CCAssignToReg<[RDI, RSI, RDX, RCX, R8 , R9 ]>>,
 111
 112   // The first 8 FP/Vector arguments are passed in XMM registers.
 113   CCIfType<[f32, f64, v16i8, v8i16, v4i32, v2i64, v4f32, v2f64],
 114               CCAssignToReg<[XMM0, XMM1, XMM2, XMM3, XMM4, XMM5, XMM6, XMM7]>>,
 115
 116   // The first 8 MMX vector arguments are passed in GPRs.
 117   CCIfType<[v8i8, v4i16, v2i32, v1i64],
 118               CCAssignToReg<[RDI, RSI, RDX, RCX, R8 , R9 ]>>,
 119
 120   // Integer/FP values get stored in stack slots that are 8 bytes in size and
 121   // 8-byte aligned if there are no more registers to hold them.
 122   CCIfType<[i32, i64, f32, f64], CCAssignToStack<8, 8>>,
 123
 124   // Long doubles get stack slots whose size and alignment depends on the
 125   // subtarget.
 126   CCIfType<[f80], CCAssignToStack<0, 0>>,
 127
 128   // Vectors get 16-byte stack slots that are 16-byte aligned.
 129   CCIfType<[v16i8, v8i16, v4i32, v2i64, v4f32, v2f64], CCAssignToStack<16, 16>>,
 130
 131   // __m64 vectors get 8-byte stack slots that are 8-byte aligned.
 132   CCIfType<[v8i8, v4i16, v2i32, v1i64], CCAssignToStack<8, 8>>
 133 ]>;
 134
 135 // Tail call convention (fast): One register is reserved for target address,
 136 // namely R9
 137 def CC_X86_64_TailCall : CallingConv<[
 138   // Handles byval parameters.
 139   CCIfByVal<CCPassByVal<8, 8>>,
 140
 141   // Promote i8/i16 arguments to i32.
 142   CCIfType<[i8, i16], CCPromoteToType<i32>>,
 143
 144   // The 'nest' parameter, if any, is passed in R10.
 145   CCIfNest<CCAssignToReg<[R10]>>,
 146
 147   // The first 6 integer arguments are passed in integer registers.
 148   CCIfType<[i32], CCAssignToReg<[EDI, ESI, EDX, ECX, R8D]>>,
 149   CCIfType<[i64], CCAssignToReg<[RDI, RSI, RDX, RCX, R8]>>,
 150
 151   // The first 8 FP/Vector arguments are passed in XMM registers.
 152   CCIfType<[f32, f64, v16i8, v8i16, v4i32, v2i64, v4f32, v2f64],
 153               CCAssignToReg<[XMM0, XMM1, XMM2, XMM3, XMM4, XMM5, XMM6, XMM7]>>,
 154
 155   // The first 8 MMX vector arguments are passed in GPRs.
 156   CCIfType<[v8i8, v4i16, v2i32, v1i64],
 157               CCAssignToReg<[RDI, RSI, RDX, RCX, R8]>>,
 158
 159   // Integer/FP values get stored in stack slots that are 8 bytes in size and
 160   // 8-byte aligned if there are no more registers to hold them.
 161   CCIfType<[i32, i64, f32, f64], CCAssignToStack<8, 8>>,
 162
 163   // Vectors get 16-byte stack slots that are 16-byte aligned.
 164   CCIfType<[v16i8, v8i16, v4i32, v2i64, v4f32, v2f64], CCAssignToStack<16, 16>>,
 165
 166   // __m64 vectors get 8-byte stack slots that are 8-byte aligned.
 167   CCIfType<[v8i8, v4i16, v2i32, v1i64], CCAssignToStack<8, 8>>
 168 ]>;
 169
 170
 171 //===----------------------------------------------------------------------===//
 172 // X86 C Calling Convention
 173 //===----------------------------------------------------------------------===//
 174
 175 /// CC_X86_32_Common - In all X86-32 calling conventions, extra integers and FP
 176 /// values are spilled on the stack, and the first 4 vector values go in XMM
 177 /// regs.
 178 def CC_X86_32_Common : CallingConv<[
 179   // Handles byval parameters.
 180   CCIfByVal<CCPassByVal<4, 4>>,
 181
 182   // Integer/Float values get stored in stack slots that are 4 bytes in
 183   // size and 4-byte aligned.
 184   CCIfType<[i32, f32], CCAssignToStack<4, 4>>,
 185
 186   // Doubles get 8-byte slots that are 4-byte aligned.
 187   CCIfType<[f64], CCAssignToStack<8, 4>>,
 188
 189   // Long doubles get slots whose size depends on the subtarget.
 190   CCIfType<[f80], CCAssignToStack<0, 4>>,
 191
 192   // The first 4 vector arguments are passed in XMM registers.
 193   CCIfNotVarArg<CCIfType<[v16i8, v8i16, v4i32, v2i64, v4f32, v2f64],
 194                 CCAssignToReg<[XMM0, XMM1, XMM2, XMM3]>>>,
 195
 196   // Other vectors get 16-byte stack slots that are 16-byte aligned.
 197   CCIfType<[v16i8, v8i16, v4i32, v2i64, v4f32, v2f64], CCAssignToStack<16, 16>>,
 198
 199   // __m64 vectors get 8-byte stack slots that are 8-byte aligned. They are
 200   // passed in the parameter area.
 201   CCIfType<[v8i8, v4i16, v2i32, v1i64], CCAssignToStack<8, 8>>
 202 ]>;
 203
 204 def CC_X86_32_C : CallingConv<[
 205   // Promote i8/i16 arguments to i32.
 206   CCIfType<[i8, i16], CCPromoteToType<i32>>,
 207
 208   // The 'nest' parameter, if any, is passed in ECX.
 209   CCIfNest<CCAssignToReg<[ECX]>>,
 210
 211   // The first 3 integer arguments, if marked 'inreg' and if the call is not
 212   // a vararg call, are passed in integer registers.
 213   CCIfNotVarArg<CCIfInReg<CCIfType<[i32], CCAssignToReg<[EAX, EDX, ECX]>>>>,
 214
 215   // Otherwise, same as everything else.
 216   CCDelegateTo<CC_X86_32_Common>
 217 ]>;
 218
 219 /// Same as C calling convention except for non-free ECX which is used for storing
 220 /// a potential pointer to the tail called function.
 221 def CC_X86_32_TailCall : CallingConv<[
 222   // Promote i8/i16 arguments to i32.
 223   CCIfType<[i8, i16], CCPromoteToType<i32>>,
 224
 225   // Nested function trampolines are currently not supported by fastcc.
 226
 227   // The first 3 integer arguments, if marked 'inreg' and if the call is not
 228   // a vararg call, are passed in integer registers.
 229   CCIfNotVarArg<CCIfInReg<CCIfType<[i32], CCAssignToReg<[EAX, EDX]>>>>,
 230
 231   // Otherwise, same as everything else.
 232   CCDelegateTo<CC_X86_32_Common>
 233 ]>;
 234
 235 def CC_X86_32_FastCall : CallingConv<[
 236   // Promote i8/i16 arguments to i32.
 237   CCIfType<[i8, i16], CCPromoteToType<i32>>,
 238
 239   // The 'nest' parameter, if any, is passed in EAX.
 240   CCIfNest<CCAssignToReg<[EAX]>>,
 241
 242   // The first 2 integer arguments are passed in ECX/EDX
 243   CCIfType<[i32], CCAssignToReg<[ECX, EDX]>>,
 244
 245   // Otherwise, same as everything else.
 246   CCDelegateTo<CC_X86_32_Common>
 247 ]>;