lib/Target/WebAssembly/WebAssemblyInstrInfo.td

   1 // WebAssemblyInstrInfo.td-Describe the WebAssembly Instructions-*- tablegen -*-
   2 //
   3 //                     The LLVM Compiler Infrastructure
   4 //
   5 // This file is distributed under the University of Illinois Open Source
   6 // License. See LICENSE.TXT for details.
   7 //
   8 //===----------------------------------------------------------------------===//
   9 ///
  10 /// \file
  11 /// \brief WebAssembly Instruction definitions.
  12 ///
  13 //===----------------------------------------------------------------------===//
  14
  15 //===----------------------------------------------------------------------===//
  16 // WebAssembly Instruction Predicate Definitions.
  17 //===----------------------------------------------------------------------===//
  18
  19 def HasAddr32 : Predicate<"!Subtarget->hasAddr64()">;
  20 def HasAddr64 : Predicate<"Subtarget->hasAddr64()">;
  21 def HasSIMD128 : Predicate<"Subtarget->hasSIMD128()">,
  22                            AssemblerPredicate<"FeatureSIMD128", "simd128">;
  23
  24 //===----------------------------------------------------------------------===//
  25 // WebAssembly-specific DAG Node Types.
  26 //===----------------------------------------------------------------------===//
  27
  28 def SDT_WebAssemblyCallSeqStart : SDCallSeqStart<[SDTCisVT<0, iPTR>]>;
  29 def SDT_WebAssemblyCallSeqEnd :
  30     SDCallSeqEnd<[SDTCisVT<0, iPTR>, SDTCisVT<1, iPTR>]>;
  31 def SDT_WebAssemblyCall0    : SDTypeProfile<0, -1, [SDTCisPtrTy<0>]>;
  32 def SDT_WebAssemblyCall1    : SDTypeProfile<1, -1, [SDTCisPtrTy<1>]>;
  33 def SDT_WebAssemblyTableswitch : SDTypeProfile<0, -1, [SDTCisPtrTy<0>]>;
  34 def SDT_WebAssemblyArgument : SDTypeProfile<1, 1, [SDTCisVT<1, i32>]>;
  35 def SDT_WebAssemblyReturn   : SDTypeProfile<0, -1, []>;
  36 def SDT_WebAssemblyWrapper  : SDTypeProfile<1, 1, [SDTCisSameAs<0, 1>,
  37                                                    SDTCisPtrTy<0>]>;
  38
  39 //===----------------------------------------------------------------------===//
  40 // WebAssembly-specific DAG Nodes.
  41 //===----------------------------------------------------------------------===//
  42
  43 def WebAssemblycallseq_start :
  44     SDNode<"ISD::CALLSEQ_START", SDT_WebAssemblyCallSeqStart,
  45            [SDNPHasChain, SDNPOutGlue]>;
  46 def WebAssemblycallseq_end :
  47     SDNode<"ISD::CALLSEQ_END", SDT_WebAssemblyCallSeqEnd,
  48            [SDNPHasChain, SDNPOptInGlue, SDNPOutGlue]>;
  49 def WebAssemblycall0 : SDNode<"WebAssemblyISD::CALL0",
  50                               SDT_WebAssemblyCall0,
  51                               [SDNPHasChain, SDNPVariadic]>;
  52 def WebAssemblycall1 : SDNode<"WebAssemblyISD::CALL1",
  53                               SDT_WebAssemblyCall1,
  54                               [SDNPHasChain, SDNPVariadic]>;
  55 def WebAssemblytableswitch : SDNode<"WebAssemblyISD::TABLESWITCH",
  56                                     SDT_WebAssemblyTableswitch,
  57                                     [SDNPHasChain, SDNPVariadic]>;
  58 def WebAssemblyargument : SDNode<"WebAssemblyISD::ARGUMENT",
  59                                  SDT_WebAssemblyArgument>;
  60 def WebAssemblyreturn   : SDNode<"WebAssemblyISD::RETURN",
  61                                  SDT_WebAssemblyReturn, [SDNPHasChain]>;
  62 def WebAssemblywrapper  : SDNode<"WebAssemblyISD::Wrapper",
  63                                  SDT_WebAssemblyWrapper>;
  64
  65 //===----------------------------------------------------------------------===//
  66 // WebAssembly-specific Operands.
  67 //===----------------------------------------------------------------------===//
  68
  69 def bb_op : Operand<OtherVT>;
  70 def tjumptable_op : Operand<iPTR>;
  71 def global : Operand<iPTR>;
  72
  73 //===----------------------------------------------------------------------===//
  74 // WebAssembly Instruction Format Definitions.
  75 //===----------------------------------------------------------------------===//
  76
  77 include "WebAssemblyInstrFormats.td"
  78
  79 //===----------------------------------------------------------------------===//
  80 // Additional instructions.
  81 //===----------------------------------------------------------------------===//
  82
  83 multiclass ARGUMENT<WebAssemblyRegClass vt> {
  84   def ARGUMENT_#vt : I<(outs vt:$res), (ins i32imm:$argno),
  85                        [(set vt:$res, (WebAssemblyargument timm:$argno))]>;
  86 }
  87 defm : ARGUMENT<I32>;
  88 defm : ARGUMENT<I64>;
  89 defm : ARGUMENT<F32>;
  90 defm : ARGUMENT<F64>;
  91
  92 // get_local and set_local are not generated by instruction selection; they
  93 // are implied by virtual register uses and defs in most contexts. However,
  94 // they are explicitly emitted for special purposes.
  95 multiclass LOCAL<WebAssemblyRegClass vt> {
  96   def GET_LOCAL_#vt : I<(outs vt:$res), (ins i32imm:$regno), [],
  97                         "get_local\t$res, $regno">;
  98   // TODO: set_local returns its operand value
  99   def SET_LOCAL_#vt : I<(outs), (ins i32imm:$regno, vt:$src), [],
 100                         "set_local\t$regno, $src">;
 101
 102   // COPY_LOCAL is not an actual instruction in wasm, but since we allow
 103   // get_local and set_local to be implicit, we can have a COPY_LOCAL which
 104   // is actually a no-op because all the work is done in the implied
 105   // get_local and set_local.
 106   let isAsCheapAsAMove = 1 in
 107   def COPY_LOCAL_#vt : I<(outs vt:$res), (ins vt:$src), [],
 108                          "copy_local\t$res, $src">;
 109 }
 110 defm : LOCAL<I32>;
 111 defm : LOCAL<I64>;
 112 defm : LOCAL<F32>;
 113 defm : LOCAL<F64>;
 114
 115 def CONST_I32 : I<(outs I32:$res), (ins i32imm:$imm),
 116                   [(set I32:$res, imm:$imm)],
 117                   "i32.const\t$res, $imm">;
 118 def CONST_I64 : I<(outs I64:$res), (ins i64imm:$imm),
 119                   [(set I64:$res, imm:$imm)],
 120                   "i64.const\t$res, $imm">;
 121 def CONST_F32 : I<(outs F32:$res), (ins f32imm:$imm),
 122                   [(set F32:$res, fpimm:$imm)],
 123                   "f32.const\t$res, $imm">;
 124 def CONST_F64 : I<(outs F64:$res), (ins f64imm:$imm),
 125                   [(set F64:$res, fpimm:$imm)],
 126                   "f64.const\t$res, $imm">;
 127
 128 def : Pat<(i32 (WebAssemblywrapper tglobaladdr :$dst)),
 129           (CONST_I32 tglobaladdr :$dst)>;
 130
 131 def JUMP_TABLE : I<(outs I32:$dst), (ins tjumptable_op:$addr),
 132                    [(set I32:$dst, (WebAssemblywrapper tjumptable:$addr))],
 133                    "jump_table\t$dst, $addr">;
 134
 135 // Function signature and local variable declaration "instructions".
 136 def PARAM  : I<(outs), (ins variable_ops), [], ".param  \t">;
 137 def RESULT : I<(outs), (ins variable_ops), [], ".result \t">;
 138 def LOCAL  : I<(outs), (ins variable_ops), [], ".local  \t">;
 139
 140 //===----------------------------------------------------------------------===//
 141 // Additional sets of instructions.
 142 //===----------------------------------------------------------------------===//
 143
 144 include "WebAssemblyInstrMemory.td"
 145 include "WebAssemblyInstrCall.td"
 146 include "WebAssemblyInstrControl.td"
 147 include "WebAssemblyInstrInteger.td"
 148 include "WebAssemblyInstrFloat.td"
 149 include "WebAssemblyInstrConv.td"
 150 include "WebAssemblyInstrAtomics.td"
 151 include "WebAssemblyInstrSIMD.td"