lib/Target/WebAssembly/WebAssemblyInstrControl.td

   1 //===- WebAssemblyInstrControl.td-WebAssembly control-flow ------*- tablegen -*-
   2 //
   3 //                     The LLVM Compiler Infrastructure
   4 //
   5 // This file is distributed under the University of Illinois Open Source
   6 // License. See LICENSE.TXT for details.
   7 //
   8 //===----------------------------------------------------------------------===//
   9 ///
  10 /// \file
  11 /// \brief WebAssembly control-flow code-gen constructs.
  12 ///
  13 //===----------------------------------------------------------------------===//
  14
  15 /*
  16  * TODO(jfb): Add the following.
  17  *
  18  * block: a fixed-length sequence of statements
  19  * if: if statement
  20  * do_while: do while statement, basically a loop with a conditional branch
  21  * forever: infinite loop statement (like while (1)), basically an unconditional
  22  *          branch (back to the top of the loop)
  23  * continue: continue to start of nested loop
  24  * break: break to end from nested loop or block
  25  * switch: switch statement with fallthrough
  26  */
  27
  28 let isBranch = 1, isTerminator = 1, hasCtrlDep = 1 in {
  29 def BR_IF_ : I<(outs), (ins bb_op:$dst, I32:$a),
  30                [(brcond I32:$a, bb:$dst)]>;
  31 let isBarrier = 1 in {
  32 def BR   : I<(outs), (ins bb_op:$dst),
  33              [(br bb:$dst)]>;
  34 } // isBarrier = 1
  35 } // isBranch = 1, isTerminator = 1, hasCtrlDep = 1
  36
  37 // TODO: SelectionDAG's lowering insists on using a pointer as the index for
  38 // jump tables, so in practice we don't ever use SWITCH_I64 in wasm32 mode
  39 // currently.
  40 let isTerminator = 1, hasCtrlDep = 1, isBarrier = 1 in {
  41 def SWITCH_I32 : I<(outs), (ins I32:$index, variable_ops),
  42                    [(WebAssemblyswitch I32:$index)]>;
  43 def SWITCH_I64 : I<(outs), (ins I64:$index, variable_ops),
  44                    [(WebAssemblyswitch I64:$index)]>;
  45 } // isTerminator = 1, hasCtrlDep = 1, isBarrier = 1
  46
  47 // Placemarkers to indicate the start of a block or loop scope.
  48 def BLOCK     : I<(outs), (ins bb_op:$dst), []>;
  49 def LOOP      : I<(outs), (ins bb_op:$dst), []>;
  50
  51 multiclass RETURN<WebAssemblyRegClass vt> {
  52   def RETURN_#vt : I<(outs), (ins vt:$val), [(WebAssemblyreturn vt:$val)]>;
  53 }
  54 let isReturn = 1, isTerminator = 1, hasCtrlDep = 1, isBarrier = 1 in {
  55   defm : RETURN<I32>;
  56   defm : RETURN<I64>;
  57   defm : RETURN<F32>;
  58   defm : RETURN<F64>;
  59   def RETURN_VOID : I<(outs), (ins), [(WebAssemblyreturn)]>;
  60 } // isReturn = 1, isTerminator = 1, hasCtrlDep = 1, isBarrier = 1