lib/Target/WebAssembly/WebAssemblyInstrCall.td

   1 //===- WebAssemblyInstrCall.td-WebAssembly Call codegen support -*- tablegen -*-
   2 //
   3 //                     The LLVM Compiler Infrastructure
   4 //
   5 // This file is distributed under the University of Illinois Open Source
   6 // License. See LICENSE.TXT for details.
   7 //
   8 //===----------------------------------------------------------------------===//
   9 ///
  10 /// \file
  11 /// \brief WebAssembly Call operand code-gen constructs.
  12 ///
  13 //===----------------------------------------------------------------------===//
  14
  15 // TODO: addr64: These currently assume the callee address is 32-bit.
  16
  17 let Defs = [ARGUMENTS] in {
  18
  19 // Call sequence markers. These have an immediate which represents the amount of
  20 // stack space to allocate or free, which is used for varargs lowering.
  21 let Uses = [SP32, SP64], Defs = [SP32, SP64], isCodeGenOnly = 1 in {
  22 def ADJCALLSTACKDOWN : I<(outs), (ins i32imm:$amt),
  23                          [(WebAssemblycallseq_start timm:$amt)]>;
  24 def ADJCALLSTACKUP : I<(outs), (ins i32imm:$amt),
  25                        [(WebAssemblycallseq_end timm:$amt, undef)]>;
  26 } // isCodeGenOnly = 1
  27
  28 multiclass CALL<WebAssemblyRegClass vt, string prefix> {
  29   def CALL_#vt : I<(outs vt:$dst), (ins i32imm:$callee, variable_ops),
  30                    [(set vt:$dst, (WebAssemblycall1 (i32 imm:$callee)))],
  31                    !strconcat(prefix, "call\t$dst, $callee")>;
  32   def CALL_INDIRECT_#vt : I<(outs vt:$dst), (ins I32:$callee, variable_ops),
  33                             [(set vt:$dst, (WebAssemblycall1 I32:$callee))],
  34                             !strconcat(prefix, "call_indirect\t$dst, $callee")>;
  35 }
  36 let Uses = [SP32, SP64], isCall = 1 in {
  37   defm : CALL<I32, "i32.">;
  38   defm : CALL<I64, "i64.">;
  39   defm : CALL<F32, "f32.">;
  40   defm : CALL<F64, "f64.">;
  41
  42   def CALL_VOID : I<(outs), (ins i32imm:$callee, variable_ops),
  43                     [(WebAssemblycall0 (i32 imm:$callee))],
  44                     "call    \t$callee">;
  45   def CALL_INDIRECT_VOID : I<(outs), (ins I32:$callee, variable_ops),
  46                              [(WebAssemblycall0 I32:$callee)],
  47                              "call_indirect\t$callee">;
  48 } // Uses = [SP32,SP64], isCall = 1
  49
  50 } // Defs = [ARGUMENTS]
  51
  52 // Patterns for matching a direct call to a global address.
  53 def : Pat<(i32 (WebAssemblycall1 (WebAssemblywrapper tglobaladdr:$callee))),
  54           (CALL_I32 tglobaladdr:$callee)>;
  55 def : Pat<(i64 (WebAssemblycall1 (WebAssemblywrapper tglobaladdr:$callee))),
  56           (CALL_I64 tglobaladdr:$callee)>;
  57 def : Pat<(f32 (WebAssemblycall1 (WebAssemblywrapper tglobaladdr:$callee))),
  58           (CALL_F32 tglobaladdr:$callee)>;
  59 def : Pat<(f64 (WebAssemblycall1 (WebAssemblywrapper tglobaladdr:$callee))),
  60           (CALL_F64 tglobaladdr:$callee)>;
  61 def : Pat<(WebAssemblycall0 (WebAssemblywrapper tglobaladdr:$callee)),
  62           (CALL_VOID tglobaladdr:$callee)>;
  63
  64 // Patterns for matching a direct call to an external symbol.
  65 def : Pat<(i32 (WebAssemblycall1 (WebAssemblywrapper texternalsym:$callee))),
  66           (CALL_I32 texternalsym:$callee)>;
  67 def : Pat<(i64 (WebAssemblycall1 (WebAssemblywrapper texternalsym:$callee))),
  68           (CALL_I64 texternalsym:$callee)>;
  69 def : Pat<(f32 (WebAssemblycall1 (WebAssemblywrapper texternalsym:$callee))),
  70           (CALL_F32 texternalsym:$callee)>;
  71 def : Pat<(f64 (WebAssemblycall1 (WebAssemblywrapper texternalsym:$callee))),
  72           (CALL_F64 texternalsym:$callee)>;
  73 def : Pat<(WebAssemblycall0 (WebAssemblywrapper texternalsym:$callee)),
  74           (CALL_VOID texternalsym:$callee)>;