lib/Target/SystemZ/SystemZInstrInfo.td

   1 //===-- SystemZInstrInfo.td - General SystemZ instructions ----*- tblgen-*-===//
   2 //
   3 //                     The LLVM Compiler Infrastructure
   4 //
   5 // This file is distributed under the University of Illinois Open Source
   6 // License. See LICENSE.TXT for details.
   7 //
   8 //===----------------------------------------------------------------------===//
   9
  10 //===----------------------------------------------------------------------===//
  11 // Stack allocation
  12 //===----------------------------------------------------------------------===//
  13
  14 def ADJCALLSTACKDOWN : Pseudo<(outs), (ins i64imm:$amt),
  15                               [(callseq_start timm:$amt)]>;
  16 def ADJCALLSTACKUP   : Pseudo<(outs), (ins i64imm:$amt1, i64imm:$amt2),
  17                               [(callseq_end timm:$amt1, timm:$amt2)]>;
  18
  19 let neverHasSideEffects = 1 in {
  20   // Takes as input the value of the stack pointer after a dynamic allocation
  21   // has been made.  Sets the output to the address of the dynamically-
  22   // allocated area itself, skipping the outgoing arguments.
  23   //
  24   // This expands to an LA or LAY instruction.  We restrict the offset
  25   // to the range of LA and keep the LAY range in reserve for when
  26   // the size of the outgoing arguments is added.
  27   def ADJDYNALLOC : Pseudo<(outs GR64:$dst), (ins dynalloc12only:$src),
  28                            [(set GR64:$dst, dynalloc12only:$src)]>;
  29 }
  30
  31 //===----------------------------------------------------------------------===//
  32 // Control flow instructions
  33 //===----------------------------------------------------------------------===//
  34
  35 // A return instruction.  R1 is the condition-code mask (all 1s)
  36 // and R2 is the target address, which is always stored in %r14.
  37 let isReturn = 1, isTerminator = 1, isBarrier = 1, hasCtrlDep = 1,
  38     R1 = 15, R2 = 14, isCodeGenOnly = 1 in {
  39   def RET : InstRR<0x07, (outs), (ins), "br\t%r14", [(z_retflag)]>;
  40 }
  41
  42 // Unconditional branches.  R1 is the condition-code mask (all 1s).
  43 let isBranch = 1, isTerminator = 1, isBarrier = 1, R1 = 15 in {
  44   let isIndirectBranch = 1 in
  45     def BR : InstRR<0x07, (outs), (ins ADDR64:$R2),
  46                     "br\t$R2", [(brind ADDR64:$R2)]>;
  47
  48   // An assembler extended mnemonic for BRC.
  49   def J : InstRI<0xA74, (outs), (ins brtarget16:$I2), "j\t$I2",
  50                  [(br bb:$I2)]>;
  51
  52   // An assembler extended mnemonic for BRCL.  (The extension is "G"
  53   // rather than "L" because "JL" is "Jump if Less".)
  54   def JG : InstRIL<0xC04, (outs), (ins brtarget32:$I2), "jg\t$I2", []>;
  55 }
  56
  57 // Conditional branches.  It's easier for LLVM to handle these branches
  58 // in their raw BRC/BRCL form, with the 4-bit condition-code mask being
  59 // the first operand.  It seems friendlier to use mnemonic forms like
  60 // JE and JLH when writing out the assembly though.
  61 let isBranch = 1, isTerminator = 1, Uses = [CC] in {
  62   let isCodeGenOnly = 1, CCMaskFirst = 1 in {
  63     def BRC : InstRI<0xA74, (outs), (ins cond4:$valid, cond4:$R1,
  64                                          brtarget16:$I2), "j$R1\t$I2",
  65                      [(z_br_ccmask cond4:$valid, cond4:$R1, bb:$I2)]>;
  66     def BRCL : InstRIL<0xC04, (outs), (ins cond4:$valid, cond4:$R1,
  67                                            brtarget32:$I2), "jg$R1\t$I2", []>;
  68   }
  69   def AsmBRC : InstRI<0xA74, (outs), (ins uimm8zx4:$R1, brtarget16:$I2),
  70                       "brc\t$R1, $I2", []>;
  71   def AsmBRCL : InstRIL<0xC04, (outs), (ins uimm8zx4:$R1, brtarget32:$I2),
  72                         "brcl\t$R1, $I2", []>;
  73 }
  74
  75 // Fused compare-and-branch instructions.  As for normal branches,
  76 // we handle these instructions internally in their raw CRJ-like form,
  77 // but use assembly macros like CRJE when writing them out.
  78 //
  79 // These instructions do not use or clobber the condition codes.
  80 // We nevertheless pretend that they clobber CC, so that we can lower
  81 // them to separate comparisons and BRCLs if the branch ends up being
  82 // out of range.
  83 multiclass CompareBranches<Operand ccmask, string pos1, string pos2> {
  84   let isBranch = 1, isTerminator = 1, Defs = [CC] in {
  85     def RJ  : InstRIEb<0xEC76, (outs), (ins GR32:$R1, GR32:$R2, ccmask:$M3,
  86                                             brtarget16:$RI4),
  87                        "crj"##pos1##"\t$R1, $R2, "##pos2##"$RI4", []>;
  88     def GRJ : InstRIEb<0xEC64, (outs), (ins GR64:$R1, GR64:$R2, ccmask:$M3,
  89                                             brtarget16:$RI4),
  90                        "cgrj"##pos1##"\t$R1, $R2, "##pos2##"$RI4", []>;
  91     def IJ  : InstRIEc<0xEC7E, (outs), (ins GR32:$R1, imm32sx8:$I2, ccmask:$M3,
  92                                             brtarget16:$RI4),
  93                        "cij"##pos1##"\t$R1, $I2, "##pos2##"$RI4", []>;
  94     def GIJ : InstRIEc<0xEC7C, (outs), (ins GR64:$R1, imm64sx8:$I2, ccmask:$M3,
  95                                             brtarget16:$RI4),
  96                        "cgij"##pos1##"\t$R1, $I2, "##pos2##"$RI4", []>;
  97   }
  98 }
  99 let isCodeGenOnly = 1 in
 100   defm C : CompareBranches<cond4, "$M3", "">;
 101 defm AsmC : CompareBranches<uimm8zx4, "", "$M3, ">;
 102
 103 // Define AsmParser mnemonics for each general condition-code mask
 104 // (integer or floating-point)
 105 multiclass CondExtendedMnemonic<bits<4> ccmask, string name> {
 106   let R1 = ccmask in {
 107     def J : InstRI<0xA74, (outs), (ins brtarget16:$I2),
 108                    "j"##name##"\t$I2", []>;
 109     def JG : InstRIL<0xC04, (outs), (ins brtarget32:$I2),
 110                      "jg"##name##"\t$I2", []>;
 111   }
 112   def LOCR  : FixedCondUnaryRRF<"locr"##name,  0xB9F2, GR32, GR32, ccmask>;
 113   def LOCGR : FixedCondUnaryRRF<"locgr"##name, 0xB9E2, GR64, GR64, ccmask>;
 114   def LOC   : FixedCondUnaryRSY<"loc"##name,   0xEBF2, GR32, ccmask, 4>;
 115   def LOCG  : FixedCondUnaryRSY<"locg"##name,  0xEBE2, GR64, ccmask, 8>;
 116   def STOC  : FixedCondStoreRSY<"stoc"##name,  0xEBF3, GR32, ccmask, 4>;
 117   def STOCG : FixedCondStoreRSY<"stocg"##name, 0xEBE3, GR64, ccmask, 8>;
 118 }
 119 defm AsmO   : CondExtendedMnemonic<1,  "o">;
 120 defm AsmH   : CondExtendedMnemonic<2,  "h">;
 121 defm AsmNLE : CondExtendedMnemonic<3,  "nle">;
 122 defm AsmL   : CondExtendedMnemonic<4,  "l">;
 123 defm AsmNHE : CondExtendedMnemonic<5,  "nhe">;
 124 defm AsmLH  : CondExtendedMnemonic<6,  "lh">;
 125 defm AsmNE  : CondExtendedMnemonic<7,  "ne">;
 126 defm AsmE   : CondExtendedMnemonic<8,  "e">;
 127 defm AsmNLH : CondExtendedMnemonic<9,  "nlh">;
 128 defm AsmHE  : CondExtendedMnemonic<10, "he">;
 129 defm AsmNL  : CondExtendedMnemonic<11, "nl">;
 130 defm AsmLE  : CondExtendedMnemonic<12, "le">;
 131 defm AsmNH  : CondExtendedMnemonic<13, "nh">;
 132 defm AsmNO  : CondExtendedMnemonic<14, "no">;
 133
 134 // Define AsmParser mnemonics for each integer condition-code mask.
 135 // This is like the list above, except that condition 3 is not possible
 136 // and that the low bit of the mask is therefore always 0.  This means
 137 // that each condition has two names.  Conditions "o" and "no" are not used.
 138 //
 139 // We don't make one of the two names an alias of the other because
 140 // we need the custom parsing routines to select the correct register class.
 141 multiclass IntCondExtendedMnemonicA<bits<4> ccmask, string name> {
 142   let M3 = ccmask in {
 143     def CR  : InstRIEb<0xEC76, (outs), (ins GR32:$R1, GR32:$R2,
 144                                             brtarget16:$RI4),
 145                        "crj"##name##"\t$R1, $R2, $RI4", []>;
 146     def CGR : InstRIEb<0xEC64, (outs), (ins GR64:$R1, GR64:$R2,
 147                                             brtarget16:$RI4),
 148                        "cgrj"##name##"\t$R1, $R2, $RI4", []>;
 149     def CI  : InstRIEc<0xEC7E, (outs), (ins GR32:$R1, imm32sx8:$I2,
 150                                             brtarget16:$RI4),
 151                        "cij"##name##"\t$R1, $I2, $RI4", []>;
 152     def CGI : InstRIEc<0xEC7C, (outs), (ins GR64:$R1, imm64sx8:$I2,
 153                                             brtarget16:$RI4),
 154                        "cgij"##name##"\t$R1, $I2, $RI4", []>;
 155   }
 156 }
 157 multiclass IntCondExtendedMnemonic<bits<4> ccmask, string name1, string name2>
 158   : IntCondExtendedMnemonicA<ccmask, name1> {
 159   let isAsmParserOnly = 1 in
 160     defm Alt : IntCondExtendedMnemonicA<ccmask, name2>;
 161 }
 162 defm AsmJH   : IntCondExtendedMnemonic<2,  "h",  "nle">;
 163 defm AsmJL   : IntCondExtendedMnemonic<4,  "l",  "nhe">;
 164 defm AsmJLH  : IntCondExtendedMnemonic<6,  "lh", "ne">;
 165 defm AsmJE   : IntCondExtendedMnemonic<8,  "e",  "nlh">;
 166 defm AsmJHE  : IntCondExtendedMnemonic<10, "he", "nl">;
 167 defm AsmJLE  : IntCondExtendedMnemonic<12, "le", "nh">;
 168
 169 // Decrement a register and branch if it is nonzero.  These don't clobber CC,
 170 // but we might need to split long branches into sequences that do.
 171 let Defs = [CC] in {
 172   def BRCT  : BranchUnaryRI<"brct",  0xA76, GR32>;
 173   def BRCTG : BranchUnaryRI<"brctg", 0xA77, GR64>;
 174 }
 175
 176 //===----------------------------------------------------------------------===//
 177 // Select instructions
 178 //===----------------------------------------------------------------------===//
 179
 180 def Select32 : SelectWrapper<GR32>;
 181 def Select64 : SelectWrapper<GR64>;
 182
 183 defm CondStore8_32  : CondStores<GR32, nonvolatile_truncstorei8,
 184                                  nonvolatile_anyextloadi8, bdxaddr20only>;
 185 defm CondStore16_32 : CondStores<GR32, nonvolatile_truncstorei16,
 186                                  nonvolatile_anyextloadi16, bdxaddr20only>;
 187 defm CondStore32_32 : CondStores<GR32, nonvolatile_store,
 188                                  nonvolatile_load, bdxaddr20only>;
 189
 190 defm CondStore8  : CondStores<GR64, nonvolatile_truncstorei8,
 191                               nonvolatile_anyextloadi8, bdxaddr20only>;
 192 defm CondStore16 : CondStores<GR64, nonvolatile_truncstorei16,
 193                               nonvolatile_anyextloadi16, bdxaddr20only>;
 194 defm CondStore32 : CondStores<GR64, nonvolatile_truncstorei32,
 195                               nonvolatile_anyextloadi32, bdxaddr20only>;
 196 defm CondStore64 : CondStores<GR64, nonvolatile_store,
 197                               nonvolatile_load, bdxaddr20only>;
 198
 199 //===----------------------------------------------------------------------===//
 200 // Call instructions
 201 //===----------------------------------------------------------------------===//
 202
 203 // The definitions here are for the call-clobbered registers.
 204 let isCall = 1, Defs = [R0D, R1D, R2D, R3D, R4D, R5D, R14D,
 205                         F0D, F1D, F2D, F3D, F4D, F5D, F6D, F7D, CC],
 206     R1 = 14, isCodeGenOnly = 1 in {
 207   def BRAS  : InstRI<0xA75, (outs), (ins pcrel16call:$I2, variable_ops),
 208                      "bras\t%r14, $I2", []>;
 209   def BRASL : InstRIL<0xC05, (outs), (ins pcrel32call:$I2, variable_ops),
 210                       "brasl\t%r14, $I2", [(z_call pcrel32call:$I2)]>;
 211   def BASR  : InstRR<0x0D, (outs), (ins ADDR64:$R2, variable_ops),
 212                      "basr\t%r14, $R2", [(z_call ADDR64:$R2)]>;
 213 }
 214
 215 // Sibling calls.  Indirect sibling calls must be via R1, since R2 upwards
 216 // are argument registers and since branching to R0 is a no-op.
 217 let isCall = 1, isTerminator = 1, isReturn = 1, isBarrier = 1,
 218     isCodeGenOnly = 1, R1 = 15 in {
 219   def CallJG : InstRIL<0xC04, (outs), (ins pcrel32call:$I2),
 220                        "jg\t$I2", [(z_sibcall pcrel32call:$I2)]>;
 221   let R2 = 1, Uses = [R1D] in
 222     def CallBR : InstRR<0x07, (outs), (ins), "br\t%r1", [(z_sibcall R1D)]>;
 223 }
 224
 225 // Define the general form of the call instructions for the asm parser.
 226 // These instructions don't hard-code %r14 as the return address register.
 227 def AsmBRAS  : InstRI<0xA75, (outs), (ins GR64:$R1, brtarget16:$I2),
 228                       "bras\t$R1, $I2", []>;
 229 def AsmBRASL : InstRIL<0xC05, (outs), (ins GR64:$R1, brtarget32:$I2),
 230                        "brasl\t$R1, $I2", []>;
 231 def AsmBASR  : InstRR<0x0D, (outs), (ins GR64:$R1, ADDR64:$R2),
 232                       "basr\t$R1, $R2", []>;
 233
 234 //===----------------------------------------------------------------------===//
 235 // Move instructions
 236 //===----------------------------------------------------------------------===//
 237
 238 // Register moves.
 239 let neverHasSideEffects = 1 in {
 240   def LR  : UnaryRR <"l",  0x18,   null_frag, GR32, GR32>;
 241   def LGR : UnaryRRE<"lg", 0xB904, null_frag, GR64, GR64>;
 242 }
 243 let Defs = [CC], CCValues = 0xE, CompareZeroCCMask = 0xE in {
 244   def LTR  : UnaryRR <"lt",  0x12,   null_frag, GR32, GR32>;
 245   def LTGR : UnaryRRE<"ltg", 0xB902, null_frag, GR64, GR64>;
 246 }
 247
 248 // Move on condition.
 249 let isCodeGenOnly = 1, Uses = [CC] in {
 250   def LOCR  : CondUnaryRRF<"loc",  0xB9F2, GR32, GR32>;
 251   def LOCGR : CondUnaryRRF<"locg", 0xB9E2, GR64, GR64>;
 252 }
 253 let Uses = [CC] in {
 254   def AsmLOCR  : AsmCondUnaryRRF<"loc",  0xB9F2, GR32, GR32>;
 255   def AsmLOCGR : AsmCondUnaryRRF<"locg", 0xB9E2, GR64, GR64>;
 256 }
 257
 258 // Immediate moves.
 259 let neverHasSideEffects = 1, isAsCheapAsAMove = 1, isMoveImm = 1,
 260     isReMaterializable = 1 in {
 261   // 16-bit sign-extended immediates.
 262   def LHI  : UnaryRI<"lhi",  0xA78, bitconvert, GR32, imm32sx16>;
 263   def LGHI : UnaryRI<"lghi", 0xA79, bitconvert, GR64, imm64sx16>;
 264
 265   // Other 16-bit immediates.
 266   def LLILL : UnaryRI<"llill", 0xA5F, bitconvert, GR64, imm64ll16>;
 267   def LLILH : UnaryRI<"llilh", 0xA5E, bitconvert, GR64, imm64lh16>;
 268   def LLIHL : UnaryRI<"llihl", 0xA5D, bitconvert, GR64, imm64hl16>;
 269   def LLIHH : UnaryRI<"llihh", 0xA5C, bitconvert, GR64, imm64hh16>;
 270
 271   // 32-bit immediates.
 272   def LGFI  : UnaryRIL<"lgfi",  0xC01, bitconvert, GR64, imm64sx32>;
 273   def LLILF : UnaryRIL<"llilf", 0xC0F, bitconvert, GR64, imm64lf32>;
 274   def LLIHF : UnaryRIL<"llihf", 0xC0E, bitconvert, GR64, imm64hf32>;
 275 }
 276
 277 // Register loads.
 278 let canFoldAsLoad = 1, SimpleBDXLoad = 1 in {
 279   defm L : UnaryRXPair<"l", 0x58, 0xE358, load, GR32, 4>;
 280   def LG : UnaryRXY<"lg", 0xE304, load, GR64, 8>;
 281
 282   // These instructions are split after register allocation, so we don't
 283   // want a custom inserter.
 284   let Has20BitOffset = 1, HasIndex = 1, Is128Bit = 1 in {
 285     def L128 : Pseudo<(outs GR128:$dst), (ins bdxaddr20only128:$src),
 286                       [(set GR128:$dst, (load bdxaddr20only128:$src))]>;
 287   }
 288 }
 289 let Defs = [CC], CCValues = 0xE, CompareZeroCCMask = 0xE in {
 290   def LT  : UnaryRXY<"lt",  0xE312, load, GR32, 4>;
 291   def LTG : UnaryRXY<"ltg", 0xE302, load, GR64, 8>;
 292 }
 293
 294 let canFoldAsLoad = 1 in {
 295   def LRL  : UnaryRILPC<"lrl",  0xC4D, aligned_load, GR32>;
 296   def LGRL : UnaryRILPC<"lgrl", 0xC48, aligned_load, GR64>;
 297 }
 298
 299 // Load on condition.
 300 let isCodeGenOnly = 1, Uses = [CC] in {
 301   def LOC  : CondUnaryRSY<"loc",  0xEBF2, nonvolatile_load, GR32, 4>;
 302   def LOCG : CondUnaryRSY<"locg", 0xEBE2, nonvolatile_load, GR64, 8>;
 303 }
 304 let Uses = [CC] in {
 305   def AsmLOC  : AsmCondUnaryRSY<"loc",  0xEBF2, GR32, 4>;
 306   def AsmLOCG : AsmCondUnaryRSY<"locg", 0xEBE2, GR64, 8>;
 307 }
 308
 309 // Register stores.
 310 let SimpleBDXStore = 1 in {
 311   let isCodeGenOnly = 1 in
 312     defm ST32 : StoreRXPair<"st", 0x50, 0xE350, store, GR32, 4>;
 313   def STG : StoreRXY<"stg", 0xE324, store, GR64, 8>;
 314
 315   // These instructions are split after register allocation, so we don't
 316   // want a custom inserter.
 317   let Has20BitOffset = 1, HasIndex = 1, Is128Bit = 1 in {
 318     def ST128 : Pseudo<(outs), (ins GR128:$src, bdxaddr20only128:$dst),
 319                        [(store GR128:$src, bdxaddr20only128:$dst)]>;
 320   }
 321 }
 322 let isCodeGenOnly = 1 in
 323   def STRL32 : StoreRILPC<"strl", 0xC4F, aligned_store, GR32>;
 324 def STGRL : StoreRILPC<"stgrl", 0xC4B, aligned_store, GR64>;
 325
 326 // Store on condition.
 327 let isCodeGenOnly = 1, Uses = [CC] in {
 328   def STOC32 : CondStoreRSY<"stoc",  0xEBF3, GR32, 4>;
 329   def STOC   : CondStoreRSY<"stoc",  0xEBF3, GR64, 4>;
 330   def STOCG  : CondStoreRSY<"stocg", 0xEBE3, GR64, 8>;
 331 }
 332 let Uses = [CC] in {
 333   def AsmSTOC  : AsmCondStoreRSY<"stoc",  0xEBF3, GR32, 4>;
 334   def AsmSTOCG : AsmCondStoreRSY<"stocg", 0xEBE3, GR64, 8>;
 335 }
 336
 337 // 8-bit immediate stores to 8-bit fields.
 338 defm MVI : StoreSIPair<"mvi", 0x92, 0xEB52, truncstorei8, imm32zx8trunc>;
 339
 340 // 16-bit immediate stores to 16-, 32- or 64-bit fields.
 341 def MVHHI : StoreSIL<"mvhhi", 0xE544, truncstorei16, imm32sx16trunc>;
 342 def MVHI  : StoreSIL<"mvhi",  0xE54C, store,         imm32sx16>;
 343 def MVGHI : StoreSIL<"mvghi", 0xE548, store,         imm64sx16>;
 344
 345 // Memory-to-memory moves.
 346 let mayLoad = 1, mayStore = 1 in
 347   defm MVC : MemorySS<"mvc", 0xD2, z_mvc>;
 348
 349 // String moves.
 350 let mayLoad = 1, mayStore = 1, Defs = [CC], Uses = [R0W] in
 351   defm MVST : StringRRE<"mvst", 0xB255, z_stpcpy>;
 352
 353 defm LoadStore8_32  : MVCLoadStore<anyextloadi8, truncstorei8, i32,
 354                                    MVCWrapper, 1>;
 355 defm LoadStore16_32 : MVCLoadStore<anyextloadi16, truncstorei16, i32,
 356                                    MVCWrapper, 2>;
 357 defm LoadStore32_32 : MVCLoadStore<load, store, i32, MVCWrapper, 4>;
 358
 359 defm LoadStore8  : MVCLoadStore<anyextloadi8, truncstorei8, i64,
 360                                 MVCWrapper, 1>;
 361 defm LoadStore16 : MVCLoadStore<anyextloadi16, truncstorei16, i64,
 362                                 MVCWrapper, 2>;
 363 defm LoadStore32 : MVCLoadStore<anyextloadi32, truncstorei32, i64,
 364                                 MVCWrapper, 4>;
 365 defm LoadStore64 : MVCLoadStore<load, store, i64, MVCWrapper, 8>;
 366
 367 //===----------------------------------------------------------------------===//
 368 // Sign extensions
 369 //===----------------------------------------------------------------------===//
 370
 371 // 32-bit extensions from registers.
 372 let neverHasSideEffects = 1 in {
 373   def LBR : UnaryRRE<"lb", 0xB926, sext8,  GR32, GR32>;
 374   def LHR : UnaryRRE<"lh", 0xB927, sext16, GR32, GR32>;
 375 }
 376
 377 // 64-bit extensions from registers.
 378 let neverHasSideEffects = 1 in {
 379   def LGBR : UnaryRRE<"lgb", 0xB906, sext8,  GR64, GR64>;
 380   def LGHR : UnaryRRE<"lgh", 0xB907, sext16, GR64, GR64>;
 381   def LGFR : UnaryRRE<"lgf", 0xB914, sext32, GR64, GR32>;
 382 }
 383 let Defs = [CC], CCValues = 0xE, CompareZeroCCMask = 0xE in
 384   def LTGFR : UnaryRRE<"ltgf", 0xB912, null_frag, GR64, GR64>;
 385
 386 // Match 32-to-64-bit sign extensions in which the source is already
 387 // in a 64-bit register.
 388 def : Pat<(sext_inreg GR64:$src, i32),
 389           (LGFR (EXTRACT_SUBREG GR64:$src, subreg_32bit))>;
 390
 391 // 32-bit extensions from memory.
 392 def  LB   : UnaryRXY<"lb", 0xE376, sextloadi8, GR32, 1>;
 393 defm LH   : UnaryRXPair<"lh", 0x48, 0xE378, sextloadi16, GR32, 2>;
 394 def  LHRL : UnaryRILPC<"lhrl", 0xC45, aligned_sextloadi16, GR32>;
 395
 396 // 64-bit extensions from memory.
 397 def LGB   : UnaryRXY<"lgb", 0xE377, sextloadi8,  GR64, 1>;
 398 def LGH   : UnaryRXY<"lgh", 0xE315, sextloadi16, GR64, 2>;
 399 def LGF   : UnaryRXY<"lgf", 0xE314, sextloadi32, GR64, 4>;
 400 def LGHRL : UnaryRILPC<"lghrl", 0xC44, aligned_sextloadi16, GR64>;
 401 def LGFRL : UnaryRILPC<"lgfrl", 0xC4C, aligned_sextloadi32, GR64>;
 402 let Defs = [CC], CCValues = 0xE, CompareZeroCCMask = 0xE in
 403   def LTGF : UnaryRXY<"ltgf", 0xE332, sextloadi32, GR64, 4>;
 404
 405 // If the sign of a load-extend operation doesn't matter, use the signed ones.
 406 // There's not really much to choose between the sign and zero extensions,
 407 // but LH is more compact than LLH for small offsets.
 408 def : Pat<(i32 (extloadi8  bdxaddr20only:$src)), (LB  bdxaddr20only:$src)>;
 409 def : Pat<(i32 (extloadi16 bdxaddr12pair:$src)), (LH  bdxaddr12pair:$src)>;
 410 def : Pat<(i32 (extloadi16 bdxaddr20pair:$src)), (LHY bdxaddr20pair:$src)>;
 411
 412 def : Pat<(i64 (extloadi8  bdxaddr20only:$src)), (LGB bdxaddr20only:$src)>;
 413 def : Pat<(i64 (extloadi16 bdxaddr20only:$src)), (LGH bdxaddr20only:$src)>;
 414 def : Pat<(i64 (extloadi32 bdxaddr20only:$src)), (LGF bdxaddr20only:$src)>;
 415
 416 // We want PC-relative addresses to be tried ahead of BD and BDX addresses.
 417 // However, BDXs have two extra operands and are therefore 6 units more
 418 // complex.
 419 let AddedComplexity = 7 in {
 420   def : Pat<(i32 (extloadi16 pcrel32:$src)), (LHRL  pcrel32:$src)>;
 421   def : Pat<(i64 (extloadi16 pcrel32:$src)), (LGHRL pcrel32:$src)>;
 422 }
 423
 424 //===----------------------------------------------------------------------===//
 425 // Zero extensions
 426 //===----------------------------------------------------------------------===//
 427
 428 // 32-bit extensions from registers.
 429 let neverHasSideEffects = 1 in {
 430   def LLCR : UnaryRRE<"llc", 0xB994, zext8,  GR32, GR32>;
 431   def LLHR : UnaryRRE<"llh", 0xB995, zext16, GR32, GR32>;
 432 }
 433
 434 // 64-bit extensions from registers.
 435 let neverHasSideEffects = 1 in {
 436   def LLGCR : UnaryRRE<"llgc", 0xB984, zext8,  GR64, GR64>;
 437   def LLGHR : UnaryRRE<"llgh", 0xB985, zext16, GR64, GR64>;
 438   def LLGFR : UnaryRRE<"llgf", 0xB916, zext32, GR64, GR32>;
 439 }
 440
 441 // Match 32-to-64-bit zero extensions in which the source is already
 442 // in a 64-bit register.
 443 def : Pat<(and GR64:$src, 0xffffffff),
 444           (LLGFR (EXTRACT_SUBREG GR64:$src, subreg_32bit))>;
 445
 446 // 32-bit extensions from memory.
 447 def LLC   : UnaryRXY<"llc", 0xE394, zextloadi8,  GR32, 1>;
 448 def LLH   : UnaryRXY<"llh", 0xE395, zextloadi16, GR32, 2>;
 449 def LLHRL : UnaryRILPC<"llhrl", 0xC42, aligned_zextloadi16, GR32>;
 450
 451 // 64-bit extensions from memory.
 452 def LLGC   : UnaryRXY<"llgc", 0xE390, zextloadi8,  GR64, 1>;
 453 def LLGH   : UnaryRXY<"llgh", 0xE391, zextloadi16, GR64, 2>;
 454 def LLGF   : UnaryRXY<"llgf", 0xE316, zextloadi32, GR64, 4>;
 455 def LLGHRL : UnaryRILPC<"llghrl", 0xC46, aligned_zextloadi16, GR64>;
 456 def LLGFRL : UnaryRILPC<"llgfrl", 0xC4E, aligned_zextloadi32, GR64>;
 457
 458 //===----------------------------------------------------------------------===//
 459 // Truncations
 460 //===----------------------------------------------------------------------===//
 461
 462 // Truncations of 64-bit registers to 32-bit registers.
 463 def : Pat<(i32 (trunc GR64:$src)),
 464           (EXTRACT_SUBREG GR64:$src, subreg_32bit)>;
 465
 466 // Truncations of 32-bit registers to memory.
 467 let isCodeGenOnly = 1 in {
 468   defm STC32   : StoreRXPair<"stc", 0x42, 0xE372, truncstorei8,  GR32, 1>;
 469   defm STH32   : StoreRXPair<"sth", 0x40, 0xE370, truncstorei16, GR32, 2>;
 470   def  STHRL32 : StoreRILPC<"sthrl", 0xC47, aligned_truncstorei16, GR32>;
 471 }
 472
 473 // Truncations of 64-bit registers to memory.
 474 defm STC   : StoreRXPair<"stc", 0x42, 0xE372, truncstorei8,  GR64, 1>;
 475 defm STH   : StoreRXPair<"sth", 0x40, 0xE370, truncstorei16, GR64, 2>;
 476 def  STHRL : StoreRILPC<"sthrl", 0xC47, aligned_truncstorei16, GR64>;
 477 defm ST    : StoreRXPair<"st", 0x50, 0xE350, truncstorei32, GR64, 4>;
 478 def  STRL  : StoreRILPC<"strl", 0xC4F, aligned_truncstorei32, GR64>;
 479
 480 //===----------------------------------------------------------------------===//
 481 // Multi-register moves
 482 //===----------------------------------------------------------------------===//
 483
 484 // Multi-register loads.
 485 def LMG : LoadMultipleRSY<"lmg", 0xEB04, GR64>;
 486
 487 // Multi-register stores.
 488 def STMG : StoreMultipleRSY<"stmg", 0xEB24, GR64>;
 489
 490 //===----------------------------------------------------------------------===//
 491 // Byte swaps
 492 //===----------------------------------------------------------------------===//
 493
 494 // Byte-swapping register moves.
 495 let neverHasSideEffects = 1 in {
 496   def LRVR  : UnaryRRE<"lrv",  0xB91F, bswap, GR32, GR32>;
 497   def LRVGR : UnaryRRE<"lrvg", 0xB90F, bswap, GR64, GR64>;
 498 }
 499
 500 // Byte-swapping loads.  Unlike normal loads, these instructions are
 501 // allowed to access storage more than once.
 502 def LRV  : UnaryRXY<"lrv",  0xE31E, loadu<bswap, nonvolatile_load>, GR32, 4>;
 503 def LRVG : UnaryRXY<"lrvg", 0xE30F, loadu<bswap, nonvolatile_load>, GR64, 8>;
 504
 505 // Likewise byte-swapping stores.
 506 def STRV  : StoreRXY<"strv", 0xE33E, storeu<bswap, nonvolatile_store>, GR32, 4>;
 507 def STRVG : StoreRXY<"strvg", 0xE32F, storeu<bswap, nonvolatile_store>,
 508                      GR64, 8>;
 509
 510 //===----------------------------------------------------------------------===//
 511 // Load address instructions
 512 //===----------------------------------------------------------------------===//
 513
 514 // Load BDX-style addresses.
 515 let neverHasSideEffects = 1, isAsCheapAsAMove = 1, isReMaterializable = 1,
 516     DispKey = "la" in {
 517   let DispSize = "12" in
 518     def LA : InstRX<0x41, (outs GR64:$R1), (ins laaddr12pair:$XBD2),
 519                     "la\t$R1, $XBD2",
 520                     [(set GR64:$R1, laaddr12pair:$XBD2)]>;
 521   let DispSize = "20" in
 522     def LAY : InstRXY<0xE371, (outs GR64:$R1), (ins laaddr20pair:$XBD2),
 523                       "lay\t$R1, $XBD2",
 524                       [(set GR64:$R1, laaddr20pair:$XBD2)]>;
 525 }
 526
 527 // Load a PC-relative address.  There's no version of this instruction
 528 // with a 16-bit offset, so there's no relaxation.
 529 let neverHasSideEffects = 1, isAsCheapAsAMove = 1, isMoveImm = 1,
 530     isReMaterializable = 1 in {
 531   def LARL : InstRIL<0xC00, (outs GR64:$R1), (ins pcrel32:$I2),
 532                      "larl\t$R1, $I2",
 533                      [(set GR64:$R1, pcrel32:$I2)]>;
 534 }
 535
 536 //===----------------------------------------------------------------------===//
 537 // Negation
 538 //===----------------------------------------------------------------------===//
 539
 540 let Defs = [CC] in {
 541   let CCValues = 0xF, CompareZeroCCMask = 0x8 in {
 542     def LCR  : UnaryRR <"lc",  0x13,   ineg, GR32, GR32>;
 543     def LCGR : UnaryRRE<"lcg", 0xB903, ineg, GR64, GR64>;
 544   }
 545   let CCValues = 0xE, CompareZeroCCMask = 0xE in
 546     def LCGFR : UnaryRRE<"lcgf", 0xB913, null_frag, GR64, GR32>;
 547 }
 548 defm : SXU<ineg, LCGFR>;
 549
 550 //===----------------------------------------------------------------------===//
 551 // Insertion
 552 //===----------------------------------------------------------------------===//
 553
 554 let isCodeGenOnly = 1 in
 555   defm IC32 : BinaryRXPair<"ic", 0x43, 0xE373, inserti8, GR32, zextloadi8, 1>;
 556 defm IC : BinaryRXPair<"ic", 0x43, 0xE373, inserti8, GR64, zextloadi8, 1>;
 557
 558 defm : InsertMem<"inserti8", IC32,  GR32, zextloadi8, bdxaddr12pair>;
 559 defm : InsertMem<"inserti8", IC32Y, GR32, zextloadi8, bdxaddr20pair>;
 560
 561 defm : InsertMem<"inserti8", IC,  GR64, zextloadi8, bdxaddr12pair>;
 562 defm : InsertMem<"inserti8", ICY, GR64, zextloadi8, bdxaddr20pair>;
 563
 564 // Insertions of a 16-bit immediate, leaving other bits unaffected.
 565 // We don't have or_as_insert equivalents of these operations because
 566 // OI is available instead.
 567 let isCodeGenOnly = 1 in {
 568   def IILL32 : BinaryRI<"iill", 0xA53, insertll, GR32, imm32ll16>;
 569   def IILH32 : BinaryRI<"iilh", 0xA52, insertlh, GR32, imm32lh16>;
 570 }
 571 def IILL : BinaryRI<"iill", 0xA53, insertll, GR64, imm64ll16>;
 572 def IILH : BinaryRI<"iilh", 0xA52, insertlh, GR64, imm64lh16>;
 573 def IIHL : BinaryRI<"iihl", 0xA51, inserthl, GR64, imm64hl16>;
 574 def IIHH : BinaryRI<"iihh", 0xA50, inserthh, GR64, imm64hh16>;
 575
 576 // ...likewise for 32-bit immediates.  For GR32s this is a general
 577 // full-width move.  (We use IILF rather than something like LLILF
 578 // for 32-bit moves because IILF leaves the upper 32 bits of the
 579 // GR64 unchanged.)
 580 let isCodeGenOnly = 1, isAsCheapAsAMove = 1, isMoveImm = 1,
 581     isReMaterializable = 1 in {
 582   def IILF32 : UnaryRIL<"iilf", 0xC09, bitconvert, GR32, uimm32>;
 583 }
 584 def IILF : BinaryRIL<"iilf", 0xC09, insertlf, GR64, imm64lf32>;
 585 def IIHF : BinaryRIL<"iihf", 0xC08, inserthf, GR64, imm64hf32>;
 586
 587 // An alternative model of inserthf, with the first operand being
 588 // a zero-extended value.
 589 def : Pat<(or (zext32 GR32:$src), imm64hf32:$imm),
 590           (IIHF (INSERT_SUBREG (i64 (IMPLICIT_DEF)), GR32:$src, subreg_32bit),
 591                 imm64hf32:$imm)>;
 592
 593 //===----------------------------------------------------------------------===//
 594 // Addition
 595 //===----------------------------------------------------------------------===//
 596
 597 // Plain addition.
 598 let Defs = [CC], CCValues = 0xF, CompareZeroCCMask = 0x8 in {
 599   // Addition of a register.
 600   let isCommutable = 1 in {
 601     defm AR : BinaryRRAndK<"a", 0x1A, 0xB9F8, add, GR32, GR32>;
 602     defm AGR : BinaryRREAndK<"ag", 0xB908, 0xB9E8, add, GR64, GR64>;
 603   }
 604   def AGFR : BinaryRRE<"agf", 0xB918, null_frag, GR64, GR32>;
 605
 606   // Addition of signed 16-bit immediates.
 607   defm AHI  : BinaryRIAndK<"ahi",  0xA7A, 0xECD8, add, GR32, imm32sx16>;
 608   defm AGHI : BinaryRIAndK<"aghi", 0xA7B, 0xECD9, add, GR64, imm64sx16>;
 609
 610   // Addition of signed 32-bit immediates.
 611   def AFI  : BinaryRIL<"afi",  0xC29, add, GR32, simm32>;
 612   def AGFI : BinaryRIL<"agfi", 0xC28, add, GR64, imm64sx32>;
 613
 614   // Addition of memory.
 615   defm AH  : BinaryRXPair<"ah", 0x4A, 0xE37A, add, GR32, sextloadi16, 2>;
 616   defm A   : BinaryRXPair<"a",  0x5A, 0xE35A, add, GR32, load, 4>;
 617   def  AGF : BinaryRXY<"agf", 0xE318, add, GR64, sextloadi32, 4>;
 618   def  AG  : BinaryRXY<"ag",  0xE308, add, GR64, load, 8>;
 619
 620   // Addition to memory.
 621   def ASI  : BinarySIY<"asi",  0xEB6A, add, imm32sx8>;
 622   def AGSI : BinarySIY<"agsi", 0xEB7A, add, imm64sx8>;
 623 }
 624 defm : SXB<add, GR64, AGFR>;
 625
 626 // Addition producing a carry.
 627 let Defs = [CC] in {
 628   // Addition of a register.
 629   let isCommutable = 1 in {
 630     defm ALR : BinaryRRAndK<"al", 0x1E, 0xB9FA, addc, GR32, GR32>;
 631     defm ALGR : BinaryRREAndK<"alg", 0xB90A, 0xB9EA, addc, GR64, GR64>;
 632   }
 633   def ALGFR : BinaryRRE<"algf", 0xB91A, null_frag, GR64, GR32>;
 634
 635   // Addition of signed 16-bit immediates.
 636   def ALHSIK  : BinaryRIE<"alhsik",  0xECDA, addc, GR32, imm32sx16>,
 637                 Requires<[FeatureDistinctOps]>;
 638   def ALGHSIK : BinaryRIE<"alghsik", 0xECDB, addc, GR64, imm64sx16>,
 639                 Requires<[FeatureDistinctOps]>;
 640
 641   // Addition of unsigned 32-bit immediates.
 642   def ALFI  : BinaryRIL<"alfi",  0xC2B, addc, GR32, uimm32>;
 643   def ALGFI : BinaryRIL<"algfi", 0xC2A, addc, GR64, imm64zx32>;
 644
 645   // Addition of memory.
 646   defm AL   : BinaryRXPair<"al", 0x5E, 0xE35E, addc, GR32, load, 4>;
 647   def  ALGF : BinaryRXY<"algf", 0xE31A, addc, GR64, zextloadi32, 4>;
 648   def  ALG  : BinaryRXY<"alg",  0xE30A, addc, GR64, load, 8>;
 649 }
 650 defm : ZXB<addc, GR64, ALGFR>;
 651
 652 // Addition producing and using a carry.
 653 let Defs = [CC], Uses = [CC] in {
 654   // Addition of a register.
 655   def ALCR  : BinaryRRE<"alc",  0xB998, adde, GR32, GR32>;
 656   def ALCGR : BinaryRRE<"alcg", 0xB988, adde, GR64, GR64>;
 657
 658   // Addition of memory.
 659   def ALC  : BinaryRXY<"alc",  0xE398, adde, GR32, load, 4>;
 660   def ALCG : BinaryRXY<"alcg", 0xE388, adde, GR64, load, 8>;
 661 }
 662
 663 //===----------------------------------------------------------------------===//
 664 // Subtraction
 665 //===----------------------------------------------------------------------===//
 666
 667 // Plain substraction.  Although immediate forms exist, we use the
 668 // add-immediate instruction instead.
 669 let Defs = [CC], CCValues = 0xF, CompareZeroCCMask = 0x8 in {
 670   // Subtraction of a register.
 671   defm SR : BinaryRRAndK<"s", 0x1B, 0xB9F9, sub, GR32, GR32>;
 672   def SGFR : BinaryRRE<"sgf", 0xB919, null_frag, GR64, GR32>;
 673   defm SGR : BinaryRREAndK<"sg", 0xB909, 0xB9E9, sub, GR64, GR64>;
 674
 675   // Subtraction of memory.
 676   defm SH  : BinaryRXPair<"sh", 0x4B, 0xE37B, sub, GR32, sextloadi16, 2>;
 677   defm S   : BinaryRXPair<"s", 0x5B, 0xE35B, sub, GR32, load, 4>;
 678   def  SGF : BinaryRXY<"sgf", 0xE319, sub, GR64, sextloadi32, 4>;
 679   def  SG  : BinaryRXY<"sg",  0xE309, sub, GR64, load, 8>;
 680 }
 681 defm : SXB<sub, GR64, SGFR>;
 682
 683 // Subtraction producing a carry.
 684 let Defs = [CC] in {
 685   // Subtraction of a register.
 686   defm SLR : BinaryRRAndK<"sl", 0x1F, 0xB9FB, subc, GR32, GR32>;
 687   def SLGFR : BinaryRRE<"slgf", 0xB91B, null_frag, GR64, GR32>;
 688   defm SLGR : BinaryRREAndK<"slg", 0xB90B, 0xB9EB, subc, GR64, GR64>;
 689
 690   // Subtraction of unsigned 32-bit immediates.  These don't match
 691   // subc because we prefer addc for constants.
 692   def SLFI  : BinaryRIL<"slfi",  0xC25, null_frag, GR32, uimm32>;
 693   def SLGFI : BinaryRIL<"slgfi", 0xC24, null_frag, GR64, imm64zx32>;
 694
 695   // Subtraction of memory.
 696   defm SL   : BinaryRXPair<"sl", 0x5F, 0xE35F, subc, GR32, load, 4>;
 697   def  SLGF : BinaryRXY<"slgf", 0xE31B, subc, GR64, zextloadi32, 4>;
 698   def  SLG  : BinaryRXY<"slg",  0xE30B, subc, GR64, load, 8>;
 699 }
 700 defm : ZXB<subc, GR64, SLGFR>;
 701
 702 // Subtraction producing and using a carry.
 703 let Defs = [CC], Uses = [CC] in {
 704   // Subtraction of a register.
 705   def SLBR  : BinaryRRE<"slb",  0xB999, sube, GR32, GR32>;
 706   def SLGBR : BinaryRRE<"slbg", 0xB989, sube, GR64, GR64>;
 707
 708   // Subtraction of memory.
 709   def SLB  : BinaryRXY<"slb",  0xE399, sube, GR32, load, 4>;
 710   def SLBG : BinaryRXY<"slbg", 0xE389, sube, GR64, load, 8>;
 711 }
 712
 713 //===----------------------------------------------------------------------===//
 714 // AND
 715 //===----------------------------------------------------------------------===//
 716
 717 let Defs = [CC] in {
 718   // ANDs of a register.
 719   let isCommutable = 1, CCValues = 0xC, CompareZeroCCMask = 0x8 in {
 720     defm NR : BinaryRRAndK<"n", 0x14, 0xB9F4, and, GR32, GR32>;
 721     defm NGR : BinaryRREAndK<"ng", 0xB980, 0xB9E4, and, GR64, GR64>;
 722   }
 723
 724   let isConvertibleToThreeAddress = 1 in {
 725     // ANDs of a 16-bit immediate, leaving other bits unaffected.
 726     // The CC result only reflects the 16-bit field, not the full register.
 727     let isCodeGenOnly = 1 in {
 728       def NILL32 : BinaryRI<"nill", 0xA57, and, GR32, imm32ll16c>;
 729       def NILH32 : BinaryRI<"nilh", 0xA56, and, GR32, imm32lh16c>;
 730     }
 731     def NILL : BinaryRI<"nill", 0xA57, and, GR64, imm64ll16c>;
 732     def NILH : BinaryRI<"nilh", 0xA56, and, GR64, imm64lh16c>;
 733     def NIHL : BinaryRI<"nihl", 0xA55, and, GR64, imm64hl16c>;
 734     def NIHH : BinaryRI<"nihh", 0xA54, and, GR64, imm64hh16c>;
 735
 736     // ANDs of a 32-bit immediate, leaving other bits unaffected.
 737     // The CC result only reflects the 32-bit field, which means we can
 738     // use it as a zero indicator for i32 operations but not otherwise.
 739     let isCodeGenOnly = 1, CCValues = 0xC, CompareZeroCCMask = 0x8 in
 740       def NILF32 : BinaryRIL<"nilf", 0xC0B, and, GR32, uimm32>;
 741     def NILF : BinaryRIL<"nilf", 0xC0B, and, GR64, imm64lf32c>;
 742     def NIHF : BinaryRIL<"nihf", 0xC0A, and, GR64, imm64hf32c>;
 743   }
 744
 745   // ANDs of memory.
 746   let CCValues = 0xC, CompareZeroCCMask = 0x8 in {
 747     defm N  : BinaryRXPair<"n", 0x54, 0xE354, and, GR32, load, 4>;
 748     def  NG : BinaryRXY<"ng", 0xE380, and, GR64, load, 8>;
 749   }
 750
 751   // AND to memory
 752   defm NI : BinarySIPair<"ni", 0x94, 0xEB54, null_frag, uimm8>;
 753 }
 754 defm : RMWIByte<and, bdaddr12pair, NI>;
 755 defm : RMWIByte<and, bdaddr20pair, NIY>;
 756
 757 //===----------------------------------------------------------------------===//
 758 // OR
 759 //===----------------------------------------------------------------------===//
 760
 761 let Defs = [CC] in {
 762   // ORs of a register.
 763   let isCommutable = 1, CCValues = 0xC, CompareZeroCCMask = 0x8 in {
 764     defm OR : BinaryRRAndK<"o", 0x16, 0xB9F6, or, GR32, GR32>;
 765     defm OGR : BinaryRREAndK<"og", 0xB981, 0xB9E6, or, GR64, GR64>;
 766   }
 767
 768   // ORs of a 16-bit immediate, leaving other bits unaffected.
 769   // The CC result only reflects the 16-bit field, not the full register.
 770   let isCodeGenOnly = 1 in {
 771     def OILL32 : BinaryRI<"oill", 0xA5B, or, GR32, imm32ll16>;
 772     def OILH32 : BinaryRI<"oilh", 0xA5A, or, GR32, imm32lh16>;
 773   }
 774   def OILL : BinaryRI<"oill", 0xA5B, or, GR64, imm64ll16>;
 775   def OILH : BinaryRI<"oilh", 0xA5A, or, GR64, imm64lh16>;
 776   def OIHL : BinaryRI<"oihl", 0xA59, or, GR64, imm64hl16>;
 777   def OIHH : BinaryRI<"oihh", 0xA58, or, GR64, imm64hh16>;
 778
 779   // ORs of a 32-bit immediate, leaving other bits unaffected.
 780   // The CC result only reflects the 32-bit field, which means we can
 781   // use it as a zero indicator for i32 operations but not otherwise.
 782   let isCodeGenOnly = 1, CCValues = 0xC, CompareZeroCCMask = 0x8 in
 783     def OILF32 : BinaryRIL<"oilf", 0xC0D, or, GR32, uimm32>;
 784   def OILF : BinaryRIL<"oilf", 0xC0D, or, GR64, imm64lf32>;
 785   def OIHF : BinaryRIL<"oihf", 0xC0C, or, GR64, imm64hf32>;
 786
 787   // ORs of memory.
 788   let CCValues = 0xC, CompareZeroCCMask = 0x8 in {
 789     defm O  : BinaryRXPair<"o", 0x56, 0xE356, or, GR32, load, 4>;
 790     def  OG : BinaryRXY<"og", 0xE381, or, GR64, load, 8>;
 791   }
 792
 793   // OR to memory
 794   defm OI : BinarySIPair<"oi", 0x96, 0xEB56, null_frag, uimm8>;
 795 }
 796 defm : RMWIByte<or, bdaddr12pair, OI>;
 797 defm : RMWIByte<or, bdaddr20pair, OIY>;
 798
 799 //===----------------------------------------------------------------------===//
 800 // XOR
 801 //===----------------------------------------------------------------------===//
 802
 803 let Defs = [CC] in {
 804   // XORs of a register.
 805   let isCommutable = 1, CCValues = 0xC, CompareZeroCCMask = 0x8 in {
 806     defm XR : BinaryRRAndK<"x", 0x17, 0xB9F7, xor, GR32, GR32>;
 807     defm XGR : BinaryRREAndK<"xg", 0xB982, 0xB9E7, xor, GR64, GR64>;
 808   }
 809
 810   // XORs of a 32-bit immediate, leaving other bits unaffected.
 811   // The CC result only reflects the 32-bit field, which means we can
 812   // use it as a zero indicator for i32 operations but not otherwise.
 813   let isCodeGenOnly = 1, CCValues = 0xC, CompareZeroCCMask = 0x8 in
 814     def XILF32 : BinaryRIL<"xilf", 0xC07, xor, GR32, uimm32>;
 815   def XILF : BinaryRIL<"xilf", 0xC07, xor, GR64, imm64lf32>;
 816   def XIHF : BinaryRIL<"xihf", 0xC06, xor, GR64, imm64hf32>;
 817
 818   // XORs of memory.
 819   let CCValues = 0xC, CompareZeroCCMask = 0x8 in {
 820     defm X  : BinaryRXPair<"x",0x57, 0xE357, xor, GR32, load, 4>;
 821     def  XG : BinaryRXY<"xg", 0xE382, xor, GR64, load, 8>;
 822   }
 823
 824   // XOR to memory
 825   defm XI : BinarySIPair<"xi", 0x97, 0xEB57, null_frag, uimm8>;
 826 }
 827 defm : RMWIByte<xor, bdaddr12pair, XI>;
 828 defm : RMWIByte<xor, bdaddr20pair, XIY>;
 829
 830 //===----------------------------------------------------------------------===//
 831 // Multiplication
 832 //===----------------------------------------------------------------------===//
 833
 834 // Multiplication of a register.
 835 let isCommutable = 1 in {
 836   def MSR  : BinaryRRE<"ms",  0xB252, mul, GR32, GR32>;
 837   def MSGR : BinaryRRE<"msg", 0xB90C, mul, GR64, GR64>;
 838 }
 839 def MSGFR : BinaryRRE<"msgf", 0xB91C, null_frag, GR64, GR32>;
 840 defm : SXB<mul, GR64, MSGFR>;
 841
 842 // Multiplication of a signed 16-bit immediate.
 843 def MHI  : BinaryRI<"mhi",  0xA7C, mul, GR32, imm32sx16>;
 844 def MGHI : BinaryRI<"mghi", 0xA7D, mul, GR64, imm64sx16>;
 845
 846 // Multiplication of a signed 32-bit immediate.
 847 def MSFI  : BinaryRIL<"msfi",  0xC21, mul, GR32, simm32>;
 848 def MSGFI : BinaryRIL<"msgfi", 0xC20, mul, GR64, imm64sx32>;
 849
 850 // Multiplication of memory.
 851 defm MH   : BinaryRXPair<"mh", 0x4C, 0xE37C, mul, GR32, sextloadi16, 2>;
 852 defm MS   : BinaryRXPair<"ms", 0x71, 0xE351, mul, GR32, load, 4>;
 853 def  MSGF : BinaryRXY<"msgf", 0xE31C, mul, GR64, sextloadi32, 4>;
 854 def  MSG  : BinaryRXY<"msg",  0xE30C, mul, GR64, load, 8>;
 855
 856 // Multiplication of a register, producing two results.
 857 def MLGR : BinaryRRE<"mlg", 0xB986, z_umul_lohi64, GR128, GR64>;
 858
 859 // Multiplication of memory, producing two results.
 860 def MLG : BinaryRXY<"mlg", 0xE386, z_umul_lohi64, GR128, load, 8>;
 861
 862 //===----------------------------------------------------------------------===//
 863 // Division and remainder
 864 //===----------------------------------------------------------------------===//
 865
 866 // Division and remainder, from registers.
 867 def DSGFR : BinaryRRE<"dsgf", 0xB91D, z_sdivrem32, GR128, GR32>;
 868 def DSGR  : BinaryRRE<"dsg",  0xB90D, z_sdivrem64, GR128, GR64>;
 869 def DLR   : BinaryRRE<"dl",   0xB997, z_udivrem32, GR128, GR32>;
 870 def DLGR  : BinaryRRE<"dlg",  0xB987, z_udivrem64, GR128, GR64>;
 871
 872 // Division and remainder, from memory.
 873 def DSGF : BinaryRXY<"dsgf", 0xE31D, z_sdivrem32, GR128, load, 4>;
 874 def DSG  : BinaryRXY<"dsg",  0xE30D, z_sdivrem64, GR128, load, 8>;
 875 def DL   : BinaryRXY<"dl",   0xE397, z_udivrem32, GR128, load, 4>;
 876 def DLG  : BinaryRXY<"dlg",  0xE387, z_udivrem64, GR128, load, 8>;
 877
 878 //===----------------------------------------------------------------------===//
 879 // Shifts
 880 //===----------------------------------------------------------------------===//
 881
 882 // Shift left.
 883 let neverHasSideEffects = 1 in {
 884   defm SLL : ShiftRSAndK<"sll", 0x89, 0xEBDF, shl, GR32>;
 885   def SLLG : ShiftRSY<"sllg", 0xEB0D, shl, GR64>;
 886 }
 887
 888 // Logical shift right.
 889 let neverHasSideEffects = 1 in {
 890   defm SRL : ShiftRSAndK<"srl", 0x88, 0xEBDE, srl, GR32>;
 891   def SRLG : ShiftRSY<"srlg", 0xEB0C, srl, GR64>;
 892 }
 893
 894 // Arithmetic shift right.
 895 let Defs = [CC], CCValues = 0xE, CompareZeroCCMask = 0xE in {
 896   defm SRA : ShiftRSAndK<"sra", 0x8A, 0xEBDC, sra, GR32>;
 897   def SRAG : ShiftRSY<"srag", 0xEB0A, sra, GR64>;
 898 }
 899
 900 // Rotate left.
 901 let neverHasSideEffects = 1 in {
 902   def RLL  : ShiftRSY<"rll",  0xEB1D, rotl, GR32>;
 903   def RLLG : ShiftRSY<"rllg", 0xEB1C, rotl, GR64>;
 904 }
 905
 906 // Rotate second operand left and inserted selected bits into first operand.
 907 // These can act like 32-bit operands provided that the constant start and
 908 // end bits (operands 2 and 3) are in the range [32, 64).
 909 let Defs = [CC] in {
 910   let isCodeGenOnly = 1 in
 911     def RISBG32 : RotateSelectRIEf<"risbg", 0xEC55, GR32, GR32>;
 912   let CCValues = 0xE, CompareZeroCCMask = 0xE in
 913     def RISBG : RotateSelectRIEf<"risbg", 0xEC55, GR64, GR64>;
 914 }
 915
 916 // Forms of RISBG that only affect one word of the destination register.
 917 // They do not set CC.
 918 let isCodeGenOnly = 1 in
 919   def RISBLG32 : RotateSelectRIEf<"risblg", 0xEC51, GR32, GR32>,
 920                  Requires<[FeatureHighWord]>;
 921 def RISBHG : RotateSelectRIEf<"risbhg", 0xEC5D, GR64, GR64>,
 922              Requires<[FeatureHighWord]>;
 923 def RISBLG : RotateSelectRIEf<"risblg", 0xEC51, GR64, GR64>,
 924              Requires<[FeatureHighWord]>;
 925
 926 // Rotate second operand left and perform a logical operation with selected
 927 // bits of the first operand.  The CC result only describes the selected bits,
 928 // so isn't useful for a full comparison against zero.
 929 let Defs = [CC] in {
 930   def RNSBG : RotateSelectRIEf<"rnsbg", 0xEC54, GR64, GR64>;
 931   def ROSBG : RotateSelectRIEf<"rosbg", 0xEC56, GR64, GR64>;
 932   def RXSBG : RotateSelectRIEf<"rxsbg", 0xEC57, GR64, GR64>;
 933 }
 934
 935 //===----------------------------------------------------------------------===//
 936 // Comparison
 937 //===----------------------------------------------------------------------===//
 938
 939 // Signed comparisons.
 940 let Defs = [CC], CCValues = 0xE in {
 941   // Comparison with a register.
 942   def CR   : CompareRR <"c",   0x19,   z_cmp,     GR32, GR32>;
 943   def CGFR : CompareRRE<"cgf", 0xB930, null_frag, GR64, GR32>;
 944   def CGR  : CompareRRE<"cg",  0xB920, z_cmp,     GR64, GR64>;
 945
 946   // Comparison with a signed 16-bit immediate.
 947   def CHI  : CompareRI<"chi",  0xA7E, z_cmp, GR32, imm32sx16>;
 948   def CGHI : CompareRI<"cghi", 0xA7F, z_cmp, GR64, imm64sx16>;
 949
 950   // Comparison with a signed 32-bit immediate.
 951   def CFI  : CompareRIL<"cfi",  0xC2D, z_cmp, GR32, simm32>;
 952   def CGFI : CompareRIL<"cgfi", 0xC2C, z_cmp, GR64, imm64sx32>;
 953
 954   // Comparison with memory.
 955   defm CH    : CompareRXPair<"ch", 0x49, 0xE379, z_cmp, GR32, sextloadi16, 2>;
 956   defm C     : CompareRXPair<"c",  0x59, 0xE359, z_cmp, GR32, load, 4>;
 957   def  CGH   : CompareRXY<"cgh", 0xE334, z_cmp, GR64, sextloadi16, 2>;
 958   def  CGF   : CompareRXY<"cgf", 0xE330, z_cmp, GR64, sextloadi32, 4>;
 959   def  CG    : CompareRXY<"cg",  0xE320, z_cmp, GR64, load, 8>;
 960   def  CHRL  : CompareRILPC<"chrl",  0xC65, z_cmp, GR32, aligned_sextloadi16>;
 961   def  CRL   : CompareRILPC<"crl",   0xC6D, z_cmp, GR32, aligned_load>;
 962   def  CGHRL : CompareRILPC<"cghrl", 0xC64, z_cmp, GR64, aligned_sextloadi16>;
 963   def  CGFRL : CompareRILPC<"cgfrl", 0xC6C, z_cmp, GR64, aligned_sextloadi32>;
 964   def  CGRL  : CompareRILPC<"cgrl",  0xC68, z_cmp, GR64, aligned_load>;
 965
 966   // Comparison between memory and a signed 16-bit immediate.
 967   def CHHSI : CompareSIL<"chhsi", 0xE554, z_cmp, sextloadi16, imm32sx16>;
 968   def CHSI  : CompareSIL<"chsi",  0xE55C, z_cmp, load,        imm32sx16>;
 969   def CGHSI : CompareSIL<"cghsi", 0xE558, z_cmp, load,        imm64sx16>;
 970 }
 971 defm : SXB<z_cmp, GR64, CGFR>;
 972
 973 // Unsigned comparisons.
 974 let Defs = [CC], CCValues = 0xE, IsLogical = 1 in {
 975   // Comparison with a register.
 976   def CLR   : CompareRR <"cl",   0x15,   z_ucmp,    GR32, GR32>;
 977   def CLGFR : CompareRRE<"clgf", 0xB931, null_frag, GR64, GR32>;
 978   def CLGR  : CompareRRE<"clg",  0xB921, z_ucmp,    GR64, GR64>;
 979
 980   // Comparison with a signed 32-bit immediate.
 981   def CLFI  : CompareRIL<"clfi",  0xC2F, z_ucmp, GR32, uimm32>;
 982   def CLGFI : CompareRIL<"clgfi", 0xC2E, z_ucmp, GR64, imm64zx32>;
 983
 984   // Comparison with memory.
 985   defm CL     : CompareRXPair<"cl", 0x55, 0xE355, z_ucmp, GR32, load, 4>;
 986   def  CLGF   : CompareRXY<"clgf", 0xE331, z_ucmp, GR64, zextloadi32, 4>;
 987   def  CLG    : CompareRXY<"clg",  0xE321, z_ucmp, GR64, load, 8>;
 988   def  CLHRL  : CompareRILPC<"clhrl",  0xC67, z_ucmp, GR32,
 989                              aligned_zextloadi16>;
 990   def  CLRL   : CompareRILPC<"clrl",   0xC6F, z_ucmp, GR32,
 991                              aligned_load>;
 992   def  CLGHRL : CompareRILPC<"clghrl", 0xC66, z_ucmp, GR64,
 993                              aligned_zextloadi16>;
 994   def  CLGFRL : CompareRILPC<"clgfrl", 0xC6E, z_ucmp, GR64,
 995                              aligned_zextloadi32>;
 996   def  CLGRL  : CompareRILPC<"clgrl",  0xC6A, z_ucmp, GR64,
 997                              aligned_load>;
 998
 999   // Comparison between memory and an unsigned 8-bit immediate.
1000   defm CLI : CompareSIPair<"cli", 0x95, 0xEB55, z_ucmp, zextloadi8, imm32zx8>;
1001
1002   // Comparison between memory and an unsigned 16-bit immediate.
1003   def CLHHSI : CompareSIL<"clhhsi", 0xE555, z_ucmp, zextloadi16, imm32zx16>;
1004   def CLFHSI : CompareSIL<"clfhsi", 0xE55D, z_ucmp, load,        imm32zx16>;
1005   def CLGHSI : CompareSIL<"clghsi", 0xE559, z_ucmp, load,        imm64zx16>;
1006 }
1007 defm : ZXB<z_ucmp, GR64, CLGFR>;
1008
1009 // Memory-to-memory comparison.
1010 let mayLoad = 1, Defs = [CC] in
1011   defm CLC : MemorySS<"clc", 0xD5, z_clc>;
1012
1013 // String comparison.
1014 let mayLoad = 1, Defs = [CC], Uses = [R0W] in
1015   defm CLST : StringRRE<"clst", 0xB25D, z_strcmp>;
1016
1017 //===----------------------------------------------------------------------===//
1018 // Atomic operations
1019 //===----------------------------------------------------------------------===//
1020
1021 def ATOMIC_SWAPW        : AtomicLoadWBinaryReg<z_atomic_swapw>;
1022 def ATOMIC_SWAP_32      : AtomicLoadBinaryReg32<atomic_swap_32>;
1023 def ATOMIC_SWAP_64      : AtomicLoadBinaryReg64<atomic_swap_64>;
1024
1025 def ATOMIC_LOADW_AR     : AtomicLoadWBinaryReg<z_atomic_loadw_add>;
1026 def ATOMIC_LOADW_AFI    : AtomicLoadWBinaryImm<z_atomic_loadw_add, simm32>;
1027 def ATOMIC_LOAD_AR      : AtomicLoadBinaryReg32<atomic_load_add_32>;
1028 def ATOMIC_LOAD_AHI     : AtomicLoadBinaryImm32<atomic_load_add_32, imm32sx16>;
1029 def ATOMIC_LOAD_AFI     : AtomicLoadBinaryImm32<atomic_load_add_32, simm32>;
1030 def ATOMIC_LOAD_AGR     : AtomicLoadBinaryReg64<atomic_load_add_64>;
1031 def ATOMIC_LOAD_AGHI    : AtomicLoadBinaryImm64<atomic_load_add_64, imm64sx16>;
1032 def ATOMIC_LOAD_AGFI    : AtomicLoadBinaryImm64<atomic_load_add_64, imm64sx32>;
1033
1034 def ATOMIC_LOADW_SR     : AtomicLoadWBinaryReg<z_atomic_loadw_sub>;
1035 def ATOMIC_LOAD_SR      : AtomicLoadBinaryReg32<atomic_load_sub_32>;
1036 def ATOMIC_LOAD_SGR     : AtomicLoadBinaryReg64<atomic_load_sub_64>;
1037
1038 def ATOMIC_LOADW_NR     : AtomicLoadWBinaryReg<z_atomic_loadw_and>;
1039 def ATOMIC_LOADW_NILH   : AtomicLoadWBinaryImm<z_atomic_loadw_and, imm32lh16c>;
1040 def ATOMIC_LOAD_NR      : AtomicLoadBinaryReg32<atomic_load_and_32>;
1041 def ATOMIC_LOAD_NILL32  : AtomicLoadBinaryImm32<atomic_load_and_32, imm32ll16c>;
1042 def ATOMIC_LOAD_NILH32  : AtomicLoadBinaryImm32<atomic_load_and_32, imm32lh16c>;
1043 def ATOMIC_LOAD_NILF32  : AtomicLoadBinaryImm32<atomic_load_and_32, uimm32>;
1044 def ATOMIC_LOAD_NGR     : AtomicLoadBinaryReg64<atomic_load_and_64>;
1045 def ATOMIC_LOAD_NILL    : AtomicLoadBinaryImm64<atomic_load_and_64, imm64ll16c>;
1046 def ATOMIC_LOAD_NILH    : AtomicLoadBinaryImm64<atomic_load_and_64, imm64lh16c>;
1047 def ATOMIC_LOAD_NIHL    : AtomicLoadBinaryImm64<atomic_load_and_64, imm64hl16c>;
1048 def ATOMIC_LOAD_NIHH    : AtomicLoadBinaryImm64<atomic_load_and_64, imm64hh16c>;
1049 def ATOMIC_LOAD_NILF    : AtomicLoadBinaryImm64<atomic_load_and_64, imm64lf32c>;
1050 def ATOMIC_LOAD_NIHF    : AtomicLoadBinaryImm64<atomic_load_and_64, imm64hf32c>;
1051
1052 def ATOMIC_LOADW_OR     : AtomicLoadWBinaryReg<z_atomic_loadw_or>;
1053 def ATOMIC_LOADW_OILH   : AtomicLoadWBinaryImm<z_atomic_loadw_or, imm32lh16>;
1054 def ATOMIC_LOAD_OR      : AtomicLoadBinaryReg32<atomic_load_or_32>;
1055 def ATOMIC_LOAD_OILL32  : AtomicLoadBinaryImm32<atomic_load_or_32, imm32ll16>;
1056 def ATOMIC_LOAD_OILH32  : AtomicLoadBinaryImm32<atomic_load_or_32, imm32lh16>;
1057 def ATOMIC_LOAD_OILF32  : AtomicLoadBinaryImm32<atomic_load_or_32, uimm32>;
1058 def ATOMIC_LOAD_OGR     : AtomicLoadBinaryReg64<atomic_load_or_64>;
1059 def ATOMIC_LOAD_OILL    : AtomicLoadBinaryImm64<atomic_load_or_64, imm64ll16>;
1060 def ATOMIC_LOAD_OILH    : AtomicLoadBinaryImm64<atomic_load_or_64, imm64lh16>;
1061 def ATOMIC_LOAD_OIHL    : AtomicLoadBinaryImm64<atomic_load_or_64, imm64hl16>;
1062 def ATOMIC_LOAD_OIHH    : AtomicLoadBinaryImm64<atomic_load_or_64, imm64hh16>;
1063 def ATOMIC_LOAD_OILF    : AtomicLoadBinaryImm64<atomic_load_or_64, imm64lf32>;
1064 def ATOMIC_LOAD_OIHF    : AtomicLoadBinaryImm64<atomic_load_or_64, imm64hf32>;
1065
1066 def ATOMIC_LOADW_XR     : AtomicLoadWBinaryReg<z_atomic_loadw_xor>;
1067 def ATOMIC_LOADW_XILF   : AtomicLoadWBinaryImm<z_atomic_loadw_xor, uimm32>;
1068 def ATOMIC_LOAD_XR      : AtomicLoadBinaryReg32<atomic_load_xor_32>;
1069 def ATOMIC_LOAD_XILF32  : AtomicLoadBinaryImm32<atomic_load_xor_32, uimm32>;
1070 def ATOMIC_LOAD_XGR     : AtomicLoadBinaryReg64<atomic_load_xor_64>;
1071 def ATOMIC_LOAD_XILF    : AtomicLoadBinaryImm64<atomic_load_xor_64, imm64lf32>;
1072 def ATOMIC_LOAD_XIHF    : AtomicLoadBinaryImm64<atomic_load_xor_64, imm64hf32>;
1073
1074 def ATOMIC_LOADW_NRi    : AtomicLoadWBinaryReg<z_atomic_loadw_nand>;
1075 def ATOMIC_LOADW_NILHi  : AtomicLoadWBinaryImm<z_atomic_loadw_nand,
1076                                                imm32lh16c>;
1077 def ATOMIC_LOAD_NRi     : AtomicLoadBinaryReg32<atomic_load_nand_32>;
1078 def ATOMIC_LOAD_NILL32i : AtomicLoadBinaryImm32<atomic_load_nand_32,
1079                                                 imm32ll16c>;
1080 def ATOMIC_LOAD_NILH32i : AtomicLoadBinaryImm32<atomic_load_nand_32,
1081                                                 imm32lh16c>;
1082 def ATOMIC_LOAD_NILF32i : AtomicLoadBinaryImm32<atomic_load_nand_32, uimm32>;
1083 def ATOMIC_LOAD_NGRi    : AtomicLoadBinaryReg64<atomic_load_nand_64>;
1084 def ATOMIC_LOAD_NILLi   : AtomicLoadBinaryImm64<atomic_load_nand_64,
1085                                                 imm64ll16c>;
1086 def ATOMIC_LOAD_NILHi   : AtomicLoadBinaryImm64<atomic_load_nand_64,
1087                                                 imm64lh16c>;
1088 def ATOMIC_LOAD_NIHLi   : AtomicLoadBinaryImm64<atomic_load_nand_64,
1089                                                 imm64hl16c>;
1090 def ATOMIC_LOAD_NIHHi   : AtomicLoadBinaryImm64<atomic_load_nand_64,
1091                                                 imm64hh16c>;
1092 def ATOMIC_LOAD_NILFi   : AtomicLoadBinaryImm64<atomic_load_nand_64,
1093                                                 imm64lf32c>;
1094 def ATOMIC_LOAD_NIHFi   : AtomicLoadBinaryImm64<atomic_load_nand_64,
1095                                                 imm64hf32c>;
1096
1097 def ATOMIC_LOADW_MIN    : AtomicLoadWBinaryReg<z_atomic_loadw_min>;
1098 def ATOMIC_LOAD_MIN_32  : AtomicLoadBinaryReg32<atomic_load_min_32>;
1099 def ATOMIC_LOAD_MIN_64  : AtomicLoadBinaryReg64<atomic_load_min_64>;
1100
1101 def ATOMIC_LOADW_MAX    : AtomicLoadWBinaryReg<z_atomic_loadw_max>;
1102 def ATOMIC_LOAD_MAX_32  : AtomicLoadBinaryReg32<atomic_load_max_32>;
1103 def ATOMIC_LOAD_MAX_64  : AtomicLoadBinaryReg64<atomic_load_max_64>;
1104
1105 def ATOMIC_LOADW_UMIN   : AtomicLoadWBinaryReg<z_atomic_loadw_umin>;
1106 def ATOMIC_LOAD_UMIN_32 : AtomicLoadBinaryReg32<atomic_load_umin_32>;
1107 def ATOMIC_LOAD_UMIN_64 : AtomicLoadBinaryReg64<atomic_load_umin_64>;
1108
1109 def ATOMIC_LOADW_UMAX   : AtomicLoadWBinaryReg<z_atomic_loadw_umax>;
1110 def ATOMIC_LOAD_UMAX_32 : AtomicLoadBinaryReg32<atomic_load_umax_32>;
1111 def ATOMIC_LOAD_UMAX_64 : AtomicLoadBinaryReg64<atomic_load_umax_64>;
1112
1113 def ATOMIC_CMP_SWAPW
1114   : Pseudo<(outs GR32:$dst), (ins bdaddr20only:$addr, GR32:$cmp, GR32:$swap,
1115                                   ADDR32:$bitshift, ADDR32:$negbitshift,
1116                                   uimm32:$bitsize),
1117            [(set GR32:$dst,
1118                  (z_atomic_cmp_swapw bdaddr20only:$addr, GR32:$cmp, GR32:$swap,
1119                                      ADDR32:$bitshift, ADDR32:$negbitshift,
1120                                      uimm32:$bitsize))]> {
1121   let Defs = [CC];
1122   let mayLoad = 1;
1123   let mayStore = 1;
1124   let usesCustomInserter = 1;
1125 }
1126
1127 let Defs = [CC] in {
1128   defm CS  : CmpSwapRSPair<"cs", 0xBA, 0xEB14, atomic_cmp_swap_32, GR32>;
1129   def  CSG : CmpSwapRSY<"csg", 0xEB30, atomic_cmp_swap_64, GR64>;
1130 }
1131
1132 //===----------------------------------------------------------------------===//
1133 // Miscellaneous Instructions.
1134 //===----------------------------------------------------------------------===//
1135
1136 // Extract CC into bits 29 and 28 of a register.
1137 let Uses = [CC] in
1138   def IPM : InherentRRE<"ipm", 0xB222, GR32, (z_ipm)>;
1139
1140 // Read a 32-bit access register into a GR32.  As with all GR32 operations,
1141 // the upper 32 bits of the enclosing GR64 remain unchanged, which is useful
1142 // when a 64-bit address is stored in a pair of access registers.
1143 def EAR : InstRRE<0xB24F, (outs GR32:$R1), (ins access_reg:$R2),
1144                   "ear\t$R1, $R2",
1145                   [(set GR32:$R1, (z_extract_access access_reg:$R2))]>;
1146
1147 // Find leftmost one, AKA count leading zeros.  The instruction actually
1148 // returns a pair of GR64s, the first giving the number of leading zeros
1149 // and the second giving a copy of the source with the leftmost one bit
1150 // cleared.  We only use the first result here.
1151 let Defs = [CC] in {
1152   def FLOGR : UnaryRRE<"flog", 0xB983, null_frag, GR128, GR64>;
1153 }
1154 def : Pat<(ctlz GR64:$src),
1155           (EXTRACT_SUBREG (FLOGR GR64:$src), subreg_high)>;
1156
1157 // Use subregs to populate the "don't care" bits in a 32-bit to 64-bit anyext.
1158 def : Pat<(i64 (anyext GR32:$src)),
1159           (INSERT_SUBREG (i64 (IMPLICIT_DEF)), GR32:$src, subreg_32bit)>;
1160
1161 // There are no 32-bit equivalents of LLILL and LLILH, so use a full
1162 // 64-bit move followed by a subreg.  This preserves the invariant that
1163 // all GR32 operations only modify the low 32 bits.
1164 def : Pat<(i32 imm32ll16:$src),
1165           (EXTRACT_SUBREG (LLILL (LL16 imm:$src)), subreg_32bit)>;
1166 def : Pat<(i32 imm32lh16:$src),
1167           (EXTRACT_SUBREG (LLILH (LH16 imm:$src)), subreg_32bit)>;
1168
1169 // Extend GR32s and GR64s to GR128s.
1170 let usesCustomInserter = 1 in {
1171   def AEXT128_64 : Pseudo<(outs GR128:$dst), (ins GR64:$src), []>;
1172   def ZEXT128_32 : Pseudo<(outs GR128:$dst), (ins GR32:$src), []>;
1173   def ZEXT128_64 : Pseudo<(outs GR128:$dst), (ins GR64:$src), []>;
1174 }
1175
1176 // Search a block of memory for a character.
1177 let mayLoad = 1, Defs = [CC], Uses = [R0W] in
1178   defm SRST : StringRRE<"srst", 0xb25e, z_search_string>;
1179
1180 //===----------------------------------------------------------------------===//
1181 // Peepholes.
1182 //===----------------------------------------------------------------------===//
1183
1184 // Use AL* for GR64 additions of unsigned 32-bit values.
1185 defm : ZXB<add, GR64, ALGFR>;
1186 def  : Pat<(add GR64:$src1, imm64zx32:$src2),
1187            (ALGFI GR64:$src1, imm64zx32:$src2)>;
1188 def  : Pat<(add GR64:$src1, (zextloadi32 bdxaddr20only:$addr)),
1189            (ALGF GR64:$src1, bdxaddr20only:$addr)>;
1190
1191 // Use SL* for GR64 subtractions of unsigned 32-bit values.
1192 defm : ZXB<sub, GR64, SLGFR>;
1193 def  : Pat<(add GR64:$src1, imm64zx32n:$src2),
1194            (SLGFI GR64:$src1, imm64zx32n:$src2)>;
1195 def  : Pat<(sub GR64:$src1, (zextloadi32 bdxaddr20only:$addr)),
1196            (SLGF GR64:$src1, bdxaddr20only:$addr)>;
1197
1198 // Optimize sign-extended 1/0 selects to -1/0 selects.  This is important
1199 // for vector legalization.
1200 def : Pat<(sra (shl (i32 (z_select_ccmask 1, 0, uimm8zx4:$valid, uimm8zx4:$cc)),
1201                          (i32 31)),
1202                     (i32 31)),
1203           (Select32 (LHI -1), (LHI 0), uimm8zx4:$valid, uimm8zx4:$cc)>;
1204 def : Pat<(sra (shl (i64 (anyext (i32 (z_select_ccmask 1, 0, uimm8zx4:$valid,
1205                                                        uimm8zx4:$cc)))),
1206                     (i32 63)),
1207                (i32 63)),
1208           (Select64 (LGHI -1), (LGHI 0), uimm8zx4:$valid, uimm8zx4:$cc)>;